code.delx.au - gnu-emacs-elpa/blob - aggressive-indent.el

   1 ;;; aggressive-indent.el --- Minor mode to aggressively keep your code always indented
   2
   3 ;; Copyright (C) 2014 Artur Malabarba <bruce.connor.am@gmail.com>
   4
   5 ;; Author: Artur Malabarba <bruce.connor.am@gmail.com>
   6 ;; URL: http://github.com/Bruce-Connor/aggressive-indent-mode
   7 ;; Version: 0.3
   8 ;; Package-Requires: ((emacs "24.1") (names "0.5") (cl-lib "0.5"))
   9 ;; Keywords: indent lisp maint tools
  10 ;; Prefix: aggressive-indent
  11 ;; Separator: -
  12
  13 ;;; Commentary:
  14 ;;
  15 ;; `electric-indent-mode' is enough to keep your code nicely aligned when
  16 ;; all you do is type. However, once you start shifting blocks around,
  17 ;; transposing lines, or slurping and barfing sexps, indentation is bound
  18 ;; to go wrong.
  19 ;;
  20 ;; `aggressive-indent-mode' is a minor mode that keeps your code always
  21 ;; indented. It reindents after every command, making it more reliable
  22 ;; than `electric-indent-mode'.
  23 ;;
  24 ;; ### Instructions ###
  25 ;;
  26 ;; This package is available fom Melpa, you may install it by calling
  27 ;;
  28 ;;     M-x package-install RET aggressive-indent
  29 ;;
  30 ;; Then activate it with
  31 ;;
  32 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  33 ;;     (add-hook 'css-mode-hook #'aggressive-indent-mode)
  34 ;;
  35 ;; You can use this hook on any mode you want, `aggressive-indent' is not
  36 ;; exclusive to emacs-lisp code. In fact, if you want to turn it on for
  37 ;; every programming mode, you can do something like:
  38 ;;
  39 ;;     (global-aggressive-indent-mode 1)
  40 ;;     (add-to-list 'aggressive-indent-excluded-modes 'html-mode)
  41 ;;
  42 ;; ### Manual Installation ###
  43 ;;
  44 ;; If you don't want to install from Melpa, you can download it manually,
  45 ;; place it in your `load-path' and require it with
  46 ;;
  47 ;;     (require 'aggressive-indent)
  48
  49 ;;; Instructions:
  50 ;;
  51 ;; INSTALLATION
  52 ;;
  53 ;; This package is available fom Melpa, you may install it by calling
  54 ;; M-x package-install RET aggressive-indent.
  55 ;;
  56 ;; Then activate it with
  57 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  58 ;;
  59 ;; You can also use an equivalent hook for another mode,
  60 ;; `aggressive-indent' is not exclusive to emacs-lisp code.
  61 ;;
  62 ;; Alternatively, you can download it manually, place it in your
  63 ;; `load-path' and require it with
  64 ;;
  65 ;;     (require 'aggressive-indent)
  66
  67 ;;; License:
  68 ;;
  69 ;; This file is NOT part of GNU Emacs.
  70 ;;
  71 ;; This program is free software; you can redistribute it and/or
  72 ;; modify it under the terms of the GNU General Public License
  73 ;; as published by the Free Software Foundation; either version 2
  74 ;; of the License, or (at your option) any later version.
  75 ;;
  76 ;; This program is distributed in the hope that it will be useful,
  77 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  78 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  79 ;; GNU General Public License for more details.
  80 ;;
  81
  82 ;;; Change Log:
  83 ;; 0.3 - 2014/10/23 - Implement a smarter engine for non-lisp modes.
  84 ;; 0.2 - 2014/10/20 - Reactivate `electric-indent-mode'.
  85 ;; 0.2 - 2014/10/19 - Add variable `aggressive-indent-dont-indent-if', so the user can prevent indentation.
  86 ;; 0.1 - 2014/10/15 - Release.
  87 ;;; Code:
  88
  89 (require 'cl-lib)
  90 (require 'names)
  91
  92 ;;;###autoload
  93 (define-namespace aggressive-indent- :group indent
  94
  95 (defconst version "0.3" "Version of the aggressive-indent.el package.")
  96 (defun bug-report ()
  97   "Opens github issues page in a web browser. Please send any bugs you find.
  98 Please include your emacs and aggressive-indent versions."
  99   (interactive)
 100   (message "Your `aggressive-indent-version' is: %s, and your emacs version is: %s.
 101 Please include this in your report!"
 102            version emacs-version)
 103   (browse-url "https://github.com/Bruce-Connor/aggressive-indent-mode/issues/new"))
 104
 105 \f
 106 ;;; Start of actual Code:
 107 (defcustom excluded-modes
 108   '(text-mode tabulated-list-mode special-mode
 109               minibuffer-inactive-mode
 110               yaml-mode jabber-chat-mode)
 111   "Modes in which `aggressive-indent-mode' should not be activated.
 112 This variable is only used if `global-aggressive-indent-mode' is
 113 active. If the minor mode is turned on with the local command,
 114 `aggressive-indent-mode', this variable is ignored."
 115   :type '(repeat symbol)
 116   :package-version '(aggressive-indent . "0.2"))
 117
 118 (defcustom protected-commands '(undo undo-tree-undo undo-tree-redo)
 119   "Commands after which indentation will NOT be performed.
 120 Aggressive indentation could break things like `undo' by locking
 121 the user in a loop, so this variable is used to control which
 122 commands will NOT be followed by a re-indent."
 123   :type '(repeat symbol)
 124   :package-version '(aggressive-indent . "0.1"))
 125
 126 (defvar -internal-dont-indent-if
 127   '((memq this-command aggressive-indent-protected-commands)
 128     (region-active-p)
 129     buffer-read-only
 130     (null (buffer-modified-p)))
 131   "List of forms which prevent indentation when they evaluate to non-nil.
 132 This is for internal use only. For user customization, use
 133 `aggressive-indent-dont-indent-if' instead.")
 134
 135 (defcustom modes-to-prefer-defun '(emacs-lisp-mode lisp-mode scheme-mode)
 136   "List of major-modes in which indenting defun is preferred.
 137 Add here any major modes with very good definitions of
 138 `end-of-defun' and `beginning-of-defun', or modes which bug out
 139 if you have `after-change-functions' (such as paredit).
 140
 141 If current major mode is derived from one of these,
 142 `aggressive-indent-mode' will call
 143 `aggressive-indent-indent-defun' after every command. Otherwise,
 144 it will call `aggressive-indent-indent-region-and-on' after every
 145 buffer change."
 146   :type '(repeat symbol)
 147   :group 'aggressive-indent
 148   :package-version '(aggressive-indent . "0.3"))
 149
 150 (eval-after-load 'yasnippet
 151   '(when (boundp 'yas--active-field-overlay)
 152      (add-to-list 'aggressive-indent--internal-dont-indent-if
 153                   '(and
 154                     (overlayp yas--active-field-overlay)
 155                     (overlay-end yas--active-field-overlay))
 156                   'append)))
 157 (eval-after-load 'company
 158   '(when (boundp 'company-candidates)
 159      (add-to-list 'aggressive-indent--internal-dont-indent-if
 160                   'company-candidates)))
 161 (eval-after-load 'auto-complete
 162   '(when (boundp 'ac-completing)
 163      (add-to-list 'aggressive-indent--internal-dont-indent-if
 164                   'ac-completing)))
 165
 166 (eval-after-load 'css-mode
 167   '(add-hook
 168     'css-mode-hook
 169     (lambda () (unless defun-prompt-regexp
 170             (setq-local defun-prompt-regexp "^[^[:blank:]].*")))))
 171
 172 (defcustom dont-indent-if '()
 173   "List of variables and functions to prevent aggressive indenting.
 174 This variable is a list where each element is a lisp form.
 175 As long as any one of these forms returns non-nil,
 176 aggressive-indent will not perform any indentation.
 177
 178 See `aggressive-indent--internal-dont-indent-if' for usage examples."
 179   :type '(repeat sexp)
 180   :group 'aggressive-indent
 181   :package-version '(aggressive-indent . "0.2"))
 182
 183 (defvar -error-message
 184   "One of the forms in `aggressive-indent-dont-indent-if' had the following error, I've disabled it until you fix it: %S"
 185   "Error message thrown by `aggressive-indent-dont-indent-if'.")
 186
 187 (defvar -has-errored nil
 188   "Keep track of whether `aggressive-indent-dont-indent-if' is throwing.
 189 This is used to prevent an infinite error loop on the user.")
 190
 191 (defun -run-user-hooks ()
 192   "Safely run forms in `aggressive-indent-dont-indent-if'.
 193 If any of them errors out, we only report it once until it stops
 194 erroring again."
 195   (and dont-indent-if
 196        (condition-case er
 197            (prog1 (eval (cons 'or dont-indent-if))
 198              (setq -has-errored nil))
 199          (error
 200           (unless -has-errored
 201             (setq -has-errored t)
 202             (message -error-message er))))))
 203
 204 (defmacro -do-softly (&rest body)
 205   "Execute body unobstrusively.
 206 This means: do nothing if mark is active (to avoid deactivaing
 207 it), or if buffer is not modified (to avoid creating accidental
 208 modifications), or if any of the forms in
 209 `aggressive-indent-dont-indent-if' evaluates to non-nil.
 210
 211 Also, never throw errors nor messages.
 212 Meant for use in functions which go in hooks."
 213   (declare (debug t))
 214   `(unless (or (run-hook-wrapped
 215                 'aggressive-indent--internal-dont-indent-if
 216                 #'eval)
 217                (aggressive-indent--run-user-hooks))
 218      (ignore-errors
 219        (cl-letf (((symbol-function 'message) #'ignore))
 220          ,@body))))
 221
 222 :autoload
 223 (defun indent-defun ()
 224   "Indent current defun.
 225 Throw an error if parentheses are unbalanced."
 226   (interactive)
 227   (let ((p (point-marker)))
 228     (set-marker-insertion-type p t)
 229     (indent-region
 230      (save-excursion (beginning-of-defun 1) (point))
 231      (save-excursion (end-of-defun 1) (point)))
 232     (goto-char p)))
 233
 234 (defun -softly-indent-defun ()
 235   "Indent current defun unobstrusively.
 236 Like `aggressive-indent-indent-defun', but wrapped in a
 237 `aggressive-indent--do-softly'."
 238   (unless (or (run-hook-wrapped
 239                'aggressive-indent--internal-dont-indent-if
 240                #'eval)
 241               (aggressive-indent--run-user-hooks))
 242     (ignore-errors
 243       (cl-letf (((symbol-function 'message) #'ignore))
 244         (indent-defun)))))
 245
 246 :autoload
 247 (defun indent-region-and-on (l r)
 248   "Indent region between L and R, and then some.
 249 Call `indent-region' between L and R, and then keep indenting
 250 until nothing more happens."
 251   (interactive "r")
 252   (let ((p (point-marker))
 253         was-begining-of-line)
 254     (set-marker-insertion-type p t)
 255     (goto-char r)
 256     (setq was-begining-of-line
 257           (= r (line-beginning-position)))
 258     ;; Indent the affected region.
 259     (unless (= l r) (indent-region l r))
 260     ;; `indent-region' doesn't do anything if R was the beginning of a line, so we indent manually there.
 261     (when was-begining-of-line
 262       (indent-according-to-mode))
 263     ;; And then we indent each following line until nothing happens.
 264     (forward-line 1)
 265     (while (/= (progn (skip-chars-forward "[:blank:]")
 266                       (point))
 267                (progn (indent-according-to-mode)
 268                       (point)))
 269       (forward-line 1))
 270     (goto-char p)))
 271
 272 (defun -softly-indent-region-and-on (l r &rest _)
 273   "Indent current defun unobstrusively.
 274 Like `aggressive-indent-indent-region-and-on', but wrapped in a
 275 `aggressive-indent--do-softly'."
 276   (unless (or (run-hook-wrapped
 277                'aggressive-indent--internal-dont-indent-if
 278                #'eval)
 279               (aggressive-indent--run-user-hooks))
 280     (ignore-errors
 281       (cl-letf (((symbol-function 'message) #'ignore))
 282         (indent-region-and-on l r)))))
 283
 284 (defvar changed-list-right nil
 285   "List of right limit of regions changed in the last command loop.")
 286
 287 (defvar changed-list-left nil
 288   "List of left limit of regions changed in the last command loop.")
 289
 290 (defun -indent-if-changed ()
 291   "Indent any region that changed in the last command loop."
 292   (let ((inhibit-modification-hooks t))
 293     (when changed-list-left
 294       (-softly-indent-region-and-on
 295        (apply #'min changed-list-left)
 296        (apply #'max changed-list-right))
 297       (setq changed-list-left nil
 298             changed-list-right nil))))
 299
 300 (defun -keep-track-of-changes (l r &rest _)
 301   "Store the limits of each change that happens in the buffer."
 302   (push l changed-list-left)
 303   (push r changed-list-right))
 304
 305 \f
 306 ;;; Minor modes
 307 :autoload
 308 (define-minor-mode mode nil nil " =>"
 309   '(("\C-c\C-q" . aggressive-indent-indent-defun))
 310   (if mode
 311       (if (and global-aggressive-indent-mode
 312                (or (cl-member-if #'derived-mode-p excluded-modes)
 313                    buffer-read-only))
 314           (mode -1)
 315         (when (fboundp 'electric-indent-local-mode)
 316           (electric-indent-local-mode 1))
 317         (if (cl-member-if #'derived-mode-p modes-to-prefer-defun)
 318             (add-hook 'post-command-hook #'-softly-indent-defun nil 'local)
 319           (add-hook 'after-change-functions #'-keep-track-of-changes nil 'local)
 320           (add-hook 'post-command-hook #'-indent-if-changed nil 'local)))
 321     ;; Clean the hooks
 322     (remove-hook 'after-change-functions #'-keep-track-of-changes 'local)
 323     (remove-hook 'post-command-hook #'-indent-if-changed 'local)
 324     (remove-hook 'post-command-hook #'-softly-indent-defun 'local)))
 325
 326 :autoload
 327 (define-globalized-minor-mode global-aggressive-indent-mode
 328   mode mode)
 329
 330 :autoload
 331 (defalias 'aggressive-indent-global-mode
 332   #'global-aggressive-indent-mode)
 333 )
 334
 335 (provide 'aggressive-indent)
 336 ;;; aggressive-indent.el ends here.