code.delx.au - gnu-emacs-elpa/blob - packages/hydra/hydra.el

   1 ;;; hydra.el --- Make bindings that stick around. -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; Maintainer: Oleh Krehel <ohwoeowho@gmail.com>
   7 ;; URL: https://github.com/abo-abo/hydra
   8 ;; Version: 0.12.1
   9 ;; Keywords: bindings
  10 ;; Package-Requires: ((cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This package can be used to tie related commands into a family of
  30 ;; short bindings with a common prefix - a Hydra.
  31 ;;
  32 ;; Once you summon the Hydra (through the prefixed binding), all the
  33 ;; heads can be called in succession with only a short extension.
  34 ;; The Hydra is vanquished once Hercules, any binding that isn't the
  35 ;; Hydra's head, arrives.  Note that Hercules, besides vanquishing the
  36 ;; Hydra, will still serve his orignal purpose, calling his proper
  37 ;; command.  This makes the Hydra very seamless, it's like a minor
  38 ;; mode that disables itself automagically.
  39 ;;
  40 ;; Here's an example Hydra, bound in the global map (you can use any
  41 ;; keymap in place of `global-map'):
  42 ;;
  43 ;;     (defhydra hydra-zoom (global-map "<f2>")
  44 ;;       "zoom"
  45 ;;       ("g" text-scale-increase "in")
  46 ;;       ("l" text-scale-decrease "out"))
  47 ;;
  48 ;; It allows to start a command chain either like this:
  49 ;; "<f2> gg4ll5g", or "<f2> lgllg".
  50 ;;
  51 ;; Here's another approach, when you just want a "callable keymap":
  52 ;;
  53 ;;     (defhydra hydra-toggle (:color blue)
  54 ;;       "toggle"
  55 ;;       ("a" abbrev-mode "abbrev")
  56 ;;       ("d" toggle-debug-on-error "debug")
  57 ;;       ("f" auto-fill-mode "fill")
  58 ;;       ("t" toggle-truncate-lines "truncate")
  59 ;;       ("w" whitespace-mode "whitespace")
  60 ;;       ("q" nil "cancel"))
  61 ;;
  62 ;; This binds nothing so far, but if you follow up with:
  63 ;;
  64 ;;     (global-set-key (kbd "C-c C-v") 'hydra-toggle/body)
  65 ;;
  66 ;; you will have bound "C-c C-v a", "C-c C-v d" etc.
  67 ;;
  68 ;; Knowing that `defhydra' defines e.g. `hydra-toggle/body' command,
  69 ;; you can nest Hydras if you wish, with `hydra-toggle/body' possibly
  70 ;; becoming a blue head of another Hydra.
  71 ;;
  72 ;; Initially, Hydra shipped with a simplified `hydra-create' macro, to
  73 ;; which you could hook up the examples from hydra-examples.el.  It's
  74 ;; better to take the examples simply as templates and use `defhydra'
  75 ;; instead of `hydra-create', since it's more flexible.
  76
  77 ;;; Code:
  78 ;;* Requires
  79 (require 'cl-lib)
  80 (require 'lv)
  81
  82 (defalias 'hydra-set-transient-map
  83     (if (fboundp 'set-transient-map)
  84         'set-transient-map
  85       (lambda (map _keep-pred &optional on-exit)
  86         (with-no-warnings
  87           (set-temporary-overlay-map map (hydra--pred on-exit))))))
  88
  89 (defun hydra--pred (on-exit)
  90   "Generate a predicate on whether to continue the Hydra state.
  91 Call ON-EXIT for clean-up.
  92 This is a compatibility code for Emacs older than 24.4."
  93   `(lambda ()
  94      (if (lookup-key hydra-curr-map (this-command-keys-vector))
  95          t
  96        (hydra-cleanup)
  97        ,(when on-exit
  98               `(funcall ,(hydra--make-callable on-exit)))
  99        nil)))
 100
 101 ;;* Customize
 102 (defgroup hydra nil
 103   "Make bindings that stick around."
 104   :group 'bindings
 105   :prefix "hydra-")
 106
 107 (defcustom hydra-is-helpful t
 108   "When t, display a hint with possible bindings in the echo area."
 109   :type 'boolean
 110   :group 'hydra)
 111
 112 (defcustom hydra-keyboard-quit "\a"
 113   "This binding will quit an amaranth Hydra.
 114 It's the only other way to quit it besides though a blue head.
 115 It's possible to set this to nil.")
 116
 117 (defcustom hydra-lv t
 118   "When non-nil, `lv-message' (not `message') will be used to display hints."
 119   :type 'boolean)
 120
 121 (defcustom hydra-verbose nil
 122   "When non-nil, hydra will issue some non essential style warnings."
 123   :type 'boolean)
 124
 125 (defcustom hydra-key-format-spec "%s"
 126   "Default `format'-style specifier for _a_  syntax in docstrings.
 127 When nil, you can specify your own at each location like this: _ 5a_.")
 128
 129 (defface hydra-face-red
 130     '((t (:foreground "#FF0000" :bold t)))
 131   "Red Hydra heads will persist indefinitely."
 132   :group 'hydra)
 133
 134 (defface hydra-face-blue
 135     '((t (:foreground "#0000FF" :bold t)))
 136   "Blue Hydra heads will vanquish the Hydra.")
 137
 138 (defface hydra-face-amaranth
 139     '((t (:foreground "#E52B50" :bold t)))
 140   "Amaranth body has red heads and warns on intercepting non-heads.
 141 Vanquishable only through a blue head.")
 142
 143 (defface hydra-face-pink
 144     '((t (:foreground "#FF6EB4" :bold t)))
 145   "Pink body has red heads and on intercepting non-heads calls them without quitting.
 146 Vanquishable only through a blue head.")
 147
 148 (defface hydra-face-teal
 149     '((t (:foreground "#367588" :bold t)))
 150   "Teal body has blue heads an warns on intercepting non-heads.
 151 Vanquishable only through a blue head.")
 152
 153 ;;* Fontification
 154 (defun hydra-add-font-lock ()
 155   "Fontify `defhydra' statements."
 156   (font-lock-add-keywords
 157    'emacs-lisp-mode
 158    '(("(\\(defhydra\\)\\_> +\\(.*?\\)\\_>"
 159       (1 font-lock-keyword-face)
 160       (2 font-lock-type-face))
 161      ("(\\(defhydradio\\)\\_> +\\(.*?\\)\\_>"
 162       (1 font-lock-keyword-face)
 163       (2 font-lock-type-face)))))
 164
 165 ;;* Universal Argument
 166 (defvar hydra-base-map
 167   (let ((map (make-sparse-keymap)))
 168     (define-key map [?\C-u] 'hydra--universal-argument)
 169     (define-key map [?-] 'hydra--negative-argument)
 170     (define-key map [?0] 'hydra--digit-argument)
 171     (define-key map [?1] 'hydra--digit-argument)
 172     (define-key map [?2] 'hydra--digit-argument)
 173     (define-key map [?3] 'hydra--digit-argument)
 174     (define-key map [?4] 'hydra--digit-argument)
 175     (define-key map [?5] 'hydra--digit-argument)
 176     (define-key map [?6] 'hydra--digit-argument)
 177     (define-key map [?7] 'hydra--digit-argument)
 178     (define-key map [?8] 'hydra--digit-argument)
 179     (define-key map [?9] 'hydra--digit-argument)
 180     (define-key map [kp-0] 'hydra--digit-argument)
 181     (define-key map [kp-1] 'hydra--digit-argument)
 182     (define-key map [kp-2] 'hydra--digit-argument)
 183     (define-key map [kp-3] 'hydra--digit-argument)
 184     (define-key map [kp-4] 'hydra--digit-argument)
 185     (define-key map [kp-5] 'hydra--digit-argument)
 186     (define-key map [kp-6] 'hydra--digit-argument)
 187     (define-key map [kp-7] 'hydra--digit-argument)
 188     (define-key map [kp-8] 'hydra--digit-argument)
 189     (define-key map [kp-9] 'hydra--digit-argument)
 190     (define-key map [kp-subtract] 'hydra--negative-argument)
 191     (define-key map [switch-frame] 'hydra--handle-switch-frame)
 192     map)
 193   "Keymap that all Hydras inherit.  See `universal-argument-map'.")
 194
 195 (defvar hydra-curr-map
 196   (make-sparse-keymap)
 197   "Keymap of the current Hydra called.")
 198
 199 (defun hydra--handle-switch-frame (evt)
 200   "Quit hydra and call old switch-frame event handler for EVT."
 201   (interactive "e")
 202   (hydra-keyboard-quit)
 203   (funcall (lookup-key (current-global-map) [switch-frame]) evt))
 204
 205 (defun hydra--universal-argument (arg)
 206   "Forward to (`universal-argument' ARG)."
 207   (interactive "P")
 208   (setq prefix-arg (if (consp arg)
 209                        (list (* 4 (car arg)))
 210                      (if (eq arg '-)
 211                          (list -4)
 212                        '(4))))
 213   (hydra-set-transient-map hydra-curr-map t))
 214
 215 (defun hydra--digit-argument (arg)
 216   "Forward to (`digit-argument' ARG)."
 217   (interactive "P")
 218   (let ((universal-argument-map hydra-curr-map))
 219     (digit-argument arg)))
 220
 221 (defun hydra--negative-argument (arg)
 222   "Forward to (`negative-argument' ARG)."
 223   (interactive "P")
 224   (let ((universal-argument-map hydra-curr-map))
 225     (negative-argument arg)))
 226 ;;* Repeat
 227 (defvar hydra-repeat--prefix-arg nil
 228   "Prefix arg to use with `hydra-repeat'.")
 229
 230 (defvar hydra-repeat--command nil
 231   "Command to use with `hydra-repeat'.")
 232
 233 (defun hydra-repeat (&optional arg)
 234   "Repeat last command with last prefix arg.
 235 When ARG is non-nil, use that instead."
 236   (interactive "p")
 237   (if (eq arg 1)
 238       (unless (string-match "hydra-repeat$" (symbol-name last-command))
 239         (setq hydra-repeat--command last-command)
 240         (setq hydra-repeat--prefix-arg last-prefix-arg))
 241     (setq hydra-repeat--prefix-arg arg))
 242   (setq current-prefix-arg hydra-repeat--prefix-arg)
 243   (funcall hydra-repeat--command))
 244
 245 ;;* Misc internals
 246 (defvar hydra-last nil
 247   "The result of the last `hydra-set-transient-map' call.")
 248
 249 (defun hydra--callablep (x)
 250   "Test if X is callable."
 251   (or (functionp x)
 252       (and (consp x)
 253            (memq (car x) '(function quote)))))
 254
 255 (defun hydra--make-callable (x)
 256   "Generate a callable symbol from X.
 257 If X is a function symbol or a lambda, return it.  Otherwise, it
 258 should be a single statement.  Wrap it in an interactive lambda."
 259   (if (or (symbolp x) (functionp x))
 260       x
 261     `(lambda ()
 262        (interactive)
 263        ,x)))
 264
 265 (defun hydra-plist-get-default (plist prop default)
 266   "Extract a value from a property list.
 267 PLIST is a property list, which is a list of the form
 268 \(PROP1 VALUE1 PROP2 VALUE2...).
 269
 270 Return the value corresponding to PROP, or DEFAULT if PROP is not
 271 one of the properties on the list."
 272   (if (memq prop plist)
 273       (plist-get plist prop)
 274     default))
 275
 276 (defun hydra--head-property (h prop &optional default)
 277   "Return for Hydra head H the value of property PROP.
 278 Return DEFAULT if PROP is not in H."
 279   (hydra-plist-get-default (cl-cdddr h) prop default))
 280
 281 (defun hydra--aggregate-color (head-color body-color)
 282   "Return the resulting head color for HEAD-COLOR and BODY-COLOR."
 283   (cond ((eq head-color 'red)
 284          (cl-case body-color
 285            (red 'red)
 286            (blue 'red)
 287            (amaranth 'amaranth)
 288            (pink 'pink)
 289            (cyan 'amaranth)))
 290         ((eq head-color 'blue)
 291          (cl-case body-color
 292            (red 'blue)
 293            (blue 'blue)
 294            (amaranth 'teal)
 295            (pink 'blue)
 296            (cyan 'teal)))
 297         (t
 298          (error "Can't aggregate head %S to body %S"
 299                 head-color body-color))))
 300
 301 (defun hydra--head-color (h body)
 302   "Return the color of a Hydra head H with BODY."
 303   (let* ((exit (hydra--head-property h :exit 'default))
 304          (color (hydra--head-property h :color))
 305          (foreign-keys (hydra--body-foreign-keys body))
 306          (head-color
 307           (cond ((eq exit 'default)
 308                  (cl-case color
 309                    (blue 'blue)
 310                    (red 'red)
 311                    (t
 312                     (unless (null color)
 313                       (error "Use only :blue or :red for heads: %S" h)))))
 314                 ((null exit)
 315                  (if color
 316                      (error "Don't mix :color and :exit - they are aliases: %S" h)
 317                    (cl-case foreign-keys
 318                      (run 'pink)
 319                      (warn 'amaranth)
 320                      (t 'red))))
 321                 ((eq exit t)
 322                  (if color
 323                      (error "Don't mix :color and :exit - they are aliases: %S" h)
 324                    'blue))
 325                 (t
 326                  (error "Unknown :exit %S" exit)))))
 327     (cond ((null (cadr h))
 328            (when head-color
 329              (hydra--complain
 330               "Doubly specified blue head - nil cmd is already blue: %S" h))
 331            'blue)
 332           ((null head-color)
 333            (hydra--body-color body))
 334           ((null foreign-keys)
 335            head-color)
 336           ((eq foreign-keys 'run)
 337            (if (eq head-color 'red)
 338                'pink
 339              'blue))
 340           ((eq foreign-keys 'warn)
 341            (if (memq head-color '(red amaranth))
 342                'amaranth
 343              'teal))
 344           (t
 345            (error "Unexpected %S %S" h body)))))
 346
 347 (defun hydra--body-foreign-keys (body)
 348   "Return what BODY does with a non-head binding."
 349   (or
 350    (plist-get (cddr body) :foreign-keys)
 351    (let ((color (plist-get (cddr body) :color)))
 352      (cl-case color
 353        ((amaranth teal) 'warn)
 354        (pink 'run)))))
 355
 356 (defun hydra--body-color (body)
 357   "Return the color of BODY.
 358 BODY is the second argument to `defhydra'"
 359   (let ((color (plist-get (cddr body) :color))
 360         (exit (plist-get (cddr body) :exit))
 361         (foreign-keys (plist-get (cddr body) :foreign-keys)))
 362     (cond ((eq foreign-keys 'warn)
 363            (if exit 'teal 'amaranth))
 364           ((eq foreign-keys 'run) 'pink)
 365           (exit 'blue)
 366           (color color)
 367           (t 'red))))
 368
 369 (defun hydra--face (h body)
 370   "Return the face for a Hydra head H with BODY."
 371   (cl-case (hydra--head-color h body)
 372     (blue 'hydra-face-blue)
 373     (red 'hydra-face-red)
 374     (amaranth 'hydra-face-amaranth)
 375     (pink 'hydra-face-pink)
 376     (teal 'hydra-face-teal)
 377     (t (error "Unknown color for %S" h))))
 378
 379 (defvar hydra--input-method-function nil
 380   "Store overridden `input-method-function' here.")
 381
 382 (defun hydra-default-pre ()
 383   "Default setup that happens in each head before :pre."
 384   (when (eq input-method-function 'key-chord-input-method)
 385     (unless hydra--input-method-function
 386       (setq hydra--input-method-function input-method-function)
 387       (setq input-method-function nil))))
 388
 389 (defun hydra-cleanup ()
 390   "Clean up after a Hydra."
 391   (when hydra--input-method-function
 392     (setq input-method-function hydra--input-method-function)
 393     (setq hydra--input-method-function nil))
 394   (when (window-live-p lv-wnd)
 395     (let ((buf (window-buffer lv-wnd)))
 396       (delete-window lv-wnd)
 397       (kill-buffer buf))))
 398
 399 (defun hydra-keyboard-quit ()
 400   "Quitting function similar to `keyboard-quit'."
 401   (interactive)
 402   (hydra-disable)
 403   (hydra-cleanup)
 404   (cancel-timer hydra-timer)
 405   (unless hydra-lv
 406     (message ""))
 407   nil)
 408
 409 (defun hydra-disable ()
 410   "Disable the current Hydra."
 411   (cond
 412     ;; Emacs 25
 413     ((functionp hydra-last)
 414      (funcall hydra-last))
 415
 416     ;; Emacs 24.3 or older
 417     ((< emacs-minor-version 4)
 418      (setq emulation-mode-map-alists
 419            (cl-remove-if
 420             (lambda (x)
 421               (and (consp x)
 422                    (consp (car x))
 423                    (equal (cdar x) hydra-curr-map)))
 424             emulation-mode-map-alists)))
 425
 426     ;; Emacs 24.4.1
 427     (t
 428      (setq overriding-terminal-local-map nil))))
 429
 430 (defun hydra--unalias-var (str prefix)
 431   "Return the symbol named STR if it's bound as a variable.
 432 Otherwise, add PREFIX to the symbol name."
 433   (let ((sym (intern-soft str)))
 434     (if (boundp sym)
 435         sym
 436       (intern (concat prefix "/" str)))))
 437
 438 (defun hydra--hint (body heads)
 439   "Generate a hint for the echo area.
 440 BODY, and HEADS are parameters to `defhydra'."
 441   (let (alist)
 442     (dolist (h heads)
 443       (let ((val (assoc (cadr h) alist))
 444             (pstr (hydra-fontify-head h body)))
 445         (unless (null (cl-caddr h))
 446           (if val
 447               (setf (cadr val)
 448                     (concat (cadr val) " " pstr))
 449             (push
 450              (cons (cadr h)
 451                    (cons pstr (cl-caddr h)))
 452              alist)))))
 453     (mapconcat
 454      (lambda (x)
 455        (format
 456         (if (> (length (cdr x)) 0)
 457             (concat "[%s]: " (cdr x))
 458           "%s")
 459         (car x)))
 460      (nreverse (mapcar #'cdr alist))
 461      ", ")))
 462
 463 (defvar hydra-fontify-head-function nil
 464   "Possible replacement for `hydra-fontify-head-default'.")
 465
 466 (defun hydra-fontify-head-default (head body)
 467   "Produce a pretty string from HEAD and BODY.
 468 HEAD's binding is returned as a string with a colored face."
 469   (propertize (car head) 'face (hydra--face head body)))
 470
 471 (defun hydra-fontify-head-greyscale (head body)
 472   "Produce a pretty string from HEAD and BODY.
 473 HEAD's binding is returned as a string wrapped with [] or {}."
 474   (let ((color (hydra--head-color head body)))
 475     (format
 476      (if (eq color 'blue)
 477          "[%s]"
 478        "{%s}") (car head))))
 479
 480 (defun hydra-fontify-head (head body)
 481   "Produce a pretty string from HEAD and BODY."
 482   (funcall (or hydra-fontify-head-function 'hydra-fontify-head-default)
 483            head body))
 484
 485 (defun hydra--format (_name body docstring heads)
 486   "Generate a `format' statement from STR.
 487 \"%`...\" expressions are extracted into \"%S\".
 488 _NAME, BODY, DOCSTRING and HEADS are parameters of `defhydra'.
 489 The expressions can be auto-expanded according to NAME."
 490   (setq docstring (replace-regexp-in-string "\\^" "" docstring))
 491   (let ((rest (hydra--hint body heads))
 492         (start 0)
 493         varlist
 494         offset)
 495     (while (setq start
 496                  (string-match
 497                   "\\(?:%\\( ?-?[0-9]*s?\\)\\(`[a-z-A-Z/0-9]+\\|(\\)\\)\\|\\(?:_\\( ?-?[0-9]*\\)\\([a-z-A-Z~.,;:0-9/|?<>={}]+\\)_\\)"
 498                   docstring start))
 499       (cond ((eq ?_ (aref (match-string 0 docstring) 0))
 500              (let* ((key (match-string 4 docstring))
 501                     (head (assoc key heads)))
 502                (if head
 503                    (progn
 504                      (push (hydra-fontify-head head body) varlist)
 505                      (setq docstring
 506                            (replace-match
 507                             (or
 508                              hydra-key-format-spec
 509                              (concat "%" (match-string 3 docstring) "s"))
 510                             t nil docstring)))
 511                  (error "Unrecognized key: _%s_" key))))
 512
 513             (t
 514              (let* ((varp (if (eq ?` (aref (match-string 2 docstring) 0)) 1 0))
 515                     (spec (match-string 1 docstring))
 516                     (lspec (length spec)))
 517                (setq offset
 518                      (with-temp-buffer
 519                        (insert (substring docstring (+ 1 start varp
 520                                                        (length spec))))
 521                        (goto-char (point-min))
 522                        (push (read (current-buffer)) varlist)
 523                        (- (point) (point-min))))
 524                (when (or (zerop lspec)
 525                          (/= (aref spec (1- (length spec))) ?s))
 526                  (setq spec (concat spec "S")))
 527                (setq docstring
 528                      (concat
 529                       (substring docstring 0 start)
 530                       "%" spec
 531                       (substring docstring (+ start offset 1 lspec varp))))))))
 532     (if (eq ?\n (aref docstring 0))
 533         `(concat (format ,(substring docstring 1) ,@(nreverse varlist))
 534                  ,rest)
 535       `(format ,(concat docstring ": " rest ".")))))
 536
 537 (defun hydra--message (name body docstring heads)
 538   "Generate code to display the hint in the preferred echo area.
 539 Set `hydra-lv' to choose the echo area.
 540 NAME, BODY, DOCSTRING, and HEADS are parameters of `defhydra'."
 541   (let ((format-expr (hydra--format name body docstring heads)))
 542     `(if hydra-lv
 543          (lv-message ,format-expr)
 544        (message ,format-expr))))
 545
 546 (defun hydra--complain (format-string &rest args)
 547   "Forward to (`message' FORMAT-STRING ARGS) unless `hydra-verbose' is nil."
 548   (when hydra-verbose
 549     (apply #'warn format-string args)))
 550
 551 (defun hydra--doc (body-key body-name heads)
 552   "Generate a part of Hydra docstring.
 553 BODY-KEY is the body key binding.
 554 BODY-NAME is the symbol that identifies the Hydra.
 555 HEADS is a list of heads."
 556   (format
 557    "Create a hydra with %s body and the heads:\n\n%s\n\n%s"
 558    (if body-key
 559        (format "a \"%s\"" body-key)
 560      "no")
 561    (mapconcat
 562     (lambda (x)
 563       (format "\"%s\":    `%S'" (car x) (cadr x)))
 564     heads ",\n")
 565    (format "The body can be accessed via `%S'." body-name)))
 566
 567 (defun hydra--make-defun (name body doc head
 568                           keymap body-pre body-post &optional other-post)
 569   "Make a defun wrapper, using NAME, BODY, DOC, HEAD, and KEYMAP.
 570 NAME and BODY are the arguments to `defhydra'.
 571 DOC was generated with `hydra--doc'.
 572 HEAD is one of the HEADS passed to `defhydra'.
 573 BODY-PRE and BODY-POST are pre-processed in `defhydra'.
 574 OTHER-POST is an optional extension to the :post key of BODY."
 575   (let ((name (hydra--head-name head name body))
 576         (cmd (when (car head)
 577                (hydra--make-callable
 578                 (cadr head))))
 579         (color (when (car head)
 580                  (hydra--head-color head body)))
 581         (doc (if (car head)
 582                  (format "%s\n\nCall the head: `%S'." doc (cadr head))
 583                doc))
 584         (hint (intern (format "%S/hint" name)))
 585         (body-color (hydra--body-color body))
 586         (body-timeout (plist-get body :timeout)))
 587     `(defun ,name ()
 588        ,doc
 589        (interactive)
 590        (hydra-default-pre)
 591        ,@(when body-pre (list body-pre))
 592        (hydra-disable)
 593        ,@(when (memq color '(blue teal)) '((hydra-cleanup)))
 594        (catch 'hydra-disable
 595          ,@(delq nil
 596                  (if (memq color '(blue teal))
 597                      `(,(when cmd `(call-interactively #',cmd))
 598                         ,body-post)
 599                    `(,(when cmd
 600                             `(condition-case err
 601                                  (prog1 t
 602                                    (call-interactively #',cmd))
 603                                ((quit error)
 604                                 (message "%S" err)
 605                                 (unless hydra-lv
 606                                   (sit-for 0.8))
 607                                 nil)))
 608                       (when hydra-is-helpful
 609                         (,hint))
 610                       (setq hydra-last
 611                             (hydra-set-transient-map
 612                              (setq hydra-curr-map ',keymap)
 613                              t
 614                              ,(if (and
 615                                    (not (memq body-color
 616                                               '(amaranth pink teal)))
 617                                    body-post)
 618                                   `(lambda () (hydra-cleanup) ,body-post)
 619                                   `(lambda () (hydra-cleanup)))))
 620                       ,(or other-post
 621                            (when body-timeout
 622                              (list 'hydra-timeout
 623                                    body-timeout
 624                                    (when body-post
 625                                      (hydra--make-callable body-post))))))))))))
 626
 627 (defun hydra-pink-fallback ()
 628   "On intercepting a non-head, try to run it."
 629   (let ((keys (this-command-keys))
 630         kb)
 631     (when (equal keys [backspace])
 632       (setq keys "\7f"))
 633     (setq kb (key-binding keys))
 634     (if kb
 635         (if (commandp kb)
 636             (condition-case err
 637                 (call-interactively kb)
 638               ((quit error)
 639                (message "%S" err)
 640                (unless hydra-lv
 641                  (sit-for 0.8))))
 642           (message "Pink Hydra can't currently handle prefixes, continuing"))
 643       (message "Pink Hydra could not resolve: %S" keys))))
 644
 645 (defun hydra--modify-keymap (keymap def)
 646   "In KEYMAP, add DEF to each sub-keymap."
 647   (cl-labels
 648       ((recur (map)
 649          (if (atom map)
 650              map
 651            (if (eq (car map) 'keymap)
 652                (cons 'keymap
 653                      (cons
 654                       def
 655                       (recur (cdr map))))
 656              (cons
 657               (recur (car map))
 658               (recur (cdr map)))))))
 659     (recur keymap)))
 660
 661 (defun hydra--handle-nonhead (keymap name body heads)
 662   "Setup KEYMAP for intercepting non-head bindings.
 663 NAME, BODY and HEADS are parameters to `defhydra'."
 664   (let ((body-color (hydra--body-color body))
 665         (body-post (plist-get (cddr body) :post)))
 666     (if body-post
 667         (hydra--make-funcall body-post)
 668       (when hydra-keyboard-quit
 669         (define-key keymap hydra-keyboard-quit #'hydra-keyboard-quit)))
 670     (when (memq body-color '(amaranth pink teal))
 671       (if (cl-some (lambda (h)
 672                      (memq (hydra--head-color h body) '(blue teal)))
 673                    heads)
 674           (progn
 675             (setcdr
 676              keymap
 677              (cdr
 678               (hydra--modify-keymap
 679                keymap
 680                (cons t
 681                      `(lambda ()
 682                         (interactive)
 683                         ,(cond
 684                           ((memq body-color '(amaranth teal))
 685                            '(message "An amaranth Hydra can only exit through a blue head"))
 686                           (t
 687                            '(hydra-pink-fallback)))
 688                         (hydra-set-transient-map hydra-curr-map t)
 689                         (when hydra-is-helpful
 690                           (unless hydra-lv
 691                             (sit-for 0.8))
 692                           (,(intern (format "%S/hint" name))))))))))
 693         (unless (eq body-color 'teal)
 694           (error
 695            "An %S Hydra must have at least one blue head in order to exit"
 696            body-color))))))
 697
 698 (defun hydra--head-name (h name body)
 699   "Return the symbol for head H of hydra with NAME and BODY."
 700   (let ((str (format "%S/%s" name
 701                      (if (symbolp (cadr h))
 702                          (cadr h)
 703                        (concat "lambda-" (car h))))))
 704     (when (and (memq (hydra--head-color h body) '(blue teal))
 705                (not (memq (cadr h) '(body nil))))
 706       (setq str (concat str "-and-exit")))
 707     (intern str)))
 708
 709 (defun hydra--delete-duplicates (heads)
 710   "Return HEADS without entries that have the same CMD part.
 711 In duplicate HEADS, :cmd-name is modified to whatever they duplicate."
 712   (let ((ali '(((hydra-repeat . red) . hydra-repeat)))
 713         res entry)
 714     (dolist (h heads)
 715       (if (setq entry (assoc (cons (cadr h)
 716                                    (hydra--head-color h '(nil nil)))
 717                              ali))
 718           (setf (cl-cdddr h) (plist-put (cl-cdddr h) :cmd-name (cdr entry)))
 719         (push (cons (cons (cadr h)
 720                           (hydra--head-color h '(nil nil)))
 721                     (plist-get (cl-cdddr h) :cmd-name))
 722               ali)
 723         (push h res)))
 724     (nreverse res)))
 725
 726 (defun hydra--pad (lst n)
 727   "Pad LST with nil until length N."
 728   (let ((len (length lst)))
 729     (if (= len n)
 730         lst
 731       (append lst (make-list (- n len) nil)))))
 732
 733 (defun hydra--matrix (lst rows cols)
 734   "Create a matrix from elements of LST.
 735 The matrix size is ROWS times COLS."
 736   (let ((ls (copy-sequence lst))
 737         res)
 738     (dotimes (_c cols)
 739       (push (hydra--pad (hydra-multipop ls rows) rows) res))
 740     (nreverse res)))
 741
 742 (defun hydra--cell (fstr names)
 743   "Format a rectangular cell based on FSTR and NAMES.
 744 FSTR is a format-style string with two string inputs: one for the
 745 doc and one for the symbol name.
 746 NAMES is a list of variables."
 747   (let ((len (cl-reduce
 748               (lambda (acc it) (max (length (symbol-name it)) acc))
 749               names
 750               :initial-value 0)))
 751     (mapconcat
 752      (lambda (sym)
 753        (if sym
 754            (format fstr
 755                    (documentation-property sym 'variable-documentation)
 756                    (let ((name (symbol-name sym)))
 757                      (concat name (make-string (- len (length name)) ?^)))
 758                    sym)
 759          ""))
 760      names
 761      "\n")))
 762
 763 (defun hydra--vconcat (strs &optional joiner)
 764   "Glue STRS vertically.  They must be the same height.
 765 JOINER is a function similar to `concat'."
 766   (setq joiner (or joiner #'concat))
 767   (mapconcat
 768    (lambda (s)
 769      (if (string-match " +$" s)
 770          (replace-match "" nil nil s)
 771        s))
 772    (apply #'cl-mapcar joiner
 773           (mapcar
 774            (lambda (s) (split-string s "\n"))
 775            strs))
 776    "\n"))
 777
 778 (defcustom hydra-cell-format "% -20s %% -8`%s"
 779   "The default format for docstring cells."
 780   :type 'string)
 781
 782 (defun hydra--table (names rows cols &optional cell-formats)
 783   "Format a `format'-style table from variables in NAMES.
 784 The size of the table is ROWS times COLS.
 785 CELL-FORMATS are `format' strings for each column.
 786 If CELL-FORMATS is a string, it's used for all columns.
 787 If CELL-FORMATS is nil, `hydra-cell-format' is used for all columns."
 788   (setq cell-formats
 789         (cond ((null cell-formats)
 790                (make-list cols hydra-cell-format))
 791               ((stringp cell-formats)
 792                (make-list cols cell-formats))
 793               (t
 794                cell-formats)))
 795   (hydra--vconcat
 796    (cl-mapcar
 797     #'hydra--cell
 798     cell-formats
 799     (hydra--matrix names rows cols))
 800    (lambda (&rest x)
 801      (mapconcat #'identity x "    "))))
 802
 803 (defun hydra-reset-radios (names)
 804   "Set varibles NAMES to their defaults.
 805 NAMES should be defined by `defhydradio' or similar."
 806   (dolist (n names)
 807     (set n (aref (get n 'range) 0))))
 808
 809 (defvar hydra-timer (timer-create)
 810   "Timer for `hydra-timeout'.")
 811
 812 (defun hydra-timeout (secs &optional function)
 813   "In SECS seconds call FUNCTION, then function `hydra-keyboard-quit'.
 814 Cancel the previous `hydra-timeout'."
 815   (cancel-timer hydra-timer)
 816   (setq hydra-timer (timer-create))
 817   (timer-set-time hydra-timer
 818                   (timer-relative-time (current-time) secs))
 819   (timer-set-function
 820    hydra-timer
 821    `(lambda ()
 822       ,(when function
 823              `(funcall ,function))
 824       (hydra-keyboard-quit)))
 825   (timer-activate hydra-timer))
 826
 827 ;;* Macros
 828 ;;;###autoload
 829 (defmacro defhydra (name body &optional docstring &rest heads)
 830   "Create a Hydra - a family of functions with prefix NAME.
 831
 832 NAME should be a symbol, it will be the prefix of all functions
 833 defined here.
 834
 835 BODY has the format:
 836
 837     (BODY-MAP BODY-KEY &rest BODY-PLIST)
 838
 839 DOCSTRING will be displayed in the echo area to identify the
 840 Hydra.  When DOCSTRING starts with a newline, special Ruby-style
 841 substitution will be performed by `hydra--format'.
 842
 843 Functions are created on basis of HEADS, each of which has the
 844 format:
 845
 846     (KEY CMD &optional HINT &rest PLIST)
 847
 848 BODY-MAP is a keymap; `global-map' is used quite often.  Each
 849 function generated from HEADS will be bound in BODY-MAP to
 850 BODY-KEY + KEY (both are strings passed to `kbd'), and will set
 851 the transient map so that all following heads can be called
 852 though KEY only. BODY-KEY can be an empty string.
 853
 854 CMD is a callable expression: either an interactive function
 855 name, or an interactive lambda, or a single sexp (it will be
 856 wrapped in an interactive lambda).
 857
 858 HINT is a short string that identifies its head.  It will be
 859 printed beside KEY in the echo erea if `hydra-is-helpful' is not
 860 nil.  If you don't even want the KEY to be printed, set HINT
 861 explicitly to nil.
 862
 863 The heads inherit their PLIST from BODY-PLIST and are allowed to
 864 override some keys.  The keys recognized are :exit and :bind.
 865 :exit can be:
 866
 867 - nil (default): this head will continue the Hydra state.
 868 - t: this head will stop the Hydra state.
 869
 870 :bind can be:
 871 - nil: this head will not be bound in BODY-MAP.
 872 - a lambda taking KEY and CMD used to bind a head.
 873
 874 It is possible to omit both BODY-MAP and BODY-KEY if you don't
 875 want to bind anything.  In that case, typically you will bind the
 876 generated NAME/body command.  This command is also the return
 877 result of `defhydra'."
 878   (declare (indent defun))
 879   (cond ((stringp docstring))
 880         ((and (consp docstring)
 881               (memq (car docstring) '(hydra--table concat format)))
 882          (setq docstring (concat "\n" (eval docstring))))
 883         (t
 884          (setq heads (cons docstring heads))
 885          (setq docstring "hydra")))
 886   (when (keywordp (car body))
 887     (setq body (cons nil (cons nil body))))
 888   (let* ((keymap (copy-keymap hydra-base-map))
 889          (body-name (intern (format "%S/body" name)))
 890          (body-key (cadr body))
 891          (body-plist (cddr body))
 892          (body-map (or (car body)
 893                        (plist-get body-plist :bind)))
 894          (body-pre (plist-get body-plist :pre))
 895          (body-body-pre (plist-get body-plist :body-pre))
 896          (body-post (plist-get body-plist :post)))
 897     (hydra--make-funcall body-post)
 898     (when body-post
 899       (setq heads (cons (list hydra-keyboard-quit #'hydra-keyboard-quit nil :exit t)
 900                         heads)))
 901     (dolist (h heads)
 902       (let ((len (length h)))
 903         (cond ((< len 2)
 904                (error "Each head should have at least two items: %S" h))
 905               ((= len 2)
 906                (setcdr (cdr h)
 907                        (list
 908                         (hydra-plist-get-default body-plist :hint "")))
 909                (setcdr (nthcdr 2 h)
 910                        (list :cmd-name (hydra--head-name h name body))))
 911               (t
 912                (let ((hint (cl-caddr h)))
 913                  (unless (or (null hint)
 914                              (stringp hint))
 915                    (setcdr (cdr h) (cons
 916                                     (hydra-plist-get-default body-plist :hint "")
 917                                     (cddr h))))
 918                  (setcdr (cddr h)
 919                          `(:cmd-name
 920                            ,(hydra--head-name h name body)
 921                            ,@(cl-cdddr h))))))))
 922     (let ((doc (hydra--doc body-key body-name heads))
 923           (heads-nodup (hydra--delete-duplicates heads)))
 924       (mapc
 925        (lambda (x)
 926          (define-key keymap (kbd (car x))
 927            (plist-get (cl-cdddr x) :cmd-name)))
 928        heads)
 929       (hydra--make-funcall body-pre)
 930       (hydra--make-funcall body-body-pre)
 931       (hydra--handle-nonhead keymap name body heads)
 932       `(progn
 933          ;; create defuns
 934          ,@(mapcar
 935             (lambda (head)
 936               (hydra--make-defun name body doc head keymap
 937                                  body-pre body-post))
 938             heads-nodup)
 939          ;; free up keymap prefix
 940          ,@(unless (or (null body-key)
 941                        (null body-map)
 942                        (hydra--callablep body-map))
 943                    `((unless (keymapp (lookup-key ,body-map (kbd ,body-key)))
 944                        (define-key ,body-map (kbd ,body-key) nil))))
 945          ;; bind keys
 946          ,@(delq nil
 947                  (mapcar
 948                   (lambda (head)
 949                     (let ((name (hydra--head-property head :cmd-name)))
 950                       (when (and (cadr head)
 951                                  (not (eq (cadr head) 'hydra-keyboard-quit))
 952                                  (or body-key body-map))
 953                         (let ((bind (hydra--head-property head :bind body-map))
 954                               (final-key
 955                                (if body-key
 956                                    (vconcat (kbd body-key) (kbd (car head)))
 957                                  (kbd (car head)))))
 958                           (cond ((null bind) nil)
 959                                 ((hydra--callablep bind)
 960                                  `(funcall ,bind ,final-key (function ,name)))
 961                                 ((and (symbolp bind)
 962                                       (if (boundp bind)
 963                                           (keymapp (symbol-value bind))
 964                                         t))
 965                                  `(define-key ,bind ,final-key (function ,name)))
 966                                 (t
 967                                  (error "Invalid :bind property `%S' for head %S" bind  head)))))))
 968                   heads))
 969          (defun ,(intern (format "%S/hint" name)) ()
 970            ,(hydra--message name body docstring heads))
 971          ,(hydra--make-defun
 972            name body doc '(nil body)
 973            keymap
 974            (or body-body-pre body-pre) body-post
 975            '(setq prefix-arg current-prefix-arg))))))
 976
 977 (defmacro hydra--make-funcall (sym)
 978   "Transform SYM into a `funcall' that calls it."
 979   `(when (and ,sym (symbolp ,sym))
 980      (setq ,sym `(funcall #',,sym))))
 981
 982 (defmacro defhydradio (name _body &rest heads)
 983   "Create radios with prefix NAME.
 984 _BODY specifies the options; there are none currently.
 985 HEADS have the format:
 986
 987     (TOGGLE-NAME &optional VALUE DOC)
 988
 989 TOGGLE-NAME will be used along with NAME to generate a variable
 990 name and a function that cycles it with the same name.  VALUE
 991 should be an array.  The first element of VALUE will be used to
 992 inialize the variable.
 993 VALUE defaults to [nil t].
 994 DOC defaults to TOGGLE-NAME split and capitalized."
 995   (declare (indent defun))
 996   `(progn
 997      ,@(apply #'append
 998               (mapcar (lambda (h)
 999                         (hydra--radio name h))
1000                       heads))
1001      (defvar ,(intern (format "%S/names" name))
1002        ',(mapcar (lambda (h) (intern (format "%S/%S" name (car h))))
1003                  heads))))
1004
1005 (defmacro hydra-multipop (lst n)
1006   "Return LST's first N elements while removing them."
1007   `(if (<= (length ,lst) ,n)
1008        (prog1 ,lst
1009          (setq ,lst nil))
1010      (prog1 ,lst
1011        (setcdr
1012         (nthcdr (1- ,n) (prog1 ,lst (setq ,lst (nthcdr ,n ,lst))))
1013         nil))))
1014
1015 (defun hydra--radio (parent head)
1016   "Generate a hydradio with PARENT from HEAD."
1017   (let* ((name (car head))
1018          (full-name (intern (format "%S/%S" parent name)))
1019          (doc (cadr head))
1020          (val (or (cl-caddr head) [nil t])))
1021     `((defvar ,full-name ,(hydra--quote-maybe (aref val 0)) ,doc)
1022       (put ',full-name 'range ,val)
1023       (defun ,full-name ()
1024         (hydra--cycle-radio ',full-name)))))
1025
1026 (defun hydra--quote-maybe (x)
1027   "Quote X if it's a symbol."
1028   (cond ((null x)
1029          nil)
1030         ((symbolp x)
1031          (list 'quote x))
1032         (t
1033          x)))
1034
1035 (defun hydra--cycle-radio (sym)
1036   "Set SYM to the next value in its range."
1037   (let* ((val (symbol-value sym))
1038          (range (get sym 'range))
1039          (i 0)
1040          (l (length range)))
1041     (setq i (catch 'done
1042               (while (< i l)
1043                 (if (equal (aref range i) val)
1044                     (throw 'done (1+ i))
1045                   (cl-incf i)))
1046               (error "Val not in range for %S" sym)))
1047     (set sym
1048          (aref range
1049                (if (>= i l)
1050                    0
1051                  i)))))
1052
1053 (provide 'hydra)
1054
1055 ;;; Local Variables:
1056 ;;; outline-regexp: ";;\\*+"
1057 ;;; End:
1058
1059 ;;; hydra.el ends here