pkgbase="bsnap"
pkgname=("bsnap-borg" "bsnap-zfs" "bsnap-lvm")
pkgver=1.0.0
pkgrel=1
arch=("any")
source=("backup"
        "backup.service"
        "backup.timer"
        "bsnap-lvm"
        "setup-root-ssh"
        "bsnap-zfs"
        "etc-borg-root-env"
        "etc-borg-root-exclude"
        "znap-daily.service"
        "znap-daily.timer"
        "znap-frequent.service"
        "znap-frequent.timer"
        "znap-hourly.service"
        "znap-hourly.timer"
        "znap-take")
md5sums=('8b910ad468d754fa21f0a89dcab1715e'
         'ebc356d63196ff3ea1b3bdc51d00ae3a'
         'c0b4804dc26055ef88b3abdbba5f5b7c'
         '7b7c3a2d6bff8737b9bd1e766e65818b'
         '6f173fb271b64dfcc84b2536b076b36f'
         'ebf29f2525fc5ca671f4c24b90908d11'
         '05897a7215d9ef75e174e3dec94ca416'
         '5e2165087fa3d83c0a10f8837750bcfd'
         'b233a09cdbd997699e1ba03559ef892a'
         'eeafe687944641a401a7f7f902dac73a'
         '606b981ecbde6f7c90f135e91986b678'
         '916f9b7a74c4516da6aad084c0c32e3e'
         '832f2cd78dc266d97d3ad37d11448462'
         '0624408bb7c90a36e11f89eb64a8923e'
         '4fa1ebcd4e6f4db9c92d8c1f555975fc')

package_bsnap-borg() {
    pkgdesc="Borg backup tools"
    depends=("borg")
    backup=("etc/borg/root/exclude" "etc/borg/root/env")
    install="bsnap-borg.install"

    mkdir -p "${pkgdir}/usr/bin/"
    install -m 0755 backup setup-root-ssh "${pkgdir}/usr/bin/"

    mkdir -p "${pkgdir}/etc/borg/root/"
    install -m 0644 -T etc-borg-root-exclude "${pkgdir}/etc/borg/root/exclude"
    install -m 0600 -T etc-borg-root-env "${pkgdir}/etc/borg/root/env"

    mkdir -p "${pkgdir}/usr/lib/systemd/system/"
    install -m 0644 backup.{timer,service} "${pkgdir}/usr/lib/systemd/system/"
}

package_bsnap-zfs() {
    pkgdesc="Backup / snapshot tools for ZFS"
    depends=("zfs-utils" "zfs-auto-snapshot")
    conflicts=("bsnap-lvm")
    install="bsnap-zfs.install"

    mkdir -p "${pkgdir}/usr/bin/"
    install -m 0755 -T bsnap-zfs "${pkgdir}/usr/bin/bsnap"
    install -m 0755 znap-take "${pkgdir}/usr/bin/"

    mkdir -p "${pkgdir}/usr/lib/systemd/system/"
    install -m 0644 znap-*.{timer,service} "${pkgdir}/usr/lib/systemd/system/"
}

package_bsnap-lvm() {
    pkgdesc="Backup / snapshot tools for LVM"
    depends=("lvm2")
    conflicts=("bsnap-zfs")

    mkdir -p "${pkgdir}/usr/bin/"
    install -m 0755 -T bsnap-lvm "${pkgdir}/usr/bin/bsnap"
}