code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular text completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2016  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; URL: http://company-mode.github.io/
   8 ;; Version: 0.9.0-cvs
   9 ;; Keywords: abbrev, convenience, matching
  10 ;; Package-Requires: ((emacs "24.1") (cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion framework.  Modules for retrieving completion
  30 ;; candidates are called backends, modules for displaying them are frontends.
  31 ;;
  32 ;; Company comes with many backends, e.g. `company-etags'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Enable `company-mode' in all buffers with M-x global-company-mode.  For
  36 ;; further information look at the documentation for `company-mode' (C-h f
  37 ;; company-mode RET).
  38 ;;
  39 ;; If you want to start a specific backend, call it interactively or use
  40 ;; `company-begin-backend'.  For example:
  41 ;; M-x company-abbrev will prompt for and insert an abbrev.
  42 ;;
  43 ;; To write your own backend, look at the documentation for `company-backends'.
  44 ;; Here is a simple example completing "foo":
  45 ;;
  46 ;; (defun company-my-backend (command &optional arg &rest ignored)
  47 ;;   (pcase command
  48 ;;     (`prefix (company-grab-symbol))
  49 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  50 ;;     (`meta (format "This value is named %s" arg))))
  51 ;;
  52 ;; Sometimes it is a good idea to mix several backends together, for example to
  53 ;; enrich gtags with dabbrev-code results (to emulate local variables).  To do
  54 ;; this, add a list with both backends as an element in `company-backends'.
  55 ;;
  56 ;;; Change Log:
  57 ;;
  58 ;; See NEWS.md in the repository.
  59
  60 ;;; Code:
  61
  62 (require 'cl-lib)
  63 (require 'newcomment)
  64 (require 'pcase)
  65
  66 ;; FIXME: Use `user-error'.
  67 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  68 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  69 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  70 (add-to-list 'debug-ignored-errors "^Company not ")
  71 (add-to-list 'debug-ignored-errors "^No candidate number ")
  72 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  73 (add-to-list 'debug-ignored-errors "^No other backend$")
  74
  75 ;;; Compatibility
  76 (eval-and-compile
  77   ;; `defvar-local' for Emacs 24.2 and below
  78   (unless (fboundp 'defvar-local)
  79     (defmacro defvar-local (var val &optional docstring)
  80       "Define VAR as a buffer-local variable with default value VAL.
  81 Like `defvar' but additionally marks the variable as being automatically
  82 buffer-local wherever it is set."
  83       (declare (debug defvar) (doc-string 3))
  84       `(progn
  85          (defvar ,var ,val ,docstring)
  86          (make-variable-buffer-local ',var)))))
  87
  88 (defgroup company nil
  89   "Extensible inline text completion mechanism"
  90   :group 'abbrev
  91   :group 'convenience
  92   :group 'matching)
  93
  94 (defface company-tooltip
  95   '((default :foreground "black")
  96     (((class color) (min-colors 88) (background light))
  97      (:background "cornsilk"))
  98     (((class color) (min-colors 88) (background dark))
  99      (:background "yellow")))
 100   "Face used for the tooltip.")
 101
 102 (defface company-tooltip-selection
 103   '((((class color) (min-colors 88) (background light))
 104      (:background "light blue"))
 105     (((class color) (min-colors 88) (background dark))
 106      (:background "orange1"))
 107     (t (:background "green")))
 108   "Face used for the selection in the tooltip.")
 109
 110 (defface company-tooltip-search
 111   '((default :inherit company-tooltip-selection))
 112   "Face used for the search string in the tooltip.")
 113
 114 (defface company-tooltip-mouse
 115   '((default :inherit highlight))
 116   "Face used for the tooltip item under the mouse.")
 117
 118 (defface company-tooltip-common
 119   '((((background light))
 120      :foreground "darkred")
 121     (((background dark))
 122      :foreground "red"))
 123   "Face used for the common completion in the tooltip.")
 124
 125 (defface company-tooltip-common-selection
 126   '((default :inherit company-tooltip-common))
 127   "Face used for the selected common completion in the tooltip.")
 128
 129 (defface company-tooltip-annotation
 130   '((((background light))
 131      :foreground "firebrick4")
 132     (((background dark))
 133      :foreground "red4"))
 134   "Face used for the completion annotation in the tooltip.")
 135
 136 (defface company-tooltip-annotation-selection
 137   '((default :inherit company-tooltip-annotation))
 138   "Face used for the selected completion annotation in the tooltip.")
 139
 140 (defface company-scrollbar-fg
 141   '((((background light))
 142      :background "darkred")
 143     (((background dark))
 144      :background "red"))
 145   "Face used for the tooltip scrollbar thumb.")
 146
 147 (defface company-scrollbar-bg
 148   '((((background light))
 149      :background "wheat")
 150     (((background dark))
 151      :background "gold"))
 152   "Face used for the tooltip scrollbar background.")
 153
 154 (defface company-preview
 155   '((((background light))
 156      :inherit (company-tooltip-selection company-tooltip))
 157     (((background dark))
 158      :background "blue4"
 159      :foreground "wheat"))
 160   "Face used for the completion preview.")
 161
 162 (defface company-preview-common
 163   '((((background light))
 164      :inherit company-tooltip-common-selection)
 165     (((background dark))
 166      :inherit company-preview
 167      :foreground "red"))
 168   "Face used for the common part of the completion preview.")
 169
 170 (defface company-preview-search
 171   '((((background light))
 172      :inherit company-tooltip-common-selection)
 173     (((background dark))
 174      :inherit company-preview
 175      :background "blue1"))
 176   "Face used for the search string in the completion preview.")
 177
 178 (defface company-echo nil
 179   "Face used for completions in the echo area.")
 180
 181 (defface company-echo-common
 182   '((((background dark)) (:foreground "firebrick1"))
 183     (((background light)) (:background "firebrick4")))
 184   "Face used for the common part of completions in the echo area.")
 185
 186 (defun company-frontends-set (variable value)
 187   ;; Uniquify.
 188   (let ((value (delete-dups (copy-sequence value))))
 189     (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 190          (memq 'company-pseudo-tooltip-frontend value)
 191          (error "Pseudo tooltip frontend cannot be used twice"))
 192     (and (memq 'company-preview-if-just-one-frontend value)
 193          (memq 'company-preview-frontend value)
 194          (error "Preview frontend cannot be used twice"))
 195     (and (memq 'company-echo value)
 196          (memq 'company-echo-metadata-frontend value)
 197          (error "Echo area cannot be used twice"))
 198     ;; Preview must come last.
 199     (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 200       (when (cdr (memq f value))
 201         (setq value (append (delq f value) (list f)))))
 202     (set variable value)))
 203
 204 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 205                                company-preview-if-just-one-frontend
 206                                company-echo-metadata-frontend)
 207   "The list of active frontends (visualizations).
 208 Each frontend is a function that takes one argument.  It is called with
 209 one of the following arguments:
 210
 211 `show': When the visualization should start.
 212
 213 `hide': When the visualization should end.
 214
 215 `update': When the data has been updated.
 216
 217 `pre-command': Before every command that is executed while the
 218 visualization is active.
 219
 220 `post-command': After every command that is executed while the
 221 visualization is active.
 222
 223 The visualized data is stored in `company-prefix', `company-candidates',
 224 `company-common', `company-selection', `company-point' and
 225 `company-search-string'."
 226   :set 'company-frontends-set
 227   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 228                          (const :tag "echo, strip common"
 229                                 company-echo-strip-common-frontend)
 230                          (const :tag "show echo meta-data in echo"
 231                                 company-echo-metadata-frontend)
 232                          (const :tag "pseudo tooltip"
 233                                 company-pseudo-tooltip-frontend)
 234                          (const :tag "pseudo tooltip, multiple only"
 235                                 company-pseudo-tooltip-unless-just-one-frontend)
 236                          (const :tag "preview" company-preview-frontend)
 237                          (const :tag "preview, unique only"
 238                                 company-preview-if-just-one-frontend)
 239                          (function :tag "custom function" nil))))
 240
 241 (defcustom company-tooltip-limit 10
 242   "The maximum number of candidates in the tooltip."
 243   :type 'integer)
 244
 245 (defcustom company-tooltip-minimum 6
 246   "The minimum height of the tooltip.
 247 If this many lines are not available, prefer to display the tooltip above."
 248   :type 'integer)
 249
 250 (defcustom company-tooltip-minimum-width 0
 251   "The minimum width of the tooltip's inner area.
 252 This doesn't include the margins and the scroll bar."
 253   :type 'integer
 254   :package-version '(company . "0.8.0"))
 255
 256 (defcustom company-tooltip-margin 1
 257   "Width of margin columns to show around the toolip."
 258   :type 'integer)
 259
 260 (defcustom company-tooltip-offset-display 'scrollbar
 261   "Method using which the tooltip displays scrolling position.
 262 `scrollbar' means draw a scrollbar to the right of the items.
 263 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 264   :type '(choice (const :tag "Scrollbar" scrollbar)
 265                  (const :tag "Two lines" lines)))
 266
 267 (defcustom company-tooltip-align-annotations nil
 268   "When non-nil, align annotations to the right tooltip border."
 269   :type 'boolean
 270   :package-version '(company . "0.7.1"))
 271
 272 (defcustom company-tooltip-flip-when-above nil
 273   "Whether to flip the tooltip when it's above the current line."
 274   :type 'boolean
 275   :package-version '(company . "0.8.1"))
 276
 277 (defvar company-safe-backends
 278   '((company-abbrev . "Abbrev")
 279     (company-bbdb . "BBDB")
 280     (company-capf . "completion-at-point-functions")
 281     (company-clang . "Clang")
 282     (company-cmake . "CMake")
 283     (company-css . "CSS")
 284     (company-dabbrev . "dabbrev for plain text")
 285     (company-dabbrev-code . "dabbrev for code")
 286     (company-eclim . "Eclim (an Eclipse interface)")
 287     (company-elisp . "Emacs Lisp")
 288     (company-etags . "etags")
 289     (company-files . "Files")
 290     (company-gtags . "GNU Global")
 291     (company-ispell . "Ispell")
 292     (company-keywords . "Programming language keywords")
 293     (company-nxml . "nxml")
 294     (company-oddmuse . "Oddmuse")
 295     (company-semantic . "Semantic")
 296     (company-tempo . "Tempo templates")
 297     (company-xcode . "Xcode")))
 298 (put 'company-safe-backends 'risky-local-variable t)
 299
 300 (defun company-safe-backends-p (backends)
 301   (and (consp backends)
 302        (not (cl-dolist (backend backends)
 303               (unless (if (consp backend)
 304                           (company-safe-backends-p backend)
 305                         (assq backend company-safe-backends))
 306                 (cl-return t))))))
 307
 308 (defcustom company-backends `(,@(unless (version< "24.3.51" emacs-version)
 309                                   (list 'company-elisp))
 310                               company-bbdb
 311                               company-nxml company-css
 312                               company-eclim company-semantic company-clang
 313                               company-xcode company-cmake
 314                               company-capf
 315                               company-files
 316                               (company-dabbrev-code company-gtags company-etags
 317                                company-keywords)
 318                               company-oddmuse company-dabbrev)
 319   "The list of active backends (completion engines).
 320
 321 Only one backend is used at a time.  The choice depends on the order of
 322 the items in this list, and on the values they return in response to the
 323 `prefix' command (see below).  But a backend can also be a \"grouped\"
 324 one (see below).
 325
 326 `company-begin-backend' can be used to start a specific backend,
 327 `company-other-backend' will skip to the next matching backend in the list.
 328
 329 Each backend is a function that takes a variable number of arguments.
 330 The first argument is the command requested from the backend.  It is one
 331 of the following:
 332
 333 `prefix': The backend should return the text to be completed.  It must be
 334 text immediately before point.  Returning nil from this command passes
 335 control to the next backend.  The function should return `stop' if it
 336 should complete but cannot (e.g. if it is in the middle of a string).
 337 Instead of a string, the backend may return a cons (PREFIX . LENGTH)
 338 where LENGTH is a number used in place of PREFIX's length when
 339 comparing against `company-minimum-prefix-length'.  LENGTH can also
 340 be just t, and in the latter case the test automatically succeeds.
 341
 342 `candidates': The second argument is the prefix to be completed.  The
 343 return value should be a list of candidates that match the prefix.
 344
 345 Non-prefix matches are also supported (candidates that don't start with the
 346 prefix, but match it in some backend-defined way).  Backends that use this
 347 feature must disable cache (return t to `no-cache') and might also want to
 348 respond to `match'.
 349
 350 Optional commands
 351 =================
 352
 353 `sorted': Return t here to indicate that the candidates are sorted and will
 354 not need to be sorted again.
 355
 356 `duplicates': If non-nil, company will take care of removing duplicates
 357 from the list.
 358
 359 `no-cache': Usually company doesn't ask for candidates again as completion
 360 progresses, unless the backend returns t for this command.  The second
 361 argument is the latest prefix.
 362
 363 `ignore-case': Return t here if the backend returns case-insensitive
 364 matches.  This value is used to determine the longest common prefix (as
 365 used in `company-complete-common'), and to filter completions when fetching
 366 them from cache.
 367
 368 `meta': The second argument is a completion candidate.  Return a (short)
 369 documentation string for it.
 370
 371 `doc-buffer': The second argument is a completion candidate.  Return a
 372 buffer with documentation for it.  Preferably use `company-doc-buffer'.  If
 373 not all buffer contents pertain to this candidate, return a cons of buffer
 374 and window start position.
 375
 376 `location': The second argument is a completion candidate.  Return a cons
 377 of buffer and buffer location, or of file and line number where the
 378 completion candidate was defined.
 379
 380 `annotation': The second argument is a completion candidate.  Return a
 381 string to be displayed inline with the candidate in the popup.  If
 382 duplicates are removed by company, candidates with equal string values will
 383 be kept if they have different annotations.  For that to work properly,
 384 backends should store the related information on candidates using text
 385 properties.
 386
 387 `match': The second argument is a completion candidate.  Return the index
 388 after the end of text matching `prefix' within the candidate string.  It
 389 will be used when rendering the popup.  This command only makes sense for
 390 backends that provide non-prefix completion.
 391
 392 `require-match': If this returns t, the user is not allowed to enter
 393 anything not offered as a candidate.  Please don't use that value in normal
 394 backends.  The default value nil gives the user that choice with
 395 `company-require-match'.  Return value `never' overrides that option the
 396 other way around.
 397
 398 `init': Called once for each buffer. The backend can check for external
 399 programs and files and load any required libraries.  Raising an error here
 400 will show up in message log once, and the backend will not be used for
 401 completion.
 402
 403 `post-completion': Called after a completion candidate has been inserted
 404 into the buffer.  The second argument is the candidate.  Can be used to
 405 modify it, e.g. to expand a snippet.
 406
 407 The backend should return nil for all commands it does not support or
 408 does not know about.  It should also be callable interactively and use
 409 `company-begin-backend' to start itself in that case.
 410
 411 Grouped backends
 412 ================
 413
 414 An element of `company-backends' can also be a list of backends.  The
 415 completions from backends in such groups are merged, but only from those
 416 backends which return the same `prefix'.
 417
 418 If a backend command takes a candidate as an argument (e.g. `meta'), the
 419 call is dispatched to the backend the candidate came from.  In other
 420 cases (except for `duplicates' and `sorted'), the first non-nil value among
 421 all the backends is returned.
 422
 423 The group can also contain keywords.  Currently, `:with' and `:sorted'
 424 keywords are defined.  If the group contains keyword `:with', the backends
 425 listed after this keyword are ignored for the purpose of the `prefix'
 426 command.  If the group contains keyword `:sorted', the final list of
 427 candidates is not sorted after concatenation.
 428
 429 Asynchronous backends
 430 =====================
 431
 432 The return value of each command can also be a cons (:async . FETCHER)
 433 where FETCHER is a function of one argument, CALLBACK.  When the data
 434 arrives, FETCHER must call CALLBACK and pass it the appropriate return
 435 value, as described above.  That call must happen in the same buffer as
 436 where completion was initiated.
 437
 438 True asynchronous operation is only supported for command `candidates', and
 439 only during idle completion.  Other commands will block the user interface,
 440 even if the backend uses the asynchronous calling convention."
 441   :type `(repeat
 442           (choice
 443            :tag "backend"
 444            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 445                      company-safe-backends)
 446            (symbol :tag "User defined")
 447            (repeat :tag "Merged backends"
 448                    (choice :tag "backend"
 449                            ,@(mapcar (lambda (b)
 450                                        `(const :tag ,(cdr b) ,(car b)))
 451                                      company-safe-backends)
 452                            (const :tag "With" :with)
 453                            (symbol :tag "User defined"))))))
 454
 455 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 456
 457 (defcustom company-transformers nil
 458   "Functions to change the list of candidates received from backends.
 459
 460 Each function gets called with the return value of the previous one.
 461 The first one gets passed the list of candidates, already sorted and
 462 without duplicates."
 463   :type '(choice
 464           (const :tag "None" nil)
 465           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 466           (const :tag "Sort by backend importance"
 467                  (company-sort-by-backend-importance))
 468           (repeat :tag "User defined" (function))))
 469
 470 (defcustom company-completion-started-hook nil
 471   "Hook run when company starts completing.
 472 The hook is called with one argument that is non-nil if the completion was
 473 started manually."
 474   :type 'hook)
 475
 476 (defcustom company-completion-cancelled-hook nil
 477   "Hook run when company cancels completing.
 478 The hook is called with one argument that is non-nil if the completion was
 479 aborted manually."
 480   :type 'hook)
 481
 482 (defcustom company-completion-finished-hook nil
 483   "Hook run when company successfully completes.
 484 The hook is called with the selected candidate as an argument.
 485
 486 If you indend to use it to post-process candidates from a specific
 487 backend, consider using the `post-completion' command instead."
 488   :type 'hook)
 489
 490 (defcustom company-minimum-prefix-length 3
 491   "The minimum prefix length for idle completion."
 492   :type '(integer :tag "prefix length"))
 493
 494 (defcustom company-abort-manual-when-too-short nil
 495   "If enabled, cancel a manually started completion when the prefix gets
 496 shorter than both `company-minimum-prefix-length' and the length of the
 497 prefix it was started from."
 498   :type 'boolean
 499   :package-version '(company . "0.8.0"))
 500
 501 (defcustom company-require-match 'company-explicit-action-p
 502   "If enabled, disallow non-matching input.
 503 This can be a function do determine if a match is required.
 504
 505 This can be overridden by the backend, if it returns t or `never' to
 506 `require-match'.  `company-auto-complete' also takes precedence over this."
 507   :type '(choice (const :tag "Off" nil)
 508                  (function :tag "Predicate function")
 509                  (const :tag "On, if user interaction took place"
 510                         'company-explicit-action-p)
 511                  (const :tag "On" t)))
 512
 513 (defcustom company-auto-complete nil
 514   "Determines when to auto-complete.
 515 If this is enabled, all characters from `company-auto-complete-chars'
 516 trigger insertion of the selected completion candidate.
 517 This can also be a function."
 518   :type '(choice (const :tag "Off" nil)
 519                  (function :tag "Predicate function")
 520                  (const :tag "On, if user interaction took place"
 521                         'company-explicit-action-p)
 522                  (const :tag "On" t)))
 523
 524 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 525   "Determines which characters trigger auto-completion.
 526 See `company-auto-complete'.  If this is a string, each string character
 527 tiggers auto-completion.  If it is a list of syntax description characters (see
 528 `modify-syntax-entry'), all characters with that syntax auto-complete.
 529
 530 This can also be a function, which is called with the new input and should
 531 return non-nil if company should auto-complete.
 532
 533 A character that is part of a valid candidate never triggers auto-completion."
 534   :type '(choice (string :tag "Characters")
 535                  (set :tag "Syntax"
 536                       (const :tag "Whitespace" ?\ )
 537                       (const :tag "Symbol" ?_)
 538                       (const :tag "Opening parentheses" ?\()
 539                       (const :tag "Closing parentheses" ?\))
 540                       (const :tag "Word constituent" ?w)
 541                       (const :tag "Punctuation." ?.)
 542                       (const :tag "String quote." ?\")
 543                       (const :tag "Paired delimiter." ?$)
 544                       (const :tag "Expression quote or prefix operator." ?\')
 545                       (const :tag "Comment starter." ?<)
 546                       (const :tag "Comment ender." ?>)
 547                       (const :tag "Character-quote." ?/)
 548                       (const :tag "Generic string fence." ?|)
 549                       (const :tag "Generic comment fence." ?!))
 550                  (function :tag "Predicate function")))
 551
 552 (defcustom company-idle-delay .5
 553   "The idle delay in seconds until completion starts automatically.
 554 The prefix still has to satisfy `company-minimum-prefix-length' before that
 555 happens.  The value of nil means no idle completion."
 556   :type '(choice (const :tag "never (nil)" nil)
 557                  (const :tag "immediate (0)" 0)
 558                  (number :tag "seconds")))
 559
 560 (defcustom company-begin-commands '(self-insert-command
 561                                     org-self-insert-command
 562                                     orgtbl-self-insert-command
 563                                     c-scope-operator
 564                                     c-electric-colon
 565                                     c-electric-lt-gt
 566                                     c-electric-slash)
 567   "A list of commands after which idle completion is allowed.
 568 If this is t, it can show completions after any command except a few from a
 569 pre-defined list.  See `company-idle-delay'.
 570
 571 Alternatively, any command with a non-nil `company-begin' property is
 572 treated as if it was on this list."
 573   :type '(choice (const :tag "Any command" t)
 574                  (const :tag "Self insert command" '(self-insert-command))
 575                  (repeat :tag "Commands" function))
 576   :package-version '(company . "0.8.4"))
 577
 578 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 579                                            save-buffers-kill-terminal
 580                                            save-buffers-kill-emacs)
 581   "A list of commands that are allowed during completion.
 582 If this is t, or if `company-begin-commands' is t, any command is allowed.
 583 Otherwise, the value must be a list of symbols.  If it starts with `not',
 584 the cdr is the list of commands that abort completion.  Otherwise, all
 585 commands except those in that list, or in `company-begin-commands', or
 586 commands in the `company-' namespace, abort completion."
 587   :type '(choice (const :tag "Any command" t)
 588                  (cons  :tag "Any except"
 589                         (const not)
 590                         (repeat :tag "Commands" function))
 591                  (repeat :tag "Commands" function)))
 592
 593 (defcustom company-show-numbers nil
 594   "If enabled, show quick-access numbers for the first ten candidates."
 595   :type '(choice (const :tag "off" nil)
 596                  (const :tag "on" t)))
 597
 598 (defcustom company-selection-wrap-around nil
 599   "If enabled, selecting item before first or after last wraps around."
 600   :type '(choice (const :tag "off" nil)
 601                  (const :tag "on" t)))
 602
 603 (defvar company-async-wait 0.03
 604   "Pause between checks to see if the value's been set when turning an
 605 asynchronous call into synchronous.")
 606
 607 (defvar company-async-timeout 2
 608   "Maximum wait time for a value to be set during asynchronous call.")
 609
 610 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 611
 612 (defvar company-mode-map (make-sparse-keymap)
 613   "Keymap used by `company-mode'.")
 614
 615 (defvar company-active-map
 616   (let ((keymap (make-sparse-keymap)))
 617     (define-key keymap "\e\e\e" 'company-abort)
 618     (define-key keymap "\C-g" 'company-abort)
 619     (define-key keymap (kbd "M-n") 'company-select-next)
 620     (define-key keymap (kbd "M-p") 'company-select-previous)
 621     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 622     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 623     (define-key keymap [remap scroll-up-command] 'company-next-page)
 624     (define-key keymap [remap scroll-down-command] 'company-previous-page)
 625     (define-key keymap [down-mouse-1] 'ignore)
 626     (define-key keymap [down-mouse-3] 'ignore)
 627     (define-key keymap [mouse-1] 'company-complete-mouse)
 628     (define-key keymap [mouse-3] 'company-select-mouse)
 629     (define-key keymap [up-mouse-1] 'ignore)
 630     (define-key keymap [up-mouse-3] 'ignore)
 631     (define-key keymap [return] 'company-complete-selection)
 632     (define-key keymap (kbd "RET") 'company-complete-selection)
 633     (define-key keymap [tab] 'company-complete-common)
 634     (define-key keymap (kbd "TAB") 'company-complete-common)
 635     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 636     (define-key keymap (kbd "C-h") 'company-show-doc-buffer)
 637     (define-key keymap "\C-w" 'company-show-location)
 638     (define-key keymap "\C-s" 'company-search-candidates)
 639     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 640     (dotimes (i 10)
 641       (define-key keymap (read-kbd-macro (format "M-%d" i)) 'company-complete-number))
 642      keymap)
 643   "Keymap that is enabled during an active completion.")
 644
 645 (defvar company--disabled-backends nil)
 646
 647 (defun company-init-backend (backend)
 648   (and (symbolp backend)
 649        (not (fboundp backend))
 650        (ignore-errors (require backend nil t)))
 651   (cond
 652    ((symbolp backend)
 653     (condition-case err
 654         (progn
 655           (funcall backend 'init)
 656           (put backend 'company-init t))
 657       (error
 658        (put backend 'company-init 'failed)
 659        (unless (memq backend company--disabled-backends)
 660          (message "Company backend '%s' could not be initialized:\n%s"
 661                   backend (error-message-string err)))
 662        (cl-pushnew backend company--disabled-backends)
 663        nil)))
 664    ;; No initialization for lambdas.
 665    ((functionp backend) t)
 666    (t ;; Must be a list.
 667     (cl-dolist (b backend)
 668       (unless (keywordp b)
 669         (company-init-backend b))))))
 670
 671 (defcustom company-lighter-base "company"
 672   "Base string to use for the `company-mode' lighter."
 673   :type 'string
 674   :package-version '(company . "0.8.10"))
 675
 676 (defvar company-lighter '(" "
 677                           (company-candidates
 678                            (:eval
 679                             (if (consp company-backend)
 680                                 (company--group-lighter (nth company-selection
 681                                                              company-candidates)
 682                                                         company-lighter-base)
 683                               (symbol-name company-backend)))
 684                            company-lighter-base))
 685   "Mode line lighter for Company.
 686
 687 The value of this variable is a mode line template as in
 688 `mode-line-format'.")
 689
 690 (put 'company-lighter 'risky-local-variable t)
 691
 692 ;;;###autoload
 693 (define-minor-mode company-mode
 694   "\"complete anything\"; is an in-buffer completion framework.
 695 Completion starts automatically, depending on the values
 696 `company-idle-delay' and `company-minimum-prefix-length'.
 697
 698 Completion can be controlled with the commands:
 699 `company-complete-common', `company-complete-selection', `company-complete',
 700 `company-select-next', `company-select-previous'.  If these commands are
 701 called before `company-idle-delay', completion will also start.
 702
 703 Completions can be searched with `company-search-candidates' or
 704 `company-filter-candidates'.  These can be used while completion is
 705 inactive, as well.
 706
 707 The completion data is retrieved using `company-backends' and displayed
 708 using `company-frontends'.  If you want to start a specific backend, call
 709 it interactively or use `company-begin-backend'.
 710
 711 By default, the completions list is sorted alphabetically, unless the
 712 backend chooses otherwise, or `company-transformers' changes it later.
 713
 714 regular keymap (`company-mode-map'):
 715
 716 \\{company-mode-map}
 717 keymap during active completions (`company-active-map'):
 718
 719 \\{company-active-map}"
 720   nil company-lighter company-mode-map
 721   (if company-mode
 722       (progn
 723         (when (eq company-idle-delay t)
 724           (setq company-idle-delay 0)
 725           (warn "Setting `company-idle-delay' to t is deprecated.  Set it to 0 instead."))
 726         (add-hook 'pre-command-hook 'company-pre-command nil t)
 727         (add-hook 'post-command-hook 'company-post-command nil t)
 728         (mapc 'company-init-backend company-backends))
 729     (remove-hook 'pre-command-hook 'company-pre-command t)
 730     (remove-hook 'post-command-hook 'company-post-command t)
 731     (company-cancel)
 732     (kill-local-variable 'company-point)))
 733
 734 (defcustom company-global-modes t
 735   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 736 If nil, means no modes.  If t, then all major modes have it turned on.
 737 If a list, it should be a list of `major-mode' symbol names for which
 738 `company-mode' should be automatically turned on.  The sense of the list is
 739 negated if it begins with `not'.  For example:
 740  (c-mode c++-mode)
 741 means that `company-mode' is turned on for buffers in C and C++ modes only.
 742  (not message-mode)
 743 means that `company-mode' is always turned on except in `message-mode' buffers."
 744   :type '(choice (const :tag "none" nil)
 745                  (const :tag "all" t)
 746                  (set :menu-tag "mode specific" :tag "modes"
 747                       :value (not)
 748                       (const :tag "Except" not)
 749                       (repeat :inline t (symbol :tag "mode")))))
 750
 751 ;;;###autoload
 752 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 753
 754 (defun company-mode-on ()
 755   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 756              (cond ((eq company-global-modes t)
 757                     t)
 758                    ((eq (car-safe company-global-modes) 'not)
 759                     (not (memq major-mode (cdr company-global-modes))))
 760                    (t (memq major-mode company-global-modes))))
 761     (company-mode 1)))
 762
 763 (defsubst company-assert-enabled ()
 764   (unless company-mode
 765     (company-uninstall-map)
 766     (error "Company not enabled")))
 767
 768 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 769
 770 (defvar-local company-my-keymap nil)
 771
 772 (defvar company-emulation-alist '((t . nil)))
 773
 774 (defsubst company-enable-overriding-keymap (keymap)
 775   (company-uninstall-map)
 776   (setq company-my-keymap keymap))
 777
 778 (defun company-ensure-emulation-alist ()
 779   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 780     (setq emulation-mode-map-alists
 781           (cons 'company-emulation-alist
 782                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 783
 784 (defun company-install-map ()
 785   (unless (or (cdar company-emulation-alist)
 786               (null company-my-keymap))
 787     (setf (cdar company-emulation-alist) company-my-keymap)))
 788
 789 (defun company-uninstall-map ()
 790   (setf (cdar company-emulation-alist) nil))
 791
 792 ;; Hack:
 793 ;; Emacs calculates the active keymaps before reading the event.  That means we
 794 ;; cannot change the keymap from a timer.  So we send a bogus command.
 795 ;; XXX: Even in Emacs 24.4, seems to be needed in the terminal.
 796 (defun company-ignore ()
 797   (interactive)
 798   (setq this-command last-command))
 799
 800 (global-set-key '[company-dummy-event] 'company-ignore)
 801
 802 (defun company-input-noop ()
 803   (push 'company-dummy-event unread-command-events))
 804
 805 (defun company--posn-col-row (posn)
 806   (let ((col (car (posn-col-row posn)))
 807         ;; `posn-col-row' doesn't work well with lines of different height.
 808         ;; `posn-actual-col-row' doesn't handle multiple-width characters.
 809         (row (cdr (or (posn-actual-col-row posn)
 810                       ;; When position is non-visible for some reason.
 811                       (posn-col-row posn)))))
 812     (when (and header-line-format (version< emacs-version "24.3.93.3"))
 813       ;; http://debbugs.gnu.org/18384
 814       (cl-decf row))
 815     (cons (+ col (window-hscroll)) row)))
 816
 817 (defun company--col-row (&optional pos)
 818   (company--posn-col-row (posn-at-point pos)))
 819
 820 (defun company--row (&optional pos)
 821   (cdr (company--col-row pos)))
 822
 823 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 824
 825 (defvar-local company-backend nil)
 826
 827 (defun company-grab (regexp &optional expression limit)
 828   (when (looking-back regexp limit)
 829     (or (match-string-no-properties (or expression 0)) "")))
 830
 831 (defun company-grab-line (regexp &optional expression)
 832   "Return a match string for REGEXP if it matches text before point.
 833 If EXPRESSION is non-nil, return the match string for the respective
 834 parenthesized expression in REGEXP.
 835 Matching is limited to the current line."
 836   (let ((inhibit-field-text-motion t))
 837     (company-grab regexp expression (point-at-bol))))
 838
 839 (defun company-grab-symbol ()
 840   "If point is at the end of a symbol, return it.
 841 Otherwise, if point is not inside a symbol, return an empty string."
 842   (if (looking-at "\\_>")
 843       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 844                                                 (point)))
 845     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 846       "")))
 847
 848 (defun company-grab-word ()
 849   "If point is at the end of a word, return it.
 850 Otherwise, if point is not inside a symbol, return an empty string."
 851   (if (looking-at "\\>")
 852       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 853                                                 (point)))
 854     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 855       "")))
 856
 857 (defun company-grab-symbol-cons (idle-begin-after-re &optional max-len)
 858   "Return a string SYMBOL or a cons (SYMBOL . t).
 859 SYMBOL is as returned by `company-grab-symbol'.  If the text before point
 860 matches IDLE-BEGIN-AFTER-RE, return it wrapped in a cons."
 861   (let ((symbol (company-grab-symbol)))
 862     (when symbol
 863       (save-excursion
 864         (forward-char (- (length symbol)))
 865         (if (looking-back idle-begin-after-re (if max-len
 866                                                   (- (point) max-len)
 867                                                 (line-beginning-position)))
 868             (cons symbol t)
 869           symbol)))))
 870
 871 (defun company-in-string-or-comment ()
 872   "Return non-nil if point is within a string or comment."
 873   (let ((ppss (syntax-ppss)))
 874     (or (car (setq ppss (nthcdr 3 ppss)))
 875         (car (setq ppss (cdr ppss)))
 876         (nth 3 ppss))))
 877
 878 (defun company-call-backend (&rest args)
 879   (company--force-sync #'company-call-backend-raw args company-backend))
 880
 881 (defun company--force-sync (fun args backend)
 882   (let ((value (apply fun args)))
 883     (if (not (eq (car-safe value) :async))
 884         value
 885       (let ((res 'trash)
 886             (start (time-to-seconds)))
 887         (funcall (cdr value)
 888                  (lambda (result) (setq res result)))
 889         (while (eq res 'trash)
 890           (if (> (- (time-to-seconds) start) company-async-timeout)
 891               (error "Company: backend %s async timeout with args %s"
 892                      backend args)
 893             (sleep-for company-async-wait)))
 894         res))))
 895
 896 (defun company-call-backend-raw (&rest args)
 897   (condition-case-unless-debug err
 898       (if (functionp company-backend)
 899           (apply company-backend args)
 900         (apply #'company--multi-backend-adapter company-backend args))
 901     (error (error "Company: backend %s error \"%s\" with args %s"
 902                   company-backend (error-message-string err) args))))
 903
 904 (defun company--multi-backend-adapter (backends command &rest args)
 905   (let ((backends (cl-loop for b in backends
 906                            when (not (and (symbolp b)
 907                                           (eq 'failed (get b 'company-init))))
 908                            collect b)))
 909
 910     (when (eq command 'prefix)
 911       (setq backends (butlast backends (length (member :with backends)))))
 912
 913     (unless (memq command '(sorted))
 914       (setq backends (cl-delete-if #'keywordp backends)))
 915
 916     (pcase command
 917       (`candidates
 918        (company--multi-backend-adapter-candidates backends (car args)))
 919       (`sorted (memq :sorted backends))
 920       (`duplicates t)
 921       ((or `prefix `ignore-case `no-cache `require-match)
 922        (let (value)
 923          (cl-dolist (backend backends)
 924            (when (setq value (company--force-sync
 925                               backend (cons command args) backend))
 926              (cl-return value)))))
 927       (_
 928        (let ((arg (car args)))
 929          (when (> (length arg) 0)
 930            (let ((backend (or (get-text-property 0 'company-backend arg)
 931                               (car backends))))
 932              (apply backend command args))))))))
 933
 934 (defun company--multi-backend-adapter-candidates (backends prefix)
 935   (let ((pairs (cl-loop for backend in (cdr backends)
 936                         when (equal (company--prefix-str
 937                                      (funcall backend 'prefix))
 938                                     prefix)
 939                         collect (cons (funcall backend 'candidates prefix)
 940                                       (let ((b backend))
 941                                         (lambda (candidates)
 942                                           (mapcar
 943                                            (lambda (str)
 944                                              (propertize str 'company-backend b))
 945                                            candidates)))))))
 946     (when (equal (company--prefix-str (funcall (car backends) 'prefix)) prefix)
 947       ;; Small perf optimization: don't tag the candidates received
 948       ;; from the first backend in the group.
 949       (push (cons (funcall (car backends) 'candidates prefix)
 950                   'identity)
 951             pairs))
 952     (company--merge-async pairs (lambda (values) (apply #'append values)))))
 953
 954 (defun company--merge-async (pairs merger)
 955   (let ((async (cl-loop for pair in pairs
 956                         thereis
 957                         (eq :async (car-safe (car pair))))))
 958     (if (not async)
 959         (funcall merger (cl-loop for (val . mapper) in pairs
 960                                  collect (funcall mapper val)))
 961       (cons
 962        :async
 963        (lambda (callback)
 964          (let* (lst
 965                 (pending (mapcar #'car pairs))
 966                 (finisher (lambda ()
 967                             (unless pending
 968                               (funcall callback
 969                                        (funcall merger
 970                                                 (nreverse lst)))))))
 971            (dolist (pair pairs)
 972              (push nil lst)
 973              (let* ((cell lst)
 974                     (val (car pair))
 975                     (mapper (cdr pair))
 976                     (this-finisher (lambda (res)
 977                                      (setq pending (delq val pending))
 978                                      (setcar cell (funcall mapper res))
 979                                      (funcall finisher))))
 980                (if (not (eq :async (car-safe val)))
 981                    (funcall this-finisher val)
 982                  (let ((fetcher (cdr val)))
 983                    (funcall fetcher this-finisher)))))))))))
 984
 985 (defun company--prefix-str (prefix)
 986   (or (car-safe prefix) prefix))
 987
 988 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 989
 990 (defvar-local company-prefix nil)
 991
 992 (defvar-local company-candidates nil)
 993
 994 (defvar-local company-candidates-length nil)
 995
 996 (defvar-local company-candidates-cache nil)
 997
 998 (defvar-local company-candidates-predicate nil)
 999
1000 (defvar-local company-common nil)
1001
1002 (defvar-local company-selection 0)
1003
1004 (defvar-local company-selection-changed nil)
1005
1006 (defvar-local company--manual-action nil
1007   "Non-nil, if manual completion took place.")
1008
1009 (defvar-local company--manual-prefix nil)
1010
1011 (defvar company--auto-completion nil
1012   "Non-nil when current candidate is being inserted automatically.
1013 Controlled by `company-auto-complete'.")
1014
1015 (defvar-local company--point-max nil)
1016
1017 (defvar-local company-point nil)
1018
1019 (defvar company-timer nil)
1020
1021 (defsubst company-strip-prefix (str)
1022   (substring str (length company-prefix)))
1023
1024 (defun company--insert-candidate (candidate)
1025   (when (> (length candidate) 0)
1026     (setq candidate (substring-no-properties candidate))
1027     ;; XXX: Return value we check here is subject to change.
1028     (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
1029         (insert (company-strip-prefix candidate))
1030       (unless (equal company-prefix candidate)
1031         (delete-region (- (point) (length company-prefix)) (point))
1032         (insert candidate)))))
1033
1034 (defmacro company-with-candidate-inserted (candidate &rest body)
1035   "Evaluate BODY with CANDIDATE temporarily inserted.
1036 This is a tool for backends that need candidates inserted before they
1037 can retrieve meta-data for them."
1038   (declare (indent 1))
1039   `(let ((inhibit-modification-hooks t)
1040          (inhibit-point-motion-hooks t)
1041          (modified-p (buffer-modified-p)))
1042      (company--insert-candidate ,candidate)
1043      (unwind-protect
1044          (progn ,@body)
1045        (delete-region company-point (point))
1046        (set-buffer-modified-p modified-p))))
1047
1048 (defun company-explicit-action-p ()
1049   "Return whether explicit completion action was taken by the user."
1050   (or company--manual-action
1051       company-selection-changed))
1052
1053 (defun company-reformat (candidate)
1054   ;; company-ispell needs this, because the results are always lower-case
1055   ;; It's mory efficient to fix it only when they are displayed.
1056   ;; FIXME: Adopt the current text's capitalization instead?
1057   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
1058       (concat company-prefix (substring candidate (length company-prefix)))
1059     candidate))
1060
1061 (defun company--should-complete ()
1062   (and (eq company-idle-delay 'now)
1063        (not (or buffer-read-only overriding-terminal-local-map
1064                 overriding-local-map))
1065        ;; Check if in the middle of entering a key combination.
1066        (or (equal (this-command-keys-vector) [])
1067            (not (keymapp (key-binding (this-command-keys-vector)))))
1068        (not (and transient-mark-mode mark-active))))
1069
1070 (defun company--should-continue ()
1071   (or (eq t company-begin-commands)
1072       (eq t company-continue-commands)
1073       (if (eq 'not (car company-continue-commands))
1074           (not (memq this-command (cdr company-continue-commands)))
1075         (or (memq this-command company-begin-commands)
1076             (memq this-command company-continue-commands)
1077             (and (symbolp this-command)
1078                  (string-match-p "\\`company-" (symbol-name this-command)))))))
1079
1080 (defun company-call-frontends (command)
1081   (dolist (frontend company-frontends)
1082     (condition-case-unless-debug err
1083         (funcall frontend command)
1084       (error (error "Company: frontend %s error \"%s\" on command %s"
1085                     frontend (error-message-string err) command)))))
1086
1087 (defun company-set-selection (selection &optional force-update)
1088   (setq selection
1089         (if company-selection-wrap-around
1090             (mod selection company-candidates-length)
1091           (max 0 (min (1- company-candidates-length) selection))))
1092   (when (or force-update (not (equal selection company-selection)))
1093     (setq company-selection selection
1094           company-selection-changed t)
1095     (company-call-frontends 'update)))
1096
1097 (defun company--group-lighter (candidate base)
1098   (let ((backend (or (get-text-property 0 'company-backend candidate)
1099                      (cl-some (lambda (x) (and (not (keywordp x)) x))
1100                               company-backend))))
1101     (when (and backend (symbolp backend))
1102       (let ((name (replace-regexp-in-string "company-\\|-company" ""
1103                                             (symbol-name backend))))
1104         (format "%s-<%s>" base name)))))
1105
1106 (defun company-update-candidates (candidates)
1107   (setq company-candidates-length (length candidates))
1108   (if company-selection-changed
1109       ;; Try to restore the selection
1110       (let ((selected (nth company-selection company-candidates)))
1111         (setq company-selection 0
1112               company-candidates candidates)
1113         (when selected
1114           (catch 'found
1115             (while candidates
1116               (let ((candidate (pop candidates)))
1117                 (when (and (string= candidate selected)
1118                            (equal (company-call-backend 'annotation candidate)
1119                                   (company-call-backend 'annotation selected)))
1120                   (throw 'found t)))
1121               (cl-incf company-selection))
1122             (setq company-selection 0
1123                   company-selection-changed nil))))
1124     (setq company-selection 0
1125           company-candidates candidates))
1126   ;; Calculate common.
1127   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
1128     ;; We want to support non-prefix completion, so filtering is the
1129     ;; responsibility of each respective backend, not ours.
1130     ;; On the other hand, we don't want to replace non-prefix input in
1131     ;; `company-complete-common', unless there's only one candidate.
1132     (setq company-common
1133           (if (cdr company-candidates)
1134               (let ((common (try-completion "" company-candidates)))
1135                 (when (string-prefix-p company-prefix common
1136                                        completion-ignore-case)
1137                   common))
1138             (car company-candidates)))))
1139
1140 (defun company-calculate-candidates (prefix)
1141   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
1142         (ignore-case (company-call-backend 'ignore-case)))
1143     (or candidates
1144         (when company-candidates-cache
1145           (let ((len (length prefix))
1146                 (completion-ignore-case ignore-case)
1147                 prev)
1148             (cl-dotimes (i (1+ len))
1149               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1150                                            company-candidates-cache)))
1151                 (setq candidates (all-completions prefix prev))
1152                 (cl-return t)))))
1153         (progn
1154           ;; No cache match, call the backend.
1155           (setq candidates (company--preprocess-candidates
1156                             (company--fetch-candidates prefix)))
1157           ;; Save in cache.
1158           (push (cons prefix candidates) company-candidates-cache)))
1159     ;; Only now apply the predicate and transformers.
1160     (setq candidates (company--postprocess-candidates candidates))
1161     (when candidates
1162       (if (or (cdr candidates)
1163               (not (eq t (compare-strings (car candidates) nil nil
1164                                           prefix nil nil ignore-case))))
1165           candidates
1166         ;; Already completed and unique; don't start.
1167         t))))
1168
1169 (defun company--fetch-candidates (prefix)
1170   (let* ((non-essential (not (company-explicit-action-p)))
1171          (c (if company--manual-action
1172                 (company-call-backend 'candidates prefix)
1173               (company-call-backend-raw 'candidates prefix)))
1174          res)
1175     (if (not (eq (car c) :async))
1176         c
1177       (let ((buf (current-buffer))
1178             (win (selected-window))
1179             (tick (buffer-chars-modified-tick))
1180             (pt (point))
1181             (backend company-backend))
1182         (funcall
1183          (cdr c)
1184          (lambda (candidates)
1185            (if (not (and candidates (eq res 'done)))
1186                ;; There's no completions to display,
1187                ;; or the fetcher called us back right away.
1188                (setq res candidates)
1189              (setq company-backend backend
1190                    company-candidates-cache
1191                    (list (cons prefix
1192                                (company--preprocess-candidates candidates))))
1193              (unwind-protect
1194                  (company-idle-begin buf win tick pt)
1195                (unless company-candidates
1196                  (setq company-backend nil
1197                        company-candidates-cache nil)))))))
1198       ;; FIXME: Relying on the fact that the callers
1199       ;; will interpret nil as "do nothing" is shaky.
1200       ;; A throw-catch would be one possible improvement.
1201       (or res
1202           (progn (setq res 'done) nil)))))
1203
1204 (defun company--preprocess-candidates (candidates)
1205   (unless (company-call-backend 'sorted)
1206     (setq candidates (sort candidates 'string<)))
1207   (when (company-call-backend 'duplicates)
1208     (company--strip-duplicates candidates))
1209   candidates)
1210
1211 (defun company--postprocess-candidates (candidates)
1212   (when (or company-candidates-predicate company-transformers)
1213     (setq candidates (copy-sequence candidates)))
1214   (when company-candidates-predicate
1215     (setq candidates (cl-delete-if-not company-candidates-predicate candidates)))
1216   (company--transform-candidates candidates))
1217
1218 (defun company--strip-duplicates (candidates)
1219   (let ((c2 candidates)
1220         (annos 'unk))
1221     (while c2
1222       (setcdr c2
1223               (let ((str (pop c2)))
1224                 (while (let ((str2 (car c2)))
1225                          (if (not (equal str str2))
1226                              (progn
1227                                (setq annos 'unk)
1228                                nil)
1229                            (when (eq annos 'unk)
1230                              (setq annos (list (company-call-backend
1231                                                 'annotation str))))
1232                            (let ((anno2 (company-call-backend
1233                                          'annotation str2)))
1234                              (if (member anno2 annos)
1235                                  t
1236                                (push anno2 annos)
1237                                nil))))
1238                   (pop c2))
1239                 c2)))))
1240
1241 (defun company--transform-candidates (candidates)
1242   (let ((c candidates))
1243     (dolist (tr company-transformers)
1244       (setq c (funcall tr c)))
1245     c))
1246
1247 (defcustom company-occurrence-weight-function
1248   #'company-occurrence-prefer-closest-above
1249   "Function to weigh matches in `company-sort-by-occurrence'.
1250 It's called with three arguments: cursor position, the beginning and the
1251 end of the match."
1252   :type '(choice
1253           (const :tag "First above point, then below point"
1254                  company-occurrence-prefer-closest-above)
1255           (const :tag "Prefer closest in any direction"
1256                  company-occurrence-prefer-any-closest)))
1257
1258 (defun company-occurrence-prefer-closest-above (pos match-beg match-end)
1259   "Give priority to the matches above point, then those below point."
1260   (if (< match-beg pos)
1261       (- pos match-end)
1262     (- match-beg (window-start))))
1263
1264 (defun company-occurrence-prefer-any-closest (pos _match-beg match-end)
1265   "Give priority to the matches closest to the point."
1266   (abs (- pos match-end)))
1267
1268 (defun company-sort-by-occurrence (candidates)
1269   "Sort CANDIDATES according to their occurrences.
1270 Searches for each in the currently visible part of the current buffer and
1271 prioritizes the matches according to `company-occurrence-weight-function'.
1272 The rest of the list is appended unchanged.
1273 Keywords and function definition names are ignored."
1274   (let* ((w-start (window-start))
1275          (w-end (window-end))
1276          (start-point (point))
1277          occurs
1278          (noccurs
1279           (save-excursion
1280             (cl-delete-if
1281              (lambda (candidate)
1282                (when (catch 'done
1283                        (goto-char w-start)
1284                        (while (search-forward candidate w-end t)
1285                          (when (and (not (eq (point) start-point))
1286                                     (save-match-data
1287                                       (company--occurrence-predicate)))
1288                            (throw 'done t))))
1289                  (push
1290                   (cons candidate
1291                         (funcall company-occurrence-weight-function
1292                                  start-point
1293                                  (match-beginning 0)
1294                                  (match-end 0)))
1295                   occurs)
1296                  t))
1297              candidates))))
1298     (nconc
1299      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1300      noccurs)))
1301
1302 (defun company--occurrence-predicate ()
1303   (let ((beg (match-beginning 0))
1304         (end (match-end 0)))
1305     (save-excursion
1306       (goto-char end)
1307       (and (not (memq (get-text-property (1- (point)) 'face)
1308                       '(font-lock-function-name-face
1309                         font-lock-keyword-face)))
1310            (let ((prefix (company--prefix-str
1311                           (company-call-backend 'prefix))))
1312              (and (stringp prefix)
1313                   (= (length prefix) (- end beg))))))))
1314
1315 (defun company-sort-by-backend-importance (candidates)
1316   "Sort CANDIDATES as two priority groups.
1317 If `company-backend' is a function, do nothing.  If it's a list, move
1318 candidates from backends before keyword `:with' to the front.  Candidates
1319 from the rest of the backends in the group, if any, will be left at the end."
1320   (if (functionp company-backend)
1321       candidates
1322     (let ((low-priority (cdr (memq :with company-backend))))
1323       (if (null low-priority)
1324           candidates
1325         (sort candidates
1326               (lambda (c1 c2)
1327                 (and
1328                  (let ((b2 (get-text-property 0 'company-backend c2)))
1329                    (and b2 (memq b2 low-priority)))
1330                  (let ((b1 (get-text-property 0 'company-backend c1)))
1331                    (or (not b1) (not (memq b1 low-priority)))))))))))
1332
1333 (defun company-idle-begin (buf win tick pos)
1334   (and (eq buf (current-buffer))
1335        (eq win (selected-window))
1336        (eq tick (buffer-chars-modified-tick))
1337        (eq pos (point))
1338        (when (company-auto-begin)
1339          (company-input-noop)
1340          (let ((this-command 'company-idle-begin))
1341            (company-post-command)))))
1342
1343 (defun company-auto-begin ()
1344   (and company-mode
1345        (not company-candidates)
1346        (let ((company-idle-delay 'now))
1347          (condition-case-unless-debug err
1348              (progn
1349                (company--perform)
1350                ;; Return non-nil if active.
1351                company-candidates)
1352            (error (message "Company: An error occurred in auto-begin")
1353                   (message "%s" (error-message-string err))
1354                   (company-cancel))
1355            (quit (company-cancel))))))
1356
1357 ;;;###autoload
1358 (defun company-manual-begin ()
1359   (interactive)
1360   (company-assert-enabled)
1361   (setq company--manual-action t)
1362   (unwind-protect
1363       (let ((company-minimum-prefix-length 0))
1364         (or company-candidates
1365             (company-auto-begin)))
1366     (unless company-candidates
1367       (setq company--manual-action nil))))
1368
1369 (defun company-other-backend (&optional backward)
1370   (interactive (list current-prefix-arg))
1371   (company-assert-enabled)
1372   (let* ((after (if company-backend
1373                     (cdr (member company-backend company-backends))
1374                   company-backends))
1375          (before (cdr (member company-backend (reverse company-backends))))
1376          (next (if backward
1377                    (append before (reverse after))
1378                  (append after (reverse before)))))
1379     (company-cancel)
1380     (cl-dolist (backend next)
1381       (when (ignore-errors (company-begin-backend backend))
1382         (cl-return t))))
1383   (unless company-candidates
1384     (error "No other backend")))
1385
1386 (defun company-require-match-p ()
1387   (let ((backend-value (company-call-backend 'require-match)))
1388     (or (eq backend-value t)
1389         (and (not (eq backend-value 'never))
1390              (if (functionp company-require-match)
1391                  (funcall company-require-match)
1392                (eq company-require-match t))))))
1393
1394 (defun company-auto-complete-p (input)
1395   "Return non-nil, if input starts with punctuation or parentheses."
1396   (and (if (functionp company-auto-complete)
1397            (funcall company-auto-complete)
1398          company-auto-complete)
1399        (if (functionp company-auto-complete-chars)
1400            (funcall company-auto-complete-chars input)
1401          (if (consp company-auto-complete-chars)
1402              (memq (char-syntax (string-to-char input))
1403                    company-auto-complete-chars)
1404            (string-match (substring input 0 1) company-auto-complete-chars)))))
1405
1406 (defun company--incremental-p ()
1407   (and (> (point) company-point)
1408        (> (point-max) company--point-max)
1409        (not (eq this-command 'backward-delete-char-untabify))
1410        (equal (buffer-substring (- company-point (length company-prefix))
1411                                 company-point)
1412               company-prefix)))
1413
1414 (defun company--continue-failed (new-prefix)
1415   (let ((input (buffer-substring-no-properties (point) company-point)))
1416     (cond
1417      ((company-auto-complete-p input)
1418       ;; auto-complete
1419       (save-excursion
1420         (goto-char company-point)
1421         (let ((company--auto-completion t))
1422           (company-complete-selection))
1423         nil))
1424      ((and (or (not (company-require-match-p))
1425                ;; Don't require match if the new prefix
1426                ;; doesn't continue the old one, and the latter was a match.
1427                (not (stringp new-prefix))
1428                (<= (length new-prefix) (length company-prefix)))
1429            (member company-prefix company-candidates))
1430       ;; Last input was a success,
1431       ;; but we're treating it as an abort + input anyway,
1432       ;; like the `unique' case below.
1433       (company-cancel 'non-unique))
1434      ((company-require-match-p)
1435       ;; Wrong incremental input, but required match.
1436       (delete-char (- (length input)))
1437       (ding)
1438       (message "Matching input is required")
1439       company-candidates)
1440      (t (company-cancel)))))
1441
1442 (defun company--good-prefix-p (prefix)
1443   (and (stringp (company--prefix-str prefix)) ;excludes 'stop
1444        (or (eq (cdr-safe prefix) t)
1445            (let ((len (or (cdr-safe prefix) (length prefix))))
1446              (if company--manual-prefix
1447                  (or (not company-abort-manual-when-too-short)
1448                      ;; Must not be less than minimum or initial length.
1449                      (>= len (min company-minimum-prefix-length
1450                                   (length company--manual-prefix))))
1451                (>= len company-minimum-prefix-length))))))
1452
1453 (defun company--continue ()
1454   (when (company-call-backend 'no-cache company-prefix)
1455     ;; Don't complete existing candidates, fetch new ones.
1456     (setq company-candidates-cache nil))
1457   (let* ((new-prefix (company-call-backend 'prefix))
1458          (c (when (and (company--good-prefix-p new-prefix)
1459                        (setq new-prefix (company--prefix-str new-prefix))
1460                        (= (- (point) (length new-prefix))
1461                           (- company-point (length company-prefix))))
1462               (company-calculate-candidates new-prefix))))
1463     (cond
1464      ((eq c t)
1465       ;; t means complete/unique.
1466       ;; Handle it like completion was aborted, to differentiate from user
1467       ;; calling one of Company's commands to insert the candidate,
1468       ;; not to trigger template expansion, etc.
1469       (company-cancel 'unique))
1470      ((consp c)
1471       ;; incremental match
1472       (setq company-prefix new-prefix)
1473       (company-update-candidates c)
1474       c)
1475      ((not (company--incremental-p))
1476       (company-cancel))
1477      (t (company--continue-failed new-prefix)))))
1478
1479 (defun company--begin-new ()
1480   (let (prefix c)
1481     (cl-dolist (backend (if company-backend
1482                             ;; prefer manual override
1483                             (list company-backend)
1484                           company-backends))
1485       (setq prefix
1486             (if (or (symbolp backend)
1487                     (functionp backend))
1488                 (when (or (not (symbolp backend))
1489                           (eq t (get backend 'company-init))
1490                           (unless (get backend 'company-init)
1491                             (company-init-backend backend)))
1492                   (funcall backend 'prefix))
1493               (company--multi-backend-adapter backend 'prefix)))
1494       (when prefix
1495         (when (company--good-prefix-p prefix)
1496           (setq company-prefix (company--prefix-str prefix)
1497                 company-backend backend
1498                 c (company-calculate-candidates company-prefix))
1499           (if (not (consp c))
1500               (progn
1501                 (when company--manual-action
1502                   (message "No completion found"))
1503                 (when (eq c t)
1504                   ;; t means complete/unique.
1505                   ;; Run the hooks anyway, to e.g. clear the cache.
1506                   (company-cancel 'unique)))
1507             (when company--manual-action
1508               (setq company--manual-prefix prefix))
1509             (company-update-candidates c)
1510             (run-hook-with-args 'company-completion-started-hook
1511                                 (company-explicit-action-p))
1512             (company-call-frontends 'show)))
1513         (cl-return c)))))
1514
1515 (defun company--perform ()
1516   (or (and company-candidates (company--continue))
1517       (and (company--should-complete) (company--begin-new)))
1518   (if (not company-candidates)
1519       (setq company-backend nil)
1520     (setq company-point (point)
1521           company--point-max (point-max))
1522     (company-ensure-emulation-alist)
1523     (company-enable-overriding-keymap company-active-map)
1524     (company-call-frontends 'update)))
1525
1526 (defun company-cancel (&optional result)
1527   (let ((prefix company-prefix)
1528         (backend company-backend))
1529     (setq company-backend nil
1530           company-prefix nil
1531           company-candidates nil
1532           company-candidates-length nil
1533           company-candidates-cache nil
1534           company-candidates-predicate nil
1535           company-common nil
1536           company-selection 0
1537           company-selection-changed nil
1538           company--manual-action nil
1539           company--manual-prefix nil
1540           company--point-max nil
1541           company-point nil)
1542     (when company-timer
1543       (cancel-timer company-timer))
1544     (company-echo-cancel t)
1545     (company-search-mode 0)
1546     (company-call-frontends 'hide)
1547     (company-enable-overriding-keymap nil)
1548     (when prefix
1549       ;; FIXME: RESULT can also be e.g. `unique'.  We should call
1550       ;; `company-completion-finished-hook' in that case, with right argument.
1551       (if (stringp result)
1552           (let ((company-backend backend))
1553             (company-call-backend 'pre-completion result)
1554             (run-hook-with-args 'company-completion-finished-hook result)
1555             (company-call-backend 'post-completion result))
1556         (run-hook-with-args 'company-completion-cancelled-hook result))))
1557   ;; Make return value explicit.
1558   nil)
1559
1560 (defun company-abort ()
1561   (interactive)
1562   (company-cancel 'abort))
1563
1564 (defun company-finish (result)
1565   (company--insert-candidate result)
1566   (company-cancel result))
1567
1568 (defsubst company-keep (command)
1569   (and (symbolp command) (get command 'company-keep)))
1570
1571 (defun company-pre-command ()
1572   (company--electric-restore-window-configuration)
1573   (unless (company-keep this-command)
1574     (condition-case-unless-debug err
1575         (when company-candidates
1576           (company-call-frontends 'pre-command)
1577           (unless (company--should-continue)
1578             (company-abort)))
1579       (error (message "Company: An error occurred in pre-command")
1580              (message "%s" (error-message-string err))
1581              (company-cancel))))
1582   (when company-timer
1583     (cancel-timer company-timer)
1584     (setq company-timer nil))
1585   (company-echo-cancel t)
1586   (company-uninstall-map))
1587
1588 (defun company-post-command ()
1589   (when (and company-candidates
1590              (null this-command))
1591     ;; Happens when the user presses `C-g' while inside
1592     ;; `flyspell-post-command-hook', for example.
1593     ;; Or any other `post-command-hook' function that can call `sit-for',
1594     ;; or any quittable timer function.
1595     (company-abort)
1596     (setq this-command 'company-abort))
1597   (unless (company-keep this-command)
1598     (condition-case-unless-debug err
1599         (progn
1600           (unless (equal (point) company-point)
1601             (let (company-idle-delay) ; Against misbehavior while debugging.
1602               (company--perform)))
1603           (if company-candidates
1604               (company-call-frontends 'post-command)
1605             (and (numberp company-idle-delay)
1606                  (not defining-kbd-macro)
1607                  (company--should-begin)
1608                  (setq company-timer
1609                        (run-with-timer company-idle-delay nil
1610                                        'company-idle-begin
1611                                        (current-buffer) (selected-window)
1612                                        (buffer-chars-modified-tick) (point))))))
1613       (error (message "Company: An error occurred in post-command")
1614              (message "%s" (error-message-string err))
1615              (company-cancel))))
1616   (company-install-map))
1617
1618 (defvar company--begin-inhibit-commands '(company-abort
1619                                           company-complete-mouse
1620                                           company-complete
1621                                           company-complete-common
1622                                           company-complete-selection
1623                                           company-complete-number)
1624   "List of commands after which idle completion is (still) disabled when
1625 `company-begin-commands' is t.")
1626
1627 (defun company--should-begin ()
1628   (if (eq t company-begin-commands)
1629       (not (memq this-command company--begin-inhibit-commands))
1630     (or
1631      (memq this-command company-begin-commands)
1632      (and (symbolp this-command) (get this-command 'company-begin)))))
1633
1634 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1635
1636 (defcustom company-search-regexp-function #'regexp-quote
1637   "Function to construct the search regexp from input.
1638 It's called with one argument, the current search input.  It must return
1639 either a regexp without groups, or one where groups don't intersect and
1640 each one wraps a part of the input string."
1641   :type '(choice
1642           (const :tag "Exact match" regexp-quote)
1643           (const :tag "Words separated with spaces" company-search-words-regexp)
1644           (const :tag "Words separated with spaces, in any order"
1645                  company-search-words-in-any-order-regexp)
1646           (const :tag "All characters in given order, with anything in between"
1647                  company-search-flex-regexp)))
1648
1649 (defvar-local company-search-string "")
1650
1651 (defvar company-search-lighter '(" "
1652                                  (company-search-filtering "Filter" "Search")
1653                                  ": \""
1654                                  company-search-string
1655                                  "\""))
1656
1657 (defvar-local company-search-filtering nil
1658   "Non-nil to filter the completion candidates by the search string")
1659
1660 (defvar-local company--search-old-selection 0)
1661
1662 (defvar-local company--search-old-changed nil)
1663
1664 (defun company-search-words-regexp (input)
1665   (mapconcat (lambda (word) (format "\\(%s\\)" (regexp-quote word)))
1666              (split-string input " +" t) ".*"))
1667
1668 (defun company-search-words-in-any-order-regexp (input)
1669   (let* ((words (mapcar (lambda (word) (format "\\(%s\\)" (regexp-quote word)))
1670                         (split-string input " +" t)))
1671          (permutations (company--permutations words)))
1672     (mapconcat (lambda (words)
1673                  (mapconcat #'identity words ".*"))
1674                permutations
1675                "\\|")))
1676
1677 (defun company-search-flex-regexp (input)
1678   (if (zerop (length input))
1679       ""
1680     (concat (regexp-quote (string (aref input 0)))
1681             (mapconcat (lambda (c)
1682                          (concat "[^" (string c) "]*"
1683                                  (regexp-quote (string c))))
1684                        (substring input 1) ""))))
1685
1686 (defun company--permutations (lst)
1687   (if (not lst)
1688       '(nil)
1689     (cl-mapcan
1690      (lambda (e)
1691        (mapcar (lambda (perm) (cons e perm))
1692                (company--permutations (cl-remove e lst :count 1))))
1693      lst)))
1694
1695 (defun company--search (text lines)
1696   (let ((re (funcall company-search-regexp-function text))
1697         (i 0))
1698     (cl-dolist (line lines)
1699       (when (string-match-p re line (length company-prefix))
1700         (cl-return i))
1701       (cl-incf i))))
1702
1703 (defun company-search-keypad ()
1704   (interactive)
1705   (let* ((name (symbol-name last-command-event))
1706          (last-command-event (aref name (1- (length name)))))
1707     (company-search-printing-char)))
1708
1709 (defun company-search-printing-char ()
1710   (interactive)
1711   (company--search-assert-enabled)
1712   (let ((ss (concat company-search-string (string last-command-event))))
1713     (when company-search-filtering
1714       (company--search-update-predicate ss))
1715     (company--search-update-string ss)))
1716
1717 (defun company--search-update-predicate (ss)
1718   (let* ((re (funcall company-search-regexp-function ss))
1719          (company-candidates-predicate
1720           (and (not (string= re ""))
1721                company-search-filtering
1722                (lambda (candidate) (string-match re candidate))))
1723          (cc (company-calculate-candidates company-prefix)))
1724     (unless cc (error "No match"))
1725     (company-update-candidates cc)))
1726
1727 (defun company--search-update-string (new)
1728   (let* ((pos (company--search new (nthcdr company-selection company-candidates))))
1729     (if (null pos)
1730         (ding)
1731       (setq company-search-string new)
1732       (company-set-selection (+ company-selection pos) t))))
1733
1734 (defun company--search-assert-input ()
1735   (company--search-assert-enabled)
1736   (when (string= company-search-string "")
1737     (error "Empty search string")))
1738
1739 (defun company-search-repeat-forward ()
1740   "Repeat the incremental search in completion candidates forward."
1741   (interactive)
1742   (company--search-assert-input)
1743   (let ((pos (company--search company-search-string
1744                               (cdr (nthcdr company-selection
1745                                            company-candidates)))))
1746     (if (null pos)
1747         (ding)
1748       (company-set-selection (+ company-selection pos 1) t))))
1749
1750 (defun company-search-repeat-backward ()
1751   "Repeat the incremental search in completion candidates backwards."
1752   (interactive)
1753   (company--search-assert-input)
1754   (let ((pos (company--search company-search-string
1755                               (nthcdr (- company-candidates-length
1756                                          company-selection)
1757                                       (reverse company-candidates)))))
1758     (if (null pos)
1759         (ding)
1760       (company-set-selection (- company-selection pos 1) t))))
1761
1762 (defun company-search-toggle-filtering ()
1763   "Toggle `company-search-filtering'."
1764   (interactive)
1765   (company--search-assert-enabled)
1766   (setq company-search-filtering (not company-search-filtering))
1767   (let ((ss company-search-string))
1768     (company--search-update-predicate ss)
1769     (company--search-update-string ss)))
1770
1771 (defun company-search-abort ()
1772   "Abort searching the completion candidates."
1773   (interactive)
1774   (company--search-assert-enabled)
1775   (company-search-mode 0)
1776   (company-set-selection company--search-old-selection t)
1777   (setq company-selection-changed company--search-old-changed))
1778
1779 (defun company-search-other-char ()
1780   (interactive)
1781   (company--search-assert-enabled)
1782   (company-search-mode 0)
1783   (company--unread-last-input))
1784
1785 (defun company-search-delete-char ()
1786   (interactive)
1787   (company--search-assert-enabled)
1788   (if (string= company-search-string "")
1789       (ding)
1790     (let ((ss (substring company-search-string 0 -1)))
1791       (when company-search-filtering
1792         (company--search-update-predicate ss))
1793       (company--search-update-string ss))))
1794
1795 (defvar company-search-map
1796   (let ((i 0)
1797         (keymap (make-keymap)))
1798     (if (fboundp 'max-char)
1799         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1800                               'company-search-printing-char)
1801       (with-no-warnings
1802         ;; obsolete in Emacs 23
1803         (let ((l (generic-character-list))
1804               (table (nth 1 keymap)))
1805           (while l
1806             (set-char-table-default table (car l) 'company-search-printing-char)
1807             (setq l (cdr l))))))
1808     (define-key keymap [t] 'company-search-other-char)
1809     (while (< i ?\s)
1810       (define-key keymap (make-string 1 i) 'company-search-other-char)
1811       (cl-incf i))
1812     (while (< i 256)
1813       (define-key keymap (vector i) 'company-search-printing-char)
1814       (cl-incf i))
1815     (dotimes (i 10)
1816       (define-key keymap (read (format "[kp-%s]" i)) 'company-search-keypad))
1817     (let ((meta-map (make-sparse-keymap)))
1818       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1819       (define-key keymap [escape] meta-map))
1820     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1821     (define-key keymap (kbd "M-n") 'company-select-next)
1822     (define-key keymap (kbd "M-p") 'company-select-previous)
1823     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
1824     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
1825     (define-key keymap "\e\e\e" 'company-search-other-char)
1826     (define-key keymap [escape escape escape] 'company-search-other-char)
1827     (define-key keymap (kbd "DEL") 'company-search-delete-char)
1828     (define-key keymap [backspace] 'company-search-delete-char)
1829     (define-key keymap "\C-g" 'company-search-abort)
1830     (define-key keymap "\C-s" 'company-search-repeat-forward)
1831     (define-key keymap "\C-r" 'company-search-repeat-backward)
1832     (define-key keymap "\C-o" 'company-search-toggle-filtering)
1833     (dotimes (i 10)
1834       (define-key keymap (read-kbd-macro (format "M-%d" i)) 'company-complete-number))
1835     keymap)
1836   "Keymap used for incrementally searching the completion candidates.")
1837
1838 (define-minor-mode company-search-mode
1839   "Search mode for completion candidates.
1840 Don't start this directly, use `company-search-candidates' or
1841 `company-filter-candidates'."
1842   nil company-search-lighter nil
1843   (if company-search-mode
1844       (if (company-manual-begin)
1845           (progn
1846             (setq company--search-old-selection company-selection
1847                   company--search-old-changed company-selection-changed)
1848             (company-call-frontends 'update)
1849             (company-enable-overriding-keymap company-search-map))
1850         (setq company-search-mode nil))
1851     (kill-local-variable 'company-search-string)
1852     (kill-local-variable 'company-search-filtering)
1853     (kill-local-variable 'company--search-old-selection)
1854     (kill-local-variable 'company--search-old-changed)
1855     (when company-backend
1856       (company--search-update-predicate "")
1857       (company-call-frontends 'update))
1858     (company-enable-overriding-keymap company-active-map)))
1859
1860 (defun company--search-assert-enabled ()
1861   (company-assert-enabled)
1862   (unless company-search-mode
1863     (company-uninstall-map)
1864     (error "Company not in search mode")))
1865
1866 (defun company-search-candidates ()
1867   "Start searching the completion candidates incrementally.
1868
1869 \\<company-search-map>Search can be controlled with the commands:
1870 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1871 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1872 - `company-search-abort' (\\[company-search-abort])
1873 - `company-search-delete-char' (\\[company-search-delete-char])
1874
1875 Regular characters are appended to the search string.
1876
1877 Customize `company-search-regexp-function' to change how the input
1878 is interpreted when searching.
1879
1880 The command `company-search-toggle-filtering' (\\[company-search-toggle-filtering])
1881 uses the search string to filter the completion candidates."
1882   (interactive)
1883   (company-search-mode 1))
1884
1885 (defvar company-filter-map
1886   (let ((keymap (make-keymap)))
1887     (define-key keymap [remap company-search-printing-char]
1888       'company-filter-printing-char)
1889     (set-keymap-parent keymap company-search-map)
1890     keymap)
1891   "Keymap used for incrementally searching the completion candidates.")
1892
1893 (defun company-filter-candidates ()
1894   "Start filtering the completion candidates incrementally.
1895 This works the same way as `company-search-candidates' immediately
1896 followed by `company-search-toggle-filtering'."
1897   (interactive)
1898   (company-search-mode 1)
1899   (setq company-search-filtering t))
1900
1901 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1902
1903 (defun company-select-next (&optional arg)
1904   "Select the next candidate in the list.
1905
1906 With ARG, move by that many elements."
1907   (interactive "p")
1908   (when (company-manual-begin)
1909     (company-set-selection (+ (or arg 1) company-selection))))
1910
1911 (defun company-select-previous (&optional arg)
1912   "Select the previous candidate in the list.
1913
1914 With ARG, move by that many elements."
1915   (interactive "p")
1916   (company-select-next (if arg (- arg) -1)))
1917
1918 (defun company-select-next-or-abort (&optional arg)
1919   "Select the next candidate if more than one, else abort
1920 and invoke the normal binding.
1921
1922 With ARG, move by that many elements."
1923   (interactive "p")
1924   (if (> company-candidates-length 1)
1925       (company-select-next arg)
1926     (company-abort)
1927     (company--unread-last-input)))
1928
1929 (defun company-select-previous-or-abort (&optional arg)
1930   "Select the previous candidate if more than one, else abort
1931 and invoke the normal binding.
1932
1933 With ARG, move by that many elements."
1934   (interactive "p")
1935   (if (> company-candidates-length 1)
1936       (company-select-previous arg)
1937     (company-abort)
1938     (company--unread-last-input)))
1939
1940 (defun company-next-page ()
1941   "Select the candidate one page further."
1942   (interactive)
1943   (when (company-manual-begin)
1944     (company-set-selection (+ company-selection
1945                               company-tooltip-limit))))
1946
1947 (defun company-previous-page ()
1948   "Select the candidate one page earlier."
1949   (interactive)
1950   (when (company-manual-begin)
1951     (company-set-selection (- company-selection
1952                               company-tooltip-limit))))
1953
1954 (defvar company-pseudo-tooltip-overlay)
1955
1956 (defvar company-tooltip-offset)
1957
1958 (defun company--inside-tooltip-p (event-col-row row height)
1959   (let* ((ovl company-pseudo-tooltip-overlay)
1960          (column (overlay-get ovl 'company-column))
1961          (width (overlay-get ovl 'company-width))
1962          (evt-col (car event-col-row))
1963          (evt-row (cdr event-col-row)))
1964     (and (>= evt-col column)
1965          (< evt-col (+ column width))
1966          (if (> height 0)
1967              (and (> evt-row row)
1968                   (<= evt-row (+ row height) ))
1969            (and (< evt-row row)
1970                 (>= evt-row (+ row height)))))))
1971
1972 (defun company--event-col-row (event)
1973   (company--posn-col-row (event-start event)))
1974
1975 (defun company-select-mouse (event)
1976   "Select the candidate picked by the mouse."
1977   (interactive "e")
1978   (let ((event-col-row (company--event-col-row event))
1979         (ovl-row (company--row))
1980         (ovl-height (and company-pseudo-tooltip-overlay
1981                          (min (overlay-get company-pseudo-tooltip-overlay
1982                                            'company-height)
1983                               company-candidates-length))))
1984     (if (and ovl-height
1985              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1986         (progn
1987           (company-set-selection (+ (cdr event-col-row)
1988                                     (1- company-tooltip-offset)
1989                                     (if (and (eq company-tooltip-offset-display 'lines)
1990                                              (not (zerop company-tooltip-offset)))
1991                                         -1 0)
1992                                     (- ovl-row)
1993                                     (if (< ovl-height 0)
1994                                         (- 1 ovl-height)
1995                                       0)))
1996           t)
1997       (company-abort)
1998       (company--unread-last-input)
1999       nil)))
2000
2001 (defun company-complete-mouse (event)
2002   "Insert the candidate picked by the mouse."
2003   (interactive "e")
2004   (when (company-select-mouse event)
2005     (company-complete-selection)))
2006
2007 (defun company-complete-selection ()
2008   "Insert the selected candidate."
2009   (interactive)
2010   (when (company-manual-begin)
2011     (let ((result (nth company-selection company-candidates)))
2012       (company-finish result))))
2013
2014 (defun company-complete-common ()
2015   "Insert the common part of all candidates."
2016   (interactive)
2017   (when (company-manual-begin)
2018     (if (and (not (cdr company-candidates))
2019              (equal company-common (car company-candidates)))
2020         (company-complete-selection)
2021       (company--insert-candidate company-common))))
2022
2023 (defun company-complete-common-or-cycle (&optional arg)
2024   "Insert the common part of all candidates, or select the next one.
2025
2026 With ARG, move by that many elements."
2027   (interactive "p")
2028   (when (company-manual-begin)
2029     (let ((tick (buffer-chars-modified-tick)))
2030       (call-interactively 'company-complete-common)
2031       (when (eq tick (buffer-chars-modified-tick))
2032         (let ((company-selection-wrap-around t)
2033               (current-prefix-arg arg))
2034           (call-interactively 'company-select-next))))))
2035
2036 (defun company-indent-or-complete-common ()
2037   "Indent the current line or region, or complete the common part."
2038   (interactive)
2039   (cond
2040    ((use-region-p)
2041     (indent-region (region-beginning) (region-end)))
2042    ((let ((old-point (point))
2043           (old-tick (buffer-chars-modified-tick))
2044           (tab-always-indent t))
2045       (call-interactively #'indent-for-tab-command)
2046       (when (and (eq old-point (point))
2047                  (eq old-tick (buffer-chars-modified-tick)))
2048         (company-complete-common))))))
2049
2050 ;;;###autoload
2051 (defun company-complete ()
2052   "Insert the common part of all candidates or the current selection.
2053 The first time this is called, the common part is inserted, the second
2054 time, or when the selection has been changed, the selected candidate is
2055 inserted."
2056   (interactive)
2057   (when (company-manual-begin)
2058     (if (or company-selection-changed
2059             (eq last-command 'company-complete-common))
2060         (call-interactively 'company-complete-selection)
2061       (call-interactively 'company-complete-common)
2062       (setq this-command 'company-complete-common))))
2063
2064 (defun company-complete-number (n)
2065   "Insert the Nth candidate visible in the tooltip.
2066 To show the number next to the candidates in some backends, enable
2067 `company-show-numbers'.  When called interactively, uses the last typed
2068 character, stripping the modifiers.  That character must be a digit."
2069   (interactive
2070    (list (let* ((type (event-basic-type last-command-event))
2071                 (char (if (characterp type)
2072                           ;; Number on the main row.
2073                           type
2074                         ;; Keypad number, if bound directly.
2075                         (car (last (string-to-list (symbol-name type))))))
2076                 (n (- char ?0)))
2077            (if (zerop n) 10 n))))
2078   (when (company-manual-begin)
2079     (and (or (< n 1) (> n (- company-candidates-length
2080                              company-tooltip-offset)))
2081          (error "No candidate number %d" n))
2082     (cl-decf n)
2083     (company-finish (nth (+ n company-tooltip-offset)
2084                          company-candidates))))
2085
2086 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2087
2088 (defconst company-space-strings-limit 100)
2089
2090 (defconst company-space-strings
2091   (let (lst)
2092     (dotimes (i company-space-strings-limit)
2093       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
2094     (apply 'vector lst)))
2095
2096 (defun company-space-string (len)
2097   (if (< len company-space-strings-limit)
2098       (aref company-space-strings len)
2099     (make-string len ?\ )))
2100
2101 (defun company-safe-substring (str from &optional to)
2102   (if (> from (string-width str))
2103       ""
2104     (with-temp-buffer
2105       (insert str)
2106       (move-to-column from)
2107       (let ((beg (point)))
2108         (if to
2109             (progn
2110               (move-to-column to)
2111               (concat (buffer-substring beg (point))
2112                       (let ((padding (- to (current-column))))
2113                         (when (> padding 0)
2114                           (company-space-string padding)))))
2115           (buffer-substring beg (point-max)))))))
2116
2117 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2118
2119 (defvar-local company-last-metadata nil)
2120
2121 (defun company-fetch-metadata ()
2122   (let ((selected (nth company-selection company-candidates)))
2123     (unless (eq selected (car company-last-metadata))
2124       (setq company-last-metadata
2125             (cons selected (company-call-backend 'meta selected))))
2126     (cdr company-last-metadata)))
2127
2128 (defun company-doc-buffer (&optional string)
2129   (with-current-buffer (get-buffer-create "*company-documentation*")
2130     (erase-buffer)
2131     (when string
2132       (save-excursion
2133         (insert string)))
2134     (current-buffer)))
2135
2136 (defvar company--electric-saved-window-configuration nil)
2137
2138 (defvar company--electric-commands
2139   '(scroll-other-window scroll-other-window-down mwheel-scroll)
2140   "List of Commands that won't break out of electric commands.")
2141
2142 (defun company--electric-restore-window-configuration ()
2143   "Restore window configuration (after electric commands)."
2144   (when (and company--electric-saved-window-configuration
2145              (not (memq this-command company--electric-commands)))
2146     (set-window-configuration company--electric-saved-window-configuration)
2147     (setq company--electric-saved-window-configuration nil)))
2148
2149 (defmacro company--electric-do (&rest body)
2150   (declare (indent 0) (debug t))
2151   `(when (company-manual-begin)
2152      (cl-assert (null company--electric-saved-window-configuration))
2153      (setq company--electric-saved-window-configuration (current-window-configuration))
2154      (let ((height (window-height))
2155            (row (company--row)))
2156        ,@body
2157        (and (< (window-height) height)
2158             (< (- (window-height) row 2) company-tooltip-limit)
2159             (recenter (- (window-height) row 2))))))
2160
2161 (defun company--unread-last-input ()
2162   (when last-input-event
2163     (clear-this-command-keys t)
2164     (setq unread-command-events (list last-input-event))))
2165
2166 (defun company-show-doc-buffer ()
2167   "Temporarily show the documentation buffer for the selection."
2168   (interactive)
2169   (let (other-window-scroll-buffer)
2170     (company--electric-do
2171       (let* ((selected (nth company-selection company-candidates))
2172              (doc-buffer (or (company-call-backend 'doc-buffer selected)
2173                              (error "No documentation available")))
2174              start)
2175         (when (consp doc-buffer)
2176           (setq start (cdr doc-buffer)
2177                 doc-buffer (car doc-buffer)))
2178         (setq other-window-scroll-buffer (get-buffer doc-buffer))
2179         (let ((win (display-buffer doc-buffer t)))
2180           (set-window-start win (if start start (point-min))))))))
2181 (put 'company-show-doc-buffer 'company-keep t)
2182
2183 (defun company-show-location ()
2184   "Temporarily display a buffer showing the selected candidate in context."
2185   (interactive)
2186   (let (other-window-scroll-buffer)
2187     (company--electric-do
2188       (let* ((selected (nth company-selection company-candidates))
2189              (location (company-call-backend 'location selected))
2190              (pos (or (cdr location) (error "No location available")))
2191              (buffer (or (and (bufferp (car location)) (car location))
2192                          (find-file-noselect (car location) t))))
2193         (setq other-window-scroll-buffer (get-buffer buffer))
2194         (with-selected-window (display-buffer buffer t)
2195           (save-restriction
2196             (widen)
2197             (if (bufferp (car location))
2198                 (goto-char pos)
2199               (goto-char (point-min))
2200               (forward-line (1- pos))))
2201           (set-window-start nil (point)))))))
2202 (put 'company-show-location 'company-keep t)
2203
2204 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2205
2206 (defvar-local company-callback nil)
2207
2208 (defun company-remove-callback (&optional ignored)
2209   (remove-hook 'company-completion-finished-hook company-callback t)
2210   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
2211   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
2212
2213 (defun company-begin-backend (backend &optional callback)
2214   "Start a completion at point using BACKEND."
2215   (interactive (let ((val (completing-read "Company backend: "
2216                                            obarray
2217                                            'functionp nil "company-")))
2218                  (when val
2219                    (list (intern val)))))
2220   (when (setq company-callback callback)
2221     (add-hook 'company-completion-finished-hook company-callback nil t))
2222   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
2223   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
2224   (setq company-backend backend)
2225   ;; Return non-nil if active.
2226   (or (company-manual-begin)
2227       (error "Cannot complete at point")))
2228
2229 (defun company-begin-with (candidates
2230                            &optional prefix-length require-match callback)
2231   "Start a completion at point.
2232 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
2233 of the prefix that already is in the buffer before point.
2234 It defaults to 0.
2235
2236 CALLBACK is a function called with the selected result if the user
2237 successfully completes the input.
2238
2239 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
2240   (let ((begin-marker (copy-marker (point) t)))
2241     (company-begin-backend
2242      (lambda (command &optional arg &rest ignored)
2243        (pcase command
2244          (`prefix
2245           (when (equal (point) (marker-position begin-marker))
2246             (buffer-substring (- (point) (or prefix-length 0)) (point))))
2247          (`candidates
2248           (all-completions arg candidates))
2249          (`require-match
2250           require-match)))
2251      callback)))
2252
2253 (declare-function find-library-name "find-func")
2254 (declare-function lm-version "lisp-mnt")
2255
2256 (defun company-version (&optional show-version)
2257   "Get the Company version as string.
2258
2259 If SHOW-VERSION is non-nil, show the version in the echo area."
2260   (interactive (list t))
2261   (with-temp-buffer
2262     (require 'find-func)
2263     (insert-file-contents (find-library-name "company"))
2264     (require 'lisp-mnt)
2265     (if show-version
2266         (message "Company version: %s" (lm-version))
2267       (lm-version))))
2268
2269 (defun company-diag ()
2270   "Pop a buffer with information about completions at point."
2271   (interactive)
2272   (let* ((bb company-backends)
2273          backend
2274          (prefix (cl-loop for b in bb
2275                           thereis (let ((company-backend b))
2276                                     (setq backend b)
2277                                     (company-call-backend 'prefix))))
2278          cc annotations)
2279     (when (stringp prefix)
2280       (let ((company-backend backend))
2281         (setq cc (company-call-backend 'candidates prefix)
2282               annotations
2283               (mapcar
2284                (lambda (c) (cons c (company-call-backend 'annotation c)))
2285                cc))))
2286     (pop-to-buffer (get-buffer-create "*company-diag*"))
2287     (setq buffer-read-only nil)
2288     (erase-buffer)
2289     (insert (format "Emacs %s (%s) of %s on %s"
2290                     emacs-version system-configuration
2291                     (format-time-string "%Y-%m-%d" emacs-build-time)
2292                     emacs-build-system))
2293     (insert "\nCompany " (company-version) "\n\n")
2294     (insert "company-backends: " (pp-to-string bb))
2295     (insert "\n")
2296     (insert "Used backend: " (pp-to-string backend))
2297     (insert "\n")
2298     (insert "Prefix: " (pp-to-string prefix))
2299     (insert "\n")
2300     (insert (message  "Completions:"))
2301     (unless cc (insert " none"))
2302     (save-excursion
2303       (dolist (c annotations)
2304         (insert "\n  " (prin1-to-string (car c)))
2305         (when (cdr c)
2306           (insert " " (prin1-to-string (cdr c))))))
2307     (special-mode)))
2308
2309 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2310
2311 (defvar-local company-pseudo-tooltip-overlay nil)
2312
2313 (defvar-local company-tooltip-offset 0)
2314
2315 (defun company-tooltip--lines-update-offset (selection num-lines limit)
2316   (cl-decf limit 2)
2317   (setq company-tooltip-offset
2318         (max (min selection company-tooltip-offset)
2319              (- selection -1 limit)))
2320
2321   (when (<= company-tooltip-offset 1)
2322     (cl-incf limit)
2323     (setq company-tooltip-offset 0))
2324
2325   (when (>= company-tooltip-offset (- num-lines limit 1))
2326     (cl-incf limit)
2327     (when (= selection (1- num-lines))
2328       (cl-decf company-tooltip-offset)
2329       (when (<= company-tooltip-offset 1)
2330         (setq company-tooltip-offset 0)
2331         (cl-incf limit))))
2332
2333   limit)
2334
2335 (defun company-tooltip--simple-update-offset (selection _num-lines limit)
2336   (setq company-tooltip-offset
2337         (if (< selection company-tooltip-offset)
2338             selection
2339           (max company-tooltip-offset
2340                (- selection limit -1)))))
2341
2342 ;;; propertize
2343
2344 (defsubst company-round-tab (arg)
2345   (* (/ (+ arg tab-width) tab-width) tab-width))
2346
2347 (defun company-plainify (str)
2348   (let ((prefix (get-text-property 0 'line-prefix str)))
2349     (when prefix ; Keep the original value unmodified, for no special reason.
2350       (setq str (concat prefix str))
2351       (remove-text-properties 0 (length str) '(line-prefix) str)))
2352   (let* ((pieces (split-string str "\t"))
2353          (copy pieces))
2354     (while (cdr copy)
2355       (setcar copy (company-safe-substring
2356                     (car copy) 0 (company-round-tab (string-width (car copy)))))
2357       (pop copy))
2358     (apply 'concat pieces)))
2359
2360 (defun company-fill-propertize (value annotation width selected left right)
2361   (let* ((margin (length left))
2362          (common (or (company-call-backend 'match value)
2363                      (if company-common
2364                          (string-width company-common)
2365                        0)))
2366          (_ (setq value (company--pre-render value)
2367                   annotation (and annotation (company--pre-render annotation t))))
2368          (ann-ralign company-tooltip-align-annotations)
2369          (ann-truncate (< width
2370                           (+ (length value) (length annotation)
2371                              (if ann-ralign 1 0))))
2372          (ann-start (+ margin
2373                        (if ann-ralign
2374                            (if ann-truncate
2375                                (1+ (length value))
2376                              (- width (length annotation)))
2377                          (length value))))
2378          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
2379          (line (concat left
2380                        (if (or ann-truncate (not ann-ralign))
2381                            (company-safe-substring
2382                             (concat value
2383                                     (when (and annotation ann-ralign) " ")
2384                                     annotation)
2385                             0 width)
2386                          (concat
2387                           (company-safe-substring value 0
2388                                                   (- width (length annotation)))
2389                           annotation))
2390                        right)))
2391     (setq common (+ (min common width) margin))
2392     (setq width (+ width margin (length right)))
2393
2394     (font-lock-append-text-property 0 width 'mouse-face
2395                                     'company-tooltip-mouse
2396                                     line)
2397     (when (< ann-start ann-end)
2398       (font-lock-append-text-property ann-start ann-end 'face
2399                                       (if selected
2400                                           'company-tooltip-annotation-selection
2401                                         'company-tooltip-annotation)
2402                                       line))
2403     (font-lock-prepend-text-property margin common 'face
2404                                      (if selected
2405                                          'company-tooltip-common-selection
2406                                        'company-tooltip-common)
2407                                      line)
2408     (when selected
2409       (if (let ((re (funcall company-search-regexp-function
2410                              company-search-string)))
2411             (and (not (string= re ""))
2412                  (string-match re value (length company-prefix))))
2413           (pcase-dolist (`(,mbeg . ,mend) (company--search-chunks))
2414             (let ((beg (+ margin mbeg))
2415                   (end (+ margin mend))
2416                   (width (- width (length right))))
2417               (when (< beg width)
2418                 (font-lock-prepend-text-property beg (min end width)
2419                                                  'face 'company-tooltip-search
2420                                                  line))))
2421         (font-lock-append-text-property 0 width 'face
2422                                         'company-tooltip-selection
2423                                         line)))
2424     (font-lock-append-text-property 0 width 'face
2425                                     'company-tooltip
2426                                     line)
2427     line))
2428
2429 (defun company--search-chunks ()
2430   (let ((md (match-data t))
2431         res)
2432     (if (<= (length md) 2)
2433         (push (cons (nth 0 md) (nth 1 md)) res)
2434       (while (setq md (nthcdr 2 md))
2435         (when (car md)
2436           (push (cons (car md) (cadr md)) res))))
2437     res))
2438
2439 (defun company--pre-render (str &optional annotation-p)
2440   (or (company-call-backend 'pre-render str annotation-p)
2441       (progn
2442         (when (or (text-property-not-all 0 (length str) 'face nil str)
2443                   (text-property-not-all 0 (length str) 'mouse-face nil str))
2444           (setq str (copy-sequence str))
2445           (remove-text-properties 0 (length str)
2446                                   '(face nil font-lock-face nil mouse-face nil)
2447                                   str))
2448         str)))
2449
2450 (defun company--clean-string (str)
2451   (replace-regexp-in-string
2452    "\\([^[:graph:] ]\\)\\|\\(\ufeff\\)\\|[[:multibyte:]]"
2453    (lambda (match)
2454      (cond
2455       ((match-beginning 1)
2456        ;; FIXME: Better char for 'non-printable'?
2457        ;; We shouldn't get any of these, but sometimes we might.
2458        "\u2017")
2459       ((match-beginning 2)
2460        ;; Zero-width non-breakable space.
2461        "")
2462       ((> (string-width match) 1)
2463        (concat
2464         (make-string (1- (string-width match)) ?\ufeff)
2465         match))
2466       (t match)))
2467    str))
2468
2469 ;;; replace
2470
2471 (defun company-buffer-lines (beg end)
2472   (goto-char beg)
2473   (let (lines lines-moved)
2474     (while (and (not (eobp)) ; http://debbugs.gnu.org/19553
2475                 (> (setq lines-moved (vertical-motion 1)) 0)
2476                 (<= (point) end))
2477       (let ((bound (min end (point))))
2478         ;; A visual line can contain several physical lines (e.g. with outline's
2479         ;; folding overlay).  Take only the first one.
2480         (push (buffer-substring beg
2481                                 (save-excursion
2482                                   (goto-char beg)
2483                                   (re-search-forward "$" bound 'move)
2484                                   (point)))
2485               lines))
2486       ;; One physical line can be displayed as several visual ones as well:
2487       ;; add empty strings to the list, to even the count.
2488       (dotimes (_ (1- lines-moved))
2489         (push "" lines))
2490       (setq beg (point)))
2491     (unless (eq beg end)
2492       (push (buffer-substring beg end) lines))
2493     (nreverse lines)))
2494
2495 (defun company-modify-line (old new offset)
2496   (concat (company-safe-substring old 0 offset)
2497           new
2498           (company-safe-substring old (+ offset (length new)))))
2499
2500 (defsubst company--length-limit (lst limit)
2501   (if (nthcdr limit lst)
2502       limit
2503     (length lst)))
2504
2505 (defsubst company--window-height ()
2506   (if (fboundp 'window-screen-lines)
2507       (floor (window-screen-lines))
2508     (window-body-height)))
2509
2510 (defun company--window-width ()
2511   (let ((ww (window-body-width)))
2512     ;; Account for the line continuation column.
2513     (when (zerop (cadr (window-fringes)))
2514       (cl-decf ww))
2515     (unless (or (display-graphic-p)
2516                 (version< "24.3.1" emacs-version))
2517       ;; Emacs 24.3 and earlier included margins
2518       ;; in window-width when in TTY.
2519       (cl-decf ww
2520                (let ((margins (window-margins)))
2521                  (+ (or (car margins) 0)
2522                     (or (cdr margins) 0)))))
2523     (when (and word-wrap
2524                (version< emacs-version "24.4.51.5"))
2525       ;; http://debbugs.gnu.org/19300
2526       (cl-decf ww))
2527     ;; whitespace-mode with newline-mark
2528     (when (and buffer-display-table
2529                (aref buffer-display-table ?\n))
2530       (cl-decf ww (1- (length (aref buffer-display-table ?\n)))))
2531     ww))
2532
2533 (defun company--replacement-string (lines old column nl &optional align-top)
2534   (cl-decf column company-tooltip-margin)
2535
2536   (when (and align-top company-tooltip-flip-when-above)
2537     (setq lines (reverse lines)))
2538
2539   (let ((width (length (car lines)))
2540         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2541                            column)))
2542     (when (> width remaining-cols)
2543       (cl-decf column (- width remaining-cols))))
2544
2545   (let ((offset (and (< column 0) (- column)))
2546         new)
2547     (when offset
2548       (setq column 0))
2549     (when align-top
2550       ;; untouched lines first
2551       (dotimes (_ (- (length old) (length lines)))
2552         (push (pop old) new)))
2553     ;; length into old lines.
2554     (while old
2555       (push (company-modify-line (pop old)
2556                                  (company--offset-line (pop lines) offset)
2557                                  column)
2558             new))
2559     ;; Append whole new lines.
2560     (while lines
2561       (push (concat (company-space-string column)
2562                     (company--offset-line (pop lines) offset))
2563             new))
2564
2565     (let ((str (concat (when nl " \n")
2566                        (mapconcat 'identity (nreverse new) "\n")
2567                        "\n")))
2568       (font-lock-append-text-property 0 (length str) 'face 'default str)
2569       (when nl (put-text-property 0 1 'cursor t str))
2570       str)))
2571
2572 (defun company--offset-line (line offset)
2573   (if (and offset line)
2574       (substring line offset)
2575     line))
2576
2577 (defun company--create-lines (selection limit)
2578   (let ((len company-candidates-length)
2579         (window-width (company--window-width))
2580         lines
2581         width
2582         lines-copy
2583         items
2584         previous
2585         remainder
2586         scrollbar-bounds)
2587
2588     ;; Maybe clear old offset.
2589     (when (< len (+ company-tooltip-offset limit))
2590       (setq company-tooltip-offset 0))
2591
2592     ;; Scroll to offset.
2593     (if (eq company-tooltip-offset-display 'lines)
2594         (setq limit (company-tooltip--lines-update-offset selection len limit))
2595       (company-tooltip--simple-update-offset selection len limit))
2596
2597     (cond
2598      ((eq company-tooltip-offset-display 'scrollbar)
2599       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2600                                                         limit len)))
2601      ((eq company-tooltip-offset-display 'lines)
2602       (when (> company-tooltip-offset 0)
2603         (setq previous (format "...(%d)" company-tooltip-offset)))
2604       (setq remainder (- len limit company-tooltip-offset)
2605             remainder (when (> remainder 0)
2606                         (setq remainder (format "...(%d)" remainder))))))
2607
2608     (cl-decf selection company-tooltip-offset)
2609     (setq width (max (length previous) (length remainder))
2610           lines (nthcdr company-tooltip-offset company-candidates)
2611           len (min limit len)
2612           lines-copy lines)
2613
2614     (cl-decf window-width (* 2 company-tooltip-margin))
2615     (when scrollbar-bounds (cl-decf window-width))
2616
2617     (dotimes (_ len)
2618       (let* ((value (pop lines-copy))
2619              (annotation (company-call-backend 'annotation value)))
2620         (setq value (company--clean-string (company-reformat value)))
2621         (when annotation
2622           (when company-tooltip-align-annotations
2623             ;; `lisp-completion-at-point' adds a space.
2624             (setq annotation (comment-string-strip annotation t nil)))
2625           (setq annotation (company--clean-string annotation)))
2626         (push (cons value annotation) items)
2627         (setq width (max (+ (length value)
2628                             (if (and annotation company-tooltip-align-annotations)
2629                                 (1+ (length annotation))
2630                               (length annotation)))
2631                          width))))
2632
2633     (setq width (min window-width
2634                      (max company-tooltip-minimum-width
2635                           (if company-show-numbers
2636                               (+ 2 width)
2637                             width))))
2638
2639     (let ((items (nreverse items))
2640           (numbered (if company-show-numbers 0 99999))
2641           new)
2642       (when previous
2643         (push (company--scrollpos-line previous width) new))
2644
2645       (dotimes (i len)
2646         (let* ((item (pop items))
2647                (str (car item))
2648                (annotation (cdr item))
2649                (right (company-space-string company-tooltip-margin))
2650                (width width))
2651           (when (< numbered 10)
2652             (cl-decf width 2)
2653             (cl-incf numbered)
2654             (setq right (concat (format " %d" (mod numbered 10)) right)))
2655           (push (concat
2656                  (company-fill-propertize str annotation
2657                                           width (equal i selection)
2658                                           (company-space-string
2659                                            company-tooltip-margin)
2660                                           right)
2661                  (when scrollbar-bounds
2662                    (company--scrollbar i scrollbar-bounds)))
2663                 new)))
2664
2665       (when remainder
2666         (push (company--scrollpos-line remainder width) new))
2667
2668       (nreverse new))))
2669
2670 (defun company--scrollbar-bounds (offset limit length)
2671   (when (> length limit)
2672     (let* ((size (ceiling (* limit (float limit)) length))
2673            (lower (floor (* limit (float offset)) length))
2674            (upper (+ lower size -1)))
2675       (cons lower upper))))
2676
2677 (defun company--scrollbar (i bounds)
2678   (propertize " " 'face
2679               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2680                   'company-scrollbar-fg
2681                 'company-scrollbar-bg)))
2682
2683 (defun company--scrollpos-line (text width)
2684   (propertize (concat (company-space-string company-tooltip-margin)
2685                       (company-safe-substring text 0 width)
2686                       (company-space-string company-tooltip-margin))
2687               'face 'company-tooltip))
2688
2689 ;; show
2690
2691 (defun company--pseudo-tooltip-height ()
2692   "Calculate the appropriate tooltip height.
2693 Returns a negative number if the tooltip should be displayed above point."
2694   (let* ((lines (company--row))
2695          (below (- (company--window-height) 1 lines)))
2696     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2697              (> lines below))
2698         (- (max 3 (min company-tooltip-limit lines)))
2699       (max 3 (min company-tooltip-limit below)))))
2700
2701 (defun company-pseudo-tooltip-show (row column selection)
2702   (company-pseudo-tooltip-hide)
2703   (save-excursion
2704
2705     (let* ((height (company--pseudo-tooltip-height))
2706            above)
2707
2708       (when (< height 0)
2709         (setq row (+ row height -1)
2710               above t))
2711
2712       (let* ((nl (< (move-to-window-line row) row))
2713              (beg (point))
2714              (end (save-excursion
2715                     (move-to-window-line (+ row (abs height)))
2716                     (point)))
2717              (ov (make-overlay beg end nil t))
2718              (args (list (mapcar 'company-plainify
2719                                  (company-buffer-lines beg end))
2720                          column nl above)))
2721
2722         (setq company-pseudo-tooltip-overlay ov)
2723         (overlay-put ov 'company-replacement-args args)
2724
2725         (let ((lines (company--create-lines selection (abs height))))
2726           (overlay-put ov 'company-display
2727                        (apply 'company--replacement-string lines args))
2728           (overlay-put ov 'company-width (string-width (car lines))))
2729
2730         (overlay-put ov 'company-column column)
2731         (overlay-put ov 'company-height height)))))
2732
2733 (defun company-pseudo-tooltip-show-at-point (pos column-offset)
2734   (let* ((col-row (company--col-row pos))
2735          (col (- (car col-row) column-offset)))
2736     (when (< col 0) (setq col 0))
2737     (company-pseudo-tooltip-show (1+ (cdr col-row)) col company-selection)))
2738
2739 (defun company-pseudo-tooltip-edit (selection)
2740   (let* ((height (overlay-get company-pseudo-tooltip-overlay 'company-height))
2741          (lines  (company--create-lines selection (abs height))))
2742     (overlay-put company-pseudo-tooltip-overlay 'company-width
2743                  (string-width (car lines)))
2744     (overlay-put company-pseudo-tooltip-overlay 'company-display
2745                  (apply 'company--replacement-string
2746                         lines
2747                         (overlay-get company-pseudo-tooltip-overlay
2748                                      'company-replacement-args)))))
2749
2750 (defun company-pseudo-tooltip-hide ()
2751   (when company-pseudo-tooltip-overlay
2752     (delete-overlay company-pseudo-tooltip-overlay)
2753     (setq company-pseudo-tooltip-overlay nil)))
2754
2755 (defun company-pseudo-tooltip-hide-temporarily ()
2756   (when (overlayp company-pseudo-tooltip-overlay)
2757     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2758     (overlay-put company-pseudo-tooltip-overlay 'line-prefix nil)
2759     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)
2760     (overlay-put company-pseudo-tooltip-overlay 'display nil)))
2761
2762 (defun company-pseudo-tooltip-unhide ()
2763   (when company-pseudo-tooltip-overlay
2764     (let* ((ov company-pseudo-tooltip-overlay)
2765            (disp (overlay-get ov 'company-display)))
2766       ;; Beat outline's folding overlays, at least.
2767       (overlay-put ov 'priority 1)
2768       ;; No (extra) prefix for the first line.
2769       (overlay-put ov 'line-prefix "")
2770       ;; `display' is better
2771       ;; (http://debbugs.gnu.org/18285, http://debbugs.gnu.org/20847),
2772       ;; but it doesn't work on 0-length overlays.
2773       (if (< (overlay-start ov) (overlay-end ov))
2774           (overlay-put ov 'display disp)
2775         (overlay-put ov 'after-string disp)
2776         (overlay-put ov 'invisible t))
2777       (overlay-put ov 'window (selected-window)))))
2778
2779 (defun company-pseudo-tooltip-guard ()
2780   (cons
2781    (save-excursion (beginning-of-visual-line))
2782    (let ((ov company-pseudo-tooltip-overlay)
2783          (overhang (save-excursion (end-of-visual-line)
2784                                    (- (line-end-position) (point)))))
2785      (when (>= (overlay-get ov 'company-height) 0)
2786        (cons
2787         (buffer-substring-no-properties (point) (overlay-start ov))
2788         (when (>= overhang 0) overhang))))))
2789
2790 (defun company-pseudo-tooltip-frontend (command)
2791   "`company-mode' frontend similar to a tooltip but based on overlays."
2792   (cl-case command
2793     (pre-command (company-pseudo-tooltip-hide-temporarily))
2794     (post-command
2795      (unless (when (overlayp company-pseudo-tooltip-overlay)
2796               (let* ((ov company-pseudo-tooltip-overlay)
2797                      (old-height (overlay-get ov 'company-height))
2798                      (new-height (company--pseudo-tooltip-height)))
2799                 (and
2800                  (>= (* old-height new-height) 0)
2801                  (>= (abs old-height) (abs new-height))
2802                  (equal (company-pseudo-tooltip-guard)
2803                         (overlay-get ov 'company-guard)))))
2804        ;; Redraw needed.
2805        (company-pseudo-tooltip-show-at-point (point) (length company-prefix))
2806        (overlay-put company-pseudo-tooltip-overlay
2807                     'company-guard (company-pseudo-tooltip-guard)))
2808      (company-pseudo-tooltip-unhide))
2809     (hide (company-pseudo-tooltip-hide)
2810           (setq company-tooltip-offset 0))
2811     (update (when (overlayp company-pseudo-tooltip-overlay)
2812               (company-pseudo-tooltip-edit company-selection)))))
2813
2814 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2815   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2816   (unless (and (eq command 'post-command)
2817                (company--show-inline-p))
2818     (company-pseudo-tooltip-frontend command)))
2819
2820 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2821
2822 (defvar-local company-preview-overlay nil)
2823
2824 (defun company-preview-show-at-point (pos)
2825   (company-preview-hide)
2826
2827   (let ((completion (nth company-selection company-candidates)))
2828     (setq completion (copy-sequence (company--pre-render completion)))
2829     (font-lock-append-text-property 0 (length completion)
2830                                     'face 'company-preview
2831                                     completion)
2832     (font-lock-prepend-text-property 0 (length company-common)
2833                                      'face 'company-preview-common
2834                                      completion)
2835
2836     ;; Add search string
2837     (and (string-match (funcall company-search-regexp-function
2838                                 company-search-string)
2839                        completion)
2840          (pcase-dolist (`(,mbeg . ,mend) (company--search-chunks))
2841            (font-lock-prepend-text-property mbeg mend
2842                                             'face 'company-preview-search
2843                                             completion)))
2844
2845     (setq completion (company-strip-prefix completion))
2846
2847     (and (equal pos (point))
2848          (not (equal completion ""))
2849          (add-text-properties 0 1 '(cursor 1) completion))
2850
2851     (let* ((beg pos)
2852            (pto company-pseudo-tooltip-overlay)
2853            (ptf-workaround (and
2854                             pto
2855                             (char-before pos)
2856                             (eq pos (overlay-start pto)))))
2857       ;; Try to accomodate for the pseudo-tooltip overlay,
2858       ;; which may start at the same position if it's at eol.
2859       (when ptf-workaround
2860         (cl-decf beg)
2861         (setq completion (concat (buffer-substring beg pos) completion)))
2862
2863       (setq company-preview-overlay (make-overlay beg pos))
2864
2865       (let ((ov company-preview-overlay))
2866         (overlay-put ov (if ptf-workaround 'display 'after-string)
2867                      completion)
2868         (overlay-put ov 'window (selected-window))))))
2869
2870 (defun company-preview-hide ()
2871   (when company-preview-overlay
2872     (delete-overlay company-preview-overlay)
2873     (setq company-preview-overlay nil)))
2874
2875 (defun company-preview-frontend (command)
2876   "`company-mode' frontend showing the selection as if it had been inserted."
2877   (pcase command
2878     (`pre-command (company-preview-hide))
2879     (`post-command (company-preview-show-at-point (point)))
2880     (`hide (company-preview-hide))))
2881
2882 (defun company-preview-if-just-one-frontend (command)
2883   "`company-preview-frontend', but only shown for single candidates."
2884   (when (or (not (eq command 'post-command))
2885             (company--show-inline-p))
2886     (company-preview-frontend command)))
2887
2888 (defun company--show-inline-p ()
2889   (and (not (cdr company-candidates))
2890        company-common
2891        (or (eq (company-call-backend 'ignore-case) 'keep-prefix)
2892            (string-prefix-p company-prefix company-common))))
2893
2894 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2895
2896 (defvar-local company-echo-last-msg nil)
2897
2898 (defvar company-echo-timer nil)
2899
2900 (defvar company-echo-delay .01)
2901
2902 (defun company-echo-show (&optional getter)
2903   (when getter
2904     (setq company-echo-last-msg (funcall getter)))
2905   (let ((message-log-max nil))
2906     (if company-echo-last-msg
2907         (message "%s" company-echo-last-msg)
2908       (message ""))))
2909
2910 (defun company-echo-show-soon (&optional getter)
2911   (company-echo-cancel)
2912   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2913
2914 (defun company-echo-cancel (&optional unset)
2915   (when company-echo-timer
2916     (cancel-timer company-echo-timer))
2917   (when unset
2918     (setq company-echo-timer nil)))
2919
2920 (defun company-echo-show-when-idle (&optional getter)
2921   (company-echo-cancel)
2922   (setq company-echo-timer
2923         (run-with-idle-timer company-echo-delay nil 'company-echo-show getter)))
2924
2925 (defun company-echo-format ()
2926
2927   (let ((limit (window-body-width (minibuffer-window)))
2928         (len -1)
2929         ;; Roll to selection.
2930         (candidates (nthcdr company-selection company-candidates))
2931         (i (if company-show-numbers company-selection 99999))
2932         comp msg)
2933
2934     (while candidates
2935       (setq comp (company-reformat (pop candidates))
2936             len (+ len 1 (length comp)))
2937       (if (< i 10)
2938           ;; Add number.
2939           (progn
2940             (setq comp (propertize (format "%d: %s" i comp)
2941                                    'face 'company-echo))
2942             (cl-incf len 3)
2943             (cl-incf i)
2944             (add-text-properties 3 (+ 3 (length company-common))
2945                                  '(face company-echo-common) comp))
2946         (setq comp (propertize comp 'face 'company-echo))
2947         (add-text-properties 0 (length company-common)
2948                              '(face company-echo-common) comp))
2949       (if (>= len limit)
2950           (setq candidates nil)
2951         (push comp msg)))
2952
2953     (mapconcat 'identity (nreverse msg) " ")))
2954
2955 (defun company-echo-strip-common-format ()
2956
2957   (let ((limit (window-body-width (minibuffer-window)))
2958         (len (+ (length company-prefix) 2))
2959         ;; Roll to selection.
2960         (candidates (nthcdr company-selection company-candidates))
2961         (i (if company-show-numbers company-selection 99999))
2962         msg comp)
2963
2964     (while candidates
2965       (setq comp (company-strip-prefix (pop candidates))
2966             len (+ len 2 (length comp)))
2967       (when (< i 10)
2968         ;; Add number.
2969         (setq comp (format "%s (%d)" comp i))
2970         (cl-incf len 4)
2971         (cl-incf i))
2972       (if (>= len limit)
2973           (setq candidates nil)
2974         (push (propertize comp 'face 'company-echo) msg)))
2975
2976     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2977             (mapconcat 'identity (nreverse msg) ", ")
2978             "}")))
2979
2980 (defun company-echo-hide ()
2981   (unless (equal company-echo-last-msg "")
2982     (setq company-echo-last-msg "")
2983     (company-echo-show)))
2984
2985 (defun company-echo-frontend (command)
2986   "`company-mode' frontend showing the candidates in the echo area."
2987   (pcase command
2988     (`post-command (company-echo-show-soon 'company-echo-format))
2989     (`hide (company-echo-hide))))
2990
2991 (defun company-echo-strip-common-frontend (command)
2992   "`company-mode' frontend showing the candidates in the echo area."
2993   (pcase command
2994     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2995     (`hide (company-echo-hide))))
2996
2997 (defun company-echo-metadata-frontend (command)
2998   "`company-mode' frontend showing the documentation in the echo area."
2999   (pcase command
3000     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
3001     (`hide (company-echo-hide))))
3002
3003 (provide 'company)
3004 ;;; company.el ends here