code.delx.au - gnu-emacs/blob - config.bat

   1 @echo off
   2 rem   ----------------------------------------------------------------------
   3 rem   Configuration script for MSDOS
   4 rem   Copyright (C) 1994-1999, 2001-2016 Free Software Foundation, Inc.
   5
   6 rem   This file is part of GNU Emacs.
   7
   8 rem   GNU Emacs is free software: you can redistribute it and/or modify
   9 rem   it under the terms of the GNU General Public License as published by
  10 rem   the Free Software Foundation, either version 3 of the License, or
  11 rem   (at your option) any later version.
  12
  13 rem   GNU Emacs is distributed in the hope that it will be useful,
  14 rem   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 rem   GNU General Public License for more details.
  17
  18 rem   You should have received a copy of the GNU General Public License
  19 rem   along with GNU Emacs.  If not, see http://www.gnu.org/licenses/.
  20
  21 rem   ----------------------------------------------------------------------
  22 rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:
  23 rem
  24 rem   + msdos version 3 or better.
  25 rem   + DJGPP version 2.02 or later (version 2.03 or later recommended).
  26 rem   + make utility that allows breaking of the 128 chars limit on
  27 rem     command lines.  ndmake (as of version 4.5) won't work due to a
  28 rem     line length limit.  The DJGPP port of make works (and is
  29 rem     recommended).
  30 rem   + rm, mv, and cp (from GNU file utilities).
  31 rem   + sed (you can use the port that comes with DJGPP).
  32 rem
  33 rem   You should be able to get all the above utilities from the DJGPP FTP
  34 rem   site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".
  35 rem   ----------------------------------------------------------------------
  36 set X11=
  37 set nodebug=
  38 set djgpp_ver=
  39 set sys_malloc=
  40 set libxml=
  41 if "%1" == "" goto usage
  42 rem   ----------------------------------------------------------------------
  43 rem   See if their environment is large enough.  We need 28 bytes.
  44 set $foo$=789012345678901234567
  45 if not "%$foo$%" == "789012345678901234567" goto SmallEnv
  46 set $foo$=
  47 :again
  48 if "%1" == "" goto usage
  49 if "%1" == "--with-x" goto withx
  50 if "%1" == "--no-debug" goto nodebug
  51 if "%1" == "msdos" goto msdos
  52 if "%1" == "--with-system-malloc" goto sysmalloc
  53 :usage
  54 echo Usage: config [--no-debug] [--with-system-malloc] [--with-x] msdos
  55 echo [Read the script before you run it.]
  56 goto end
  57 rem   ----------------------------------------------------------------------
  58 :withx
  59 set X11=Y
  60 shift
  61 goto again
  62 rem   ----------------------------------------------------------------------
  63 :nodebug
  64 set nodebug=Y
  65 shift
  66 goto again
  67 rem   ----------------------------------------------------------------------
  68 :sysmalloc
  69 set sys_malloc=Y
  70 shift
  71 goto again
  72 rem   ----------------------------------------------------------------------
  73 :msdos
  74 Echo Checking whether 'sed' is available...
  75 sed -e "w junk.$$$" <Nul
  76 If Exist junk.$$$ Goto sedOk
  77 Echo To configure 'Emacs' you need to have 'sed'!
  78 Goto End
  79 :sedOk
  80 Echo Checking whether 'rm' is available...
  81 rm -f junk.$$$
  82 If Not Exist junk.$$$ Goto rmOk
  83 Echo To configure 'Emacs' you need to have 'rm'!
  84 Goto End
  85 :rmOk
  86 Echo Checking whether 'mv' is available...
  87 rm -f junk.1 junk.2
  88 echo foo >junk.1
  89 mv junk.1 ./junk.2
  90 If Exist junk.2 Goto mvOk
  91 Echo To configure 'Emacs' you need to have 'mv'!
  92 rm -f junk.1
  93 Goto End
  94 :mvOk
  95 rm -f junk.2
  96 Echo Checking whether 'gcc' is available...
  97 echo main(){} >junk.c
  98 gcc -c junk.c
  99 if exist junk.o goto gccOk
 100 Echo To configure 'Emacs' you need to have 'gcc'!
 101 rm -f junk.c
 102 Goto End
 103 :gccOk
 104 rm -f junk.c junk.o junk junk.exe
 105 Echo Checking what version of DJGPP is installed...
 106 If Not "%DJGPP%" == "" goto djgppOk
 107 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 108 Goto End
 109 :djgppOk
 110 echo int main()           >junk.c
 111 echo #ifdef __DJGPP__    >>junk.c
 112 echo {return (__DJGPP__)*10 + (__DJGPP_MINOR__);} >>junk.c
 113 echo #else               >>junk.c
 114 echo #ifdef __GO32__     >>junk.c
 115 echo {return 10;}         >>junk.c
 116 echo #else               >>junk.c
 117 echo {return 0;}         >>junk.c
 118 echo #endif              >>junk.c
 119 echo #endif              >>junk.c
 120 gcc -o junk junk.c
 121 if not exist junk.exe coff2exe junk
 122 junk
 123 If ErrorLevel 10 Goto go32Ok
 124 rm -f junk.c junk junk.exe
 125 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 126 Goto End
 127 :go32Ok
 128 set djgpp_ver=2
 129 If Not ErrorLevel 22 Echo To build 'Emacs' you need DJGPP v2.02 or later!
 130 If Not ErrorLevel 22 Goto End
 131 rm -f junk.c junk junk.exe
 132 rem DJECHO is used by the top-level Makefile in the v2.x build
 133 Echo Checking whether 'djecho' is available...
 134 redir -o Nul -eo djecho -o junk.$$$ foo
 135 If Exist junk.$$$ Goto djechoOk
 136 Echo To build 'Emacs' you need the 'djecho.exe' program!
 137 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.
 138 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,
 139 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.
 140 Echo Then run CONFIG.BAT again with the same arguments you did now.
 141 Goto End
 142 :djechoOk
 143 rm -f junk.$$$
 144 Echo Configuring for DJGPP Version %DJGPP_VER% ...
 145 Rem   ----------------------------------------------------------------------
 146 Echo Configuring the source directory...
 147 cd src
 148
 149 rem   Create "epaths.h"
 150 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp
 151 update epaths.tmp epaths.h >nul
 152 rm -f epaths.tmp
 153
 154 rem   Create "config.h"
 155 rm -f config.h2 config.tmp
 156 if exist config.in sed -e '' config.in > config.tmp
 157 if exist ..\msdos\autogen\config.in sed -e '' ../msdos/autogen/config.in > config.tmp
 158 if "%X11%" == "" goto src4
 159 if exist config.in sed -f ../msdos/sed2x.inp < config.in > config.tmp
 160 if exist ..\msdos\autogen\config.in sed -f ../msdos/sed2x.inp < ..\msdos\autogen\config.in > config.tmp
 161 :src4
 162 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2
 163 Rem See if they have libxml2 later than v2.2.0 installed
 164 Echo Checking whether libxml2 v2.2.1 or later is installed ...
 165 rm -f junk.c junk.o junk junk.exe
 166 rem Use djecho here because we need to quote brackets
 167 djecho "#include <libxml/xmlversion.h>"             >junk.c
 168 djecho "int main()"                                 >>junk.c
 169 djecho "{return (LIBXML_VERSION > 20200 ? 0 : 1);}" >>junk.c
 170 redir -o Nul -eo gcc -I/dev/env/DJDIR/include/libxml2 -o junk junk.c
 171 if not exist junk Goto xmlDone
 172 if not exist junk.exe coff2exe junk
 173 junk
 174 If ErrorLevel 1 Goto xmlDone
 175 Echo Configuring with libxml2 ...
 176 sed -e "/#undef HAVE_LIBXML2/s/^.*$/#define HAVE_LIBXML2 1/" <config.h2 >config.h3
 177 sed -e "/#define EMACS_CONFIG_FEATURES/s/^.*$/#define EMACS_CONFIG_FEATURES \"LIBXML2\"/" <config.h3 >config.h2
 178 set libxml=1
 179 :xmlDone
 180 rm -f junk.c junk junk.exe
 181 Rem See if they requested a SYSTEM_MALLOC build
 182 if "%sys_malloc%" == "" Goto cfgDone
 183 rm -f config.tmp
 184 ren config.h2 config.tmp
 185 sed -f ../msdos/sedalloc.inp <config.tmp >config.h2
 186
 187 :cfgDone
 188 rm -f junk.c junk junk.exe
 189 update config.h2 config.h >nul
 190 rm -f config.tmp config.h2
 191
 192 rem   On my system dir.h gets in the way.  It's a VMS file so who cares.
 193 if exist dir.h ren dir.h vmsdir.h
 194
 195 rem   Create "makefile" from "makefile.in".
 196 rm -f Makefile makefile.tmp
 197 copy Makefile.in+deps.mk makefile.tmp
 198 sed -f ../msdos/sed1v2.inp <makefile.tmp >Makefile
 199 rm -f makefile.tmp
 200
 201 if "%X11%" == "" goto src5
 202 mv Makefile makefile.tmp
 203 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile
 204 rm -f makefile.tmp
 205 :src5
 206
 207 if "%sys_malloc%" == "" goto src5a
 208 sed -e "/^GMALLOC_OBJ *=/s/gmalloc.o//" <Makefile >makefile.tmp
 209 sed -e "/^VMLIMIT_OBJ *=/s/vm-limit.o//" <makefile.tmp >makefile.tmp2
 210 sed -e "/^RALLOC_OBJ *=/s/ralloc.o//" <makefile.tmp2 >Makefile
 211 rm -f makefile.tmp makefile.tmp2
 212 :src5a
 213
 214 if "%nodebug%" == "" goto src6
 215 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 216 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile
 217 rm -f makefile.tmp
 218 :src6
 219
 220 if "%libxml%" == "" goto src7
 221 sed -e "/^LIBXML2_LIBS *=/s/=/= -lxml2 -lz -liconv/" <Makefile >makefile.tmp
 222 sed -e "/^LIBXML2_CFLAGS *=/s|=|= -I/dev/env/DJDIR/include/libxml2|" <makefile.tmp >Makefile
 223 rm -f makefile.tmp
 224 :src7
 225 cd ..
 226 rem   ----------------------------------------------------------------------
 227 Echo Configuring the library source directory...
 228 cd lib-src
 229 sed -f ../msdos/sed3v2.inp <Makefile.in >Makefile
 230 mv Makefile makefile.tmp
 231 sed -n -e "/^AC_INIT/s/[^,]*, \([^,]*\).*/@set emver=\1/p" ../configure.ac > emver.bat
 232 call emver.bat
 233 sed -e "s/@version@/%emver%/g" <makefile.tmp >Makefile
 234 if "%X11%" == "" goto libsrc2a
 235 mv Makefile makefile.tmp
 236 sed -f ../msdos/sed3x.inp <makefile.tmp >Makefile
 237 rm -f makefile.tmp
 238 :libsrc2a
 239 if "%nodebug%" == "" goto libsrc3
 240 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 241 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile
 242 rm -f makefile.tmp
 243 :libsrc3
 244 cd ..
 245 rem   ----------------------------------------------------------------------
 246 if "%X11%" == "" goto oldx1
 247 Echo Configuring the oldxmenu directory...
 248 cd oldxmenu
 249 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile
 250 if "%nodebug%" == "" goto oldx2
 251 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 252 mv -f makefile.tmp Makefile
 253 :oldx2
 254 cd ..
 255 :oldx1
 256 rem   ----------------------------------------------------------------------
 257 Echo Configuring the doc directory, expect one "File not found" message...
 258 cd doc
 259 Rem Rename files like djtar on plain DOS filesystem would.
 260 If Exist emacs\emacsver.texi.in update emacs/emacsver.texi.in emacs/emacsver.in
 261 If Exist man\emacs.1.in update man/emacs.1.in man/emacs.in
 262 If Exist ..\etc\refcards\emacsver.tex.in update ../etc/refcards/emacsver.tex.in ../etc/refcards/emacsver.in
 263 Rem The two variants for lispintro below is for when the shell
 264 Rem supports long file names but DJGPP does not
 265 for %%d in (emacs lispref lispintro lispintr misc) do sed -e "s/@version@/%emver%/g" -f ../msdos/sed6.inp < %%d\Makefile.in > %%d\Makefile
 266 Rem produce emacs.1 from emacs.in
 267 If Exist man\emacs.1 goto manOk
 268 sed -e "s/@version@/%emver%/g" -e "s/@PACKAGE_BUGREPORT@/bug-gnu-emacs@gnu.org/g" < man\emacs.in > man\emacs.1
 269 :manOk
 270 cd ..
 271 rem   ----------------------------------------------------------------------
 272 Echo Configuring the lib directory...
 273 If Exist build-aux\snippet\c++defs.h update build-aux/snippet/c++defs.h build-aux/snippet/cxxdefs.h
 274 cd lib
 275 Rem Rename files like djtar on plain DOS filesystem would.
 276 If Exist alloca.in.h update alloca.in.h alloca.in-h
 277 If Exist byteswap.in.h update byteswap.in.h byteswap.in-h
 278 If Exist dirent.in.h update dirent.in.h dirent.in-h
 279 If Exist errno.in.h update errno.in.h errno.in-h
 280 If Exist execinfo.in.h update execinfo.in.h execinfo.in-h
 281 If Exist fcntl.in.h update fcntl.in.h fcntl.in-h
 282 If Exist getopt.in.h update getopt.in.h getopt.in-h
 283 If Exist inttypes.in.h update inttypes.in.h inttypes.in-h
 284 If Exist stdarg.in.h update stdarg.in.h stdarg.in-h
 285 If Exist stdalign.in.h update stdalign.in.h stdalign.in-h
 286 If Exist stdbool.in.h update stdbool.in.h stdbool.in-h
 287 If Exist signal.in.h update signal.in.h signal.in-h
 288 If Exist stdalign.in.h update stdalign.in.h  stdalign.in-h
 289 If Exist stddef.in.h update stddef.in.h  stddef.in-h
 290 If Exist stdint.in.h update stdint.in.h  stdint.in-h
 291 If Exist stdio.in.h update stdio.in.h stdio.in-h
 292 If Exist stdlib.in.h update stdlib.in.h stdlib.in-h
 293 If Exist string.in.h update string.in.h string.in-h
 294 If Exist sys_select.in.h update sys_select.in.h sys_select.in-h
 295 If Exist sys_stat.in.h update sys_stat.in.h sys_stat.in-h
 296 If Exist sys_types.in.h update sys_types.in.h sys_types.in-h
 297 If Exist sys_time.in.h update sys_time.in.h sys_time.in-h
 298 If Exist time.in.h update time.in.h time.in-h
 299 If Exist unistd.in.h update unistd.in.h unistd.in-h
 300 Rem Only repository has the msdos/autogen directory
 301 If Exist Makefile.in sed -f ../msdos/sedlibcf.inp < Makefile.in > makefile.tmp
 302 If Exist ..\msdos\autogen\Makefile.in sed -f ../msdos/sedlibcf.inp < ..\msdos\autogen\Makefile.in > makefile.tmp
 303 sed -f ../msdos/sedlibmk.inp < makefile.tmp > Makefile
 304 rm -f makefile.tmp
 305 Rem Create .Po files for new files in lib/
 306 If Not Exist deps\stamp mkdir deps
 307 for %%f in (*.c) do @call ..\msdos\depfiles.bat %%f
 308 echo deps-stamp > deps\stamp
 309 cd ..
 310 rem   ----------------------------------------------------------------------
 311 Echo Configuring the lisp directory...
 312 cd lisp
 313 If Exist gnus\.dir-locals.el update gnus/.dir-locals.el gnus/_dir-locals.el
 314 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile
 315 cd ..
 316 rem   ----------------------------------------------------------------------
 317 Echo Configuring the leim directory...
 318 cd leim
 319 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile
 320 cd ..
 321 rem   ----------------------------------------------------------------------
 322 If Not Exist admin\unidata goto noadmin
 323 Echo Configuring the admin/unidata directory...
 324 cd admin\unidata
 325 sed -f ../../msdos/sedadmin.inp < Makefile.in > Makefile
 326 Echo Configuring the admin/charsets directory...
 327 cd ..\charsets
 328 sed -f ../../msdos/sedadmin.inp < Makefile.in > Makefile
 329 Echo Configuring the admin/grammars directory...
 330 cd ..\grammars
 331 sed -f ../../msdos/sedadmin.inp < Makefile.in > Makefile
 332 cd ..\..
 333 :noadmin
 334 rem   ----------------------------------------------------------------------
 335 Echo Configuring the main directory...
 336 If Exist .dir-locals.el update .dir-locals.el _dir-locals.el
 337 If Exist src\.dbxinit update src/.dbxinit src/_dbxinit
 338 Echo Looking for the GDB init file...
 339 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit
 340 If Exist src\_gdbinit goto gdbinitOk
 341 Echo ERROR:
 342 Echo I cannot find the GDB init file.  It was called ".gdbinit" in
 343 Echo the Emacs distribution, but was probably renamed to some other
 344 Echo name without the leading dot when you untarred the archive.
 345 Echo It should be in the "src/" subdirectory.  Please make sure this
 346 Echo file exists and is called "_gdbinit" with a leading underscore.
 347 Echo Then run CONFIG.BAT again with the same arguments you did now.
 348 goto End
 349 :gdbinitOk
 350 Echo Looking for the GDB init file...found
 351 rem GNUMakefile is not appropriate for MS-DOS so move it out of the way
 352 If Exist GNUmakefile mv -f GNUmakefile GNUmakefile.unix
 353 copy msdos\mainmake.v2 Makefile >nul
 354 rem   ----------------------------------------------------------------------
 355 goto End
 356 :SmallEnv
 357 echo Your environment size is too small.  Please enlarge it and run me again.
 358 echo For example, type "command.com /e:2048" to have 2048 bytes available.
 359 set $foo$=
 360 :end
 361 set X11=
 362 set nodebug=
 363 set djgpp_ver=
 364 set sys_malloc=
 365 set libxml=
 366 set emver=