code.delx.au - gnu-emacs-elpa/blob - beacon.el

   1 ;;; beacon.el --- Highlight the cursor whenever it moves long distances  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015  Artur Malabarba
   4
   5 ;; Author: Artur Malabarba <emacs@endlessparentheses.com>
   6 ;; URL: https://github.com/Malabarba/beacon
   7 ;; Keywords: convenience
   8 ;; Version: 0.1
   9 ;; Package-Requires: ((cl-lib "0.5"))
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a global minor-mode.  Turn it on everywhere with
  27 ;;     (beacon-mode 1)
  28
  29 ;;; Code:
  30
  31 (require 'cl-lib)
  32
  33 (defgroup beacon nil
  34   "Customization group for beacon."
  35   :group 'emacs
  36   :prefix "beacon-")
  37
  38 (defvar beacon--timer nil)
  39
  40 (defcustom beacon-push-mark nil
  41   "Should the mark be pushed before long movements?
  42 If nil, `beacon' will not push the mark.
  43 Otherwise this should be a number, and `beacon' will push the
  44 mark whenever point moves more than that many lines."
  45   :type '(choice integer (const nil)))
  46
  47 (defcustom beacon-blink-when-point-moves nil
  48   "Should the beacon blink when moving a long distance?
  49 If nil, don't blink due to plain movement.
  50 If non-nil, this should be an integer, which is the minimum
  51 movement distance (in lines) that triggers a beacon blink."
  52   :type '(choice integer (const nil)))
  53
  54 (defcustom beacon-blink-when-buffer-changes t
  55   "Should the beacon blink when changing buffer?"
  56   :type 'boolean)
  57
  58 (defcustom beacon-blink-when-window-scrolls t
  59   "Should the beacon blink when the window scrolls?"
  60   :type 'boolean)
  61
  62 (defcustom beacon-blink-duration 0.3
  63   "Time, in seconds, that the blink should last."
  64   :type 'number)
  65
  66 (defcustom beacon-blink-delay 0.3
  67   "Time, in seconds, before starting to fade the beacon."
  68   :type 'number)
  69
  70 (defcustom beacon-size 40
  71   "Size of the beacon in characters."
  72   :type 'number)
  73
  74 (defcustom beacon-color 0.5
  75   "Color of the beacon.
  76 This can be a string or a number.
  77
  78 If it is a number, the color is taken to be white or
  79 black (depending on the current theme's background) and this
  80 number is a float between 0 and 1 specifing the brightness.
  81
  82 If it is a string, it is a color name or specification,
  83 e.g. \"#666600\"."
  84   :type '(choice number color))
  85
  86 \f
  87 ;;; Overlays
  88 (defvar beacon--ovs nil)
  89
  90 (defun beacon--colored-overlay (color)
  91   "Put an overlay at point with background COLOR."
  92   (let ((ov (make-overlay (point) (1+ (point)))))
  93     (overlay-put ov 'face (list :background color))
  94     (overlay-put ov 'beacon t)
  95     (push ov beacon--ovs)))
  96
  97 (defun beacon--ov-put-after-string (overlay colors)
  98   "Add an after-string property to OVERLAY.
  99 The property's value is a string of spaces with background
 100 COLORS applied to each one."
 101   (if (not colors)
 102       (delete-overlay overlay)
 103     (overlay-put overlay 'beacon-colors colors)
 104     (overlay-put overlay 'after-string
 105                  (propertize
 106                   (mapconcat (lambda (c) (propertize " " 'face (list :background c)))
 107                              colors
 108                              "")
 109                   'cursor 1000))))
 110
 111 (defun beacon--after-string-overlay (colors)
 112   "Put an overlay at point with an after-string property.
 113 The property's value is a string of spaces with background
 114 COLORS applied to each one."
 115   (let ((ov (make-overlay (point) (point))))
 116     (beacon--ov-put-after-string ov colors)
 117     (overlay-put ov 'beacon t)
 118     (push ov beacon--ovs)))
 119
 120 (defun beacon--ov-at-point ()
 121   (car (or (cl-member-if (lambda (o) (overlay-get o 'beacon))
 122                          (overlays-in (point) (point)))
 123            (cl-member-if (lambda (o) (overlay-get o 'beacon))
 124                          (overlays-at (point))))))
 125
 126 (defun beacon--vanish ()
 127   "Turn off the beacon."
 128   (when (timerp beacon--timer)
 129     (cancel-timer beacon--timer))
 130   (mapc #'delete-overlay beacon--ovs)
 131   (setq beacon--ovs nil))
 132
 133 \f
 134 ;;; Colors
 135 (defun beacon--int-range (a b)
 136   "Return a list of integers between A inclusive and B exclusive.
 137 Only returns `beacon-size' elements."
 138   (let ((d (/ (- b a) beacon-size))
 139         (out (list a)))
 140     (dotimes (_ (1- beacon-size))
 141       (push (+ (car out) d) out))
 142     (nreverse out)))
 143
 144 (defun beacon--color-range ()
 145   "Return a list of background colors for the beacon."
 146   (let* ((bg (color-values (face-attribute 'default :background)))
 147          (fg (cond
 148               ((stringp beacon-color) (color-values beacon-color))
 149               ((< (color-distance "black" bg)
 150                   (color-distance "white" bg))
 151                (make-list 3 (* beacon-color 65535)))
 152               (t (make-list 3 (* (- 1 beacon-color) 65535))))))
 153     (apply #'cl-mapcar (lambda (r g b) (format "#%04x%04x%04x" r g b))
 154            (mapcar (lambda (n) (butlast (beacon--int-range (elt fg n) (elt bg n))))
 155                    [0 1 2]))))
 156
 157 \f
 158 ;;; Blinking
 159 (defun beacon--shine ()
 160   "Shine a beacon at point."
 161   (let ((colors (beacon--color-range)))
 162     (save-excursion
 163       (while colors
 164         (if (looking-at "$")
 165             (progn
 166               (beacon--after-string-overlay colors)
 167               (setq colors nil))
 168           (beacon--colored-overlay (pop colors))
 169           (forward-char 1))))))
 170
 171 (defun beacon--dec ()
 172   "Decrease the beacon brightness by one."
 173   (pcase (beacon--ov-at-point)
 174     (`nil (beacon--vanish))
 175     ((and o (let c (overlay-get o 'beacon-colors)) (guard c))
 176      (beacon--ov-put-after-string o (cdr c)))
 177     (o
 178      (delete-overlay o)
 179      (save-excursion
 180        (while (progn (forward-char 1)
 181                      (setq o (beacon--ov-at-point)))
 182          (let ((colors (overlay-get o 'beacon-colors)))
 183            (if (not colors)
 184                (move-overlay o (1- (point)) (point))
 185              (forward-char -1)
 186              (beacon--colored-overlay (pop colors))
 187              (beacon--ov-put-after-string o colors)
 188              (forward-char 1))))))))
 189
 190 (defun beacon-blink ()
 191   "Blink the beacon at the position of the cursor."
 192   (interactive)
 193   (beacon--vanish)
 194   (beacon--shine)
 195   (setq beacon--timer
 196         (run-at-time beacon-blink-delay
 197                      (/ beacon-blink-duration 1.0 beacon-size)
 198                      #'beacon--dec)))
 199
 200 \f
 201 ;;; Movement detection
 202 (defvar beacon--previous-place nil)
 203 (defvar beacon--previous-window-start nil)
 204 (defvar beacon--previous-mark-head nil)
 205
 206 (defun beacon--movement-> (delta)
 207   "Return non-nil if latest point movement is > DELTA.
 208 If DELTA is nil, return nil."
 209   (and delta
 210        (markerp beacon--previous-place)
 211        (equal (marker-buffer beacon--previous-place)
 212               (current-buffer))
 213        (> (abs (- (point) beacon--previous-place))
 214           delta)
 215        (> (count-screen-lines (min (point) beacon--previous-place)
 216                               (max (point) beacon--previous-place))
 217           delta)))
 218
 219 (defun beacon--maybe-push-mark ()
 220   "Push mark if it seems to be safe."
 221   (when (and (not mark-active)
 222              (beacon--movement-> beacon-push-mark))
 223     (let ((head (car mark-ring)))
 224       (when (and (eq beacon--previous-mark-head head)
 225                  (not (equal head beacon--previous-place)))
 226         (push-mark beacon--previous-place)))))
 227
 228 (defun beacon--post-command ()
 229   "Blink if point moved very far."
 230   (cond
 231    ((not (markerp beacon--previous-place))
 232     (beacon--vanish))
 233    ;; Blink because we changed buffer.
 234    ((not (equal (marker-buffer beacon--previous-place)
 235                 (current-buffer)))
 236     (when beacon-blink-when-buffer-changes
 237       (unless (window-minibuffer-p)
 238         (beacon-blink))))
 239    ;; Blink for scrolling.
 240    ((and beacon-blink-when-window-scrolls
 241          (progn (redisplay)
 242                 (not (equal beacon--previous-window-start (window-start)))))
 243     (beacon-blink))
 244    ;; Blink for movement
 245    ((beacon--movement-> beacon-blink-when-point-moves)
 246     (beacon-blink))
 247    ;; Even if we don't blink, vanish any previous beacon.
 248    (t (beacon--vanish)))
 249   (beacon--maybe-push-mark)
 250   (unless (window-minibuffer-p)
 251     (setq beacon--previous-window-start (window-start))
 252     (setq beacon--previous-mark-head (car mark-ring))
 253     (setq beacon--previous-place (point-marker))))
 254
 255 \f
 256 ;;; Minor-mode
 257 (defcustom beacon-lighter (cond
 258                      ((char-displayable-p ?💡) " 💡")
 259                      ((char-displayable-p ?Λ) " Λ")
 260                      (t " *"))
 261   "Lighter string used on the mode-line."
 262   :type 'string)
 263
 264 ;;;###autoload
 265 (define-minor-mode beacon-mode
 266   nil nil beacon-lighter nil
 267   :global t
 268   (if beacon-mode
 269       (add-hook 'post-command-hook #'beacon--post-command)
 270     (remove-hook 'post-command-hook #'beacon--post-command)))
 271
 272 (provide 'beacon)
 273 ;;; beacon.el ends here