code.delx.au - gnu-emacs-elpa/blob - beacon.el

   1 ;;; beacon.el --- Highlight the cursor whenever the window scrolls  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Artur Malabarba <emacs@endlessparentheses.com>
   6 ;; URL: https://github.com/Malabarba/beacon
   7 ;; Keywords: convenience
   8 ;; Version: 0.1
   9 ;; Package-Requires: ((seq "1.9"))
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a global minor-mode. Turn it on everywhere with:
  27 ;; ┌────
  28 ;; │ (beacon-mode 1)
  29 ;; └────
  30 ;;
  31 ;; Whenever the window scrolls or you switch buffer a light will shine on
  32 ;; top of your cursor so you know where it is.
  33 ;;
  34 ;; That’s it.
  35 ;;
  36 ;;
  37 ;; 1 Customizations
  38 ;; ════════════════
  39 ;;
  40 ;;   • The appearance of the beacon is configured by `beacon-size' and
  41 ;;     `beacon-color'.
  42 ;;
  43 ;;   • The duration is configured by `beacon-blink-duration' and
  44 ;;     `beacon-blink-delay'.
  45 ;;
  46 ;;   • To customize /when/ the beacon should blink at all, configure
  47 ;;     `beacon-blink-when-window-scrolls',
  48 ;;     `beacon-blink-when-buffer-changes', and
  49 ;;     `beacon-blink-when-point-moves'.
  50 ;;
  51 ;;   • To prevent the beacon from blinking only on some major-modes,
  52 ;;     configure `beacon-dont-blink-major-modes'. For specific buffers, you
  53 ;;     can do `(setq-local beacon-mode nil)'. For even more refined
  54 ;;     control, configure `beacon-dont-blink-predicates'
  55 ;;
  56 ;;   • Beacon can also push the mark for you whenever point moves a long
  57 ;;     distance. For this, configure `beacon-push-mark'.
  58
  59 ;;; Code:
  60
  61 (require 'seq)
  62
  63 (defgroup beacon nil
  64   "Customization group for beacon."
  65   :group 'emacs
  66   :prefix "beacon-")
  67
  68 (defvar beacon--timer nil)
  69
  70 (defcustom beacon-push-mark nil
  71   "Should the mark be pushed before long movements?
  72 If nil, `beacon' will not push the mark.
  73 Otherwise this should be a number, and `beacon' will push the
  74 mark whenever point moves more than that many lines."
  75   :type '(choice integer (const nil)))
  76
  77 (defcustom beacon-blink-when-point-moves nil
  78   "Should the beacon blink when moving a long distance?
  79 If nil, don't blink due to plain movement.
  80 If non-nil, this should be an integer, which is the minimum
  81 movement distance (in lines) that triggers a beacon blink."
  82   :type '(choice integer (const nil)))
  83
  84 (defcustom beacon-blink-when-buffer-changes t
  85   "Should the beacon blink when changing buffer?"
  86   :type 'boolean)
  87
  88 (defcustom beacon-blink-when-window-scrolls t
  89   "Should the beacon blink when the window scrolls?"
  90   :type 'boolean)
  91
  92 (defcustom beacon-blink-duration 0.3
  93   "Time, in seconds, that the blink should last."
  94   :type 'number)
  95
  96 (defcustom beacon-blink-delay 0.3
  97   "Time, in seconds, before starting to fade the beacon."
  98   :type 'number)
  99
 100 (defcustom beacon-size 40
 101   "Size of the beacon in characters."
 102   :type 'number)
 103
 104 (defcustom beacon-color 0.5
 105   "Color of the beacon.
 106 This can be a string or a number.
 107
 108 If it is a number, the color is taken to be white or
 109 black (depending on the current theme's background) and this
 110 number is a float between 0 and 1 specifing the brightness.
 111
 112 If it is a string, it is a color name or specification,
 113 e.g. \"#666600\"."
 114   :type '(choice number color))
 115
 116 (defcustom beacon-dont-blink-predicates nil
 117   "A list of predicates that prevent the beacon blink.
 118 These predicate functions are called in order, with no
 119 arguments, before blinking the beacon.  If any returns
 120 non-nil, the beacon will not blink."
 121   :type 'hook)
 122
 123 (add-hook 'beacon-dont-blink-predicates (lambda () (bound-and-true-p hl-line-mode)))
 124 (add-hook 'beacon-dont-blink-predicates #'window-minibuffer-p)
 125
 126 (defcustom beacon-dont-blink-major-modes nil
 127   "A list of major-modes where the beacon won't blink.
 128 Whenever the current buffer satisfies `derived-mode-p' for
 129 one of the major-modes on this list, the beacon will not
 130 blink."
 131   :type '(repeat symbol))
 132
 133 \f
 134 ;;; Overlays
 135 (defvar beacon--ovs nil)
 136
 137 (defconst beacon-overlay-priority (/ most-positive-fixnum 2)
 138   "Priotiy used on all of our overlays.")
 139
 140 (defun beacon--make-overlay (length &rest properties)
 141   "Put an overlay at point with background COLOR."
 142   (let ((ov (make-overlay (point) (+ length (point)))))
 143     (overlay-put ov 'beacon t)
 144     ;; Our overlay is very temporary, so we take the liberty of giving
 145     ;; it a high priority.
 146     (overlay-put ov 'priority beacon-overlay-priority)
 147     (while properties
 148       (overlay-put ov (pop properties) (pop properties)))
 149     (push ov beacon--ovs)
 150     ov))
 151
 152 (defun beacon--colored-overlay (color)
 153   "Put an overlay at point with background COLOR."
 154   (beacon--make-overlay 1 'face (list :background color)))
 155
 156 (defun beacon--ov-put-after-string (overlay colors)
 157   "Add an after-string property to OVERLAY.
 158 The property's value is a string of spaces with background
 159 COLORS applied to each one.
 160 If COLORS is nil, OVERLAY is deleted!"
 161   (if (not colors)
 162       (when (overlayp overlay)
 163         (delete-overlay overlay))
 164     (overlay-put overlay 'beacon-colors colors)
 165     (overlay-put overlay 'after-string
 166                  (propertize
 167                   (mapconcat (lambda (c) (propertize " " 'face (list :background c)))
 168                              colors
 169                              "")
 170                   'cursor 1000))))
 171
 172 (defun beacon--after-string-overlay (colors)
 173   "Put an overlay at point with an after-string property.
 174 The property's value is a string of spaces with background
 175 COLORS applied to each one."
 176   ;; The after-string must not be longer than the remaining columns
 177   ;; from point to right window-end else it will be wrapped around.
 178   (let ((colors (seq-take colors (- (window-width) (current-column)))))
 179     (beacon--ov-put-after-string (beacon--make-overlay 0) colors)))
 180
 181 (defun beacon--ov-at-point ()
 182   (car (or (seq-filter (lambda (o) (overlay-get o 'beacon))
 183                      (overlays-in (point) (point)))
 184            (seq-filter (lambda (o) (overlay-get o 'beacon))
 185                      (overlays-at (point))))))
 186
 187 (defun beacon--vanish ()
 188   "Turn off the beacon."
 189   (when (timerp beacon--timer)
 190     (cancel-timer beacon--timer))
 191   (mapc #'delete-overlay beacon--ovs)
 192   (setq beacon--ovs nil))
 193
 194 \f
 195 ;;; Colors
 196 (defun beacon--int-range (a b)
 197   "Return a list of integers between A inclusive and B exclusive.
 198 Only returns `beacon-size' elements."
 199   (let ((d (/ (- b a) beacon-size))
 200         (out (list a)))
 201     (dotimes (_ (1- beacon-size))
 202       (push (+ (car out) d) out))
 203     (nreverse out)))
 204
 205 (defun beacon--color-range ()
 206   "Return a list of background colors for the beacon."
 207   (let* ((bg (color-values (face-attribute 'default :background)))
 208          (fg (cond
 209               ((stringp beacon-color) (color-values beacon-color))
 210               ((< (color-distance "black" bg)
 211                   (color-distance "white" bg))
 212                (make-list 3 (* beacon-color 65535)))
 213               (t (make-list 3 (* (- 1 beacon-color) 65535))))))
 214     (apply #'cl-mapcar (lambda (r g b) (format "#%04x%04x%04x" r g b))
 215            (mapcar (lambda (n) (butlast (beacon--int-range (elt fg n) (elt bg n))))
 216                    [0 1 2]))))
 217
 218 \f
 219 ;;; Blinking
 220 (defun beacon--shine ()
 221   "Shine a beacon at point."
 222   (let ((colors (beacon--color-range)))
 223     (save-excursion
 224       (while colors
 225         (if (looking-at "$")
 226             (progn
 227               (beacon--after-string-overlay colors)
 228               (setq colors nil))
 229           (beacon--colored-overlay (pop colors))
 230           (forward-char 1))))))
 231
 232 (defun beacon--dec ()
 233   "Decrease the beacon brightness by one."
 234   (pcase (beacon--ov-at-point)
 235     (`nil (beacon--vanish))
 236     ((and o (let c (overlay-get o 'beacon-colors)) (guard c))
 237      (beacon--ov-put-after-string o (cdr c)))
 238     (o
 239      (delete-overlay o)
 240      (save-excursion
 241        (while (progn (forward-char 1)
 242                      (setq o (beacon--ov-at-point)))
 243          (let ((colors (overlay-get o 'beacon-colors)))
 244            (if (not colors)
 245                (move-overlay o (1- (point)) (point))
 246              (forward-char -1)
 247              (beacon--colored-overlay (pop colors))
 248              (beacon--ov-put-after-string o colors)
 249              (forward-char 1))))))))
 250
 251 (defun beacon-blink ()
 252   "Blink the beacon at the position of the cursor."
 253   (interactive)
 254   (beacon--vanish)
 255   (unless (or (not beacon-mode)
 256               (run-hook-with-args-until-success 'beacon-dont-blink-predicates)
 257               (seq-find #'derived-mode-p beacon-dont-blink-major-modes))
 258     (beacon--shine)
 259     (setq beacon--timer
 260           (run-at-time beacon-blink-delay
 261                        (/ beacon-blink-duration 1.0 beacon-size)
 262                        #'beacon--dec))))
 263
 264 \f
 265 ;;; Movement detection
 266 (defvar beacon--window-scrolled nil)
 267 (defvar beacon--previous-place nil)
 268 (defvar beacon--previous-mark-head nil)
 269
 270 (defun beacon--movement-> (delta)
 271   "Return non-nil if latest point movement is > DELTA.
 272 If DELTA is nil, return nil."
 273   (and delta
 274        (markerp beacon--previous-place)
 275        (equal (marker-buffer beacon--previous-place)
 276               (current-buffer))
 277        (> (abs (- (point) beacon--previous-place))
 278           delta)
 279        (> (count-screen-lines (min (point) beacon--previous-place)
 280                               (max (point) beacon--previous-place))
 281           delta)))
 282
 283 (defun beacon--maybe-push-mark ()
 284   "Push mark if it seems to be safe."
 285   (when (and (not mark-active)
 286              (beacon--movement-> beacon-push-mark))
 287     (let ((head (car mark-ring)))
 288       (when (and (eq beacon--previous-mark-head head)
 289                  (not (equal head beacon--previous-place)))
 290         (push-mark beacon--previous-place)))))
 291
 292 (defun beacon--post-command ()
 293   "Blink if point moved very far."
 294   (cond
 295    ((not (markerp beacon--previous-place))
 296     (beacon--vanish))
 297    ;; Blink for scrolling.
 298    ((and beacon-blink-when-window-scrolls
 299          beacon--window-scrolled
 300          (equal beacon--window-scrolled (selected-window)))
 301     (beacon-blink))
 302    ;; Blink for movement
 303    ((beacon--movement-> beacon-blink-when-point-moves)
 304     (beacon-blink))
 305    ;; Even if we don't blink, vanish any previous beacon.
 306    (t (beacon--vanish)))
 307   (beacon--maybe-push-mark)
 308   (setq beacon--window-scrolled nil)
 309   (unless (window-minibuffer-p)
 310     (setq beacon--previous-mark-head (car mark-ring))
 311     (setq beacon--previous-place (point-marker))))
 312
 313 (defun beacon--window-scroll-function (win _start-pos)
 314   "Blink the beacon or record that window has been scrolled.
 315 If invoked during the command loop, record the current window so
 316 that it may be blinked on post-command.  This is because the
 317 scrolled window might not be active, but we only know that at
 318 `post-command-hook'.
 319
 320 If invoked outside the command loop, `post-command-hook' would be
 321 unreliable, so just blink immediately."
 322   (if this-command
 323       (setq beacon--window-scrolled win)
 324     (setq beacon--window-scrolled nil)
 325     (beacon-blink)))
 326
 327 \f
 328 ;;; Minor-mode
 329 (defcustom beacon-lighter
 330   (cond
 331    ((char-displayable-p ?💡) " 💡")
 332    ((char-displayable-p ?Λ) " Λ")
 333    (t " *"))
 334   "Lighter string used on the mode-line."
 335   :type 'string)
 336
 337 ;;;###autoload
 338 (define-minor-mode beacon-mode
 339   nil nil beacon-lighter nil
 340   :global t
 341   (if beacon-mode
 342       (progn
 343         (add-hook 'window-scroll-functions #'beacon--window-scroll-function)
 344         (add-hook 'post-command-hook #'beacon--post-command)
 345         (add-hook 'pre-command-hook #'beacon--vanish))
 346     (remove-hook 'window-scroll-functions #'beacon--window-scroll-function)
 347     (remove-hook 'post-command-hook #'beacon--post-command)
 348     (remove-hook 'pre-command-hook #'beacon--vanish)))
 349
 350 (provide 'beacon)
 351 ;;; beacon.el ends here