code.delx.au - gnu-emacs-elpa/blob - company-dabbrev.el

   1 ;;; company-dabbrev.el --- dabbrev-like company-mode completion back-end  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009, 2011, 2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'cl-lib)
  30
  31 (defgroup company-dabbrev nil
  32   "dabbrev-like completion back-end."
  33   :group 'company)
  34
  35 (defcustom company-dabbrev-other-buffers 'all
  36   "Determines whether `company-dabbrev' should search other buffers.
  37 If `all', search all other buffers.  If t, search buffers with the same
  38 major mode.
  39 See also `company-dabbrev-time-limit'."
  40   :type '(choice (const :tag "Off" nil)
  41                  (const :tag "Same major mode" t)
  42                  (const :tag "All" all)))
  43
  44 (defcustom company-dabbrev-time-limit .1
  45   "Determines how many seconds `company-dabbrev' should look for matches."
  46   :type '(choice (const :tag "Off" nil)
  47                  (number :tag "Seconds")))
  48
  49 (defcustom company-dabbrev-char-regexp "\\sw"
  50   "A regular expression matching the characters `company-dabbrev' looks for."
  51   :type 'regexp)
  52
  53 (defcustom company-dabbrev-ignore-case 'keep-prefix
  54   "The value of `ignore-case' returned by `company-dabbrev'.")
  55
  56 (defcustom company-dabbrev-downcase 'case-replace
  57   "Whether to downcase the returned candidates.
  58
  59 The value of nil means keep them as-is.
  60 `case-replace' means use the value of `case-replace'.
  61 Any other value means downcase.
  62
  63 If you set this value to nil, you may also want to set
  64 `company-dabbrev-ignore-case' to any value other than `keep-prefix'.")
  65
  66 (defcustom company-dabbrev-minimum-length 4
  67   "The minimum length for the completion candidate to be included.
  68 This variable affects both `company-dabbrev' and `company-dabbrev-code'."
  69   :type 'integer
  70   :package-version '(company . "0.8.3"))
  71
  72 (defmacro company-dabrev--time-limit-while (test start limit &rest body)
  73   (declare (indent 3) (debug t))
  74   `(let ((company-time-limit-while-counter 0))
  75      (catch 'done
  76        (while ,test
  77          ,@body
  78          (and ,limit
  79               (eq (cl-incf company-time-limit-while-counter) 25)
  80               (setq company-time-limit-while-counter 0)
  81               (> (float-time (time-since ,start)) ,limit)
  82               (throw 'done 'company-time-out))))))
  83
  84 (defsubst company-dabbrev--make-regexp (prefix)
  85   (concat "\\<" (if (equal prefix "")
  86               company-dabbrev-char-regexp
  87             (regexp-quote prefix))
  88           "\\(" company-dabbrev-char-regexp "\\)*\\>"))
  89
  90 (defun company-dabbrev--search-buffer (regexp pos symbols start limit
  91                                        ignore-comments)
  92   (save-excursion
  93     (let (match)
  94       (goto-char (if pos (1- pos) (point-min)))
  95       ;; search before pos
  96       (company-dabrev--time-limit-while (re-search-backward regexp nil t)
  97           start limit
  98         (setq match (match-string-no-properties 0))
  99         (if (and ignore-comments (company-in-string-or-comment))
 100             (goto-char (nth 8 (syntax-ppss)))
 101           (when (>= (length match) company-dabbrev-minimum-length)
 102             (push match symbols))))
 103       (goto-char (or pos (point-min)))
 104       ;; search after pos
 105       (company-dabrev--time-limit-while (re-search-forward regexp nil t)
 106           start limit
 107         (setq match (match-string-no-properties 0))
 108         (if (and ignore-comments (company-in-string-or-comment))
 109             (re-search-forward "\\s>\\|\\s!\\|\\s\"" nil t)
 110           (when (>= (length match) company-dabbrev-minimum-length)
 111             (push match symbols))))
 112       symbols)))
 113
 114 (defun company-dabbrev--search (regexp &optional limit other-buffer-modes
 115                                 ignore-comments)
 116   (let* ((start (current-time))
 117          (symbols (company-dabbrev--search-buffer regexp (point) nil start limit
 118                                                   ignore-comments)))
 119     (when other-buffer-modes
 120       (cl-dolist (buffer (delq (current-buffer) (buffer-list)))
 121         (with-current-buffer buffer
 122           (when (or (eq other-buffer-modes 'all)
 123                     (apply #'derived-mode-p other-buffer-modes))
 124             (setq symbols
 125                   (company-dabbrev--search-buffer regexp nil symbols start
 126                                                   limit ignore-comments))))
 127         (and limit
 128              (> (float-time (time-since start)) limit)
 129              (cl-return))))
 130     symbols))
 131
 132 ;;;###autoload
 133 (defun company-dabbrev (command &optional arg &rest ignored)
 134   "dabbrev-like `company-mode' completion back-end."
 135   (interactive (list 'interactive))
 136   (cl-case command
 137     (interactive (company-begin-backend 'company-dabbrev))
 138     (prefix (company-grab-word))
 139     (candidates
 140      (let* ((case-fold-search company-dabbrev-ignore-case)
 141             (words (company-dabbrev--search (company-dabbrev--make-regexp arg)
 142                                             company-dabbrev-time-limit
 143                                             (pcase company-dabbrev-other-buffers
 144                                               (`t (list major-mode))
 145                                               (`all `all))))
 146             (downcase-p (if (eq company-dabbrev-downcase 'case-replace)
 147                             case-replace
 148                           company-dabbrev-downcase)))
 149        (if downcase-p
 150            (mapcar 'downcase words)
 151          words)))
 152     (ignore-case company-dabbrev-ignore-case)
 153     (duplicates t)))
 154
 155 (provide 'company-dabbrev)
 156 ;;; company-dabbrev.el ends here