code.delx.au - gnu-emacs/blob - lisp/misc.el

   1 ;;; misc.el --- some nonstandard basic editing commands for Emacs
   2
   3 ;; Copyright (C) 1989, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   4 ;;   2009, 2010, 2011  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defun copy-from-above-command (&optional arg)
  30   "Copy characters from previous nonblank line, starting just above point.
  31 Copy ARG characters, but not past the end of that line.
  32 If no argument given, copy the entire rest of the line.
  33 The characters copied are inserted in the buffer before point."
  34   (interactive "P")
  35   (let ((cc (current-column))
  36         n
  37         (string ""))
  38     (save-excursion
  39       (beginning-of-line)
  40       (backward-char 1)
  41       (skip-chars-backward "\ \t\n")
  42       (move-to-column cc)
  43       ;; Default is enough to copy the whole rest of the line.
  44       (setq n (if arg (prefix-numeric-value arg) (point-max)))
  45       ;; If current column winds up in middle of a tab,
  46       ;; copy appropriate number of "virtual" space chars.
  47       (if (< cc (current-column))
  48           (if (= (preceding-char) ?\t)
  49               (progn
  50                 (setq string (make-string (min n (- (current-column) cc)) ?\s))
  51                 (setq n (- n (min n (- (current-column) cc)))))
  52             ;; In middle of ctl char => copy that whole char.
  53             (backward-char 1)))
  54       (setq string (concat string
  55                            (buffer-substring
  56                             (point)
  57                             (min (line-end-position)
  58                                  (+ n (point)))))))
  59     (insert string)))
  60
  61 ;; Variation of `zap-to-char'.
  62
  63 (defun zap-up-to-char (arg char)
  64   "Kill up to, but not including ARGth occurrence of CHAR.
  65 Case is ignored if `case-fold-search' is non-nil in the current buffer.
  66 Goes backward if ARG is negative; error if CHAR not found.
  67 Ignores CHAR at point."
  68   (interactive "p\ncZap up to char: ")
  69   (let ((direction (if (>= arg 0) 1 -1)))
  70     (kill-region (point)
  71                  (progn
  72                    (forward-char direction)
  73                    (unwind-protect
  74                        (search-forward (char-to-string char) nil nil arg)
  75                      (backward-char direction))
  76                    (point)))))
  77
  78 ;; These were added with an eye to making possible a more CCA-compatible
  79 ;; command set; but that turned out not to be interesting.
  80
  81 (defun mark-beginning-of-buffer ()
  82   "Set mark at the beginning of the buffer."
  83   (interactive)
  84   (push-mark (point-min)))
  85
  86 (defun mark-end-of-buffer ()
  87   "Set mark at the end of the buffer."
  88   (interactive)
  89   (push-mark (point-max)))
  90
  91 (defun upcase-char (arg)
  92   "Uppercasify ARG chars starting from point.  Point doesn't move."
  93   (interactive "p")
  94   (save-excursion
  95     (upcase-region (point) (progn (forward-char arg) (point)))))
  96
  97 (defun forward-to-word (arg)
  98   "Move forward until encountering the beginning of a word.
  99 With argument, do this that many times."
 100   (interactive "p")
 101   (or (re-search-forward (if (> arg 0) "\\W\\b" "\\b\\W") nil t arg)
 102       (goto-char (if (> arg 0) (point-max) (point-min)))))
 103
 104 (defun backward-to-word (arg)
 105   "Move backward until encountering the end of a word.
 106 With argument, do this that many times."
 107   (interactive "p")
 108   (forward-to-word (- arg)))
 109
 110 ;;;###autoload
 111 (defun butterfly ()
 112   "Use butterflies to flip the desired bit on the drive platter.
 113 Open hands and let the delicate wings flap once.  The disturbance
 114 ripples outward, changing the flow of the eddy currents in the
 115 upper atmosphere.  These cause momentary pockets of higher-pressure
 116 air to form, which act as lenses that deflect incoming cosmic rays,
 117 focusing them to strike the drive platter and flip the desired bit.
 118 You can type `M-x butterfly C-M-c' to run it.  This is a permuted
 119 variation of `C-x M-c M-butterfly' from url `http://xkcd.com/378/'."
 120   (interactive)
 121   (if (yes-or-no-p "Do you really want to unleash the powers of the butterfly? ")
 122       (progn
 123         (switch-to-buffer (get-buffer-create "*butterfly*"))
 124         (erase-buffer)
 125         (sit-for 0)
 126         (animate-string "Amazing physics going on..."
 127                         (/ (window-height) 2) (- (/ (window-width) 2) 12))
 128         (sit-for (* 5 (/ (abs (random)) (float most-positive-fixnum))))
 129         (message "Successfully flipped one bit!"))
 130     (message "Well, then go to xkcd.com!")
 131     (browse-url "http://xkcd.com/378/")))
 132
 133 (provide 'misc)
 134
 135 ;;; misc.el ends here