code.delx.au - gnu-emacs-elpa/blob - company-dabbrev-code.el

   1 ;;; company-dabbrev-code.el --- a dabbrev-like company-mode back-end for code
   2 ;;
   3 ;; Copyright (C) 2009 Nikolaj Schumacher
   4 ;;
   5 ;; This file is part of company 0.3.1.
   6 ;;
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License
   9 ;; as published by the Free Software Foundation; either version 2
  10 ;; of the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (require 'company)
  21 (eval-when-compile (require 'cl))
  22
  23 (defcustom company-dabbrev-code-modes
  24   '(asm-mode batch-file-mode c++-mode c-mode cperl-mode csharp-mode css-mode
  25     emacs-lisp-mode erlang-mode espresso-mode f90-mode fortran-mode
  26     haskell-mode java-mode javascript-mode jde-mode js2-mode lisp-mode
  27     lua-mode objc-mode perl-mode php-mode python-mode ruby-mode scheme-mode
  28     shell-script-mode)
  29   "*Modes that use `company-dabbrev-code'.
  30 In all these modes `company-dabbrev-code' will complete only symbols, not text
  31 in comments or strings.  In other modes `company-dabbrev-code' will pass control
  32 to other back-ends \(e.g. `company-dabbrev'\).
  33 Value t means complete in all modes."
  34   :group 'company
  35   :type '(choice (repeat (symbol :tag "Major mode"))
  36                  (const tag "All modes" t)))
  37
  38 (defcustom company-dabbrev-code-other-buffers .5
  39   "*Determines whether `company-dabbrev-code' should search other buffers.
  40 If t, search all buffers with the same major-mode.  A numeric value means
  41 search other buffers for that many seconds and then return."
  42   :group 'company
  43   :type '(choice (const :tag "Off" nil)
  44                  (const :tag "Same major mode" t)
  45                  (number :tag "Seconds")))
  46
  47 (defmacro company-dabrev-code--time-limit-while (test start limit &rest body)
  48   (declare (indent 3) (debug t))
  49   `(let ((company-time-limit-while-counter 0))
  50      (catch 'done
  51        (while ,test
  52          ,@body
  53          (and ,limit
  54               (eq (incf company-time-limit-while-counter) 25)
  55               (setq company-time-limit-while-counter 0)
  56               (> (float-time (time-since ,start)) ,limit)
  57               (throw 'done 'company-time-out))))))
  58
  59 (defun company-dabbrev-code--buffer-symbols (prefix pos &optional symbols
  60                                              start limit)
  61   (save-excursion
  62     (goto-char (point-min))
  63     (let ((regexp (concat "\\_<" (if (equal prefix "")
  64                                      "\\([a-zA-Z]\\|\\s_\\)"
  65                                    (regexp-quote prefix))
  66                           "\\(\\sw\\|\\s_\\)*\\_>"))
  67           match)
  68       (company-dabrev-code--time-limit-while (re-search-forward regexp nil t)
  69           start limit
  70         (setq match (match-string-no-properties 0))
  71         (if (company-in-string-or-comment)
  72             (re-search-forward "\\s>\\|\\s!\\|\\s\"" nil t)
  73           (unless (eq (match-end 0) pos) ;; ignore match before point
  74             (push match symbols))))
  75       symbols)))
  76
  77 (defun company-dabbrev-code--symbols (prefix &optional limit)
  78   (let ((start (current-time))
  79         (symbols (company-dabbrev-code--buffer-symbols prefix (point))))
  80     (dolist (buffer (delq (current-buffer) (buffer-list)))
  81       (and (eq (buffer-local-value 'major-mode buffer) major-mode)
  82            (with-current-buffer buffer
  83              (setq symbols
  84                    (company-dabbrev-code--buffer-symbols prefix nil symbols
  85                                                          start limit))))
  86       (and limit
  87            (> (float-time (time-since start)) limit)
  88            (return)))
  89     symbols))
  90
  91 ;;;###autoload
  92 (defun company-dabbrev-code (command &optional arg &rest ignored)
  93   "A dabbrev-like `company-mode' back-end for code.
  94 The back-end looks for all symbols in the current buffer that aren't in
  95 comments or strings."
  96   (interactive (list 'interactive))
  97   (case command
  98     ('interactive (company-begin-backend 'company-dabbrev-code))
  99     ('prefix (and (or (eq t company-dabbrev-code-modes)
 100                       (apply 'derived-mode-p company-dabbrev-code-modes))
 101                   (not (company-in-string-or-comment))
 102                   (or (company-grab-symbol) 'stop)))
 103     ('candidates (let ((case-fold-search nil))
 104                    (if company-dabbrev-code-other-buffers
 105                        (company-dabbrev-code--symbols
 106                         arg
 107                         (when (numberp company-dabbrev-code-other-buffers)
 108                           company-dabbrev-code-other-buffers))
 109                      (company-dabbrev-code--buffer-symbols arg (point)))))
 110     ('duplicates t)))
 111
 112 (provide 'company-dabbrev-code)
 113 ;;; company-dabbrev-code.el ends here