code.delx.au - gnu-emacs/blob - lisp/progmodes/m4-mode.el

   1 ;;; m4-mode.el --- m4 code editing commands for Emacs
   2
   3 ;; Copyright (C) 1996, 1997, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Andrew Csillag <drew_csillag@geocities.com>
   7 ;; Maintainer: Andrew Csillag <drew_csillag@geocities.com>
   8 ;; Keywords: languages, faces
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; A smart editing mode for m4 macro definitions.  It seems to have most of the
  28 ;; syntax right (sexp motion commands work, but function motion commands don't).
  29 ;; It also sets the font-lock syntax stuff for colorization
  30
  31 ;; To Do's:
  32
  33 ;; * want to make m4-m4-(buffer|region) look sorta like M-x compile look&feel ?
  34 ;; * sexp motion commands don't seem to work right
  35
  36 ;;; Thanks:
  37 ;;;         to Akim Demaille and Terry Jones for the bug reports
  38 ;;;         to Simon Marshall for the regexp tip
  39 ;;;         to Martin Buchholz for some general fixes
  40
  41 ;;; Code:
  42
  43 (defgroup m4 nil
  44   "m4 code editing commands for Emacs."
  45   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  46   :prefix "m4-"
  47   :group 'languages)
  48
  49 (defcustom m4-program
  50   (cond
  51    ((file-exists-p "/usr/local/bin/m4") "/usr/local/bin/m4")
  52    ((file-exists-p "/usr/bin/m4") "/usr/bin/m4")
  53    ((file-exists-p "/bin/m4") "/bin/m4")
  54    ((file-exists-p "/usr/ccs/bin/m4") "/usr/ccs/bin/m4")
  55    ( t "m4")
  56    )
  57   "File name of the m4 executable."
  58   :type 'file
  59   :group 'm4)
  60
  61 ;;options to m4
  62 (defcustom m4-program-options nil
  63   "Options to pass to `m4-program'."
  64   :type '(repeat string)
  65   :group 'm4)
  66
  67 ;;to use --prefix-builtins, you can use
  68 ;;(defconst m4-program-options '("-P"))
  69 ;;or
  70 ;;(defconst m4-program-options '("--prefix-builtins"))
  71
  72 (defvar m4-font-lock-keywords
  73   `(
  74     ("\\(\\b\\(m4_\\)?dnl\\b\\|^\\#\\).*$" . font-lock-comment-face)
  75 ;    ("\\(\\bdnl\\b\\|\\bm4_dnl\\b\\|^\\#\\).*$" . font-lock-comment-face)
  76     ("\\$[*#@0-9]" . font-lock-variable-name-face)
  77     ("\\\$\\\@" . font-lock-variable-name-face)
  78     ("\\\$\\\*" . font-lock-variable-name-face)
  79     ("\\b\\(builtin\\|change\\(com\\|quote\\|word\\)\\|d\\(e\\(bug\\(file\\|mode\\)\\|cr\\|f\\(ine\\|n\\)\\)\\|iv\\(ert\\|num\\)\\|nl\\|umpdef\\)\\|e\\(rrprint\\|syscmd\\|val\\)\\|f\\(ile\\|ormat\\)\\|gnu\\|i\\(f\\(def\\|else\\)\\|n\\(c\\(lude\\|r\\)\\|d\\(ex\\|ir\\)\\)\\)\\|l\\(en\\|ine\\)\\|m\\(4\\(exit\\|wrap\\)\\|aketemp\\)\\|p\\(atsubst\\|opdef\\|ushdef\\)\\|regexp\\|s\\(hift\\|include\\|ubstr\\|ys\\(cmd\\|val\\)\\)\\|tra\\(ceo\\(ff\\|n\\)\\|nslit\\)\\|un\\(d\\(efine\\|ivert\\)\\|ix\\)\\)\\b" . font-lock-keyword-face)
  80     ("\\b\\(m4_\\(builtin\\|change\\(com\\|quote\\|word\\)\\|d\\(e\\(bug\\(file\\|mode\\)\\|cr\\|f\\(ine\\|n\\)\\)\\|iv\\(ert\\|num\\)\\|nl\\|umpdef\\)\\|e\\(rrprint\\|syscmd\\|val\\)\\|f\\(ile\\|ormat\\)\\|i\\(f\\(def\\|else\\)\\|n\\(c\\(lude\\|r\\)\\|d\\(ex\\|ir\\)\\)\\)\\|l\\(en\\|ine\\)\\|m\\(4\\(_undefine\\|exit\\|wrap\\)\\|aketemp\\)\\|p\\(atsubst\\|opdef\\|ushdef\\)\\|regexp\\|s\\(hift\\|include\\|ubstr\\|ys\\(cmd\\|val\\)\\)\\|tra\\(ceo\\(ff\\|n\\)\\|nslit\\)\\|undivert\\)\\)\\b" . font-lock-keyword-face))
  81   "Default font-lock-keywords for `m4 mode'.")
  82
  83 (defcustom m4-mode-hook nil
  84   "*Hook called by `m4-mode'."
  85   :type 'hook
  86   :group 'm4)
  87
  88 ;;this may still need some work
  89 (defvar m4-mode-syntax-table nil
  90   "Syntax table used while in `m4-mode'.")
  91 (setq m4-mode-syntax-table (make-syntax-table))
  92 (modify-syntax-entry ?` "('" m4-mode-syntax-table)
  93 (modify-syntax-entry ?' ")`" m4-mode-syntax-table)
  94 (modify-syntax-entry ?# "<\n" m4-mode-syntax-table)
  95 (modify-syntax-entry ?\n ">#" m4-mode-syntax-table)
  96 (modify-syntax-entry ?{  "_" m4-mode-syntax-table)
  97 (modify-syntax-entry ?}  "_" m4-mode-syntax-table)
  98 (modify-syntax-entry ?*  "w" m4-mode-syntax-table)
  99 (modify-syntax-entry ?_  "w" m4-mode-syntax-table)
 100 (modify-syntax-entry ?\"  "w" m4-mode-syntax-table)
 101 (modify-syntax-entry ?\"  "w" m4-mode-syntax-table)
 102
 103 (defvar m4-mode-map
 104   (let ((map (make-sparse-keymap))
 105         (menu-map (make-sparse-keymap)))
 106     (define-key map "\C-c\C-b" 'm4-m4-buffer)
 107     (define-key map "\C-c\C-r" 'm4-m4-region)
 108     (define-key map "\C-c\C-c" 'comment-region)
 109     (define-key map [menu-bar m4-mode] (cons "M4" menu-map))
 110     (define-key menu-map [m4c]
 111       '(menu-item "Comment Region" comment-region
 112                   :help "Comment Region"))
 113     (define-key menu-map [m4b]
 114       '(menu-item "M4 Buffer" m4-m4-buffer
 115                   :help "Send contents of the current buffer to m4"))
 116     (define-key menu-map [m4r]
 117       '(menu-item "M4 Region" m4-m4-region
 118                   :help "Send contents of the current region to m4"))
 119     map))
 120
 121 (defvar m4-mode-abbrev-table nil
 122   "Abbrev table used while in `m4-mode'.")
 123
 124 (unless m4-mode-abbrev-table
 125   (define-abbrev-table 'm4-mode-abbrev-table ()))
 126
 127 (defun m4-m4-buffer ()
 128   "Send contents of the current buffer to m4."
 129   (interactive)
 130   (shell-command-on-region
 131    (point-min) (point-max)
 132    (mapconcat 'identity (cons m4-program m4-program-options) "\s")
 133    "*m4-output*" nil)
 134   (switch-to-buffer-other-window "*m4-output*"))
 135
 136 (defun m4-m4-region ()
 137   "Send contents of the current region to m4."
 138   (interactive)
 139   (shell-command-on-region
 140    (point) (mark)
 141    (mapconcat 'identity (cons m4-program m4-program-options) "\s")
 142    "*m4-output*" nil)
 143   (switch-to-buffer-other-window "*m4-output*"))
 144
 145 ;;;###autoload
 146 (define-derived-mode m4-mode prog-mode "m4"
 147   "A major mode to edit m4 macro files."
 148   :abbrev-table m4-mode-abbrev-table
 149   (set (make-local-variable 'comment-start) "#")
 150   (set (make-local-variable 'parse-sexp-ignore-comments) t)
 151   (set (make-local-variable 'font-lock-defaults) '(m4-font-lock-keywords nil)))
 152
 153 (provide 'm4-mode)
 154 ;;stuff to play with for debugging
 155 ;(char-to-string (char-syntax ?`))
 156
 157 ;;;how I generate the nasty looking regexps at the top
 158 ;;;(make-regexp '("builtin" "changecom" "changequote" "changeword" "debugfile"
 159 ;;;               "debugmode" "decr" "define" "defn" "divert" "divnum" "dnl"
 160 ;;;               "dumpdef" "errprint" "esyscmd" "eval" "file" "format" "gnu"
 161 ;;;               "ifdef" "ifelse" "include" "incr" "index" "indir" "len" "line"
 162 ;;;               "m4exit" "m4wrap" "maketemp" "patsubst" "popdef" "pushdef" "regexp"
 163 ;;;               "shift" "sinclude" "substr" "syscmd" "sysval" "traceoff" "traceon"
 164 ;;;               "translit" "undefine" "undivert" "unix"))
 165 ;;;(make-regexp '("m4_builtin" "m4_changecom" "m4_changequote" "m4_changeword"
 166 ;;;               "m4_debugfile" "m4_debugmode" "m4_decr" "m4_define" "m4_defn"
 167 ;;;               "m4_divert" "m4_divnum" "m4_dnl" "m4_dumpdef" "m4_errprint"
 168 ;;;               "m4_esyscmd" "m4_eval" "m4_file" "m4_format" "m4_ifdef" "m4_ifelse"
 169 ;;;               "m4_include" "m4_incr" "m4_index" "m4_indir" "m4_len" "m4_line"
 170 ;;;               "m4_m4exit" "m4_m4wrap" "m4_maketemp" "m4_patsubst" "m4_popdef"
 171 ;;;               "m4_pushdef" "m4_regexp" "m4_shift" "m4_sinclude" "m4_substr"
 172 ;;;               "m4_syscmd" "m4_sysval" "m4_traceoff" "m4_traceon" "m4_translit"
 173 ;;;               "m4_m4_undefine" "m4_undivert"))
 174
 175 ;;; m4-mode.el ends here