code.delx.au - gnu-emacs-elpa/blob - company-clang.el

   1 ;;; company-clang.el --- company-mode completion back-end for Clang  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009, 2011, 2013-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'company-template)
  30 (require 'cl-lib)
  31
  32 (defgroup company-clang nil
  33   "Completion back-end for Clang."
  34   :group 'company)
  35
  36 (defcustom company-clang-executable
  37   (executable-find "clang")
  38   "Location of clang executable."
  39   :type 'file)
  40
  41 (defcustom company-clang-begin-after-member-access t
  42   "When non-nil, automatic completion will start whenever the current
  43 symbol is preceded by \".\", \"->\" or \"::\", ignoring
  44 `company-minimum-prefix-length'.
  45
  46 If `company-begin-commands' is a list, it should include `c-electric-lt-gt'
  47 and `c-electric-colon', for automatic completion right after \">\" and
  48 \":\".")
  49
  50 (defcustom company-clang-arguments nil
  51   "Additional arguments to pass to clang when completing.
  52 Prefix files (-include ...) can be selected with `company-clang-set-prefix'
  53 or automatically through a custom `company-clang-prefix-guesser'."
  54   :type '(repeat (string :tag "Argument")))
  55
  56 (defcustom company-clang-prefix-guesser 'company-clang-guess-prefix
  57   "A function to determine the prefix file for the current buffer."
  58   :type '(function :tag "Guesser function" nil))
  59
  60 (defvar company-clang-modes '(c-mode c++-mode objc-mode)
  61   "Major modes which clang may complete.")
  62
  63 (defcustom company-clang-insert-arguments t
  64   "When non-nil, insert function arguments as a template after completion."
  65   :type 'boolean
  66   :package-version '(company . "0.8.0"))
  67
  68 ;; prefix ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  69
  70 (defvar company-clang--prefix nil)
  71
  72 (defsubst company-clang--guess-pch-file (file)
  73   (let ((dir (directory-file-name (file-name-directory file))))
  74     (when (equal (file-name-nondirectory dir) "Classes")
  75       (setq dir (file-name-directory dir)))
  76     (car (directory-files dir t "\\([^.]h\\|[^h]\\).pch\\'" t))))
  77
  78 (defsubst company-clang--file-substring (file beg end)
  79   (with-temp-buffer
  80     (insert-file-contents-literally file nil beg end)
  81     (buffer-string)))
  82
  83 (defun company-clang-guess-prefix ()
  84   "Try to guess the prefix file for the current buffer."
  85   ;; Prefixes seem to be called .pch.  Pre-compiled headers do, too.
  86   ;; So we look at the magic number to rule them out.
  87   (let* ((file (company-clang--guess-pch-file buffer-file-name))
  88          (magic-number (and file (company-clang--file-substring file 0 4))))
  89     (unless (member magic-number '("CPCH" "gpch"))
  90       file)))
  91
  92 (defun company-clang-set-prefix (&optional prefix)
  93   "Use PREFIX as a prefix (-include ...) file for clang completion."
  94   (interactive (let ((def (funcall company-clang-prefix-guesser)))
  95      (unless (stringp def)
  96        (setq def default-directory))
  97      (list (read-file-name "Prefix file: "
  98                            (when def (file-name-directory def))
  99                            def t (when def (file-name-nondirectory def))))))
 100   ;; TODO: pre-compile?
 101   (setq company-clang--prefix (and (stringp prefix)
 102                                    (file-regular-p prefix)
 103                                    prefix)))
 104
 105 ;; Clean-up on exit.
 106 (add-hook 'kill-emacs-hook 'company-clang-set-prefix)
 107
 108 ;; parsing ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110 ;; TODO: Handle Pattern (syntactic hints would be neat).
 111 ;; Do we ever see OVERLOAD (or OVERRIDE)?
 112 (defconst company-clang--completion-pattern
 113   "^COMPLETION: \\_<\\(%s[a-zA-Z0-9_:<>]*\\)\\(?: : \\(.*\\)$\\)?$")
 114
 115 (defconst company-clang--error-buffer-name "*clang-error*")
 116
 117 (defun company-clang--lang-option ()
 118      (if (eq major-mode 'objc-mode)
 119          (if (string= "m" (file-name-extension buffer-file-name))
 120              "objective-c" "objective-c++")
 121        (substring (symbol-name major-mode) 0 -5)))
 122
 123 (defun company-clang--parse-output (prefix _objc)
 124   (goto-char (point-min))
 125   (let ((pattern (format company-clang--completion-pattern
 126                          (regexp-quote prefix)))
 127         (case-fold-search nil)
 128         lines match)
 129     (while (re-search-forward pattern nil t)
 130       (setq match (match-string-no-properties 1))
 131       (unless (equal match "Pattern")
 132         (save-match-data
 133           (when (string-match ":" match)
 134             (setq match (substring match 0 (match-beginning 0)))))
 135         (let ((meta (match-string-no-properties 2)))
 136           (when (and meta (not (string= match meta)))
 137             (put-text-property 0 1 'meta
 138                                (company-clang--strip-formatting meta)
 139                                match)))
 140         (push match lines)))
 141     lines))
 142
 143 (defun company-clang--meta (candidate)
 144   (get-text-property 0 'meta candidate))
 145
 146 (defun company-clang--annotation (candidate)
 147   (let ((meta (company-clang--meta candidate)))
 148     (cond
 149      ((null meta) nil)
 150      ((string-match "[^:]:[^:]" meta)
 151       (substring meta (1+ (match-beginning 0))))
 152      ((string-match "\\((.*)[ a-z]*\\'\\)" meta)
 153       (match-string 1 meta)))))
 154
 155 (defun company-clang--strip-formatting (text)
 156   (replace-regexp-in-string
 157    "#]" " "
 158    (replace-regexp-in-string "[<{[]#\\|#[>}]" "" text t)
 159    t))
 160
 161 (defun company-clang--handle-error (res args)
 162   (goto-char (point-min))
 163   (let* ((buf (get-buffer-create company-clang--error-buffer-name))
 164          (cmd (concat company-clang-executable " " (mapconcat 'identity args " ")))
 165          (pattern (format company-clang--completion-pattern ""))
 166          (err (if (re-search-forward pattern nil t)
 167                   (buffer-substring-no-properties (point-min)
 168                                                   (1- (match-beginning 0)))
 169                 ;; Warn the user more aggressively if no match was found.
 170                 (message "clang failed with error %d:\n%s" res cmd)
 171                 (buffer-string))))
 172
 173     (with-current-buffer buf
 174       (let ((inhibit-read-only t))
 175         (erase-buffer)
 176         (insert (current-time-string)
 177                 (format "\nclang failed with error %d:\n" res)
 178                 cmd "\n\n")
 179         (insert err)
 180         (setq buffer-read-only t)
 181         (goto-char (point-min))))))
 182
 183 (defun company-clang--start-process (prefix callback &rest args)
 184   (let ((objc (derived-mode-p 'objc-mode))
 185         (buf (get-buffer-create "*clang-output*"))
 186         (process-adaptive-read-buffering nil))
 187     (with-current-buffer buf (erase-buffer))
 188     (if (get-buffer-process buf)
 189         (funcall callback nil)
 190       (let ((process (apply #'start-process "company-clang" buf
 191                             company-clang-executable args)))
 192         (set-process-sentinel
 193          process
 194          (lambda (proc status)
 195            (unless (string-match-p "hangup" status)
 196              (funcall
 197               callback
 198               (let ((res (process-exit-status proc)))
 199                 (with-current-buffer buf
 200                   (unless (eq 0 res)
 201                     (company-clang--handle-error res args))
 202                   ;; Still try to get any useful input.
 203                   (company-clang--parse-output prefix objc)))))))
 204         (unless (company-clang--auto-save-p)
 205           (send-region process (point-min) (point-max))
 206           (send-string process "\n")
 207           (process-send-eof process))))))
 208
 209 (defsubst company-clang--build-location (pos)
 210   (save-excursion
 211     (goto-char pos)
 212     (format "%s:%d:%d"
 213             (if (company-clang--auto-save-p) buffer-file-name "-")
 214             (line-number-at-pos)
 215             (1+ (length
 216                  (encode-coding-region
 217                   (line-beginning-position)
 218                   (point)
 219                   'utf-8
 220                   t))))))
 221
 222 (defsubst company-clang--build-complete-args (pos)
 223   (append '("-fsyntax-only" "-Xclang" "-code-completion-macros")
 224           (unless (company-clang--auto-save-p)
 225             (list "-x" (company-clang--lang-option)))
 226           company-clang-arguments
 227           (when (stringp company-clang--prefix)
 228             (list "-include" (expand-file-name company-clang--prefix)))
 229           (list "-Xclang" (format "-code-completion-at=%s"
 230                                   (company-clang--build-location pos)))
 231           (list (if (company-clang--auto-save-p) buffer-file-name "-"))))
 232
 233 (defun company-clang--candidates (prefix callback)
 234   (and (company-clang--auto-save-p)
 235        (buffer-modified-p)
 236        (basic-save-buffer))
 237   (when (null company-clang--prefix)
 238     (company-clang-set-prefix (or (funcall company-clang-prefix-guesser)
 239                                   'none)))
 240   (apply 'company-clang--start-process
 241          prefix
 242          callback
 243          (company-clang--build-complete-args (- (point) (length prefix)))))
 244
 245 (defun company-clang--prefix ()
 246   (if company-clang-begin-after-member-access
 247       (company-grab-symbol-cons "\\.\\|->\\|::" 2)
 248     (company-grab-symbol)))
 249
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251
 252 (defconst company-clang-required-version 1.1)
 253
 254 (defvar company-clang--version nil)
 255
 256 (defun company-clang--auto-save-p ()
 257   (< company-clang--version 2.9))
 258
 259 (defsubst company-clang-version ()
 260   "Return the version of `company-clang-executable'."
 261   (with-temp-buffer
 262     (call-process company-clang-executable nil t nil "--version")
 263     (goto-char (point-min))
 264     (if (re-search-forward "clang\\(?: version \\|-\\)\\([0-9.]+\\)" nil t)
 265         (let ((ver (string-to-number (match-string-no-properties 1))))
 266           (if (> ver 100)
 267               (/ ver 100)
 268             ver))
 269       0)))
 270
 271 (defun company-clang-objc-templatify (selector)
 272   (let* ((end (point-marker))
 273          (beg (- (point) (length selector) 1))
 274          (templ (company-template-declare-template beg end))
 275          (cnt 0))
 276     (save-excursion
 277       (goto-char beg)
 278       (catch 'stop
 279         (while (search-forward ":" end t)
 280           (when (looking-at "([^)]*) ?")
 281             (delete-region (match-beginning 0) (match-end 0)))
 282           (company-template-add-field templ (point) (format "arg%d" cnt))
 283           (if (< (point) end)
 284               (insert " ")
 285             (throw 'stop t))
 286           (cl-incf cnt))))
 287     (company-template-move-to-first templ)))
 288
 289 (defun company-clang (command &optional arg &rest ignored)
 290   "`company-mode' completion back-end for Clang.
 291 Clang is a parser for C and ObjC.  Clang version 1.1 or newer is required.
 292
 293 Additional command line arguments can be specified in
 294 `company-clang-arguments'.  Prefix files (-include ...) can be selected
 295 with `company-clang-set-prefix' or automatically through a custom
 296 `company-clang-prefix-guesser'.
 297
 298 With Clang versions before 2.9, we have to save the buffer before
 299 performing completion.  With Clang 2.9 and later, buffer contents are
 300 passed via standard input."
 301   (interactive (list 'interactive))
 302   (cl-case command
 303     (interactive (company-begin-backend 'company-clang))
 304     (init (when (memq major-mode company-clang-modes)
 305             (unless company-clang-executable
 306               (error "Company found no clang executable"))
 307             (setq company-clang--version (company-clang-version))
 308             (when (< company-clang--version company-clang-required-version)
 309               (error "Company requires clang version 1.1"))))
 310     (prefix (and (memq major-mode company-clang-modes)
 311                  buffer-file-name
 312                  company-clang-executable
 313                  (not (company-in-string-or-comment))
 314                  (or (company-clang--prefix) 'stop)))
 315     (candidates (cons :async
 316                       (lambda (cb) (company-clang--candidates arg cb))))
 317     (meta       (company-clang--meta arg))
 318     (annotation (company-clang--annotation arg))
 319     (post-completion (let ((anno (company-clang--annotation arg)))
 320                        (when (and company-clang-insert-arguments anno)
 321                          (insert anno)
 322                          (if (string-match "\\`:[^:]" anno)
 323                              (company-clang-objc-templatify anno)
 324                            (company-template-c-like-templatify
 325                             (concat arg anno))))))))
 326
 327 (provide 'company-clang)
 328 ;;; company-clang.el ends here