code.delx.au - gnu-emacs-elpa/blob - async-bytecomp.el

   1 ;;; async-bytecomp.el --- Async functions to compile elisp files async
   2
   3 ;; Copyright (C) 2014 John Wiegley
   4 ;; Copyright (C) 2014 Thierry Volpiatto
   5
   6 ;; Authors: John Wiegley <jwiegley@gmail.com>
   7 ;;          Thierry Volpiatto <thierry.volpiatto@gmail.com>
   8
   9 ;; Keywords: dired async byte-compile
  10 ;; X-URL: https://github.com/jwiegley/dired-async
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;;  This package provide the `async-byte-recompile-directory' function
  30 ;;  which allows, as the name says to recompile a directory outside of
  31 ;;  your running emacs.
  32 ;;  The benefit is your files will be compiled in a clean environment without
  33 ;;  the old *.el files loaded.
  34 ;;  Among other things, this fix a bug in package.el which recompile
  35 ;;  the new files in the current environment with the old files loaded, creating
  36 ;;  errors in most packages after upgrades.
  37 ;;
  38 ;;  NB: This package is advicing the function `package--compile'.
  39
  40 ;;; Code:
  41
  42 (require 'cl-lib)
  43 (require 'async)
  44
  45 (defcustom async-bytecomp-allowed-packages '(async helm helm-core helm-ls-git helm-ls-hg)
  46   "Packages in this list will be compiled asynchronously by `package--compile'.
  47 All the dependencies of these packages will be compiled async too,
  48 so no need to add dependencies to this list.
  49 The value of this variable can also be a list with a single element,
  50 the symbol `all', in this case packages are always compiled asynchronously."
  51   :group 'async
  52   :type '(repeat (choice symbol)))
  53
  54 (defvar async-byte-compile-log-file "~/.emacs.d/async-bytecomp.log")
  55
  56 ;;;###autoload
  57 (defun async-byte-recompile-directory (directory &optional quiet)
  58   "Compile all *.el files in DIRECTORY asynchronously.
  59 All *.elc files are systematically deleted before proceeding."
  60   (cl-loop with dir = (directory-files directory t "\\.elc\\'")
  61            unless dir return nil
  62            for f in dir
  63            when (file-exists-p f) do (delete-file f))
  64   ;; Ensure async is reloaded when async.elc is deleted.
  65   ;; This happen when recompiling its own directory.
  66   (load "async")
  67   (let ((call-back
  68          `(lambda (&optional ignore)
  69             (if (file-exists-p async-byte-compile-log-file)
  70                 (let ((buf (get-buffer-create byte-compile-log-buffer))
  71                       (n 0))
  72                   (with-current-buffer buf
  73                     (goto-char (point-max))
  74                     (let ((inhibit-read-only t))
  75                       (insert-file-contents async-byte-compile-log-file)
  76                       (compilation-mode))
  77                     (display-buffer buf)
  78                     (delete-file async-byte-compile-log-file)
  79                     (unless ,quiet
  80                       (save-excursion
  81                         (goto-char (point-min))
  82                         (while (re-search-forward "^.*:Error:" nil t)
  83                           (cl-incf n)))
  84                       (if (> n 0)
  85                           (message "Failed to compile %d files in directory `%s'" n ,directory)
  86                           (message "Directory `%s' compiled asynchronously with warnings" ,directory)))))
  87                 (unless ,quiet
  88                   (message "Directory `%s' compiled asynchronously with success" ,directory))))))
  89     (async-start
  90      `(lambda ()
  91         (require 'bytecomp)
  92         ,(async-inject-variables "\\`\\(load-path\\)\\|byte\\'")
  93         (let ((default-directory (file-name-as-directory ,directory))
  94               error-data)
  95           (add-to-list 'load-path default-directory)
  96           (byte-recompile-directory ,directory 0 t)
  97           (when (get-buffer byte-compile-log-buffer)
  98             (setq error-data (with-current-buffer byte-compile-log-buffer
  99                                (buffer-substring-no-properties (point-min) (point-max))))
 100             (unless (string= error-data "")
 101               (with-temp-file ,async-byte-compile-log-file
 102                 (erase-buffer)
 103                 (insert error-data))))))
 104      call-back)
 105     (unless quiet (message "Started compiling asynchronously directory %s" directory))))
 106
 107 (defvar package-archive-contents)
 108 (declare-function package-desc-reqs "package.el" (cl-x))
 109
 110 (defun async-bytecomp--get-package-deps (pkg &optional only)
 111   (let* ((pkg-desc (cadr (assq pkg package-archive-contents)))
 112          (direct-deps (cl-loop for p in (package-desc-reqs pkg-desc)
 113                                for name = (car p)
 114                                when (assq name package-archive-contents)
 115                                collect name))
 116          (indirect-deps (unless (eq only 'direct)
 117                           (delete-dups
 118                            (cl-loop for p in direct-deps append
 119                                     (async-bytecomp--get-package-deps p))))))
 120     (cl-case only
 121       (direct   direct-deps)
 122       (separate (list direct-deps indirect-deps))
 123       (indirect indirect-deps)
 124       (t        (delete-dups (append direct-deps indirect-deps))))))
 125
 126 (defun async-bytecomp-get-allowed-pkgs ()
 127   (when (and async-bytecomp-allowed-packages
 128              (listp async-bytecomp-allowed-packages))
 129     (cl-loop for p in async-bytecomp-allowed-packages
 130              append (async-bytecomp--get-package-deps p) into reqs
 131              finally return
 132              (delete-dups
 133               (append async-bytecomp-allowed-packages reqs)))))
 134
 135 (defadvice package--compile (around byte-compile-async)
 136   (let ((cur-package (package-desc-name pkg-desc)))
 137     (if (or (equal async-bytecomp-allowed-packages '(all))
 138             (memq cur-package (async-bytecomp-get-allowed-pkgs)))
 139         (progn
 140           (when (eq cur-package 'async)
 141             (fmakunbound 'async-byte-recompile-directory))
 142           (package-activate-1 pkg-desc)
 143           (load "async-bytecomp") ; emacs-24.3 don't reload new files.
 144           (async-byte-recompile-directory (package-desc-dir pkg-desc) t))
 145         ad-do-it)))
 146
 147 ;;;###autoload
 148 (define-minor-mode async-bytecomp-package-mode
 149     "Byte compile asynchronously packages installed with package.el.
 150 Async compilation of packages can be controlled by
 151 `async-bytecomp-allowed-packages'."
 152   :group 'async
 153   :global t
 154   (if async-bytecomp-package-mode
 155       (ad-activate 'package--compile)
 156       (ad-deactivate 'package--compile)))
 157
 158 (provide 'async-bytecomp)
 159
 160 ;;; async-bytecomp.el ends here