code.delx.au - gnu-emacs-elpa/blob - company-eclim.el

   1 ;;; company-eclim.el --- company-mode completion back-end for Eclim
   2
   3 ;; Copyright (C) 2009, 2011, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23 ;;
  24 ;; Using `emacs-eclim' together with (or instead of) this back-end is
  25 ;; recommended, as it allows you to use other Eclim features.
  26 ;;
  27 ;; The alternative back-end provided by `emacs-eclim' uses `yasnippet'
  28 ;; instead of `company-template' to expand function calls, and it supports
  29 ;; some languages other than Java.
  30
  31 ;;; Code:
  32
  33 (require 'company)
  34 (require 'company-template)
  35 (eval-when-compile (require 'cl))
  36
  37 (defgroup company-eclim nil
  38   "Completion back-end for Eclim."
  39   :group 'company)
  40
  41 (defun company-eclim-executable-find ()
  42   (let (file)
  43     (dolist (eclipse-root '("/Applications/eclipse" "/usr/lib/eclipse"
  44                             "/usr/local/lib/eclipse"))
  45       (and (file-exists-p (setq file (expand-file-name "plugins" eclipse-root)))
  46            (setq file (car (last (directory-files file t "^org.eclim_"))))
  47            (file-exists-p (setq file (expand-file-name "bin/eclim" file)))
  48            (return file)))))
  49
  50 (defcustom company-eclim-executable
  51   (or (executable-find "eclim") (company-eclim-executable-find))
  52   "Location of eclim executable."
  53   :type 'file)
  54
  55 (defcustom company-eclim-auto-save t
  56   "Determines whether to save the buffer when retrieving completions.
  57 eclim can only complete correctly when the buffer has been saved."
  58   :type '(choice (const :tag "Off" nil)
  59                  (const :tag "On" t)))
  60
  61 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  62
  63 (defvar company-eclim--project-dir 'unknown)
  64 (make-variable-buffer-local 'company-eclim--project-dir)
  65
  66 (defvar company-eclim--project-name nil)
  67 (make-variable-buffer-local 'company-eclim--project-name)
  68
  69 (defvar company-eclim--doc nil)
  70 (make-variable-buffer-local 'company-eclim--doc)
  71
  72 (declare-function json-read "json")
  73
  74 (defun company-eclim--call-process (&rest args)
  75   (let ((coding-system-for-read 'utf-8)
  76         res)
  77     (require 'json)
  78     (with-temp-buffer
  79       (if (= 0 (setq res (apply 'call-process company-eclim-executable nil t nil
  80                                 "-command" args)))
  81           (let ((json-array-type 'list))
  82             (goto-char (point-min))
  83             (unless (eobp)
  84               (json-read)))
  85         (message "Company-eclim command failed with error %d:\n%s" res
  86                  (buffer-substring (point-min) (point-max)))
  87         nil))))
  88
  89 (defun company-eclim--project-list ()
  90   (company-eclim--call-process "project_list"))
  91
  92 (defun company-eclim--project-dir ()
  93   (if (eq company-eclim--project-dir 'unknown)
  94       (setq company-eclim--project-dir
  95             (directory-file-name
  96              (expand-file-name
  97               (company-locate-dominating-file buffer-file-name ".project"))))
  98     company-eclim--project-dir))
  99
 100 (defun company-eclim--project-name ()
 101   (or company-eclim--project-name
 102       (let ((dir (company-eclim--project-dir)))
 103         (when dir
 104           (setq company-eclim--project-name
 105                 (loop for project in (company-eclim--project-list)
 106                       when (equal (cdr (assoc 'path project)) dir)
 107                       return (cdr (assoc 'name project))))))))
 108
 109 (defun company-eclim--candidates (prefix)
 110   (interactive "d")
 111   (let ((project-file (file-relative-name buffer-file-name
 112                                           (company-eclim--project-dir)))
 113         (project-name (company-eclim--project-name)))
 114     (when company-eclim-auto-save
 115       (when (buffer-modified-p)
 116         (basic-save-buffer))
 117       ;; FIXME: Sometimes this isn't finished when we complete.
 118       (company-eclim--call-process "java_src_update"
 119                                    "-p" (company-eclim--project-name)
 120                                    "-f" project-file))
 121     (setq company-eclim--doc
 122           (make-hash-table :test 'equal))
 123     (dolist (item (cdr (assoc 'completions
 124                               (company-eclim--call-process
 125                                "java_complete" "-p" (company-eclim--project-name)
 126                                "-f" project-file
 127                                "-o" (number-to-string
 128                                      (company-eclim--search-point prefix))
 129                                "-e" "utf-8"
 130                                "-l" "standard"))))
 131       (let* ((meta (cdr (assoc 'info item)))
 132              (completion meta))
 133         (when (string-match " [:-]" completion)
 134           (setq completion (substring completion 0 (match-beginning 0))))
 135         (puthash completion meta company-eclim--doc))))
 136   (let ((completion-ignore-case nil))
 137     (all-completions prefix company-eclim--doc)))
 138
 139 (defun company-eclim--search-point (prefix)
 140   (if (or (plusp (length prefix)) (eq (char-before) ?.))
 141       (1- (point))
 142     (point)))
 143
 144 (defun company-eclim--meta (candidate)
 145   (gethash candidate company-eclim--doc))
 146
 147 (defun company-eclim--prefix ()
 148   (let ((prefix (company-grab-symbol)))
 149     (when prefix
 150       ;; Completion candidates for annotations don't include '@'.
 151       (when (eq ?@ (string-to-char prefix))
 152         (setq prefix (substring prefix 1)))
 153       prefix)))
 154
 155 (defun company-eclim (command &optional arg &rest ignored)
 156   "`company-mode' completion back-end for Eclim.
 157 Eclim provides access to Eclipse Java IDE features for other editors.
 158
 159 Eclim version 1.7.13 or newer (?) is required.
 160
 161 Completions only work correctly when the buffer has been saved.
 162 `company-eclim-auto-save' determines whether to do this automatically."
 163   (interactive (list 'interactive))
 164   (case command
 165     (interactive (company-begin-backend 'company-eclim))
 166     (prefix (and (derived-mode-p 'java-mode 'jde-mode)
 167                  buffer-file-name
 168                  company-eclim-executable
 169                  (company-eclim--project-name)
 170                  (not (company-in-string-or-comment))
 171                  (or (company-eclim--prefix) 'stop)))
 172     (candidates (company-eclim--candidates arg))
 173     (meta (company-eclim--meta arg))
 174     ;; because "" doesn't return everything
 175     (no-cache (equal arg ""))
 176     (crop (when (string-match "(" arg)
 177             (substring arg 0 (match-beginning 0))))
 178     (post-completion (when (string-match "([^)]" arg)
 179                        (company-template-c-like-templatify arg)))))
 180
 181 (provide 'company-eclim)
 182 ;;; company-eclim.el ends here