code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular in-buffer completion framework
   2
   3 ;; Copyright (C) 2009-2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; Version: 0.6
   8 ;; Keywords: abbrev, convenience, matching
   9 ;; URL: http://company-mode.github.com/
  10 ;; Compatibility: GNU Emacs 22.x, GNU Emacs 23.x, GNU Emacs 24.x
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (case command
  52 ;;     (prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;; Known Issues:
  62 ;; When point is at the very end of the buffer, the pseudo-tooltip appears very
  63 ;; wrong, unless company is allowed to temporarily insert a fake newline.
  64 ;; This behavior is enabled by `company-end-of-buffer-workaround'.
  65 ;;
  66 ;;; Change Log:
  67 ;;
  68 ;; See NEWS.md in the repository.
  69
  70 ;;; Code:
  71
  72 (eval-when-compile (require 'cl))
  73
  74 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  75 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  76 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  77 (add-to-list 'debug-ignored-errors "^Company not ")
  78 (add-to-list 'debug-ignored-errors "^No candidate number ")
  79 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  80 (add-to-list 'debug-ignored-errors "^No other back-end$")
  81
  82 (defgroup company nil
  83   "Extensible inline text completion mechanism"
  84   :group 'abbrev
  85   :group 'convenience
  86   :group 'matching)
  87
  88 (defface company-tooltip
  89   '((t :background "yellow"
  90        :foreground "black"))
  91   "Face used for the tool tip."
  92   :group 'company)
  93
  94 (defface company-tooltip-selection
  95   '((default :inherit company-tooltip)
  96     (((class color) (min-colors 88)) (:background "orange1"))
  97     (t (:background "green")))
  98   "Face used for the selection in the tool tip."
  99   :group 'company)
 100
 101 (defface company-tooltip-mouse
 102   '((default :inherit highlight))
 103   "Face used for the tool tip item under the mouse."
 104   :group 'company)
 105
 106 (defface company-tooltip-common
 107   '((t :inherit company-tooltip
 108        :foreground "red"))
 109   "Face used for the common completion in the tool tip."
 110   :group 'company)
 111
 112 (defface company-tooltip-common-selection
 113   '((t :inherit company-tooltip-selection
 114        :foreground "red"))
 115   "Face used for the selected common completion in the tool tip."
 116   :group 'company)
 117
 118 (defface company-preview
 119   '((t :background "blue4"
 120        :foreground "wheat"))
 121   "Face used for the completion preview."
 122   :group 'company)
 123
 124 (defface company-preview-common
 125   '((t :inherit company-preview
 126        :foreground "red"))
 127   "Face used for the common part of the completion preview."
 128   :group 'company)
 129
 130 (defface company-preview-search
 131   '((t :inherit company-preview
 132        :background "blue1"))
 133   "Face used for the search string in the completion preview."
 134   :group 'company)
 135
 136 (defface company-echo nil
 137   "Face used for completions in the echo area."
 138   :group 'company)
 139
 140 (defface company-echo-common
 141   '((((background dark)) (:foreground "firebrick1"))
 142     (((background light)) (:background "firebrick4")))
 143   "Face used for the common part of completions in the echo area."
 144   :group 'company)
 145
 146 (defun company-frontends-set (variable value)
 147   ;; uniquify
 148   (let ((remainder value))
 149     (setcdr remainder (delq (car remainder) (cdr remainder))))
 150   (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 151        (memq 'company-pseudo-tooltip-frontend value)
 152        (error "Pseudo tooltip frontend cannot be used twice"))
 153   (and (memq 'company-preview-if-just-one-frontend value)
 154        (memq 'company-preview-frontend value)
 155        (error "Preview frontend cannot be used twice"))
 156   (and (memq 'company-echo value)
 157        (memq 'company-echo-metadata-frontend value)
 158        (error "Echo area cannot be used twice"))
 159   ;; preview must come last
 160   (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 161     (when (memq f value)
 162       (setq value (append (delq f value) (list f)))))
 163   (set variable value))
 164
 165 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 166                                company-preview-if-just-one-frontend
 167                                company-echo-metadata-frontend)
 168   "The list of active front-ends (visualizations).
 169 Each front-end is a function that takes one argument.  It is called with
 170 one of the following arguments:
 171
 172 'show: When the visualization should start.
 173
 174 'hide: When the visualization should end.
 175
 176 'update: When the data has been updated.
 177
 178 'pre-command: Before every command that is executed while the
 179 visualization is active.
 180
 181 'post-command: After every command that is executed while the
 182 visualization is active.
 183
 184 The visualized data is stored in `company-prefix', `company-candidates',
 185 `company-common', `company-selection', `company-point' and
 186 `company-search-string'."
 187   :set 'company-frontends-set
 188   :group 'company
 189   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 190                          (const :tag "echo, strip common"
 191                                 company-echo-strip-common-frontend)
 192                          (const :tag "show echo meta-data in echo"
 193                                 company-echo-metadata-frontend)
 194                          (const :tag "pseudo tooltip"
 195                                 company-pseudo-tooltip-frontend)
 196                          (const :tag "pseudo tooltip, multiple only"
 197                                 company-pseudo-tooltip-unless-just-one-frontend)
 198                          (const :tag "preview" company-preview-frontend)
 199                          (const :tag "preview, unique only"
 200                                 company-preview-if-just-one-frontend)
 201                          (function :tag "custom function" nil))))
 202
 203 (defcustom company-tooltip-limit 10
 204   "The maximum number of candidates in the tool tip"
 205   :group 'company
 206   :type 'integer)
 207
 208 (defcustom company-tooltip-minimum 6
 209   "The minimum height of the tool tip.
 210 If this many lines are not available, prefer to display the tooltip above."
 211   :group 'company
 212   :type 'integer)
 213
 214 (defvar company-safe-backends
 215   '((company-abbrev . "Abbrev")
 216     (company-clang . "clang")
 217     (company-css . "CSS")
 218     (company-dabbrev . "dabbrev for plain text")
 219     (company-dabbrev-code . "dabbrev for code")
 220     (company-eclim . "eclim (an Eclipse interace)")
 221     (company-elisp . "Emacs Lisp")
 222     (company-etags . "etags")
 223     (company-files . "Files")
 224     (company-gtags . "GNU Global")
 225     (company-ispell . "ispell")
 226     (company-keywords . "Programming language keywords")
 227     (company-nxml . "nxml")
 228     (company-oddmuse . "Oddmuse")
 229     (company-pysmell . "PySmell")
 230     (company-ropemacs . "ropemacs")
 231     (company-semantic . "CEDET Semantic")
 232     (company-tempo . "Tempo templates")
 233     (company-xcode . "Xcode")))
 234 (put 'company-safe-backends 'risky-local-variable t)
 235
 236 (defun company-safe-backends-p (backends)
 237   (and (consp backends)
 238        (not (dolist (backend backends)
 239               (unless (if (consp backend)
 240                           (company-safe-backends-p backend)
 241                         (assq backend company-safe-backends))
 242                 (return t))))))
 243
 244 (defun company-capf (command &optional arg &rest args)
 245   "`company-mode' back-end using `completion-at-point-functions'.
 246 Requires Emacs 24.1 or newer."
 247   (interactive (list 'interactive))
 248   (case command
 249     (interactive (company-begin-backend 'company-capf))
 250     (prefix
 251      (let ((res (run-hook-wrapped 'completion-at-point-functions
 252                                   ;; Ignore misbehaving functions.
 253                                   #'completion--capf-wrapper 'optimist)))
 254        (when (consp res)
 255          (if (> (nth 2 res) (point))
 256              'stop
 257            (buffer-substring-no-properties (nth 1 res) (point))))))
 258     (candidates
 259      (let ((res (run-hook-wrapped 'completion-at-point-functions
 260                                   ;; Ignore misbehaving functions.
 261                                   #'completion--capf-wrapper 'optimist)))
 262        (when (consp res)
 263          (all-completions arg (nth 3 res)
 264                           (plist-get (nthcdr 4 res) :predicate)))))))
 265
 266 (defcustom company-backends '(company-elisp company-nxml company-css
 267                               company-clang company-semantic company-eclim
 268                               company-xcode company-ropemacs
 269                               (company-gtags company-etags company-dabbrev-code
 270                                company-keywords)
 271                               company-oddmuse company-files company-dabbrev)
 272   "The list of active back-ends (completion engines).
 273 Each list elements can itself be a list of back-ends.  In that case their
 274 completions are merged.  Otherwise only the first matching back-end returns
 275 results.
 276
 277 `company-begin-backend' can be used to start a specific back-end,
 278 `company-other-backend' will skip to the next matching back-end in the list.
 279
 280 Each back-end is a function that takes a variable number of arguments.
 281 The first argument is the command requested from the back-end.  It is one
 282 of the following:
 283
 284 `prefix': The back-end should return the text to be completed.  It must be
 285 text immediately before `point'.  Returning nil passes control to the next
 286 back-end.  The function should return 'stop if it should complete but cannot
 287 \(e.g. if it is in the middle of a string\).  If the returned value is only
 288 part of the prefix (e.g. the part after \"->\" in C), the back-end may return a
 289 cons of prefix and prefix length, which is then used in the
 290 `company-minimum-prefix-length' test.
 291
 292 `candidates': The second argument is the prefix to be completed.  The
 293 return value should be a list of candidates that start with the prefix.
 294
 295 Optional commands:
 296
 297 `sorted': The back-end may return t here to indicate that the candidates
 298 are sorted and will not need to be sorted again.
 299
 300 `duplicates': If non-nil, company will take care of removing duplicates
 301 from the list.
 302
 303 `no-cache': Usually company doesn't ask for candidates again as completion
 304 progresses, unless the back-end returns t for this command.  The second
 305 argument is the latest prefix.
 306
 307 `meta': The second argument is a completion candidate.  The back-end should
 308 return a (short) documentation string for it.
 309
 310 `doc-buffer': The second argument is a completion candidate.
 311 The back-end should create a buffer (preferably with `company-doc-buffer'),
 312 fill it with documentation and return it.
 313
 314 `location': The second argument is a completion candidate.  The back-end can
 315 return the cons of buffer and buffer location, or of file and line
 316 number where the completion candidate was defined.
 317
 318 `require-match': If this value is t, the user is not allowed to enter anything
 319 not offering as a candidate.  Use with care!  The default value nil gives the
 320 user that choice with `company-require-match'.  Return value 'never overrides
 321 that option the other way around.
 322
 323 `init': Called once for each buffer, the back-end can check for external
 324 programs and files and load any required libraries.  Raising an error here will
 325 show up in message log once, and the backend will not be used for completion.
 326
 327 `post-completion': Called after a completion candidate has been inserted into
 328 the buffer.  The second argument is the candidate.  Can be used to modify it,
 329 e.g. to expand a snippet.
 330
 331 The back-end should return nil for all commands it does not support or
 332 does not know about.  It should also be callable interactively and use
 333 `company-begin-backend' to start itself in that case."
 334   :group 'company
 335   :type `(repeat
 336           (choice
 337            :tag "Back-end"
 338            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 339                      company-safe-backends)
 340            (symbol :tag "User defined")
 341            (repeat :tag "Merged Back-ends"
 342                    (choice :tag "Back-end"
 343                            ,@(mapcar (lambda (b)
 344                                        `(const :tag ,(cdr b) ,(car b)))
 345                                      company-safe-backends)
 346                            (symbol :tag "User defined"))))))
 347
 348 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 349
 350 (defcustom company-completion-started-hook nil
 351   "Hook run when company starts completing.
 352 The hook is called with one argument that is non-nil if the completion was
 353 started manually."
 354   :group 'company
 355   :type 'hook)
 356
 357 (defcustom company-completion-cancelled-hook nil
 358   "Hook run when company cancels completing.
 359 The hook is called with one argument that is non-nil if the completion was
 360 aborted manually."
 361   :group 'company
 362   :type 'hook)
 363
 364 (defcustom company-completion-finished-hook nil
 365   "Hook run when company successfully completes.
 366 The hook is called with the selected candidate as an argument."
 367   :group 'company
 368   :type 'hook)
 369
 370 (defcustom company-minimum-prefix-length 3
 371   "The minimum prefix length for automatic completion."
 372   :group 'company
 373   :type '(integer :tag "prefix length"))
 374
 375 (defcustom company-require-match 'company-explicit-action-p
 376   "If enabled, disallow non-matching input.
 377 This can be a function do determine if a match is required.
 378
 379 This can be overridden by the back-end, if it returns t or 'never to
 380 'require-match.  `company-auto-complete' also takes precedence over this."
 381   :group 'company
 382   :type '(choice (const :tag "Off" nil)
 383                  (function :tag "Predicate function")
 384                  (const :tag "On, if user interaction took place"
 385                         'company-explicit-action-p)
 386                  (const :tag "On" t)))
 387
 388 (defcustom company-auto-complete 'company-explicit-action-p
 389   "Determines when to auto-complete.
 390 If this is enabled, all characters from `company-auto-complete-chars' complete
 391 the selected completion.  This can also be a function."
 392   :group 'company
 393   :type '(choice (const :tag "Off" nil)
 394                  (function :tag "Predicate function")
 395                  (const :tag "On, if user interaction took place"
 396                         'company-explicit-action-p)
 397                  (const :tag "On" t)))
 398
 399 (defcustom company-auto-complete-chars '(?\  ?\( ?\) ?. ?\" ?$ ?\' ?< ?| ?!)
 400   "Determines which characters trigger an automatic completion.
 401 See `company-auto-complete'.  If this is a string, each string character causes
 402 completion.  If it is a list of syntax description characters (see
 403 `modify-syntax-entry'), all characters with that syntax auto-complete.
 404
 405 This can also be a function, which is called with the new input and should
 406 return non-nil if company should auto-complete.
 407
 408 A character that is part of a valid candidate never starts auto-completion."
 409   :group 'company
 410   :type '(choice (string :tag "Characters")
 411                  (set :tag "Syntax"
 412                       (const :tag "Whitespace" ?\ )
 413                       (const :tag "Symbol" ?_)
 414                       (const :tag "Opening parentheses" ?\()
 415                       (const :tag "Closing parentheses" ?\))
 416                       (const :tag "Word constituent" ?w)
 417                       (const :tag "Punctuation." ?.)
 418                       (const :tag "String quote." ?\")
 419                       (const :tag "Paired delimiter." ?$)
 420                       (const :tag "Expression quote or prefix operator." ?\')
 421                       (const :tag "Comment starter." ?<)
 422                       (const :tag "Comment ender." ?>)
 423                       (const :tag "Character-quote." ?/)
 424                       (const :tag "Generic string fence." ?|)
 425                       (const :tag "Generic comment fence." ?!))
 426                  (function :tag "Predicate function")))
 427
 428 (defcustom company-idle-delay .7
 429   "The idle delay in seconds until automatic completions starts.
 430 A value of nil means never complete automatically, t means complete
 431 immediately when a prefix of `company-minimum-prefix-length' is reached."
 432   :group 'company
 433   :type '(choice (const :tag "never (nil)" nil)
 434                  (const :tag "immediate (t)" t)
 435                  (number :tag "seconds")))
 436
 437 (defcustom company-begin-commands t
 438   "A list of commands following which company will start completing.
 439 If this is t, it will complete after any command.  See `company-idle-delay'.
 440
 441 Alternatively any command with a non-nil 'company-begin property is treated as
 442 if it was on this list."
 443   :group 'company
 444   :type '(choice (const :tag "Any command" t)
 445                  (const :tag "Self insert command" '(self-insert-command))
 446                  (repeat :tag "Commands" function)))
 447
 448 (defcustom company-show-numbers nil
 449   "If enabled, show quick-access numbers for the first ten candidates."
 450   :group 'company
 451   :type '(choice (const :tag "off" nil)
 452                  (const :tag "on" t)))
 453
 454 (defvar company-end-of-buffer-workaround t
 455   "Work around a visualization bug when completing at the end of the buffer.
 456 The work-around consists of adding a newline.")
 457
 458 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 459
 460 (defvar company-mode-map (make-sparse-keymap)
 461   "Keymap used by `company-mode'.")
 462
 463 (defvar company-active-map
 464   (let ((keymap (make-sparse-keymap)))
 465     (define-key keymap "\e\e\e" 'company-abort)
 466     (define-key keymap "\C-g" 'company-abort)
 467     (define-key keymap (kbd "M-n") 'company-select-next)
 468     (define-key keymap (kbd "M-p") 'company-select-previous)
 469     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 470     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 471     (define-key keymap [down-mouse-1] 'ignore)
 472     (define-key keymap [down-mouse-3] 'ignore)
 473     (define-key keymap [mouse-1] 'company-complete-mouse)
 474     (define-key keymap [mouse-3] 'company-select-mouse)
 475     (define-key keymap [up-mouse-1] 'ignore)
 476     (define-key keymap [up-mouse-3] 'ignore)
 477     (define-key keymap [return] 'company-complete-selection)
 478     (define-key keymap [tab] 'company-complete-common)
 479     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 480     (define-key keymap "\C-w" 'company-show-location)
 481     (define-key keymap "\C-s" 'company-search-candidates)
 482     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 483     (dotimes (i 10)
 484       (define-key keymap (vector (+ (aref (kbd "M-0") 0) i))
 485         `(lambda () (interactive) (company-complete-number ,i))))
 486
 487     keymap)
 488   "Keymap that is enabled during an active completion.")
 489
 490 (defvar company--disabled-backends nil)
 491
 492 (defun company-init-backend (backend)
 493   (and (symbolp backend)
 494        (not (fboundp backend))
 495        (ignore-errors (require backend nil t)))
 496
 497   (if (or (symbolp backend)
 498           (functionp backend))
 499       (condition-case err
 500           (progn
 501             (funcall backend 'init)
 502             (put backend 'company-init t))
 503         (error
 504          (put backend 'company-init 'failed)
 505          (unless (memq backend company--disabled-backends)
 506            (message "Company back-end '%s' could not be initialized:\n%s"
 507                     backend (error-message-string err)))
 508          (pushnew backend company--disabled-backends)
 509          nil))
 510     (mapc 'company-init-backend backend)))
 511
 512 (defvar company-default-lighter " company")
 513
 514 (defvar company-lighter company-default-lighter)
 515 (make-variable-buffer-local 'company-lighter)
 516
 517 ;;;###autoload
 518 (define-minor-mode company-mode
 519   "\"complete anything\"; is an in-buffer completion framework.
 520 Completion starts automatically, depending on the values
 521 `company-idle-delay' and `company-minimum-prefix-length'.
 522
 523 Completion can be controlled with the commands:
 524 `company-complete-common', `company-complete-selection', `company-complete',
 525 `company-select-next', `company-select-previous'.  If these commands are
 526 called before `company-idle-delay', completion will also start.
 527
 528 Completions can be searched with `company-search-candidates' or
 529 `company-filter-candidates'.  These can be used while completion is
 530 inactive, as well.
 531
 532 The completion data is retrieved using `company-backends' and displayed using
 533 `company-frontends'.  If you want to start a specific back-end, call it
 534 interactively or use `company-begin-backend'.
 535
 536 regular keymap (`company-mode-map'):
 537
 538 \\{company-mode-map}
 539 keymap during active completions (`company-active-map'):
 540
 541 \\{company-active-map}"
 542   nil company-lighter company-mode-map
 543   (if company-mode
 544       (progn
 545         (add-hook 'pre-command-hook 'company-pre-command nil t)
 546         (add-hook 'post-command-hook 'company-post-command nil t)
 547         (mapc 'company-init-backend company-backends))
 548     (remove-hook 'pre-command-hook 'company-pre-command t)
 549     (remove-hook 'post-command-hook 'company-post-command t)
 550     (company-cancel)
 551     (kill-local-variable 'company-point)))
 552
 553 (define-globalized-minor-mode global-company-mode company-mode
 554   (lambda () (unless (or noninteractive (eq (aref (buffer-name) 0) ?\s))
 555           (company-mode 1))))
 556
 557 (defsubst company-assert-enabled ()
 558   (unless company-mode
 559     (company-uninstall-map)
 560     (error "Company not enabled")))
 561
 562 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 563
 564 (defvar company-my-keymap nil)
 565 (make-variable-buffer-local 'company-my-keymap)
 566
 567 (defvar company-emulation-alist '((t . nil)))
 568
 569 (defsubst company-enable-overriding-keymap (keymap)
 570   (company-uninstall-map)
 571   (setq company-my-keymap keymap))
 572
 573 (defun company-ensure-emulation-alist ()
 574   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 575     (setq emulation-mode-map-alists
 576           (cons 'company-emulation-alist
 577                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 578
 579 (defun company-install-map ()
 580   (unless (or (cdar company-emulation-alist)
 581               (null company-my-keymap))
 582     (setf (cdar company-emulation-alist) company-my-keymap)))
 583
 584 (defun company-uninstall-map ()
 585   (setf (cdar company-emulation-alist) nil))
 586
 587 ;; Hack:
 588 ;; Emacs calculates the active keymaps before reading the event.  That means we
 589 ;; cannot change the keymap from a timer.  So we send a bogus command.
 590 (defun company-ignore ()
 591   (interactive)
 592   (setq this-command last-command))
 593
 594 (global-set-key '[31415926] 'company-ignore)
 595
 596 (defun company-input-noop ()
 597   (push 31415926 unread-command-events))
 598
 599 ;; Hack:
 600 ;; posn-col-row is incorrect in older Emacsen when line-spacing is set
 601 (defun company--col-row (&optional pos)
 602   (let ((posn (posn-at-point pos)))
 603     (cons (car (posn-col-row posn)) (cdr (posn-actual-col-row posn)))))
 604
 605 (defsubst company--column (&optional pos)
 606   (car (posn-col-row (posn-at-point pos))))
 607
 608 (defsubst company--row (&optional pos)
 609   (cdr (posn-actual-col-row (posn-at-point pos))))
 610
 611 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 612
 613 (defun company-grab (regexp &optional expression limit)
 614   (when (looking-back regexp limit)
 615     (or (match-string-no-properties (or expression 0)) "")))
 616
 617 (defun company-grab-line (regexp &optional expression)
 618   (company-grab regexp expression (point-at-bol)))
 619
 620 (defun company-grab-symbol ()
 621   (if (looking-at "\\_>")
 622       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 623                                                 (point)))
 624     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 625       "")))
 626
 627 (defun company-grab-word ()
 628   (if (looking-at "\\>")
 629       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 630                                                 (point)))
 631     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 632       "")))
 633
 634 (defun company-in-string-or-comment ()
 635   (let ((ppss (syntax-ppss)))
 636     (or (car (setq ppss (nthcdr 3 ppss)))
 637         (car (setq ppss (cdr ppss)))
 638         (nth 3 ppss))))
 639
 640 (if (fboundp 'locate-dominating-file)
 641     (defalias 'company-locate-dominating-file 'locate-dominating-file)
 642   (defun company-locate-dominating-file (file name)
 643     (catch 'root
 644       (let ((dir (file-name-directory file))
 645             (prev-dir nil))
 646         (while (not (equal dir prev-dir))
 647           (when (file-exists-p (expand-file-name name dir))
 648             (throw 'root dir))
 649           (setq prev-dir dir
 650                 dir (file-name-directory (directory-file-name dir))))))))
 651
 652 (defun company-call-backend (&rest args)
 653   (if (functionp company-backend)
 654       (apply company-backend args)
 655     (apply 'company--multi-backend-adapter company-backend args)))
 656
 657 (defun company--multi-backend-adapter (backends command &rest args)
 658   (let ((backends (remove-if (lambda (b) (eq 'failed (get b 'company-init)))
 659                              backends)))
 660     (case command
 661       (candidates
 662        (loop for backend in backends
 663              when (equal (funcall backend 'prefix)
 664                          (car args))
 665              nconc (apply backend 'candidates args)))
 666       (sorted nil)
 667       (duplicates t)
 668       (otherwise
 669        (let (value)
 670          (dolist (backend backends)
 671            (when (setq value (apply backend command args))
 672              (return value))))))))
 673
 674 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 675
 676 (defvar company-backend nil)
 677 (make-variable-buffer-local 'company-backend)
 678
 679 (defvar company-prefix nil)
 680 (make-variable-buffer-local 'company-prefix)
 681
 682 (defvar company-candidates nil)
 683 (make-variable-buffer-local 'company-candidates)
 684
 685 (defvar company-candidates-length nil)
 686 (make-variable-buffer-local 'company-candidates-length)
 687
 688 (defvar company-candidates-cache nil)
 689 (make-variable-buffer-local 'company-candidates-cache)
 690
 691 (defvar company-candidates-predicate nil)
 692 (make-variable-buffer-local 'company-candidates-predicate)
 693
 694 (defvar company-common nil)
 695 (make-variable-buffer-local 'company-common)
 696
 697 (defvar company-selection 0)
 698 (make-variable-buffer-local 'company-selection)
 699
 700 (defvar company-selection-changed nil)
 701 (make-variable-buffer-local 'company-selection-changed)
 702
 703 (defvar company--explicit-action nil
 704   "Non-nil, if explicit completion took place.")
 705 (make-variable-buffer-local 'company--explicit-action)
 706
 707 (defvar company--auto-completion nil
 708   "Non-nil when current candidate is being completed automatically.
 709 Controlled by `company-auto-complete'.")
 710
 711 (defvar company--point-max nil)
 712 (make-variable-buffer-local 'company--point-max)
 713
 714 (defvar company-point nil)
 715 (make-variable-buffer-local 'company-point)
 716
 717 (defvar company-timer nil)
 718
 719 (defvar company-added-newline nil)
 720 (make-variable-buffer-local 'company-added-newline)
 721
 722 (defsubst company-strip-prefix (str)
 723   (substring str (length company-prefix)))
 724
 725 (defmacro company-with-candidate-inserted (candidate &rest body)
 726   "Evaluate BODY with CANDIDATE temporarily inserted.
 727 This is a tool for back-ends that need candidates inserted before they
 728 can retrieve meta-data for them."
 729   (declare (indent 1))
 730   `(let ((inhibit-modification-hooks t)
 731          (inhibit-point-motion-hooks t)
 732          (modified-p (buffer-modified-p)))
 733      (insert (company-strip-prefix ,candidate))
 734      (unwind-protect
 735          (progn ,@body)
 736        (delete-region company-point (point)))))
 737
 738 (defun company-explicit-action-p ()
 739   "Return whether explicit completion action was taken by the user."
 740   (or company--explicit-action
 741       company-selection-changed))
 742
 743 (defsubst company-reformat (candidate)
 744   ;; company-ispell needs this, because the results are always lower-case
 745   ;; It's mory efficient to fix it only when they are displayed.
 746   (concat company-prefix (substring candidate (length company-prefix))))
 747
 748 (defun company--should-complete ()
 749   (and (not (or buffer-read-only overriding-terminal-local-map
 750                 overriding-local-map
 751                 (minibufferp)))
 752        ;; Check if in the middle of entering a key combination.
 753        (or (equal (this-command-keys-vector) [])
 754            (not (keymapp (key-binding (this-command-keys-vector)))))
 755        (eq company-idle-delay t)
 756        (or (eq t company-begin-commands)
 757            (memq this-command company-begin-commands)
 758            (and (symbolp this-command) (get this-command 'company-begin)))
 759        (not (and transient-mark-mode mark-active))))
 760
 761 (defsubst company-call-frontends (command)
 762   (dolist (frontend company-frontends)
 763     (condition-case err
 764         (funcall frontend command)
 765       (error (error "Company: Front-end %s error \"%s\" on command %s"
 766                     frontend (error-message-string err) command)))))
 767
 768 (defsubst company-set-selection (selection &optional force-update)
 769   (setq selection (max 0 (min (1- company-candidates-length) selection)))
 770   (when (or force-update (not (equal selection company-selection)))
 771     (setq company-selection selection
 772           company-selection-changed t)
 773     (company-call-frontends 'update)))
 774
 775 (defun company-apply-predicate (candidates predicate)
 776   (let (new)
 777     (dolist (c candidates)
 778       (when (funcall predicate c)
 779         (push c new)))
 780     (nreverse new)))
 781
 782 (defun company-update-candidates (candidates)
 783   (setq company-candidates-length (length candidates))
 784   (if (> company-selection 0)
 785       ;; Try to restore the selection
 786       (let ((selected (nth company-selection company-candidates)))
 787         (setq company-selection 0
 788               company-candidates candidates)
 789         (when selected
 790           (while (and candidates (string< (pop candidates) selected))
 791             (incf company-selection))
 792           (unless candidates
 793             ;; Make sure selection isn't out of bounds.
 794             (setq company-selection (min (1- company-candidates-length)
 795                                          company-selection)))))
 796     (setq company-selection 0
 797           company-candidates candidates))
 798   ;; Save in cache:
 799   (push (cons company-prefix company-candidates) company-candidates-cache)
 800   ;; Calculate common.
 801   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
 802     (setq company-common (company--safe-candidate
 803                           (try-completion company-prefix company-candidates))))
 804   (when (eq company-common t)
 805     (setq company-candidates nil)))
 806
 807 (defun company--safe-candidate (str)
 808   (or (company-call-backend 'crop str)
 809       str))
 810
 811 (defun company-calculate-candidates (prefix)
 812   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
 813         (ignore-case (company-call-backend 'ignore-case)))
 814     (or candidates
 815         (when company-candidates-cache
 816           (let ((len (length prefix))
 817                 (completion-ignore-case ignore-case)
 818                 prev)
 819             (dotimes (i (1+ len))
 820               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
 821                                            company-candidates-cache)))
 822                 (setq candidates (all-completions prefix prev))
 823                 (return t)))))
 824         ;; no cache match, call back-end
 825         (progn
 826           (setq candidates (company-call-backend 'candidates prefix))
 827           (when company-candidates-predicate
 828             (setq candidates
 829                   (company-apply-predicate candidates
 830                                            company-candidates-predicate)))
 831           (unless (company-call-backend 'sorted)
 832             (setq candidates (sort candidates 'string<)))
 833           (when (company-call-backend 'duplicates)
 834             ;; strip duplicates
 835             (let ((c2 candidates))
 836               (while c2
 837                 (setcdr c2 (progn (while (equal (pop c2) (car c2)))
 838                                   c2)))))))
 839     (if (and candidates
 840              (or (cdr candidates)
 841                  (not (eq t (compare-strings (car candidates) nil nil
 842                                              prefix nil nil ignore-case)))))
 843         candidates
 844       ;; Already completed and unique; don't start.
 845       ;; FIXME: Not the right place? maybe when setting?
 846       (and company-candidates t))))
 847
 848 (defun company-idle-begin (buf win tick pos)
 849   (and company-mode
 850        (eq buf (current-buffer))
 851        (eq win (selected-window))
 852        (eq tick (buffer-chars-modified-tick))
 853        (eq pos (point))
 854        (not company-candidates)
 855        (not (equal (point) company-point))
 856        (let ((company-idle-delay t)
 857              (company-begin-commands t))
 858          (company-begin)
 859          (when company-candidates
 860            (company-input-noop)
 861            (company-post-command)))))
 862
 863 (defun company-auto-begin ()
 864   (company-assert-enabled)
 865   (and company-mode
 866        (not company-candidates)
 867        (let ((company-idle-delay t)
 868              (company-minimum-prefix-length 0)
 869              (company-begin-commands t))
 870          (company-begin)))
 871   ;; Return non-nil if active.
 872   company-candidates)
 873
 874 (defun company-manual-begin ()
 875   (interactive)
 876   (setq company--explicit-action t)
 877   (company-auto-begin))
 878
 879 (defun company-other-backend (&optional backward)
 880   (interactive (list current-prefix-arg))
 881   (company-assert-enabled)
 882   (if company-backend
 883       (let* ((after (cdr (member company-backend company-backends)))
 884              (before (cdr (member company-backend (reverse company-backends))))
 885              (next (if backward
 886                        (append before (reverse after))
 887                      (append after (reverse before)))))
 888         (company-cancel)
 889         (dolist (backend next)
 890           (when (ignore-errors (company-begin-backend backend))
 891             (return t))))
 892     (company-manual-begin))
 893   (unless company-candidates
 894     (error "No other back-end")))
 895
 896 (defun company-require-match-p ()
 897   (let ((backend-value (company-call-backend 'require-match)))
 898     (or (eq backend-value t)
 899         (and (if (functionp company-require-match)
 900                  (funcall company-require-match)
 901                (eq company-require-match t))
 902              (not (eq backend-value 'never))))))
 903
 904 (defun company-punctuation-p (input)
 905   "Return non-nil, if input starts with punctuation or parentheses."
 906   (memq (char-syntax (string-to-char input)) '(?. ?\( ?\))))
 907
 908 (defun company-auto-complete-p (input)
 909   "Return non-nil, if input starts with punctuation or parentheses."
 910   (and (if (functionp company-auto-complete)
 911            (funcall company-auto-complete)
 912          company-auto-complete)
 913        (if (functionp company-auto-complete-chars)
 914            (funcall company-auto-complete-chars input)
 915          (if (consp company-auto-complete-chars)
 916              (memq (char-syntax (string-to-char input))
 917                    company-auto-complete-chars)
 918            (string-match (substring input 0 1) company-auto-complete-chars)))))
 919
 920 (defun company--incremental-p ()
 921   (and (> (point) company-point)
 922        (> (point-max) company--point-max)
 923        (not (eq this-command 'backward-delete-char-untabify))
 924        (equal (buffer-substring (- company-point (length company-prefix))
 925                                 company-point)
 926               company-prefix)))
 927
 928 (defsubst company--string-incremental-p (old-prefix new-prefix)
 929   (and (> (length new-prefix) (length old-prefix))
 930        (equal old-prefix (substring new-prefix 0 (length old-prefix)))))
 931
 932 (defun company--continue-failed (new-prefix)
 933   (when (company--incremental-p)
 934     (let ((input (buffer-substring-no-properties (point) company-point)))
 935       (cond
 936        ((company-auto-complete-p input)
 937         ;; auto-complete
 938         (save-excursion
 939           (goto-char company-point)
 940           (let ((company--auto-completion t))
 941             (company-complete-selection))
 942           nil))
 943        ((and (company--string-incremental-p company-prefix new-prefix)
 944              (company-require-match-p))
 945         ;; wrong incremental input, but required match
 946         (backward-delete-char (length input))
 947         (ding)
 948         (message "Matching input is required")
 949         company-candidates)
 950        ((equal company-prefix (car company-candidates))
 951         ;; last input was actually success
 952         (company-cancel company-prefix)
 953         nil)))))
 954
 955 (defun company--good-prefix-p (prefix)
 956   (and (or (company-explicit-action-p)
 957            (>= (or (cdr-safe prefix) (length prefix))
 958                company-minimum-prefix-length))
 959        (stringp (or (car-safe prefix) prefix))))
 960
 961 (defun company--continue ()
 962   (when (company-call-backend 'no-cache company-prefix)
 963     ;; Don't complete existing candidates, fetch new ones.
 964     (setq company-candidates-cache nil))
 965   (let* ((new-prefix (company-call-backend 'prefix))
 966          (c (when (and (company--good-prefix-p new-prefix)
 967                        (setq new-prefix (or (car-safe new-prefix) new-prefix))
 968                        (= (- (point) (length new-prefix))
 969                           (- company-point (length company-prefix))))
 970               (setq new-prefix (or (car-safe new-prefix) new-prefix))
 971               (company-calculate-candidates new-prefix))))
 972     (or (cond
 973          ((eq c t)
 974           ;; t means complete/unique.
 975           (company-cancel new-prefix)
 976           nil)
 977          ((consp c)
 978           ;; incremental match
 979           (setq company-prefix new-prefix)
 980           (company-update-candidates c)
 981           c)
 982          (t (company--continue-failed new-prefix)))
 983         (company-cancel))))
 984
 985 (defun company--begin-new ()
 986   (let (prefix c)
 987     (dolist (backend (if company-backend
 988                          ;; prefer manual override
 989                          (list company-backend)
 990                        company-backends))
 991       (setq prefix
 992             (if (or (symbolp backend)
 993                     (functionp backend))
 994                 (when (or (not (symbolp backend))
 995                           (eq t (get backend 'company-init))
 996                           (unless (get backend 'company-init)
 997                             (company-init-backend backend)))
 998                   (funcall backend 'prefix))
 999               (company--multi-backend-adapter backend 'prefix)))
1000       (when prefix
1001         (when (company--good-prefix-p prefix)
1002           (setq prefix (or (car-safe prefix) prefix)
1003                 company-backend backend
1004                 c (company-calculate-candidates prefix))
1005           ;; t means complete/unique.  We don't start, so no hooks.
1006           (if (not (consp c))
1007               (when company--explicit-action
1008                 (message "No completion found"))
1009             (setq company-prefix prefix)
1010             (when (symbolp backend)
1011               (setq company-lighter (concat " " (symbol-name backend))))
1012             (company-update-candidates c)
1013             (run-hook-with-args 'company-completion-started-hook
1014                                 (company-explicit-action-p))
1015             (company-call-frontends 'show)))
1016         (return c)))))
1017
1018 (defun company-begin ()
1019   (or (and company-candidates (company--continue))
1020       (and (company--should-complete) (company--begin-new)))
1021   (when company-candidates
1022     (when (and company-end-of-buffer-workaround (eobp))
1023       (save-excursion (insert "\n"))
1024       (setq company-added-newline (buffer-chars-modified-tick)))
1025     (setq company-point (point)
1026           company--point-max (point-max))
1027     (company-ensure-emulation-alist)
1028     (company-enable-overriding-keymap company-active-map)
1029     (company-call-frontends 'update)))
1030
1031 (defun company-cancel (&optional result)
1032   (and company-added-newline
1033        (> (point-max) (point-min))
1034        (let ((tick (buffer-chars-modified-tick)))
1035          (delete-region (1- (point-max)) (point-max))
1036          (equal tick company-added-newline))
1037        ;; Only set unmodified when tick remained the same since insert.
1038        (set-buffer-modified-p nil))
1039   (when company-prefix
1040     (if (stringp result)
1041         (progn
1042           (company-call-backend 'pre-completion result)
1043           (run-hook-with-args 'company-completion-finished-hook result)
1044           (company-call-backend 'post-completion result))
1045       (run-hook-with-args 'company-completion-cancelled-hook result)))
1046   (setq company-added-newline nil
1047         company-backend nil
1048         company-prefix nil
1049         company-candidates nil
1050         company-candidates-length nil
1051         company-candidates-cache nil
1052         company-candidates-predicate nil
1053         company-common nil
1054         company-selection 0
1055         company-selection-changed nil
1056         company--explicit-action nil
1057         company-lighter company-default-lighter
1058         company--point-max nil
1059         company-point nil)
1060   (when company-timer
1061     (cancel-timer company-timer))
1062   (company-search-mode 0)
1063   (company-call-frontends 'hide)
1064   (company-enable-overriding-keymap nil))
1065
1066 (defun company-abort ()
1067   (interactive)
1068   (company-cancel t)
1069   ;; Don't start again, unless started manually.
1070   (setq company-point (point)))
1071
1072 (defun company-finish (result)
1073   (insert (company-strip-prefix result))
1074   (company-cancel result)
1075   ;; Don't start again, unless started manually.
1076   (setq company-point (point)))
1077
1078 (defsubst company-keep (command)
1079   (and (symbolp command) (get command 'company-keep)))
1080
1081 (defun company-pre-command ()
1082   (unless (company-keep this-command)
1083     (condition-case err
1084         (when company-candidates
1085           (company-call-frontends 'pre-command))
1086       (error (message "Company: An error occurred in pre-command")
1087              (message "%s" (error-message-string err))
1088              (company-cancel))))
1089   (when company-timer
1090     (cancel-timer company-timer)
1091     (setq company-timer nil))
1092   (company-uninstall-map))
1093
1094 (defun company-post-command ()
1095   (unless (company-keep this-command)
1096     (condition-case err
1097         (progn
1098           (unless (equal (point) company-point)
1099             (company-begin))
1100           (if company-candidates
1101               (company-call-frontends 'post-command)
1102             (and (numberp company-idle-delay)
1103                  (or (eq t company-begin-commands)
1104                      (memq this-command company-begin-commands))
1105                  (setq company-timer
1106                        (run-with-timer company-idle-delay nil
1107                                        'company-idle-begin
1108                                        (current-buffer) (selected-window)
1109                                        (buffer-chars-modified-tick) (point))))))
1110       (error (message "Company: An error occurred in post-command")
1111              (message "%s" (error-message-string err))
1112              (company-cancel))))
1113   (company-install-map))
1114
1115 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1116
1117 (defvar company-search-string nil)
1118 (make-variable-buffer-local 'company-search-string)
1119
1120 (defvar company-search-lighter " Search: \"\"")
1121 (make-variable-buffer-local 'company-search-lighter)
1122
1123 (defvar company-search-old-map nil)
1124 (make-variable-buffer-local 'company-search-old-map)
1125
1126 (defvar company-search-old-selection 0)
1127 (make-variable-buffer-local 'company-search-old-selection)
1128
1129 (defun company-search (text lines)
1130   (let ((quoted (regexp-quote text))
1131         (i 0))
1132     (dolist (line lines)
1133       (when (string-match quoted line (length company-prefix))
1134         (return i))
1135       (incf i))))
1136
1137 (defun company-search-printing-char ()
1138   (interactive)
1139   (company-search-assert-enabled)
1140   (setq company-search-string
1141         (concat (or company-search-string "") (string last-command-event))
1142         company-search-lighter (concat " Search: \"" company-search-string
1143                                         "\""))
1144   (let ((pos (company-search company-search-string
1145                               (nthcdr company-selection company-candidates))))
1146     (if (null pos)
1147         (ding)
1148       (company-set-selection (+ company-selection pos) t))))
1149
1150 (defun company-search-repeat-forward ()
1151   "Repeat the incremental search in completion candidates forward."
1152   (interactive)
1153   (company-search-assert-enabled)
1154   (let ((pos (company-search company-search-string
1155                               (cdr (nthcdr company-selection
1156                                            company-candidates)))))
1157     (if (null pos)
1158         (ding)
1159       (company-set-selection (+ company-selection pos 1) t))))
1160
1161 (defun company-search-repeat-backward ()
1162   "Repeat the incremental search in completion candidates backwards."
1163   (interactive)
1164   (company-search-assert-enabled)
1165   (let ((pos (company-search company-search-string
1166                               (nthcdr (- company-candidates-length
1167                                          company-selection)
1168                                       (reverse company-candidates)))))
1169     (if (null pos)
1170         (ding)
1171       (company-set-selection (- company-selection pos 1) t))))
1172
1173 (defun company-create-match-predicate ()
1174   (setq company-candidates-predicate
1175         `(lambda (candidate)
1176            ,(if company-candidates-predicate
1177                 `(and (string-match ,company-search-string candidate)
1178                       (funcall ,company-candidates-predicate
1179                                candidate))
1180               `(string-match ,company-search-string candidate))))
1181   (company-update-candidates
1182    (company-apply-predicate company-candidates company-candidates-predicate))
1183   ;; Invalidate cache.
1184   (setq company-candidates-cache (cons company-prefix company-candidates)))
1185
1186 (defun company-filter-printing-char ()
1187   (interactive)
1188   (company-search-assert-enabled)
1189   (company-search-printing-char)
1190   (company-create-match-predicate)
1191   (company-call-frontends 'update))
1192
1193 (defun company-search-kill-others ()
1194   "Limit the completion candidates to the ones matching the search string."
1195   (interactive)
1196   (company-search-assert-enabled)
1197   (company-create-match-predicate)
1198   (company-search-mode 0)
1199   (company-call-frontends 'update))
1200
1201 (defun company-search-abort ()
1202   "Abort searching the completion candidates."
1203   (interactive)
1204   (company-search-assert-enabled)
1205   (company-set-selection company-search-old-selection t)
1206   (company-search-mode 0))
1207
1208 (defun company-search-other-char ()
1209   (interactive)
1210   (company-search-assert-enabled)
1211   (company-search-mode 0)
1212   (company--unread-last-input))
1213
1214 (defvar company-search-map
1215   (let ((i 0)
1216         (keymap (make-keymap)))
1217     (if (fboundp 'max-char)
1218         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1219                               'company-search-printing-char)
1220       (with-no-warnings
1221         ;; obsolete in Emacs 23
1222         (let ((l (generic-character-list))
1223               (table (nth 1 keymap)))
1224           (while l
1225             (set-char-table-default table (car l) 'company-search-printing-char)
1226             (setq l (cdr l))))))
1227     (define-key keymap [t] 'company-search-other-char)
1228     (while (< i ?\s)
1229       (define-key keymap (make-string 1 i) 'company-search-other-char)
1230       (incf i))
1231     (while (< i 256)
1232       (define-key keymap (vector i) 'company-search-printing-char)
1233       (incf i))
1234     (let ((meta-map (make-sparse-keymap)))
1235       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1236       (define-key keymap [escape] meta-map))
1237     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1238     (define-key keymap "\e\e\e" 'company-search-other-char)
1239     (define-key keymap  [escape escape escape] 'company-search-other-char)
1240
1241     (define-key keymap "\C-g" 'company-search-abort)
1242     (define-key keymap "\C-s" 'company-search-repeat-forward)
1243     (define-key keymap "\C-r" 'company-search-repeat-backward)
1244     (define-key keymap "\C-o" 'company-search-kill-others)
1245     keymap)
1246   "Keymap used for incrementally searching the completion candidates.")
1247
1248 (define-minor-mode company-search-mode
1249   "Search mode for completion candidates.
1250 Don't start this directly, use `company-search-candidates' or
1251 `company-filter-candidates'."
1252   nil company-search-lighter nil
1253   (if company-search-mode
1254       (if (company-manual-begin)
1255           (progn
1256             (setq company-search-old-selection company-selection)
1257             (company-call-frontends 'update))
1258         (setq company-search-mode nil))
1259     (kill-local-variable 'company-search-string)
1260     (kill-local-variable 'company-search-lighter)
1261     (kill-local-variable 'company-search-old-selection)
1262     (company-enable-overriding-keymap company-active-map)))
1263
1264 (defsubst company-search-assert-enabled ()
1265   (company-assert-enabled)
1266   (unless company-search-mode
1267     (company-uninstall-map)
1268     (error "Company not in search mode")))
1269
1270 (defun company-search-candidates ()
1271   "Start searching the completion candidates incrementally.
1272
1273 \\<company-search-map>Search can be controlled with the commands:
1274 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1275 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1276 - `company-search-abort' (\\[company-search-abort])
1277
1278 Regular characters are appended to the search string.
1279
1280 The command `company-search-kill-others' (\\[company-search-kill-others]) uses
1281  the search string to limit the completion candidates."
1282   (interactive)
1283   (company-search-mode 1)
1284   (company-enable-overriding-keymap company-search-map))
1285
1286 (defvar company-filter-map
1287   (let ((keymap (make-keymap)))
1288     (define-key keymap [remap company-search-printing-char]
1289       'company-filter-printing-char)
1290     (set-keymap-parent keymap company-search-map)
1291     keymap)
1292   "Keymap used for incrementally searching the completion candidates.")
1293
1294 (defun company-filter-candidates ()
1295   "Start filtering the completion candidates incrementally.
1296 This works the same way as `company-search-candidates' immediately
1297 followed by `company-search-kill-others' after each input."
1298   (interactive)
1299   (company-search-mode 1)
1300   (company-enable-overriding-keymap company-filter-map))
1301
1302 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1303
1304 (defun company-select-next ()
1305   "Select the next candidate in the list."
1306   (interactive)
1307   (when (company-manual-begin)
1308     (company-set-selection (1+ company-selection))))
1309
1310 (defun company-select-previous ()
1311   "Select the previous candidate in the list."
1312   (interactive)
1313   (when (company-manual-begin)
1314     (company-set-selection (1- company-selection))))
1315
1316 (defun company-select-next-or-abort ()
1317   "Select the next candidate if more than one, else abort
1318 and invoke the normal binding."
1319   (interactive)
1320   (if (> company-candidates-length 1)
1321       (company-select-next)
1322     (company-abort)
1323     (company--unread-last-input)))
1324
1325 (defun company-select-previous-or-abort ()
1326   "Select the previous candidate if more than one, else abort
1327 and invoke the normal binding."
1328   (interactive)
1329   (if (> company-candidates-length 1)
1330       (company-select-previous)
1331     (company-abort)
1332     (company--unread-last-input)))
1333
1334 (defun company-select-mouse (event)
1335   "Select the candidate picked by the mouse."
1336   (interactive "e")
1337   (when (nth 4 (event-start event))
1338     (company-set-selection (- (cdr (posn-actual-col-row (event-start event)))
1339                               (company--row)
1340                               1))
1341     t))
1342
1343 (defun company-complete-mouse (event)
1344   "Complete the candidate picked by the mouse."
1345   (interactive "e")
1346   (when (company-select-mouse event)
1347     (company-complete-selection)))
1348
1349 (defun company-complete-selection ()
1350   "Complete the selected candidate."
1351   (interactive)
1352   (when (company-manual-begin)
1353     (let ((result (nth company-selection company-candidates)))
1354       (when company--auto-completion
1355         (setq result (company--safe-candidate result)))
1356       (company-finish result))))
1357
1358 (defun company-complete-common ()
1359   "Complete the common part of all candidates."
1360   (interactive)
1361   (when (company-manual-begin)
1362     (if (and (not (cdr company-candidates))
1363              (equal company-common (car company-candidates)))
1364         (company-complete-selection)
1365       (insert (company-strip-prefix company-common)))))
1366
1367 (defun company-complete ()
1368   "Complete the common part of all candidates or the current selection.
1369 The first time this is called, the common part is completed, the second time, or
1370 when the selection has been changed, the selected candidate is completed."
1371   (interactive)
1372   (when (company-manual-begin)
1373     (if (or company-selection-changed
1374             (eq last-command 'company-complete-common))
1375         (call-interactively 'company-complete-selection)
1376       (call-interactively 'company-complete-common)
1377       (setq this-command 'company-complete-common))))
1378
1379 (defun company-complete-number (n)
1380   "Complete the Nth candidate.
1381 To show the number next to the candidates in some back-ends, enable
1382 `company-show-numbers'."
1383   (when (company-manual-begin)
1384     (and (< n 1) (> n company-candidates-length)
1385          (error "No candidate number %d" n))
1386     (decf n)
1387     (company-finish (nth n company-candidates))))
1388
1389 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1390
1391 (defconst company-space-strings-limit 100)
1392
1393 (defconst company-space-strings
1394   (let (lst)
1395     (dotimes (i company-space-strings-limit)
1396       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1397     (apply 'vector lst)))
1398
1399 (defsubst company-space-string (len)
1400   (if (< len company-space-strings-limit)
1401       (aref company-space-strings len)
1402     (make-string len ?\ )))
1403
1404 (defsubst company-safe-substring (str from &optional to)
1405   (if (> from (string-width str))
1406       ""
1407     (with-temp-buffer
1408       (insert str)
1409       (move-to-column from)
1410       (let ((beg (point)))
1411         (if to
1412             (progn
1413               (move-to-column to)
1414               (concat (buffer-substring beg (point))
1415                       (let ((padding (- to (current-column))))
1416                         (when (> padding 0)
1417                           (company-space-string padding)))))
1418           (buffer-substring beg (point-max)))))))
1419
1420 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1421
1422 (defvar company-last-metadata nil)
1423 (make-variable-buffer-local 'company-last-metadata)
1424
1425 (defun company-fetch-metadata ()
1426   (let ((selected (nth company-selection company-candidates)))
1427     (unless (equal selected (car company-last-metadata))
1428       (setq company-last-metadata
1429             (cons selected (company-call-backend 'meta selected))))
1430     (cdr company-last-metadata)))
1431
1432 (defun company-doc-buffer (&optional string)
1433   (with-current-buffer (get-buffer-create "*Company meta-data*")
1434     (erase-buffer)
1435     (current-buffer)))
1436
1437 (defvar company--electric-commands
1438   '(scroll-other-window scroll-other-window-down)
1439   "List of Commands that won't break out of electric commands.")
1440
1441 (defmacro company--electric-do (&rest body)
1442   (declare (indent 0) (debug t))
1443   `(when (company-manual-begin)
1444      (save-window-excursion
1445        (let ((height (window-height))
1446              (row (company--row))
1447              cmd)
1448          ,@body
1449          (and (< (window-height) height)
1450               (< (- (window-height) row 2) company-tooltip-limit)
1451               (recenter (- (window-height) row 2)))
1452          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1453                       company--electric-commands)
1454            (call-interactively cmd))
1455          (company--unread-last-input)))))
1456
1457 (defun company--unread-last-input ()
1458   (when last-input-event
1459     (clear-this-command-keys t)
1460     (setq unread-command-events (list last-input-event))))
1461
1462 (defun company-show-doc-buffer ()
1463   "Temporarily show a buffer with the complete documentation for the selection."
1464   (interactive)
1465   (company--electric-do
1466     (let* ((selected (nth company-selection company-candidates))
1467            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1468                            (error "No documentation available"))))
1469       (with-current-buffer doc-buffer
1470         (goto-char (point-min)))
1471       (display-buffer doc-buffer t))))
1472 (put 'company-show-doc-buffer 'company-keep t)
1473
1474 (defun company-show-location ()
1475   "Temporarily display a buffer showing the selected candidate in context."
1476   (interactive)
1477   (company--electric-do
1478     (let* ((selected (nth company-selection company-candidates))
1479            (location (company-call-backend 'location selected))
1480            (pos (or (cdr location) (error "No location available")))
1481            (buffer (or (and (bufferp (car location)) (car location))
1482                        (find-file-noselect (car location) t))))
1483       (with-selected-window (display-buffer buffer t)
1484         (save-restriction
1485           (widen)
1486           (if (bufferp (car location))
1487               (goto-char pos)
1488             (goto-char (point-min))
1489             (forward-line (1- pos))))
1490         (set-window-start nil (point))))))
1491 (put 'company-show-location 'company-keep t)
1492
1493 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1494
1495 (defvar company-callback nil)
1496 (make-variable-buffer-local 'company-callback)
1497
1498 (defvar company-begin-with-marker nil)
1499 (make-variable-buffer-local 'company-begin-with-marker)
1500
1501 (defun company-remove-callback (&optional ignored)
1502   (remove-hook 'company-completion-finished-hook company-callback t)
1503   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1504   (remove-hook 'company-completion-finished-hook 'company-remove-callback t)
1505   (when company-begin-with-marker
1506     (set-marker company-begin-with-marker nil)))
1507
1508 (defun company-begin-backend (backend &optional callback)
1509   "Start a completion at point using BACKEND."
1510   (interactive (let ((val (completing-read "Company back-end: "
1511                                            obarray
1512                                            'functionp nil "company-")))
1513                  (when val
1514                    (list (intern val)))))
1515   (when (setq company-callback callback)
1516     (add-hook 'company-completion-finished-hook company-callback nil t))
1517   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1518   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1519   (setq company-backend backend)
1520   ;; Return non-nil if active.
1521   (or (company-manual-begin)
1522       (error "Cannot complete at point")))
1523
1524 (defun company-begin-with (candidates
1525                            &optional prefix-length require-match callback)
1526   "Start a completion at point.
1527 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length of
1528 the prefix that already is in the buffer before point.  It defaults to 0.
1529
1530 CALLBACK is a function called with the selected result if the user successfully
1531 completes the input.
1532
1533 Example:
1534 \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
1535   (setq company-begin-with-marker (copy-marker (point) t))
1536   (company-begin-backend
1537    `(lambda (command &optional arg &rest ignored)
1538       (cond
1539        ((eq command 'prefix)
1540         (when (equal (point) (marker-position company-begin-with-marker))
1541           (buffer-substring ,(- (point) (or prefix-length 0)) (point))))
1542        ((eq command 'candidates)
1543         (all-completions arg ',candidates))
1544        ((eq command 'require-match)
1545         ,require-match)))
1546    callback))
1547
1548 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1549
1550 (defvar company-pseudo-tooltip-overlay nil)
1551 (make-variable-buffer-local 'company-pseudo-tooltip-overlay)
1552
1553 (defvar company-tooltip-offset 0)
1554 (make-variable-buffer-local 'company-tooltip-offset)
1555
1556 (defun company-pseudo-tooltip-update-offset (selection num-lines limit)
1557
1558   (decf limit 2)
1559   (setq company-tooltip-offset
1560         (max (min selection company-tooltip-offset)
1561              (- selection -1 limit)))
1562
1563   (when (<= company-tooltip-offset 1)
1564     (incf limit)
1565     (setq company-tooltip-offset 0))
1566
1567   (when (>= company-tooltip-offset (- num-lines limit 1))
1568     (incf limit)
1569     (when (= selection (1- num-lines))
1570       (decf company-tooltip-offset)
1571       (when (<= company-tooltip-offset 1)
1572         (setq company-tooltip-offset 0)
1573         (incf limit))))
1574
1575   limit)
1576
1577 ;;; propertize
1578
1579 (defsubst company-round-tab (arg)
1580   (* (/ (+ arg tab-width) tab-width) tab-width))
1581
1582 (defun company-untabify (str)
1583   (let* ((pieces (split-string str "\t"))
1584          (copy pieces))
1585     (while (cdr copy)
1586       (setcar copy (company-safe-substring
1587                     (car copy) 0 (company-round-tab (string-width (car copy)))))
1588       (pop copy))
1589     (apply 'concat pieces)))
1590
1591 (defun company-fill-propertize (line width selected)
1592   (setq line (company-safe-substring line 0 width))
1593   (add-text-properties 0 width '(face company-tooltip
1594                                  mouse-face company-tooltip-mouse)
1595                        line)
1596   (add-text-properties 0 (length company-common)
1597                        '(face company-tooltip-common
1598                          mouse-face company-tooltip-mouse)
1599                        line)
1600   (when selected
1601     (if (and company-search-string
1602              (string-match (regexp-quote company-search-string) line
1603                            (length company-prefix)))
1604         (progn
1605           (add-text-properties (match-beginning 0) (match-end 0)
1606                                '(face company-tooltip-selection)
1607                                line)
1608           (when (< (match-beginning 0) (length company-common))
1609             (add-text-properties (match-beginning 0) (length company-common)
1610                                  '(face company-tooltip-common-selection)
1611                                  line)))
1612       (add-text-properties 0 width '(face company-tooltip-selection
1613                                           mouse-face company-tooltip-selection)
1614                            line)
1615       (add-text-properties 0 (length company-common)
1616                            '(face company-tooltip-common-selection
1617                              mouse-face company-tooltip-selection)
1618                            line)))
1619   line)
1620
1621 ;;; replace
1622
1623 (defun company-buffer-lines (beg end)
1624   (goto-char beg)
1625   (let (lines)
1626     (while (and (= 1 (vertical-motion 1))
1627                 (<= (point) end))
1628       (push (buffer-substring beg (min end (1- (point)))) lines)
1629       (setq beg (point)))
1630     (unless (eq beg end)
1631       (push (buffer-substring beg end) lines))
1632     (nreverse lines)))
1633
1634 (defsubst company-modify-line (old new offset)
1635   (concat (company-safe-substring old 0 offset)
1636           new
1637           (company-safe-substring old (+ offset (length new)))))
1638
1639 (defsubst company--length-limit (lst limit)
1640   (if (nthcdr limit lst)
1641       limit
1642     (length lst)))
1643
1644 (defun company--replacement-string (lines old column nl &optional align-top)
1645
1646   (let ((width (length (car lines))))
1647     (when (> width (- (window-width) column))
1648       (setq column (max 0 (- (window-width) width)))))
1649
1650   (let (new)
1651     (when align-top
1652       ;; untouched lines first
1653       (dotimes (i (- (length old) (length lines)))
1654         (push (pop old) new)))
1655     ;; length into old lines.
1656     (while old
1657       (push (company-modify-line (pop old) (pop lines) column) new))
1658     ;; Append whole new lines.
1659     (while lines
1660       (push (concat (company-space-string column) (pop lines)) new))
1661
1662     (let ((str (concat (when nl "\n")
1663                        (mapconcat 'identity (nreverse new) "\n")
1664                        "\n")))
1665       (font-lock-append-text-property 0 (length str) 'face 'default str)
1666       str)))
1667
1668 (defun company--create-lines (selection limit)
1669
1670   (let ((len company-candidates-length)
1671         (numbered 99999)
1672         lines
1673         width
1674         lines-copy
1675         previous
1676         remainder
1677         new)
1678
1679     ;; Scroll to offset.
1680     (setq limit (company-pseudo-tooltip-update-offset selection len limit))
1681
1682     (when (> company-tooltip-offset 0)
1683       (setq previous (format "...(%d)" company-tooltip-offset)))
1684
1685     (setq remainder (- len limit company-tooltip-offset)
1686           remainder (when (> remainder 0)
1687                       (setq remainder (format "...(%d)" remainder))))
1688
1689     (decf selection company-tooltip-offset)
1690     (setq width (max (length previous) (length remainder))
1691           lines (nthcdr company-tooltip-offset company-candidates)
1692           len (min limit len)
1693           lines-copy lines)
1694
1695     (dotimes (i len)
1696       (setq width (max (length (pop lines-copy)) width)))
1697     (setq width (min width (window-width)))
1698
1699     (setq lines-copy lines)
1700
1701     ;; number can make tooltip too long
1702     (when company-show-numbers
1703       (setq numbered company-tooltip-offset))
1704
1705     (when previous
1706       (push (propertize (company-safe-substring previous 0 width)
1707                         'face 'company-tooltip)
1708             new))
1709
1710     (dotimes (i len)
1711       (push (company-fill-propertize
1712              (if (>= numbered 10)
1713                  (company-reformat (pop lines))
1714                (incf numbered)
1715                (format "%s %d"
1716                        (company-safe-substring (company-reformat (pop lines))
1717                                                0 (- width 2))
1718                        (mod numbered 10)))
1719              width (equal i selection))
1720             new))
1721
1722     (when remainder
1723       (push (propertize (company-safe-substring remainder 0 width)
1724                         'face 'company-tooltip)
1725             new))
1726
1727     (setq lines (nreverse new))))
1728
1729 ;; show
1730
1731 (defsubst company--window-inner-height ()
1732   (let ((edges (window-inside-edges (selected-window))))
1733     (- (nth 3 edges) (nth 1 edges))))
1734
1735 (defsubst company--pseudo-tooltip-height ()
1736   "Calculate the appropriate tooltip height.
1737 Returns a negative number if the tooltip should be displayed above point."
1738   (let* ((lines (company--row))
1739          (below (- (company--window-inner-height) 1 lines)))
1740     (if (and (< below (min company-tooltip-minimum company-candidates-length))
1741              (> lines below))
1742         (- (max 3 (min company-tooltip-limit lines)))
1743       (max 3 (min company-tooltip-limit below)))))
1744
1745 (defun company-pseudo-tooltip-show (row column selection)
1746   (company-pseudo-tooltip-hide)
1747   (save-excursion
1748
1749     (move-to-column 0)
1750
1751     (let* ((height (company--pseudo-tooltip-height))
1752            above)
1753
1754       (when (< height 0)
1755         (setq row (+ row height -1)
1756               above t))
1757
1758       (let* ((nl (< (move-to-window-line row) row))
1759              (beg (point))
1760              (end (save-excursion
1761                     (move-to-window-line (+ row (abs height)))
1762                     (point)))
1763              (ov (make-overlay beg end))
1764              (args (list (mapcar 'company-untabify
1765                                  (company-buffer-lines beg end))
1766                          column nl above)))
1767
1768         (setq company-pseudo-tooltip-overlay ov)
1769         (overlay-put ov 'company-replacement-args args)
1770         (overlay-put ov 'company-before
1771                      (apply 'company--replacement-string
1772                             (company--create-lines selection (abs height))
1773                             args))
1774
1775         (overlay-put ov 'company-column column)
1776         (overlay-put ov 'company-height (abs height))))))
1777
1778 (defun company-pseudo-tooltip-show-at-point (pos)
1779   (let ((col-row (company--col-row pos)))
1780     (when col-row
1781       (company-pseudo-tooltip-show (1+ (cdr col-row)) (car col-row)
1782                                    company-selection))))
1783
1784 (defun company-pseudo-tooltip-edit (lines selection)
1785   (let ((column (overlay-get company-pseudo-tooltip-overlay 'company-column))
1786         (height (overlay-get company-pseudo-tooltip-overlay 'company-height)))
1787     (overlay-put company-pseudo-tooltip-overlay 'company-before
1788                  (apply 'company--replacement-string
1789                         (company--create-lines selection height)
1790                         (overlay-get company-pseudo-tooltip-overlay
1791                                      'company-replacement-args)))))
1792
1793 (defun company-pseudo-tooltip-hide ()
1794   (when company-pseudo-tooltip-overlay
1795     (delete-overlay company-pseudo-tooltip-overlay)
1796     (setq company-pseudo-tooltip-overlay nil)))
1797
1798 (defun company-pseudo-tooltip-hide-temporarily ()
1799   (when (overlayp company-pseudo-tooltip-overlay)
1800     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
1801     (overlay-put company-pseudo-tooltip-overlay 'before-string nil)))
1802
1803 (defun company-pseudo-tooltip-unhide ()
1804   (when company-pseudo-tooltip-overlay
1805     (overlay-put company-pseudo-tooltip-overlay 'invisible t)
1806     (overlay-put company-pseudo-tooltip-overlay 'before-string
1807                  (overlay-get company-pseudo-tooltip-overlay 'company-before))
1808     (overlay-put company-pseudo-tooltip-overlay 'window (selected-window))))
1809
1810 (defun company-pseudo-tooltip-frontend (command)
1811   "A `company-mode' front-end similar to a tool-tip but based on overlays."
1812   (case command
1813     (pre-command (company-pseudo-tooltip-hide-temporarily))
1814     (post-command
1815      (let ((old-height (if (overlayp company-pseudo-tooltip-overlay)
1816                            (overlay-get company-pseudo-tooltip-overlay
1817                                         'company-height)
1818                          0))
1819            (new-height (company--pseudo-tooltip-height)))
1820        (unless (and (>= (* old-height new-height) 0)
1821                     (>= (abs old-height) (abs new-height)))
1822          ;; Redraw needed.
1823          (company-pseudo-tooltip-show-at-point (- (point)
1824                                                   (length company-prefix)))))
1825      (company-pseudo-tooltip-unhide))
1826     (hide (company-pseudo-tooltip-hide)
1827           (setq company-tooltip-offset 0))
1828     (update (when (overlayp company-pseudo-tooltip-overlay)
1829               (company-pseudo-tooltip-edit company-candidates
1830                                            company-selection)))))
1831
1832 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
1833   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
1834   (unless (and (eq command 'post-command)
1835                (not (cdr company-candidates)))
1836     (company-pseudo-tooltip-frontend command)))
1837
1838 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1839
1840 (defvar company-preview-overlay nil)
1841 (make-variable-buffer-local 'company-preview-overlay)
1842
1843 (defun company-preview-show-at-point (pos)
1844   (company-preview-hide)
1845
1846   (setq company-preview-overlay (make-overlay pos pos))
1847
1848   (let ((completion(nth company-selection company-candidates)))
1849     (setq completion (propertize completion 'face 'company-preview))
1850     (add-text-properties 0 (length company-common)
1851                          '(face company-preview-common) completion)
1852
1853     ;; Add search string
1854     (and company-search-string
1855          (string-match (regexp-quote company-search-string) completion)
1856          (add-text-properties (match-beginning 0)
1857                               (match-end 0)
1858                               '(face company-preview-search)
1859                               completion))
1860
1861     (setq completion (company-strip-prefix completion))
1862
1863     (and (equal pos (point))
1864          (not (equal completion ""))
1865          (add-text-properties 0 1 '(cursor t) completion))
1866
1867     (overlay-put company-preview-overlay 'after-string completion)
1868     (overlay-put company-preview-overlay 'window (selected-window))))
1869
1870 (defun company-preview-hide ()
1871   (when company-preview-overlay
1872     (delete-overlay company-preview-overlay)
1873     (setq company-preview-overlay nil)))
1874
1875 (defun company-preview-frontend (command)
1876   "A `company-mode' front-end showing the selection as if it had been inserted."
1877   (case command
1878     (pre-command (company-preview-hide))
1879     (post-command (company-preview-show-at-point (point)))
1880     (hide (company-preview-hide))))
1881
1882 (defun company-preview-if-just-one-frontend (command)
1883   "`company-preview-frontend', but only shown for single candidates."
1884   (unless (and (eq command 'post-command)
1885                (cdr company-candidates))
1886     (company-preview-frontend command)))
1887
1888 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1889
1890 (defvar company-echo-last-msg nil)
1891 (make-variable-buffer-local 'company-echo-last-msg)
1892
1893 (defvar company-echo-timer nil)
1894
1895 (defvar company-echo-delay .01)
1896
1897 (defun company-echo-show (&optional getter)
1898   (when getter
1899     (setq company-echo-last-msg (funcall getter)))
1900   (let ((message-log-max nil))
1901     (if company-echo-last-msg
1902         (message "%s" company-echo-last-msg)
1903       (message ""))))
1904
1905 (defsubst company-echo-show-soon (&optional getter)
1906   (when company-echo-timer
1907     (cancel-timer company-echo-timer))
1908   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
1909
1910 (defsubst company-echo-show-when-idle (&optional getter)
1911   (when (sit-for .01)
1912     (company-echo-show getter)))
1913
1914 (defsubst company-echo-show-when-not-busy (&optional getter)
1915   "Run `company-echo-show' with arg GETTER once Emacs isn't busy."
1916   (when (sit-for company-echo-delay)
1917     (company-echo-show getter)))
1918
1919 (defun company-echo-format ()
1920
1921   (let ((limit (window-width (minibuffer-window)))
1922         (len -1)
1923         ;; Roll to selection.
1924         (candidates (nthcdr company-selection company-candidates))
1925         (i (if company-show-numbers company-selection 99999))
1926         comp msg)
1927
1928     (while candidates
1929       (setq comp (company-reformat (pop candidates))
1930             len (+ len 1 (length comp)))
1931       (if (< i 10)
1932           ;; Add number.
1933           (progn
1934             (setq comp (propertize (format "%d: %s" i comp)
1935                                    'face 'company-echo))
1936             (incf len 3)
1937             (incf i)
1938             (add-text-properties 3 (+ 3 (length company-common))
1939                                  '(face company-echo-common) comp))
1940         (setq comp (propertize comp 'face 'company-echo))
1941         (add-text-properties 0 (length company-common)
1942                              '(face company-echo-common) comp))
1943       (if (>= len limit)
1944           (setq candidates nil)
1945         (push comp msg)))
1946
1947     (mapconcat 'identity (nreverse msg) " ")))
1948
1949 (defun company-echo-strip-common-format ()
1950
1951   (let ((limit (window-width (minibuffer-window)))
1952         (len (+ (length company-prefix) 2))
1953         ;; Roll to selection.
1954         (candidates (nthcdr company-selection company-candidates))
1955         (i (if company-show-numbers company-selection 99999))
1956         msg comp)
1957
1958     (while candidates
1959       (setq comp (company-strip-prefix (pop candidates))
1960             len (+ len 2 (length comp)))
1961       (when (< i 10)
1962         ;; Add number.
1963         (setq comp (format "%s (%d)" comp i))
1964         (incf len 4)
1965         (incf i))
1966       (if (>= len limit)
1967           (setq candidates nil)
1968         (push (propertize comp 'face 'company-echo) msg)))
1969
1970     (concat (propertize company-prefix 'face 'company-echo-common) "{"
1971             (mapconcat 'identity (nreverse msg) ", ")
1972             "}")))
1973
1974 (defun company-echo-hide ()
1975   (unless (equal company-echo-last-msg "")
1976     (setq company-echo-last-msg "")
1977     (company-echo-show)))
1978
1979 (defun company-echo-frontend (command)
1980   "A `company-mode' front-end showing the candidates in the echo area."
1981   (case command
1982     (post-command (company-echo-show-soon 'company-echo-format))
1983     (hide (company-echo-hide))))
1984
1985 (defun company-echo-strip-common-frontend (command)
1986   "A `company-mode' front-end showing the candidates in the echo area."
1987   (case command
1988     (post-command (company-echo-show-soon 'company-echo-strip-common-format))
1989     (hide (company-echo-hide))))
1990
1991 (defun company-echo-metadata-frontend (command)
1992   "A `company-mode' front-end showing the documentation in the echo area."
1993   (case command
1994     (post-command (company-echo-show-when-idle 'company-fetch-metadata))
1995     (hide (company-echo-hide))))
1996
1997 ;; templates ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1998
1999 (autoload 'company-template-declare-template "company-template")
2000
2001 (provide 'company)
2002 ;;; company.el ends here