code.delx.au - gnu-emacs-elpa/blob - beacon.el

   1 ;;; beacon.el --- Highlight the cursor whenever the window scrolls  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Artur Malabarba <emacs@endlessparentheses.com>
   6 ;; URL: https://github.com/Malabarba/beacon
   7 ;; Keywords: convenience
   8 ;; Version: 0.5.1
   9 ;; Package-Requires: ((seq "1.11"))
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a global minor-mode. Turn it on everywhere with:
  27 ;; ┌────
  28 ;; │ (beacon-mode 1)
  29 ;; └────
  30 ;;
  31 ;; Whenever the window scrolls a light will shine on top of your cursor so
  32 ;; you know where it is.
  33 ;;
  34 ;; That’s it.
  35 ;;
  36 ;; See the accompanying Readme.org for configuration details.
  37
  38 ;;; Code:
  39
  40 (require 'seq)
  41 (require 'faces)
  42 (unless (fboundp 'seq-mapn)
  43   ;; This is for people who are on outdated Emacs snapshots. Will be
  44   ;; deleted in a couple of weeks.
  45   (defun seq-mapn (function sequence &rest sequences)
  46     "Like `seq-map' but FUNCTION is mapped over all SEQUENCES.
  47 The arity of FUNCTION must match the number of SEQUENCES, and the
  48 mapping stops on the shortest sequence.
  49 Return a list of the results.
  50
  51 \(fn FUNCTION SEQUENCES...)"
  52     (let ((result nil)
  53           (sequences (seq-map (lambda (s) (seq-into s 'list))
  54                             (cons sequence sequences))))
  55       (while (not (memq nil sequences))
  56         (push (apply function (seq-map #'car sequences)) result)
  57         (setq sequences (seq-map #'cdr sequences)))
  58       (nreverse result))))
  59
  60 (defgroup beacon nil
  61   "Customization group for beacon."
  62   :group 'emacs
  63   :prefix "beacon-")
  64
  65 (defvar beacon--timer nil)
  66
  67 (defcustom beacon-push-mark 35
  68   "Should the mark be pushed before long movements?
  69 If nil, `beacon' will not push the mark.
  70 Otherwise this should be a number, and `beacon' will push the
  71 mark whenever point moves more than that many lines."
  72   :type '(choice integer (const nil)))
  73
  74 (defcustom beacon-blink-when-point-moves-vertically nil
  75   "Should the beacon blink when moving a long distance vertically?
  76 If nil, don't blink due to vertical movement.
  77 If non-nil, this should be an integer, which is the minimum
  78 movement distance (in lines) that triggers a beacon blink."
  79   :type '(choice integer (const nil)))
  80
  81 (defcustom beacon-blink-when-point-moves-horizontally nil
  82   "Should the beacon blink when moving a long distance horizontally?
  83 If nil, don't blink due to horizontal movement.
  84 If non-nil, this should be an integer, which is the minimum
  85 movement distance (in columns) that triggers a beacon blink."
  86   :type '(choice integer (const nil)))
  87
  88 (defcustom beacon-blink-when-buffer-changes t
  89   "Should the beacon blink when changing buffer?"
  90   :type 'boolean)
  91
  92 (defcustom beacon-blink-when-window-scrolls t
  93   "Should the beacon blink when the window scrolls?"
  94   :type 'boolean)
  95
  96 (defcustom beacon-blink-when-window-changes t
  97   "Should the beacon blink when the window changes?"
  98   :type 'boolean)
  99
 100 (defcustom beacon-blink-when-focused nil
 101   "Should the beacon blink when Emacs gains focus?
 102 Note that, due to a limitation of `focus-in-hook', this might
 103 trigger false positives on some systems."
 104   :type 'boolean
 105   :package-version '(beacon . "0.2"))
 106
 107 (defcustom beacon-blink-duration 0.3
 108   "Time, in seconds, that the blink should last."
 109   :type 'number)
 110
 111 (defcustom beacon-blink-delay 0.3
 112   "Time, in seconds, before starting to fade the beacon."
 113   :type 'number)
 114
 115 (defcustom beacon-size 40
 116   "Size of the beacon in characters."
 117   :type 'number)
 118
 119 (defcustom beacon-color 0.5
 120   "Color of the beacon.
 121 This can be a string or a number.
 122
 123 If it is a number, the color is taken to be white or
 124 black (depending on the current theme's background) and this
 125 number is a float between 0 and 1 specifing the brightness.
 126
 127 If it is a string, it is a color name or specification,
 128 e.g. \"#666600\"."
 129   :type '(choice number color))
 130
 131 (defface beacon-fallback-background
 132   '((((class color) (background light)) (:background "black"))
 133     (((class color) (background dark)) (:background "white")))
 134   "Fallback beacon background color.
 135 Used in cases where the color can't be determined by Emacs.
 136 Only the background of this face is used.")
 137
 138 (defvar beacon-dont-blink-predicates nil
 139   "A list of predicates that prevent the beacon blink.
 140 These predicate functions are called in order, with no
 141 arguments, before blinking the beacon.  If any returns
 142 non-nil, the beacon will not blink.
 143
 144 For instance, if you want to disable beacon on buffers where
 145 `hl-line-mode' is on, you can do:
 146
 147     (add-hook \\='beacon-dont-blink-predicates
 148               (lambda () (bound-and-true-p hl-line-mode)))")
 149
 150 (add-hook 'beacon-dont-blink-predicates #'window-minibuffer-p)
 151
 152 (defcustom beacon-dont-blink-major-modes '(magit-status-mode magit-popup-mode)
 153   "A list of major-modes where the beacon won't blink.
 154 Whenever the current buffer satisfies `derived-mode-p' for
 155 one of the major-modes on this list, the beacon will not
 156 blink."
 157   :type '(repeat symbol))
 158
 159 (defcustom beacon-dont-blink-commands '(recenter-top-bottom)
 160   "A list of commands that should not make the beacon blink.
 161 Use this for commands that scroll the window in very
 162 predictable ways, when the blink would be more distracting
 163 than helpful.."
 164   :type '(repeat symbol))
 165
 166 \f
 167 ;;; Internal variables
 168 (defvar beacon--window-scrolled nil)
 169 (defvar beacon--previous-place nil)
 170 (defvar beacon--previous-mark-head nil)
 171 (defvar beacon--previous-window nil)
 172 (defvar beacon--previous-window-start 0)
 173
 174 (defun beacon--record-vars ()
 175   (unless (window-minibuffer-p)
 176     (setq beacon--previous-mark-head (car mark-ring))
 177     (setq beacon--previous-place (point-marker))
 178     (setq beacon--previous-window (selected-window))
 179     (setq beacon--previous-window-start (window-start))))
 180
 181 \f
 182 ;;; Overlays
 183 (defvar beacon--ovs nil)
 184
 185 (defconst beacon-overlay-priority (/ most-positive-fixnum 2)
 186   "Priotiy used on all of our overlays.")
 187
 188 (defun beacon--make-overlay (length &rest properties)
 189   "Put an overlay at point with background COLOR."
 190   (let ((ov (make-overlay (point) (+ length (point)))))
 191     (overlay-put ov 'beacon t)
 192     ;; Our overlay is very temporary, so we take the liberty of giving
 193     ;; it a high priority.
 194     (overlay-put ov 'priority beacon-overlay-priority)
 195     (overlay-put ov 'window (selected-window))
 196     (while properties
 197       (overlay-put ov (pop properties) (pop properties)))
 198     (push ov beacon--ovs)
 199     ov))
 200
 201 (defun beacon--colored-overlay (color)
 202   "Put an overlay at point with background COLOR."
 203   (beacon--make-overlay 1 'face (list :background color)))
 204
 205 (defun beacon--ov-put-after-string (overlay colors)
 206   "Add an after-string property to OVERLAY.
 207 The property's value is a string of spaces with background
 208 COLORS applied to each one.
 209 If COLORS is nil, OVERLAY is deleted!"
 210   (if (not colors)
 211       (when (overlayp overlay)
 212         (delete-overlay overlay))
 213     (overlay-put overlay 'beacon-colors colors)
 214     (overlay-put overlay 'after-string
 215                  (propertize
 216                   (mapconcat (lambda (c) (propertize " " 'face (list :background c)))
 217                              colors
 218                              "")
 219                   'cursor 1000))))
 220
 221 (defun beacon--after-string-overlay (colors)
 222   "Put an overlay at point with an after-string property.
 223 The property's value is a string of spaces with background
 224 COLORS applied to each one."
 225   ;; The after-string must not be longer than the remaining columns
 226   ;; from point to right window-end else it will be wrapped around.
 227   (let ((colors (seq-take colors (- (window-width) (current-column)))))
 228     (beacon--ov-put-after-string (beacon--make-overlay 0) colors)))
 229
 230 (defun beacon--ov-at-point ()
 231   (car (or (seq-filter (lambda (o) (overlay-get o 'beacon))
 232                        (overlays-in (point) (point)))
 233            (seq-filter (lambda (o) (overlay-get o 'beacon))
 234                        (overlays-at (point))))))
 235
 236 (defun beacon--vanish ()
 237   "Turn off the beacon."
 238   (when (timerp beacon--timer)
 239     (cancel-timer beacon--timer))
 240   (mapc #'delete-overlay beacon--ovs)
 241   (setq beacon--ovs nil))
 242
 243 \f
 244 ;;; Colors
 245 (defun beacon--int-range (a b)
 246   "Return a list of integers between A inclusive and B exclusive.
 247 Only returns `beacon-size' elements."
 248   (let ((d (/ (- b a) beacon-size))
 249         (out (list a)))
 250     (dotimes (_ (1- beacon-size))
 251       (push (+ (car out) d) out))
 252     (nreverse out)))
 253
 254 (defun beacon--color-range ()
 255   "Return a list of background colors for the beacon."
 256   (let* ((default-bg (or (background-color-at-point)
 257                          (face-background 'default)))
 258          (bg (color-values (if (string-match "\\`unspecified-" default-bg)
 259                                (face-attribute 'beacon-fallback-background :background)
 260                              default-bg)))
 261          (fg (cond
 262               ((stringp beacon-color) (color-values beacon-color))
 263               ((< (color-distance "black" bg)
 264                   (color-distance "white" bg))
 265                (make-list 3 (* beacon-color 65535)))
 266               (t (make-list 3 (* (- 1 beacon-color) 65535))))))
 267     (apply #'seq-mapn (lambda (r g b) (format "#%04x%04x%04x" r g b))
 268            (mapcar (lambda (n) (butlast (beacon--int-range (elt fg n) (elt bg n))))
 269                    [0 1 2]))))
 270
 271 \f
 272 ;;; Blinking
 273 (defun beacon--shine ()
 274   "Shine a beacon at point."
 275   (let ((colors (beacon--color-range)))
 276     (save-excursion
 277       (while colors
 278         (if (looking-at "$")
 279             (progn
 280               (beacon--after-string-overlay colors)
 281               (setq colors nil))
 282           (beacon--colored-overlay (pop colors))
 283           (forward-char 1))))))
 284
 285 (defun beacon--dec ()
 286   "Decrease the beacon brightness by one."
 287   (pcase (beacon--ov-at-point)
 288     (`nil (beacon--vanish))
 289     ((and o (let c (overlay-get o 'beacon-colors)) (guard c))
 290      (beacon--ov-put-after-string o (cdr c)))
 291     (o
 292      (delete-overlay o)
 293      (save-excursion
 294        (while (progn (forward-char 1)
 295                      (setq o (beacon--ov-at-point)))
 296          (let ((colors (overlay-get o 'beacon-colors)))
 297            (if (not colors)
 298                (move-overlay o (1- (point)) (point))
 299              (forward-char -1)
 300              (beacon--colored-overlay (pop colors))
 301              (beacon--ov-put-after-string o colors)
 302              (forward-char 1))))))))
 303
 304 (defun beacon-blink ()
 305   "Blink the beacon at the position of the cursor."
 306   (interactive)
 307   (beacon--vanish)
 308   ;; Record vars here in case something is blinking outside the
 309   ;; command loop.
 310   (beacon--record-vars)
 311   (unless (or (not beacon-mode)
 312               (run-hook-with-args-until-success 'beacon-dont-blink-predicates)
 313               (seq-find #'derived-mode-p beacon-dont-blink-major-modes)
 314               (memq (or this-command last-command) beacon-dont-blink-commands))
 315     (beacon--shine)
 316     (setq beacon--timer
 317           (run-at-time beacon-blink-delay
 318                        (/ beacon-blink-duration 1.0 beacon-size)
 319                        #'beacon--dec))))
 320
 321 \f
 322 ;;; Movement detection
 323 (defun beacon--movement-> (delta-y &optional delta-x)
 324   "Return non-nil if latest vertical movement is > DELTA-Y.
 325 If DELTA-Y is nil, return nil.
 326 The same is true for DELTA-X and horizonta movement."
 327   (and delta-y
 328        (markerp beacon--previous-place)
 329        (equal (marker-buffer beacon--previous-place)
 330               (current-buffer))
 331        ;; Quick check that prevents running the code below in very
 332        ;; short movements (like typing).
 333        (> (abs (- (point) beacon--previous-place))
 334           delta-y)
 335        ;; Col movement.
 336        (or (and delta-x
 337                 (> (abs (- (current-column)
 338                            (save-excursion
 339                              (goto-char beacon--previous-place)
 340                              (current-column))))
 341                    delta-x))
 342            ;; Check if the movement was >= DELTA lines by moving DELTA
 343            ;; lines. `count-screen-lines' is too slow if the movement had
 344            ;; thousands of lines.
 345            (save-excursion
 346              (let ((p (point)))
 347                (goto-char (min beacon--previous-place p))
 348                (vertical-motion delta-y)
 349                (> (max p beacon--previous-place)
 350                   (line-beginning-position)))))))
 351
 352 (defun beacon--maybe-push-mark ()
 353   "Push mark if it seems to be safe."
 354   (when (and (not mark-active)
 355              (beacon--movement-> beacon-push-mark))
 356     (let ((head (car mark-ring)))
 357       (when (and (eq beacon--previous-mark-head head)
 358                  (not (equal head beacon--previous-place)))
 359         (push-mark beacon--previous-place 'silent)))))
 360
 361 (defun beacon--post-command ()
 362   "Blink if point moved very far."
 363   (cond
 364    ((not (markerp beacon--previous-place))
 365     (beacon--vanish))
 366    ;; Blink for switching windows.
 367    ((and beacon-blink-when-window-changes
 368          (not (eq beacon--previous-window (selected-window))))
 369     (beacon-blink))
 370    ;; Blink for scrolling.
 371    ((and beacon--window-scrolled
 372          (equal beacon--window-scrolled (selected-window)))
 373     (beacon-blink))
 374    ;; Blink for movement
 375    ((beacon--movement-> beacon-blink-when-point-moves-vertically
 376                   beacon-blink-when-point-moves-horizontally)
 377     (beacon-blink))
 378    ;; Even if we don't blink, vanish any previous beacon.
 379    (t (beacon--vanish)))
 380   (beacon--maybe-push-mark)
 381   (setq beacon--window-scrolled nil))
 382
 383 (defun beacon--window-scroll-function (win start-pos)
 384   "Blink the beacon or record that window has been scrolled.
 385 If invoked during the command loop, record the current window so
 386 that it may be blinked on post-command.  This is because the
 387 scrolled window might not be active, but we only know that at
 388 `post-command-hook'.
 389
 390 If invoked outside the command loop, `post-command-hook' would be
 391 unreliable, so just blink immediately."
 392   (unless (or (and (equal beacon--previous-window-start start-pos)
 393                    (equal beacon--previous-window win))
 394               (not beacon-blink-when-window-scrolls))
 395     (if this-command
 396         (setq beacon--window-scrolled win)
 397       (setq beacon--window-scrolled nil)
 398       (beacon-blink))))
 399
 400 (defun beacon--blink-on-focus ()
 401   "Blink if `beacon-blink-when-focused' is non-nil"
 402   (when beacon-blink-when-focused
 403     (beacon-blink)))
 404
 405 \f
 406 ;;; Minor-mode
 407 (defcustom beacon-lighter
 408   (cond
 409    ;; ((char-displayable-p ?💡) " 💡")
 410    ;; ((char-displayable-p ?Λ) " Λ")
 411    (t " (*)"))
 412   "Lighter string used on the mode-line."
 413   :type 'string)
 414
 415 ;;;###autoload
 416 (define-minor-mode beacon-mode
 417   nil nil beacon-lighter nil
 418   :global t
 419   (if beacon-mode
 420       (progn
 421         (add-hook 'window-scroll-functions #'beacon--window-scroll-function)
 422         (add-hook 'focus-in-hook #'beacon--blink-on-focus)
 423         (add-hook 'post-command-hook #'beacon--post-command)
 424         (add-hook 'pre-command-hook #'beacon--record-vars)
 425         (add-hook 'pre-command-hook #'beacon--vanish))
 426     (remove-hook 'focus-in-hook #'beacon--blink-on-focus)
 427     (remove-hook 'window-scroll-functions #'beacon--window-scroll-function)
 428     (remove-hook 'post-command-hook #'beacon--post-command)
 429     (remove-hook 'pre-command-hook #'beacon--record-vars)
 430     (remove-hook 'pre-command-hook #'beacon--vanish)))
 431
 432 (provide 'beacon)
 433 ;;; beacon.el ends here
 434
 435 ;; Local Variables:
 436 ;; indent-tabs-mode: nil
 437 ;; End: