code.delx.au - gnu-emacs/blob - lisp/hi-lock.el

   1 ;;; hi-lock.el --- minor mode for interactive automatic highlighting
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Author: David M. Koppelman <koppel@ece.lsu.edu>
   7 ;; Keywords: faces, minor-mode, matching, display
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;
  26 ;;  With the hi-lock commands text matching interactively entered
  27 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  28 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  29 ;;  using a yellow background face.  New occurrences of `clearly' will
  30 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  31 ;;  will remove the highlighting.  Any existing face can be used for
  32 ;;  highlighting and a set of appropriate faces is provided.  The
  33 ;;  regexps can be written into the current buffer in a form that will
  34 ;;  be recognized the next time the corresponding file is read (when
  35 ;;  file patterns is turned on).
  36 ;;
  37 ;;  Applications:
  38 ;;
  39 ;;    In program source code highlight a variable to quickly see all
  40 ;;    places it is modified or referenced:
  41 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  42 ;;
  43 ;;    In a shell or other buffer that is showing lots of program
  44 ;;    output, highlight the parts of the output you're interested in:
  45 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  46 ;;
  47 ;;    In buffers displaying tables, highlight the lines you're interested in:
  48 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  49 ;;
  50 ;;    When writing text, highlight personal cliches.  This can be
  51 ;;    amusing.
  52 ;;    M-x highlight-phrase as can be seen RET RET
  53 ;;
  54 ;;  Setup:
  55 ;;
  56 ;;    Put the following code in your .emacs file.  This turns on
  57 ;;    hi-lock mode and adds a "Regexp Highlighting" entry
  58 ;;    to the edit menu.
  59 ;;
  60 ;;    (global-hi-lock-mode 1)
  61 ;;
  62 ;;    To enable the use of patterns found in files (presumably placed
  63 ;;    there by hi-lock) include the following in your .emacs file:
  64 ;;
  65 ;;    (setq hi-lock-file-patterns-policy 'ask)
  66 ;;
  67 ;;    If you get tired of being asked each time a file is loaded replace
  68 ;;    `ask' with a function that returns t if patterns should be read.
  69 ;;
  70 ;;    You might also want to bind the hi-lock commands to more
  71 ;;    finger-friendly sequences:
  72
  73 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  74 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  75 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  76 ;;    (define-key hi-lock-map "\C-zp" 'highlight-phrase)
  77 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  78 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  79
  80 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  81 ;;    additional instructions.
  82
  83 ;; Sample file patterns:
  84
  85 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  86 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  87 ; Hi-lock: end
  88
  89 ;;; Code:
  90
  91 (eval-and-compile
  92   (require 'font-lock))
  93
  94 (defgroup hi-lock nil
  95   "Interactively add and remove font-lock patterns for highlighting text."
  96   :link '(custom-manual "(emacs)Highlight Interactively")
  97   :group 'font-lock)
  98
  99 (defcustom hi-lock-file-patterns-range 10000
 100   "Limit of search in a buffer for hi-lock patterns.
 101 When a file is visited and hi-lock mode is on, patterns starting
 102 up to this limit are added to font-lock's patterns.  See documentation
 103 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 104   :type 'integer
 105   :group 'hi-lock)
 106
 107 (defcustom hi-lock-highlight-range 200000
 108   "Size of area highlighted by hi-lock when font-lock not active.
 109 Font-lock is not active in buffers that do their own highlighting,
 110 such as the buffer created by `list-colors-display'.  In those buffers
 111 hi-lock patterns will only be applied over a range of
 112 `hi-lock-highlight-range' characters.  If font-lock is active then
 113 highlighting will be applied throughout the buffer."
 114   :type 'integer
 115   :group 'hi-lock)
 116
 117 (defcustom hi-lock-exclude-modes
 118   '(rmail-mode mime/viewer-mode gnus-article-mode)
 119   "List of major modes in which hi-lock will not run.
 120 For security reasons since font lock patterns can specify function
 121 calls."
 122   :type '(repeat symbol)
 123   :group 'hi-lock)
 124
 125 (defcustom hi-lock-file-patterns-policy 'ask
 126   "Specify when hi-lock should use patterns found in file.
 127 If `ask', prompt when patterns found in buffer; if bound to a function,
 128 use patterns when function returns t (function is called with patterns
 129 as first argument); if nil or `never' or anything else, don't use file
 130 patterns."
 131   :type '(choice (const :tag "Do not use file patterns" never)
 132                  (const :tag "Ask about file patterns" ask)
 133                  (function :tag "Function to check file patterns"))
 134   :group 'hi-lock
 135   :version "22.1")
 136
 137 ;; It can have a function value.
 138 (put 'hi-lock-file-patterns-policy 'risky-local-variable t)
 139
 140 (defgroup hi-lock-faces nil
 141   "Faces for hi-lock."
 142   :group 'hi-lock
 143   :group 'faces)
 144
 145 (defface hi-yellow
 146   '((((min-colors 88) (background dark))
 147      (:background "yellow1" :foreground "black"))
 148     (((background dark)) (:background "yellow" :foreground "black"))
 149     (((min-colors 88)) (:background "yellow1"))
 150     (t (:background "yellow")))
 151   "Default face for hi-lock mode."
 152   :group 'hi-lock-faces)
 153
 154 (defface hi-pink
 155   '((((background dark)) (:background "pink" :foreground "black"))
 156     (t (:background "pink")))
 157   "Face for hi-lock mode."
 158   :group 'hi-lock-faces)
 159
 160 (defface hi-green
 161   '((((min-colors 88) (background dark))
 162      (:background "green1" :foreground "black"))
 163     (((background dark)) (:background "green" :foreground "black"))
 164     (((min-colors 88)) (:background "green1"))
 165     (t (:background "green")))
 166   "Face for hi-lock mode."
 167   :group 'hi-lock-faces)
 168
 169 (defface hi-blue
 170   '((((background dark)) (:background "light blue" :foreground "black"))
 171     (t (:background "light blue")))
 172   "Face for hi-lock mode."
 173   :group 'hi-lock-faces)
 174
 175 (defface hi-black-b
 176   '((t (:weight bold)))
 177   "Face for hi-lock mode."
 178   :group 'hi-lock-faces)
 179
 180 (defface hi-blue-b
 181   '((((min-colors 88)) (:weight bold :foreground "blue1"))
 182     (t (:weight bold :foreground "blue")))
 183   "Face for hi-lock mode."
 184   :group 'hi-lock-faces)
 185
 186 (defface hi-green-b
 187   '((((min-colors 88)) (:weight bold :foreground "green1"))
 188     (t (:weight bold :foreground "green")))
 189   "Face for hi-lock mode."
 190   :group 'hi-lock-faces)
 191
 192 (defface hi-red-b
 193   '((((min-colors 88)) (:weight bold :foreground "red1"))
 194     (t (:weight bold :foreground "red")))
 195   "Face for hi-lock mode."
 196   :group 'hi-lock-faces)
 197
 198 (defface hi-black-hb
 199   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 200   "Face for hi-lock mode."
 201   :group 'hi-lock-faces)
 202
 203 (defvar hi-lock-file-patterns nil
 204   "Patterns found in file for hi-lock.  Should not be changed.")
 205
 206 (defvar hi-lock-interactive-patterns nil
 207   "Patterns provided to hi-lock by user.  Should not be changed.")
 208
 209 (defvar hi-lock-face-defaults
 210   '("hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 211     "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 212   "Default faces for hi-lock interactive functions.")
 213
 214 ;(dolist (f hi-lock-face-defaults) (unless (facep f) (error "%s not a face" f)))
 215
 216 (define-obsolete-variable-alias 'hi-lock-face-history
 217                                 'hi-lock-face-defaults
 218                                 "23.1")
 219
 220 (define-obsolete-variable-alias 'hi-lock-regexp-history
 221                                 'regexp-history
 222                                 "23.1")
 223
 224 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 225   "Search target for finding hi-lock patterns at top of file.")
 226
 227 (defvar hi-lock-archaic-interface-message-used nil
 228   "True if user alerted that `global-hi-lock-mode' is now the global switch.
 229 Earlier versions of hi-lock used `hi-lock-mode' as the global switch;
 230 the message is issued if it appears that `hi-lock-mode' is used assuming
 231 that older functionality.  This variable avoids multiple reminders.")
 232
 233 (defvar hi-lock-archaic-interface-deduce nil
 234   "If non-nil, sometimes assume that `hi-lock-mode' means `global-hi-lock-mode'.
 235 Assumption is made if `hi-lock-mode' used in the *scratch* buffer while
 236 a library is being loaded.")
 237
 238 (make-variable-buffer-local 'hi-lock-interactive-patterns)
 239 (put 'hi-lock-interactive-patterns 'permanent-local t)
 240 (make-variable-buffer-local 'hi-lock-file-patterns)
 241 (put 'hi-lock-file-patterns 'permanent-local t)
 242
 243 (defvar hi-lock-menu (make-sparse-keymap "Hi Lock")
 244   "Menu for hi-lock mode.")
 245
 246 (define-key-after hi-lock-menu [highlight-regexp]
 247   '(menu-item "Highlight Regexp..." highlight-regexp
 248               :help "Highlight text matching PATTERN (a regexp)."))
 249
 250 (define-key-after hi-lock-menu [highlight-phrase]
 251   '(menu-item "Highlight Phrase..." highlight-phrase
 252               :help "Highlight text matching PATTERN (a regexp processed to match phrases)."))
 253
 254 (define-key-after hi-lock-menu [highlight-lines-matching-regexp]
 255   '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 256               :help "Highlight lines containing match of PATTERN (a regexp)."))
 257
 258 (define-key-after hi-lock-menu [unhighlight-regexp]
 259   '(menu-item "Remove Highlighting..." unhighlight-regexp
 260               :help "Remove previously entered highlighting pattern."
 261               :enable hi-lock-interactive-patterns))
 262
 263 (define-key-after hi-lock-menu [hi-lock-write-interactive-patterns]
 264   '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 265               :help "Insert interactively added REGEXPs into buffer at point."
 266               :enable hi-lock-interactive-patterns))
 267
 268 (define-key-after hi-lock-menu [hi-lock-find-patterns]
 269   '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 270               :help "Use patterns (if any) near top of buffer."))
 271
 272 (defvar hi-lock-map (make-sparse-keymap "Hi Lock")
 273   "Key map for hi-lock.")
 274
 275 (define-key hi-lock-map "\C-xwi" 'hi-lock-find-patterns)
 276 (define-key hi-lock-map "\C-xwl" 'highlight-lines-matching-regexp)
 277 (define-key hi-lock-map "\C-xwp" 'highlight-phrase)
 278 (define-key hi-lock-map "\C-xwh" 'highlight-regexp)
 279 (define-key hi-lock-map "\C-xwr" 'unhighlight-regexp)
 280 (define-key hi-lock-map "\C-xwb" 'hi-lock-write-interactive-patterns)
 281
 282 ;; Visible Functions
 283
 284 ;;;###autoload
 285 (define-minor-mode hi-lock-mode
 286   "Toggle minor mode for interactively adding font-lock highlighting patterns.
 287
 288 If ARG positive, turn hi-lock on.  Issuing a hi-lock command will also
 289 turn hi-lock on.  To turn hi-lock on in all buffers use
 290 `global-hi-lock-mode' or in your .emacs file (global-hi-lock-mode 1).
 291 When hi-lock is turned on, a \"Regexp Highlighting\" submenu is added
 292 to the \"Edit\" menu.  The commands in the submenu, which can be
 293 called interactively, are:
 294
 295 \\[highlight-regexp] REGEXP FACE
 296   Highlight matches of pattern REGEXP in current buffer with FACE.
 297
 298 \\[highlight-phrase] PHRASE FACE
 299   Highlight matches of phrase PHRASE in current buffer with FACE.
 300   (PHRASE can be any REGEXP, but spaces will be replaced by matches
 301   to whitespace and initial lower-case letters will become case insensitive.)
 302
 303 \\[highlight-lines-matching-regexp] REGEXP FACE
 304   Highlight lines containing matches of REGEXP in current buffer with FACE.
 305
 306 \\[unhighlight-regexp] REGEXP
 307   Remove highlighting on matches of REGEXP in current buffer.
 308
 309 \\[hi-lock-write-interactive-patterns]
 310   Write active REGEXPs into buffer as comments (if possible).  They may
 311   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 312   is issued.  The inserted regexps are in the form of font lock keywords.
 313   (See `font-lock-keywords'.)  They may be edited and re-loaded with \\[hi-lock-find-patterns],
 314   any valid `font-lock-keywords' form is acceptable.  When a file is
 315   loaded the patterns are read if `hi-lock-file-patterns-policy' is
 316   'ask and the user responds y to the prompt, or if
 317   `hi-lock-file-patterns-policy' is bound to a function and that
 318   function returns t.
 319
 320 \\[hi-lock-find-patterns]
 321   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 322
 323 When hi-lock is started and if the mode is not excluded or patterns
 324 rejected, the beginning of the buffer is searched for lines of the
 325 form:
 326   Hi-lock: FOO
 327 where FOO is a list of patterns.  These are added to the font lock
 328 keywords already present.  The patterns must start before position
 329 \(number of characters into buffer) `hi-lock-file-patterns-range'.
 330 Patterns will be read until
 331  Hi-lock: end
 332 is found.  A mode is excluded if it's in the list `hi-lock-exclude-modes'."
 333   :group 'hi-lock
 334   :lighter (:eval (if (or hi-lock-interactive-patterns
 335                           hi-lock-file-patterns)
 336                       " Hi" ""))
 337   :global nil
 338   :keymap hi-lock-map
 339   (when (and (equal (buffer-name) "*scratch*")
 340              load-in-progress
 341              (not (called-interactively-p 'interactive))
 342              (not hi-lock-archaic-interface-message-used))
 343     (setq hi-lock-archaic-interface-message-used t)
 344     (if hi-lock-archaic-interface-deduce
 345         (global-hi-lock-mode hi-lock-mode)
 346       (warn
 347        "Possible archaic use of (hi-lock-mode).
 348 Use (global-hi-lock-mode 1) in .emacs to enable hi-lock for all buffers,
 349 use (hi-lock-mode 1) for individual buffers.  For compatibility with Emacs
 350 versions before 22 use the following in your .emacs file:
 351
 352         (if (functionp 'global-hi-lock-mode)
 353             (global-hi-lock-mode 1)
 354           (hi-lock-mode 1))
 355 ")))
 356   (if hi-lock-mode
 357       ;; Turned on.
 358       (progn
 359         (unless font-lock-mode (font-lock-mode 1))
 360         (define-key-after menu-bar-edit-menu [hi-lock]
 361           (cons "Regexp Highlighting" hi-lock-menu))
 362         (hi-lock-find-patterns)
 363         (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook nil t))
 364     ;; Turned off.
 365     (when (or hi-lock-interactive-patterns
 366               hi-lock-file-patterns)
 367       (when hi-lock-interactive-patterns
 368         (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 369         (setq hi-lock-interactive-patterns nil))
 370       (when hi-lock-file-patterns
 371         (font-lock-remove-keywords nil hi-lock-file-patterns)
 372         (setq hi-lock-file-patterns nil))
 373       (remove-overlays nil nil 'hi-lock-overlay t)
 374       (when font-lock-fontified (font-lock-fontify-buffer)))
 375     (define-key-after menu-bar-edit-menu [hi-lock] nil)
 376     (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook t)))
 377
 378 ;;;###autoload
 379 (define-globalized-minor-mode global-hi-lock-mode
 380   hi-lock-mode turn-on-hi-lock-if-enabled
 381   :group 'hi-lock)
 382
 383 (defun turn-on-hi-lock-if-enabled ()
 384   (setq hi-lock-archaic-interface-message-used t)
 385   (unless (memq major-mode hi-lock-exclude-modes)
 386     (hi-lock-mode 1)))
 387
 388 ;;;###autoload
 389 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 390 ;;;###autoload
 391 (defun hi-lock-line-face-buffer (regexp &optional face)
 392   "Set face of all lines containing a match of REGEXP to FACE.
 393
 394 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 395 list maintained for regexps, global history maintained for faces.
 396 \\<minibuffer-local-map>Use \\[previous-history-element] to retrieve previous history items,
 397 and \\[next-history-element] to retrieve default values.
 398 \(See info node `Minibuffer History'.)"
 399   (interactive
 400    (list
 401     (hi-lock-regexp-okay
 402      (read-regexp "Regexp to highlight line" (car regexp-history)))
 403     (hi-lock-read-face-name)))
 404   (or (facep face) (setq face 'hi-yellow))
 405   (unless hi-lock-mode (hi-lock-mode 1))
 406   (hi-lock-set-pattern
 407    ;; The \\(?:...\\) grouping construct ensures that a leading ^, +, * or ?
 408    ;; or a trailing $ in REGEXP will be interpreted correctly.
 409    (concat "^.*\\(?:" regexp "\\).*$") face))
 410
 411
 412 ;;;###autoload
 413 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 414 ;;;###autoload
 415 (defun hi-lock-face-buffer (regexp &optional face)
 416   "Set face of each match of REGEXP to FACE.
 417
 418 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 419 list maintained for regexps, global history maintained for faces.
 420 \\<minibuffer-local-map>Use \\[previous-history-element] to retrieve previous history items,
 421 and \\[next-history-element] to retrieve default values.
 422 \(See info node `Minibuffer History'.)"
 423   (interactive
 424    (list
 425     (hi-lock-regexp-okay
 426      (read-regexp "Regexp to highlight" (car regexp-history)))
 427     (hi-lock-read-face-name)))
 428   (or (facep face) (setq face 'hi-yellow))
 429   (unless hi-lock-mode (hi-lock-mode 1))
 430   (hi-lock-set-pattern regexp face))
 431
 432 ;;;###autoload
 433 (defalias 'highlight-phrase 'hi-lock-face-phrase-buffer)
 434 ;;;###autoload
 435 (defun hi-lock-face-phrase-buffer (regexp &optional face)
 436   "Set face of each match of phrase REGEXP to FACE.
 437
 438 Whitespace in REGEXP converted to arbitrary whitespace and initial
 439 lower-case letters made case insensitive."
 440   (interactive
 441    (list
 442     (hi-lock-regexp-okay
 443      (hi-lock-process-phrase
 444       (read-regexp "Phrase to highlight" (car regexp-history))))
 445     (hi-lock-read-face-name)))
 446   (or (facep face) (setq face 'hi-yellow))
 447   (unless hi-lock-mode (hi-lock-mode 1))
 448   (hi-lock-set-pattern regexp face))
 449
 450 (declare-function x-popup-menu "menu.c" (position menu))
 451
 452 ;;;###autoload
 453 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 454 ;;;###autoload
 455 (defun hi-lock-unface-buffer (regexp)
 456   "Remove highlighting of each match to REGEXP set by hi-lock.
 457
 458 Interactively, prompt for REGEXP.  Buffer-local history of inserted
 459 regexp's maintained.  Will accept only regexps inserted by hi-lock
 460 interactive functions.  \(See `hi-lock-interactive-patterns'.\)
 461 \\<minibuffer-local-must-match-map>Use \\[minibuffer-complete] to complete a partially typed regexp.
 462 \(See info node `Minibuffer History'.\)"
 463   (interactive
 464    (if (and (display-popup-menus-p)
 465             (listp last-nonmenu-event)
 466             use-dialog-box)
 467        (catch 'snafu
 468          (or
 469           (x-popup-menu
 470            t
 471            (cons
 472             `keymap
 473             (cons "Select Pattern to Unhighlight"
 474                   (mapcar (lambda (pattern)
 475                             (list (car pattern)
 476                                   (format
 477                                    "%s (%s)" (car pattern)
 478                                    (symbol-name
 479                                     (car
 480                                      (cdr (car (cdr (car (cdr pattern))))))))
 481                                   (cons nil nil)
 482                                   (car pattern)))
 483                           hi-lock-interactive-patterns))))
 484           ;; If the user clicks outside the menu, meaning that they
 485           ;; change their mind, x-popup-menu returns nil, and
 486           ;; interactive signals a wrong number of arguments error.
 487           ;; To prevent that, we return an empty string, which will
 488           ;; effectively disable the rest of the function.
 489           (throw 'snafu '(""))))
 490      (let ((history-list (mapcar (lambda (p) (car p))
 491                                  hi-lock-interactive-patterns)))
 492        (unless hi-lock-interactive-patterns
 493          (error "No highlighting to remove"))
 494        (list
 495         (completing-read "Regexp to unhighlight: "
 496                          hi-lock-interactive-patterns nil t
 497                          (car (car hi-lock-interactive-patterns))
 498                          (cons 'history-list 1))))))
 499   (let ((keyword (assoc regexp hi-lock-interactive-patterns)))
 500     (when keyword
 501       (font-lock-remove-keywords nil (list keyword))
 502       (setq hi-lock-interactive-patterns
 503             (delq keyword hi-lock-interactive-patterns))
 504       (remove-overlays
 505        nil nil 'hi-lock-overlay-regexp (hi-lock-string-serialize regexp))
 506       (when font-lock-fontified (font-lock-fontify-buffer)))))
 507
 508 ;;;###autoload
 509 (defun hi-lock-write-interactive-patterns ()
 510   "Write interactively added patterns, if any, into buffer at point.
 511
 512 Interactively added patterns are those normally specified using
 513 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 514 be found in variable `hi-lock-interactive-patterns'."
 515   (interactive)
 516   (if (null hi-lock-interactive-patterns)
 517       (error "There are no interactive patterns"))
 518   (let ((beg (point)))
 519     (mapc
 520      (lambda (pattern)
 521        (insert (format "%s: (%s)\n"
 522                        hi-lock-file-patterns-prefix
 523                        (prin1-to-string pattern))))
 524      hi-lock-interactive-patterns)
 525     (comment-region beg (point)))
 526   (when (> (point) hi-lock-file-patterns-range)
 527     (warn "Inserted keywords not close enough to top of file")))
 528
 529 ;; Implementation Functions
 530
 531 (defun hi-lock-process-phrase (phrase)
 532   "Convert regexp PHRASE to a regexp that matches phrases.
 533
 534 Blanks in PHRASE replaced by regexp that matches arbitrary whitespace
 535 and initial lower-case letters made case insensitive."
 536   (let ((mod-phrase nil))
 537     (setq mod-phrase
 538           (replace-regexp-in-string
 539            "\\<[a-z]" (lambda (m) (format "[%s%s]" (upcase m) m)) phrase))
 540     (setq mod-phrase
 541           (replace-regexp-in-string
 542            "\\s-+" "[ \t\n]+" mod-phrase nil t))))
 543
 544 (defun hi-lock-regexp-okay (regexp)
 545   "Return REGEXP if it appears suitable for a font-lock pattern.
 546
 547 Otherwise signal an error.  A pattern that matches the null string is
 548 not suitable."
 549   (if (string-match regexp "")
 550       (error "Regexp cannot match an empty string")
 551     regexp))
 552
 553 (defun hi-lock-read-face-name ()
 554   "Read face name from minibuffer with completion and history."
 555   (intern (completing-read
 556            "Highlight using face: "
 557            obarray 'facep t
 558            (cons (car hi-lock-face-defaults)
 559                  (let ((prefix
 560                         (try-completion
 561                          (substring (car hi-lock-face-defaults) 0 1)
 562                          hi-lock-face-defaults)))
 563                    (if (and (stringp prefix)
 564                             (not (equal prefix (car hi-lock-face-defaults))))
 565                        (length prefix) 0)))
 566            'face-name-history
 567            (cdr hi-lock-face-defaults))))
 568
 569 (defun hi-lock-set-pattern (regexp face)
 570   "Highlight REGEXP with face FACE."
 571   (let ((pattern (list regexp (list 0 (list 'quote face) t))))
 572     (unless (member pattern hi-lock-interactive-patterns)
 573       (push pattern hi-lock-interactive-patterns)
 574       (if font-lock-fontified
 575           (progn
 576             (font-lock-add-keywords nil (list pattern) t)
 577             (font-lock-fontify-buffer))
 578         (let* ((serial (hi-lock-string-serialize regexp))
 579                (range-min (- (point) (/ hi-lock-highlight-range 2)))
 580                (range-max (+ (point) (/ hi-lock-highlight-range 2)))
 581                (search-start
 582                 (max (point-min)
 583                      (- range-min (max 0 (- range-max (point-max))))))
 584                (search-end
 585                 (min (point-max)
 586                      (+ range-max (max 0 (- (point-min) range-min))))))
 587           (save-excursion
 588             (goto-char search-start)
 589             (while (re-search-forward regexp search-end t)
 590               (let ((overlay (make-overlay (match-beginning 0) (match-end 0))))
 591                 (overlay-put overlay 'hi-lock-overlay t)
 592                 (overlay-put overlay 'hi-lock-overlay-regexp serial)
 593                 (overlay-put overlay 'face face))
 594               (goto-char (match-end 0)))))))))
 595
 596 (defun hi-lock-set-file-patterns (patterns)
 597   "Replace file patterns list with PATTERNS and refontify."
 598   (when (or hi-lock-file-patterns patterns)
 599     (font-lock-remove-keywords nil hi-lock-file-patterns)
 600     (setq hi-lock-file-patterns patterns)
 601     (font-lock-add-keywords nil hi-lock-file-patterns t)
 602     (font-lock-fontify-buffer)))
 603
 604 (defun hi-lock-find-patterns ()
 605   "Find patterns in current buffer for hi-lock."
 606   (interactive)
 607   (unless (memq major-mode hi-lock-exclude-modes)
 608     (let ((all-patterns nil)
 609           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 610       (save-excursion
 611         (save-restriction
 612           (widen)
 613           (goto-char (point-min))
 614           (re-search-forward target-regexp
 615                              (+ (point) hi-lock-file-patterns-range) t)
 616           (beginning-of-line)
 617           (while (and (re-search-forward target-regexp (+ (point) 100) t)
 618                       (not (looking-at "\\s-*end")))
 619             (condition-case nil
 620                 (setq all-patterns (append (read (current-buffer)) all-patterns))
 621               (error (message "Invalid pattern list expression at %d"
 622                               (line-number-at-pos)))))))
 623       (when (and all-patterns
 624                  hi-lock-mode
 625                  (cond
 626                   ((eq this-command 'hi-lock-find-patterns) t)
 627                   ((functionp hi-lock-file-patterns-policy)
 628                    (funcall hi-lock-file-patterns-policy all-patterns))
 629                   ((eq hi-lock-file-patterns-policy 'ask)
 630                    (y-or-n-p "Add patterns from this buffer to hi-lock? "))
 631                   (t nil)))
 632         (hi-lock-set-file-patterns all-patterns)
 633         (if (called-interactively-p 'interactive)
 634             (message "Hi-lock added %d patterns." (length all-patterns)))))))
 635
 636 (defun hi-lock-font-lock-hook ()
 637   "Add hi-lock patterns to font-lock's."
 638   (when font-lock-fontified
 639     (font-lock-add-keywords nil hi-lock-file-patterns t)
 640     (font-lock-add-keywords nil hi-lock-interactive-patterns t)))
 641
 642 (defvar hi-lock-string-serialize-hash
 643   (make-hash-table :test 'equal)
 644   "Hash table used to assign unique numbers to strings.")
 645
 646 (defvar hi-lock-string-serialize-serial 1
 647   "Number assigned to last new string in call to `hi-lock-string-serialize'.
 648 A string is considered new if it had not previously been used in a call to
 649 `hi-lock-string-serialize'.")
 650
 651 (defun hi-lock-string-serialize (string)
 652   "Return unique serial number for STRING."
 653   (interactive)
 654   (let ((val (gethash string hi-lock-string-serialize-hash)))
 655     (if val val
 656       (puthash string
 657                (setq hi-lock-string-serialize-serial
 658                      (1+ hi-lock-string-serialize-serial))
 659                hi-lock-string-serialize-hash)
 660       hi-lock-string-serialize-serial)))
 661
 662 (defun hi-lock-unload-function ()
 663   "Unload the Hi-Lock library."
 664   (global-hi-lock-mode -1)
 665   ;; continue standard unloading
 666   nil)
 667
 668 (provide 'hi-lock)
 669
 670 ;; arch-tag: d2e8fd07-4cc9-4c6f-a200-1e729bc54066
 671 ;;; hi-lock.el ends here