code.delx.au - gnu-emacs-elpa/blob - aggressive-indent.el

   1 ;;; aggressive-indent.el --- Minor mode to aggressively keep your code always indented
   2
   3 ;; Copyright (C) 2014 Artur Malabarba <bruce.connor.am@gmail.com>
   4
   5 ;; Author: Artur Malabarba <bruce.connor.am@gmail.com>
   6 ;; URL: http://github.com/Bruce-Connor/aggressive-indent-mode
   7 ;; Version: 0.3.3
   8 ;; Package-Requires: ((emacs "24.1") (names "0.5") (cl-lib "0.5"))
   9 ;; Keywords: indent lisp maint tools
  10 ;; Prefix: aggressive-indent
  11 ;; Separator: -
  12
  13 ;;; Commentary:
  14 ;;
  15 ;; `electric-indent-mode' is enough to keep your code nicely aligned when
  16 ;; all you do is type. However, once you start shifting blocks around,
  17 ;; transposing lines, or slurping and barfing sexps, indentation is bound
  18 ;; to go wrong.
  19 ;;
  20 ;; `aggressive-indent-mode' is a minor mode that keeps your code always
  21 ;; indented. It reindents after every command, making it more reliable
  22 ;; than `electric-indent-mode'.
  23 ;;
  24 ;; ### Instructions ###
  25 ;;
  26 ;; This package is available fom Melpa, you may install it by calling
  27 ;;
  28 ;;     M-x package-install RET aggressive-indent
  29 ;;
  30 ;; Then activate it with
  31 ;;
  32 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  33 ;;     (add-hook 'css-mode-hook #'aggressive-indent-mode)
  34 ;;
  35 ;; You can use this hook on any mode you want, `aggressive-indent' is not
  36 ;; exclusive to emacs-lisp code. In fact, if you want to turn it on for
  37 ;; every programming mode, you can do something like:
  38 ;;
  39 ;;     (global-aggressive-indent-mode 1)
  40 ;;     (add-to-list 'aggressive-indent-excluded-modes 'html-mode)
  41 ;;
  42 ;; ### Manual Installation ###
  43 ;;
  44 ;; If you don't want to install from Melpa, you can download it manually,
  45 ;; place it in your `load-path' and require it with
  46 ;;
  47 ;;     (require 'aggressive-indent)
  48
  49 ;;; Instructions:
  50 ;;
  51 ;; INSTALLATION
  52 ;;
  53 ;; This package is available fom Melpa, you may install it by calling
  54 ;; M-x package-install RET aggressive-indent.
  55 ;;
  56 ;; Then activate it with
  57 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  58 ;;
  59 ;; You can also use an equivalent hook for another mode,
  60 ;; `aggressive-indent' is not exclusive to emacs-lisp code.
  61 ;;
  62 ;; Alternatively, you can download it manually, place it in your
  63 ;; `load-path' and require it with
  64 ;;
  65 ;;     (require 'aggressive-indent)
  66
  67 ;;; License:
  68 ;;
  69 ;; This file is NOT part of GNU Emacs.
  70 ;;
  71 ;; This program is free software; you can redistribute it and/or
  72 ;; modify it under the terms of the GNU General Public License
  73 ;; as published by the Free Software Foundation; either version 2
  74 ;; of the License, or (at your option) any later version.
  75 ;;
  76 ;; This program is distributed in the hope that it will be useful,
  77 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  78 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  79 ;; GNU General Public License for more details.
  80 ;;
  81
  82 ;;; Change Log:
  83 ;; 0.3.1 - 2014/10/30 - Define new delete-backward bound to backspace.
  84 ;; 0.3   - 2014/10/23 - Implement a smarter engine for non-lisp modes.
  85 ;; 0.2   - 2014/10/20 - Reactivate `electric-indent-mode'.
  86 ;; 0.2   - 2014/10/19 - Add variable `aggressive-indent-dont-indent-if', so the user can prevent indentation.
  87 ;; 0.1   - 2014/10/15 - Release.
  88 ;;; Code:
  89
  90 (require 'cl-lib)
  91 (require 'names)
  92
  93 (defmacro aggressive-indent--do-softly (&rest body)
  94   "Execute body unobstrusively.
  95 This means:
  96  1. Do nothing in several situations, specified by
  97     `aggressive-indent-dont-indent-if' and
  98     `aggressive-indent--internal-dont-indent-if'.
  99  2. Silence all messages.
 100  3. Never throw errors.
 101 Meant for use in functions which go in hooks."
 102   (declare (debug t))
 103   `(unless (or (run-hook-wrapped
 104                 'aggressive-indent--internal-dont-indent-if
 105                 #'eval)
 106                (aggressive-indent--run-user-hooks))
 107      (cl-letf (((symbol-function 'message) #'ignore))
 108        (ignore-errors ,@body))))
 109
 110 ;;;###autoload
 111 (define-namespace aggressive-indent- :group indent
 112
 113 (defconst version "0.3.2" "Version of the aggressive-indent.el package.")
 114 (defun bug-report ()
 115   "Opens github issues page in a web browser. Please send any bugs you find.
 116 Please include your emacs and aggressive-indent versions."
 117   (interactive)
 118   (message "Your `aggressive-indent-version' is: %s, and your emacs version is: %s.
 119 Please include this in your report!"
 120            version emacs-version)
 121   (browse-url "https://github.com/Bruce-Connor/aggressive-indent-mode/issues/new"))
 122
 123 \f
 124 ;;; Start of actual Code:
 125 (defcustom dont-electric-modes '(ruby-mode)
 126   "List of major-modes where `electric-indent-mode' should be disabled."
 127   :type '(choice
 128           (const :tag "Never use `electric-indent-mode'." t)
 129           (repeat :tag "List of major-modes to avoid `electric-indent-mode'." symbol))
 130   :package-version '(aggressive-indent . "0.3.1"))
 131
 132 (defcustom excluded-modes
 133   '(
 134     bibtex-mode
 135     coffee-mode
 136     Custom-mode
 137     diff-mode
 138     erc-mode
 139     jabber-chat-mode
 140     haml-mode
 141     haskell-mode
 142     makefile-mode
 143     minibuffer-inactive-mode
 144     python-mode
 145     special-mode
 146     shell-mode
 147     snippet-mode
 148     eshell-mode
 149     tabulated-list-mode
 150     term-mode
 151     text-mode
 152     yaml-mode
 153     )
 154   "Modes in which `aggressive-indent-mode' should not be activated.
 155 This variable is only used if `global-aggressive-indent-mode' is
 156 active. If the minor mode is turned on with the local command,
 157 `aggressive-indent-mode', this variable is ignored."
 158   :type '(repeat symbol)
 159   :package-version '(aggressive-indent . "0.3.1"))
 160
 161 (defcustom protected-commands '(undo undo-tree-undo undo-tree-redo)
 162   "Commands after which indentation will NOT be performed.
 163 Aggressive indentation could break things like `undo' by locking
 164 the user in a loop, so this variable is used to control which
 165 commands will NOT be followed by a re-indent."
 166   :type '(repeat symbol)
 167   :package-version '(aggressive-indent . "0.1"))
 168
 169 (defcustom comments-too nil
 170   "If non-nil, aggressively indent in comments as well."
 171   :type 'boolean
 172   :package-version '(aggressive-indent . "0.3"))
 173
 174 (defvar -internal-dont-indent-if
 175   '((memq this-command aggressive-indent-protected-commands)
 176     (region-active-p)
 177     buffer-read-only
 178     (null (buffer-modified-p))
 179     (and (boundp 'smerge-mode) smerge-mode)
 180     (string-match "\\`[[:blank:]]*\n?\\'" (or (thing-at-point 'line) ""))
 181     (and (not aggressive-indent-comments-too)
 182          (aggressive-indent--in-comment-p))
 183     (aggressive-indent--in-string-p))
 184   "List of forms which prevent indentation when they evaluate to non-nil.
 185 This is for internal use only. For user customization, use
 186 `aggressive-indent-dont-indent-if' instead.")
 187
 188 (defcustom modes-to-prefer-defun '(emacs-lisp-mode lisp-mode scheme-mode)
 189   "List of major-modes in which indenting defun is preferred.
 190 Add here any major modes with very good definitions of
 191 `end-of-defun' and `beginning-of-defun', or modes which bug out
 192 if you have `after-change-functions' (such as paredit).
 193
 194 If current major mode is derived from one of these,
 195 `aggressive-indent-mode' will call
 196 `aggressive-indent-indent-defun' after every command. Otherwise,
 197 it will call `aggressive-indent-indent-region-and-on' after every
 198 buffer change."
 199   :type '(repeat symbol)
 200   :package-version '(aggressive-indent . "0.3"))
 201
 202 (eval-after-load 'yasnippet
 203   '(when (boundp 'yas--active-field-overlay)
 204      (add-to-list 'aggressive-indent--internal-dont-indent-if
 205                   '(and
 206                     (overlayp yas--active-field-overlay)
 207                     (overlay-end yas--active-field-overlay))
 208                   'append)))
 209 (eval-after-load 'company
 210   '(when (boundp 'company-candidates)
 211      (add-to-list 'aggressive-indent--internal-dont-indent-if
 212                   'company-candidates)))
 213 (eval-after-load 'auto-complete
 214   '(when (boundp 'ac-completing)
 215      (add-to-list 'aggressive-indent--internal-dont-indent-if
 216                   'ac-completing)))
 217
 218 (defcustom dont-indent-if '()
 219   "List of variables and functions to prevent aggressive indenting.
 220 This variable is a list where each element is a lisp form.
 221 As long as any one of these forms returns non-nil,
 222 aggressive-indent will not perform any indentation.
 223
 224 See `aggressive-indent--internal-dont-indent-if' for usage examples."
 225   :type '(repeat sexp)
 226   :group 'aggressive-indent
 227   :package-version '(aggressive-indent . "0.2"))
 228
 229 (defvar -error-message
 230   "One of the forms in `aggressive-indent-dont-indent-if' had the following error, I've disabled it until you fix it: %S"
 231   "Error message thrown by `aggressive-indent-dont-indent-if'.")
 232
 233 (defvar -has-errored nil
 234   "Keep track of whether `aggressive-indent-dont-indent-if' is throwing.
 235 This is used to prevent an infinite error loop on the user.")
 236
 237 (defun -run-user-hooks ()
 238   "Safely run forms in `aggressive-indent-dont-indent-if'.
 239 If any of them errors out, we only report it once until it stops
 240 erroring again."
 241   (and dont-indent-if
 242        (condition-case er
 243            (prog1 (eval (cons 'or dont-indent-if))
 244              (setq -has-errored nil))
 245          (error
 246           (unless -has-errored
 247             (setq -has-errored t)
 248             (message -error-message er))))))
 249
 250 :autoload
 251 (defun indent-defun ()
 252   "Indent current defun.
 253 Throw an error if parentheses are unbalanced."
 254   (interactive)
 255   (let ((p (point-marker)))
 256     (set-marker-insertion-type p t)
 257     (indent-region
 258      (save-excursion (beginning-of-defun 1) (point))
 259      (save-excursion (end-of-defun 1) (point)))
 260     (goto-char p)))
 261
 262 (defun -softly-indent-defun ()
 263   "Indent current defun unobstrusively.
 264 Like `aggressive-indent-indent-defun', but wrapped in a
 265 `aggressive-indent--do-softly'."
 266   (unless (or (run-hook-wrapped
 267                'aggressive-indent--internal-dont-indent-if
 268                #'eval)
 269               (aggressive-indent--run-user-hooks))
 270     (cl-letf (((symbol-function 'message) #'ignore))
 271       (ignore-errors (indent-defun)))))
 272
 273 :autoload
 274 (defun indent-region-and-on (l r)
 275   "Indent region between L and R, and then some.
 276 Call `indent-region' between L and R, and then keep indenting
 277 until nothing more happens."
 278   (interactive "r")
 279   (let ((p (point-marker))
 280         was-begining-of-line)
 281     (set-marker-insertion-type p t)
 282     (unwind-protect
 283         (progn
 284           (goto-char r)
 285           (setq was-begining-of-line
 286                 (= r (line-beginning-position)))
 287           ;; If L is at the end of a line, skip that line.
 288           (unless (= l r)
 289             (goto-char l)
 290             (when (= l (line-end-position))
 291               (cl-incf l)))
 292           ;; Indent the affected region.
 293           (unless (= l r) (indent-region l r))
 294           ;; `indent-region' doesn't do anything if R was the beginning of a line, so we indent manually there.
 295           (when was-begining-of-line
 296             (indent-according-to-mode))
 297           ;; And then we indent each following line until nothing happens.
 298           (forward-line 1)
 299           (while (and (null (eobp))
 300                       (/= (progn (skip-chars-forward "[:blank:]\n")
 301                                  (point))
 302                           (progn (indent-according-to-mode)
 303                                  (point))))
 304             (forward-line 1)))
 305       (goto-char p))))
 306
 307 (defun -softly-indent-region-and-on (l r &rest _)
 308   "Indent current defun unobstrusively.
 309 Like `aggressive-indent-indent-region-and-on', but wrapped in a
 310 `aggressive-indent--do-softly'."
 311   (unless (or (run-hook-wrapped
 312                'aggressive-indent--internal-dont-indent-if
 313                #'eval)
 314               (aggressive-indent--run-user-hooks))
 315     (cl-letf (((symbol-function 'message) #'ignore))
 316       (ignore-errors (indent-region-and-on l r)))))
 317
 318 (defvar -changed-list-right nil
 319   "List of right limit of regions changed in the last command loop.")
 320
 321 (defvar -changed-list-left nil
 322   "List of left limit of regions changed in the last command loop.")
 323
 324 (defun -indent-if-changed ()
 325   "Indent any region that changed in the last command loop."
 326   (let ((inhibit-modification-hooks t))
 327     (when -changed-list-left
 328       (-softly-indent-region-and-on
 329        (apply #'min -changed-list-left)
 330        (apply #'max -changed-list-right))
 331       (setq -changed-list-left nil
 332             -changed-list-right nil))))
 333
 334 (defun -keep-track-of-changes (l r &rest _)
 335   "Store the limits of each change that happens in the buffer."
 336   (push l -changed-list-left)
 337   (push r -changed-list-right))
 338
 339 (defun -in-comment-p ()
 340   "Return non-nil if point is inside a comment.
 341 Assumes that the syntax table is sufficient to find comments."
 342   (nth 4 (syntax-ppss)))
 343
 344 (defun -in-string-p ()
 345   "Return non-nil if point is inside a string.
 346 Assumes that the syntax table is sufficient for recognizing
 347 strings."
 348   (nth 3 (syntax-ppss)))
 349
 350 \f
 351 ;;; Minor modes
 352 :autoload
 353 (define-minor-mode mode nil nil " =>"
 354   '(("\ 3\11" . aggressive-indent-indent-defun)
 355     ([backspace] menu-item "maybe-delete-indentation" ignore
 356      :filter (lambda (&optional _)
 357                (when (and (looking-back "^[[:blank:]]+")
 358                           ;; Wherever we don't want to indent, we probably also
 359                           ;; want the default backspace behavior.
 360                           (not (run-hook-wrapped
 361                                 'aggressive-indent--internal-dont-indent-if
 362                                 #'eval))
 363                           (not (aggressive-indent--run-user-hooks)))
 364                  #'delete-indentation))))
 365   (if mode
 366       (if (and global-aggressive-indent-mode
 367                (or (cl-member-if #'derived-mode-p excluded-modes)
 368                    buffer-read-only))
 369           (mode -1)
 370         ;; Should electric indent be ON or OFF?
 371         (if (or (eq dont-electric-modes t)
 372                 (cl-member-if #'derived-mode-p dont-electric-modes))
 373             (-local-electric nil)
 374           (-local-electric t))
 375         (if (cl-member-if #'derived-mode-p modes-to-prefer-defun)
 376             (add-hook 'post-command-hook #'-softly-indent-defun nil 'local)
 377           (add-hook 'after-change-functions #'-keep-track-of-changes nil 'local)
 378           (add-hook 'post-command-hook #'-indent-if-changed nil 'local)))
 379     ;; Clean the hooks
 380     (remove-hook 'after-change-functions #'-keep-track-of-changes 'local)
 381     (remove-hook 'post-command-hook #'-indent-if-changed 'local)
 382     (remove-hook 'post-command-hook #'-softly-indent-defun 'local)))
 383
 384 (defun -local-electric (on)
 385   "Turn `electric-indent-mode' on or off locally, as given by boolean ON."
 386   (if (fboundp 'electric-indent-local-mode)
 387       (electric-indent-local-mode (if on 1 -1))
 388     (set (make-local-variable 'electric-indent-mode) on)))
 389
 390 :autoload
 391 (define-globalized-minor-mode global-aggressive-indent-mode
 392   mode mode)
 393
 394 :autoload
 395 (defalias 'aggressive-indent-global-mode
 396   #'global-aggressive-indent-mode)
 397 )
 398
 399 (provide 'aggressive-indent)
 400 ;;; aggressive-indent.el ends here.