code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular in-buffer completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; URL: http://company-mode.github.io/
   8 ;; Version: 0.8.0-snapshot
   9 ;; Keywords: abbrev, convenience, matching
  10 ;; Package-Requires: ((emacs "24.1"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (pcase command
  52 ;;     (`prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (`meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;; Known Issues:
  62 ;; When point is at the very end of the buffer, the pseudo-tooltip appears very
  63 ;; wrong, unless company is allowed to temporarily insert a fake newline.
  64 ;; This behavior is enabled by `company-end-of-buffer-workaround'.
  65 ;;
  66 ;;; Change Log:
  67 ;;
  68 ;; See NEWS.md in the repository.
  69
  70 ;;; Code:
  71
  72 (eval-when-compile (require 'cl))
  73 (require 'newcomment)
  74
  75 ;; FIXME: Use `user-error'.
  76 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  77 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  78 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  79 (add-to-list 'debug-ignored-errors "^Company not ")
  80 (add-to-list 'debug-ignored-errors "^No candidate number ")
  81 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  82 (add-to-list 'debug-ignored-errors "^No other back-end$")
  83
  84 (defgroup company nil
  85   "Extensible inline text completion mechanism"
  86   :group 'abbrev
  87   :group 'convenience
  88   :group 'matching)
  89
  90 (defface company-tooltip
  91   '((default :foreground "black")
  92     (((class color) (min-colors 88) (background light))
  93      (:background "cornsilk"))
  94     (((class color) (min-colors 88) (background dark))
  95      (:background "yellow")))
  96   "Face used for the tooltip.")
  97
  98 (defface company-tooltip-selection
  99   '((default :inherit company-tooltip)
 100     (((class color) (min-colors 88) (background light))
 101      (:background "light blue"))
 102     (((class color) (min-colors 88) (background dark))
 103      (:background "orange1"))
 104     (t (:background "green")))
 105   "Face used for the selection in the tooltip.")
 106
 107 (defface company-tooltip-mouse
 108   '((default :inherit highlight))
 109   "Face used for the tooltip item under the mouse.")
 110
 111 (defface company-tooltip-common
 112   '((default :inherit company-tooltip)
 113     (((background light))
 114      :foreground "darkred")
 115     (((background dark))
 116      :foreground "red"))
 117   "Face used for the common completion in the tooltip.")
 118
 119 (defface company-tooltip-common-selection
 120   '((default :inherit company-tooltip-selection)
 121     (((background light))
 122      :foreground "darkred")
 123     (((background dark))
 124      :foreground "red"))
 125   "Face used for the selected common completion in the tooltip.")
 126
 127 (defface company-tooltip-annotation
 128   '((default :inherit company-tooltip)
 129     (((background light))
 130      :foreground "firebrick4")
 131     (((background dark))
 132      :foreground "red4"))
 133   "Face used for the annotation in the tooltip.")
 134
 135 (defface company-scrollbar-fg
 136   '((((background light))
 137      :background "darkred")
 138     (((background dark))
 139      :background "red"))
 140   "Face used for the tooltip scrollbar thumb.")
 141
 142 (defface company-scrollbar-bg
 143   '((default :inherit company-tooltip)
 144     (((background light))
 145      :background "wheat")
 146     (((background dark))
 147      :background "gold"))
 148   "Face used for the tooltip scrollbar background.")
 149
 150 (defface company-preview
 151   '((((background light))
 152      :inherit company-tooltip-selection)
 153     (((background dark))
 154      :background "blue4"
 155      :foreground "wheat"))
 156   "Face used for the completion preview.")
 157
 158 (defface company-preview-common
 159   '((((background light))
 160      :inherit company-tooltip-selection)
 161     (((background dark))
 162      :inherit company-preview
 163      :foreground "red"))
 164   "Face used for the common part of the completion preview.")
 165
 166 (defface company-preview-search
 167   '((((background light))
 168      :inherit company-tooltip-common-selection)
 169     (((background dark))
 170      :inherit company-preview
 171      :background "blue1"))
 172   "Face used for the search string in the completion preview.")
 173
 174 (defface company-echo nil
 175   "Face used for completions in the echo area.")
 176
 177 (defface company-echo-common
 178   '((((background dark)) (:foreground "firebrick1"))
 179     (((background light)) (:background "firebrick4")))
 180   "Face used for the common part of completions in the echo area.")
 181
 182 (defun company-frontends-set (variable value)
 183   ;; uniquify
 184   (let ((remainder value))
 185     (setcdr remainder (delq (car remainder) (cdr remainder))))
 186   (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 187        (memq 'company-pseudo-tooltip-frontend value)
 188        (error "Pseudo tooltip frontend cannot be used twice"))
 189   (and (memq 'company-preview-if-just-one-frontend value)
 190        (memq 'company-preview-frontend value)
 191        (error "Preview frontend cannot be used twice"))
 192   (and (memq 'company-echo value)
 193        (memq 'company-echo-metadata-frontend value)
 194        (error "Echo area cannot be used twice"))
 195   ;; preview must come last
 196   (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 197     (when (memq f value)
 198       (setq value (append (delq f value) (list f)))))
 199   (set variable value))
 200
 201 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 202                                company-preview-if-just-one-frontend
 203                                company-echo-metadata-frontend)
 204   "The list of active front-ends (visualizations).
 205 Each front-end is a function that takes one argument.  It is called with
 206 one of the following arguments:
 207
 208 `show': When the visualization should start.
 209
 210 `hide': When the visualization should end.
 211
 212 `update': When the data has been updated.
 213
 214 `pre-command': Before every command that is executed while the
 215 visualization is active.
 216
 217 `post-command': After every command that is executed while the
 218 visualization is active.
 219
 220 The visualized data is stored in `company-prefix', `company-candidates',
 221 `company-common', `company-selection', `company-point' and
 222 `company-search-string'."
 223   :set 'company-frontends-set
 224   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 225                          (const :tag "echo, strip common"
 226                                 company-echo-strip-common-frontend)
 227                          (const :tag "show echo meta-data in echo"
 228                                 company-echo-metadata-frontend)
 229                          (const :tag "pseudo tooltip"
 230                                 company-pseudo-tooltip-frontend)
 231                          (const :tag "pseudo tooltip, multiple only"
 232                                 company-pseudo-tooltip-unless-just-one-frontend)
 233                          (const :tag "preview" company-preview-frontend)
 234                          (const :tag "preview, unique only"
 235                                 company-preview-if-just-one-frontend)
 236                          (function :tag "custom function" nil))))
 237
 238 (defcustom company-tooltip-limit 10
 239   "The maximum number of candidates in the tooltip"
 240   :type 'integer)
 241
 242 (defcustom company-tooltip-minimum 6
 243   "The minimum height of the tooltip.
 244 If this many lines are not available, prefer to display the tooltip above."
 245   :type 'integer)
 246
 247 (defcustom company-tooltip-margin 1
 248   "Width of margin columns to show around the toolip."
 249   :type 'integer)
 250
 251 (defcustom company-tooltip-offset-display 'scrollbar
 252   "Method using which the tooltip displays scrolling position.
 253 `scrollbar' means draw a scrollbar to the right of the items.
 254 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 255   :type '(choice (const :tag "Scrollbar" scrollbar)
 256                  (const :tag "Two lines" lines)))
 257
 258 (defcustom company-tooltip-align-annotations nil
 259   "When non-nil, align annotations to the right tooltip border."
 260   :type 'boolean)
 261
 262 (defvar company-safe-backends
 263   '((company-abbrev . "Abbrev")
 264     (company-bbdb . "BBDB")
 265     (company-capf . "completion-at-point-functions")
 266     (company-clang . "Clang")
 267     (company-cmake . "CMake")
 268     (company-css . "CSS")
 269     (company-dabbrev . "dabbrev for plain text")
 270     (company-dabbrev-code . "dabbrev for code")
 271     (company-eclim . "Eclim (an Eclipse interface)")
 272     (company-elisp . "Emacs Lisp")
 273     (company-etags . "etags")
 274     (company-files . "Files")
 275     (company-gtags . "GNU Global")
 276     (company-ispell . "Ispell")
 277     (company-keywords . "Programming language keywords")
 278     (company-nxml . "nxml")
 279     (company-oddmuse . "Oddmuse")
 280     (company-pysmell . "PySmell")
 281     (company-ropemacs . "ropemacs")
 282     (company-semantic . "Semantic")
 283     (company-tempo . "Tempo templates")
 284     (company-xcode . "Xcode")))
 285 (put 'company-safe-backends 'risky-local-variable t)
 286
 287 (defun company-safe-backends-p (backends)
 288   (and (consp backends)
 289        (not (dolist (backend backends)
 290               (unless (if (consp backend)
 291                           (company-safe-backends-p backend)
 292                         (assq backend company-safe-backends))
 293                 (return t))))))
 294
 295 (defvar company--include-capf (version< "24.3.50" emacs-version))
 296
 297 (defcustom company-backends `(,@(unless company--include-capf
 298                                   (list 'company-elisp))
 299                               company-bbdb
 300                               company-nxml company-css
 301                               company-eclim company-semantic company-clang
 302                               company-xcode company-ropemacs company-cmake
 303                               ,@(when company--include-capf
 304                                   (list 'company-capf))
 305                               (company-dabbrev-code company-gtags company-etags
 306                                company-keywords)
 307                               company-oddmuse company-files company-dabbrev)
 308   "The list of active back-ends (completion engines).
 309
 310 `company-begin-backend' can be used to start a specific back-end,
 311 `company-other-backend' will skip to the next matching back-end in the list.
 312
 313 Each back-end is a function that takes a variable number of arguments.
 314 The first argument is the command requested from the back-end.  It is one
 315 of the following:
 316
 317 `prefix': The back-end should return the text to be completed.  It must be
 318 text immediately before point.  Returning nil passes control to the next
 319 back-end.  The function should return `stop' if it should complete but
 320 cannot \(e.g. if it is in the middle of a string\).  Instead of a string,
 321 the back-end may return a cons where car is the prefix and cdr is used in
 322 `company-minimum-prefix-length' test.  It must be either number or t, and
 323 in the latter case the test automatically succeeds.
 324
 325 `candidates': The second argument is the prefix to be completed.  The
 326 return value should be a list of candidates that match the prefix.
 327
 328 Non-prefix matches are also supported (candidates that don't start with the
 329 prefix, but match it in some backend-defined way).  Backends that use this
 330 feature must disable cache (return t to `no-cache') and should also respond
 331 to `match'.
 332
 333 Optional commands:
 334
 335 `sorted': Return t here to indicate that the candidates are sorted and will
 336 not need to be sorted again.
 337
 338 `duplicates': If non-nil, company will take care of removing duplicates
 339 from the list.
 340
 341 `no-cache': Usually company doesn't ask for candidates again as completion
 342 progresses, unless the back-end returns t for this command.  The second
 343 argument is the latest prefix.
 344
 345 `meta': The second argument is a completion candidate.  Return a (short)
 346 documentation string for it.
 347
 348 `doc-buffer': The second argument is a completion candidate.  Return a
 349 buffer with documentation for it.  Preferably use `company-doc-buffer',
 350
 351 `location': The second argument is a completion candidate.  Return the cons
 352 of buffer and buffer location, or of file and line number where the
 353 completion candidate was defined.
 354
 355 `annotation': The second argument is a completion candidate.  Return a
 356 string to be displayed inline with the candidate in the popup.  If
 357 duplicates are removed by company, candidates with equal string values will
 358 be kept if they have different annotations.  For that to work properly,
 359 backends should store the related information on candidates using text
 360 properties.
 361
 362 `match': The second argument is a completion candidate.  Backends that
 363 provide non-prefix completions should return the position of the end of
 364 text in the candidate that matches `prefix'.  It will be used when
 365 rendering the popup.
 366
 367 `require-match': If this returns t, the user is not allowed to enter
 368 anything not offered as a candidate.  Use with care!  The default value nil
 369 gives the user that choice with `company-require-match'.  Return value
 370 `never' overrides that option the other way around.
 371
 372 `init': Called once for each buffer. The back-end can check for external
 373 programs and files and load any required libraries.  Raising an error here
 374 will show up in message log once, and the back-end will not be used for
 375 completion.
 376
 377 `post-completion': Called after a completion candidate has been inserted
 378 into the buffer.  The second argument is the candidate.  Can be used to
 379 modify it, e.g. to expand a snippet.
 380
 381 The back-end should return nil for all commands it does not support or
 382 does not know about.  It should also be callable interactively and use
 383 `company-begin-backend' to start itself in that case.
 384
 385 Grouped back-ends:
 386
 387 An element of `company-backends' can also itself be a list of back-ends,
 388 then it's considered to be a \"grouped\" back-end.
 389
 390 When possible, commands taking a candidate as an argument are dispatched to
 391 the back-end it came from.  In other cases, the first non-nil value among
 392 all the back-ends is returned.
 393
 394 The latter is the case for the `prefix' command.  But if the group contains
 395 the keyword `:with', the back-ends after it are ignored for this command.
 396
 397 The completions from back-ends in a group are merged (but only from those
 398 that return the same `prefix').
 399
 400 Asynchronous back-ends:
 401
 402 The return value of each command can also be a cons (:async . FETCHER)
 403 where FETCHER is a function of one argument, CALLBACK.  When the data
 404 arrives, FETCHER must call CALLBACK and pass it the appropriate return
 405 value, as described above.
 406
 407 True asynchronous operation is only supported for command `candidates', and
 408 only during idle completion.  Other commands will block the user interface,
 409 even if the back-end uses the asynchronous calling convention."
 410   :type `(repeat
 411           (choice
 412            :tag "Back-end"
 413            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 414                      company-safe-backends)
 415            (symbol :tag "User defined")
 416            (repeat :tag "Merged Back-ends"
 417                    (choice :tag "Back-end"
 418                            ,@(mapcar (lambda (b)
 419                                        `(const :tag ,(cdr b) ,(car b)))
 420                                      company-safe-backends)
 421                            (const :tag "With" :with)
 422                            (symbol :tag "User defined"))))))
 423
 424 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 425
 426 (defcustom company-transformers nil
 427   "Functions to change the list of candidates received from backends,
 428 after sorting and removal of duplicates (if appropriate).
 429 Each function gets called with the return value of the previous one."
 430   :type '(choice
 431           (const :tag "None" nil)
 432           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 433           (repeat :tag "User defined" (function))))
 434
 435 (defcustom company-completion-started-hook nil
 436   "Hook run when company starts completing.
 437 The hook is called with one argument that is non-nil if the completion was
 438 started manually."
 439   :type 'hook)
 440
 441 (defcustom company-completion-cancelled-hook nil
 442   "Hook run when company cancels completing.
 443 The hook is called with one argument that is non-nil if the completion was
 444 aborted manually."
 445   :type 'hook)
 446
 447 (defcustom company-completion-finished-hook nil
 448   "Hook run when company successfully completes.
 449 The hook is called with the selected candidate as an argument.
 450
 451 If you indend to use it to post-process candidates from a specific
 452 back-end, consider using the `post-completion' command instead."
 453   :type 'hook)
 454
 455 (defcustom company-minimum-prefix-length 3
 456   "The minimum prefix length for idle completion."
 457   :type '(integer :tag "prefix length"))
 458
 459 (defcustom company-abort-manual-when-too-short nil
 460   "If enabled, cancel a manually started completion when the prefix gets
 461 shorter than both `company-minimum-prefix-length' and the length of the
 462 prefix it was started from."
 463   :type 'boolean)
 464
 465 (defcustom company-require-match 'company-explicit-action-p
 466   "If enabled, disallow non-matching input.
 467 This can be a function do determine if a match is required.
 468
 469 This can be overridden by the back-end, if it returns t or `never' to
 470 `require-match'.  `company-auto-complete' also takes precedence over this."
 471   :type '(choice (const :tag "Off" nil)
 472                  (function :tag "Predicate function")
 473                  (const :tag "On, if user interaction took place"
 474                         'company-explicit-action-p)
 475                  (const :tag "On" t)))
 476
 477 (defcustom company-auto-complete nil
 478   "Determines when to auto-complete.
 479 If this is enabled, all characters from `company-auto-complete-chars'
 480 trigger insertion of the selected completion candidate.
 481 This can also be a function."
 482   :type '(choice (const :tag "Off" nil)
 483                  (function :tag "Predicate function")
 484                  (const :tag "On, if user interaction took place"
 485                         'company-explicit-action-p)
 486                  (const :tag "On" t)))
 487
 488 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 489   "Determines which characters trigger auto-completion.
 490 See `company-auto-complete'.  If this is a string, each string character
 491 tiggers auto-completion.  If it is a list of syntax description characters (see
 492 `modify-syntax-entry'), all characters with that syntax auto-complete.
 493
 494 This can also be a function, which is called with the new input and should
 495 return non-nil if company should auto-complete.
 496
 497 A character that is part of a valid candidate never triggers auto-completion."
 498   :type '(choice (string :tag "Characters")
 499                  (set :tag "Syntax"
 500                       (const :tag "Whitespace" ?\ )
 501                       (const :tag "Symbol" ?_)
 502                       (const :tag "Opening parentheses" ?\()
 503                       (const :tag "Closing parentheses" ?\))
 504                       (const :tag "Word constituent" ?w)
 505                       (const :tag "Punctuation." ?.)
 506                       (const :tag "String quote." ?\")
 507                       (const :tag "Paired delimiter." ?$)
 508                       (const :tag "Expression quote or prefix operator." ?\')
 509                       (const :tag "Comment starter." ?<)
 510                       (const :tag "Comment ender." ?>)
 511                       (const :tag "Character-quote." ?/)
 512                       (const :tag "Generic string fence." ?|)
 513                       (const :tag "Generic comment fence." ?!))
 514                  (function :tag "Predicate function")))
 515
 516 (defcustom company-idle-delay .7
 517   "The idle delay in seconds until completion starts automatically.
 518 A value of nil means no idle completion, t means show candidates
 519 immediately when a prefix of `company-minimum-prefix-length' is reached."
 520   :type '(choice (const :tag "never (nil)" nil)
 521                  (const :tag "immediate (t)" t)
 522                  (number :tag "seconds")))
 523
 524 (defcustom company-begin-commands '(self-insert-command org-self-insert-command)
 525   "A list of commands after which idle completion is allowed.
 526 If this is t, it can show completions after any command.  See
 527 `company-idle-delay'.
 528
 529 Alternatively, any command with a non-nil `company-begin' property is
 530 treated as if it was on this list."
 531   :type '(choice (const :tag "Any command" t)
 532                  (const :tag "Self insert command" '(self-insert-command))
 533                  (repeat :tag "Commands" function)))
 534
 535 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 536                                            save-buffers-kill-terminal
 537                                            save-buffers-kill-emacs)
 538   "A list of commands that are allowed during completion.
 539 If this is t, or if `company-begin-commands' is t, any command is allowed.
 540 Otherwise, the value must be a list of symbols.  If it starts with `not',
 541 the cdr is the list of commands that abort completion.  Otherwise, all
 542 commands except those in that list, or in `company-begin-commands', or
 543 commands in the `company-' namespace, abort completion."
 544   :type '(choice (const :tag "Any command" t)
 545                  (cons  :tag "Any except"
 546                         (const not)
 547                         (repeat :tag "Commands" function))
 548                  (repeat :tag "Commands" function)))
 549
 550 (defcustom company-show-numbers nil
 551   "If enabled, show quick-access numbers for the first ten candidates."
 552   :type '(choice (const :tag "off" nil)
 553                  (const :tag "on" t)))
 554
 555 (defcustom company-selection-wrap-around nil
 556   "If enabled, selecting item before first or after last wraps around."
 557   :type '(choice (const :tag "off" nil)
 558                  (const :tag "on" t)))
 559
 560 (defvar company-end-of-buffer-workaround t
 561   "Work around a visualization bug when completing at the end of the buffer.
 562 The work-around consists of adding a newline.")
 563
 564 (defvar company-async-wait 0.03
 565   "Pause between checks to see if the value's been set when turning an
 566 asynchronous call into synchronous.")
 567
 568 (defvar company-async-timeout 2
 569   "Maximum wait time for a value to be set during asynchronous call.")
 570
 571 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 572
 573 (defvar company-mode-map (make-sparse-keymap)
 574   "Keymap used by `company-mode'.")
 575
 576 (defvar company-active-map
 577   (let ((keymap (make-sparse-keymap)))
 578     (define-key keymap "\e\e\e" 'company-abort)
 579     (define-key keymap "\C-g" 'company-abort)
 580     (define-key keymap (kbd "M-n") 'company-select-next)
 581     (define-key keymap (kbd "M-p") 'company-select-previous)
 582     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 583     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 584     (define-key keymap [down-mouse-1] 'ignore)
 585     (define-key keymap [down-mouse-3] 'ignore)
 586     (define-key keymap [mouse-1] 'company-complete-mouse)
 587     (define-key keymap [mouse-3] 'company-select-mouse)
 588     (define-key keymap [up-mouse-1] 'ignore)
 589     (define-key keymap [up-mouse-3] 'ignore)
 590     (define-key keymap [return] 'company-complete-selection)
 591     (define-key keymap (kbd "RET") 'company-complete-selection)
 592     (define-key keymap [tab] 'company-complete-common)
 593     (define-key keymap (kbd "TAB") 'company-complete-common)
 594     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 595     (define-key keymap "\C-w" 'company-show-location)
 596     (define-key keymap "\C-s" 'company-search-candidates)
 597     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 598     (dotimes (i 10)
 599       (define-key keymap (vector (+ (aref (kbd "M-0") 0) i))
 600         `(lambda () (interactive) (company-complete-number ,i))))
 601
 602     keymap)
 603   "Keymap that is enabled during an active completion.")
 604
 605 (defvar company--disabled-backends nil)
 606
 607 (defun company-init-backend (backend)
 608   (and (symbolp backend)
 609        (not (fboundp backend))
 610        (ignore-errors (require backend nil t)))
 611   (cond
 612    ((symbolp backend)
 613     (condition-case err
 614         (progn
 615           (funcall backend 'init)
 616           (put backend 'company-init t))
 617       (error
 618        (put backend 'company-init 'failed)
 619        (unless (memq backend company--disabled-backends)
 620          (message "Company back-end '%s' could not be initialized:\n%s"
 621                   backend (error-message-string err)))
 622        (pushnew backend company--disabled-backends)
 623        nil)))
 624    ;; No initialization for lambdas.
 625    ((functionp backend) t)
 626    (t ;; Must be a list.
 627     (dolist (b backend)
 628       (unless (keywordp b)
 629         (company-init-backend b))))))
 630
 631 (defvar company-default-lighter " company")
 632
 633 (defvar company-lighter company-default-lighter)
 634 (make-variable-buffer-local 'company-lighter)
 635
 636 ;;;###autoload
 637 (define-minor-mode company-mode
 638   "\"complete anything\"; is an in-buffer completion framework.
 639 Completion starts automatically, depending on the values
 640 `company-idle-delay' and `company-minimum-prefix-length'.
 641
 642 Completion can be controlled with the commands:
 643 `company-complete-common', `company-complete-selection', `company-complete',
 644 `company-select-next', `company-select-previous'.  If these commands are
 645 called before `company-idle-delay', completion will also start.
 646
 647 Completions can be searched with `company-search-candidates' or
 648 `company-filter-candidates'.  These can be used while completion is
 649 inactive, as well.
 650
 651 The completion data is retrieved using `company-backends' and displayed
 652 using `company-frontends'.  If you want to start a specific back-end, call
 653 it interactively or use `company-begin-backend'.
 654
 655 regular keymap (`company-mode-map'):
 656
 657 \\{company-mode-map}
 658 keymap during active completions (`company-active-map'):
 659
 660 \\{company-active-map}"
 661   nil company-lighter company-mode-map
 662   (if company-mode
 663       (progn
 664         (add-hook 'pre-command-hook 'company-pre-command nil t)
 665         (add-hook 'post-command-hook 'company-post-command nil t)
 666         (mapc 'company-init-backend company-backends))
 667     (remove-hook 'pre-command-hook 'company-pre-command t)
 668     (remove-hook 'post-command-hook 'company-post-command t)
 669     (company-cancel)
 670     (kill-local-variable 'company-point)))
 671
 672 (defcustom company-global-modes t
 673   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 674 If nil, means no modes.  If t, then all major modes have it turned on.
 675 If a list, it should be a list of `major-mode' symbol names for which
 676 `company-mode' should be automatically turned on.  The sense of the list is
 677 negated if it begins with `not'.  For example:
 678  (c-mode c++-mode)
 679 means that `company-mode' is turned on for buffers in C and C++ modes only.
 680  (not message-mode)
 681 means that `company-mode' is always turned on except in `message-mode' buffers."
 682   :type '(choice (const :tag "none" nil)
 683                  (const :tag "all" t)
 684                  (set :menu-tag "mode specific" :tag "modes"
 685                       :value (not)
 686                       (const :tag "Except" not)
 687                       (repeat :inline t (symbol :tag "mode")))))
 688
 689 ;;;###autoload
 690 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 691
 692 (defun company-mode-on ()
 693   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 694              (cond ((eq company-global-modes t)
 695                     t)
 696                    ((eq (car-safe company-global-modes) 'not)
 697                     (not (memq major-mode (cdr company-global-modes))))
 698                    (t (memq major-mode company-global-modes))))
 699     (company-mode 1)))
 700
 701 (defsubst company-assert-enabled ()
 702   (unless company-mode
 703     (company-uninstall-map)
 704     (error "Company not enabled")))
 705
 706 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 707
 708 (defvar company-my-keymap nil)
 709 (make-variable-buffer-local 'company-my-keymap)
 710
 711 (defvar company-emulation-alist '((t . nil)))
 712
 713 (defsubst company-enable-overriding-keymap (keymap)
 714   (company-uninstall-map)
 715   (setq company-my-keymap keymap))
 716
 717 (defun company-ensure-emulation-alist ()
 718   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 719     (setq emulation-mode-map-alists
 720           (cons 'company-emulation-alist
 721                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 722
 723 (defun company-install-map ()
 724   (unless (or (cdar company-emulation-alist)
 725               (null company-my-keymap))
 726     (setf (cdar company-emulation-alist) company-my-keymap)))
 727
 728 (defun company-uninstall-map ()
 729   (setf (cdar company-emulation-alist) nil))
 730
 731 ;; Hack:
 732 ;; Emacs calculates the active keymaps before reading the event.  That means we
 733 ;; cannot change the keymap from a timer.  So we send a bogus command.
 734 ;; XXX: Seems not to be needed anymore in Emacs 24.4
 735 (defun company-ignore ()
 736   (interactive)
 737   (setq this-command last-command))
 738
 739 (global-set-key '[31415926] 'company-ignore)
 740
 741 (defun company-input-noop ()
 742   (push 31415926 unread-command-events))
 743
 744 (defun company--column (&optional pos)
 745   (save-excursion
 746     (when pos (goto-char pos))
 747     (save-restriction
 748       (+ (save-excursion
 749            (vertical-motion 0)
 750            (narrow-to-region (point) (point-max))
 751            (let ((prefix (get-text-property (point) 'line-prefix)))
 752              (if prefix (length prefix) 0)))
 753          (current-column)))))
 754
 755 (defun company--row (&optional pos)
 756   (save-excursion
 757     (when pos (goto-char pos))
 758     (count-screen-lines (window-start)
 759                         (progn (vertical-motion 0) (point)))))
 760
 761 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 762
 763 (defvar company-backend nil)
 764 (make-variable-buffer-local 'company-backend)
 765
 766 (defun company-grab (regexp &optional expression limit)
 767   (when (looking-back regexp limit)
 768     (or (match-string-no-properties (or expression 0)) "")))
 769
 770 (defun company-grab-line (regexp &optional expression)
 771   (company-grab regexp expression (point-at-bol)))
 772
 773 (defun company-grab-symbol ()
 774   (if (looking-at "\\_>")
 775       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 776                                                 (point)))
 777     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 778       "")))
 779
 780 (defun company-grab-word ()
 781   (if (looking-at "\\>")
 782       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 783                                                 (point)))
 784     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 785       "")))
 786
 787 (defun company-in-string-or-comment ()
 788   (let ((ppss (syntax-ppss)))
 789     (or (car (setq ppss (nthcdr 3 ppss)))
 790         (car (setq ppss (cdr ppss)))
 791         (nth 3 ppss))))
 792
 793 (defun company-call-backend (&rest args)
 794   (let ((val (apply #'company-call-backend-raw args)))
 795     (company--force-sync val company-backend args)))
 796
 797 (defun company--force-sync (value backend args)
 798   (if (not (eq (car-safe value) :async))
 799       value
 800     (let ((res 'trash)
 801           (start (time-to-seconds)))
 802       (funcall (cdr value)
 803                (lambda (result) (setq res result)))
 804       (while (eq res 'trash)
 805         (if (> (- (time-to-seconds) start) company-async-timeout)
 806             (error "Company: Back-end %s async timeout with args %s"
 807                    backend args)
 808           (sleep-for company-async-wait)))
 809       res)))
 810
 811 (defun company-call-backend-raw (&rest args)
 812   (condition-case err
 813       (if (functionp company-backend)
 814           (apply company-backend args)
 815         (apply #'company--multi-backend-adapter company-backend args))
 816     (error (error "Company: Back-end %s error \"%s\" with args %s"
 817                   company-backend (error-message-string err) args))))
 818
 819 (defun company--multi-backend-adapter (backends command &rest args)
 820   (let ((backends (loop for b in backends
 821                         when (not (and (symbolp b)
 822                                        (eq 'failed (get b 'company-init))))
 823                         collect b)))
 824     (setq backends
 825           (if (eq command 'prefix)
 826               (butlast backends (length (member :with backends)))
 827             (delq :with backends)))
 828     (pcase command
 829       (`candidates
 830        (company--multi-backend-adapter-candidates backends (car args)))
 831       (`sorted nil)
 832       (`duplicates t)
 833       ((or `prefix `ignore-case `no-cache `require-match)
 834        (let (value)
 835          (dolist (backend backends)
 836            (when (setq value (company--force-sync
 837                               (apply backend command args)
 838                               backend (cons command args)))
 839              (return value)))))
 840       (_
 841        (let ((arg (car args)))
 842          (when (> (length arg) 0)
 843            (let ((backend (or (get-text-property 0 'company-backend arg)
 844                               (car backends))))
 845              (apply backend command args))))))))
 846
 847 (defun company--multi-backend-adapter-candidates (backends prefix)
 848   (let ((pairs (loop for backend in (cdr backends)
 849                      when (equal (funcall backend 'prefix)
 850                                  prefix)
 851                      collect (cons (funcall backend 'candidates prefix)
 852                                    (lambda (candidates)
 853                                      (mapcar
 854                                       (lambda (str)
 855                                         (propertize str 'company-backend
 856                                                     backend))
 857                                       candidates))))))
 858     (when (equal (funcall (car backends) 'prefix) prefix)
 859       ;; Small perf optimization: don't tag the candidates received
 860       ;; from the first backend in the group.
 861       (push (cons (funcall (car backends) 'candidates prefix)
 862                   'identity)
 863             pairs))
 864     (company--merge-async pairs (lambda (values) (apply #'append values)))))
 865
 866 (defun company--merge-async (pairs merger)
 867   (let ((async (loop for pair in pairs
 868                      thereis
 869                      (eq :async (car-safe (car pair))))))
 870     (if (not async)
 871         (funcall merger (loop for (val . mapper) in pairs
 872                               collect (funcall mapper val)))
 873       (cons
 874        :async
 875        (lambda (callback)
 876          (let* (lst pending
 877                 (finisher (lambda ()
 878                             (unless pending
 879                               (funcall callback
 880                                        (funcall merger
 881                                                 (nreverse lst)))))))
 882            (dolist (pair pairs)
 883              (let ((val (car pair))
 884                    (mapper (cdr pair)))
 885                (if (not (eq :async (car-safe val)))
 886                    (push (funcall mapper val) lst)
 887                  (push nil lst)
 888                  (let ((cell lst)
 889                        (fetcher (cdr val)))
 890                    (push fetcher pending)
 891                    (funcall fetcher
 892                             (lambda (res)
 893                               (setq pending (delq fetcher pending))
 894                               (setcar cell (funcall mapper res))
 895                               (funcall finisher)))))))))))))
 896
 897 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 898
 899 (defvar company-prefix nil)
 900 (make-variable-buffer-local 'company-prefix)
 901
 902 (defvar company-candidates nil)
 903 (make-variable-buffer-local 'company-candidates)
 904
 905 (defvar company-candidates-length nil)
 906 (make-variable-buffer-local 'company-candidates-length)
 907
 908 (defvar company-candidates-cache nil)
 909 (make-variable-buffer-local 'company-candidates-cache)
 910
 911 (defvar company-candidates-predicate nil)
 912 (make-variable-buffer-local 'company-candidates-predicate)
 913
 914 (defvar company-common nil)
 915 (make-variable-buffer-local 'company-common)
 916
 917 (defvar company-selection 0)
 918 (make-variable-buffer-local 'company-selection)
 919
 920 (defvar company-selection-changed nil)
 921 (make-variable-buffer-local 'company-selection-changed)
 922
 923 (defvar company--manual-action nil
 924   "Non-nil, if manual completion took place.")
 925 (make-variable-buffer-local 'company--manual-action)
 926
 927 (defvar company--manual-prefix nil)
 928 (make-variable-buffer-local 'company--manual-prefix)
 929
 930 (defvar company--auto-completion nil
 931   "Non-nil when current candidate is being inserted automatically.
 932 Controlled by `company-auto-complete'.")
 933
 934 (defvar company--point-max nil)
 935 (make-variable-buffer-local 'company--point-max)
 936
 937 (defvar company-point nil)
 938 (make-variable-buffer-local 'company-point)
 939
 940 (defvar company-timer nil)
 941
 942 (defvar company-added-newline nil)
 943 (make-variable-buffer-local 'company-added-newline)
 944
 945 (defsubst company-strip-prefix (str)
 946   (substring str (length company-prefix)))
 947
 948 (defun company--insert-candidate (candidate)
 949   (setq candidate (substring-no-properties candidate))
 950   ;; XXX: Return value we check here is subject to change.
 951   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 952       (insert (company-strip-prefix candidate))
 953     (delete-region (- (point) (length company-prefix)) (point))
 954     (insert candidate)))
 955
 956 (defmacro company-with-candidate-inserted (candidate &rest body)
 957   "Evaluate BODY with CANDIDATE temporarily inserted.
 958 This is a tool for back-ends that need candidates inserted before they
 959 can retrieve meta-data for them."
 960   (declare (indent 1))
 961   `(let ((inhibit-modification-hooks t)
 962          (inhibit-point-motion-hooks t)
 963          (modified-p (buffer-modified-p)))
 964      (company--insert-candidate ,candidate)
 965      (unwind-protect
 966          (progn ,@body)
 967        (delete-region company-point (point)))))
 968
 969 (defun company-explicit-action-p ()
 970   "Return whether explicit completion action was taken by the user."
 971   (or company--manual-action
 972       company-selection-changed))
 973
 974 (defun company-reformat (candidate)
 975   ;; company-ispell needs this, because the results are always lower-case
 976   ;; It's mory efficient to fix it only when they are displayed.
 977   ;; FIXME: Adopt the current text's capitalization instead?
 978   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 979       (concat company-prefix (substring candidate (length company-prefix)))
 980     candidate))
 981
 982 (defun company--should-complete ()
 983   (and (not (or buffer-read-only overriding-terminal-local-map
 984                 overriding-local-map))
 985        ;; Check if in the middle of entering a key combination.
 986        (or (equal (this-command-keys-vector) [])
 987            (not (keymapp (key-binding (this-command-keys-vector)))))
 988        (eq company-idle-delay t)
 989        (or (eq t company-begin-commands)
 990            (memq this-command company-begin-commands)
 991            (and (symbolp this-command) (get this-command 'company-begin)))
 992        (not (and transient-mark-mode mark-active))))
 993
 994 (defun company--should-continue ()
 995   (or (eq t company-begin-commands)
 996       (eq t company-continue-commands)
 997       (if (eq 'not (car company-continue-commands))
 998           (not (memq this-command (cdr company-continue-commands)))
 999         (or (memq this-command company-begin-commands)
1000             (memq this-command company-continue-commands)
1001             (string-match-p "\\`company-" (symbol-name this-command))))))
1002
1003 (defun company-call-frontends (command)
1004   (dolist (frontend company-frontends)
1005     (condition-case err
1006         (funcall frontend command)
1007       (error (error "Company: Front-end %s error \"%s\" on command %s"
1008                     frontend (error-message-string err) command)))))
1009
1010 (defun company-set-selection (selection &optional force-update)
1011   (setq selection
1012         (if company-selection-wrap-around
1013             (mod selection company-candidates-length)
1014           (max 0 (min (1- company-candidates-length) selection))))
1015   (when (or force-update (not (equal selection company-selection)))
1016     (setq company-selection selection
1017           company-selection-changed t)
1018     (company-call-frontends 'update)))
1019
1020 (defun company-apply-predicate (candidates predicate)
1021   (let (new)
1022     (dolist (c candidates)
1023       (when (funcall predicate c)
1024         (push c new)))
1025     (nreverse new)))
1026
1027 (defun company-update-candidates (candidates)
1028   (setq company-candidates-length (length candidates))
1029   (if (> company-selection 0)
1030       ;; Try to restore the selection
1031       (let ((selected (nth company-selection company-candidates)))
1032         (setq company-selection 0
1033               company-candidates candidates)
1034         (when selected
1035           (while (and candidates (string< (pop candidates) selected))
1036             (incf company-selection))
1037           (unless candidates
1038             ;; Make sure selection isn't out of bounds.
1039             (setq company-selection (min (1- company-candidates-length)
1040                                          company-selection)))))
1041     (setq company-selection 0
1042           company-candidates candidates))
1043   ;; Save in cache:
1044   (push (cons company-prefix company-candidates) company-candidates-cache)
1045   ;; Calculate common.
1046   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
1047     ;; We want to support non-prefix completion, so filtering is the
1048     ;; responsibility of each respective backend, not ours.
1049     ;; On the other hand, we don't want to replace non-prefix input in
1050     ;; `company-complete-common'.
1051     (setq company-common
1052           (if (cdr company-candidates)
1053               (let ((common (try-completion company-prefix company-candidates)))
1054                 (if (eq common t)
1055                     ;; Mulple equal strings, probably with different
1056                     ;; annotations.
1057                     company-prefix
1058                   common))
1059             (car company-candidates)))))
1060
1061 (defun company-calculate-candidates (prefix)
1062   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
1063         (ignore-case (company-call-backend 'ignore-case)))
1064     (or candidates
1065         (when company-candidates-cache
1066           (let ((len (length prefix))
1067                 (completion-ignore-case ignore-case)
1068                 prev)
1069             (dotimes (i (1+ len))
1070               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1071                                            company-candidates-cache)))
1072                 (setq candidates (all-completions prefix prev))
1073                 (return t)))))
1074         ;; no cache match, call back-end
1075         (setq candidates
1076               (company--process-candidates
1077                (company--fetch-candidates prefix))))
1078     (setq candidates (company--transform-candidates candidates))
1079     (when candidates
1080       (if (or (cdr candidates)
1081               (not (eq t (compare-strings (car candidates) nil nil
1082                                           prefix nil nil ignore-case))))
1083           candidates
1084         ;; Already completed and unique; don't start.
1085         t))))
1086
1087 (defun company--fetch-candidates (prefix)
1088   (let ((c (if company--manual-action
1089                (company-call-backend 'candidates prefix)
1090              (company-call-backend-raw 'candidates prefix)))
1091         res)
1092     (if (not (eq (car c) :async))
1093         c
1094       (let ((buf (current-buffer))
1095             (win (selected-window))
1096             (tick (buffer-chars-modified-tick))
1097             (pt (point))
1098             (backend company-backend))
1099         (funcall
1100          (cdr c)
1101          (lambda (candidates)
1102            (if (not (and candidates (eq res 'done)))
1103                ;; Fetcher called us right back.
1104                (setq res candidates)
1105              (setq company-backend backend
1106                    company-candidates-cache
1107                    (list (cons prefix
1108                                (company--process-candidates
1109                                 candidates))))
1110              (company-idle-begin buf win tick pt)))))
1111       ;; FIXME: Relying on the fact that the callers
1112       ;; will interpret nil as "do nothing" is shaky.
1113       ;; A throw-catch would be one possible improvement.
1114       (or res
1115           (progn (setq res 'done) nil)))))
1116
1117 (defun company--process-candidates (candidates)
1118   (when company-candidates-predicate
1119     (setq candidates
1120           (company-apply-predicate candidates
1121                                    company-candidates-predicate)))
1122   (unless (company-call-backend 'sorted)
1123     (setq candidates (sort candidates 'string<)))
1124   (when (company-call-backend 'duplicates)
1125     (company--strip-duplicates candidates))
1126   candidates)
1127
1128 (defun company--strip-duplicates (candidates)
1129   (let ((c2 candidates))
1130     (while c2
1131       (setcdr c2
1132               (let ((str (car c2))
1133                     (anno 'unk))
1134                 (pop c2)
1135                 (while (let ((str2 (car c2)))
1136                          (if (not (equal str str2))
1137                              nil
1138                            (when (eq anno 'unk)
1139                              (setq anno (company-call-backend
1140                                          'annotation str)))
1141                            (equal anno
1142                                   (company-call-backend
1143                                    'annotation str2))))
1144                   (pop c2))
1145                 c2)))))
1146
1147 (defun company--transform-candidates (candidates)
1148   (let ((c candidates))
1149     (dolist (tr company-transformers)
1150       (setq c (funcall tr c)))
1151     c))
1152
1153 (defun company-sort-by-occurrence (candidates)
1154   "Sort CANDIDATES according to their occurrences.
1155 Searches for each in the currently visible part of the current buffer and
1156 gives priority to the closest ones above point, then closest ones below
1157 point. The rest of the list is appended unchanged.
1158 Keywords and function definition names are ignored."
1159   (let* (occurs
1160          (noccurs
1161           (delete-if
1162            (lambda (candidate)
1163              (when (or
1164                     (save-excursion
1165                       (progn (forward-line 0)
1166                              (search-backward candidate (window-start) t)))
1167                     (save-excursion
1168                       (search-forward candidate (window-end) t)))
1169                (let ((beg (match-beginning 0))
1170                      (end (match-end 0)))
1171                  (when (save-excursion
1172                          (goto-char end)
1173                          (and (not (memq (get-text-property (point) 'face)
1174                                          '(font-lock-function-name-face
1175                                            font-lock-keyword-face)))
1176                               (let* ((prefix (company-call-backend 'prefix))
1177                                      (prefix (or (car-safe prefix) prefix)))
1178                                 (and (stringp prefix)
1179                                      (= (length prefix) (- end beg))))))
1180                    (push (cons candidate (if (< beg (point))
1181                                              (- (point) end)
1182                                            (- beg (window-start))))
1183                          occurs)
1184                    t))))
1185            candidates)))
1186     (nconc
1187      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1188      noccurs)))
1189
1190 (defun company-idle-begin (buf win tick pos)
1191   (and (eq buf (current-buffer))
1192        (eq win (selected-window))
1193        (eq tick (buffer-chars-modified-tick))
1194        (eq pos (point))
1195        (when (company-auto-begin)
1196          (when (version< emacs-version "24.3.50")
1197            (company-input-noop))
1198          (company-post-command))))
1199
1200 (defun company-auto-begin ()
1201   (and company-mode
1202        (not company-candidates)
1203        (let ((company-idle-delay t)
1204              (company-begin-commands t))
1205          (condition-case-unless-debug err
1206              (company-begin)
1207            (error (message "Company: An error occurred in auto-begin")
1208                   (message "%s" (error-message-string err))
1209                   (company-cancel))
1210            (quit (company-cancel)))))
1211   (unless company-candidates
1212     (setq company-backend nil))
1213   ;; Return non-nil if active.
1214   company-candidates)
1215
1216 (defun company-manual-begin ()
1217   (interactive)
1218   (company-assert-enabled)
1219   (setq company--manual-action t)
1220   (unwind-protect
1221       (let ((company-minimum-prefix-length 0))
1222         (company-auto-begin))
1223     (unless company-candidates
1224       (setq company--manual-action nil))))
1225
1226 (defun company-other-backend (&optional backward)
1227   (interactive (list current-prefix-arg))
1228   (company-assert-enabled)
1229   (if company-backend
1230       (let* ((after (cdr (member company-backend company-backends)))
1231              (before (cdr (member company-backend (reverse company-backends))))
1232              (next (if backward
1233                        (append before (reverse after))
1234                      (append after (reverse before)))))
1235         (company-cancel)
1236         (dolist (backend next)
1237           (when (ignore-errors (company-begin-backend backend))
1238             (return t))))
1239     (company-manual-begin))
1240   (unless company-candidates
1241     (error "No other back-end")))
1242
1243 (defun company-require-match-p ()
1244   (let ((backend-value (company-call-backend 'require-match)))
1245     (or (eq backend-value t)
1246         (and (not (eq backend-value 'never))
1247              (if (functionp company-require-match)
1248                  (funcall company-require-match)
1249                (eq company-require-match t))))))
1250
1251 (defun company-auto-complete-p (input)
1252   "Return non-nil, if input starts with punctuation or parentheses."
1253   (and (if (functionp company-auto-complete)
1254            (funcall company-auto-complete)
1255          company-auto-complete)
1256        (if (functionp company-auto-complete-chars)
1257            (funcall company-auto-complete-chars input)
1258          (if (consp company-auto-complete-chars)
1259              (memq (char-syntax (string-to-char input))
1260                    company-auto-complete-chars)
1261            (string-match (substring input 0 1) company-auto-complete-chars)))))
1262
1263 (defun company--incremental-p ()
1264   (and (> (point) company-point)
1265        (> (point-max) company--point-max)
1266        (not (eq this-command 'backward-delete-char-untabify))
1267        (equal (buffer-substring (- company-point (length company-prefix))
1268                                 company-point)
1269               company-prefix)))
1270
1271 (defun company--continue-failed ()
1272   (let ((input (buffer-substring-no-properties (point) company-point)))
1273     (cond
1274      ((company-auto-complete-p input)
1275       ;; auto-complete
1276       (save-excursion
1277         (goto-char company-point)
1278         (let ((company--auto-completion t))
1279           (company-complete-selection))
1280         nil))
1281      ((company-require-match-p)
1282       ;; wrong incremental input, but required match
1283       (delete-char (- (length input)))
1284       (ding)
1285       (message "Matching input is required")
1286       company-candidates)
1287      ((equal company-prefix (car company-candidates))
1288       ;; last input was actually success
1289       (company-cancel company-prefix))
1290      (t (company-cancel)))))
1291
1292 (defun company--good-prefix-p (prefix)
1293   (and (stringp (or (car-safe prefix) prefix)) ;excludes 'stop
1294        (or (eq (cdr-safe prefix) t)
1295            (let ((len (or (cdr-safe prefix) (length prefix))))
1296              (if company--manual-prefix
1297                  (or (not company-abort-manual-when-too-short)
1298                      ;; Must not be less than minimum or initial length.
1299                      (>= len (min company-minimum-prefix-length
1300                                   (length company--manual-prefix))))
1301                (>= len company-minimum-prefix-length))))))
1302
1303 (defun company--continue ()
1304   (when (company-call-backend 'no-cache company-prefix)
1305     ;; Don't complete existing candidates, fetch new ones.
1306     (setq company-candidates-cache nil))
1307   (let* ((new-prefix (company-call-backend 'prefix))
1308          (c (when (and (company--good-prefix-p new-prefix)
1309                        (setq new-prefix (or (car-safe new-prefix) new-prefix))
1310                        (= (- (point) (length new-prefix))
1311                           (- company-point (length company-prefix))))
1312               (company-calculate-candidates new-prefix))))
1313     (cond
1314      ((eq c t)
1315       ;; t means complete/unique.
1316       (company-cancel new-prefix))
1317      ((consp c)
1318       ;; incremental match
1319       (setq company-prefix new-prefix)
1320       (company-update-candidates c)
1321       c)
1322      ((not (company--incremental-p))
1323       (company-cancel))
1324      (t (company--continue-failed)))))
1325
1326 (defun company--begin-new ()
1327   (let (prefix c)
1328     (dolist (backend (if company-backend
1329                          ;; prefer manual override
1330                          (list company-backend)
1331                        company-backends))
1332       (setq prefix
1333             (if (or (symbolp backend)
1334                     (functionp backend))
1335                 (when (or (not (symbolp backend))
1336                           (eq t (get backend 'company-init))
1337                           (unless (get backend 'company-init)
1338                             (company-init-backend backend)))
1339                   (funcall backend 'prefix))
1340               (company--multi-backend-adapter backend 'prefix)))
1341       (when prefix
1342         (when (company--good-prefix-p prefix)
1343           (setq prefix (or (car-safe prefix) prefix)
1344                 company-backend backend
1345                 c (company-calculate-candidates prefix))
1346           ;; t means complete/unique.  We don't start, so no hooks.
1347           (if (not (consp c))
1348               (when company--manual-action
1349                 (message "No completion found"))
1350             (setq company-prefix prefix)
1351             (when company--manual-action
1352               (setq company--manual-prefix prefix))
1353             (when (symbolp backend)
1354               (setq company-lighter (concat " " (symbol-name backend))))
1355             (company-update-candidates c)
1356             (run-hook-with-args 'company-completion-started-hook
1357                                 (company-explicit-action-p))
1358             (company-call-frontends 'show)))
1359         (return c)))))
1360
1361 (defun company-begin ()
1362   (or (and company-candidates (company--continue))
1363       (and (company--should-complete) (company--begin-new)))
1364   (when company-candidates
1365     (let ((modified (buffer-modified-p)))
1366       (when (and company-end-of-buffer-workaround (eobp))
1367         (save-excursion (insert "\n"))
1368         (setq company-added-newline
1369               (or modified (buffer-chars-modified-tick)))))
1370     (setq company-point (point)
1371           company--point-max (point-max))
1372     (company-ensure-emulation-alist)
1373     (company-enable-overriding-keymap company-active-map)
1374     (company-call-frontends 'update)))
1375
1376 (defun company-cancel (&optional result)
1377   (and company-added-newline
1378        (> (point-max) (point-min))
1379        (let ((tick (buffer-chars-modified-tick)))
1380          (delete-region (1- (point-max)) (point-max))
1381          (equal tick company-added-newline))
1382        ;; Only set unmodified when tick remained the same since insert,
1383        ;; and the buffer wasn't modified before.
1384        (set-buffer-modified-p nil))
1385   (when company-prefix
1386     (if (stringp result)
1387         (progn
1388           (company-call-backend 'pre-completion result)
1389           (run-hook-with-args 'company-completion-finished-hook result)
1390           (company-call-backend 'post-completion result))
1391       (run-hook-with-args 'company-completion-cancelled-hook result)))
1392   (setq company-added-newline nil
1393         company-backend nil
1394         company-prefix nil
1395         company-candidates nil
1396         company-candidates-length nil
1397         company-candidates-cache nil
1398         company-candidates-predicate nil
1399         company-common nil
1400         company-selection 0
1401         company-selection-changed nil
1402         company--manual-action nil
1403         company--manual-prefix nil
1404         company-lighter company-default-lighter
1405         company--point-max nil
1406         company-point nil)
1407   (when company-timer
1408     (cancel-timer company-timer))
1409   (company-search-mode 0)
1410   (company-call-frontends 'hide)
1411   (company-enable-overriding-keymap nil)
1412   ;; Make return value explicit.
1413   nil)
1414
1415 (defun company-abort ()
1416   (interactive)
1417   (company-cancel t)
1418   ;; Don't start again, unless started manually.
1419   (setq company-point (point)))
1420
1421 (defun company-finish (result)
1422   (company--insert-candidate result)
1423   (company-cancel result)
1424   ;; Don't start again, unless started manually.
1425   (setq company-point (point)))
1426
1427 (defsubst company-keep (command)
1428   (and (symbolp command) (get command 'company-keep)))
1429
1430 (defun company-pre-command ()
1431   (unless (company-keep this-command)
1432     (condition-case err
1433         (when company-candidates
1434           (company-call-frontends 'pre-command)
1435           (unless (company--should-continue)
1436             (company-abort)))
1437       (error (message "Company: An error occurred in pre-command")
1438              (message "%s" (error-message-string err))
1439              (company-cancel))))
1440   (when company-timer
1441     (cancel-timer company-timer)
1442     (setq company-timer nil))
1443   (company-uninstall-map))
1444
1445 (defun company-post-command ()
1446   (unless (company-keep this-command)
1447     (condition-case err
1448         (progn
1449           (unless (equal (point) company-point)
1450             (company-begin))
1451           (if company-candidates
1452               (company-call-frontends 'post-command)
1453             (and (numberp company-idle-delay)
1454                  (or (eq t company-begin-commands)
1455                      (memq this-command company-begin-commands))
1456                  (not (equal (point) company-point))
1457                  (setq company-timer
1458                        (run-with-timer company-idle-delay nil
1459                                        'company-idle-begin
1460                                        (current-buffer) (selected-window)
1461                                        (buffer-chars-modified-tick) (point))))))
1462       (error (message "Company: An error occurred in post-command")
1463              (message "%s" (error-message-string err))
1464              (company-cancel))))
1465   (company-install-map))
1466
1467 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1468
1469 (defvar company-search-string nil)
1470 (make-variable-buffer-local 'company-search-string)
1471
1472 (defvar company-search-lighter " Search: \"\"")
1473 (make-variable-buffer-local 'company-search-lighter)
1474
1475 (defvar company-search-old-map nil)
1476 (make-variable-buffer-local 'company-search-old-map)
1477
1478 (defvar company-search-old-selection 0)
1479 (make-variable-buffer-local 'company-search-old-selection)
1480
1481 (defun company-search (text lines)
1482   (let ((quoted (regexp-quote text))
1483         (i 0))
1484     (dolist (line lines)
1485       (when (string-match quoted line (length company-prefix))
1486         (return i))
1487       (incf i))))
1488
1489 (defun company-search-printing-char ()
1490   (interactive)
1491   (company-search-assert-enabled)
1492   (setq company-search-string
1493         (concat (or company-search-string "") (string last-command-event))
1494         company-search-lighter (concat " Search: \"" company-search-string
1495                                         "\""))
1496   (let ((pos (company-search company-search-string
1497                               (nthcdr company-selection company-candidates))))
1498     (if (null pos)
1499         (ding)
1500       (company-set-selection (+ company-selection pos) t))))
1501
1502 (defun company-search-repeat-forward ()
1503   "Repeat the incremental search in completion candidates forward."
1504   (interactive)
1505   (company-search-assert-enabled)
1506   (let ((pos (company-search company-search-string
1507                               (cdr (nthcdr company-selection
1508                                            company-candidates)))))
1509     (if (null pos)
1510         (ding)
1511       (company-set-selection (+ company-selection pos 1) t))))
1512
1513 (defun company-search-repeat-backward ()
1514   "Repeat the incremental search in completion candidates backwards."
1515   (interactive)
1516   (company-search-assert-enabled)
1517   (let ((pos (company-search company-search-string
1518                               (nthcdr (- company-candidates-length
1519                                          company-selection)
1520                                       (reverse company-candidates)))))
1521     (if (null pos)
1522         (ding)
1523       (company-set-selection (- company-selection pos 1) t))))
1524
1525 (defun company-create-match-predicate ()
1526   (setq company-candidates-predicate
1527         `(lambda (candidate)
1528            ,(if company-candidates-predicate
1529                 `(and (string-match ,company-search-string candidate)
1530                       (funcall ,company-candidates-predicate
1531                                candidate))
1532               `(string-match ,company-search-string candidate))))
1533   (company-update-candidates
1534    (company-apply-predicate company-candidates company-candidates-predicate))
1535   ;; Invalidate cache.
1536   (setq company-candidates-cache (cons company-prefix company-candidates)))
1537
1538 (defun company-filter-printing-char ()
1539   (interactive)
1540   (company-search-assert-enabled)
1541   (company-search-printing-char)
1542   (company-create-match-predicate)
1543   (company-call-frontends 'update))
1544
1545 (defun company-search-kill-others ()
1546   "Limit the completion candidates to the ones matching the search string."
1547   (interactive)
1548   (company-search-assert-enabled)
1549   (company-create-match-predicate)
1550   (company-search-mode 0)
1551   (company-call-frontends 'update))
1552
1553 (defun company-search-abort ()
1554   "Abort searching the completion candidates."
1555   (interactive)
1556   (company-search-assert-enabled)
1557   (company-set-selection company-search-old-selection t)
1558   (company-search-mode 0))
1559
1560 (defun company-search-other-char ()
1561   (interactive)
1562   (company-search-assert-enabled)
1563   (company-search-mode 0)
1564   (company--unread-last-input))
1565
1566 (defvar company-search-map
1567   (let ((i 0)
1568         (keymap (make-keymap)))
1569     (if (fboundp 'max-char)
1570         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1571                               'company-search-printing-char)
1572       (with-no-warnings
1573         ;; obsolete in Emacs 23
1574         (let ((l (generic-character-list))
1575               (table (nth 1 keymap)))
1576           (while l
1577             (set-char-table-default table (car l) 'company-search-printing-char)
1578             (setq l (cdr l))))))
1579     (define-key keymap [t] 'company-search-other-char)
1580     (while (< i ?\s)
1581       (define-key keymap (make-string 1 i) 'company-search-other-char)
1582       (incf i))
1583     (while (< i 256)
1584       (define-key keymap (vector i) 'company-search-printing-char)
1585       (incf i))
1586     (let ((meta-map (make-sparse-keymap)))
1587       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1588       (define-key keymap [escape] meta-map))
1589     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1590     (define-key keymap "\e\e\e" 'company-search-other-char)
1591     (define-key keymap  [escape escape escape] 'company-search-other-char)
1592
1593     (define-key keymap "\C-g" 'company-search-abort)
1594     (define-key keymap "\C-s" 'company-search-repeat-forward)
1595     (define-key keymap "\C-r" 'company-search-repeat-backward)
1596     (define-key keymap "\C-o" 'company-search-kill-others)
1597     keymap)
1598   "Keymap used for incrementally searching the completion candidates.")
1599
1600 (define-minor-mode company-search-mode
1601   "Search mode for completion candidates.
1602 Don't start this directly, use `company-search-candidates' or
1603 `company-filter-candidates'."
1604   nil company-search-lighter nil
1605   (if company-search-mode
1606       (if (company-manual-begin)
1607           (progn
1608             (setq company-search-old-selection company-selection)
1609             (company-call-frontends 'update))
1610         (setq company-search-mode nil))
1611     (kill-local-variable 'company-search-string)
1612     (kill-local-variable 'company-search-lighter)
1613     (kill-local-variable 'company-search-old-selection)
1614     (company-enable-overriding-keymap company-active-map)))
1615
1616 (defun company-search-assert-enabled ()
1617   (company-assert-enabled)
1618   (unless company-search-mode
1619     (company-uninstall-map)
1620     (error "Company not in search mode")))
1621
1622 (defun company-search-candidates ()
1623   "Start searching the completion candidates incrementally.
1624
1625 \\<company-search-map>Search can be controlled with the commands:
1626 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1627 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1628 - `company-search-abort' (\\[company-search-abort])
1629
1630 Regular characters are appended to the search string.
1631
1632 The command `company-search-kill-others' (\\[company-search-kill-others])
1633 uses the search string to limit the completion candidates."
1634   (interactive)
1635   (company-search-mode 1)
1636   (company-enable-overriding-keymap company-search-map))
1637
1638 (defvar company-filter-map
1639   (let ((keymap (make-keymap)))
1640     (define-key keymap [remap company-search-printing-char]
1641       'company-filter-printing-char)
1642     (set-keymap-parent keymap company-search-map)
1643     keymap)
1644   "Keymap used for incrementally searching the completion candidates.")
1645
1646 (defun company-filter-candidates ()
1647   "Start filtering the completion candidates incrementally.
1648 This works the same way as `company-search-candidates' immediately
1649 followed by `company-search-kill-others' after each input."
1650   (interactive)
1651   (company-search-mode 1)
1652   (company-enable-overriding-keymap company-filter-map))
1653
1654 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1655
1656 (defun company-select-next ()
1657   "Select the next candidate in the list."
1658   (interactive)
1659   (when (company-manual-begin)
1660     (company-set-selection (1+ company-selection))))
1661
1662 (defun company-select-previous ()
1663   "Select the previous candidate in the list."
1664   (interactive)
1665   (when (company-manual-begin)
1666     (company-set-selection (1- company-selection))))
1667
1668 (defun company-select-next-or-abort ()
1669   "Select the next candidate if more than one, else abort
1670 and invoke the normal binding."
1671   (interactive)
1672   (if (> company-candidates-length 1)
1673       (company-select-next)
1674     (company-abort)
1675     (company--unread-last-input)))
1676
1677 (defun company-select-previous-or-abort ()
1678   "Select the previous candidate if more than one, else abort
1679 and invoke the normal binding."
1680   (interactive)
1681   (if (> company-candidates-length 1)
1682       (company-select-previous)
1683     (company-abort)
1684     (company--unread-last-input)))
1685
1686 (defvar company-pseudo-tooltip-overlay)
1687
1688 (defvar company-tooltip-offset)
1689
1690 (defun company--inside-tooltip-p (event-col-row row height)
1691   (let* ((ovl company-pseudo-tooltip-overlay)
1692          (column (overlay-get ovl 'company-column))
1693          (width (overlay-get ovl 'company-width))
1694          (evt-col (car event-col-row))
1695          (evt-row (cdr event-col-row)))
1696     (and (>= evt-col column)
1697          (< evt-col (+ column width))
1698          (if (> height 0)
1699              (and (> evt-row row)
1700                   (<= evt-row (+ row height) ))
1701            (and (< evt-row row)
1702                 (>= evt-row (+ row height)))))))
1703
1704 (defun company--event-col-row (event)
1705   (let* ((col-row (posn-actual-col-row (event-start event)))
1706          (col (car col-row))
1707          (row (cdr col-row)))
1708     (incf col (window-hscroll))
1709     (and header-line-format
1710          (version< "24" emacs-version)
1711          (decf row))
1712     (cons col row)))
1713
1714 (defun company-select-mouse (event)
1715   "Select the candidate picked by the mouse."
1716   (interactive "e")
1717   (let ((event-col-row (company--event-col-row event))
1718         (ovl-row (company--row))
1719         (ovl-height (and company-pseudo-tooltip-overlay
1720                          (min (overlay-get company-pseudo-tooltip-overlay
1721                                            'company-height)
1722                               company-candidates-length))))
1723     (if (and ovl-height
1724              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1725         (progn
1726           (company-set-selection (+ (cdr event-col-row)
1727                                     (1- company-tooltip-offset)
1728                                     (if (and (eq company-tooltip-offset-display 'lines)
1729                                              (not (zerop company-tooltip-offset)))
1730                                         -1 0)
1731                                     (- ovl-row)
1732                                     (if (< ovl-height 0)
1733                                         (- 1 ovl-height)
1734                                       0)))
1735           t)
1736       (company-abort)
1737       (company--unread-last-input)
1738       nil)))
1739
1740 (defun company-complete-mouse (event)
1741   "Insert the candidate picked by the mouse."
1742   (interactive "e")
1743   (when (company-select-mouse event)
1744     (company-complete-selection)))
1745
1746 (defun company-complete-selection ()
1747   "Insert the selected candidate."
1748   (interactive)
1749   (when (company-manual-begin)
1750     (let ((result (nth company-selection company-candidates)))
1751       (company-finish result))))
1752
1753 (defun company-complete-common ()
1754   "Insert the common part of all candidates."
1755   (interactive)
1756   (when (company-manual-begin)
1757     (if (and (not (cdr company-candidates))
1758              (equal company-common (car company-candidates)))
1759         (company-complete-selection)
1760       (when company-common
1761         (company--insert-candidate company-common)))))
1762
1763 (defun company-complete ()
1764   "Insert the common part of all candidates or the current selection.
1765 The first time this is called, the common part is inserted, the second
1766 time, or when the selection has been changed, the selected candidate is
1767 inserted."
1768   (interactive)
1769   (when (company-manual-begin)
1770     (if (or company-selection-changed
1771             (eq last-command 'company-complete-common))
1772         (call-interactively 'company-complete-selection)
1773       (call-interactively 'company-complete-common)
1774       (setq this-command 'company-complete-common))))
1775
1776 (defun company-complete-number (n)
1777   "Insert the Nth candidate.
1778 To show the number next to the candidates in some back-ends, enable
1779 `company-show-numbers'."
1780   (when (company-manual-begin)
1781     (and (< n 1) (> n company-candidates-length)
1782          (error "No candidate number %d" n))
1783     (decf n)
1784     (company-finish (nth n company-candidates))))
1785
1786 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1787
1788 (defconst company-space-strings-limit 100)
1789
1790 (defconst company-space-strings
1791   (let (lst)
1792     (dotimes (i company-space-strings-limit)
1793       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1794     (apply 'vector lst)))
1795
1796 (defun company-space-string (len)
1797   (if (< len company-space-strings-limit)
1798       (aref company-space-strings len)
1799     (make-string len ?\ )))
1800
1801 (defun company-safe-substring (str from &optional to)
1802   (if (> from (string-width str))
1803       ""
1804     (with-temp-buffer
1805       (insert str)
1806       (move-to-column from)
1807       (let ((beg (point)))
1808         (if to
1809             (progn
1810               (move-to-column to)
1811               (concat (buffer-substring beg (point))
1812                       (let ((padding (- to (current-column))))
1813                         (when (> padding 0)
1814                           (company-space-string padding)))))
1815           (buffer-substring beg (point-max)))))))
1816
1817 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1818
1819 (defvar company-last-metadata nil)
1820 (make-variable-buffer-local 'company-last-metadata)
1821
1822 (defun company-fetch-metadata ()
1823   (let ((selected (nth company-selection company-candidates)))
1824     (unless (eq selected (car company-last-metadata))
1825       (setq company-last-metadata
1826             (cons selected (company-call-backend 'meta selected))))
1827     (cdr company-last-metadata)))
1828
1829 (defun company-doc-buffer (&optional string)
1830   (with-current-buffer (get-buffer-create "*company-documentation*")
1831     (erase-buffer)
1832     (when string
1833       (save-excursion
1834         (insert string)))
1835     (current-buffer)))
1836
1837 (defvar company--electric-commands
1838   '(scroll-other-window scroll-other-window-down)
1839   "List of Commands that won't break out of electric commands.")
1840
1841 (defmacro company--electric-do (&rest body)
1842   (declare (indent 0) (debug t))
1843   `(when (company-manual-begin)
1844      (save-window-excursion
1845        (let ((height (window-height))
1846              (row (company--row))
1847              cmd)
1848          ,@body
1849          (and (< (window-height) height)
1850               (< (- (window-height) row 2) company-tooltip-limit)
1851               (recenter (- (window-height) row 2)))
1852          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1853                       company--electric-commands)
1854            (call-interactively cmd))
1855          (company--unread-last-input)))))
1856
1857 (defun company--unread-last-input ()
1858   (when last-input-event
1859     (clear-this-command-keys t)
1860     (setq unread-command-events (list last-input-event))))
1861
1862 (defun company-show-doc-buffer ()
1863   "Temporarily show the documentation buffer for the selection."
1864   (interactive)
1865   (company--electric-do
1866     (let* ((selected (nth company-selection company-candidates))
1867            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1868                            (error "No documentation available"))))
1869       (with-current-buffer doc-buffer
1870         (goto-char (point-min)))
1871       (display-buffer doc-buffer t))))
1872 (put 'company-show-doc-buffer 'company-keep t)
1873
1874 (defun company-show-location ()
1875   "Temporarily display a buffer showing the selected candidate in context."
1876   (interactive)
1877   (company--electric-do
1878     (let* ((selected (nth company-selection company-candidates))
1879            (location (company-call-backend 'location selected))
1880            (pos (or (cdr location) (error "No location available")))
1881            (buffer (or (and (bufferp (car location)) (car location))
1882                        (find-file-noselect (car location) t))))
1883       (with-selected-window (display-buffer buffer t)
1884         (save-restriction
1885           (widen)
1886           (if (bufferp (car location))
1887               (goto-char pos)
1888             (goto-char (point-min))
1889             (forward-line (1- pos))))
1890         (set-window-start nil (point))))))
1891 (put 'company-show-location 'company-keep t)
1892
1893 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1894
1895 (defvar company-callback nil)
1896 (make-variable-buffer-local 'company-callback)
1897
1898 (defun company-remove-callback (&optional ignored)
1899   (remove-hook 'company-completion-finished-hook company-callback t)
1900   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1901   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
1902
1903 (defun company-begin-backend (backend &optional callback)
1904   "Start a completion at point using BACKEND."
1905   (interactive (let ((val (completing-read "Company back-end: "
1906                                            obarray
1907                                            'functionp nil "company-")))
1908                  (when val
1909                    (list (intern val)))))
1910   (when (setq company-callback callback)
1911     (add-hook 'company-completion-finished-hook company-callback nil t))
1912   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1913   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1914   (setq company-backend backend)
1915   ;; Return non-nil if active.
1916   (or (company-manual-begin)
1917       (error "Cannot complete at point")))
1918
1919 (defun company-begin-with (candidates
1920                            &optional prefix-length require-match callback)
1921   "Start a completion at point.
1922 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
1923 of the prefix that already is in the buffer before point.
1924 It defaults to 0.
1925
1926 CALLBACK is a function called with the selected result if the user
1927 successfully completes the input.
1928
1929 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
1930   (let ((begin-marker (copy-marker (point) t)))
1931     (company-begin-backend
1932      (lambda (command &optional arg &rest ignored)
1933        (pcase command
1934         (`prefix
1935          (when (equal (point) (marker-position begin-marker))
1936            (buffer-substring (- (point) (or prefix-length 0)) (point))))
1937         (`candidates
1938          (all-completions arg candidates))
1939         (`require-match
1940          require-match)))
1941      callback)))
1942
1943 (defun company-version (&optional show-version)
1944   "Get the Company version as string.
1945
1946 If SHOW-VERSION is non-nil, show the version in the echo area."
1947   (interactive (list t))
1948   (with-temp-buffer
1949     (insert-file-contents (find-library-name "company"))
1950     (require 'lisp-mnt)
1951     (if show-version
1952         (message "Company version: %s" (lm-version))
1953       (lm-version))))
1954
1955 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1956
1957 (defvar company-pseudo-tooltip-overlay nil)
1958 (make-variable-buffer-local 'company-pseudo-tooltip-overlay)
1959
1960 (defvar company-tooltip-offset 0)
1961 (make-variable-buffer-local 'company-tooltip-offset)
1962
1963 (defun company-tooltip--lines-update-offset (selection num-lines limit)
1964   (decf limit 2)
1965   (setq company-tooltip-offset
1966         (max (min selection company-tooltip-offset)
1967              (- selection -1 limit)))
1968
1969   (when (<= company-tooltip-offset 1)
1970     (incf limit)
1971     (setq company-tooltip-offset 0))
1972
1973   (when (>= company-tooltip-offset (- num-lines limit 1))
1974     (incf limit)
1975     (when (= selection (1- num-lines))
1976       (decf company-tooltip-offset)
1977       (when (<= company-tooltip-offset 1)
1978         (setq company-tooltip-offset 0)
1979         (incf limit))))
1980
1981   limit)
1982
1983 (defun company-tooltip--simple-update-offset (selection num-lines limit)
1984   (setq company-tooltip-offset
1985         (if (< selection company-tooltip-offset)
1986             selection
1987           (max company-tooltip-offset
1988                (- selection limit -1)))))
1989
1990 ;;; propertize
1991
1992 (defsubst company-round-tab (arg)
1993   (* (/ (+ arg tab-width) tab-width) tab-width))
1994
1995 (defun company-plainify (str)
1996   (let ((prefix (get-text-property 0 'line-prefix str)))
1997     (when prefix ; Keep the original value unmodified, for no special reason.
1998       (setq str (concat prefix str))
1999       (remove-text-properties 0 (length str) '(line-prefix) str)))
2000   (let* ((pieces (split-string str "\t"))
2001          (copy pieces))
2002     (while (cdr copy)
2003       (setcar copy (company-safe-substring
2004                     (car copy) 0 (company-round-tab (string-width (car copy)))))
2005       (pop copy))
2006     (apply 'concat pieces)))
2007
2008 (defun company-fill-propertize (value annotation width selected left right)
2009   (let* ((margin (length left))
2010          (common (+ (or (company-call-backend 'match value)
2011                         (length company-common)) margin))
2012          (ann-ralign company-tooltip-align-annotations)
2013          (ann-truncate (< width
2014                           (+ (length value) (length annotation)
2015                              (if ann-ralign 1 0))))
2016          (ann-start (+ margin
2017                        (if ann-ralign
2018                            (if ann-truncate
2019                                (1+ (length value))
2020                              (- width (length annotation)))
2021                          (length value))))
2022          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
2023          (line (concat left
2024                        (if (or ann-truncate (not ann-ralign))
2025                            (company-safe-substring
2026                             (concat value
2027                                     (when (and annotation ann-ralign) " ")
2028                                     annotation)
2029                             0 width)
2030                          (concat
2031                           (company-safe-substring value 0
2032                                                   (- width (length annotation)))
2033                           annotation))
2034                        right)))
2035     (setq width (+ width margin (length right)))
2036
2037     (add-text-properties 0 width '(face company-tooltip
2038                                    mouse-face company-tooltip-mouse)
2039                          line)
2040     (add-text-properties margin common
2041                          '(face company-tooltip-common
2042                            mouse-face company-tooltip-mouse)
2043                          line)
2044     (when (< ann-start ann-end)
2045       (add-text-properties ann-start ann-end
2046                            '(face company-tooltip-annotation
2047                              mouse-face company-tooltip-mouse)
2048                            line))
2049     (when selected
2050       (if (and company-search-string
2051                (string-match (regexp-quote company-search-string) value
2052                              (length company-prefix)))
2053           (let ((beg (+ margin (match-beginning 0)))
2054                 (end (+ margin (match-end 0))))
2055             (add-text-properties beg end '(face company-tooltip-selection)
2056                                  line)
2057             (when (< beg common)
2058               (add-text-properties beg common
2059                                    '(face company-tooltip-common-selection)
2060                                    line)))
2061         (add-text-properties 0 width '(face company-tooltip-selection
2062                                        mouse-face company-tooltip-selection)
2063                              line)
2064         (add-text-properties margin common
2065                              '(face company-tooltip-common-selection
2066                                mouse-face company-tooltip-selection)
2067                              line)))
2068     line))
2069
2070 ;;; replace
2071
2072 (defun company-buffer-lines (beg end)
2073   (goto-char beg)
2074   (let (lines)
2075     (while (and (= 1 (vertical-motion 1))
2076                 (<= (point) end))
2077       (let ((bound (min end (1- (point)))))
2078         ;; A visual line can contain several physical lines (e.g. with outline's
2079         ;; folding overlay).  Take only the first one.
2080         (push (buffer-substring beg
2081                                 (save-excursion
2082                                   (goto-char beg)
2083                                   (re-search-forward "$" bound 'move)
2084                                   (point)))
2085               lines))
2086       (setq beg (point)))
2087     (unless (eq beg end)
2088       (push (buffer-substring beg end) lines))
2089     (nreverse lines)))
2090
2091 (defun company-modify-line (old new offset)
2092   (concat (company-safe-substring old 0 offset)
2093           new
2094           (company-safe-substring old (+ offset (length new)))))
2095
2096 (defsubst company--length-limit (lst limit)
2097   (if (nthcdr limit lst)
2098       limit
2099     (length lst)))
2100
2101 (defun company--replacement-string (lines old column nl &optional align-top)
2102   (decf column company-tooltip-margin)
2103
2104   (let ((width (length (car lines)))
2105         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2106                            column)))
2107     (when (> width remaining-cols)
2108       (decf column (- width remaining-cols))))
2109
2110   (let ((offset (and (< column 0) (- column)))
2111         new)
2112     (when offset
2113       (setq column 0))
2114     (when align-top
2115       ;; untouched lines first
2116       (dotimes (_ (- (length old) (length lines)))
2117         (push (pop old) new)))
2118     ;; length into old lines.
2119     (while old
2120       (push (company-modify-line (pop old)
2121                                  (company--offset-line (pop lines) offset)
2122                                  column) new))
2123     ;; Append whole new lines.
2124     (while lines
2125       (push (concat (company-space-string column)
2126                     (company--offset-line (pop lines) offset))
2127             new))
2128
2129     (let ((str (concat (when nl "\n")
2130                        (mapconcat 'identity (nreverse new) "\n")
2131                        "\n")))
2132       (font-lock-append-text-property 0 (length str) 'face 'default str)
2133       str)))
2134
2135 (defun company--offset-line (line offset)
2136   (if (and offset line)
2137       (substring line offset)
2138     line))
2139
2140 (defun company--create-lines (selection limit)
2141   (let ((len company-candidates-length)
2142         (numbered 99999)
2143         (window-width (company--window-width))
2144         lines
2145         width
2146         lines-copy
2147         items
2148         previous
2149         remainder
2150         scrollbar-bounds)
2151
2152     ;; Maybe clear old offset.
2153     (when (< len (+ company-tooltip-offset limit))
2154       (setq company-tooltip-offset 0))
2155
2156     ;; Scroll to offset.
2157     (if (eq company-tooltip-offset-display 'lines)
2158         (setq limit (company-tooltip--lines-update-offset selection len limit))
2159       (company-tooltip--simple-update-offset selection len limit))
2160
2161     (cond
2162      ((eq company-tooltip-offset-display 'scrollbar)
2163       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2164                                                         limit len)))
2165      ((eq company-tooltip-offset-display 'lines)
2166       (when (> company-tooltip-offset 0)
2167         (setq previous (format "...(%d)" company-tooltip-offset)))
2168       (setq remainder (- len limit company-tooltip-offset)
2169             remainder (when (> remainder 0)
2170                         (setq remainder (format "...(%d)" remainder))))))
2171
2172     (decf selection company-tooltip-offset)
2173     (setq width (max (length previous) (length remainder))
2174           lines (nthcdr company-tooltip-offset company-candidates)
2175           len (min limit len)
2176           lines-copy lines)
2177
2178     (decf window-width (* 2 company-tooltip-margin))
2179     (when scrollbar-bounds (decf window-width))
2180
2181     (dotimes (_ len)
2182       (let* ((value (pop lines-copy))
2183              (annotation (company-call-backend 'annotation value)))
2184         (when (and annotation company-tooltip-align-annotations)
2185           ;; `lisp-completion-at-point' adds a space.
2186           (setq annotation (comment-string-strip annotation t nil)))
2187         (push (cons value annotation) items)
2188         (setq width (max (+ (length value)
2189                             (if (and annotation company-tooltip-align-annotations)
2190                                 (1+ (length annotation))
2191                               (length annotation)))
2192                          width))))
2193
2194     (setq width (min window-width
2195                      (if (and company-show-numbers
2196                               (< company-tooltip-offset 10))
2197                          (+ 2 width)
2198                        width)))
2199
2200     ;; number can make tooltip too long
2201     (when company-show-numbers
2202       (setq numbered company-tooltip-offset))
2203
2204     (let ((items (nreverse items)) new)
2205       (when previous
2206         (push (company--scrollpos-line previous width) new))
2207
2208       (dotimes (i len)
2209         (let* ((item (pop items))
2210                (str (company-reformat (car item)))
2211                (annotation (cdr item))
2212                (right (company-space-string company-tooltip-margin))
2213                (width width))
2214           (when (< numbered 10)
2215             (decf width 2)
2216             (incf numbered)
2217             (setq right (concat (format " %d" (mod numbered 10)) right)))
2218           (push (concat
2219                  (company-fill-propertize str annotation
2220                                           width (equal i selection)
2221                                           (company-space-string
2222                                            company-tooltip-margin)
2223                                           right)
2224                  (when scrollbar-bounds
2225                    (company--scrollbar i scrollbar-bounds)))
2226                 new)))
2227
2228       (when remainder
2229         (push (company--scrollpos-line remainder width) new))
2230
2231       (nreverse new))))
2232
2233 (defun company--scrollbar-bounds (offset limit length)
2234   (when (> length limit)
2235     (let* ((size (ceiling (* limit (float limit)) length))
2236            (lower (floor (* limit (float offset)) length))
2237            (upper (+ lower size -1)))
2238       (cons lower upper))))
2239
2240 (defun company--scrollbar (i bounds)
2241   (propertize " " 'face
2242               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2243                   'company-scrollbar-fg
2244                 'company-scrollbar-bg)))
2245
2246 (defun company--scrollpos-line (text width)
2247   (propertize (concat (company-space-string company-tooltip-margin)
2248                       (company-safe-substring text 0 width)
2249                       (company-space-string company-tooltip-margin))
2250    'face 'company-tooltip))
2251
2252 ;; show
2253
2254 (defsubst company--window-inner-height ()
2255   (let ((edges (window-inside-edges)))
2256     (- (nth 3 edges) (nth 1 edges))))
2257
2258 (defsubst company--window-width ()
2259   (- (window-width)
2260      (cond
2261       ((display-graphic-p) 0)
2262       ;; Account for the line continuation column.
2263       ((version< "24.3.1" emacs-version) 1)
2264       ;; Emacs 24.3 and earlier included margins
2265       ;; in window-width when in TTY.
2266       (t (1+ (let ((margins (window-margins)))
2267                (+ (or (car margins) 0)
2268                   (or (cdr margins) 0))))))))
2269
2270 (defun company--pseudo-tooltip-height ()
2271   "Calculate the appropriate tooltip height.
2272 Returns a negative number if the tooltip should be displayed above point."
2273   (let* ((lines (company--row))
2274          (below (- (company--window-inner-height) 1 lines)))
2275     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2276              (> lines below))
2277         (- (max 3 (min company-tooltip-limit lines)))
2278       (max 3 (min company-tooltip-limit below)))))
2279
2280 (defun company-pseudo-tooltip-show (row column selection)
2281   (company-pseudo-tooltip-hide)
2282   (save-excursion
2283
2284     (let* ((height (company--pseudo-tooltip-height))
2285            above)
2286
2287       (when (< height 0)
2288         (setq row (+ row height -1)
2289               above t))
2290
2291       (let* ((nl (< (move-to-window-line row) row))
2292              (beg (point))
2293              (end (save-excursion
2294                     (move-to-window-line (+ row (abs height)))
2295                     (point)))
2296              (ov (make-overlay beg end))
2297              (args (list (mapcar 'company-plainify
2298                                  (company-buffer-lines beg end))
2299                          column nl above)))
2300
2301         (setq company-pseudo-tooltip-overlay ov)
2302         (overlay-put ov 'company-replacement-args args)
2303
2304         (let ((lines (company--create-lines selection (abs height))))
2305           (overlay-put ov 'company-after
2306                        (apply 'company--replacement-string lines args))
2307           (overlay-put ov 'company-width (string-width (car lines))))
2308
2309         (overlay-put ov 'company-column column)
2310         (overlay-put ov 'company-height height)))))
2311
2312 (defun company-pseudo-tooltip-show-at-point (pos)
2313   (let ((row (company--row pos))
2314         (col (company--column pos)))
2315     (company-pseudo-tooltip-show (1+ row) col company-selection)))
2316
2317 (defun company-pseudo-tooltip-edit (selection)
2318   (let ((height (overlay-get company-pseudo-tooltip-overlay 'company-height)))
2319     (overlay-put company-pseudo-tooltip-overlay 'company-after
2320                  (apply 'company--replacement-string
2321                         (company--create-lines selection (abs height))
2322                         (overlay-get company-pseudo-tooltip-overlay
2323                                      'company-replacement-args)))))
2324
2325 (defun company-pseudo-tooltip-hide ()
2326   (when company-pseudo-tooltip-overlay
2327     (delete-overlay company-pseudo-tooltip-overlay)
2328     (setq company-pseudo-tooltip-overlay nil)))
2329
2330 (defun company-pseudo-tooltip-hide-temporarily ()
2331   (when (overlayp company-pseudo-tooltip-overlay)
2332     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2333     (overlay-put company-pseudo-tooltip-overlay 'line-prefix nil)
2334     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)))
2335
2336 (defun company-pseudo-tooltip-unhide ()
2337   (when company-pseudo-tooltip-overlay
2338     (overlay-put company-pseudo-tooltip-overlay 'invisible t)
2339     ;; Beat outline's folding overlays, at least.
2340     (overlay-put company-pseudo-tooltip-overlay 'priority 1)
2341     ;; No (extra) prefix for the first line.
2342     (overlay-put company-pseudo-tooltip-overlay 'line-prefix "")
2343     (overlay-put company-pseudo-tooltip-overlay 'after-string
2344                  (overlay-get company-pseudo-tooltip-overlay 'company-after))
2345     (overlay-put company-pseudo-tooltip-overlay 'window (selected-window))))
2346
2347 (defun company-pseudo-tooltip-guard ()
2348   (buffer-substring-no-properties
2349    (point) (overlay-start company-pseudo-tooltip-overlay)))
2350
2351 (defun company-pseudo-tooltip-frontend (command)
2352   "`company-mode' front-end similar to a tooltip but based on overlays."
2353   (case command
2354     (pre-command (company-pseudo-tooltip-hide-temporarily))
2355     (post-command
2356      (let ((old-height (if (overlayp company-pseudo-tooltip-overlay)
2357                            (overlay-get company-pseudo-tooltip-overlay
2358                                         'company-height)
2359                          0))
2360            (new-height (company--pseudo-tooltip-height)))
2361        (unless (and (>= (* old-height new-height) 0)
2362                     (>= (abs old-height) (abs new-height))
2363                     (equal (company-pseudo-tooltip-guard)
2364                            (overlay-get company-pseudo-tooltip-overlay
2365                                         'company-guard)))
2366          ;; Redraw needed.
2367          (company-pseudo-tooltip-show-at-point (- (point)
2368                                                   (length company-prefix)))
2369          (overlay-put company-pseudo-tooltip-overlay
2370                       'company-guard (company-pseudo-tooltip-guard))))
2371      (company-pseudo-tooltip-unhide))
2372     (hide (company-pseudo-tooltip-hide)
2373           (setq company-tooltip-offset 0))
2374     (update (when (overlayp company-pseudo-tooltip-overlay)
2375               (company-pseudo-tooltip-edit company-selection)))))
2376
2377 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2378   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2379   (unless (and (eq command 'post-command)
2380                (company--show-inline-p))
2381     (company-pseudo-tooltip-frontend command)))
2382
2383 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2384
2385 (defvar company-preview-overlay nil)
2386 (make-variable-buffer-local 'company-preview-overlay)
2387
2388 (defun company-preview-show-at-point (pos)
2389   (company-preview-hide)
2390
2391   (setq company-preview-overlay (make-overlay pos (1+ pos)))
2392
2393   (let ((completion (nth company-selection company-candidates)))
2394     (setq completion (propertize completion 'face 'company-preview))
2395     (add-text-properties 0 (length company-common)
2396                          '(face company-preview-common) completion)
2397
2398     ;; Add search string
2399     (and company-search-string
2400          (string-match (regexp-quote company-search-string) completion)
2401          (add-text-properties (match-beginning 0)
2402                               (match-end 0)
2403                               '(face company-preview-search)
2404                               completion))
2405
2406     (setq completion (company-strip-prefix completion))
2407
2408     (and (equal pos (point))
2409          (not (equal completion ""))
2410          (add-text-properties 0 1 '(cursor t) completion))
2411
2412     (overlay-put company-preview-overlay 'display
2413                  (concat completion (unless (eq pos (point-max))
2414                                       (buffer-substring pos (1+ pos)))))
2415     (overlay-put company-preview-overlay 'window (selected-window))))
2416
2417 (defun company-preview-hide ()
2418   (when company-preview-overlay
2419     (delete-overlay company-preview-overlay)
2420     (setq company-preview-overlay nil)))
2421
2422 (defun company-preview-frontend (command)
2423   "`company-mode' front-end showing the selection as if it had been inserted."
2424   (pcase command
2425     (`pre-command (company-preview-hide))
2426     (`post-command (company-preview-show-at-point (point)))
2427     (`hide (company-preview-hide))))
2428
2429 (defun company-preview-if-just-one-frontend (command)
2430   "`company-preview-frontend', but only shown for single candidates."
2431   (when (or (not (eq command 'post-command))
2432             (company--show-inline-p))
2433     (company-preview-frontend command)))
2434
2435 (defun company--show-inline-p ()
2436   (and (not (cdr company-candidates))
2437        company-common
2438        (string-prefix-p company-prefix company-common
2439                         (company-call-backend 'ignore-case))))
2440
2441 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2442
2443 (defvar company-echo-last-msg nil)
2444 (make-variable-buffer-local 'company-echo-last-msg)
2445
2446 (defvar company-echo-timer nil)
2447
2448 (defvar company-echo-delay .01)
2449
2450 (defun company-echo-show (&optional getter)
2451   (when getter
2452     (setq company-echo-last-msg (funcall getter)))
2453   (let ((message-log-max nil))
2454     (if company-echo-last-msg
2455         (message "%s" company-echo-last-msg)
2456       (message ""))))
2457
2458 (defun company-echo-show-soon (&optional getter)
2459   (when company-echo-timer
2460     (cancel-timer company-echo-timer))
2461   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2462
2463 (defsubst company-echo-show-when-idle (&optional getter)
2464   (when (sit-for company-echo-delay)
2465     (company-echo-show getter)))
2466
2467 (defun company-echo-format ()
2468
2469   (let ((limit (window-width (minibuffer-window)))
2470         (len -1)
2471         ;; Roll to selection.
2472         (candidates (nthcdr company-selection company-candidates))
2473         (i (if company-show-numbers company-selection 99999))
2474         comp msg)
2475
2476     (while candidates
2477       (setq comp (company-reformat (pop candidates))
2478             len (+ len 1 (length comp)))
2479       (if (< i 10)
2480           ;; Add number.
2481           (progn
2482             (setq comp (propertize (format "%d: %s" i comp)
2483                                    'face 'company-echo))
2484             (incf len 3)
2485             (incf i)
2486             (add-text-properties 3 (+ 3 (length company-common))
2487                                  '(face company-echo-common) comp))
2488         (setq comp (propertize comp 'face 'company-echo))
2489         (add-text-properties 0 (length company-common)
2490                              '(face company-echo-common) comp))
2491       (if (>= len limit)
2492           (setq candidates nil)
2493         (push comp msg)))
2494
2495     (mapconcat 'identity (nreverse msg) " ")))
2496
2497 (defun company-echo-strip-common-format ()
2498
2499   (let ((limit (window-width (minibuffer-window)))
2500         (len (+ (length company-prefix) 2))
2501         ;; Roll to selection.
2502         (candidates (nthcdr company-selection company-candidates))
2503         (i (if company-show-numbers company-selection 99999))
2504         msg comp)
2505
2506     (while candidates
2507       (setq comp (company-strip-prefix (pop candidates))
2508             len (+ len 2 (length comp)))
2509       (when (< i 10)
2510         ;; Add number.
2511         (setq comp (format "%s (%d)" comp i))
2512         (incf len 4)
2513         (incf i))
2514       (if (>= len limit)
2515           (setq candidates nil)
2516         (push (propertize comp 'face 'company-echo) msg)))
2517
2518     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2519             (mapconcat 'identity (nreverse msg) ", ")
2520             "}")))
2521
2522 (defun company-echo-hide ()
2523   (unless (equal company-echo-last-msg "")
2524     (setq company-echo-last-msg "")
2525     (company-echo-show)))
2526
2527 (defun company-echo-frontend (command)
2528   "`company-mode' front-end showing the candidates in the echo area."
2529   (pcase command
2530     (`post-command (company-echo-show-soon 'company-echo-format))
2531     (`hide (company-echo-hide))))
2532
2533 (defun company-echo-strip-common-frontend (command)
2534   "`company-mode' front-end showing the candidates in the echo area."
2535   (pcase command
2536     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2537     (`hide (company-echo-hide))))
2538
2539 (defun company-echo-metadata-frontend (command)
2540   "`company-mode' front-end showing the documentation in the echo area."
2541   (pcase command
2542     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
2543     (`hide (company-echo-hide))))
2544
2545 (provide 'company)
2546 ;;; company.el ends here