code.delx.au - gnu-emacs-elpa/blob - hydra.el

   1 ;;; hydra.el --- Make bindings that stick around. -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; Maintainer: Oleh Krehel <ohwoeowho@gmail.com>
   7 ;; URL: https://github.com/abo-abo/hydra
   8 ;; Version: 0.12.0
   9 ;; Keywords: bindings
  10 ;; Package-Requires: ((cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This package can be used to tie related commands into a family of
  30 ;; short bindings with a common prefix - a Hydra.
  31 ;;
  32 ;; Once you summon the Hydra (through the prefixed binding), all the
  33 ;; heads can be called in succession with only a short extension.
  34 ;; The Hydra is vanquished once Hercules, any binding that isn't the
  35 ;; Hydra's head, arrives.  Note that Hercules, besides vanquishing the
  36 ;; Hydra, will still serve his orignal purpose, calling his proper
  37 ;; command.  This makes the Hydra very seamless, it's like a minor
  38 ;; mode that disables itself automagically.
  39 ;;
  40 ;; Here's an example Hydra, bound in the global map (you can use any
  41 ;; keymap in place of `global-map'):
  42 ;;
  43 ;;     (defhydra hydra-zoom (global-map "<f2>")
  44 ;;       "zoom"
  45 ;;       ("g" text-scale-increase "in")
  46 ;;       ("l" text-scale-decrease "out"))
  47 ;;
  48 ;; It allows to start a command chain either like this:
  49 ;; "<f2> gg4ll5g", or "<f2> lgllg".
  50 ;;
  51 ;; Here's another approach, when you just want a "callable keymap":
  52 ;;
  53 ;;     (defhydra hydra-toggle (:color blue)
  54 ;;       "toggle"
  55 ;;       ("a" abbrev-mode "abbrev")
  56 ;;       ("d" toggle-debug-on-error "debug")
  57 ;;       ("f" auto-fill-mode "fill")
  58 ;;       ("t" toggle-truncate-lines "truncate")
  59 ;;       ("w" whitespace-mode "whitespace")
  60 ;;       ("q" nil "cancel"))
  61 ;;
  62 ;; This binds nothing so far, but if you follow up with:
  63 ;;
  64 ;;     (global-set-key (kbd "C-c C-v") 'hydra-toggle/body)
  65 ;;
  66 ;; you will have bound "C-c C-v a", "C-c C-v d" etc.
  67 ;;
  68 ;; Knowing that `defhydra' defines e.g. `hydra-toggle/body' command,
  69 ;; you can nest Hydras if you wish, with `hydra-toggle/body' possibly
  70 ;; becoming a blue head of another Hydra.
  71 ;;
  72 ;; Initially, Hydra shipped with a simplified `hydra-create' macro, to
  73 ;; which you could hook up the examples from hydra-examples.el.  It's
  74 ;; better to take the examples simply as templates and use `defhydra'
  75 ;; instead of `hydra-create', since it's more flexible.
  76
  77 ;;; Code:
  78 ;;* Requires
  79 (require 'cl-lib)
  80 (require 'lv)
  81
  82 (defalias 'hydra-set-transient-map
  83     (if (fboundp 'set-transient-map)
  84         'set-transient-map
  85       (lambda (map _keep-pred &optional on-exit)
  86         (with-no-warnings
  87           (set-temporary-overlay-map map (hydra--pred on-exit))))))
  88
  89 (defun hydra--pred (on-exit)
  90   "Generate a predicate on whether to continue the Hydra state.
  91 Call ON-EXIT for clean-up.
  92 This is a compatibility code for Emacs older than 24.4."
  93   `(lambda ()
  94      (if (lookup-key hydra-curr-map (this-command-keys-vector))
  95          t
  96        (hydra-cleanup)
  97        ,(when on-exit
  98               `(funcall ,(hydra--make-callable on-exit)))
  99        nil)))
 100
 101 ;;* Customize
 102 (defgroup hydra nil
 103   "Make bindings that stick around."
 104   :group 'bindings
 105   :prefix "hydra-")
 106
 107 (defcustom hydra-is-helpful t
 108   "When t, display a hint with possible bindings in the echo area."
 109   :type 'boolean
 110   :group 'hydra)
 111
 112 (defcustom hydra-keyboard-quit "\a"
 113   "This binding will quit an amaranth Hydra.
 114 It's the only other way to quit it besides though a blue head.
 115 It's possible to set this to nil.")
 116
 117 (defcustom hydra-lv t
 118   "When non-nil, `lv-message' (not `message') will be used to display hints."
 119   :type 'boolean)
 120
 121 (defcustom hydra-verbose nil
 122   "When non-nil, hydra will issue some non essential style warnings."
 123   :type 'boolean)
 124
 125 (defcustom hydra-key-format-spec "%s"
 126   "Default `format'-style specifier for _a_  syntax in docstrings.
 127 When nil, you can specify your own at each location like this: _ 5a_.")
 128
 129 (defface hydra-face-red
 130     '((t (:foreground "#FF0000" :bold t)))
 131   "Red Hydra heads will persist indefinitely."
 132   :group 'hydra)
 133
 134 (defface hydra-face-blue
 135     '((t (:foreground "#0000FF" :bold t)))
 136   "Blue Hydra heads will vanquish the Hydra.")
 137
 138 (defface hydra-face-amaranth
 139     '((t (:foreground "#E52B50" :bold t)))
 140   "Amaranth body has red heads and warns on intercepting non-heads.
 141 Vanquishable only through a blue head.")
 142
 143 (defface hydra-face-pink
 144     '((t (:foreground "#FF6EB4" :bold t)))
 145   "Pink body has red heads and on intercepting non-heads calls them without quitting.
 146 Vanquishable only through a blue head.")
 147
 148 (defface hydra-face-teal
 149     '((t (:foreground "#367588" :bold t)))
 150   "Teal body has blue heads an warns on intercepting non-heads.
 151 Vanquishable only through a blue head.")
 152
 153 ;;* Fontification
 154 (defun hydra-add-font-lock ()
 155   "Fontify `defhydra' statements."
 156   (font-lock-add-keywords
 157    'emacs-lisp-mode
 158    '(("(\\(defhydra\\)\\_> +\\(.*?\\)\\_>"
 159       (1 font-lock-keyword-face)
 160       (2 font-lock-type-face))
 161      ("(\\(defhydradio\\)\\_> +\\(.*?\\)\\_>"
 162       (1 font-lock-keyword-face)
 163       (2 font-lock-type-face)))))
 164
 165 ;;* Universal Argument
 166 (defvar hydra-base-map
 167   (let ((map (make-sparse-keymap)))
 168     (define-key map [?\C-u] 'hydra--universal-argument)
 169     (define-key map [?-] 'hydra--negative-argument)
 170     (define-key map [?0] 'hydra--digit-argument)
 171     (define-key map [?1] 'hydra--digit-argument)
 172     (define-key map [?2] 'hydra--digit-argument)
 173     (define-key map [?3] 'hydra--digit-argument)
 174     (define-key map [?4] 'hydra--digit-argument)
 175     (define-key map [?5] 'hydra--digit-argument)
 176     (define-key map [?6] 'hydra--digit-argument)
 177     (define-key map [?7] 'hydra--digit-argument)
 178     (define-key map [?8] 'hydra--digit-argument)
 179     (define-key map [?9] 'hydra--digit-argument)
 180     (define-key map [kp-0] 'hydra--digit-argument)
 181     (define-key map [kp-1] 'hydra--digit-argument)
 182     (define-key map [kp-2] 'hydra--digit-argument)
 183     (define-key map [kp-3] 'hydra--digit-argument)
 184     (define-key map [kp-4] 'hydra--digit-argument)
 185     (define-key map [kp-5] 'hydra--digit-argument)
 186     (define-key map [kp-6] 'hydra--digit-argument)
 187     (define-key map [kp-7] 'hydra--digit-argument)
 188     (define-key map [kp-8] 'hydra--digit-argument)
 189     (define-key map [kp-9] 'hydra--digit-argument)
 190     (define-key map [kp-subtract] 'hydra--negative-argument)
 191     (define-key map [switch-frame] 'hydra--handle-switch-frame)
 192     map)
 193   "Keymap that all Hydras inherit.  See `universal-argument-map'.")
 194
 195 (defvar hydra-curr-map
 196   (make-sparse-keymap)
 197   "Keymap of the current Hydra called.")
 198
 199 (defun hydra--handle-switch-frame (evt)
 200   "Quit hydra and call old switch-frame event handler."
 201   (interactive "e")
 202   (hydra-keyboard-quit)
 203   (funcall (lookup-key (current-global-map) [switch-frame]) evt))
 204
 205 (defun hydra--universal-argument (arg)
 206   "Forward to (`universal-argument' ARG)."
 207   (interactive "P")
 208   (setq prefix-arg (if (consp arg)
 209                        (list (* 4 (car arg)))
 210                      (if (eq arg '-)
 211                          (list -4)
 212                        '(4))))
 213   (hydra-set-transient-map hydra-curr-map t))
 214
 215 (defun hydra--digit-argument (arg)
 216   "Forward to (`digit-argument' ARG)."
 217   (interactive "P")
 218   (let ((universal-argument-map hydra-curr-map))
 219     (digit-argument arg)))
 220
 221 (defun hydra--negative-argument (arg)
 222   "Forward to (`negative-argument' ARG)."
 223   (interactive "P")
 224   (let ((universal-argument-map hydra-curr-map))
 225     (negative-argument arg)))
 226 ;;* Repeat
 227 (defvar hydra-repeat--prefix-arg nil
 228   "Prefix arg to use with `hydra-repeat'.")
 229
 230 (defvar hydra-repeat--command nil
 231   "Command to use with `hydra-repeat'.")
 232
 233 (defun hydra-repeat ()
 234   "Repeat last command with last prefix arg."
 235   (interactive)
 236   (unless (string-match "hydra-repeat$" (symbol-name last-command))
 237     (setq hydra-repeat--command last-command)
 238     (setq hydra-repeat--prefix-arg (or last-prefix-arg 1)))
 239   (setq current-prefix-arg hydra-repeat--prefix-arg)
 240   (funcall hydra-repeat--command))
 241
 242 ;;* Misc internals
 243 (defvar hydra-last nil
 244   "The result of the last `hydra-set-transient-map' call.")
 245
 246 (defun hydra--callablep (x)
 247   "Test if X is callable."
 248   (or (functionp x)
 249       (and (consp x)
 250            (memq (car x) '(function quote)))))
 251
 252 (defun hydra--make-callable (x)
 253   "Generate a callable symbol from X.
 254 If X is a function symbol or a lambda, return it.  Otherwise, it
 255 should be a single statement.  Wrap it in an interactive lambda."
 256   (if (or (symbolp x) (functionp x))
 257       x
 258     `(lambda ()
 259        (interactive)
 260        ,x)))
 261
 262 (defun hydra-plist-get-default (plist prop default)
 263   "Extract a value from a property list.
 264 PLIST is a property list, which is a list of the form
 265 \(PROP1 VALUE1 PROP2 VALUE2...).
 266
 267 Return the value corresponding to PROP, or DEFAULT if PROP is not
 268 one of the properties on the list."
 269   (if (memq prop plist)
 270       (plist-get plist prop)
 271     default))
 272
 273 (defun hydra--head-property (h prop &optional default)
 274   "Return for Hydra head H the value of property PROP.
 275 Return DEFAULT if PROP is not in H."
 276   (hydra-plist-get-default (cl-cdddr h) prop default))
 277
 278 (defun hydra--aggregate-color (head-color body-color)
 279   "Return the resulting head color for HEAD-COLOR and BODY-COLOR."
 280   (cond ((eq head-color 'red)
 281          (cl-case body-color
 282            (red 'red)
 283            (blue 'red)
 284            (amaranth 'amaranth)
 285            (pink 'pink)
 286            (cyan 'amaranth)))
 287         ((eq head-color 'blue)
 288          (cl-case body-color
 289            (red 'blue)
 290            (blue 'blue)
 291            (amaranth 'teal)
 292            (pink 'blue)
 293            (cyan 'teal)))
 294         (t
 295          (error "Can't aggregate head %S to body %S"
 296                 head-color body-color))))
 297
 298 (defun hydra--head-color (h body)
 299   "Return the color of a Hydra head H with BODY."
 300   (let* ((exit (hydra--head-property h :exit 'default))
 301          (color (hydra--head-property h :color))
 302          (foreign-keys (hydra--body-foreign-keys body))
 303          (head-color
 304           (cond ((eq exit 'default)
 305                  (cl-case color
 306                    (blue 'blue)
 307                    (red 'red)
 308                    (t
 309                     (unless (null color)
 310                       (error "Use only :blue or :red for heads: %S" h)))))
 311                 ((null exit)
 312                  (if color
 313                      (error "Don't mix :color and :exit - they are aliases: %S" h)
 314                    (cl-case foreign-keys
 315                      (run 'pink)
 316                      (warn 'amaranth)
 317                      (t 'red))))
 318                 ((eq exit t)
 319                  (if color
 320                      (error "Don't mix :color and :exit - they are aliases: %S" h)
 321                    'blue))
 322                 (t
 323                  (error "Unknown :exit %S" exit)))))
 324     (cond ((null (cadr h))
 325            (when head-color
 326              (hydra--complain
 327               "Doubly specified blue head - nil cmd is already blue: %S" h))
 328            'blue)
 329           ((null head-color)
 330            (hydra--body-color body))
 331           ((null foreign-keys)
 332            head-color)
 333           ((eq foreign-keys 'run)
 334            (if (eq head-color 'red)
 335                'pink
 336              'blue))
 337           ((eq foreign-keys 'warn)
 338            (if (memq head-color '(red amaranth))
 339                'amaranth
 340              'teal))
 341           (t
 342            (error "Unexpected %S %S" h body)))))
 343
 344 (defun hydra--body-foreign-keys (body)
 345   "Return what BODY does with a non-head binding."
 346   (or
 347    (plist-get (cddr body) :foreign-keys)
 348    (let ((color (plist-get (cddr body) :color)))
 349      (cl-case color
 350        ((amaranth teal) 'warn)
 351        (pink 'run)))))
 352
 353 (defun hydra--body-color (body)
 354   "Return the color of BODY.
 355 BODY is the second argument to `defhydra'"
 356   (let ((color (plist-get (cddr body) :color))
 357         (exit (plist-get (cddr body) :exit))
 358         (foreign-keys (plist-get (cddr body) :foreign-keys)))
 359     (cond ((eq foreign-keys 'warn)
 360            (if exit 'teal 'amaranth))
 361           ((eq foreign-keys 'run) 'pink)
 362           (exit 'blue)
 363           (color color)
 364           (t 'red))))
 365
 366 (defun hydra--face (h body)
 367   "Return the face for a Hydra head H with BODY."
 368   (cl-case (hydra--head-color h body)
 369     (blue 'hydra-face-blue)
 370     (red 'hydra-face-red)
 371     (amaranth 'hydra-face-amaranth)
 372     (pink 'hydra-face-pink)
 373     (teal 'hydra-face-teal)
 374     (t (error "Unknown color for %S" h))))
 375
 376 (defun hydra-cleanup ()
 377   "Clean up after a Hydra."
 378   (when (window-live-p lv-wnd)
 379     (let ((buf (window-buffer lv-wnd)))
 380       (delete-window lv-wnd)
 381       (kill-buffer buf))))
 382
 383 (defun hydra-keyboard-quit ()
 384   "Quitting function similar to `keyboard-quit'."
 385   (interactive)
 386   (hydra-disable)
 387   (hydra-cleanup)
 388   (cancel-timer hydra-timer)
 389   (unless hydra-lv
 390     (message ""))
 391   nil)
 392
 393 (defun hydra-disable ()
 394   "Disable the current Hydra."
 395   (cond
 396     ;; Emacs 25
 397     ((functionp hydra-last)
 398      (funcall hydra-last))
 399
 400     ;; Emacs 24.3 or older
 401     ((< emacs-minor-version 4)
 402      (setq emulation-mode-map-alists
 403            (cl-remove-if
 404             (lambda (x)
 405               (and (consp x)
 406                    (consp (car x))
 407                    (equal (cdar x) hydra-curr-map)))
 408             emulation-mode-map-alists)))
 409
 410     ;; Emacs 24.4.1
 411     (t
 412      (setq overriding-terminal-local-map nil))))
 413
 414 (defun hydra--unalias-var (str prefix)
 415   "Return the symbol named STR if it's bound as a variable.
 416 Otherwise, add PREFIX to the symbol name."
 417   (let ((sym (intern-soft str)))
 418     (if (boundp sym)
 419         sym
 420       (intern (concat prefix "/" str)))))
 421
 422 (defun hydra--hint (body heads)
 423   "Generate a hint for the echo area.
 424 BODY, and HEADS are parameters to `defhydra'."
 425   (let (alist)
 426     (dolist (h heads)
 427       (let ((val (assoc (cadr h) alist))
 428             (pstr (hydra-fontify-head h body)))
 429         (unless (null (cl-caddr h))
 430           (if val
 431               (setf (cadr val)
 432                     (concat (cadr val) " " pstr))
 433             (push
 434              (cons (cadr h)
 435                    (cons pstr (cl-caddr h)))
 436              alist)))))
 437     (mapconcat
 438      (lambda (x)
 439        (format
 440         (if (> (length (cdr x)) 0)
 441             (concat "[%s]: " (cdr x))
 442           "%s")
 443         (car x)))
 444      (nreverse (mapcar #'cdr alist))
 445      ", ")))
 446
 447 (defvar hydra-fontify-head-function nil
 448   "Possible replacement for `hydra-fontify-head-default'.")
 449
 450 (defun hydra-fontify-head-default (head body)
 451   "Produce a pretty string from HEAD and BODY.
 452 HEAD's binding is returned as a string with a colored face."
 453   (propertize (car head) 'face (hydra--face head body)))
 454
 455 (defun hydra-fontify-head-greyscale (head body)
 456   "Produce a pretty string from HEAD and BODY.
 457 HEAD's binding is returned as a string wrapped with [] or {}."
 458   (let ((color (hydra--head-color head body)))
 459     (format
 460      (if (eq color 'blue)
 461          "[%s]"
 462        "{%s}") (car head))))
 463
 464 (defun hydra-fontify-head (head body)
 465   "Produce a pretty string from HEAD and BODY."
 466   (funcall (or hydra-fontify-head-function 'hydra-fontify-head-default)
 467            head body))
 468
 469 (defun hydra--format (name body docstring heads)
 470   "Generate a `format' statement from STR.
 471 \"%`...\" expressions are extracted into \"%S\".
 472 NAME, BODY, DOCSTRING and HEADS are parameters of `defhydra'.
 473 The expressions can be auto-expanded according to NAME."
 474   (setq docstring (replace-regexp-in-string "\\^" "" docstring))
 475   (let ((rest (hydra--hint body heads))
 476         (prefix (symbol-name name))
 477         (start 0)
 478         varlist
 479         offset)
 480     (while (setq start
 481                  (string-match
 482                   "\\(?:%\\( ?-?[0-9]*s?\\)\\(`[a-z-A-Z/0-9]+\\|(\\)\\)\\|\\(?:_\\( ?-?[0-9]*\\)\\([a-z-~A-Z;:0-9/|?<>={}]+\\)_\\)"
 483                   docstring start))
 484       (cond ((eq ?_ (aref (match-string 0 docstring) 0))
 485              (let* ((key (match-string 4 docstring))
 486                     (head (assoc key heads)))
 487                (if head
 488                    (progn
 489                      (push (hydra-fontify-head head body) varlist)
 490                      (setq docstring
 491                            (replace-match
 492                             (or
 493                              hydra-key-format-spec
 494                              (concat "%" (match-string 3 docstring) "s"))
 495                             nil nil docstring)))
 496                  (error "Unrecognized key: _%s_" key))))
 497
 498             ((eq ?` (aref (match-string 2 docstring) 0))
 499              (push (hydra--unalias-var
 500                     (substring (match-string 2 docstring) 1) prefix)
 501                    varlist)
 502              (setq docstring
 503                    (replace-match
 504                     (concat "%" (match-string 1 docstring) "S")
 505                     nil nil docstring 0)))
 506
 507             (t
 508              (let* ((spec (match-string 1 docstring))
 509                     (lspec (length spec))
 510                     (me2 (match-end 2)))
 511                (setq offset
 512                      (with-temp-buffer
 513                        (insert (substring docstring (+ 1 start (length spec))))
 514                        (goto-char (point-min))
 515                        (push (read (current-buffer)) varlist)
 516                        (- (point) (point-min))))
 517                (when (or (zerop lspec)
 518                          (/= (aref spec (1- (length spec))) ?s))
 519                  (setq spec (concat spec "S")))
 520                (setq docstring
 521                      (concat
 522                       (substring docstring 0 start)
 523                       "%" spec
 524                       (substring docstring (+ me2 offset -1))))))))
 525     (if (eq ?\n (aref docstring 0))
 526         `(concat (format ,(substring docstring 1) ,@(nreverse varlist))
 527                  ,rest)
 528       `(format ,(concat docstring ": " rest ".")))))
 529
 530 (defun hydra--message (name body docstring heads)
 531   "Generate code to display the hint in the preferred echo area.
 532 Set `hydra-lv' to choose the echo area.
 533 NAME, BODY, DOCSTRING, and HEADS are parameters of `defhydra'."
 534   (let ((format-expr (hydra--format name body docstring heads)))
 535     `(if hydra-lv
 536          (lv-message ,format-expr)
 537        (message ,format-expr))))
 538
 539 (defun hydra--complain (format-string &rest args)
 540   "Forward to (`message' FORMAT-STRING ARGS) unless `hydra-verbose' is nil."
 541   (when hydra-verbose
 542     (apply #'warn format-string args)))
 543
 544 (defun hydra--doc (body-key body-name heads)
 545   "Generate a part of Hydra docstring.
 546 BODY-KEY is the body key binding.
 547 BODY-NAME is the symbol that identifies the Hydra.
 548 HEADS is a list of heads."
 549   (format
 550    "Create a hydra with %s body and the heads:\n\n%s\n\n%s"
 551    (if body-key
 552        (format "a \"%s\"" body-key)
 553      "no")
 554    (mapconcat
 555     (lambda (x)
 556       (format "\"%s\":    `%S'" (car x) (cadr x)))
 557     heads ",\n")
 558    (format "The body can be accessed via `%S'." body-name)))
 559
 560 (defun hydra--make-defun (name body doc head
 561                           keymap body-pre body-post &optional other-post)
 562   "Make a defun wrapper, using NAME, BODY, DOC, HEAD, and KEYMAP.
 563 NAME and BODY are the arguments to `defhydra'.
 564 DOC was generated with `hydra--doc'.
 565 HEAD is one of the HEADS passed to `defhydra'.
 566 BODY-PRE and BODY-POST are pre-processed in `defhydra'.
 567 OTHER-POST is an optional extension to the :post key of BODY."
 568   (let ((name (hydra--head-name head name))
 569         (cmd (when (car head)
 570                (hydra--make-callable
 571                 (cadr head))))
 572         (color (when (car head)
 573                  (hydra--head-color head body)))
 574         (doc (if (car head)
 575                  (format "%s\n\nCall the head: `%S'." doc (cadr head))
 576                doc))
 577         (hint (intern (format "%S/hint" name)))
 578         (body-color (hydra--body-color body))
 579         (body-timeout (plist-get body :timeout)))
 580     `(defun ,name ()
 581        ,doc
 582        (interactive)
 583        ,@(when body-pre (list body-pre))
 584        (hydra-disable)
 585        ,@(when (memq color '(blue teal)) '((hydra-cleanup)))
 586        (catch 'hydra-disable
 587          ,@(delq nil
 588                  (if (memq color '(blue teal))
 589                      `(,(when cmd `(call-interactively #',cmd))
 590                         ,body-post)
 591                    `(,(when cmd
 592                             `(condition-case err
 593                                  (prog1 t
 594                                    (call-interactively #',cmd))
 595                                ((quit error)
 596                                 (message "%S" err)
 597                                 (unless hydra-lv
 598                                   (sit-for 0.8))
 599                                 nil)))
 600                       (when hydra-is-helpful
 601                         (,hint))
 602                       (setq hydra-last
 603                             (hydra-set-transient-map
 604                              (setq hydra-curr-map ',keymap)
 605                              t
 606                              ,(if (and
 607                                    (not (memq body-color
 608                                               '(amaranth pink teal)))
 609                                    body-post)
 610                                   `(lambda () (hydra-cleanup) ,body-post)
 611                                   `(lambda () (hydra-cleanup)))))
 612                       ,(or other-post
 613                            (when body-timeout
 614                              (list 'hydra-timeout
 615                                    body-timeout
 616                                    (when body-post
 617                                      (hydra--make-callable body-post))))))))))))
 618
 619 (defun hydra-pink-fallback ()
 620   "On intercepting a non-head, try to run it."
 621   (let ((keys (this-command-keys))
 622         kb)
 623     (when (equal keys [backspace])
 624       (setq keys "\7f"))
 625     (setq kb (key-binding keys))
 626     (if kb
 627         (if (commandp kb)
 628             (condition-case err
 629                 (call-interactively kb)
 630               ((quit error)
 631                (message "%S" err)
 632                (unless hydra-lv
 633                  (sit-for 0.8))))
 634           (message "Pink Hydra can't currently handle prefixes, continuing"))
 635       (message "Pink Hydra could not resolve: %S" keys))))
 636
 637 (defun hydra--modify-keymap (keymap def)
 638   "In KEYMAP, add DEF to each sub-keymap."
 639   (cl-labels
 640       ((recur (map)
 641          (if (atom map)
 642              map
 643            (if (eq (car map) 'keymap)
 644                (cons 'keymap
 645                      (cons
 646                       def
 647                       (recur (cdr map))))
 648              (cons
 649               (recur (car map))
 650               (recur (cdr map)))))))
 651     (recur keymap)))
 652
 653 (defun hydra--handle-nonhead (keymap name body heads)
 654   "Setup KEYMAP for intercepting non-head bindings.
 655 NAME, BODY and HEADS are parameters to `defhydra'."
 656   (let ((body-color (hydra--body-color body))
 657         (body-post (plist-get (cddr body) :post)))
 658     (if body-post
 659         (when (symbolp body-post)
 660           (setq body-post `(funcall #',body-post)))
 661       (when hydra-keyboard-quit
 662         (define-key keymap hydra-keyboard-quit #'hydra-keyboard-quit)))
 663     (when (memq body-color '(amaranth pink teal))
 664       (if (cl-some (lambda (h)
 665                      (memq (hydra--head-color h body) '(blue teal)))
 666                    heads)
 667           (progn
 668             (setcdr
 669              keymap
 670              (cdr
 671               (hydra--modify-keymap
 672                keymap
 673                (cons t
 674                      `(lambda ()
 675                         (interactive)
 676                         ,(cond
 677                           ((memq body-color '(amaranth teal))
 678                            '(message "An amaranth Hydra can only exit through a blue head"))
 679                           (t
 680                            '(hydra-pink-fallback)))
 681                         (hydra-set-transient-map hydra-curr-map t)
 682                         (when hydra-is-helpful
 683                           (unless hydra-lv
 684                             (sit-for 0.8))
 685                           (,(intern (format "%S/hint" name))))))))))
 686         (unless (eq body-color 'teal)
 687           (error
 688            "An %S Hydra must have at least one blue head in order to exit"
 689            body-color))))))
 690
 691 (defun hydra--head-name (h body-name)
 692   "Return the symbol for head H of body BODY-NAME."
 693   (intern (format "%S/%s" body-name
 694                   (if (symbolp (cadr h))
 695                       (cadr h)
 696                     (concat "lambda-" (car h))))))
 697
 698 (defun hydra--delete-duplicates (heads)
 699   "Return HEADS without entries that have the same CMD part.
 700 In duplicate HEADS, :cmd-name is modified to whatever they duplicate."
 701   (let ((ali '(((hydra-repeat . red) . hydra-repeat)))
 702         res entry)
 703     (dolist (h heads)
 704       (if (setq entry (assoc (cons (cadr h)
 705                                    (hydra--head-color h '(nil nil)))
 706                              ali))
 707           (setf (cl-cdddr h) (plist-put (cl-cdddr h) :cmd-name (cdr entry)))
 708         (push (cons (cons (cadr h)
 709                           (hydra--head-color h '(nil nil)))
 710                     (plist-get (cl-cdddr h) :cmd-name))
 711               ali)
 712         (push h res)))
 713     (nreverse res)))
 714
 715 (defun hydra--pad (lst n)
 716   "Pad LST with nil until length N."
 717   (let ((len (length lst)))
 718     (if (= len n)
 719         lst
 720       (append lst (make-list (- n len) nil)))))
 721
 722 (defun hydra--matrix (lst rows cols)
 723   "Create a matrix from elements of LST.
 724 The matrix size is ROWS times COLS."
 725   (let ((ls (copy-sequence lst))
 726         res)
 727     (dotimes (_c cols)
 728       (push (hydra--pad (hydra-multipop ls rows) rows) res))
 729     (nreverse res)))
 730
 731 (defun hydra--cell (fstr names)
 732   "Format a rectangular cell based on FSTR and NAMES.
 733 FSTR is a format-style string with two string inputs: one for the
 734 doc and one for the symbol name.
 735 NAMES is a list of variables."
 736   (let ((len (cl-reduce
 737               (lambda (acc it) (max (length (symbol-name it)) acc))
 738               names
 739               :initial-value 0)))
 740     (mapconcat
 741      (lambda (sym)
 742        (if sym
 743            (format fstr
 744                    (documentation-property sym 'variable-documentation)
 745                    (let ((name (symbol-name sym)))
 746                      (concat name (make-string (- len (length name)) ?^)))
 747                    sym)
 748          ""))
 749      names
 750      "\n")))
 751
 752 (defun hydra--vconcat (strs &optional joiner)
 753   "Glue STRS vertically.  They must be the same height.
 754 JOINER is a function similar to `concat'."
 755   (setq joiner (or joiner #'concat))
 756   (mapconcat
 757    (lambda (s)
 758      (if (string-match " +$" s)
 759          (replace-match "" nil nil s)
 760        s))
 761    (apply #'cl-mapcar joiner
 762           (mapcar
 763            (lambda (s) (split-string s "\n"))
 764            strs))
 765    "\n"))
 766
 767 (defcustom hydra-cell-format "% -20s %% -8`%s"
 768   "The default format for docstring cells."
 769   :type 'string)
 770
 771 (defun hydra--table (names rows cols &optional cell-formats)
 772   "Format a `format'-style table from variables in NAMES.
 773 The size of the table is ROWS times COLS.
 774 CELL-FORMATS are `format' strings for each column.
 775 If CELL-FORMATS is a string, it's used for all columns.
 776 If CELL-FORMATS is nil, `hydra-cell-format' is used for all columns."
 777   (setq cell-formats
 778         (cond ((null cell-formats)
 779                (make-list cols hydra-cell-format))
 780               ((stringp cell-formats)
 781                (make-list cols cell-formats))
 782               (t
 783                cell-formats)))
 784   (hydra--vconcat
 785    (cl-mapcar
 786     #'hydra--cell
 787     cell-formats
 788     (hydra--matrix names rows cols))
 789    (lambda (&rest x)
 790      (mapconcat #'identity x "    "))))
 791
 792 (defun hydra-reset-radios (names)
 793   "Set varibles NAMES to their defaults.
 794 NAMES should be defined by `defhydradio' or similar."
 795   (dolist (n names)
 796     (set n (aref (get n 'range) 0))))
 797
 798 (defvar hydra-timer (timer-create)
 799   "Timer for `hydra-timeout'.")
 800
 801 (defun hydra-timeout (secs &optional function)
 802   "In SECS seconds call FUNCTION, then `hydra-keyboard-quit'.
 803 Cancel the previous `hydra-timeout'."
 804   (cancel-timer hydra-timer)
 805   (setq hydra-timer (timer-create))
 806   (timer-set-time hydra-timer
 807                   (timer-relative-time (current-time) secs))
 808   (timer-set-function
 809    hydra-timer
 810    `(lambda ()
 811       ,(when function
 812              `(funcall ,function))
 813       (hydra-keyboard-quit)))
 814   (timer-activate hydra-timer))
 815
 816 ;;* Macros
 817 ;;** defhydra
 818 ;;;###autoload
 819 (defmacro defhydra (name body &optional docstring &rest heads)
 820   "Create a Hydra - a family of functions with prefix NAME.
 821
 822 NAME should be a symbol, it will be the prefix of all functions
 823 defined here.
 824
 825 BODY has the format:
 826
 827     (BODY-MAP BODY-KEY &rest PLIST)
 828
 829 DOCSTRING will be displayed in the echo area to identify the
 830 Hydra.
 831
 832 Functions are created on basis of HEADS, each of which has the
 833 format:
 834
 835     (KEY CMD &optional HINT &rest PLIST)
 836
 837 BODY-MAP is a keymap; `global-map' is used quite often.  Each
 838 function generated from HEADS will be bound in BODY-MAP to
 839 BODY-KEY + KEY (both are strings passed to `kbd'), and will set
 840 the transient map so that all following heads can be called
 841 though KEY only.
 842
 843 CMD is a callable expression: either an interactive function
 844 name, or an interactive lambda, or a single sexp (it will be
 845 wrapped in an interactive lambda).
 846
 847 HINT is a short string that identifies its head.  It will be
 848 printed beside KEY in the echo erea if `hydra-is-helpful' is not
 849 nil.  If you don't even want the KEY to be printed, set HINT
 850 explicitly to nil.
 851
 852 The heads inherit their PLIST from the body and are allowed to
 853 override each key.  The keys recognized are :color and :bind.
 854 :color can be:
 855
 856 - red (default): this head will continue the Hydra state.
 857 - blue: this head will stop the Hydra state.
 858 - amaranth (applies to body only): similar to red, but no binding
 859 except a blue head can stop the Hydra state.
 860
 861 :bind can be:
 862 - nil: this head will not be bound in BODY-MAP.
 863 - a lambda taking KEY and CMD used to bind a head
 864
 865 It is possible to omit both BODY-MAP and BODY-KEY if you don't
 866 want to bind anything.  In that case, typically you will bind the
 867 generated NAME/body command.  This command is also the return
 868 result of `defhydra'."
 869   (declare (indent defun))
 870   (cond ((stringp docstring))
 871         ((and (consp docstring)
 872               (memq (car docstring) '(hydra--table concat format)))
 873          (setq docstring (concat "\n" (eval docstring))))
 874         (t
 875          (setq heads (cons docstring heads))
 876          (setq docstring "hydra")))
 877   (when (keywordp (car body))
 878     (setq body (cons nil (cons nil body))))
 879   (let ((keymap (copy-keymap hydra-base-map))
 880         (body-name (intern (format "%S/body" name)))
 881         (body-key (cadr body))
 882         (body-pre (plist-get (cddr body) :pre))
 883         (body-body-pre (plist-get (cddr body) :body-pre))
 884         (body-post (plist-get (cddr body) :post))
 885         (method (or (plist-get body :bind)
 886                     (car body))))
 887     (when body-post
 888       (when (symbolp body-post)
 889         (setq body-post `(funcall #',body-post)))
 890       (setq heads (cons (list hydra-keyboard-quit #'hydra-keyboard-quit nil :exit t)
 891                         heads)))
 892     (dolist (h heads)
 893       (let ((len (length h))
 894             (cmd-name (hydra--head-name h name)))
 895         (cond ((< len 2)
 896                (error "Each head should have at least two items: %S" h))
 897               ((= len 2)
 898                (setcdr (cdr h)
 899                        (list
 900                         (hydra-plist-get-default (cddr body) :hint "")
 901                         :cmd-name cmd-name)))
 902               (t
 903                (let ((hint (cl-caddr h)))
 904                  (unless (or (null hint)
 905                              (stringp hint))
 906                    (setcdr (cdr h) (cons
 907                                     (hydra-plist-get-default (cddr body) :hint "")
 908                                     (cddr h))))
 909                  (setcdr (cddr h) `(:cmd-name ,cmd-name ,@(cl-cdddr h))))))))
 910     (let ((doc (hydra--doc body-key body-name heads))
 911           (heads-nodup (hydra--delete-duplicates heads)))
 912       (mapc
 913        (lambda (x)
 914          (define-key keymap (kbd (car x))
 915            (plist-get (cl-cdddr x) :cmd-name)))
 916        heads)
 917       (when (and body-pre (symbolp body-pre))
 918         (setq body-pre `(funcall #',body-pre)))
 919       (when (and body-body-pre (symbolp body-body-pre))
 920         (setq body-body-pre `(funcall #',body-body-pre)))
 921       (hydra--handle-nonhead keymap name body heads)
 922       `(progn
 923          ,@(mapcar
 924             (lambda (head)
 925               (hydra--make-defun name body doc head keymap
 926                                  body-pre body-post))
 927             heads-nodup)
 928          ,@(unless (or (null body-key)
 929                        (null method)
 930                        (hydra--callablep method))
 931                    `((unless (keymapp (lookup-key ,method (kbd ,body-key)))
 932                        (define-key ,method (kbd ,body-key) nil))))
 933          ,@(delq nil
 934                  (cl-mapcar
 935                   (lambda (head)
 936                     (let ((name (hydra--head-property head :cmd-name)))
 937                       (when (and (cadr head)
 938                                  (not (eq (cadr head) 'hydra-keyboard-quit))
 939                                  (or body-key method))
 940                         (let ((bind (hydra--head-property head :bind 'default))
 941                               (final-key
 942                                (if body-key
 943                                    (vconcat (kbd body-key) (kbd (car head)))
 944                                  (kbd (car head)))))
 945                           (cond ((null bind) nil)
 946
 947                                 ((eq bind 'default)
 948                                  (list
 949                                   (if (hydra--callablep method)
 950                                       'funcall
 951                                     'define-key)
 952                                   method
 953                                   final-key
 954                                   (list 'function name)))
 955
 956                                 ((hydra--callablep bind)
 957                                  `(funcall (function ,bind)
 958                                            ,final-key
 959                                            (function ,name)))
 960
 961                                 (t
 962                                  (error "Invalid :bind property %S" head)))))))
 963                   heads))
 964          (defun ,(intern (format "%S/hint" name)) ()
 965            ,(hydra--message name body docstring heads))
 966          ,(hydra--make-defun
 967            name body doc '(nil body)
 968            keymap
 969            (or body-body-pre body-pre) body-post
 970            '(setq prefix-arg current-prefix-arg))))))
 971
 972 (defmacro defhydradio (name _body &rest heads)
 973   "Create radios with prefix NAME.
 974 BODY specifies the options; there are none currently.
 975 HEADS have the format:
 976
 977     (TOGGLE-NAME &optional VALUE DOC)
 978
 979 TOGGLE-NAME will be used along with NAME to generate a variable
 980 name and a function that cycles it with the same name.  VALUE
 981 should be an array.  The first element of VALUE will be used to
 982 inialize the variable.
 983 VALUE defaults to [nil t].
 984 DOC defaults to TOGGLE-NAME split and capitalized."
 985   (declare (indent defun))
 986   `(progn
 987      ,@(apply #'append
 988               (mapcar (lambda (h)
 989                         (hydra--radio name h))
 990                       heads))
 991      (defvar ,(intern (format "%S/names" name))
 992        ',(mapcar (lambda (h) (intern (format "%S/%S" name (car h))))
 993                  heads))))
 994
 995 (defmacro hydra-multipop (lst n)
 996   "Return LST's first N elements while removing them."
 997   `(if (<= (length ,lst) ,n)
 998        (prog1 ,lst
 999          (setq ,lst nil))
1000      (prog1 ,lst
1001        (setcdr
1002         (nthcdr (1- ,n) (prog1 ,lst (setq ,lst (nthcdr ,n ,lst))))
1003         nil))))
1004
1005 (defun hydra--radio (parent head)
1006   "Generate a hydradio with PARENT from HEAD."
1007   (let* ((name (car head))
1008          (full-name (intern (format "%S/%S" parent name)))
1009          (doc (cadr head))
1010          (val (or (cl-caddr head) [nil t])))
1011     `((defvar ,full-name ,(hydra--quote-maybe (aref val 0)) ,doc)
1012       (put ',full-name 'range ,val)
1013       (defun ,full-name ()
1014         (hydra--cycle-radio ',full-name)))))
1015
1016 (defun hydra--quote-maybe (x)
1017   "Quote X if it's a symbol."
1018   (cond ((null x)
1019          nil)
1020         ((symbolp x)
1021          (list 'quote x))
1022         (t
1023          x)))
1024
1025 (defun hydra--cycle-radio (sym)
1026   "Set SYM to the next value in its range."
1027   (let* ((val (symbol-value sym))
1028          (range (get sym 'range))
1029          (i 0)
1030          (l (length range)))
1031     (setq i (catch 'done
1032               (while (< i l)
1033                 (if (equal (aref range i) val)
1034                     (throw 'done (1+ i))
1035                   (cl-incf i)))
1036               (error "Val not in range for %S" sym)))
1037     (set sym
1038          (aref range
1039                (if (>= i l)
1040                    0
1041                  i)))))
1042
1043 (provide 'hydra)
1044
1045 ;;; Local Variables:
1046 ;;; outline-regexp: ";;\\*+"
1047 ;;; End:
1048
1049 ;;; hydra.el ends here