code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular in-buffer completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; URL: http://company-mode.github.io/
   8 ;; Version: 0.8.0-snapshot
   9 ;; Keywords: abbrev, convenience, matching
  10 ;; Package-Requires: ((emacs "24.1"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (pcase command
  52 ;;     (`prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (`meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;; Known Issues:
  62 ;; When point is at the very end of the buffer, the pseudo-tooltip appears very
  63 ;; wrong, unless company is allowed to temporarily insert a fake newline.
  64 ;; This behavior is enabled by `company-end-of-buffer-workaround'.
  65 ;;
  66 ;;; Change Log:
  67 ;;
  68 ;; See NEWS.md in the repository.
  69
  70 ;;; Code:
  71
  72 (eval-when-compile (require 'cl))
  73 (require 'newcomment)
  74
  75 ;; FIXME: Use `user-error'.
  76 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  77 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  78 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  79 (add-to-list 'debug-ignored-errors "^Company not ")
  80 (add-to-list 'debug-ignored-errors "^No candidate number ")
  81 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  82 (add-to-list 'debug-ignored-errors "^No other back-end$")
  83
  84 (defgroup company nil
  85   "Extensible inline text completion mechanism"
  86   :group 'abbrev
  87   :group 'convenience
  88   :group 'matching)
  89
  90 (defface company-tooltip
  91   '((default :foreground "black")
  92     (((class color) (min-colors 88) (background light))
  93      (:background "cornsilk"))
  94     (((class color) (min-colors 88) (background dark))
  95      (:background "yellow")))
  96   "Face used for the tooltip.")
  97
  98 (defface company-tooltip-selection
  99   '((default :inherit company-tooltip)
 100     (((class color) (min-colors 88) (background light))
 101      (:background "light blue"))
 102     (((class color) (min-colors 88) (background dark))
 103      (:background "orange1"))
 104     (t (:background "green")))
 105   "Face used for the selection in the tooltip.")
 106
 107 (defface company-tooltip-mouse
 108   '((default :inherit highlight))
 109   "Face used for the tooltip item under the mouse.")
 110
 111 (defface company-tooltip-common
 112   '((default :inherit company-tooltip)
 113     (((background light))
 114      :foreground "darkred")
 115     (((background dark))
 116      :foreground "red"))
 117   "Face used for the common completion in the tooltip.")
 118
 119 (defface company-tooltip-common-selection
 120   '((default :inherit company-tooltip-selection)
 121     (((background light))
 122      :foreground "darkred")
 123     (((background dark))
 124      :foreground "red"))
 125   "Face used for the selected common completion in the tooltip.")
 126
 127 (defface company-tooltip-annotation
 128   '((default :inherit company-tooltip)
 129     (((background light))
 130      :foreground "firebrick4")
 131     (((background dark))
 132      :foreground "red4"))
 133   "Face used for the annotation in the tooltip.")
 134
 135 (defface company-scrollbar-fg
 136   '((((background light))
 137      :background "darkred")
 138     (((background dark))
 139      :background "red"))
 140   "Face used for the tooltip scrollbar thumb.")
 141
 142 (defface company-scrollbar-bg
 143   '((default :inherit company-tooltip)
 144     (((background light))
 145      :background "wheat")
 146     (((background dark))
 147      :background "gold"))
 148   "Face used for the tooltip scrollbar background.")
 149
 150 (defface company-preview
 151   '((((background light))
 152      :inherit company-tooltip-selection)
 153     (((background dark))
 154      :background "blue4"
 155      :foreground "wheat"))
 156   "Face used for the completion preview.")
 157
 158 (defface company-preview-common
 159   '((((background light))
 160      :inherit company-tooltip-selection)
 161     (((background dark))
 162      :inherit company-preview
 163      :foreground "red"))
 164   "Face used for the common part of the completion preview.")
 165
 166 (defface company-preview-search
 167   '((((background light))
 168      :inherit company-tooltip-common-selection)
 169     (((background dark))
 170      :inherit company-preview
 171      :background "blue1"))
 172   "Face used for the search string in the completion preview.")
 173
 174 (defface company-echo nil
 175   "Face used for completions in the echo area.")
 176
 177 (defface company-echo-common
 178   '((((background dark)) (:foreground "firebrick1"))
 179     (((background light)) (:background "firebrick4")))
 180   "Face used for the common part of completions in the echo area.")
 181
 182 (defun company-frontends-set (variable value)
 183   ;; uniquify
 184   (let ((remainder value))
 185     (setcdr remainder (delq (car remainder) (cdr remainder))))
 186   (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 187        (memq 'company-pseudo-tooltip-frontend value)
 188        (error "Pseudo tooltip frontend cannot be used twice"))
 189   (and (memq 'company-preview-if-just-one-frontend value)
 190        (memq 'company-preview-frontend value)
 191        (error "Preview frontend cannot be used twice"))
 192   (and (memq 'company-echo value)
 193        (memq 'company-echo-metadata-frontend value)
 194        (error "Echo area cannot be used twice"))
 195   ;; preview must come last
 196   (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 197     (when (memq f value)
 198       (setq value (append (delq f value) (list f)))))
 199   (set variable value))
 200
 201 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 202                                company-preview-if-just-one-frontend
 203                                company-echo-metadata-frontend)
 204   "The list of active front-ends (visualizations).
 205 Each front-end is a function that takes one argument.  It is called with
 206 one of the following arguments:
 207
 208 `show': When the visualization should start.
 209
 210 `hide': When the visualization should end.
 211
 212 `update': When the data has been updated.
 213
 214 `pre-command': Before every command that is executed while the
 215 visualization is active.
 216
 217 `post-command': After every command that is executed while the
 218 visualization is active.
 219
 220 The visualized data is stored in `company-prefix', `company-candidates',
 221 `company-common', `company-selection', `company-point' and
 222 `company-search-string'."
 223   :set 'company-frontends-set
 224   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 225                          (const :tag "echo, strip common"
 226                                 company-echo-strip-common-frontend)
 227                          (const :tag "show echo meta-data in echo"
 228                                 company-echo-metadata-frontend)
 229                          (const :tag "pseudo tooltip"
 230                                 company-pseudo-tooltip-frontend)
 231                          (const :tag "pseudo tooltip, multiple only"
 232                                 company-pseudo-tooltip-unless-just-one-frontend)
 233                          (const :tag "preview" company-preview-frontend)
 234                          (const :tag "preview, unique only"
 235                                 company-preview-if-just-one-frontend)
 236                          (function :tag "custom function" nil))))
 237
 238 (defcustom company-tooltip-limit 10
 239   "The maximum number of candidates in the tooltip"
 240   :type 'integer)
 241
 242 (defcustom company-tooltip-minimum 6
 243   "The minimum height of the tooltip.
 244 If this many lines are not available, prefer to display the tooltip above."
 245   :type 'integer)
 246
 247 (defcustom company-tooltip-margin 1
 248   "Width of margin columns to show around the toolip."
 249   :type 'integer)
 250
 251 (defcustom company-tooltip-offset-display 'scrollbar
 252   "Method using which the tooltip displays scrolling position.
 253 `scrollbar' means draw a scrollbar to the right of the items.
 254 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 255   :type '(choice (const :tag "Scrollbar" scrollbar)
 256                  (const :tag "Two lines" lines)))
 257
 258 (defcustom company-tooltip-align-annotations nil
 259   "When non-nil, align annotations to the right tooltip border."
 260   :type 'boolean)
 261
 262 (defvar company-safe-backends
 263   '((company-abbrev . "Abbrev")
 264     (company-bbdb . "BBDB")
 265     (company-capf . "completion-at-point-functions")
 266     (company-clang . "Clang")
 267     (company-cmake . "CMake")
 268     (company-css . "CSS")
 269     (company-dabbrev . "dabbrev for plain text")
 270     (company-dabbrev-code . "dabbrev for code")
 271     (company-eclim . "Eclim (an Eclipse interface)")
 272     (company-elisp . "Emacs Lisp")
 273     (company-etags . "etags")
 274     (company-files . "Files")
 275     (company-gtags . "GNU Global")
 276     (company-ispell . "Ispell")
 277     (company-keywords . "Programming language keywords")
 278     (company-nxml . "nxml")
 279     (company-oddmuse . "Oddmuse")
 280     (company-pysmell . "PySmell")
 281     (company-ropemacs . "ropemacs")
 282     (company-semantic . "Semantic")
 283     (company-tempo . "Tempo templates")
 284     (company-xcode . "Xcode")))
 285 (put 'company-safe-backends 'risky-local-variable t)
 286
 287 (defun company-safe-backends-p (backends)
 288   (and (consp backends)
 289        (not (dolist (backend backends)
 290               (unless (if (consp backend)
 291                           (company-safe-backends-p backend)
 292                         (assq backend company-safe-backends))
 293                 (return t))))))
 294
 295 (defvar company--include-capf (version< "24.3.50" emacs-version))
 296
 297 (defcustom company-backends `(,@(unless company--include-capf
 298                                   (list 'company-elisp))
 299                               company-bbdb
 300                               company-nxml company-css
 301                               company-eclim company-semantic company-clang
 302                               company-xcode company-ropemacs company-cmake
 303                               ,@(when company--include-capf
 304                                   (list 'company-capf))
 305                               (company-dabbrev-code company-gtags company-etags
 306                                company-keywords)
 307                               company-oddmuse company-files company-dabbrev)
 308   "The list of active back-ends (completion engines).
 309
 310 `company-begin-backend' can be used to start a specific back-end,
 311 `company-other-backend' will skip to the next matching back-end in the list.
 312
 313 Each back-end is a function that takes a variable number of arguments.
 314 The first argument is the command requested from the back-end.  It is one
 315 of the following:
 316
 317 `prefix': The back-end should return the text to be completed.  It must be
 318 text immediately before point.  Returning nil passes control to the next
 319 back-end.  The function should return `stop' if it should complete but
 320 cannot \(e.g. if it is in the middle of a string\).  Instead of a string,
 321 the back-end may return a cons where car is the prefix and cdr is used in
 322 `company-minimum-prefix-length' test.  It must be either number or t, and
 323 in the latter case the test automatically succeeds.
 324
 325 `candidates': The second argument is the prefix to be completed.  The
 326 return value should be a list of candidates that match the prefix.
 327
 328 Non-prefix matches are also supported (candidates that don't start with the
 329 prefix, but match it in some backend-defined way).  Backends that use this
 330 feature must disable cache (return t to `no-cache') and should also respond
 331 to `match'.
 332
 333 Optional commands:
 334
 335 `sorted': Return t here to indicate that the candidates are sorted and will
 336 not need to be sorted again.
 337
 338 `duplicates': If non-nil, company will take care of removing duplicates
 339 from the list.
 340
 341 `no-cache': Usually company doesn't ask for candidates again as completion
 342 progresses, unless the back-end returns t for this command.  The second
 343 argument is the latest prefix.
 344
 345 `meta': The second argument is a completion candidate.  Return a (short)
 346 documentation string for it.
 347
 348 `doc-buffer': The second argument is a completion candidate.  Return a
 349 buffer with documentation for it.  Preferably use `company-doc-buffer',
 350
 351 `location': The second argument is a completion candidate.  Return the cons
 352 of buffer and buffer location, or of file and line number where the
 353 completion candidate was defined.
 354
 355 `annotation': The second argument is a completion candidate.  Return a
 356 string to be displayed inline with the candidate in the popup.  If
 357 duplicates are removed by company, candidates with equal string values will
 358 be kept if they have different annotations.  For that to work properly,
 359 backends should store the related information on candidates using text
 360 properties.
 361
 362 `match': The second argument is a completion candidate.  Backends that
 363 provide non-prefix completions should return the position of the end of
 364 text in the candidate that matches `prefix'.  It will be used when
 365 rendering the popup.
 366
 367 `require-match': If this returns t, the user is not allowed to enter
 368 anything not offered as a candidate.  Use with care!  The default value nil
 369 gives the user that choice with `company-require-match'.  Return value
 370 `never' overrides that option the other way around.
 371
 372 `init': Called once for each buffer. The back-end can check for external
 373 programs and files and load any required libraries.  Raising an error here
 374 will show up in message log once, and the back-end will not be used for
 375 completion.
 376
 377 `post-completion': Called after a completion candidate has been inserted
 378 into the buffer.  The second argument is the candidate.  Can be used to
 379 modify it, e.g. to expand a snippet.
 380
 381 The back-end should return nil for all commands it does not support or
 382 does not know about.  It should also be callable interactively and use
 383 `company-begin-backend' to start itself in that case.
 384
 385 Grouped back-ends:
 386
 387 An element of `company-backends' can also itself be a list of back-ends,
 388 then it's considered to be a \"grouped\" back-end.
 389
 390 When possible, commands taking a candidate as an argument are dispatched to
 391 the back-end it came from.  In other cases, the first non-nil value among
 392 all the back-ends is returned.
 393
 394 The latter is the case for the `prefix' command.  But if the group contains
 395 the keyword `:with', the back-ends after it are ignored for this command.
 396
 397 The completions from back-ends in a group are merged (but only from those
 398 that return the same `prefix').
 399
 400 Asynchronous back-ends:
 401
 402 The return value of each command can also be a cons (:async . FETCHER)
 403 where FETCHER is a function of one argument, CALLBACK.  When the data
 404 arrives, FETCHER must call CALLBACK and pass it the appropriate return
 405 value, as described above.
 406
 407 True asynchronous operation is only supported for command `candidates', and
 408 only during idle completion.  Other commands will block the user interface,
 409 even if the back-end uses the asynchronous calling convention."
 410   :type `(repeat
 411           (choice
 412            :tag "Back-end"
 413            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 414                      company-safe-backends)
 415            (symbol :tag "User defined")
 416            (repeat :tag "Merged Back-ends"
 417                    (choice :tag "Back-end"
 418                            ,@(mapcar (lambda (b)
 419                                        `(const :tag ,(cdr b) ,(car b)))
 420                                      company-safe-backends)
 421                            (const :tag "With" :with)
 422                            (symbol :tag "User defined"))))))
 423
 424 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 425
 426 (defcustom company-transformers nil
 427   "Functions to change the list of candidates received from backends,
 428 after sorting and removal of duplicates (if appropriate).
 429 Each function gets called with the return value of the previous one."
 430   :type '(choice
 431           (const :tag "None" nil)
 432           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 433           (repeat :tag "User defined" (function))))
 434
 435 (defcustom company-completion-started-hook nil
 436   "Hook run when company starts completing.
 437 The hook is called with one argument that is non-nil if the completion was
 438 started manually."
 439   :type 'hook)
 440
 441 (defcustom company-completion-cancelled-hook nil
 442   "Hook run when company cancels completing.
 443 The hook is called with one argument that is non-nil if the completion was
 444 aborted manually."
 445   :type 'hook)
 446
 447 (defcustom company-completion-finished-hook nil
 448   "Hook run when company successfully completes.
 449 The hook is called with the selected candidate as an argument.
 450
 451 If you indend to use it to post-process candidates from a specific
 452 back-end, consider using the `post-completion' command instead."
 453   :type 'hook)
 454
 455 (defcustom company-minimum-prefix-length 3
 456   "The minimum prefix length for idle completion."
 457   :type '(integer :tag "prefix length"))
 458
 459 (defcustom company-abort-manual-when-too-short nil
 460   "If enabled, cancel a manually started completion when the prefix gets
 461 shorter than both `company-minimum-prefix-length' and the length of the
 462 prefix it was started from."
 463   :type 'boolean)
 464
 465 (defcustom company-require-match 'company-explicit-action-p
 466   "If enabled, disallow non-matching input.
 467 This can be a function do determine if a match is required.
 468
 469 This can be overridden by the back-end, if it returns t or `never' to
 470 `require-match'.  `company-auto-complete' also takes precedence over this."
 471   :type '(choice (const :tag "Off" nil)
 472                  (function :tag "Predicate function")
 473                  (const :tag "On, if user interaction took place"
 474                         'company-explicit-action-p)
 475                  (const :tag "On" t)))
 476
 477 (defcustom company-auto-complete nil
 478   "Determines when to auto-complete.
 479 If this is enabled, all characters from `company-auto-complete-chars'
 480 trigger insertion of the selected completion candidate.
 481 This can also be a function."
 482   :type '(choice (const :tag "Off" nil)
 483                  (function :tag "Predicate function")
 484                  (const :tag "On, if user interaction took place"
 485                         'company-explicit-action-p)
 486                  (const :tag "On" t)))
 487
 488 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 489   "Determines which characters trigger auto-completion.
 490 See `company-auto-complete'.  If this is a string, each string character
 491 tiggers auto-completion.  If it is a list of syntax description characters (see
 492 `modify-syntax-entry'), all characters with that syntax auto-complete.
 493
 494 This can also be a function, which is called with the new input and should
 495 return non-nil if company should auto-complete.
 496
 497 A character that is part of a valid candidate never triggers auto-completion."
 498   :type '(choice (string :tag "Characters")
 499                  (set :tag "Syntax"
 500                       (const :tag "Whitespace" ?\ )
 501                       (const :tag "Symbol" ?_)
 502                       (const :tag "Opening parentheses" ?\()
 503                       (const :tag "Closing parentheses" ?\))
 504                       (const :tag "Word constituent" ?w)
 505                       (const :tag "Punctuation." ?.)
 506                       (const :tag "String quote." ?\")
 507                       (const :tag "Paired delimiter." ?$)
 508                       (const :tag "Expression quote or prefix operator." ?\')
 509                       (const :tag "Comment starter." ?<)
 510                       (const :tag "Comment ender." ?>)
 511                       (const :tag "Character-quote." ?/)
 512                       (const :tag "Generic string fence." ?|)
 513                       (const :tag "Generic comment fence." ?!))
 514                  (function :tag "Predicate function")))
 515
 516 (defcustom company-idle-delay .7
 517   "The idle delay in seconds until completion starts automatically.
 518 A value of nil means no idle completion, t means show candidates
 519 immediately when a prefix of `company-minimum-prefix-length' is reached."
 520   :type '(choice (const :tag "never (nil)" nil)
 521                  (const :tag "immediate (t)" t)
 522                  (number :tag "seconds")))
 523
 524 (defcustom company-begin-commands '(self-insert-command org-self-insert-command)
 525   "A list of commands after which idle completion is allowed.
 526 If this is t, it can show completions after any command.  See
 527 `company-idle-delay'.
 528
 529 Alternatively, any command with a non-nil `company-begin' property is
 530 treated as if it was on this list."
 531   :type '(choice (const :tag "Any command" t)
 532                  (const :tag "Self insert command" '(self-insert-command))
 533                  (repeat :tag "Commands" function)))
 534
 535 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 536                                            save-buffers-kill-terminal
 537                                            save-buffers-kill-emacs)
 538   "A list of commands that are allowed during completion.
 539 If this is t, or if `company-begin-commands' is t, any command is allowed.
 540 Otherwise, the value must be a list of symbols.  If it starts with `not',
 541 the cdr is the list of commands that abort completion.  Otherwise, all
 542 commands except those in that list, or in `company-begin-commands', or
 543 commands in the `company-' namespace, abort completion."
 544   :type '(choice (const :tag "Any command" t)
 545                  (cons  :tag "Any except"
 546                         (const not)
 547                         (repeat :tag "Commands" function))
 548                  (repeat :tag "Commands" function)))
 549
 550 (defcustom company-show-numbers nil
 551   "If enabled, show quick-access numbers for the first ten candidates."
 552   :type '(choice (const :tag "off" nil)
 553                  (const :tag "on" t)))
 554
 555 (defcustom company-selection-wrap-around nil
 556   "If enabled, selecting item before first or after last wraps around."
 557   :type '(choice (const :tag "off" nil)
 558                  (const :tag "on" t)))
 559
 560 (defvar company-end-of-buffer-workaround t
 561   "Work around a visualization bug when completing at the end of the buffer.
 562 The work-around consists of adding a newline.")
 563
 564 (defvar company-async-wait 0.03
 565   "Pause between checks to see if the value's been set when turning an
 566 asynchronous call into synchronous.")
 567
 568 (defvar company-async-timeout 2
 569   "Maximum wait time for a value to be set during asynchronous call.")
 570
 571 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 572
 573 (defvar company-mode-map (make-sparse-keymap)
 574   "Keymap used by `company-mode'.")
 575
 576 (defvar company-active-map
 577   (let ((keymap (make-sparse-keymap)))
 578     (define-key keymap "\e\e\e" 'company-abort)
 579     (define-key keymap "\C-g" 'company-abort)
 580     (define-key keymap (kbd "M-n") 'company-select-next)
 581     (define-key keymap (kbd "M-p") 'company-select-previous)
 582     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 583     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 584     (define-key keymap [down-mouse-1] 'ignore)
 585     (define-key keymap [down-mouse-3] 'ignore)
 586     (define-key keymap [mouse-1] 'company-complete-mouse)
 587     (define-key keymap [mouse-3] 'company-select-mouse)
 588     (define-key keymap [up-mouse-1] 'ignore)
 589     (define-key keymap [up-mouse-3] 'ignore)
 590     (define-key keymap [return] 'company-complete-selection)
 591     (define-key keymap (kbd "RET") 'company-complete-selection)
 592     (define-key keymap [tab] 'company-complete-common)
 593     (define-key keymap (kbd "TAB") 'company-complete-common)
 594     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 595     (define-key keymap "\C-w" 'company-show-location)
 596     (define-key keymap "\C-s" 'company-search-candidates)
 597     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 598     (dotimes (i 10)
 599       (define-key keymap (vector (+ (aref (kbd "M-0") 0) i))
 600         `(lambda () (interactive) (company-complete-number ,i))))
 601
 602     keymap)
 603   "Keymap that is enabled during an active completion.")
 604
 605 (defvar company--disabled-backends nil)
 606
 607 (defun company-init-backend (backend)
 608   (and (symbolp backend)
 609        (not (fboundp backend))
 610        (ignore-errors (require backend nil t)))
 611   (cond
 612    ((symbolp backend)
 613     (condition-case err
 614         (progn
 615           (funcall backend 'init)
 616           (put backend 'company-init t))
 617       (error
 618        (put backend 'company-init 'failed)
 619        (unless (memq backend company--disabled-backends)
 620          (message "Company back-end '%s' could not be initialized:\n%s"
 621                   backend (error-message-string err)))
 622        (pushnew backend company--disabled-backends)
 623        nil)))
 624    ;; No initialization for lambdas.
 625    ((functionp backend) t)
 626    (t ;; Must be a list.
 627     (dolist (b backend)
 628       (unless (keywordp b)
 629         (company-init-backend b))))))
 630
 631 (defvar company-default-lighter " company")
 632
 633 (defvar company-lighter company-default-lighter)
 634 (make-variable-buffer-local 'company-lighter)
 635
 636 ;;;###autoload
 637 (define-minor-mode company-mode
 638   "\"complete anything\"; is an in-buffer completion framework.
 639 Completion starts automatically, depending on the values
 640 `company-idle-delay' and `company-minimum-prefix-length'.
 641
 642 Completion can be controlled with the commands:
 643 `company-complete-common', `company-complete-selection', `company-complete',
 644 `company-select-next', `company-select-previous'.  If these commands are
 645 called before `company-idle-delay', completion will also start.
 646
 647 Completions can be searched with `company-search-candidates' or
 648 `company-filter-candidates'.  These can be used while completion is
 649 inactive, as well.
 650
 651 The completion data is retrieved using `company-backends' and displayed
 652 using `company-frontends'.  If you want to start a specific back-end, call
 653 it interactively or use `company-begin-backend'.
 654
 655 regular keymap (`company-mode-map'):
 656
 657 \\{company-mode-map}
 658 keymap during active completions (`company-active-map'):
 659
 660 \\{company-active-map}"
 661   nil company-lighter company-mode-map
 662   (if company-mode
 663       (progn
 664         (add-hook 'pre-command-hook 'company-pre-command nil t)
 665         (add-hook 'post-command-hook 'company-post-command nil t)
 666         (mapc 'company-init-backend company-backends))
 667     (remove-hook 'pre-command-hook 'company-pre-command t)
 668     (remove-hook 'post-command-hook 'company-post-command t)
 669     (company-cancel)
 670     (kill-local-variable 'company-point)))
 671
 672 (defcustom company-global-modes t
 673   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 674 If nil, means no modes.  If t, then all major modes have it turned on.
 675 If a list, it should be a list of `major-mode' symbol names for which
 676 `company-mode' should be automatically turned on.  The sense of the list is
 677 negated if it begins with `not'.  For example:
 678  (c-mode c++-mode)
 679 means that `company-mode' is turned on for buffers in C and C++ modes only.
 680  (not message-mode)
 681 means that `company-mode' is always turned on except in `message-mode' buffers."
 682   :type '(choice (const :tag "none" nil)
 683                  (const :tag "all" t)
 684                  (set :menu-tag "mode specific" :tag "modes"
 685                       :value (not)
 686                       (const :tag "Except" not)
 687                       (repeat :inline t (symbol :tag "mode")))))
 688
 689 ;;;###autoload
 690 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 691
 692 (defun company-mode-on ()
 693   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 694              (cond ((eq company-global-modes t)
 695                     t)
 696                    ((eq (car-safe company-global-modes) 'not)
 697                     (not (memq major-mode (cdr company-global-modes))))
 698                    (t (memq major-mode company-global-modes))))
 699     (company-mode 1)))
 700
 701 (defsubst company-assert-enabled ()
 702   (unless company-mode
 703     (company-uninstall-map)
 704     (error "Company not enabled")))
 705
 706 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 707
 708 (defvar company-my-keymap nil)
 709 (make-variable-buffer-local 'company-my-keymap)
 710
 711 (defvar company-emulation-alist '((t . nil)))
 712
 713 (defsubst company-enable-overriding-keymap (keymap)
 714   (company-uninstall-map)
 715   (setq company-my-keymap keymap))
 716
 717 (defun company-ensure-emulation-alist ()
 718   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 719     (setq emulation-mode-map-alists
 720           (cons 'company-emulation-alist
 721                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 722
 723 (defun company-install-map ()
 724   (unless (or (cdar company-emulation-alist)
 725               (null company-my-keymap))
 726     (setf (cdar company-emulation-alist) company-my-keymap)))
 727
 728 (defun company-uninstall-map ()
 729   (setf (cdar company-emulation-alist) nil))
 730
 731 ;; Hack:
 732 ;; Emacs calculates the active keymaps before reading the event.  That means we
 733 ;; cannot change the keymap from a timer.  So we send a bogus command.
 734 ;; XXX: Seems not to be needed anymore in Emacs 24.4
 735 (defun company-ignore ()
 736   (interactive)
 737   (setq this-command last-command))
 738
 739 (global-set-key '[31415926] 'company-ignore)
 740
 741 (defun company-input-noop ()
 742   (push 31415926 unread-command-events))
 743
 744 (defun company--column (&optional pos)
 745   (save-excursion
 746     (when pos (goto-char pos))
 747     (save-restriction
 748       (+ (save-excursion
 749            (vertical-motion 0)
 750            (narrow-to-region (point) (point-max))
 751            (let ((prefix (get-text-property (point) 'line-prefix)))
 752              (if prefix (length prefix) 0)))
 753          (current-column)))))
 754
 755 (defun company--row (&optional pos)
 756   (save-excursion
 757     (when pos (goto-char pos))
 758     (count-screen-lines (window-start)
 759                         (progn (vertical-motion 0) (point)))))
 760
 761 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 762
 763 (defvar company-backend nil)
 764 (make-variable-buffer-local 'company-backend)
 765
 766 (defun company-grab (regexp &optional expression limit)
 767   (when (looking-back regexp limit)
 768     (or (match-string-no-properties (or expression 0)) "")))
 769
 770 (defun company-grab-line (regexp &optional expression)
 771   (company-grab regexp expression (point-at-bol)))
 772
 773 (defun company-grab-symbol ()
 774   (if (looking-at "\\_>")
 775       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 776                                                 (point)))
 777     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 778       "")))
 779
 780 (defun company-grab-word ()
 781   (if (looking-at "\\>")
 782       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 783                                                 (point)))
 784     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 785       "")))
 786
 787 (defun company-in-string-or-comment ()
 788   (let ((ppss (syntax-ppss)))
 789     (or (car (setq ppss (nthcdr 3 ppss)))
 790         (car (setq ppss (cdr ppss)))
 791         (nth 3 ppss))))
 792
 793 (defun company-call-backend (&rest args)
 794   (let ((val (apply #'company-call-backend-raw args)))
 795     (company--force-sync val company-backend args)))
 796
 797 (defun company--force-sync (value backend args)
 798   (if (not (eq (car-safe value) :async))
 799       value
 800     (let ((res 'trash)
 801           (start (time-to-seconds)))
 802       (funcall (cdr value)
 803                (lambda (result) (setq res result)))
 804       (while (eq res 'trash)
 805         (if (> (- (time-to-seconds) start) company-async-timeout)
 806             (error "Company: Back-end %s async timeout with args %s"
 807                    backend args)
 808           (sleep-for company-async-wait)))
 809       res)))
 810
 811 (defun company-call-backend-raw (&rest args)
 812   (condition-case err
 813       (if (functionp company-backend)
 814           (apply company-backend args)
 815         (apply #'company--multi-backend-adapter company-backend args))
 816     (error (error "Company: Back-end %s error \"%s\" with args %s"
 817                   company-backend (error-message-string err) args))))
 818
 819 (defun company--multi-backend-adapter (backends command &rest args)
 820   (let ((backends (loop for b in backends
 821                         when (not (and (symbolp b)
 822                                        (eq 'failed (get b 'company-init))))
 823                         collect b)))
 824     (setq backends
 825           (if (eq command 'prefix)
 826               (butlast backends (length (member :with backends)))
 827             (delq :with backends)))
 828     (pcase command
 829       (`candidates
 830        (company--multi-backend-adapter-candidates backends (car args)))
 831       (`sorted nil)
 832       (`duplicates t)
 833       ((or `prefix `ignore-case `no-cache `require-match)
 834        (let (value)
 835          (dolist (backend backends)
 836            (when (setq value (company--force-sync
 837                               (apply backend command args)
 838                               backend (cons command args)))
 839              (return value)))))
 840       (_
 841        (let ((arg (car args)))
 842          (when (> (length arg) 0)
 843            (let ((backend (or (get-text-property 0 'company-backend arg)
 844                               (car backends))))
 845              (apply backend command args))))))))
 846
 847 (defun company--multi-backend-adapter-candidates (backends prefix)
 848   (let ((pairs (loop for backend in (cdr backends)
 849                      when (equal (funcall backend 'prefix)
 850                                  prefix)
 851                      collect (cons (funcall backend 'candidates prefix)
 852                                    (lambda (candidates)
 853                                      (mapcar
 854                                       (lambda (str)
 855                                         (propertize str 'company-backend
 856                                                     backend))
 857                                       candidates))))))
 858     (when (equal (funcall (car backends) 'prefix) prefix)
 859       ;; Small perf optimization: don't tag the candidates received
 860       ;; from the first backend in the group.
 861       (push (cons (funcall (car backends) 'candidates prefix)
 862                   'identity)
 863             pairs))
 864     (company--merge-async pairs (lambda (values) (apply #'append values)))))
 865
 866 (defun company--merge-async (pairs merger)
 867   (let ((async (loop for (val . mapper) in pairs
 868                      thereis
 869                      (eq :async (car-safe val)))))
 870     (if (not async)
 871         (funcall merger (mapcar (lambda (pair)
 872                                   (funcall (cdr pair) (car pair)))
 873                                 pairs))
 874       (cons
 875        :async
 876        (lambda (callback)
 877          (let* (lst pending
 878                 (finisher (lambda ()
 879                             (unless pending
 880                               (funcall callback
 881                                        (funcall merger
 882                                                 (nreverse lst)))))))
 883            (dolist (pair pairs)
 884              (let ((val (car pair))
 885                    (mapper (cdr pair)))
 886                (if (not (eq :async (car-safe val)))
 887                    (push (funcall mapper val) lst)
 888                  (push nil lst)
 889                  (let ((cell lst)
 890                        (fetcher (cdr val)))
 891                    (push fetcher pending)
 892                    (funcall fetcher
 893                             (lambda (res)
 894                               (setq pending (delq fetcher pending))
 895                               (setcar cell (funcall mapper res))
 896                               (funcall finisher)))))))
 897            (funcall finisher)))))))
 898
 899 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 900
 901 (defvar company-prefix nil)
 902 (make-variable-buffer-local 'company-prefix)
 903
 904 (defvar company-candidates nil)
 905 (make-variable-buffer-local 'company-candidates)
 906
 907 (defvar company-candidates-length nil)
 908 (make-variable-buffer-local 'company-candidates-length)
 909
 910 (defvar company-candidates-cache nil)
 911 (make-variable-buffer-local 'company-candidates-cache)
 912
 913 (defvar company-candidates-predicate nil)
 914 (make-variable-buffer-local 'company-candidates-predicate)
 915
 916 (defvar company-common nil)
 917 (make-variable-buffer-local 'company-common)
 918
 919 (defvar company-selection 0)
 920 (make-variable-buffer-local 'company-selection)
 921
 922 (defvar company-selection-changed nil)
 923 (make-variable-buffer-local 'company-selection-changed)
 924
 925 (defvar company--manual-action nil
 926   "Non-nil, if manual completion took place.")
 927 (make-variable-buffer-local 'company--manual-action)
 928
 929 (defvar company--manual-prefix nil)
 930 (make-variable-buffer-local 'company--manual-prefix)
 931
 932 (defvar company--auto-completion nil
 933   "Non-nil when current candidate is being inserted automatically.
 934 Controlled by `company-auto-complete'.")
 935
 936 (defvar company--point-max nil)
 937 (make-variable-buffer-local 'company--point-max)
 938
 939 (defvar company-point nil)
 940 (make-variable-buffer-local 'company-point)
 941
 942 (defvar company-timer nil)
 943
 944 (defvar company-added-newline nil)
 945 (make-variable-buffer-local 'company-added-newline)
 946
 947 (defsubst company-strip-prefix (str)
 948   (substring str (length company-prefix)))
 949
 950 (defun company--insert-candidate (candidate)
 951   (setq candidate (substring-no-properties candidate))
 952   ;; XXX: Return value we check here is subject to change.
 953   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 954       (insert (company-strip-prefix candidate))
 955     (delete-region (- (point) (length company-prefix)) (point))
 956     (insert candidate)))
 957
 958 (defmacro company-with-candidate-inserted (candidate &rest body)
 959   "Evaluate BODY with CANDIDATE temporarily inserted.
 960 This is a tool for back-ends that need candidates inserted before they
 961 can retrieve meta-data for them."
 962   (declare (indent 1))
 963   `(let ((inhibit-modification-hooks t)
 964          (inhibit-point-motion-hooks t)
 965          (modified-p (buffer-modified-p)))
 966      (company--insert-candidate ,candidate)
 967      (unwind-protect
 968          (progn ,@body)
 969        (delete-region company-point (point)))))
 970
 971 (defun company-explicit-action-p ()
 972   "Return whether explicit completion action was taken by the user."
 973   (or company--manual-action
 974       company-selection-changed))
 975
 976 (defun company-reformat (candidate)
 977   ;; company-ispell needs this, because the results are always lower-case
 978   ;; It's mory efficient to fix it only when they are displayed.
 979   ;; FIXME: Adopt the current text's capitalization instead?
 980   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 981       (concat company-prefix (substring candidate (length company-prefix)))
 982     candidate))
 983
 984 (defun company--should-complete ()
 985   (and (not (or buffer-read-only overriding-terminal-local-map
 986                 overriding-local-map))
 987        ;; Check if in the middle of entering a key combination.
 988        (or (equal (this-command-keys-vector) [])
 989            (not (keymapp (key-binding (this-command-keys-vector)))))
 990        (eq company-idle-delay t)
 991        (or (eq t company-begin-commands)
 992            (memq this-command company-begin-commands)
 993            (and (symbolp this-command) (get this-command 'company-begin)))
 994        (not (and transient-mark-mode mark-active))))
 995
 996 (defun company--should-continue ()
 997   (or (eq t company-begin-commands)
 998       (eq t company-continue-commands)
 999       (if (eq 'not (car company-continue-commands))
1000           (not (memq this-command (cdr company-continue-commands)))
1001         (or (memq this-command company-begin-commands)
1002             (memq this-command company-continue-commands)
1003             (string-match-p "\\`company-" (symbol-name this-command))))))
1004
1005 (defun company-call-frontends (command)
1006   (dolist (frontend company-frontends)
1007     (condition-case err
1008         (funcall frontend command)
1009       (error (error "Company: Front-end %s error \"%s\" on command %s"
1010                     frontend (error-message-string err) command)))))
1011
1012 (defun company-set-selection (selection &optional force-update)
1013   (setq selection
1014         (if company-selection-wrap-around
1015             (mod selection company-candidates-length)
1016           (max 0 (min (1- company-candidates-length) selection))))
1017   (when (or force-update (not (equal selection company-selection)))
1018     (setq company-selection selection
1019           company-selection-changed t)
1020     (company-call-frontends 'update)))
1021
1022 (defun company-apply-predicate (candidates predicate)
1023   (let (new)
1024     (dolist (c candidates)
1025       (when (funcall predicate c)
1026         (push c new)))
1027     (nreverse new)))
1028
1029 (defun company-update-candidates (candidates)
1030   (setq company-candidates-length (length candidates))
1031   (if (> company-selection 0)
1032       ;; Try to restore the selection
1033       (let ((selected (nth company-selection company-candidates)))
1034         (setq company-selection 0
1035               company-candidates candidates)
1036         (when selected
1037           (while (and candidates (string< (pop candidates) selected))
1038             (incf company-selection))
1039           (unless candidates
1040             ;; Make sure selection isn't out of bounds.
1041             (setq company-selection (min (1- company-candidates-length)
1042                                          company-selection)))))
1043     (setq company-selection 0
1044           company-candidates candidates))
1045   ;; Save in cache:
1046   (push (cons company-prefix company-candidates) company-candidates-cache)
1047   ;; Calculate common.
1048   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
1049     ;; We want to support non-prefix completion, so filtering is the
1050     ;; responsibility of each respective backend, not ours.
1051     ;; On the other hand, we don't want to replace non-prefix input in
1052     ;; `company-complete-common'.
1053     (setq company-common
1054           (if (cdr company-candidates)
1055               (let ((common (try-completion company-prefix company-candidates)))
1056                 (if (eq common t)
1057                     ;; Mulple equal strings, probably with different
1058                     ;; annotations.
1059                     company-prefix
1060                   common))
1061             (car company-candidates)))))
1062
1063 (defun company-calculate-candidates (prefix)
1064   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
1065         (ignore-case (company-call-backend 'ignore-case)))
1066     (or candidates
1067         (when company-candidates-cache
1068           (let ((len (length prefix))
1069                 (completion-ignore-case ignore-case)
1070                 prev)
1071             (dotimes (i (1+ len))
1072               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1073                                            company-candidates-cache)))
1074                 (setq candidates (all-completions prefix prev))
1075                 (return t)))))
1076         ;; no cache match, call back-end
1077         (setq candidates
1078               (company--process-candidates
1079                (company--fetch-candidates prefix))))
1080     (setq candidates (company--transform-candidates candidates))
1081     (when candidates
1082       (if (or (cdr candidates)
1083               (not (eq t (compare-strings (car candidates) nil nil
1084                                           prefix nil nil ignore-case))))
1085           candidates
1086         ;; Already completed and unique; don't start.
1087         t))))
1088
1089 (defun company--fetch-candidates (prefix)
1090   (let ((c (if company--manual-action
1091                (company-call-backend 'candidates prefix)
1092              (company-call-backend-raw 'candidates prefix)))
1093         res)
1094     (if (not (eq (car c) :async))
1095         c
1096       (let ((buf (current-buffer))
1097             (win (selected-window))
1098             (tick (buffer-chars-modified-tick))
1099             (pt (point))
1100             (backend company-backend))
1101         (funcall
1102          (cdr c)
1103          (lambda (candidates)
1104            (if (not (and candidates (eq res 'done)))
1105                ;; Fetcher called us right back.
1106                (setq res candidates)
1107              (setq company-backend backend
1108                    company-candidates-cache
1109                    (list (cons prefix
1110                                (company--process-candidates
1111                                 candidates))))
1112              (company-idle-begin buf win tick pt)))))
1113       ;; FIXME: Relying on the fact that the callers
1114       ;; will interpret nil as "do nothing" is shaky.
1115       ;; A throw-catch would be one possible improvement.
1116       (or res
1117           (progn (setq res 'done) nil)))))
1118
1119 (defun company--process-candidates (candidates)
1120   (when company-candidates-predicate
1121     (setq candidates
1122           (company-apply-predicate candidates
1123                                    company-candidates-predicate)))
1124   (unless (company-call-backend 'sorted)
1125     (setq candidates (sort candidates 'string<)))
1126   (when (company-call-backend 'duplicates)
1127     (company--strip-duplicates candidates))
1128   candidates)
1129
1130 (defun company--strip-duplicates (candidates)
1131   (let ((c2 candidates))
1132     (while c2
1133       (setcdr c2
1134               (let ((str (car c2))
1135                     (anno 'unk))
1136                 (pop c2)
1137                 (while (let ((str2 (car c2)))
1138                          (if (not (equal str str2))
1139                              nil
1140                            (when (eq anno 'unk)
1141                              (setq anno (company-call-backend
1142                                          'annotation str)))
1143                            (equal anno
1144                                   (company-call-backend
1145                                    'annotation str2))))
1146                   (pop c2))
1147                 c2)))))
1148
1149 (defun company--transform-candidates (candidates)
1150   (let ((c candidates))
1151     (dolist (tr company-transformers)
1152       (setq c (funcall tr c)))
1153     c))
1154
1155 (defun company-sort-by-occurrence (candidates)
1156   "Sort CANDIDATES according to their occurrences.
1157 Searches for each in the currently visible part of the current buffer and
1158 gives priority to the closest ones above point, then closest ones below
1159 point. The rest of the list is appended unchanged.
1160 Keywords and function definition names are ignored."
1161   (let* (occurs
1162          (noccurs
1163           (delete-if
1164            (lambda (candidate)
1165              (when (or
1166                     (save-excursion
1167                       (progn (forward-line 0)
1168                              (search-backward candidate (window-start) t)))
1169                     (save-excursion
1170                       (search-forward candidate (window-end) t)))
1171                (let ((beg (match-beginning 0))
1172                      (end (match-end 0)))
1173                  (when (save-excursion
1174                          (goto-char end)
1175                          (and (not (memq (get-text-property (point) 'face)
1176                                          '(font-lock-function-name-face
1177                                            font-lock-keyword-face)))
1178                               (let* ((prefix (company-call-backend 'prefix))
1179                                      (prefix (or (car-safe prefix) prefix)))
1180                                 (and (stringp prefix)
1181                                      (= (length prefix) (- end beg))))))
1182                    (push (cons candidate (if (< beg (point))
1183                                              (- (point) end)
1184                                            (- beg (window-start))))
1185                          occurs)
1186                    t))))
1187            candidates)))
1188     (nconc
1189      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1190      noccurs)))
1191
1192 (defun company-idle-begin (buf win tick pos)
1193   (and (eq buf (current-buffer))
1194        (eq win (selected-window))
1195        (eq tick (buffer-chars-modified-tick))
1196        (eq pos (point))
1197        (when (company-auto-begin)
1198          (when (version< emacs-version "24.3.50")
1199            (company-input-noop))
1200          (company-post-command))))
1201
1202 (defun company-auto-begin ()
1203   (and company-mode
1204        (not company-candidates)
1205        (let ((company-idle-delay t)
1206              (company-begin-commands t))
1207          (condition-case-unless-debug err
1208              (company-begin)
1209            (error (message "Company: An error occurred in auto-begin")
1210                   (message "%s" (error-message-string err))
1211                   (company-cancel))
1212            (quit (company-cancel)))))
1213   (unless company-candidates
1214     (setq company-backend nil))
1215   ;; Return non-nil if active.
1216   company-candidates)
1217
1218 (defun company-manual-begin ()
1219   (interactive)
1220   (company-assert-enabled)
1221   (setq company--manual-action t)
1222   (unwind-protect
1223       (let ((company-minimum-prefix-length 0))
1224         (company-auto-begin))
1225     (unless company-candidates
1226       (setq company--manual-action nil))))
1227
1228 (defun company-other-backend (&optional backward)
1229   (interactive (list current-prefix-arg))
1230   (company-assert-enabled)
1231   (if company-backend
1232       (let* ((after (cdr (member company-backend company-backends)))
1233              (before (cdr (member company-backend (reverse company-backends))))
1234              (next (if backward
1235                        (append before (reverse after))
1236                      (append after (reverse before)))))
1237         (company-cancel)
1238         (dolist (backend next)
1239           (when (ignore-errors (company-begin-backend backend))
1240             (return t))))
1241     (company-manual-begin))
1242   (unless company-candidates
1243     (error "No other back-end")))
1244
1245 (defun company-require-match-p ()
1246   (let ((backend-value (company-call-backend 'require-match)))
1247     (or (eq backend-value t)
1248         (and (not (eq backend-value 'never))
1249              (if (functionp company-require-match)
1250                  (funcall company-require-match)
1251                (eq company-require-match t))))))
1252
1253 (defun company-auto-complete-p (input)
1254   "Return non-nil, if input starts with punctuation or parentheses."
1255   (and (if (functionp company-auto-complete)
1256            (funcall company-auto-complete)
1257          company-auto-complete)
1258        (if (functionp company-auto-complete-chars)
1259            (funcall company-auto-complete-chars input)
1260          (if (consp company-auto-complete-chars)
1261              (memq (char-syntax (string-to-char input))
1262                    company-auto-complete-chars)
1263            (string-match (substring input 0 1) company-auto-complete-chars)))))
1264
1265 (defun company--incremental-p ()
1266   (and (> (point) company-point)
1267        (> (point-max) company--point-max)
1268        (not (eq this-command 'backward-delete-char-untabify))
1269        (equal (buffer-substring (- company-point (length company-prefix))
1270                                 company-point)
1271               company-prefix)))
1272
1273 (defun company--continue-failed ()
1274   (let ((input (buffer-substring-no-properties (point) company-point)))
1275     (cond
1276      ((company-auto-complete-p input)
1277       ;; auto-complete
1278       (save-excursion
1279         (goto-char company-point)
1280         (let ((company--auto-completion t))
1281           (company-complete-selection))
1282         nil))
1283      ((company-require-match-p)
1284       ;; wrong incremental input, but required match
1285       (delete-char (- (length input)))
1286       (ding)
1287       (message "Matching input is required")
1288       company-candidates)
1289      ((equal company-prefix (car company-candidates))
1290       ;; last input was actually success
1291       (company-cancel company-prefix))
1292      (t (company-cancel)))))
1293
1294 (defun company--good-prefix-p (prefix)
1295   (and (stringp (or (car-safe prefix) prefix)) ;excludes 'stop
1296        (or (eq (cdr-safe prefix) t)
1297            (let ((len (or (cdr-safe prefix) (length prefix))))
1298              (if company--manual-prefix
1299                  (or (not company-abort-manual-when-too-short)
1300                      ;; Must not be less than minimum or initial length.
1301                      (>= len (min company-minimum-prefix-length
1302                                   (length company--manual-prefix))))
1303                (>= len company-minimum-prefix-length))))))
1304
1305 (defun company--continue ()
1306   (when (company-call-backend 'no-cache company-prefix)
1307     ;; Don't complete existing candidates, fetch new ones.
1308     (setq company-candidates-cache nil))
1309   (let* ((new-prefix (company-call-backend 'prefix))
1310          (c (when (and (company--good-prefix-p new-prefix)
1311                        (setq new-prefix (or (car-safe new-prefix) new-prefix))
1312                        (= (- (point) (length new-prefix))
1313                           (- company-point (length company-prefix))))
1314               (company-calculate-candidates new-prefix))))
1315     (cond
1316      ((eq c t)
1317       ;; t means complete/unique.
1318       (company-cancel new-prefix))
1319      ((consp c)
1320       ;; incremental match
1321       (setq company-prefix new-prefix)
1322       (company-update-candidates c)
1323       c)
1324      ((not (company--incremental-p))
1325       (company-cancel))
1326      (t (company--continue-failed)))))
1327
1328 (defun company--begin-new ()
1329   (let (prefix c)
1330     (dolist (backend (if company-backend
1331                          ;; prefer manual override
1332                          (list company-backend)
1333                        company-backends))
1334       (setq prefix
1335             (if (or (symbolp backend)
1336                     (functionp backend))
1337                 (when (or (not (symbolp backend))
1338                           (eq t (get backend 'company-init))
1339                           (unless (get backend 'company-init)
1340                             (company-init-backend backend)))
1341                   (funcall backend 'prefix))
1342               (company--multi-backend-adapter backend 'prefix)))
1343       (when prefix
1344         (when (company--good-prefix-p prefix)
1345           (setq prefix (or (car-safe prefix) prefix)
1346                 company-backend backend
1347                 c (company-calculate-candidates prefix))
1348           ;; t means complete/unique.  We don't start, so no hooks.
1349           (if (not (consp c))
1350               (when company--manual-action
1351                 (message "No completion found"))
1352             (setq company-prefix prefix)
1353             (when company--manual-action
1354               (setq company--manual-prefix prefix))
1355             (when (symbolp backend)
1356               (setq company-lighter (concat " " (symbol-name backend))))
1357             (company-update-candidates c)
1358             (run-hook-with-args 'company-completion-started-hook
1359                                 (company-explicit-action-p))
1360             (company-call-frontends 'show)))
1361         (return c)))))
1362
1363 (defun company-begin ()
1364   (or (and company-candidates (company--continue))
1365       (and (company--should-complete) (company--begin-new)))
1366   (when company-candidates
1367     (let ((modified (buffer-modified-p)))
1368       (when (and company-end-of-buffer-workaround (eobp))
1369         (save-excursion (insert "\n"))
1370         (setq company-added-newline
1371               (or modified (buffer-chars-modified-tick)))))
1372     (setq company-point (point)
1373           company--point-max (point-max))
1374     (company-ensure-emulation-alist)
1375     (company-enable-overriding-keymap company-active-map)
1376     (company-call-frontends 'update)))
1377
1378 (defun company-cancel (&optional result)
1379   (and company-added-newline
1380        (> (point-max) (point-min))
1381        (let ((tick (buffer-chars-modified-tick)))
1382          (delete-region (1- (point-max)) (point-max))
1383          (equal tick company-added-newline))
1384        ;; Only set unmodified when tick remained the same since insert,
1385        ;; and the buffer wasn't modified before.
1386        (set-buffer-modified-p nil))
1387   (when company-prefix
1388     (if (stringp result)
1389         (progn
1390           (company-call-backend 'pre-completion result)
1391           (run-hook-with-args 'company-completion-finished-hook result)
1392           (company-call-backend 'post-completion result))
1393       (run-hook-with-args 'company-completion-cancelled-hook result)))
1394   (setq company-added-newline nil
1395         company-backend nil
1396         company-prefix nil
1397         company-candidates nil
1398         company-candidates-length nil
1399         company-candidates-cache nil
1400         company-candidates-predicate nil
1401         company-common nil
1402         company-selection 0
1403         company-selection-changed nil
1404         company--manual-action nil
1405         company--manual-prefix nil
1406         company-lighter company-default-lighter
1407         company--point-max nil
1408         company-point nil)
1409   (when company-timer
1410     (cancel-timer company-timer))
1411   (company-search-mode 0)
1412   (company-call-frontends 'hide)
1413   (company-enable-overriding-keymap nil)
1414   ;; Make return value explicit.
1415   nil)
1416
1417 (defun company-abort ()
1418   (interactive)
1419   (company-cancel t)
1420   ;; Don't start again, unless started manually.
1421   (setq company-point (point)))
1422
1423 (defun company-finish (result)
1424   (company--insert-candidate result)
1425   (company-cancel result)
1426   ;; Don't start again, unless started manually.
1427   (setq company-point (point)))
1428
1429 (defsubst company-keep (command)
1430   (and (symbolp command) (get command 'company-keep)))
1431
1432 (defun company-pre-command ()
1433   (unless (company-keep this-command)
1434     (condition-case err
1435         (when company-candidates
1436           (company-call-frontends 'pre-command)
1437           (unless (company--should-continue)
1438             (company-abort)))
1439       (error (message "Company: An error occurred in pre-command")
1440              (message "%s" (error-message-string err))
1441              (company-cancel))))
1442   (when company-timer
1443     (cancel-timer company-timer)
1444     (setq company-timer nil))
1445   (company-uninstall-map))
1446
1447 (defun company-post-command ()
1448   (unless (company-keep this-command)
1449     (condition-case err
1450         (progn
1451           (unless (equal (point) company-point)
1452             (company-begin))
1453           (if company-candidates
1454               (company-call-frontends 'post-command)
1455             (and (numberp company-idle-delay)
1456                  (or (eq t company-begin-commands)
1457                      (memq this-command company-begin-commands))
1458                  (not (equal (point) company-point))
1459                  (setq company-timer
1460                        (run-with-timer company-idle-delay nil
1461                                        'company-idle-begin
1462                                        (current-buffer) (selected-window)
1463                                        (buffer-chars-modified-tick) (point))))))
1464       (error (message "Company: An error occurred in post-command")
1465              (message "%s" (error-message-string err))
1466              (company-cancel))))
1467   (company-install-map))
1468
1469 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1470
1471 (defvar company-search-string nil)
1472 (make-variable-buffer-local 'company-search-string)
1473
1474 (defvar company-search-lighter " Search: \"\"")
1475 (make-variable-buffer-local 'company-search-lighter)
1476
1477 (defvar company-search-old-map nil)
1478 (make-variable-buffer-local 'company-search-old-map)
1479
1480 (defvar company-search-old-selection 0)
1481 (make-variable-buffer-local 'company-search-old-selection)
1482
1483 (defun company-search (text lines)
1484   (let ((quoted (regexp-quote text))
1485         (i 0))
1486     (dolist (line lines)
1487       (when (string-match quoted line (length company-prefix))
1488         (return i))
1489       (incf i))))
1490
1491 (defun company-search-printing-char ()
1492   (interactive)
1493   (company-search-assert-enabled)
1494   (setq company-search-string
1495         (concat (or company-search-string "") (string last-command-event))
1496         company-search-lighter (concat " Search: \"" company-search-string
1497                                         "\""))
1498   (let ((pos (company-search company-search-string
1499                               (nthcdr company-selection company-candidates))))
1500     (if (null pos)
1501         (ding)
1502       (company-set-selection (+ company-selection pos) t))))
1503
1504 (defun company-search-repeat-forward ()
1505   "Repeat the incremental search in completion candidates forward."
1506   (interactive)
1507   (company-search-assert-enabled)
1508   (let ((pos (company-search company-search-string
1509                               (cdr (nthcdr company-selection
1510                                            company-candidates)))))
1511     (if (null pos)
1512         (ding)
1513       (company-set-selection (+ company-selection pos 1) t))))
1514
1515 (defun company-search-repeat-backward ()
1516   "Repeat the incremental search in completion candidates backwards."
1517   (interactive)
1518   (company-search-assert-enabled)
1519   (let ((pos (company-search company-search-string
1520                               (nthcdr (- company-candidates-length
1521                                          company-selection)
1522                                       (reverse company-candidates)))))
1523     (if (null pos)
1524         (ding)
1525       (company-set-selection (- company-selection pos 1) t))))
1526
1527 (defun company-create-match-predicate ()
1528   (setq company-candidates-predicate
1529         `(lambda (candidate)
1530            ,(if company-candidates-predicate
1531                 `(and (string-match ,company-search-string candidate)
1532                       (funcall ,company-candidates-predicate
1533                                candidate))
1534               `(string-match ,company-search-string candidate))))
1535   (company-update-candidates
1536    (company-apply-predicate company-candidates company-candidates-predicate))
1537   ;; Invalidate cache.
1538   (setq company-candidates-cache (cons company-prefix company-candidates)))
1539
1540 (defun company-filter-printing-char ()
1541   (interactive)
1542   (company-search-assert-enabled)
1543   (company-search-printing-char)
1544   (company-create-match-predicate)
1545   (company-call-frontends 'update))
1546
1547 (defun company-search-kill-others ()
1548   "Limit the completion candidates to the ones matching the search string."
1549   (interactive)
1550   (company-search-assert-enabled)
1551   (company-create-match-predicate)
1552   (company-search-mode 0)
1553   (company-call-frontends 'update))
1554
1555 (defun company-search-abort ()
1556   "Abort searching the completion candidates."
1557   (interactive)
1558   (company-search-assert-enabled)
1559   (company-set-selection company-search-old-selection t)
1560   (company-search-mode 0))
1561
1562 (defun company-search-other-char ()
1563   (interactive)
1564   (company-search-assert-enabled)
1565   (company-search-mode 0)
1566   (company--unread-last-input))
1567
1568 (defvar company-search-map
1569   (let ((i 0)
1570         (keymap (make-keymap)))
1571     (if (fboundp 'max-char)
1572         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1573                               'company-search-printing-char)
1574       (with-no-warnings
1575         ;; obsolete in Emacs 23
1576         (let ((l (generic-character-list))
1577               (table (nth 1 keymap)))
1578           (while l
1579             (set-char-table-default table (car l) 'company-search-printing-char)
1580             (setq l (cdr l))))))
1581     (define-key keymap [t] 'company-search-other-char)
1582     (while (< i ?\s)
1583       (define-key keymap (make-string 1 i) 'company-search-other-char)
1584       (incf i))
1585     (while (< i 256)
1586       (define-key keymap (vector i) 'company-search-printing-char)
1587       (incf i))
1588     (let ((meta-map (make-sparse-keymap)))
1589       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1590       (define-key keymap [escape] meta-map))
1591     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1592     (define-key keymap "\e\e\e" 'company-search-other-char)
1593     (define-key keymap  [escape escape escape] 'company-search-other-char)
1594
1595     (define-key keymap "\C-g" 'company-search-abort)
1596     (define-key keymap "\C-s" 'company-search-repeat-forward)
1597     (define-key keymap "\C-r" 'company-search-repeat-backward)
1598     (define-key keymap "\C-o" 'company-search-kill-others)
1599     keymap)
1600   "Keymap used for incrementally searching the completion candidates.")
1601
1602 (define-minor-mode company-search-mode
1603   "Search mode for completion candidates.
1604 Don't start this directly, use `company-search-candidates' or
1605 `company-filter-candidates'."
1606   nil company-search-lighter nil
1607   (if company-search-mode
1608       (if (company-manual-begin)
1609           (progn
1610             (setq company-search-old-selection company-selection)
1611             (company-call-frontends 'update))
1612         (setq company-search-mode nil))
1613     (kill-local-variable 'company-search-string)
1614     (kill-local-variable 'company-search-lighter)
1615     (kill-local-variable 'company-search-old-selection)
1616     (company-enable-overriding-keymap company-active-map)))
1617
1618 (defun company-search-assert-enabled ()
1619   (company-assert-enabled)
1620   (unless company-search-mode
1621     (company-uninstall-map)
1622     (error "Company not in search mode")))
1623
1624 (defun company-search-candidates ()
1625   "Start searching the completion candidates incrementally.
1626
1627 \\<company-search-map>Search can be controlled with the commands:
1628 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1629 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1630 - `company-search-abort' (\\[company-search-abort])
1631
1632 Regular characters are appended to the search string.
1633
1634 The command `company-search-kill-others' (\\[company-search-kill-others])
1635 uses the search string to limit the completion candidates."
1636   (interactive)
1637   (company-search-mode 1)
1638   (company-enable-overriding-keymap company-search-map))
1639
1640 (defvar company-filter-map
1641   (let ((keymap (make-keymap)))
1642     (define-key keymap [remap company-search-printing-char]
1643       'company-filter-printing-char)
1644     (set-keymap-parent keymap company-search-map)
1645     keymap)
1646   "Keymap used for incrementally searching the completion candidates.")
1647
1648 (defun company-filter-candidates ()
1649   "Start filtering the completion candidates incrementally.
1650 This works the same way as `company-search-candidates' immediately
1651 followed by `company-search-kill-others' after each input."
1652   (interactive)
1653   (company-search-mode 1)
1654   (company-enable-overriding-keymap company-filter-map))
1655
1656 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1657
1658 (defun company-select-next ()
1659   "Select the next candidate in the list."
1660   (interactive)
1661   (when (company-manual-begin)
1662     (company-set-selection (1+ company-selection))))
1663
1664 (defun company-select-previous ()
1665   "Select the previous candidate in the list."
1666   (interactive)
1667   (when (company-manual-begin)
1668     (company-set-selection (1- company-selection))))
1669
1670 (defun company-select-next-or-abort ()
1671   "Select the next candidate if more than one, else abort
1672 and invoke the normal binding."
1673   (interactive)
1674   (if (> company-candidates-length 1)
1675       (company-select-next)
1676     (company-abort)
1677     (company--unread-last-input)))
1678
1679 (defun company-select-previous-or-abort ()
1680   "Select the previous candidate if more than one, else abort
1681 and invoke the normal binding."
1682   (interactive)
1683   (if (> company-candidates-length 1)
1684       (company-select-previous)
1685     (company-abort)
1686     (company--unread-last-input)))
1687
1688 (defvar company-pseudo-tooltip-overlay)
1689
1690 (defvar company-tooltip-offset)
1691
1692 (defun company--inside-tooltip-p (event-col-row row height)
1693   (let* ((ovl company-pseudo-tooltip-overlay)
1694          (column (overlay-get ovl 'company-column))
1695          (width (overlay-get ovl 'company-width))
1696          (evt-col (car event-col-row))
1697          (evt-row (cdr event-col-row)))
1698     (and (>= evt-col column)
1699          (< evt-col (+ column width))
1700          (if (> height 0)
1701              (and (> evt-row row)
1702                   (<= evt-row (+ row height) ))
1703            (and (< evt-row row)
1704                 (>= evt-row (+ row height)))))))
1705
1706 (defun company--event-col-row (event)
1707   (let* ((col-row (posn-actual-col-row (event-start event)))
1708          (col (car col-row))
1709          (row (cdr col-row)))
1710     (incf col (window-hscroll))
1711     (and header-line-format
1712          (version< "24" emacs-version)
1713          (decf row))
1714     (cons col row)))
1715
1716 (defun company-select-mouse (event)
1717   "Select the candidate picked by the mouse."
1718   (interactive "e")
1719   (let ((event-col-row (company--event-col-row event))
1720         (ovl-row (company--row))
1721         (ovl-height (and company-pseudo-tooltip-overlay
1722                          (min (overlay-get company-pseudo-tooltip-overlay
1723                                            'company-height)
1724                               company-candidates-length))))
1725     (if (and ovl-height
1726              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1727         (progn
1728           (company-set-selection (+ (cdr event-col-row)
1729                                     (1- company-tooltip-offset)
1730                                     (if (and (eq company-tooltip-offset-display 'lines)
1731                                              (not (zerop company-tooltip-offset)))
1732                                         -1 0)
1733                                     (- ovl-row)
1734                                     (if (< ovl-height 0)
1735                                         (- 1 ovl-height)
1736                                       0)))
1737           t)
1738       (company-abort)
1739       (company--unread-last-input)
1740       nil)))
1741
1742 (defun company-complete-mouse (event)
1743   "Insert the candidate picked by the mouse."
1744   (interactive "e")
1745   (when (company-select-mouse event)
1746     (company-complete-selection)))
1747
1748 (defun company-complete-selection ()
1749   "Insert the selected candidate."
1750   (interactive)
1751   (when (company-manual-begin)
1752     (let ((result (nth company-selection company-candidates)))
1753       (company-finish result))))
1754
1755 (defun company-complete-common ()
1756   "Insert the common part of all candidates."
1757   (interactive)
1758   (when (company-manual-begin)
1759     (if (and (not (cdr company-candidates))
1760              (equal company-common (car company-candidates)))
1761         (company-complete-selection)
1762       (when company-common
1763         (company--insert-candidate company-common)))))
1764
1765 (defun company-complete ()
1766   "Insert the common part of all candidates or the current selection.
1767 The first time this is called, the common part is inserted, the second
1768 time, or when the selection has been changed, the selected candidate is
1769 inserted."
1770   (interactive)
1771   (when (company-manual-begin)
1772     (if (or company-selection-changed
1773             (eq last-command 'company-complete-common))
1774         (call-interactively 'company-complete-selection)
1775       (call-interactively 'company-complete-common)
1776       (setq this-command 'company-complete-common))))
1777
1778 (defun company-complete-number (n)
1779   "Insert the Nth candidate.
1780 To show the number next to the candidates in some back-ends, enable
1781 `company-show-numbers'."
1782   (when (company-manual-begin)
1783     (and (< n 1) (> n company-candidates-length)
1784          (error "No candidate number %d" n))
1785     (decf n)
1786     (company-finish (nth n company-candidates))))
1787
1788 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1789
1790 (defconst company-space-strings-limit 100)
1791
1792 (defconst company-space-strings
1793   (let (lst)
1794     (dotimes (i company-space-strings-limit)
1795       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1796     (apply 'vector lst)))
1797
1798 (defun company-space-string (len)
1799   (if (< len company-space-strings-limit)
1800       (aref company-space-strings len)
1801     (make-string len ?\ )))
1802
1803 (defun company-safe-substring (str from &optional to)
1804   (if (> from (string-width str))
1805       ""
1806     (with-temp-buffer
1807       (insert str)
1808       (move-to-column from)
1809       (let ((beg (point)))
1810         (if to
1811             (progn
1812               (move-to-column to)
1813               (concat (buffer-substring beg (point))
1814                       (let ((padding (- to (current-column))))
1815                         (when (> padding 0)
1816                           (company-space-string padding)))))
1817           (buffer-substring beg (point-max)))))))
1818
1819 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1820
1821 (defvar company-last-metadata nil)
1822 (make-variable-buffer-local 'company-last-metadata)
1823
1824 (defun company-fetch-metadata ()
1825   (let ((selected (nth company-selection company-candidates)))
1826     (unless (eq selected (car company-last-metadata))
1827       (setq company-last-metadata
1828             (cons selected (company-call-backend 'meta selected))))
1829     (cdr company-last-metadata)))
1830
1831 (defun company-doc-buffer (&optional string)
1832   (with-current-buffer (get-buffer-create "*company-documentation*")
1833     (erase-buffer)
1834     (when string
1835       (save-excursion
1836         (insert string)))
1837     (current-buffer)))
1838
1839 (defvar company--electric-commands
1840   '(scroll-other-window scroll-other-window-down)
1841   "List of Commands that won't break out of electric commands.")
1842
1843 (defmacro company--electric-do (&rest body)
1844   (declare (indent 0) (debug t))
1845   `(when (company-manual-begin)
1846      (save-window-excursion
1847        (let ((height (window-height))
1848              (row (company--row))
1849              cmd)
1850          ,@body
1851          (and (< (window-height) height)
1852               (< (- (window-height) row 2) company-tooltip-limit)
1853               (recenter (- (window-height) row 2)))
1854          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1855                       company--electric-commands)
1856            (call-interactively cmd))
1857          (company--unread-last-input)))))
1858
1859 (defun company--unread-last-input ()
1860   (when last-input-event
1861     (clear-this-command-keys t)
1862     (setq unread-command-events (list last-input-event))))
1863
1864 (defun company-show-doc-buffer ()
1865   "Temporarily show the documentation buffer for the selection."
1866   (interactive)
1867   (company--electric-do
1868     (let* ((selected (nth company-selection company-candidates))
1869            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1870                            (error "No documentation available"))))
1871       (with-current-buffer doc-buffer
1872         (goto-char (point-min)))
1873       (display-buffer doc-buffer t))))
1874 (put 'company-show-doc-buffer 'company-keep t)
1875
1876 (defun company-show-location ()
1877   "Temporarily display a buffer showing the selected candidate in context."
1878   (interactive)
1879   (company--electric-do
1880     (let* ((selected (nth company-selection company-candidates))
1881            (location (company-call-backend 'location selected))
1882            (pos (or (cdr location) (error "No location available")))
1883            (buffer (or (and (bufferp (car location)) (car location))
1884                        (find-file-noselect (car location) t))))
1885       (with-selected-window (display-buffer buffer t)
1886         (save-restriction
1887           (widen)
1888           (if (bufferp (car location))
1889               (goto-char pos)
1890             (goto-char (point-min))
1891             (forward-line (1- pos))))
1892         (set-window-start nil (point))))))
1893 (put 'company-show-location 'company-keep t)
1894
1895 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1896
1897 (defvar company-callback nil)
1898 (make-variable-buffer-local 'company-callback)
1899
1900 (defun company-remove-callback (&optional ignored)
1901   (remove-hook 'company-completion-finished-hook company-callback t)
1902   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1903   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
1904
1905 (defun company-begin-backend (backend &optional callback)
1906   "Start a completion at point using BACKEND."
1907   (interactive (let ((val (completing-read "Company back-end: "
1908                                            obarray
1909                                            'functionp nil "company-")))
1910                  (when val
1911                    (list (intern val)))))
1912   (when (setq company-callback callback)
1913     (add-hook 'company-completion-finished-hook company-callback nil t))
1914   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1915   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1916   (setq company-backend backend)
1917   ;; Return non-nil if active.
1918   (or (company-manual-begin)
1919       (error "Cannot complete at point")))
1920
1921 (defun company-begin-with (candidates
1922                            &optional prefix-length require-match callback)
1923   "Start a completion at point.
1924 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
1925 of the prefix that already is in the buffer before point.
1926 It defaults to 0.
1927
1928 CALLBACK is a function called with the selected result if the user
1929 successfully completes the input.
1930
1931 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
1932   (let ((begin-marker (copy-marker (point) t)))
1933     (company-begin-backend
1934      (lambda (command &optional arg &rest ignored)
1935        (pcase command
1936         (`prefix
1937          (when (equal (point) (marker-position begin-marker))
1938            (buffer-substring (- (point) (or prefix-length 0)) (point))))
1939         (`candidates
1940          (all-completions arg candidates))
1941         (`require-match
1942          require-match)))
1943      callback)))
1944
1945 (defun company-version (&optional show-version)
1946   "Get the Company version as string.
1947
1948 If SHOW-VERSION is non-nil, show the version in the echo area."
1949   (interactive (list t))
1950   (with-temp-buffer
1951     (insert-file-contents (find-library-name "company"))
1952     (require 'lisp-mnt)
1953     (if show-version
1954         (message "Company version: %s" (lm-version))
1955       (lm-version))))
1956
1957 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1958
1959 (defvar company-pseudo-tooltip-overlay nil)
1960 (make-variable-buffer-local 'company-pseudo-tooltip-overlay)
1961
1962 (defvar company-tooltip-offset 0)
1963 (make-variable-buffer-local 'company-tooltip-offset)
1964
1965 (defun company-tooltip--lines-update-offset (selection num-lines limit)
1966   (decf limit 2)
1967   (setq company-tooltip-offset
1968         (max (min selection company-tooltip-offset)
1969              (- selection -1 limit)))
1970
1971   (when (<= company-tooltip-offset 1)
1972     (incf limit)
1973     (setq company-tooltip-offset 0))
1974
1975   (when (>= company-tooltip-offset (- num-lines limit 1))
1976     (incf limit)
1977     (when (= selection (1- num-lines))
1978       (decf company-tooltip-offset)
1979       (when (<= company-tooltip-offset 1)
1980         (setq company-tooltip-offset 0)
1981         (incf limit))))
1982
1983   limit)
1984
1985 (defun company-tooltip--simple-update-offset (selection num-lines limit)
1986   (setq company-tooltip-offset
1987         (if (< selection company-tooltip-offset)
1988             selection
1989           (max company-tooltip-offset
1990                (- selection limit -1)))))
1991
1992 ;;; propertize
1993
1994 (defsubst company-round-tab (arg)
1995   (* (/ (+ arg tab-width) tab-width) tab-width))
1996
1997 (defun company-plainify (str)
1998   (let ((prefix (get-text-property 0 'line-prefix str)))
1999     (when prefix ; Keep the original value unmodified, for no special reason.
2000       (setq str (concat prefix str))
2001       (remove-text-properties 0 (length str) '(line-prefix) str)))
2002   (let* ((pieces (split-string str "\t"))
2003          (copy pieces))
2004     (while (cdr copy)
2005       (setcar copy (company-safe-substring
2006                     (car copy) 0 (company-round-tab (string-width (car copy)))))
2007       (pop copy))
2008     (apply 'concat pieces)))
2009
2010 (defun company-fill-propertize (value annotation width selected left right)
2011   (let* ((margin (length left))
2012          (common (+ (or (company-call-backend 'match value)
2013                         (length company-common)) margin))
2014          (ann-ralign company-tooltip-align-annotations)
2015          (ann-truncate (< width
2016                           (+ (length value) (length annotation)
2017                              (if ann-ralign 1 0))))
2018          (ann-start (+ margin
2019                        (if ann-ralign
2020                            (if ann-truncate
2021                                (1+ (length value))
2022                              (- width (length annotation)))
2023                          (length value))))
2024          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
2025          (line (concat left
2026                        (if (or ann-truncate (not ann-ralign))
2027                            (company-safe-substring
2028                             (concat value
2029                                     (when (and annotation ann-ralign) " ")
2030                                     annotation)
2031                             0 width)
2032                          (concat
2033                           (company-safe-substring value 0
2034                                                   (- width (length annotation)))
2035                           annotation))
2036                        right)))
2037     (setq width (+ width margin (length right)))
2038
2039     (add-text-properties 0 width '(face company-tooltip
2040                                    mouse-face company-tooltip-mouse)
2041                          line)
2042     (add-text-properties margin common
2043                          '(face company-tooltip-common
2044                            mouse-face company-tooltip-mouse)
2045                          line)
2046     (when (< ann-start ann-end)
2047       (add-text-properties ann-start ann-end
2048                            '(face company-tooltip-annotation
2049                              mouse-face company-tooltip-mouse)
2050                            line))
2051     (when selected
2052       (if (and company-search-string
2053                (string-match (regexp-quote company-search-string) value
2054                              (length company-prefix)))
2055           (let ((beg (+ margin (match-beginning 0)))
2056                 (end (+ margin (match-end 0))))
2057             (add-text-properties beg end '(face company-tooltip-selection)
2058                                  line)
2059             (when (< beg common)
2060               (add-text-properties beg common
2061                                    '(face company-tooltip-common-selection)
2062                                    line)))
2063         (add-text-properties 0 width '(face company-tooltip-selection
2064                                        mouse-face company-tooltip-selection)
2065                              line)
2066         (add-text-properties margin common
2067                              '(face company-tooltip-common-selection
2068                                mouse-face company-tooltip-selection)
2069                              line)))
2070     line))
2071
2072 ;;; replace
2073
2074 (defun company-buffer-lines (beg end)
2075   (goto-char beg)
2076   (let (lines)
2077     (while (and (= 1 (vertical-motion 1))
2078                 (<= (point) end))
2079       (let ((bound (min end (1- (point)))))
2080         ;; A visual line can contain several physical lines (e.g. with outline's
2081         ;; folding overlay).  Take only the first one.
2082         (push (buffer-substring beg
2083                                 (save-excursion
2084                                   (goto-char beg)
2085                                   (re-search-forward "$" bound 'move)
2086                                   (point)))
2087               lines))
2088       (setq beg (point)))
2089     (unless (eq beg end)
2090       (push (buffer-substring beg end) lines))
2091     (nreverse lines)))
2092
2093 (defun company-modify-line (old new offset)
2094   (concat (company-safe-substring old 0 offset)
2095           new
2096           (company-safe-substring old (+ offset (length new)))))
2097
2098 (defsubst company--length-limit (lst limit)
2099   (if (nthcdr limit lst)
2100       limit
2101     (length lst)))
2102
2103 (defun company--replacement-string (lines old column nl &optional align-top)
2104   (decf column company-tooltip-margin)
2105
2106   (let ((width (length (car lines)))
2107         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2108                            column)))
2109     (when (> width remaining-cols)
2110       (decf column (- width remaining-cols))))
2111
2112   (let ((offset (and (< column 0) (- column)))
2113         new)
2114     (when offset
2115       (setq column 0))
2116     (when align-top
2117       ;; untouched lines first
2118       (dotimes (_ (- (length old) (length lines)))
2119         (push (pop old) new)))
2120     ;; length into old lines.
2121     (while old
2122       (push (company-modify-line (pop old)
2123                                  (company--offset-line (pop lines) offset)
2124                                  column) new))
2125     ;; Append whole new lines.
2126     (while lines
2127       (push (concat (company-space-string column)
2128                     (company--offset-line (pop lines) offset))
2129             new))
2130
2131     (let ((str (concat (when nl "\n")
2132                        (mapconcat 'identity (nreverse new) "\n")
2133                        "\n")))
2134       (font-lock-append-text-property 0 (length str) 'face 'default str)
2135       str)))
2136
2137 (defun company--offset-line (line offset)
2138   (if (and offset line)
2139       (substring line offset)
2140     line))
2141
2142 (defun company--create-lines (selection limit)
2143   (let ((len company-candidates-length)
2144         (numbered 99999)
2145         (window-width (company--window-width))
2146         lines
2147         width
2148         lines-copy
2149         items
2150         previous
2151         remainder
2152         scrollbar-bounds)
2153
2154     ;; Maybe clear old offset.
2155     (when (< len (+ company-tooltip-offset limit))
2156       (setq company-tooltip-offset 0))
2157
2158     ;; Scroll to offset.
2159     (if (eq company-tooltip-offset-display 'lines)
2160         (setq limit (company-tooltip--lines-update-offset selection len limit))
2161       (company-tooltip--simple-update-offset selection len limit))
2162
2163     (cond
2164      ((eq company-tooltip-offset-display 'scrollbar)
2165       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2166                                                         limit len)))
2167      ((eq company-tooltip-offset-display 'lines)
2168       (when (> company-tooltip-offset 0)
2169         (setq previous (format "...(%d)" company-tooltip-offset)))
2170       (setq remainder (- len limit company-tooltip-offset)
2171             remainder (when (> remainder 0)
2172                         (setq remainder (format "...(%d)" remainder))))))
2173
2174     (decf selection company-tooltip-offset)
2175     (setq width (max (length previous) (length remainder))
2176           lines (nthcdr company-tooltip-offset company-candidates)
2177           len (min limit len)
2178           lines-copy lines)
2179
2180     (decf window-width (* 2 company-tooltip-margin))
2181     (when scrollbar-bounds (decf window-width))
2182
2183     (dotimes (_ len)
2184       (let* ((value (pop lines-copy))
2185              (annotation (company-call-backend 'annotation value)))
2186         (when (and annotation company-tooltip-align-annotations)
2187           ;; `lisp-completion-at-point' adds a space.
2188           (setq annotation (comment-string-strip annotation t nil)))
2189         (push (cons value annotation) items)
2190         (setq width (max (+ (length value)
2191                             (if (and annotation company-tooltip-align-annotations)
2192                                 (1+ (length annotation))
2193                               (length annotation)))
2194                          width))))
2195
2196     (setq width (min window-width
2197                      (if (and company-show-numbers
2198                               (< company-tooltip-offset 10))
2199                          (+ 2 width)
2200                        width)))
2201
2202     ;; number can make tooltip too long
2203     (when company-show-numbers
2204       (setq numbered company-tooltip-offset))
2205
2206     (let ((items (nreverse items)) new)
2207       (when previous
2208         (push (company--scrollpos-line previous width) new))
2209
2210       (dotimes (i len)
2211         (let* ((item (pop items))
2212                (str (company-reformat (car item)))
2213                (annotation (cdr item))
2214                (right (company-space-string company-tooltip-margin))
2215                (width width))
2216           (when (< numbered 10)
2217             (decf width 2)
2218             (incf numbered)
2219             (setq right (concat (format " %d" (mod numbered 10)) right)))
2220           (push (concat
2221                  (company-fill-propertize str annotation
2222                                           width (equal i selection)
2223                                           (company-space-string
2224                                            company-tooltip-margin)
2225                                           right)
2226                  (when scrollbar-bounds
2227                    (company--scrollbar i scrollbar-bounds)))
2228                 new)))
2229
2230       (when remainder
2231         (push (company--scrollpos-line remainder width) new))
2232
2233       (nreverse new))))
2234
2235 (defun company--scrollbar-bounds (offset limit length)
2236   (when (> length limit)
2237     (let* ((size (ceiling (* limit (float limit)) length))
2238            (lower (floor (* limit (float offset)) length))
2239            (upper (+ lower size -1)))
2240       (cons lower upper))))
2241
2242 (defun company--scrollbar (i bounds)
2243   (propertize " " 'face
2244               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2245                   'company-scrollbar-fg
2246                 'company-scrollbar-bg)))
2247
2248 (defun company--scrollpos-line (text width)
2249   (propertize (concat (company-space-string company-tooltip-margin)
2250                       (company-safe-substring text 0 width)
2251                       (company-space-string company-tooltip-margin))
2252    'face 'company-tooltip))
2253
2254 ;; show
2255
2256 (defsubst company--window-inner-height ()
2257   (let ((edges (window-inside-edges)))
2258     (- (nth 3 edges) (nth 1 edges))))
2259
2260 (defsubst company--window-width ()
2261   (- (window-width)
2262      (cond
2263       ((display-graphic-p) 0)
2264       ;; Account for the line continuation column.
2265       ((version< "24.3.1" emacs-version) 1)
2266       ;; Emacs 24.3 and earlier included margins
2267       ;; in window-width when in TTY.
2268       (t (1+ (let ((margins (window-margins)))
2269                (+ (or (car margins) 0)
2270                   (or (cdr margins) 0))))))))
2271
2272 (defun company--pseudo-tooltip-height ()
2273   "Calculate the appropriate tooltip height.
2274 Returns a negative number if the tooltip should be displayed above point."
2275   (let* ((lines (company--row))
2276          (below (- (company--window-inner-height) 1 lines)))
2277     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2278              (> lines below))
2279         (- (max 3 (min company-tooltip-limit lines)))
2280       (max 3 (min company-tooltip-limit below)))))
2281
2282 (defun company-pseudo-tooltip-show (row column selection)
2283   (company-pseudo-tooltip-hide)
2284   (save-excursion
2285
2286     (let* ((height (company--pseudo-tooltip-height))
2287            above)
2288
2289       (when (< height 0)
2290         (setq row (+ row height -1)
2291               above t))
2292
2293       (let* ((nl (< (move-to-window-line row) row))
2294              (beg (point))
2295              (end (save-excursion
2296                     (move-to-window-line (+ row (abs height)))
2297                     (point)))
2298              (ov (make-overlay beg end))
2299              (args (list (mapcar 'company-plainify
2300                                  (company-buffer-lines beg end))
2301                          column nl above)))
2302
2303         (setq company-pseudo-tooltip-overlay ov)
2304         (overlay-put ov 'company-replacement-args args)
2305
2306         (let ((lines (company--create-lines selection (abs height))))
2307           (overlay-put ov 'company-after
2308                        (apply 'company--replacement-string lines args))
2309           (overlay-put ov 'company-width (string-width (car lines))))
2310
2311         (overlay-put ov 'company-column column)
2312         (overlay-put ov 'company-height height)))))
2313
2314 (defun company-pseudo-tooltip-show-at-point (pos)
2315   (let ((row (company--row pos))
2316         (col (company--column pos)))
2317     (company-pseudo-tooltip-show (1+ row) col company-selection)))
2318
2319 (defun company-pseudo-tooltip-edit (selection)
2320   (let ((height (overlay-get company-pseudo-tooltip-overlay 'company-height)))
2321     (overlay-put company-pseudo-tooltip-overlay 'company-after
2322                  (apply 'company--replacement-string
2323                         (company--create-lines selection (abs height))
2324                         (overlay-get company-pseudo-tooltip-overlay
2325                                      'company-replacement-args)))))
2326
2327 (defun company-pseudo-tooltip-hide ()
2328   (when company-pseudo-tooltip-overlay
2329     (delete-overlay company-pseudo-tooltip-overlay)
2330     (setq company-pseudo-tooltip-overlay nil)))
2331
2332 (defun company-pseudo-tooltip-hide-temporarily ()
2333   (when (overlayp company-pseudo-tooltip-overlay)
2334     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2335     (overlay-put company-pseudo-tooltip-overlay 'line-prefix nil)
2336     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)))
2337
2338 (defun company-pseudo-tooltip-unhide ()
2339   (when company-pseudo-tooltip-overlay
2340     (overlay-put company-pseudo-tooltip-overlay 'invisible t)
2341     ;; Beat outline's folding overlays, at least.
2342     (overlay-put company-pseudo-tooltip-overlay 'priority 1)
2343     ;; No (extra) prefix for the first line.
2344     (overlay-put company-pseudo-tooltip-overlay 'line-prefix "")
2345     (overlay-put company-pseudo-tooltip-overlay 'after-string
2346                  (overlay-get company-pseudo-tooltip-overlay 'company-after))
2347     (overlay-put company-pseudo-tooltip-overlay 'window (selected-window))))
2348
2349 (defun company-pseudo-tooltip-guard ()
2350   (buffer-substring-no-properties
2351    (point) (overlay-start company-pseudo-tooltip-overlay)))
2352
2353 (defun company-pseudo-tooltip-frontend (command)
2354   "`company-mode' front-end similar to a tooltip but based on overlays."
2355   (case command
2356     (pre-command (company-pseudo-tooltip-hide-temporarily))
2357     (post-command
2358      (let ((old-height (if (overlayp company-pseudo-tooltip-overlay)
2359                            (overlay-get company-pseudo-tooltip-overlay
2360                                         'company-height)
2361                          0))
2362            (new-height (company--pseudo-tooltip-height)))
2363        (unless (and (>= (* old-height new-height) 0)
2364                     (>= (abs old-height) (abs new-height))
2365                     (equal (company-pseudo-tooltip-guard)
2366                            (overlay-get company-pseudo-tooltip-overlay
2367                                         'company-guard)))
2368          ;; Redraw needed.
2369          (company-pseudo-tooltip-show-at-point (- (point)
2370                                                   (length company-prefix)))
2371          (overlay-put company-pseudo-tooltip-overlay
2372                       'company-guard (company-pseudo-tooltip-guard))))
2373      (company-pseudo-tooltip-unhide))
2374     (hide (company-pseudo-tooltip-hide)
2375           (setq company-tooltip-offset 0))
2376     (update (when (overlayp company-pseudo-tooltip-overlay)
2377               (company-pseudo-tooltip-edit company-selection)))))
2378
2379 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2380   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2381   (unless (and (eq command 'post-command)
2382                (company--show-inline-p))
2383     (company-pseudo-tooltip-frontend command)))
2384
2385 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2386
2387 (defvar company-preview-overlay nil)
2388 (make-variable-buffer-local 'company-preview-overlay)
2389
2390 (defun company-preview-show-at-point (pos)
2391   (company-preview-hide)
2392
2393   (setq company-preview-overlay (make-overlay pos (1+ pos)))
2394
2395   (let ((completion (nth company-selection company-candidates)))
2396     (setq completion (propertize completion 'face 'company-preview))
2397     (add-text-properties 0 (length company-common)
2398                          '(face company-preview-common) completion)
2399
2400     ;; Add search string
2401     (and company-search-string
2402          (string-match (regexp-quote company-search-string) completion)
2403          (add-text-properties (match-beginning 0)
2404                               (match-end 0)
2405                               '(face company-preview-search)
2406                               completion))
2407
2408     (setq completion (company-strip-prefix completion))
2409
2410     (and (equal pos (point))
2411          (not (equal completion ""))
2412          (add-text-properties 0 1 '(cursor t) completion))
2413
2414     (overlay-put company-preview-overlay 'display
2415                  (concat completion (unless (eq pos (point-max))
2416                                       (buffer-substring pos (1+ pos)))))
2417     (overlay-put company-preview-overlay 'window (selected-window))))
2418
2419 (defun company-preview-hide ()
2420   (when company-preview-overlay
2421     (delete-overlay company-preview-overlay)
2422     (setq company-preview-overlay nil)))
2423
2424 (defun company-preview-frontend (command)
2425   "`company-mode' front-end showing the selection as if it had been inserted."
2426   (pcase command
2427     (`pre-command (company-preview-hide))
2428     (`post-command (company-preview-show-at-point (point)))
2429     (`hide (company-preview-hide))))
2430
2431 (defun company-preview-if-just-one-frontend (command)
2432   "`company-preview-frontend', but only shown for single candidates."
2433   (when (or (not (eq command 'post-command))
2434             (company--show-inline-p))
2435     (company-preview-frontend command)))
2436
2437 (defun company--show-inline-p ()
2438   (and (not (cdr company-candidates))
2439        company-common
2440        (string-prefix-p company-prefix company-common
2441                         (company-call-backend 'ignore-case))))
2442
2443 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2444
2445 (defvar company-echo-last-msg nil)
2446 (make-variable-buffer-local 'company-echo-last-msg)
2447
2448 (defvar company-echo-timer nil)
2449
2450 (defvar company-echo-delay .01)
2451
2452 (defun company-echo-show (&optional getter)
2453   (when getter
2454     (setq company-echo-last-msg (funcall getter)))
2455   (let ((message-log-max nil))
2456     (if company-echo-last-msg
2457         (message "%s" company-echo-last-msg)
2458       (message ""))))
2459
2460 (defun company-echo-show-soon (&optional getter)
2461   (when company-echo-timer
2462     (cancel-timer company-echo-timer))
2463   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2464
2465 (defsubst company-echo-show-when-idle (&optional getter)
2466   (when (sit-for company-echo-delay)
2467     (company-echo-show getter)))
2468
2469 (defun company-echo-format ()
2470
2471   (let ((limit (window-width (minibuffer-window)))
2472         (len -1)
2473         ;; Roll to selection.
2474         (candidates (nthcdr company-selection company-candidates))
2475         (i (if company-show-numbers company-selection 99999))
2476         comp msg)
2477
2478     (while candidates
2479       (setq comp (company-reformat (pop candidates))
2480             len (+ len 1 (length comp)))
2481       (if (< i 10)
2482           ;; Add number.
2483           (progn
2484             (setq comp (propertize (format "%d: %s" i comp)
2485                                    'face 'company-echo))
2486             (incf len 3)
2487             (incf i)
2488             (add-text-properties 3 (+ 3 (length company-common))
2489                                  '(face company-echo-common) comp))
2490         (setq comp (propertize comp 'face 'company-echo))
2491         (add-text-properties 0 (length company-common)
2492                              '(face company-echo-common) comp))
2493       (if (>= len limit)
2494           (setq candidates nil)
2495         (push comp msg)))
2496
2497     (mapconcat 'identity (nreverse msg) " ")))
2498
2499 (defun company-echo-strip-common-format ()
2500
2501   (let ((limit (window-width (minibuffer-window)))
2502         (len (+ (length company-prefix) 2))
2503         ;; Roll to selection.
2504         (candidates (nthcdr company-selection company-candidates))
2505         (i (if company-show-numbers company-selection 99999))
2506         msg comp)
2507
2508     (while candidates
2509       (setq comp (company-strip-prefix (pop candidates))
2510             len (+ len 2 (length comp)))
2511       (when (< i 10)
2512         ;; Add number.
2513         (setq comp (format "%s (%d)" comp i))
2514         (incf len 4)
2515         (incf i))
2516       (if (>= len limit)
2517           (setq candidates nil)
2518         (push (propertize comp 'face 'company-echo) msg)))
2519
2520     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2521             (mapconcat 'identity (nreverse msg) ", ")
2522             "}")))
2523
2524 (defun company-echo-hide ()
2525   (unless (equal company-echo-last-msg "")
2526     (setq company-echo-last-msg "")
2527     (company-echo-show)))
2528
2529 (defun company-echo-frontend (command)
2530   "`company-mode' front-end showing the candidates in the echo area."
2531   (pcase command
2532     (`post-command (company-echo-show-soon 'company-echo-format))
2533     (`hide (company-echo-hide))))
2534
2535 (defun company-echo-strip-common-frontend (command)
2536   "`company-mode' front-end showing the candidates in the echo area."
2537   (pcase command
2538     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2539     (`hide (company-echo-hide))))
2540
2541 (defun company-echo-metadata-frontend (command)
2542   "`company-mode' front-end showing the documentation in the echo area."
2543   (pcase command
2544     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
2545     (`hide (company-echo-hide))))
2546
2547 (provide 'company)
2548 ;;; company.el ends here