code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular text completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; URL: http://company-mode.github.io/
   8 ;; Version: 0.8.0-snapshot
   9 ;; Keywords: abbrev, convenience, matching
  10 ;; Package-Requires: ((emacs "24.1"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (pcase command
  52 ;;     (`prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (`meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;; Known Issues:
  62 ;; When point is at the very end of the buffer, the pseudo-tooltip appears very
  63 ;; wrong, unless company is allowed to temporarily insert a fake newline.
  64 ;; This behavior is enabled by `company-end-of-buffer-workaround'.
  65 ;;
  66 ;;; Change Log:
  67 ;;
  68 ;; See NEWS.md in the repository.
  69
  70 ;;; Code:
  71
  72 (eval-when-compile (require 'cl))
  73 (require 'newcomment)
  74
  75 ;; FIXME: Use `user-error'.
  76 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  77 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  78 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  79 (add-to-list 'debug-ignored-errors "^Company not ")
  80 (add-to-list 'debug-ignored-errors "^No candidate number ")
  81 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  82 (add-to-list 'debug-ignored-errors "^No other back-end$")
  83
  84 (defgroup company nil
  85   "Extensible inline text completion mechanism"
  86   :group 'abbrev
  87   :group 'convenience
  88   :group 'matching)
  89
  90 (defface company-tooltip
  91   '((default :foreground "black")
  92     (((class color) (min-colors 88) (background light))
  93      (:background "cornsilk"))
  94     (((class color) (min-colors 88) (background dark))
  95      (:background "yellow")))
  96   "Face used for the tooltip.")
  97
  98 (defface company-tooltip-selection
  99   '((default :inherit company-tooltip)
 100     (((class color) (min-colors 88) (background light))
 101      (:background "light blue"))
 102     (((class color) (min-colors 88) (background dark))
 103      (:background "orange1"))
 104     (t (:background "green")))
 105   "Face used for the selection in the tooltip.")
 106
 107 (defface company-tooltip-mouse
 108   '((default :inherit highlight))
 109   "Face used for the tooltip item under the mouse.")
 110
 111 (defface company-tooltip-common
 112   '((default :inherit company-tooltip)
 113     (((background light))
 114      :foreground "darkred")
 115     (((background dark))
 116      :foreground "red"))
 117   "Face used for the common completion in the tooltip.")
 118
 119 (defface company-tooltip-common-selection
 120   '((default :inherit company-tooltip-selection)
 121     (((background light))
 122      :foreground "darkred")
 123     (((background dark))
 124      :foreground "red"))
 125   "Face used for the selected common completion in the tooltip.")
 126
 127 (defface company-tooltip-annotation
 128   '((default :inherit company-tooltip)
 129     (((background light))
 130      :foreground "firebrick4")
 131     (((background dark))
 132      :foreground "red4"))
 133   "Face used for the annotation in the tooltip.")
 134
 135 (defface company-scrollbar-fg
 136   '((((background light))
 137      :background "darkred")
 138     (((background dark))
 139      :background "red"))
 140   "Face used for the tooltip scrollbar thumb.")
 141
 142 (defface company-scrollbar-bg
 143   '((default :inherit company-tooltip)
 144     (((background light))
 145      :background "wheat")
 146     (((background dark))
 147      :background "gold"))
 148   "Face used for the tooltip scrollbar background.")
 149
 150 (defface company-preview
 151   '((((background light))
 152      :inherit company-tooltip-selection)
 153     (((background dark))
 154      :background "blue4"
 155      :foreground "wheat"))
 156   "Face used for the completion preview.")
 157
 158 (defface company-preview-common
 159   '((((background light))
 160      :inherit company-tooltip-selection)
 161     (((background dark))
 162      :inherit company-preview
 163      :foreground "red"))
 164   "Face used for the common part of the completion preview.")
 165
 166 (defface company-preview-search
 167   '((((background light))
 168      :inherit company-tooltip-common-selection)
 169     (((background dark))
 170      :inherit company-preview
 171      :background "blue1"))
 172   "Face used for the search string in the completion preview.")
 173
 174 (defface company-echo nil
 175   "Face used for completions in the echo area.")
 176
 177 (defface company-echo-common
 178   '((((background dark)) (:foreground "firebrick1"))
 179     (((background light)) (:background "firebrick4")))
 180   "Face used for the common part of completions in the echo area.")
 181
 182 (defun company-frontends-set (variable value)
 183   ;; uniquify
 184   (let ((remainder value))
 185     (setcdr remainder (delq (car remainder) (cdr remainder))))
 186   (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 187        (memq 'company-pseudo-tooltip-frontend value)
 188        (error "Pseudo tooltip frontend cannot be used twice"))
 189   (and (memq 'company-preview-if-just-one-frontend value)
 190        (memq 'company-preview-frontend value)
 191        (error "Preview frontend cannot be used twice"))
 192   (and (memq 'company-echo value)
 193        (memq 'company-echo-metadata-frontend value)
 194        (error "Echo area cannot be used twice"))
 195   ;; preview must come last
 196   (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 197     (when (memq f value)
 198       (setq value (append (delq f value) (list f)))))
 199   (set variable value))
 200
 201 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 202                                company-preview-if-just-one-frontend
 203                                company-echo-metadata-frontend)
 204   "The list of active front-ends (visualizations).
 205 Each front-end is a function that takes one argument.  It is called with
 206 one of the following arguments:
 207
 208 `show': When the visualization should start.
 209
 210 `hide': When the visualization should end.
 211
 212 `update': When the data has been updated.
 213
 214 `pre-command': Before every command that is executed while the
 215 visualization is active.
 216
 217 `post-command': After every command that is executed while the
 218 visualization is active.
 219
 220 The visualized data is stored in `company-prefix', `company-candidates',
 221 `company-common', `company-selection', `company-point' and
 222 `company-search-string'."
 223   :set 'company-frontends-set
 224   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 225                          (const :tag "echo, strip common"
 226                                 company-echo-strip-common-frontend)
 227                          (const :tag "show echo meta-data in echo"
 228                                 company-echo-metadata-frontend)
 229                          (const :tag "pseudo tooltip"
 230                                 company-pseudo-tooltip-frontend)
 231                          (const :tag "pseudo tooltip, multiple only"
 232                                 company-pseudo-tooltip-unless-just-one-frontend)
 233                          (const :tag "preview" company-preview-frontend)
 234                          (const :tag "preview, unique only"
 235                                 company-preview-if-just-one-frontend)
 236                          (function :tag "custom function" nil))))
 237
 238 (defcustom company-tooltip-limit 10
 239   "The maximum number of candidates in the tooltip"
 240   :type 'integer)
 241
 242 (defcustom company-tooltip-minimum 6
 243   "The minimum height of the tooltip.
 244 If this many lines are not available, prefer to display the tooltip above."
 245   :type 'integer)
 246
 247 (defcustom company-tooltip-margin 1
 248   "Width of margin columns to show around the toolip."
 249   :type 'integer)
 250
 251 (defcustom company-tooltip-offset-display 'scrollbar
 252   "Method using which the tooltip displays scrolling position.
 253 `scrollbar' means draw a scrollbar to the right of the items.
 254 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 255   :type '(choice (const :tag "Scrollbar" scrollbar)
 256                  (const :tag "Two lines" lines)))
 257
 258 (defcustom company-tooltip-align-annotations nil
 259   "When non-nil, align annotations to the right tooltip border."
 260   :type 'boolean)
 261
 262 (defvar company-safe-backends
 263   '((company-abbrev . "Abbrev")
 264     (company-bbdb . "BBDB")
 265     (company-capf . "completion-at-point-functions")
 266     (company-clang . "Clang")
 267     (company-cmake . "CMake")
 268     (company-css . "CSS")
 269     (company-dabbrev . "dabbrev for plain text")
 270     (company-dabbrev-code . "dabbrev for code")
 271     (company-eclim . "Eclim (an Eclipse interface)")
 272     (company-elisp . "Emacs Lisp")
 273     (company-etags . "etags")
 274     (company-files . "Files")
 275     (company-gtags . "GNU Global")
 276     (company-ispell . "Ispell")
 277     (company-keywords . "Programming language keywords")
 278     (company-nxml . "nxml")
 279     (company-oddmuse . "Oddmuse")
 280     (company-pysmell . "PySmell")
 281     (company-ropemacs . "ropemacs")
 282     (company-semantic . "Semantic")
 283     (company-tempo . "Tempo templates")
 284     (company-xcode . "Xcode")))
 285 (put 'company-safe-backends 'risky-local-variable t)
 286
 287 (defun company-safe-backends-p (backends)
 288   (and (consp backends)
 289        (not (dolist (backend backends)
 290               (unless (if (consp backend)
 291                           (company-safe-backends-p backend)
 292                         (assq backend company-safe-backends))
 293                 (return t))))))
 294
 295 (defvar company--include-capf (version< "24.3.50" emacs-version))
 296
 297 (defcustom company-backends `(,@(unless company--include-capf
 298                                   (list 'company-elisp))
 299                               company-bbdb
 300                               company-nxml company-css
 301                               company-eclim company-semantic company-clang
 302                               company-xcode company-ropemacs company-cmake
 303                               ,@(when company--include-capf
 304                                   (list 'company-capf))
 305                               (company-dabbrev-code company-gtags company-etags
 306                                company-keywords)
 307                               company-oddmuse company-files company-dabbrev)
 308   "The list of active back-ends (completion engines).
 309
 310 `company-begin-backend' can be used to start a specific back-end,
 311 `company-other-backend' will skip to the next matching back-end in the list.
 312
 313 Each back-end is a function that takes a variable number of arguments.
 314 The first argument is the command requested from the back-end.  It is one
 315 of the following:
 316
 317 `prefix': The back-end should return the text to be completed.  It must be
 318 text immediately before point.  Returning nil passes control to the next
 319 back-end.  The function should return `stop' if it should complete but
 320 cannot \(e.g. if it is in the middle of a string\).  Instead of a string,
 321 the back-end may return a cons where car is the prefix and cdr is used in
 322 `company-minimum-prefix-length' test.  It must be either number or t, and
 323 in the latter case the test automatically succeeds.
 324
 325 `candidates': The second argument is the prefix to be completed.  The
 326 return value should be a list of candidates that match the prefix.
 327
 328 Non-prefix matches are also supported (candidates that don't start with the
 329 prefix, but match it in some backend-defined way).  Backends that use this
 330 feature must disable cache (return t to `no-cache') and should also respond
 331 to `match'.
 332
 333 Optional commands:
 334
 335 `sorted': Return t here to indicate that the candidates are sorted and will
 336 not need to be sorted again.
 337
 338 `duplicates': If non-nil, company will take care of removing duplicates
 339 from the list.
 340
 341 `no-cache': Usually company doesn't ask for candidates again as completion
 342 progresses, unless the back-end returns t for this command.  The second
 343 argument is the latest prefix.
 344
 345 `meta': The second argument is a completion candidate.  Return a (short)
 346 documentation string for it.
 347
 348 `doc-buffer': The second argument is a completion candidate.  Return a
 349 buffer with documentation for it.  Preferably use `company-doc-buffer',
 350
 351 `location': The second argument is a completion candidate.  Return the cons
 352 of buffer and buffer location, or of file and line number where the
 353 completion candidate was defined.
 354
 355 `annotation': The second argument is a completion candidate.  Return a
 356 string to be displayed inline with the candidate in the popup.  If
 357 duplicates are removed by company, candidates with equal string values will
 358 be kept if they have different annotations.  For that to work properly,
 359 backends should store the related information on candidates using text
 360 properties.
 361
 362 `match': The second argument is a completion candidate.  Backends that
 363 provide non-prefix completions should return the position of the end of
 364 text in the candidate that matches `prefix'.  It will be used when
 365 rendering the popup.
 366
 367 `require-match': If this returns t, the user is not allowed to enter
 368 anything not offered as a candidate.  Use with care!  The default value nil
 369 gives the user that choice with `company-require-match'.  Return value
 370 `never' overrides that option the other way around.
 371
 372 `init': Called once for each buffer. The back-end can check for external
 373 programs and files and load any required libraries.  Raising an error here
 374 will show up in message log once, and the back-end will not be used for
 375 completion.
 376
 377 `post-completion': Called after a completion candidate has been inserted
 378 into the buffer.  The second argument is the candidate.  Can be used to
 379 modify it, e.g. to expand a snippet.
 380
 381 The back-end should return nil for all commands it does not support or
 382 does not know about.  It should also be callable interactively and use
 383 `company-begin-backend' to start itself in that case.
 384
 385 Grouped back-ends:
 386
 387 An element of `company-backends' can also itself be a list of back-ends,
 388 then it's considered to be a \"grouped\" back-end.
 389
 390 When possible, commands taking a candidate as an argument are dispatched to
 391 the back-end it came from.  In other cases, the first non-nil value among
 392 all the back-ends is returned.
 393
 394 The latter is the case for the `prefix' command.  But if the group contains
 395 the keyword `:with', the back-ends after it are ignored for this command.
 396
 397 The completions from back-ends in a group are merged (but only from those
 398 that return the same `prefix').
 399
 400 Asynchronous back-ends:
 401
 402 The return value of each command can also be a cons (:async . FETCHER)
 403 where FETCHER is a function of one argument, CALLBACK.  When the data
 404 arrives, FETCHER must call CALLBACK and pass it the appropriate return
 405 value, as described above.
 406
 407 True asynchronous operation is only supported for command `candidates', and
 408 only during idle completion.  Other commands will block the user interface,
 409 even if the back-end uses the asynchronous calling convention."
 410   :type `(repeat
 411           (choice
 412            :tag "Back-end"
 413            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 414                      company-safe-backends)
 415            (symbol :tag "User defined")
 416            (repeat :tag "Merged Back-ends"
 417                    (choice :tag "Back-end"
 418                            ,@(mapcar (lambda (b)
 419                                        `(const :tag ,(cdr b) ,(car b)))
 420                                      company-safe-backends)
 421                            (const :tag "With" :with)
 422                            (symbol :tag "User defined"))))))
 423
 424 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 425
 426 (defcustom company-transformers nil
 427   "Functions to change the list of candidates received from backends,
 428 after sorting and removal of duplicates (if appropriate).
 429 Each function gets called with the return value of the previous one."
 430   :type '(choice
 431           (const :tag "None" nil)
 432           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 433           (repeat :tag "User defined" (function))))
 434
 435 (defcustom company-completion-started-hook nil
 436   "Hook run when company starts completing.
 437 The hook is called with one argument that is non-nil if the completion was
 438 started manually."
 439   :type 'hook)
 440
 441 (defcustom company-completion-cancelled-hook nil
 442   "Hook run when company cancels completing.
 443 The hook is called with one argument that is non-nil if the completion was
 444 aborted manually."
 445   :type 'hook)
 446
 447 (defcustom company-completion-finished-hook nil
 448   "Hook run when company successfully completes.
 449 The hook is called with the selected candidate as an argument.
 450
 451 If you indend to use it to post-process candidates from a specific
 452 back-end, consider using the `post-completion' command instead."
 453   :type 'hook)
 454
 455 (defcustom company-minimum-prefix-length 3
 456   "The minimum prefix length for idle completion."
 457   :type '(integer :tag "prefix length"))
 458
 459 (defcustom company-abort-manual-when-too-short nil
 460   "If enabled, cancel a manually started completion when the prefix gets
 461 shorter than both `company-minimum-prefix-length' and the length of the
 462 prefix it was started from."
 463   :type 'boolean)
 464
 465 (defcustom company-require-match 'company-explicit-action-p
 466   "If enabled, disallow non-matching input.
 467 This can be a function do determine if a match is required.
 468
 469 This can be overridden by the back-end, if it returns t or `never' to
 470 `require-match'.  `company-auto-complete' also takes precedence over this."
 471   :type '(choice (const :tag "Off" nil)
 472                  (function :tag "Predicate function")
 473                  (const :tag "On, if user interaction took place"
 474                         'company-explicit-action-p)
 475                  (const :tag "On" t)))
 476
 477 (defcustom company-auto-complete nil
 478   "Determines when to auto-complete.
 479 If this is enabled, all characters from `company-auto-complete-chars'
 480 trigger insertion of the selected completion candidate.
 481 This can also be a function."
 482   :type '(choice (const :tag "Off" nil)
 483                  (function :tag "Predicate function")
 484                  (const :tag "On, if user interaction took place"
 485                         'company-explicit-action-p)
 486                  (const :tag "On" t)))
 487
 488 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 489   "Determines which characters trigger auto-completion.
 490 See `company-auto-complete'.  If this is a string, each string character
 491 tiggers auto-completion.  If it is a list of syntax description characters (see
 492 `modify-syntax-entry'), all characters with that syntax auto-complete.
 493
 494 This can also be a function, which is called with the new input and should
 495 return non-nil if company should auto-complete.
 496
 497 A character that is part of a valid candidate never triggers auto-completion."
 498   :type '(choice (string :tag "Characters")
 499                  (set :tag "Syntax"
 500                       (const :tag "Whitespace" ?\ )
 501                       (const :tag "Symbol" ?_)
 502                       (const :tag "Opening parentheses" ?\()
 503                       (const :tag "Closing parentheses" ?\))
 504                       (const :tag "Word constituent" ?w)
 505                       (const :tag "Punctuation." ?.)
 506                       (const :tag "String quote." ?\")
 507                       (const :tag "Paired delimiter." ?$)
 508                       (const :tag "Expression quote or prefix operator." ?\')
 509                       (const :tag "Comment starter." ?<)
 510                       (const :tag "Comment ender." ?>)
 511                       (const :tag "Character-quote." ?/)
 512                       (const :tag "Generic string fence." ?|)
 513                       (const :tag "Generic comment fence." ?!))
 514                  (function :tag "Predicate function")))
 515
 516 (defcustom company-idle-delay .7
 517   "The idle delay in seconds until completion starts automatically.
 518 A value of nil means no idle completion, t means show candidates
 519 immediately when a prefix of `company-minimum-prefix-length' is reached."
 520   :type '(choice (const :tag "never (nil)" nil)
 521                  (const :tag "immediate (t)" t)
 522                  (number :tag "seconds")))
 523
 524 (defcustom company-begin-commands '(self-insert-command org-self-insert-command)
 525   "A list of commands after which idle completion is allowed.
 526 If this is t, it can show completions after any command.  See
 527 `company-idle-delay'.
 528
 529 Alternatively, any command with a non-nil `company-begin' property is
 530 treated as if it was on this list."
 531   :type '(choice (const :tag "Any command" t)
 532                  (const :tag "Self insert command" '(self-insert-command))
 533                  (repeat :tag "Commands" function)))
 534
 535 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 536                                            save-buffers-kill-terminal
 537                                            save-buffers-kill-emacs)
 538   "A list of commands that are allowed during completion.
 539 If this is t, or if `company-begin-commands' is t, any command is allowed.
 540 Otherwise, the value must be a list of symbols.  If it starts with `not',
 541 the cdr is the list of commands that abort completion.  Otherwise, all
 542 commands except those in that list, or in `company-begin-commands', or
 543 commands in the `company-' namespace, abort completion."
 544   :type '(choice (const :tag "Any command" t)
 545                  (cons  :tag "Any except"
 546                         (const not)
 547                         (repeat :tag "Commands" function))
 548                  (repeat :tag "Commands" function)))
 549
 550 (defcustom company-show-numbers nil
 551   "If enabled, show quick-access numbers for the first ten candidates."
 552   :type '(choice (const :tag "off" nil)
 553                  (const :tag "on" t)))
 554
 555 (defcustom company-selection-wrap-around nil
 556   "If enabled, selecting item before first or after last wraps around."
 557   :type '(choice (const :tag "off" nil)
 558                  (const :tag "on" t)))
 559
 560 (defvar company-end-of-buffer-workaround t
 561   "Work around a visualization bug when completing at the end of the buffer.
 562 The work-around consists of adding a newline.")
 563
 564 (defvar company-async-wait 0.03
 565   "Pause between checks to see if the value's been set when turning an
 566 asynchronous call into synchronous.")
 567
 568 (defvar company-async-timeout 2
 569   "Maximum wait time for a value to be set during asynchronous call.")
 570
 571 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 572
 573 (defvar company-mode-map (make-sparse-keymap)
 574   "Keymap used by `company-mode'.")
 575
 576 (defvar company-active-map
 577   (let ((keymap (make-sparse-keymap)))
 578     (define-key keymap "\e\e\e" 'company-abort)
 579     (define-key keymap "\C-g" 'company-abort)
 580     (define-key keymap (kbd "M-n") 'company-select-next)
 581     (define-key keymap (kbd "M-p") 'company-select-previous)
 582     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 583     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 584     (define-key keymap [down-mouse-1] 'ignore)
 585     (define-key keymap [down-mouse-3] 'ignore)
 586     (define-key keymap [mouse-1] 'company-complete-mouse)
 587     (define-key keymap [mouse-3] 'company-select-mouse)
 588     (define-key keymap [up-mouse-1] 'ignore)
 589     (define-key keymap [up-mouse-3] 'ignore)
 590     (define-key keymap [return] 'company-complete-selection)
 591     (define-key keymap (kbd "RET") 'company-complete-selection)
 592     (define-key keymap [tab] 'company-complete-common)
 593     (define-key keymap (kbd "TAB") 'company-complete-common)
 594     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 595     (define-key keymap "\C-w" 'company-show-location)
 596     (define-key keymap "\C-s" 'company-search-candidates)
 597     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 598     (dotimes (i 10)
 599       (define-key keymap (vector (+ (aref (kbd "M-0") 0) i))
 600         `(lambda () (interactive) (company-complete-number ,i))))
 601
 602     keymap)
 603   "Keymap that is enabled during an active completion.")
 604
 605 (defvar company--disabled-backends nil)
 606
 607 (defun company-init-backend (backend)
 608   (and (symbolp backend)
 609        (not (fboundp backend))
 610        (ignore-errors (require backend nil t)))
 611   (cond
 612    ((symbolp backend)
 613     (condition-case err
 614         (progn
 615           (funcall backend 'init)
 616           (put backend 'company-init t))
 617       (error
 618        (put backend 'company-init 'failed)
 619        (unless (memq backend company--disabled-backends)
 620          (message "Company back-end '%s' could not be initialized:\n%s"
 621                   backend (error-message-string err)))
 622        (pushnew backend company--disabled-backends)
 623        nil)))
 624    ;; No initialization for lambdas.
 625    ((functionp backend) t)
 626    (t ;; Must be a list.
 627     (dolist (b backend)
 628       (unless (keywordp b)
 629         (company-init-backend b))))))
 630
 631 (defvar company-default-lighter " company")
 632
 633 (defvar company-lighter company-default-lighter)
 634 (make-variable-buffer-local 'company-lighter)
 635
 636 ;;;###autoload
 637 (define-minor-mode company-mode
 638   "\"complete anything\"; is an in-buffer completion framework.
 639 Completion starts automatically, depending on the values
 640 `company-idle-delay' and `company-minimum-prefix-length'.
 641
 642 Completion can be controlled with the commands:
 643 `company-complete-common', `company-complete-selection', `company-complete',
 644 `company-select-next', `company-select-previous'.  If these commands are
 645 called before `company-idle-delay', completion will also start.
 646
 647 Completions can be searched with `company-search-candidates' or
 648 `company-filter-candidates'.  These can be used while completion is
 649 inactive, as well.
 650
 651 The completion data is retrieved using `company-backends' and displayed
 652 using `company-frontends'.  If you want to start a specific back-end, call
 653 it interactively or use `company-begin-backend'.
 654
 655 regular keymap (`company-mode-map'):
 656
 657 \\{company-mode-map}
 658 keymap during active completions (`company-active-map'):
 659
 660 \\{company-active-map}"
 661   nil company-lighter company-mode-map
 662   (if company-mode
 663       (progn
 664         (add-hook 'pre-command-hook 'company-pre-command nil t)
 665         (add-hook 'post-command-hook 'company-post-command nil t)
 666         (mapc 'company-init-backend company-backends))
 667     (remove-hook 'pre-command-hook 'company-pre-command t)
 668     (remove-hook 'post-command-hook 'company-post-command t)
 669     (company-cancel)
 670     (kill-local-variable 'company-point)))
 671
 672 (defcustom company-global-modes t
 673   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 674 If nil, means no modes.  If t, then all major modes have it turned on.
 675 If a list, it should be a list of `major-mode' symbol names for which
 676 `company-mode' should be automatically turned on.  The sense of the list is
 677 negated if it begins with `not'.  For example:
 678  (c-mode c++-mode)
 679 means that `company-mode' is turned on for buffers in C and C++ modes only.
 680  (not message-mode)
 681 means that `company-mode' is always turned on except in `message-mode' buffers."
 682   :type '(choice (const :tag "none" nil)
 683                  (const :tag "all" t)
 684                  (set :menu-tag "mode specific" :tag "modes"
 685                       :value (not)
 686                       (const :tag "Except" not)
 687                       (repeat :inline t (symbol :tag "mode")))))
 688
 689 ;;;###autoload
 690 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 691
 692 (defun company-mode-on ()
 693   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 694              (cond ((eq company-global-modes t)
 695                     t)
 696                    ((eq (car-safe company-global-modes) 'not)
 697                     (not (memq major-mode (cdr company-global-modes))))
 698                    (t (memq major-mode company-global-modes))))
 699     (company-mode 1)))
 700
 701 (defsubst company-assert-enabled ()
 702   (unless company-mode
 703     (company-uninstall-map)
 704     (error "Company not enabled")))
 705
 706 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 707
 708 (defvar company-my-keymap nil)
 709 (make-variable-buffer-local 'company-my-keymap)
 710
 711 (defvar company-emulation-alist '((t . nil)))
 712
 713 (defsubst company-enable-overriding-keymap (keymap)
 714   (company-uninstall-map)
 715   (setq company-my-keymap keymap))
 716
 717 (defun company-ensure-emulation-alist ()
 718   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 719     (setq emulation-mode-map-alists
 720           (cons 'company-emulation-alist
 721                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 722
 723 (defun company-install-map ()
 724   (unless (or (cdar company-emulation-alist)
 725               (null company-my-keymap))
 726     (setf (cdar company-emulation-alist) company-my-keymap)))
 727
 728 (defun company-uninstall-map ()
 729   (setf (cdar company-emulation-alist) nil))
 730
 731 ;; Hack:
 732 ;; Emacs calculates the active keymaps before reading the event.  That means we
 733 ;; cannot change the keymap from a timer.  So we send a bogus command.
 734 ;; XXX: Seems not to be needed anymore in Emacs 24.4
 735 (defun company-ignore ()
 736   (interactive)
 737   (setq this-command last-command))
 738
 739 (global-set-key '[31415926] 'company-ignore)
 740
 741 (defun company-input-noop ()
 742   (push 31415926 unread-command-events))
 743
 744 (defun company--column (&optional pos)
 745   (save-excursion
 746     (when pos (goto-char pos))
 747     (save-restriction
 748       (+ (save-excursion
 749            (vertical-motion 0)
 750            (narrow-to-region (point) (point-max))
 751            (let ((prefix (get-text-property (point) 'line-prefix)))
 752              (if prefix (length prefix) 0)))
 753          (current-column)))))
 754
 755 (defun company--row (&optional pos)
 756   (save-excursion
 757     (when pos (goto-char pos))
 758     (count-screen-lines (window-start)
 759                         (progn (vertical-motion 0) (point)))))
 760
 761 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 762
 763 (defvar company-backend nil)
 764 (make-variable-buffer-local 'company-backend)
 765
 766 (defun company-grab (regexp &optional expression limit)
 767   (when (looking-back regexp limit)
 768     (or (match-string-no-properties (or expression 0)) "")))
 769
 770 (defun company-grab-line (regexp &optional expression)
 771   (company-grab regexp expression (point-at-bol)))
 772
 773 (defun company-grab-symbol ()
 774   (if (looking-at "\\_>")
 775       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 776                                                 (point)))
 777     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 778       "")))
 779
 780 (defun company-grab-word ()
 781   (if (looking-at "\\>")
 782       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 783                                                 (point)))
 784     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 785       "")))
 786
 787 (defun company-in-string-or-comment ()
 788   (let ((ppss (syntax-ppss)))
 789     (or (car (setq ppss (nthcdr 3 ppss)))
 790         (car (setq ppss (cdr ppss)))
 791         (nth 3 ppss))))
 792
 793 (defun company-call-backend (&rest args)
 794   (company--force-sync #'company-call-backend-raw args company-backend))
 795
 796 (defun company--force-sync (fun args backend)
 797   (let ((value (apply fun args)))
 798     (if (not (eq (car-safe value) :async))
 799         value
 800       (let ((res 'trash)
 801             (start (time-to-seconds)))
 802         (funcall (cdr value)
 803                  (lambda (result) (setq res result)))
 804         (while (eq res 'trash)
 805           (if (> (- (time-to-seconds) start) company-async-timeout)
 806               (error "Company: Back-end %s async timeout with args %s"
 807                      backend args)
 808             (sleep-for company-async-wait)))
 809         res))))
 810
 811 (defun company-call-backend-raw (&rest args)
 812   (condition-case err
 813       (if (functionp company-backend)
 814           (apply company-backend args)
 815         (apply #'company--multi-backend-adapter company-backend args))
 816     (error (error "Company: Back-end %s error \"%s\" with args %s"
 817                   company-backend (error-message-string err) args))))
 818
 819 (defun company--multi-backend-adapter (backends command &rest args)
 820   (let ((backends (loop for b in backends
 821                         when (not (and (symbolp b)
 822                                        (eq 'failed (get b 'company-init))))
 823                         collect b)))
 824     (setq backends
 825           (if (eq command 'prefix)
 826               (butlast backends (length (member :with backends)))
 827             (delq :with backends)))
 828     (pcase command
 829       (`candidates
 830        (company--multi-backend-adapter-candidates backends (car args)))
 831       (`sorted nil)
 832       (`duplicates t)
 833       ((or `prefix `ignore-case `no-cache `require-match)
 834        (let (value)
 835          (dolist (backend backends)
 836            (when (setq value (company--force-sync
 837                               backend (cons command args) backend))
 838              (return value)))))
 839       (_
 840        (let ((arg (car args)))
 841          (when (> (length arg) 0)
 842            (let ((backend (or (get-text-property 0 'company-backend arg)
 843                               (car backends))))
 844              (apply backend command args))))))))
 845
 846 (defun company--multi-backend-adapter-candidates (backends prefix)
 847   (let ((pairs (loop for backend in (cdr backends)
 848                      when (equal (funcall backend 'prefix)
 849                                  prefix)
 850                      collect (cons (funcall backend 'candidates prefix)
 851                                    (lambda (candidates)
 852                                      (mapcar
 853                                       (lambda (str)
 854                                         (propertize str 'company-backend
 855                                                     backend))
 856                                       candidates))))))
 857     (when (equal (funcall (car backends) 'prefix) prefix)
 858       ;; Small perf optimization: don't tag the candidates received
 859       ;; from the first backend in the group.
 860       (push (cons (funcall (car backends) 'candidates prefix)
 861                   'identity)
 862             pairs))
 863     (company--merge-async pairs (lambda (values) (apply #'append values)))))
 864
 865 (defun company--merge-async (pairs merger)
 866   (let ((async (loop for pair in pairs
 867                      thereis
 868                      (eq :async (car-safe (car pair))))))
 869     (if (not async)
 870         (funcall merger (loop for (val . mapper) in pairs
 871                               collect (funcall mapper val)))
 872       (cons
 873        :async
 874        (lambda (callback)
 875          (let* (lst pending
 876                 (finisher (lambda ()
 877                             (unless pending
 878                               (funcall callback
 879                                        (funcall merger
 880                                                 (nreverse lst)))))))
 881            (dolist (pair pairs)
 882              (let ((val (car pair))
 883                    (mapper (cdr pair)))
 884                (if (not (eq :async (car-safe val)))
 885                    (push (funcall mapper val) lst)
 886                  (push nil lst)
 887                  (let ((cell lst)
 888                        (fetcher (cdr val)))
 889                    (push fetcher pending)
 890                    (funcall fetcher
 891                             (lambda (res)
 892                               (setq pending (delq fetcher pending))
 893                               (setcar cell (funcall mapper res))
 894                               (funcall finisher)))))))))))))
 895
 896 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 897
 898 (defvar company-prefix nil)
 899 (make-variable-buffer-local 'company-prefix)
 900
 901 (defvar company-candidates nil)
 902 (make-variable-buffer-local 'company-candidates)
 903
 904 (defvar company-candidates-length nil)
 905 (make-variable-buffer-local 'company-candidates-length)
 906
 907 (defvar company-candidates-cache nil)
 908 (make-variable-buffer-local 'company-candidates-cache)
 909
 910 (defvar company-candidates-predicate nil)
 911 (make-variable-buffer-local 'company-candidates-predicate)
 912
 913 (defvar company-common nil)
 914 (make-variable-buffer-local 'company-common)
 915
 916 (defvar company-selection 0)
 917 (make-variable-buffer-local 'company-selection)
 918
 919 (defvar company-selection-changed nil)
 920 (make-variable-buffer-local 'company-selection-changed)
 921
 922 (defvar company--manual-action nil
 923   "Non-nil, if manual completion took place.")
 924 (make-variable-buffer-local 'company--manual-action)
 925
 926 (defvar company--manual-prefix nil)
 927 (make-variable-buffer-local 'company--manual-prefix)
 928
 929 (defvar company--auto-completion nil
 930   "Non-nil when current candidate is being inserted automatically.
 931 Controlled by `company-auto-complete'.")
 932
 933 (defvar company--point-max nil)
 934 (make-variable-buffer-local 'company--point-max)
 935
 936 (defvar company-point nil)
 937 (make-variable-buffer-local 'company-point)
 938
 939 (defvar company-timer nil)
 940
 941 (defvar company-added-newline nil)
 942 (make-variable-buffer-local 'company-added-newline)
 943
 944 (defsubst company-strip-prefix (str)
 945   (substring str (length company-prefix)))
 946
 947 (defun company--insert-candidate (candidate)
 948   (setq candidate (substring-no-properties candidate))
 949   ;; XXX: Return value we check here is subject to change.
 950   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 951       (insert (company-strip-prefix candidate))
 952     (delete-region (- (point) (length company-prefix)) (point))
 953     (insert candidate)))
 954
 955 (defmacro company-with-candidate-inserted (candidate &rest body)
 956   "Evaluate BODY with CANDIDATE temporarily inserted.
 957 This is a tool for back-ends that need candidates inserted before they
 958 can retrieve meta-data for them."
 959   (declare (indent 1))
 960   `(let ((inhibit-modification-hooks t)
 961          (inhibit-point-motion-hooks t)
 962          (modified-p (buffer-modified-p)))
 963      (company--insert-candidate ,candidate)
 964      (unwind-protect
 965          (progn ,@body)
 966        (delete-region company-point (point)))))
 967
 968 (defun company-explicit-action-p ()
 969   "Return whether explicit completion action was taken by the user."
 970   (or company--manual-action
 971       company-selection-changed))
 972
 973 (defun company-reformat (candidate)
 974   ;; company-ispell needs this, because the results are always lower-case
 975   ;; It's mory efficient to fix it only when they are displayed.
 976   ;; FIXME: Adopt the current text's capitalization instead?
 977   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 978       (concat company-prefix (substring candidate (length company-prefix)))
 979     candidate))
 980
 981 (defun company--should-complete ()
 982   (and (not (or buffer-read-only overriding-terminal-local-map
 983                 overriding-local-map))
 984        ;; Check if in the middle of entering a key combination.
 985        (or (equal (this-command-keys-vector) [])
 986            (not (keymapp (key-binding (this-command-keys-vector)))))
 987        (eq company-idle-delay t)
 988        (or (eq t company-begin-commands)
 989            (memq this-command company-begin-commands)
 990            (and (symbolp this-command) (get this-command 'company-begin)))
 991        (not (and transient-mark-mode mark-active))))
 992
 993 (defun company--should-continue ()
 994   (or (eq t company-begin-commands)
 995       (eq t company-continue-commands)
 996       (if (eq 'not (car company-continue-commands))
 997           (not (memq this-command (cdr company-continue-commands)))
 998         (or (memq this-command company-begin-commands)
 999             (memq this-command company-continue-commands)
1000             (string-match-p "\\`company-" (symbol-name this-command))))))
1001
1002 (defun company-call-frontends (command)
1003   (dolist (frontend company-frontends)
1004     (condition-case err
1005         (funcall frontend command)
1006       (error (error "Company: Front-end %s error \"%s\" on command %s"
1007                     frontend (error-message-string err) command)))))
1008
1009 (defun company-set-selection (selection &optional force-update)
1010   (setq selection
1011         (if company-selection-wrap-around
1012             (mod selection company-candidates-length)
1013           (max 0 (min (1- company-candidates-length) selection))))
1014   (when (or force-update (not (equal selection company-selection)))
1015     (setq company-selection selection
1016           company-selection-changed t)
1017     (company-call-frontends 'update)))
1018
1019 (defun company-apply-predicate (candidates predicate)
1020   (let (new)
1021     (dolist (c candidates)
1022       (when (funcall predicate c)
1023         (push c new)))
1024     (nreverse new)))
1025
1026 (defun company-update-candidates (candidates)
1027   (setq company-candidates-length (length candidates))
1028   (if (> company-selection 0)
1029       ;; Try to restore the selection
1030       (let ((selected (nth company-selection company-candidates)))
1031         (setq company-selection 0
1032               company-candidates candidates)
1033         (when selected
1034           (while (and candidates (string< (pop candidates) selected))
1035             (incf company-selection))
1036           (unless candidates
1037             ;; Make sure selection isn't out of bounds.
1038             (setq company-selection (min (1- company-candidates-length)
1039                                          company-selection)))))
1040     (setq company-selection 0
1041           company-candidates candidates))
1042   ;; Save in cache:
1043   (push (cons company-prefix company-candidates) company-candidates-cache)
1044   ;; Calculate common.
1045   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
1046     ;; We want to support non-prefix completion, so filtering is the
1047     ;; responsibility of each respective backend, not ours.
1048     ;; On the other hand, we don't want to replace non-prefix input in
1049     ;; `company-complete-common'.
1050     (setq company-common
1051           (if (cdr company-candidates)
1052               (let ((common (try-completion company-prefix company-candidates)))
1053                 (if (eq common t)
1054                     ;; Mulple equal strings, probably with different
1055                     ;; annotations.
1056                     company-prefix
1057                   common))
1058             (car company-candidates)))))
1059
1060 (defun company-calculate-candidates (prefix)
1061   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
1062         (ignore-case (company-call-backend 'ignore-case)))
1063     (or candidates
1064         (when company-candidates-cache
1065           (let ((len (length prefix))
1066                 (completion-ignore-case ignore-case)
1067                 prev)
1068             (dotimes (i (1+ len))
1069               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1070                                            company-candidates-cache)))
1071                 (setq candidates (all-completions prefix prev))
1072                 (return t)))))
1073         ;; no cache match, call back-end
1074         (setq candidates
1075               (company--process-candidates
1076                (company--fetch-candidates prefix))))
1077     (setq candidates (company--transform-candidates candidates))
1078     (when candidates
1079       (if (or (cdr candidates)
1080               (not (eq t (compare-strings (car candidates) nil nil
1081                                           prefix nil nil ignore-case))))
1082           candidates
1083         ;; Already completed and unique; don't start.
1084         t))))
1085
1086 (defun company--fetch-candidates (prefix)
1087   (let ((c (if company--manual-action
1088                (company-call-backend 'candidates prefix)
1089              (company-call-backend-raw 'candidates prefix)))
1090         res)
1091     (if (not (eq (car c) :async))
1092         c
1093       (let ((buf (current-buffer))
1094             (win (selected-window))
1095             (tick (buffer-chars-modified-tick))
1096             (pt (point))
1097             (backend company-backend))
1098         (funcall
1099          (cdr c)
1100          (lambda (candidates)
1101            (if (not (and candidates (eq res 'done)))
1102                ;; Fetcher called us right back.
1103                (setq res candidates)
1104              (setq company-backend backend
1105                    company-candidates-cache
1106                    (list (cons prefix
1107                                (company--process-candidates
1108                                 candidates))))
1109              (company-idle-begin buf win tick pt)))))
1110       ;; FIXME: Relying on the fact that the callers
1111       ;; will interpret nil as "do nothing" is shaky.
1112       ;; A throw-catch would be one possible improvement.
1113       (or res
1114           (progn (setq res 'done) nil)))))
1115
1116 (defun company--process-candidates (candidates)
1117   (when company-candidates-predicate
1118     (setq candidates
1119           (company-apply-predicate candidates
1120                                    company-candidates-predicate)))
1121   (unless (company-call-backend 'sorted)
1122     (setq candidates (sort candidates 'string<)))
1123   (when (company-call-backend 'duplicates)
1124     (company--strip-duplicates candidates))
1125   candidates)
1126
1127 (defun company--strip-duplicates (candidates)
1128   (let ((c2 candidates))
1129     (while c2
1130       (setcdr c2
1131               (let ((str (car c2))
1132                     (anno 'unk))
1133                 (pop c2)
1134                 (while (let ((str2 (car c2)))
1135                          (if (not (equal str str2))
1136                              nil
1137                            (when (eq anno 'unk)
1138                              (setq anno (company-call-backend
1139                                          'annotation str)))
1140                            (equal anno
1141                                   (company-call-backend
1142                                    'annotation str2))))
1143                   (pop c2))
1144                 c2)))))
1145
1146 (defun company--transform-candidates (candidates)
1147   (let ((c candidates))
1148     (dolist (tr company-transformers)
1149       (setq c (funcall tr c)))
1150     c))
1151
1152 (defun company-sort-by-occurrence (candidates)
1153   "Sort CANDIDATES according to their occurrences.
1154 Searches for each in the currently visible part of the current buffer and
1155 gives priority to the closest ones above point, then closest ones below
1156 point. The rest of the list is appended unchanged.
1157 Keywords and function definition names are ignored."
1158   (let* (occurs
1159          (noccurs
1160           (delete-if
1161            (lambda (candidate)
1162              (when (or
1163                     (save-excursion
1164                       (progn (forward-line 0)
1165                              (search-backward candidate (window-start) t)))
1166                     (save-excursion
1167                       (search-forward candidate (window-end) t)))
1168                (let ((beg (match-beginning 0))
1169                      (end (match-end 0)))
1170                  (when (save-excursion
1171                          (goto-char end)
1172                          (and (not (memq (get-text-property (point) 'face)
1173                                          '(font-lock-function-name-face
1174                                            font-lock-keyword-face)))
1175                               (let* ((prefix (company-call-backend 'prefix))
1176                                      (prefix (or (car-safe prefix) prefix)))
1177                                 (and (stringp prefix)
1178                                      (= (length prefix) (- end beg))))))
1179                    (push (cons candidate (if (< beg (point))
1180                                              (- (point) end)
1181                                            (- beg (window-start))))
1182                          occurs)
1183                    t))))
1184            candidates)))
1185     (nconc
1186      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1187      noccurs)))
1188
1189 (defun company-idle-begin (buf win tick pos)
1190   (and (eq buf (current-buffer))
1191        (eq win (selected-window))
1192        (eq tick (buffer-chars-modified-tick))
1193        (eq pos (point))
1194        (when (company-auto-begin)
1195          (when (version< emacs-version "24.3.50")
1196            (company-input-noop))
1197          (company-post-command))))
1198
1199 (defun company-auto-begin ()
1200   (and company-mode
1201        (not company-candidates)
1202        (let ((company-idle-delay t)
1203              (company-begin-commands t))
1204          (condition-case-unless-debug err
1205              (company-begin)
1206            (error (message "Company: An error occurred in auto-begin")
1207                   (message "%s" (error-message-string err))
1208                   (company-cancel))
1209            (quit (company-cancel)))))
1210   (unless company-candidates
1211     (setq company-backend nil))
1212   ;; Return non-nil if active.
1213   company-candidates)
1214
1215 (defun company-manual-begin ()
1216   (interactive)
1217   (company-assert-enabled)
1218   (setq company--manual-action t)
1219   (unwind-protect
1220       (let ((company-minimum-prefix-length 0))
1221         (company-auto-begin))
1222     (unless company-candidates
1223       (setq company--manual-action nil))))
1224
1225 (defun company-other-backend (&optional backward)
1226   (interactive (list current-prefix-arg))
1227   (company-assert-enabled)
1228   (if company-backend
1229       (let* ((after (cdr (member company-backend company-backends)))
1230              (before (cdr (member company-backend (reverse company-backends))))
1231              (next (if backward
1232                        (append before (reverse after))
1233                      (append after (reverse before)))))
1234         (company-cancel)
1235         (dolist (backend next)
1236           (when (ignore-errors (company-begin-backend backend))
1237             (return t))))
1238     (company-manual-begin))
1239   (unless company-candidates
1240     (error "No other back-end")))
1241
1242 (defun company-require-match-p ()
1243   (let ((backend-value (company-call-backend 'require-match)))
1244     (or (eq backend-value t)
1245         (and (not (eq backend-value 'never))
1246              (if (functionp company-require-match)
1247                  (funcall company-require-match)
1248                (eq company-require-match t))))))
1249
1250 (defun company-auto-complete-p (input)
1251   "Return non-nil, if input starts with punctuation or parentheses."
1252   (and (if (functionp company-auto-complete)
1253            (funcall company-auto-complete)
1254          company-auto-complete)
1255        (if (functionp company-auto-complete-chars)
1256            (funcall company-auto-complete-chars input)
1257          (if (consp company-auto-complete-chars)
1258              (memq (char-syntax (string-to-char input))
1259                    company-auto-complete-chars)
1260            (string-match (substring input 0 1) company-auto-complete-chars)))))
1261
1262 (defun company--incremental-p ()
1263   (and (> (point) company-point)
1264        (> (point-max) company--point-max)
1265        (not (eq this-command 'backward-delete-char-untabify))
1266        (equal (buffer-substring (- company-point (length company-prefix))
1267                                 company-point)
1268               company-prefix)))
1269
1270 (defun company--continue-failed ()
1271   (let ((input (buffer-substring-no-properties (point) company-point)))
1272     (cond
1273      ((company-auto-complete-p input)
1274       ;; auto-complete
1275       (save-excursion
1276         (goto-char company-point)
1277         (let ((company--auto-completion t))
1278           (company-complete-selection))
1279         nil))
1280      ((company-require-match-p)
1281       ;; wrong incremental input, but required match
1282       (delete-char (- (length input)))
1283       (ding)
1284       (message "Matching input is required")
1285       company-candidates)
1286      ((equal company-prefix (car company-candidates))
1287       ;; last input was actually success
1288       (company-cancel company-prefix))
1289      (t (company-cancel)))))
1290
1291 (defun company--good-prefix-p (prefix)
1292   (and (stringp (or (car-safe prefix) prefix)) ;excludes 'stop
1293        (or (eq (cdr-safe prefix) t)
1294            (let ((len (or (cdr-safe prefix) (length prefix))))
1295              (if company--manual-prefix
1296                  (or (not company-abort-manual-when-too-short)
1297                      ;; Must not be less than minimum or initial length.
1298                      (>= len (min company-minimum-prefix-length
1299                                   (length company--manual-prefix))))
1300                (>= len company-minimum-prefix-length))))))
1301
1302 (defun company--continue ()
1303   (when (company-call-backend 'no-cache company-prefix)
1304     ;; Don't complete existing candidates, fetch new ones.
1305     (setq company-candidates-cache nil))
1306   (let* ((new-prefix (company-call-backend 'prefix))
1307          (c (when (and (company--good-prefix-p new-prefix)
1308                        (setq new-prefix (or (car-safe new-prefix) new-prefix))
1309                        (= (- (point) (length new-prefix))
1310                           (- company-point (length company-prefix))))
1311               (company-calculate-candidates new-prefix))))
1312     (cond
1313      ((eq c t)
1314       ;; t means complete/unique.
1315       (company-cancel new-prefix))
1316      ((consp c)
1317       ;; incremental match
1318       (setq company-prefix new-prefix)
1319       (company-update-candidates c)
1320       c)
1321      ((not (company--incremental-p))
1322       (company-cancel))
1323      (t (company--continue-failed)))))
1324
1325 (defun company--begin-new ()
1326   (let (prefix c)
1327     (dolist (backend (if company-backend
1328                          ;; prefer manual override
1329                          (list company-backend)
1330                        company-backends))
1331       (setq prefix
1332             (if (or (symbolp backend)
1333                     (functionp backend))
1334                 (when (or (not (symbolp backend))
1335                           (eq t (get backend 'company-init))
1336                           (unless (get backend 'company-init)
1337                             (company-init-backend backend)))
1338                   (funcall backend 'prefix))
1339               (company--multi-backend-adapter backend 'prefix)))
1340       (when prefix
1341         (when (company--good-prefix-p prefix)
1342           (setq prefix (or (car-safe prefix) prefix)
1343                 company-backend backend
1344                 c (company-calculate-candidates prefix))
1345           ;; t means complete/unique.  We don't start, so no hooks.
1346           (if (not (consp c))
1347               (when company--manual-action
1348                 (message "No completion found"))
1349             (setq company-prefix prefix)
1350             (when company--manual-action
1351               (setq company--manual-prefix prefix))
1352             (when (symbolp backend)
1353               (setq company-lighter (concat " " (symbol-name backend))))
1354             (company-update-candidates c)
1355             (run-hook-with-args 'company-completion-started-hook
1356                                 (company-explicit-action-p))
1357             (company-call-frontends 'show)))
1358         (return c)))))
1359
1360 (defun company-begin ()
1361   (or (and company-candidates (company--continue))
1362       (and (company--should-complete) (company--begin-new)))
1363   (when company-candidates
1364     (let ((modified (buffer-modified-p)))
1365       (when (and company-end-of-buffer-workaround (eobp))
1366         (save-excursion (insert "\n"))
1367         (setq company-added-newline
1368               (or modified (buffer-chars-modified-tick)))))
1369     (setq company-point (point)
1370           company--point-max (point-max))
1371     (company-ensure-emulation-alist)
1372     (company-enable-overriding-keymap company-active-map)
1373     (company-call-frontends 'update)))
1374
1375 (defun company-cancel (&optional result)
1376   (and company-added-newline
1377        (> (point-max) (point-min))
1378        (let ((tick (buffer-chars-modified-tick)))
1379          (delete-region (1- (point-max)) (point-max))
1380          (equal tick company-added-newline))
1381        ;; Only set unmodified when tick remained the same since insert,
1382        ;; and the buffer wasn't modified before.
1383        (set-buffer-modified-p nil))
1384   (when company-prefix
1385     (if (stringp result)
1386         (progn
1387           (company-call-backend 'pre-completion result)
1388           (run-hook-with-args 'company-completion-finished-hook result)
1389           (company-call-backend 'post-completion result))
1390       (run-hook-with-args 'company-completion-cancelled-hook result)))
1391   (setq company-added-newline nil
1392         company-backend nil
1393         company-prefix nil
1394         company-candidates nil
1395         company-candidates-length nil
1396         company-candidates-cache nil
1397         company-candidates-predicate nil
1398         company-common nil
1399         company-selection 0
1400         company-selection-changed nil
1401         company--manual-action nil
1402         company--manual-prefix nil
1403         company-lighter company-default-lighter
1404         company--point-max nil
1405         company-point nil)
1406   (when company-timer
1407     (cancel-timer company-timer))
1408   (company-search-mode 0)
1409   (company-call-frontends 'hide)
1410   (company-enable-overriding-keymap nil)
1411   ;; Make return value explicit.
1412   nil)
1413
1414 (defun company-abort ()
1415   (interactive)
1416   (company-cancel t)
1417   ;; Don't start again, unless started manually.
1418   (setq company-point (point)))
1419
1420 (defun company-finish (result)
1421   (company--insert-candidate result)
1422   (company-cancel result)
1423   ;; Don't start again, unless started manually.
1424   (setq company-point (point)))
1425
1426 (defsubst company-keep (command)
1427   (and (symbolp command) (get command 'company-keep)))
1428
1429 (defun company-pre-command ()
1430   (unless (company-keep this-command)
1431     (condition-case err
1432         (when company-candidates
1433           (company-call-frontends 'pre-command)
1434           (unless (company--should-continue)
1435             (company-abort)))
1436       (error (message "Company: An error occurred in pre-command")
1437              (message "%s" (error-message-string err))
1438              (company-cancel))))
1439   (when company-timer
1440     (cancel-timer company-timer)
1441     (setq company-timer nil))
1442   (company-uninstall-map))
1443
1444 (defun company-post-command ()
1445   (unless (company-keep this-command)
1446     (condition-case err
1447         (progn
1448           (unless (equal (point) company-point)
1449             (company-begin))
1450           (if company-candidates
1451               (company-call-frontends 'post-command)
1452             (and (numberp company-idle-delay)
1453                  (or (eq t company-begin-commands)
1454                      (memq this-command company-begin-commands))
1455                  (not (equal (point) company-point))
1456                  (setq company-timer
1457                        (run-with-timer company-idle-delay nil
1458                                        'company-idle-begin
1459                                        (current-buffer) (selected-window)
1460                                        (buffer-chars-modified-tick) (point))))))
1461       (error (message "Company: An error occurred in post-command")
1462              (message "%s" (error-message-string err))
1463              (company-cancel))))
1464   (company-install-map))
1465
1466 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1467
1468 (defvar company-search-string nil)
1469 (make-variable-buffer-local 'company-search-string)
1470
1471 (defvar company-search-lighter " Search: \"\"")
1472 (make-variable-buffer-local 'company-search-lighter)
1473
1474 (defvar company-search-old-map nil)
1475 (make-variable-buffer-local 'company-search-old-map)
1476
1477 (defvar company-search-old-selection 0)
1478 (make-variable-buffer-local 'company-search-old-selection)
1479
1480 (defun company-search (text lines)
1481   (let ((quoted (regexp-quote text))
1482         (i 0))
1483     (dolist (line lines)
1484       (when (string-match quoted line (length company-prefix))
1485         (return i))
1486       (incf i))))
1487
1488 (defun company-search-printing-char ()
1489   (interactive)
1490   (company-search-assert-enabled)
1491   (setq company-search-string
1492         (concat (or company-search-string "") (string last-command-event))
1493         company-search-lighter (concat " Search: \"" company-search-string
1494                                         "\""))
1495   (let ((pos (company-search company-search-string
1496                               (nthcdr company-selection company-candidates))))
1497     (if (null pos)
1498         (ding)
1499       (company-set-selection (+ company-selection pos) t))))
1500
1501 (defun company-search-repeat-forward ()
1502   "Repeat the incremental search in completion candidates forward."
1503   (interactive)
1504   (company-search-assert-enabled)
1505   (let ((pos (company-search company-search-string
1506                               (cdr (nthcdr company-selection
1507                                            company-candidates)))))
1508     (if (null pos)
1509         (ding)
1510       (company-set-selection (+ company-selection pos 1) t))))
1511
1512 (defun company-search-repeat-backward ()
1513   "Repeat the incremental search in completion candidates backwards."
1514   (interactive)
1515   (company-search-assert-enabled)
1516   (let ((pos (company-search company-search-string
1517                               (nthcdr (- company-candidates-length
1518                                          company-selection)
1519                                       (reverse company-candidates)))))
1520     (if (null pos)
1521         (ding)
1522       (company-set-selection (- company-selection pos 1) t))))
1523
1524 (defun company-create-match-predicate ()
1525   (setq company-candidates-predicate
1526         `(lambda (candidate)
1527            ,(if company-candidates-predicate
1528                 `(and (string-match ,company-search-string candidate)
1529                       (funcall ,company-candidates-predicate
1530                                candidate))
1531               `(string-match ,company-search-string candidate))))
1532   (company-update-candidates
1533    (company-apply-predicate company-candidates company-candidates-predicate))
1534   ;; Invalidate cache.
1535   (setq company-candidates-cache (cons company-prefix company-candidates)))
1536
1537 (defun company-filter-printing-char ()
1538   (interactive)
1539   (company-search-assert-enabled)
1540   (company-search-printing-char)
1541   (company-create-match-predicate)
1542   (company-call-frontends 'update))
1543
1544 (defun company-search-kill-others ()
1545   "Limit the completion candidates to the ones matching the search string."
1546   (interactive)
1547   (company-search-assert-enabled)
1548   (company-create-match-predicate)
1549   (company-search-mode 0)
1550   (company-call-frontends 'update))
1551
1552 (defun company-search-abort ()
1553   "Abort searching the completion candidates."
1554   (interactive)
1555   (company-search-assert-enabled)
1556   (company-set-selection company-search-old-selection t)
1557   (company-search-mode 0))
1558
1559 (defun company-search-other-char ()
1560   (interactive)
1561   (company-search-assert-enabled)
1562   (company-search-mode 0)
1563   (company--unread-last-input))
1564
1565 (defvar company-search-map
1566   (let ((i 0)
1567         (keymap (make-keymap)))
1568     (if (fboundp 'max-char)
1569         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1570                               'company-search-printing-char)
1571       (with-no-warnings
1572         ;; obsolete in Emacs 23
1573         (let ((l (generic-character-list))
1574               (table (nth 1 keymap)))
1575           (while l
1576             (set-char-table-default table (car l) 'company-search-printing-char)
1577             (setq l (cdr l))))))
1578     (define-key keymap [t] 'company-search-other-char)
1579     (while (< i ?\s)
1580       (define-key keymap (make-string 1 i) 'company-search-other-char)
1581       (incf i))
1582     (while (< i 256)
1583       (define-key keymap (vector i) 'company-search-printing-char)
1584       (incf i))
1585     (let ((meta-map (make-sparse-keymap)))
1586       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1587       (define-key keymap [escape] meta-map))
1588     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1589     (define-key keymap "\e\e\e" 'company-search-other-char)
1590     (define-key keymap  [escape escape escape] 'company-search-other-char)
1591
1592     (define-key keymap "\C-g" 'company-search-abort)
1593     (define-key keymap "\C-s" 'company-search-repeat-forward)
1594     (define-key keymap "\C-r" 'company-search-repeat-backward)
1595     (define-key keymap "\C-o" 'company-search-kill-others)
1596     keymap)
1597   "Keymap used for incrementally searching the completion candidates.")
1598
1599 (define-minor-mode company-search-mode
1600   "Search mode for completion candidates.
1601 Don't start this directly, use `company-search-candidates' or
1602 `company-filter-candidates'."
1603   nil company-search-lighter nil
1604   (if company-search-mode
1605       (if (company-manual-begin)
1606           (progn
1607             (setq company-search-old-selection company-selection)
1608             (company-call-frontends 'update))
1609         (setq company-search-mode nil))
1610     (kill-local-variable 'company-search-string)
1611     (kill-local-variable 'company-search-lighter)
1612     (kill-local-variable 'company-search-old-selection)
1613     (company-enable-overriding-keymap company-active-map)))
1614
1615 (defun company-search-assert-enabled ()
1616   (company-assert-enabled)
1617   (unless company-search-mode
1618     (company-uninstall-map)
1619     (error "Company not in search mode")))
1620
1621 (defun company-search-candidates ()
1622   "Start searching the completion candidates incrementally.
1623
1624 \\<company-search-map>Search can be controlled with the commands:
1625 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1626 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1627 - `company-search-abort' (\\[company-search-abort])
1628
1629 Regular characters are appended to the search string.
1630
1631 The command `company-search-kill-others' (\\[company-search-kill-others])
1632 uses the search string to limit the completion candidates."
1633   (interactive)
1634   (company-search-mode 1)
1635   (company-enable-overriding-keymap company-search-map))
1636
1637 (defvar company-filter-map
1638   (let ((keymap (make-keymap)))
1639     (define-key keymap [remap company-search-printing-char]
1640       'company-filter-printing-char)
1641     (set-keymap-parent keymap company-search-map)
1642     keymap)
1643   "Keymap used for incrementally searching the completion candidates.")
1644
1645 (defun company-filter-candidates ()
1646   "Start filtering the completion candidates incrementally.
1647 This works the same way as `company-search-candidates' immediately
1648 followed by `company-search-kill-others' after each input."
1649   (interactive)
1650   (company-search-mode 1)
1651   (company-enable-overriding-keymap company-filter-map))
1652
1653 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1654
1655 (defun company-select-next ()
1656   "Select the next candidate in the list."
1657   (interactive)
1658   (when (company-manual-begin)
1659     (company-set-selection (1+ company-selection))))
1660
1661 (defun company-select-previous ()
1662   "Select the previous candidate in the list."
1663   (interactive)
1664   (when (company-manual-begin)
1665     (company-set-selection (1- company-selection))))
1666
1667 (defun company-select-next-or-abort ()
1668   "Select the next candidate if more than one, else abort
1669 and invoke the normal binding."
1670   (interactive)
1671   (if (> company-candidates-length 1)
1672       (company-select-next)
1673     (company-abort)
1674     (company--unread-last-input)))
1675
1676 (defun company-select-previous-or-abort ()
1677   "Select the previous candidate if more than one, else abort
1678 and invoke the normal binding."
1679   (interactive)
1680   (if (> company-candidates-length 1)
1681       (company-select-previous)
1682     (company-abort)
1683     (company--unread-last-input)))
1684
1685 (defvar company-pseudo-tooltip-overlay)
1686
1687 (defvar company-tooltip-offset)
1688
1689 (defun company--inside-tooltip-p (event-col-row row height)
1690   (let* ((ovl company-pseudo-tooltip-overlay)
1691          (column (overlay-get ovl 'company-column))
1692          (width (overlay-get ovl 'company-width))
1693          (evt-col (car event-col-row))
1694          (evt-row (cdr event-col-row)))
1695     (and (>= evt-col column)
1696          (< evt-col (+ column width))
1697          (if (> height 0)
1698              (and (> evt-row row)
1699                   (<= evt-row (+ row height) ))
1700            (and (< evt-row row)
1701                 (>= evt-row (+ row height)))))))
1702
1703 (defun company--event-col-row (event)
1704   (let* ((col-row (posn-actual-col-row (event-start event)))
1705          (col (car col-row))
1706          (row (cdr col-row)))
1707     (incf col (window-hscroll))
1708     (and header-line-format
1709          (version< "24" emacs-version)
1710          (decf row))
1711     (cons col row)))
1712
1713 (defun company-select-mouse (event)
1714   "Select the candidate picked by the mouse."
1715   (interactive "e")
1716   (let ((event-col-row (company--event-col-row event))
1717         (ovl-row (company--row))
1718         (ovl-height (and company-pseudo-tooltip-overlay
1719                          (min (overlay-get company-pseudo-tooltip-overlay
1720                                            'company-height)
1721                               company-candidates-length))))
1722     (if (and ovl-height
1723              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1724         (progn
1725           (company-set-selection (+ (cdr event-col-row)
1726                                     (1- company-tooltip-offset)
1727                                     (if (and (eq company-tooltip-offset-display 'lines)
1728                                              (not (zerop company-tooltip-offset)))
1729                                         -1 0)
1730                                     (- ovl-row)
1731                                     (if (< ovl-height 0)
1732                                         (- 1 ovl-height)
1733                                       0)))
1734           t)
1735       (company-abort)
1736       (company--unread-last-input)
1737       nil)))
1738
1739 (defun company-complete-mouse (event)
1740   "Insert the candidate picked by the mouse."
1741   (interactive "e")
1742   (when (company-select-mouse event)
1743     (company-complete-selection)))
1744
1745 (defun company-complete-selection ()
1746   "Insert the selected candidate."
1747   (interactive)
1748   (when (company-manual-begin)
1749     (let ((result (nth company-selection company-candidates)))
1750       (company-finish result))))
1751
1752 (defun company-complete-common ()
1753   "Insert the common part of all candidates."
1754   (interactive)
1755   (when (company-manual-begin)
1756     (if (and (not (cdr company-candidates))
1757              (equal company-common (car company-candidates)))
1758         (company-complete-selection)
1759       (when company-common
1760         (company--insert-candidate company-common)))))
1761
1762 (defun company-complete ()
1763   "Insert the common part of all candidates or the current selection.
1764 The first time this is called, the common part is inserted, the second
1765 time, or when the selection has been changed, the selected candidate is
1766 inserted."
1767   (interactive)
1768   (when (company-manual-begin)
1769     (if (or company-selection-changed
1770             (eq last-command 'company-complete-common))
1771         (call-interactively 'company-complete-selection)
1772       (call-interactively 'company-complete-common)
1773       (setq this-command 'company-complete-common))))
1774
1775 (defun company-complete-number (n)
1776   "Insert the Nth candidate.
1777 To show the number next to the candidates in some back-ends, enable
1778 `company-show-numbers'."
1779   (when (company-manual-begin)
1780     (and (< n 1) (> n company-candidates-length)
1781          (error "No candidate number %d" n))
1782     (decf n)
1783     (company-finish (nth n company-candidates))))
1784
1785 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1786
1787 (defconst company-space-strings-limit 100)
1788
1789 (defconst company-space-strings
1790   (let (lst)
1791     (dotimes (i company-space-strings-limit)
1792       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1793     (apply 'vector lst)))
1794
1795 (defun company-space-string (len)
1796   (if (< len company-space-strings-limit)
1797       (aref company-space-strings len)
1798     (make-string len ?\ )))
1799
1800 (defun company-safe-substring (str from &optional to)
1801   (if (> from (string-width str))
1802       ""
1803     (with-temp-buffer
1804       (insert str)
1805       (move-to-column from)
1806       (let ((beg (point)))
1807         (if to
1808             (progn
1809               (move-to-column to)
1810               (concat (buffer-substring beg (point))
1811                       (let ((padding (- to (current-column))))
1812                         (when (> padding 0)
1813                           (company-space-string padding)))))
1814           (buffer-substring beg (point-max)))))))
1815
1816 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1817
1818 (defvar company-last-metadata nil)
1819 (make-variable-buffer-local 'company-last-metadata)
1820
1821 (defun company-fetch-metadata ()
1822   (let ((selected (nth company-selection company-candidates)))
1823     (unless (eq selected (car company-last-metadata))
1824       (setq company-last-metadata
1825             (cons selected (company-call-backend 'meta selected))))
1826     (cdr company-last-metadata)))
1827
1828 (defun company-doc-buffer (&optional string)
1829   (with-current-buffer (get-buffer-create "*company-documentation*")
1830     (erase-buffer)
1831     (when string
1832       (save-excursion
1833         (insert string)))
1834     (current-buffer)))
1835
1836 (defvar company--electric-commands
1837   '(scroll-other-window scroll-other-window-down)
1838   "List of Commands that won't break out of electric commands.")
1839
1840 (defmacro company--electric-do (&rest body)
1841   (declare (indent 0) (debug t))
1842   `(when (company-manual-begin)
1843      (save-window-excursion
1844        (let ((height (window-height))
1845              (row (company--row))
1846              cmd)
1847          ,@body
1848          (and (< (window-height) height)
1849               (< (- (window-height) row 2) company-tooltip-limit)
1850               (recenter (- (window-height) row 2)))
1851          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1852                       company--electric-commands)
1853            (call-interactively cmd))
1854          (company--unread-last-input)))))
1855
1856 (defun company--unread-last-input ()
1857   (when last-input-event
1858     (clear-this-command-keys t)
1859     (setq unread-command-events (list last-input-event))))
1860
1861 (defun company-show-doc-buffer ()
1862   "Temporarily show the documentation buffer for the selection."
1863   (interactive)
1864   (company--electric-do
1865     (let* ((selected (nth company-selection company-candidates))
1866            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1867                            (error "No documentation available"))))
1868       (with-current-buffer doc-buffer
1869         (goto-char (point-min)))
1870       (display-buffer doc-buffer t))))
1871 (put 'company-show-doc-buffer 'company-keep t)
1872
1873 (defun company-show-location ()
1874   "Temporarily display a buffer showing the selected candidate in context."
1875   (interactive)
1876   (company--electric-do
1877     (let* ((selected (nth company-selection company-candidates))
1878            (location (company-call-backend 'location selected))
1879            (pos (or (cdr location) (error "No location available")))
1880            (buffer (or (and (bufferp (car location)) (car location))
1881                        (find-file-noselect (car location) t))))
1882       (with-selected-window (display-buffer buffer t)
1883         (save-restriction
1884           (widen)
1885           (if (bufferp (car location))
1886               (goto-char pos)
1887             (goto-char (point-min))
1888             (forward-line (1- pos))))
1889         (set-window-start nil (point))))))
1890 (put 'company-show-location 'company-keep t)
1891
1892 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1893
1894 (defvar company-callback nil)
1895 (make-variable-buffer-local 'company-callback)
1896
1897 (defun company-remove-callback (&optional ignored)
1898   (remove-hook 'company-completion-finished-hook company-callback t)
1899   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1900   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
1901
1902 (defun company-begin-backend (backend &optional callback)
1903   "Start a completion at point using BACKEND."
1904   (interactive (let ((val (completing-read "Company back-end: "
1905                                            obarray
1906                                            'functionp nil "company-")))
1907                  (when val
1908                    (list (intern val)))))
1909   (when (setq company-callback callback)
1910     (add-hook 'company-completion-finished-hook company-callback nil t))
1911   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1912   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1913   (setq company-backend backend)
1914   ;; Return non-nil if active.
1915   (or (company-manual-begin)
1916       (error "Cannot complete at point")))
1917
1918 (defun company-begin-with (candidates
1919                            &optional prefix-length require-match callback)
1920   "Start a completion at point.
1921 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
1922 of the prefix that already is in the buffer before point.
1923 It defaults to 0.
1924
1925 CALLBACK is a function called with the selected result if the user
1926 successfully completes the input.
1927
1928 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
1929   (let ((begin-marker (copy-marker (point) t)))
1930     (company-begin-backend
1931      (lambda (command &optional arg &rest ignored)
1932        (pcase command
1933         (`prefix
1934          (when (equal (point) (marker-position begin-marker))
1935            (buffer-substring (- (point) (or prefix-length 0)) (point))))
1936         (`candidates
1937          (all-completions arg candidates))
1938         (`require-match
1939          require-match)))
1940      callback)))
1941
1942 (defun company-version (&optional show-version)
1943   "Get the Company version as string.
1944
1945 If SHOW-VERSION is non-nil, show the version in the echo area."
1946   (interactive (list t))
1947   (with-temp-buffer
1948     (insert-file-contents (find-library-name "company"))
1949     (require 'lisp-mnt)
1950     (if show-version
1951         (message "Company version: %s" (lm-version))
1952       (lm-version))))
1953
1954 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1955
1956 (defvar company-pseudo-tooltip-overlay nil)
1957 (make-variable-buffer-local 'company-pseudo-tooltip-overlay)
1958
1959 (defvar company-tooltip-offset 0)
1960 (make-variable-buffer-local 'company-tooltip-offset)
1961
1962 (defun company-tooltip--lines-update-offset (selection num-lines limit)
1963   (decf limit 2)
1964   (setq company-tooltip-offset
1965         (max (min selection company-tooltip-offset)
1966              (- selection -1 limit)))
1967
1968   (when (<= company-tooltip-offset 1)
1969     (incf limit)
1970     (setq company-tooltip-offset 0))
1971
1972   (when (>= company-tooltip-offset (- num-lines limit 1))
1973     (incf limit)
1974     (when (= selection (1- num-lines))
1975       (decf company-tooltip-offset)
1976       (when (<= company-tooltip-offset 1)
1977         (setq company-tooltip-offset 0)
1978         (incf limit))))
1979
1980   limit)
1981
1982 (defun company-tooltip--simple-update-offset (selection num-lines limit)
1983   (setq company-tooltip-offset
1984         (if (< selection company-tooltip-offset)
1985             selection
1986           (max company-tooltip-offset
1987                (- selection limit -1)))))
1988
1989 ;;; propertize
1990
1991 (defsubst company-round-tab (arg)
1992   (* (/ (+ arg tab-width) tab-width) tab-width))
1993
1994 (defun company-plainify (str)
1995   (let ((prefix (get-text-property 0 'line-prefix str)))
1996     (when prefix ; Keep the original value unmodified, for no special reason.
1997       (setq str (concat prefix str))
1998       (remove-text-properties 0 (length str) '(line-prefix) str)))
1999   (let* ((pieces (split-string str "\t"))
2000          (copy pieces))
2001     (while (cdr copy)
2002       (setcar copy (company-safe-substring
2003                     (car copy) 0 (company-round-tab (string-width (car copy)))))
2004       (pop copy))
2005     (apply 'concat pieces)))
2006
2007 (defun company-fill-propertize (value annotation width selected left right)
2008   (let* ((margin (length left))
2009          (common (+ (or (company-call-backend 'match value)
2010                         (length company-common)) margin))
2011          (ann-ralign company-tooltip-align-annotations)
2012          (ann-truncate (< width
2013                           (+ (length value) (length annotation)
2014                              (if ann-ralign 1 0))))
2015          (ann-start (+ margin
2016                        (if ann-ralign
2017                            (if ann-truncate
2018                                (1+ (length value))
2019                              (- width (length annotation)))
2020                          (length value))))
2021          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
2022          (line (concat left
2023                        (if (or ann-truncate (not ann-ralign))
2024                            (company-safe-substring
2025                             (concat value
2026                                     (when (and annotation ann-ralign) " ")
2027                                     annotation)
2028                             0 width)
2029                          (concat
2030                           (company-safe-substring value 0
2031                                                   (- width (length annotation)))
2032                           annotation))
2033                        right)))
2034     (setq width (+ width margin (length right)))
2035
2036     (add-text-properties 0 width '(face company-tooltip
2037                                    mouse-face company-tooltip-mouse)
2038                          line)
2039     (add-text-properties margin common
2040                          '(face company-tooltip-common
2041                            mouse-face company-tooltip-mouse)
2042                          line)
2043     (when (< ann-start ann-end)
2044       (add-text-properties ann-start ann-end
2045                            '(face company-tooltip-annotation
2046                              mouse-face company-tooltip-mouse)
2047                            line))
2048     (when selected
2049       (if (and company-search-string
2050                (string-match (regexp-quote company-search-string) value
2051                              (length company-prefix)))
2052           (let ((beg (+ margin (match-beginning 0)))
2053                 (end (+ margin (match-end 0))))
2054             (add-text-properties beg end '(face company-tooltip-selection)
2055                                  line)
2056             (when (< beg common)
2057               (add-text-properties beg common
2058                                    '(face company-tooltip-common-selection)
2059                                    line)))
2060         (add-text-properties 0 width '(face company-tooltip-selection
2061                                        mouse-face company-tooltip-selection)
2062                              line)
2063         (add-text-properties margin common
2064                              '(face company-tooltip-common-selection
2065                                mouse-face company-tooltip-selection)
2066                              line)))
2067     line))
2068
2069 ;;; replace
2070
2071 (defun company-buffer-lines (beg end)
2072   (goto-char beg)
2073   (let (lines)
2074     (while (and (= 1 (vertical-motion 1))
2075                 (<= (point) end))
2076       (let ((bound (min end (1- (point)))))
2077         ;; A visual line can contain several physical lines (e.g. with outline's
2078         ;; folding overlay).  Take only the first one.
2079         (push (buffer-substring beg
2080                                 (save-excursion
2081                                   (goto-char beg)
2082                                   (re-search-forward "$" bound 'move)
2083                                   (point)))
2084               lines))
2085       (setq beg (point)))
2086     (unless (eq beg end)
2087       (push (buffer-substring beg end) lines))
2088     (nreverse lines)))
2089
2090 (defun company-modify-line (old new offset)
2091   (concat (company-safe-substring old 0 offset)
2092           new
2093           (company-safe-substring old (+ offset (length new)))))
2094
2095 (defsubst company--length-limit (lst limit)
2096   (if (nthcdr limit lst)
2097       limit
2098     (length lst)))
2099
2100 (defun company--replacement-string (lines old column nl &optional align-top)
2101   (decf column company-tooltip-margin)
2102
2103   (let ((width (length (car lines)))
2104         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2105                            column)))
2106     (when (> width remaining-cols)
2107       (decf column (- width remaining-cols))))
2108
2109   (let ((offset (and (< column 0) (- column)))
2110         new)
2111     (when offset
2112       (setq column 0))
2113     (when align-top
2114       ;; untouched lines first
2115       (dotimes (_ (- (length old) (length lines)))
2116         (push (pop old) new)))
2117     ;; length into old lines.
2118     (while old
2119       (push (company-modify-line (pop old)
2120                                  (company--offset-line (pop lines) offset)
2121                                  column) new))
2122     ;; Append whole new lines.
2123     (while lines
2124       (push (concat (company-space-string column)
2125                     (company--offset-line (pop lines) offset))
2126             new))
2127
2128     (let ((str (concat (when nl "\n")
2129                        (mapconcat 'identity (nreverse new) "\n")
2130                        "\n")))
2131       (font-lock-append-text-property 0 (length str) 'face 'default str)
2132       str)))
2133
2134 (defun company--offset-line (line offset)
2135   (if (and offset line)
2136       (substring line offset)
2137     line))
2138
2139 (defun company--create-lines (selection limit)
2140   (let ((len company-candidates-length)
2141         (numbered 99999)
2142         (window-width (company--window-width))
2143         lines
2144         width
2145         lines-copy
2146         items
2147         previous
2148         remainder
2149         scrollbar-bounds)
2150
2151     ;; Maybe clear old offset.
2152     (when (< len (+ company-tooltip-offset limit))
2153       (setq company-tooltip-offset 0))
2154
2155     ;; Scroll to offset.
2156     (if (eq company-tooltip-offset-display 'lines)
2157         (setq limit (company-tooltip--lines-update-offset selection len limit))
2158       (company-tooltip--simple-update-offset selection len limit))
2159
2160     (cond
2161      ((eq company-tooltip-offset-display 'scrollbar)
2162       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2163                                                         limit len)))
2164      ((eq company-tooltip-offset-display 'lines)
2165       (when (> company-tooltip-offset 0)
2166         (setq previous (format "...(%d)" company-tooltip-offset)))
2167       (setq remainder (- len limit company-tooltip-offset)
2168             remainder (when (> remainder 0)
2169                         (setq remainder (format "...(%d)" remainder))))))
2170
2171     (decf selection company-tooltip-offset)
2172     (setq width (max (length previous) (length remainder))
2173           lines (nthcdr company-tooltip-offset company-candidates)
2174           len (min limit len)
2175           lines-copy lines)
2176
2177     (decf window-width (* 2 company-tooltip-margin))
2178     (when scrollbar-bounds (decf window-width))
2179
2180     (dotimes (_ len)
2181       (let* ((value (pop lines-copy))
2182              (annotation (company-call-backend 'annotation value)))
2183         (when (and annotation company-tooltip-align-annotations)
2184           ;; `lisp-completion-at-point' adds a space.
2185           (setq annotation (comment-string-strip annotation t nil)))
2186         (push (cons value annotation) items)
2187         (setq width (max (+ (length value)
2188                             (if (and annotation company-tooltip-align-annotations)
2189                                 (1+ (length annotation))
2190                               (length annotation)))
2191                          width))))
2192
2193     (setq width (min window-width
2194                      (if (and company-show-numbers
2195                               (< company-tooltip-offset 10))
2196                          (+ 2 width)
2197                        width)))
2198
2199     ;; number can make tooltip too long
2200     (when company-show-numbers
2201       (setq numbered company-tooltip-offset))
2202
2203     (let ((items (nreverse items)) new)
2204       (when previous
2205         (push (company--scrollpos-line previous width) new))
2206
2207       (dotimes (i len)
2208         (let* ((item (pop items))
2209                (str (company-reformat (car item)))
2210                (annotation (cdr item))
2211                (right (company-space-string company-tooltip-margin))
2212                (width width))
2213           (when (< numbered 10)
2214             (decf width 2)
2215             (incf numbered)
2216             (setq right (concat (format " %d" (mod numbered 10)) right)))
2217           (push (concat
2218                  (company-fill-propertize str annotation
2219                                           width (equal i selection)
2220                                           (company-space-string
2221                                            company-tooltip-margin)
2222                                           right)
2223                  (when scrollbar-bounds
2224                    (company--scrollbar i scrollbar-bounds)))
2225                 new)))
2226
2227       (when remainder
2228         (push (company--scrollpos-line remainder width) new))
2229
2230       (nreverse new))))
2231
2232 (defun company--scrollbar-bounds (offset limit length)
2233   (when (> length limit)
2234     (let* ((size (ceiling (* limit (float limit)) length))
2235            (lower (floor (* limit (float offset)) length))
2236            (upper (+ lower size -1)))
2237       (cons lower upper))))
2238
2239 (defun company--scrollbar (i bounds)
2240   (propertize " " 'face
2241               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2242                   'company-scrollbar-fg
2243                 'company-scrollbar-bg)))
2244
2245 (defun company--scrollpos-line (text width)
2246   (propertize (concat (company-space-string company-tooltip-margin)
2247                       (company-safe-substring text 0 width)
2248                       (company-space-string company-tooltip-margin))
2249    'face 'company-tooltip))
2250
2251 ;; show
2252
2253 (defsubst company--window-inner-height ()
2254   (let ((edges (window-inside-edges)))
2255     (- (nth 3 edges) (nth 1 edges))))
2256
2257 (defsubst company--window-width ()
2258   (- (window-width)
2259      (cond
2260       ((display-graphic-p) 0)
2261       ;; Account for the line continuation column.
2262       ((version< "24.3.1" emacs-version) 1)
2263       ;; Emacs 24.3 and earlier included margins
2264       ;; in window-width when in TTY.
2265       (t (1+ (let ((margins (window-margins)))
2266                (+ (or (car margins) 0)
2267                   (or (cdr margins) 0))))))))
2268
2269 (defun company--pseudo-tooltip-height ()
2270   "Calculate the appropriate tooltip height.
2271 Returns a negative number if the tooltip should be displayed above point."
2272   (let* ((lines (company--row))
2273          (below (- (company--window-inner-height) 1 lines)))
2274     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2275              (> lines below))
2276         (- (max 3 (min company-tooltip-limit lines)))
2277       (max 3 (min company-tooltip-limit below)))))
2278
2279 (defun company-pseudo-tooltip-show (row column selection)
2280   (company-pseudo-tooltip-hide)
2281   (save-excursion
2282
2283     (let* ((height (company--pseudo-tooltip-height))
2284            above)
2285
2286       (when (< height 0)
2287         (setq row (+ row height -1)
2288               above t))
2289
2290       (let* ((nl (< (move-to-window-line row) row))
2291              (beg (point))
2292              (end (save-excursion
2293                     (move-to-window-line (+ row (abs height)))
2294                     (point)))
2295              (ov (make-overlay beg end))
2296              (args (list (mapcar 'company-plainify
2297                                  (company-buffer-lines beg end))
2298                          column nl above)))
2299
2300         (setq company-pseudo-tooltip-overlay ov)
2301         (overlay-put ov 'company-replacement-args args)
2302
2303         (let ((lines (company--create-lines selection (abs height))))
2304           (overlay-put ov 'company-after
2305                        (apply 'company--replacement-string lines args))
2306           (overlay-put ov 'company-width (string-width (car lines))))
2307
2308         (overlay-put ov 'company-column column)
2309         (overlay-put ov 'company-height height)))))
2310
2311 (defun company-pseudo-tooltip-show-at-point (pos)
2312   (let ((row (company--row pos))
2313         (col (company--column pos)))
2314     (company-pseudo-tooltip-show (1+ row) col company-selection)))
2315
2316 (defun company-pseudo-tooltip-edit (selection)
2317   (let ((height (overlay-get company-pseudo-tooltip-overlay 'company-height)))
2318     (overlay-put company-pseudo-tooltip-overlay 'company-after
2319                  (apply 'company--replacement-string
2320                         (company--create-lines selection (abs height))
2321                         (overlay-get company-pseudo-tooltip-overlay
2322                                      'company-replacement-args)))))
2323
2324 (defun company-pseudo-tooltip-hide ()
2325   (when company-pseudo-tooltip-overlay
2326     (delete-overlay company-pseudo-tooltip-overlay)
2327     (setq company-pseudo-tooltip-overlay nil)))
2328
2329 (defun company-pseudo-tooltip-hide-temporarily ()
2330   (when (overlayp company-pseudo-tooltip-overlay)
2331     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2332     (overlay-put company-pseudo-tooltip-overlay 'line-prefix nil)
2333     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)))
2334
2335 (defun company-pseudo-tooltip-unhide ()
2336   (when company-pseudo-tooltip-overlay
2337     (overlay-put company-pseudo-tooltip-overlay 'invisible t)
2338     ;; Beat outline's folding overlays, at least.
2339     (overlay-put company-pseudo-tooltip-overlay 'priority 1)
2340     ;; No (extra) prefix for the first line.
2341     (overlay-put company-pseudo-tooltip-overlay 'line-prefix "")
2342     (overlay-put company-pseudo-tooltip-overlay 'after-string
2343                  (overlay-get company-pseudo-tooltip-overlay 'company-after))
2344     (overlay-put company-pseudo-tooltip-overlay 'window (selected-window))))
2345
2346 (defun company-pseudo-tooltip-guard ()
2347   (buffer-substring-no-properties
2348    (point) (overlay-start company-pseudo-tooltip-overlay)))
2349
2350 (defun company-pseudo-tooltip-frontend (command)
2351   "`company-mode' front-end similar to a tooltip but based on overlays."
2352   (case command
2353     (pre-command (company-pseudo-tooltip-hide-temporarily))
2354     (post-command
2355      (let ((old-height (if (overlayp company-pseudo-tooltip-overlay)
2356                            (overlay-get company-pseudo-tooltip-overlay
2357                                         'company-height)
2358                          0))
2359            (new-height (company--pseudo-tooltip-height)))
2360        (unless (and (>= (* old-height new-height) 0)
2361                     (>= (abs old-height) (abs new-height))
2362                     (equal (company-pseudo-tooltip-guard)
2363                            (overlay-get company-pseudo-tooltip-overlay
2364                                         'company-guard)))
2365          ;; Redraw needed.
2366          (company-pseudo-tooltip-show-at-point (- (point)
2367                                                   (length company-prefix)))
2368          (overlay-put company-pseudo-tooltip-overlay
2369                       'company-guard (company-pseudo-tooltip-guard))))
2370      (company-pseudo-tooltip-unhide))
2371     (hide (company-pseudo-tooltip-hide)
2372           (setq company-tooltip-offset 0))
2373     (update (when (overlayp company-pseudo-tooltip-overlay)
2374               (company-pseudo-tooltip-edit company-selection)))))
2375
2376 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2377   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2378   (unless (and (eq command 'post-command)
2379                (company--show-inline-p))
2380     (company-pseudo-tooltip-frontend command)))
2381
2382 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2383
2384 (defvar company-preview-overlay nil)
2385 (make-variable-buffer-local 'company-preview-overlay)
2386
2387 (defun company-preview-show-at-point (pos)
2388   (company-preview-hide)
2389
2390   (setq company-preview-overlay (make-overlay pos (1+ pos)))
2391
2392   (let ((completion (nth company-selection company-candidates)))
2393     (setq completion (propertize completion 'face 'company-preview))
2394     (add-text-properties 0 (length company-common)
2395                          '(face company-preview-common) completion)
2396
2397     ;; Add search string
2398     (and company-search-string
2399          (string-match (regexp-quote company-search-string) completion)
2400          (add-text-properties (match-beginning 0)
2401                               (match-end 0)
2402                               '(face company-preview-search)
2403                               completion))
2404
2405     (setq completion (company-strip-prefix completion))
2406
2407     (and (equal pos (point))
2408          (not (equal completion ""))
2409          (add-text-properties 0 1 '(cursor t) completion))
2410
2411     (overlay-put company-preview-overlay 'display
2412                  (concat completion (unless (eq pos (point-max))
2413                                       (buffer-substring pos (1+ pos)))))
2414     (overlay-put company-preview-overlay 'window (selected-window))))
2415
2416 (defun company-preview-hide ()
2417   (when company-preview-overlay
2418     (delete-overlay company-preview-overlay)
2419     (setq company-preview-overlay nil)))
2420
2421 (defun company-preview-frontend (command)
2422   "`company-mode' front-end showing the selection as if it had been inserted."
2423   (pcase command
2424     (`pre-command (company-preview-hide))
2425     (`post-command (company-preview-show-at-point (point)))
2426     (`hide (company-preview-hide))))
2427
2428 (defun company-preview-if-just-one-frontend (command)
2429   "`company-preview-frontend', but only shown for single candidates."
2430   (when (or (not (eq command 'post-command))
2431             (company--show-inline-p))
2432     (company-preview-frontend command)))
2433
2434 (defun company--show-inline-p ()
2435   (and (not (cdr company-candidates))
2436        company-common
2437        (string-prefix-p company-prefix company-common
2438                         (company-call-backend 'ignore-case))))
2439
2440 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2441
2442 (defvar company-echo-last-msg nil)
2443 (make-variable-buffer-local 'company-echo-last-msg)
2444
2445 (defvar company-echo-timer nil)
2446
2447 (defvar company-echo-delay .01)
2448
2449 (defun company-echo-show (&optional getter)
2450   (when getter
2451     (setq company-echo-last-msg (funcall getter)))
2452   (let ((message-log-max nil))
2453     (if company-echo-last-msg
2454         (message "%s" company-echo-last-msg)
2455       (message ""))))
2456
2457 (defun company-echo-show-soon (&optional getter)
2458   (when company-echo-timer
2459     (cancel-timer company-echo-timer))
2460   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2461
2462 (defsubst company-echo-show-when-idle (&optional getter)
2463   (when (sit-for company-echo-delay)
2464     (company-echo-show getter)))
2465
2466 (defun company-echo-format ()
2467
2468   (let ((limit (window-width (minibuffer-window)))
2469         (len -1)
2470         ;; Roll to selection.
2471         (candidates (nthcdr company-selection company-candidates))
2472         (i (if company-show-numbers company-selection 99999))
2473         comp msg)
2474
2475     (while candidates
2476       (setq comp (company-reformat (pop candidates))
2477             len (+ len 1 (length comp)))
2478       (if (< i 10)
2479           ;; Add number.
2480           (progn
2481             (setq comp (propertize (format "%d: %s" i comp)
2482                                    'face 'company-echo))
2483             (incf len 3)
2484             (incf i)
2485             (add-text-properties 3 (+ 3 (length company-common))
2486                                  '(face company-echo-common) comp))
2487         (setq comp (propertize comp 'face 'company-echo))
2488         (add-text-properties 0 (length company-common)
2489                              '(face company-echo-common) comp))
2490       (if (>= len limit)
2491           (setq candidates nil)
2492         (push comp msg)))
2493
2494     (mapconcat 'identity (nreverse msg) " ")))
2495
2496 (defun company-echo-strip-common-format ()
2497
2498   (let ((limit (window-width (minibuffer-window)))
2499         (len (+ (length company-prefix) 2))
2500         ;; Roll to selection.
2501         (candidates (nthcdr company-selection company-candidates))
2502         (i (if company-show-numbers company-selection 99999))
2503         msg comp)
2504
2505     (while candidates
2506       (setq comp (company-strip-prefix (pop candidates))
2507             len (+ len 2 (length comp)))
2508       (when (< i 10)
2509         ;; Add number.
2510         (setq comp (format "%s (%d)" comp i))
2511         (incf len 4)
2512         (incf i))
2513       (if (>= len limit)
2514           (setq candidates nil)
2515         (push (propertize comp 'face 'company-echo) msg)))
2516
2517     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2518             (mapconcat 'identity (nreverse msg) ", ")
2519             "}")))
2520
2521 (defun company-echo-hide ()
2522   (unless (equal company-echo-last-msg "")
2523     (setq company-echo-last-msg "")
2524     (company-echo-show)))
2525
2526 (defun company-echo-frontend (command)
2527   "`company-mode' front-end showing the candidates in the echo area."
2528   (pcase command
2529     (`post-command (company-echo-show-soon 'company-echo-format))
2530     (`hide (company-echo-hide))))
2531
2532 (defun company-echo-strip-common-frontend (command)
2533   "`company-mode' front-end showing the candidates in the echo area."
2534   (pcase command
2535     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2536     (`hide (company-echo-hide))))
2537
2538 (defun company-echo-metadata-frontend (command)
2539   "`company-mode' front-end showing the documentation in the echo area."
2540   (pcase command
2541     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
2542     (`hide (company-echo-hide))))
2543
2544 (provide 'company)
2545 ;;; company.el ends here