code.delx.au - gnu-emacs-elpa/blob - beacon.el

   1 ;;; beacon.el --- Highlight the cursor whenever it moves long distances  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015  Artur Malabarba
   4
   5 ;; Author: Artur Malabarba <emacs@endlessparentheses.com>
   6 ;; URL: https://github.com/Malabarba/beacon
   7 ;; Keywords: convenience
   8 ;; Version: 0.1
   9 ;; Package-Requires: ((cl-lib "0.5"))
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a global minor-mode.  Turn it on everywhere with
  27 ;;     (beacon-mode 1)
  28
  29 ;;; Code:
  30
  31 (require 'cl-lib)
  32
  33 (defgroup beacon nil
  34   "Customization group for beacon."
  35   :group 'emacs
  36   :prefix "beacon-")
  37
  38 (defvar beacon--timer nil)
  39
  40 (defcustom beacon-push-mark nil
  41   "Should the mark be pushed before long movements?
  42 If nil, `beacon' will not push the mark.
  43 Otherwise this should be a number, and `beacon' will push the
  44 mark whenever point moves more than that many lines."
  45   :type '(choice integer (const nil)))
  46
  47 (defcustom beacon-blink-when-point-moves nil
  48   "Should the beacon blink when moving a long distance?
  49 If nil, don't blink due to plain movement.
  50 If non-nil, this should be an integer, which is the minimum
  51 movement distance (in lines) that triggers a beacon blink."
  52   :type '(choice integer (const nil)))
  53
  54 (defcustom beacon-blink-when-buffer-changes t
  55   "Should the beacon blink when changing buffer?"
  56   :type 'boolean)
  57
  58 (defcustom beacon-blink-when-window-scrolls t
  59   "Should the beacon blink when the window scrolls?"
  60   :type 'boolean)
  61
  62 (defcustom beacon-blink-duration 0.3
  63   "Time, in seconds, that the blink should last."
  64   :type 'number)
  65
  66 (defcustom beacon-blink-delay 0.3
  67   "Time, in seconds, before starting to fade the beacon."
  68   :type 'number)
  69
  70 (defcustom beacon-size 40
  71   "Size of the beacon in characters."
  72   :type 'number)
  73
  74 (defcustom beacon-color 0.5
  75   "Color of the beacon.
  76 This can be a string or a number.
  77
  78 If it is a number, the color is taken to be white or
  79 black (depending on the current theme's background) and this
  80 number is a float between 0 and 1 specifing the brightness.
  81
  82 If it is a string, it is a color name or specification,
  83 e.g. \"#666600\"."
  84   :type '(choice number color))
  85
  86 \f
  87 ;;; Overlays
  88 (defvar beacon--ovs nil)
  89
  90 (defun beacon--colored-overlay (color)
  91   "Put an overlay at point with background COLOR."
  92   (let ((ov (make-overlay (point) (1+ (point)))))
  93     (overlay-put ov 'face (list :background color))
  94     (overlay-put ov 'beacon t)
  95     (push ov beacon--ovs)))
  96
  97 (defun beacon--ov-at-point ()
  98   (car (cl-member-if (lambda (o) (overlay-get o 'beacon))
  99                      (overlays-at (point)))))
 100
 101 (defun beacon--vanish ()
 102   "Turn off the beacon."
 103   (when (timerp beacon--timer)
 104     (cancel-timer beacon--timer))
 105   (mapc #'delete-overlay beacon--ovs)
 106   (setq beacon--ovs nil))
 107
 108 \f
 109 ;;; Colors
 110 (defun beacon--int-range (a b)
 111   "Return a list of integers between A inclusive and B exclusive.
 112 Only returns `beacon-size' elements."
 113   (let ((d (/ (- b a) beacon-size))
 114         (out (list a)))
 115     (dotimes (_ (1- beacon-size))
 116       (push (+ (car out) d) out))
 117     (nreverse out)))
 118
 119 (defun beacon--color-range ()
 120   "Return a list of background colors for the beacon."
 121   (let* ((bg (color-values (face-attribute 'default :background)))
 122          (fg (cond
 123               ((stringp beacon-color) (color-values beacon-color))
 124               ((< (color-distance "black" bg)
 125                   (color-distance "white" bg))
 126                (make-list 3 (* beacon-color 65535)))
 127               (t (make-list 3 (* (- 1 beacon-color) 65535))))))
 128     (apply #'cl-mapcar (lambda (r g b) (format "#%04x%04x%04x" r g b))
 129            (mapcar (lambda (n) (butlast (beacon--int-range (elt fg n) (elt bg n))))
 130                    [0 1 2]))))
 131
 132 \f
 133 ;;; Blinking
 134 (defun beacon--shine ()
 135   "Shine a beacon at point."
 136   (let ((colors (beacon--color-range)))
 137     (save-excursion
 138       (while colors
 139         (if (looking-at "$")
 140             (progn
 141               ;; (beacon--after-string)
 142               (setq colors nil))
 143           (beacon--colored-overlay (pop colors))
 144           (forward-char 1))))))
 145
 146 (defun beacon--dec ()
 147   "Decrease the beacon brightness by one."
 148   (let ((o (beacon--ov-at-point)))
 149     (if (not o)
 150         (beacon--vanish)
 151       (delete-overlay o)
 152       (save-excursion
 153         (while (progn (forward-char 1)
 154                       (setq o (beacon--ov-at-point)))
 155           (move-overlay o (1- (point)) (point)))))))
 156
 157 (defun beacon-blink ()
 158   "Blink the beacon at the position of the cursor."
 159   (interactive)
 160   (beacon--vanish)
 161   (beacon--shine)
 162   (setq beacon--timer
 163         (run-at-time beacon-blink-delay
 164                      (/ beacon-blink-duration 1.0 beacon-size)
 165                      #'beacon--dec)))
 166
 167 \f
 168 ;;; Movement detection
 169 (defvar beacon--previous-place nil)
 170 (defvar beacon--previous-window-start nil)
 171 (defvar beacon--previous-mark-head nil)
 172
 173 (defun beacon--movement-> (delta)
 174   "Return non-nil if latest point movement is > DELTA.
 175 If DELTA is nil, return nil."
 176   (and delta
 177        (equal (marker-buffer beacon--previous-place)
 178               (current-buffer))
 179        (> (abs (- (point) beacon--previous-place))
 180           delta)
 181        (> (count-screen-lines (min (point) beacon--previous-place)
 182                               (max (point) beacon--previous-place))
 183           delta)))
 184
 185 (defun beacon--maybe-push-mark ()
 186   "Push mark if it seems to be safe."
 187   (when (and (not mark-active)
 188              (beacon--movement-> beacon-push-mark))
 189     (let ((head (car mark-ring)))
 190       (when (and (eq beacon--previous-mark-head head)
 191                  (not (equal head beacon--previous-place)))
 192         (push-mark beacon--previous-place)))))
 193
 194 (defun beacon--post-command ()
 195   "Blink if point moved very far."
 196   (cond
 197    ((not (markerp beacon--previous-place))
 198     (beacon--vanish))
 199    ;; Blink because we changed buffer.
 200    ((not (equal (marker-buffer beacon--previous-place)
 201                 (current-buffer)))
 202     (when beacon-blink-when-buffer-changes
 203       (unless (window-minibuffer-p)
 204         (beacon-blink))))
 205    ;; Blink for scrolling.
 206    ((and beacon-blink-when-window-scrolls
 207          (progn (redisplay)
 208                 (not (equal beacon--previous-window-start (window-start)))))
 209     (beacon-blink))
 210    ;; Blink for movement
 211    ((beacon--movement-> beacon-blink-when-point-moves)
 212     (beacon-blink))
 213    ;; Even if we don't blink, vanish any previous beacon.
 214    (t (beacon--vanish)))
 215   (beacon--maybe-push-mark)
 216   (unless (window-minibuffer-p)
 217     (setq beacon--previous-window-start (window-start))
 218     (setq beacon--previous-mark-head (car mark-ring))
 219     (setq beacon--previous-place (point-marker))))
 220
 221 \f
 222 ;;; Minor-mode
 223 (defcustom beacon-lighter (cond
 224                      ((char-displayable-p ?💡) "💡")
 225                      ((char-displayable-p ?Λ) "Λ")
 226                      (t "*"))
 227   "Lighter string used on the mode-line."
 228   :type 'string)
 229
 230 ;;;###autoload
 231 (define-minor-mode beacon-mode
 232   nil nil beacon-lighter nil
 233   :global t
 234   (if beacon-mode
 235       (add-hook 'post-command-hook #'beacon--post-command)
 236     (remove-hook 'post-command-hook #'beacon--post-command)))
 237
 238 (provide 'beacon)
 239 ;;; beacon.el ends here