code.delx.au - gnu-emacs-elpa/blob - company-semantic.el

   1 ;;; company-semantic.el --- company-mode completion back-end using Semantic
   2
   3 ;; Copyright (C) 2009-2011, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (eval-when-compile (require 'cl))
  30
  31 (defvar semantic-idle-summary-function)
  32 (declare-function semantic-documentation-for-tag "semantic/doc" )
  33 (declare-function semantic-analyze-current-context "semantic/analyze")
  34 (declare-function semantic-analyze-possible-completions "semantic/complete")
  35 (declare-function semantic-analyze-find-tags-by-prefix "semantic/analyze/fcn")
  36 (declare-function semantic-tag-class "semantic/tag")
  37 (declare-function semantic-tag-name "semantic/tag")
  38 (declare-function semantic-tag-start "semantic/tag")
  39 (declare-function semantic-tag-buffer "semantic/tag")
  40 (declare-function semantic-active-p "semantic")
  41
  42 (defgroup company-semantic nil
  43   "Completion back-end using Semantic."
  44   :group 'company)
  45
  46 (defcustom company-semantic-metadata-function 'company-semantic-summary-and-doc
  47   "The function turning a semantic tag into doc information."
  48   :type 'function)
  49
  50 (defvar company-semantic-modes '(c-mode c++-mode jde-mode java-mode))
  51
  52 (defvar company-semantic--current-tags nil
  53   "Tags for the current context.")
  54
  55 (defun company-semantic-doc-or-summary (tag)
  56   (or (semantic-documentation-for-tag tag)
  57       (and (require 'semantic-idle nil t)
  58            (require 'semantic/idle nil t)
  59            (funcall semantic-idle-summary-function tag nil t))))
  60
  61 (defun company-semantic-summary-and-doc (tag)
  62   (let ((doc (semantic-documentation-for-tag tag))
  63         (summary (funcall semantic-idle-summary-function tag nil t)))
  64     (and (stringp doc)
  65          (string-match "\n*\\(.*\\)$" doc)
  66          (setq doc (match-string 1 doc)))
  67     (concat (funcall semantic-idle-summary-function tag nil t)
  68             (when doc
  69                   (if (< (+ (length doc) (length summary) 4) (window-width))
  70                       " -- "
  71                     "\n"))
  72             doc)))
  73
  74 (defun company-semantic-doc-buffer (tag)
  75   (let ((doc (semantic-documentation-for-tag tag)))
  76     (when doc
  77       (with-current-buffer (company-doc-buffer)
  78         (insert (funcall semantic-idle-summary-function tag nil t)
  79                 "\n"
  80                 doc)
  81         (current-buffer)))))
  82
  83 (defsubst company-semantic-completions (prefix)
  84   (ignore-errors
  85     (let ((completion-ignore-case nil)
  86           (context (semantic-analyze-current-context)))
  87       (setq company-semantic--current-tags
  88             (semantic-analyze-possible-completions context))
  89       (all-completions prefix company-semantic--current-tags))))
  90
  91 (defun company-semantic-completions-raw (prefix)
  92   (setq company-semantic--current-tags nil)
  93   (dolist (tag (semantic-analyze-find-tags-by-prefix prefix))
  94     (unless (eq (semantic-tag-class tag) 'include)
  95       (push tag company-semantic--current-tags)))
  96   (delete "" (mapcar 'semantic-tag-name company-semantic--current-tags)))
  97
  98 (defun company-semantic--pre-prefix-length (prefix-length)
  99   "Sum up the length of all chained symbols before POS.
 100 Symbols are chained by \".\" or \"->\"."
 101   (save-excursion
 102     (let ((pos (point)))
 103       (goto-char (- (point) prefix-length))
 104       (while (looking-back "->\\|\\.")
 105         (goto-char (match-beginning 0))
 106         (skip-syntax-backward "w_"))
 107       (- pos (point)))))
 108
 109 (defun company-semantic--grab ()
 110   "Grab the semantic prefix, but return everything before -> or . as length."
 111   (let ((symbol (company-grab-symbol)))
 112     (when symbol
 113       (cons symbol (company-semantic--pre-prefix-length (length symbol))))))
 114
 115 ;;;###autoload
 116 (defun company-semantic (command &optional arg &rest ignored)
 117   "`company-mode' completion back-end using CEDET Semantic."
 118   (interactive (list 'interactive))
 119   (case command
 120     (interactive (company-begin-backend 'company-semantic))
 121     (prefix (and (featurep 'semantic)
 122                  (semantic-active-p)
 123                  (memq major-mode company-semantic-modes)
 124                  (not (company-in-string-or-comment))
 125                  (or (company-semantic--grab) 'stop)))
 126     (candidates (if (and (equal arg "")
 127                          (not (looking-back "->\\|\\.")))
 128                     (company-semantic-completions-raw arg)
 129                   (company-semantic-completions arg)))
 130     (meta (funcall company-semantic-metadata-function
 131                    (assoc arg company-semantic--current-tags)))
 132     (doc-buffer (company-semantic-doc-buffer
 133                  (assoc arg company-semantic--current-tags)))
 134     ;; Because "" is an empty context and doesn't return local variables.
 135     (no-cache (equal arg ""))
 136     (location (let ((tag (assoc arg company-semantic--current-tags)))
 137                 (when (buffer-live-p (semantic-tag-buffer tag))
 138                   (cons (semantic-tag-buffer tag)
 139                         (semantic-tag-start tag)))))))
 140
 141 (provide 'company-semantic)
 142 ;;; company-semantic.el ends here