code.delx.au - gnu-emacs-elpa/blob - company-tests.el

   1 ;;; company-tests.el --- company-mode tests
   2
   3 ;; Copyright (C) 2011, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'ert)
  30 (require 'company)
  31 (require 'company-keywords)
  32 (require 'company-elisp)
  33 (require 'company-clang)
  34
  35 ;;; Core
  36
  37 (ert-deftest company-sorted-keywords ()
  38   "Test that keywords in `company-keywords-alist' are in alphabetical order."
  39   (dolist (pair company-keywords-alist)
  40     (when (consp (cdr pair))
  41       (let ((prev (cadr pair)))
  42         (dolist (next (cddr pair))
  43           (should (not (equal prev next)))
  44           (should (string< prev next))
  45           (setq prev next))))))
  46
  47 (ert-deftest company-good-prefix ()
  48   (let ((company-minimum-prefix-length 5)
  49         company--explicit-action)
  50     (should (eq t (company--good-prefix-p "!@#$%")))
  51     (should (eq nil (company--good-prefix-p "abcd")))
  52     (should (eq nil (company--good-prefix-p 'stop)))
  53     (should (eq t (company--good-prefix-p '("foo" . 5))))
  54     (should (eq nil (company--good-prefix-p '("foo" . 4))))))
  55
  56 (ert-deftest company-multi-backend-with-lambdas ()
  57   (let ((company-backend
  58          (list (lambda (command &optional arg &rest ignore)
  59                  (case command
  60                    (prefix "z")
  61                    (candidates '("a" "b"))))
  62                (lambda (command &optional arg &rest ignore)
  63                  (case command
  64                    (prefix "z")
  65                    (candidates '("c" "d")))))))
  66     (should (equal (company-call-backend 'candidates "z") '("a" "b" "c" "d")))))
  67
  68 (ert-deftest company-begin-backend-failure-doesnt-break-company-backends ()
  69   (with-temp-buffer
  70     (insert "a")
  71     (company-mode)
  72     (should-error
  73      (company-begin-backend (lambda (command &rest ignore))))
  74     (let (company-frontends
  75           (company-backends
  76            (list (lambda (command &optional arg)
  77                    (case command
  78                      (prefix "a")
  79                      (candidates '("a" "ab" "ac")))))))
  80       (let (this-command)
  81         (company-call 'complete))
  82       (should (eq 3 company-candidates-length)))))
  83
  84 (ert-deftest company-require-match-explicit ()
  85   (with-temp-buffer
  86     (insert "ab")
  87     (company-mode)
  88     (let (company-frontends
  89           (company-require-match 'company-explicit-action-p)
  90           (company-backends
  91            (list (lambda (command &optional arg)
  92                    (case command
  93                      (prefix (buffer-substring (point-min) (point)))
  94                      (candidates '("abc" "abd")))))))
  95       (let (this-command)
  96         (company-complete))
  97       (let ((last-command-event ?e))
  98         (company-call 'self-insert-command 1))
  99       (should (eq 2 company-candidates-length))
 100       (should (eq 3 (point))))))
 101
 102 (ert-deftest company-dont-require-match-when-idle ()
 103   (with-temp-buffer
 104     (insert "ab")
 105     (company-mode)
 106     (let (company-frontends
 107           (company-require-match 'company-explicit-action-p)
 108           (company-backends
 109            (list (lambda (command &optional arg)
 110                    (case command
 111                      (prefix (buffer-substring (point-min) (point)))
 112                      (candidates '("abc" "abd")))))))
 113       (company-idle-begin (current-buffer) (selected-window)
 114                           (buffer-chars-modified-tick) (point))
 115       (let ((last-command-event ?e))
 116         (company-call 'self-insert-command 1))
 117       (should (eq nil company-candidates-length))
 118       (should (eq 4 (point))))))
 119
 120 (ert-deftest company-auto-complete-explicit ()
 121   (with-temp-buffer
 122     (insert "ab")
 123     (company-mode)
 124     (let (company-frontends
 125           (company-auto-complete 'company-explicit-action-p)
 126           (company-auto-complete-chars '(? ))
 127           (company-backends
 128            (list (lambda (command &optional arg)
 129                    (case command
 130                      (prefix (buffer-substring (point-min) (point)))
 131                      (candidates '("abcd" "abef")))))))
 132       (let (this-command)
 133         (company-complete))
 134       (let ((last-command-event ? ))
 135         (company-call 'self-insert-command 1))
 136       (should (string= "abcd " (buffer-string))))))
 137
 138 (ert-deftest company-no-auto-complete-when-idle ()
 139   (with-temp-buffer
 140     (insert "ab")
 141     (company-mode)
 142     (let (company-frontends
 143           (company-auto-complete 'company-explicit-action-p)
 144           (company-auto-complete-chars '(? ))
 145           (company-backends
 146            (list (lambda (command &optional arg)
 147                    (case command
 148                      (prefix (buffer-substring (point-min) (point)))
 149                      (candidates '("abcd" "abef")))))))
 150       (company-idle-begin (current-buffer) (selected-window)
 151                           (buffer-chars-modified-tick) (point))
 152       (let ((last-command-event ? ))
 153         (company-call 'self-insert-command 1))
 154       (should (string= "ab " (buffer-string))))))
 155
 156 (ert-deftest company-clears-explicit-action-when-no-matches ()
 157   (with-temp-buffer
 158     (company-mode)
 159     (let (company-frontends
 160           company-backends)
 161       (company-call 'manual-begin) ;; fails
 162       (should (null company-candidates))
 163       (should (null (company-explicit-action-p))))))
 164
 165 (ert-deftest company-ignore-case-replaces-prefix ()
 166   (with-temp-buffer
 167     (company-mode)
 168     (let (company-frontends
 169           company-end-of-buffer-workaround
 170           (company-backends
 171            (list (lambda (command &optional arg)
 172                    (case command
 173                      (prefix (buffer-substring (point-min) (point)))
 174                      (candidates '("abcd" "abef"))
 175                      (ignore-case t))))))
 176       (insert "A")
 177       (let (this-command)
 178         (company-complete))
 179       (should (string= "ab" (buffer-string)))
 180       (delete-char -2)
 181       (insert "A") ; hack, to keep it in one test
 182       (company-complete-selection)
 183       (should (string= "abcd" (buffer-string))))))
 184
 185 (ert-deftest company-ignore-case-with-keep-prefix ()
 186   (with-temp-buffer
 187     (insert "AB")
 188     (company-mode)
 189     (let (company-frontends
 190           (company-backends
 191            (list (lambda (command &optional arg)
 192                    (case command
 193                      (prefix (buffer-substring (point-min) (point)))
 194                      (candidates '("abcd" "abef"))
 195                      (ignore-case 'keep-prefix))))))
 196       (let (this-command)
 197         (company-complete))
 198       (company-complete-selection)
 199       (should (string= "ABcd" (buffer-string))))))
 200
 201 (ert-deftest company-non-prefix-completion ()
 202   (with-temp-buffer
 203     (insert "tc")
 204     (company-mode)
 205     (let (company-frontends
 206           company-end-of-buffer-workaround
 207           (company-backends
 208            (list (lambda (command &optional arg)
 209                    (case command
 210                      (prefix (buffer-substring (point-min) (point)))
 211                      (candidates '("tea-cup" "teal-color")))))))
 212       (let (this-command)
 213         (company-complete))
 214       (should (string= "tc" (buffer-string)))
 215       (company-complete-selection)
 216       (should (string= "tea-cup" (buffer-string))))))
 217
 218 (ert-deftest company-pseudo-tooltip-does-not-get-displaced ()
 219   :tags '(interactive)
 220   (with-temp-buffer
 221     (save-window-excursion
 222       (set-window-buffer nil (current-buffer))
 223       (save-excursion (insert " ff"))
 224       (company-mode)
 225       (let ((company-frontends '(company-pseudo-tooltip-frontend))
 226             (company-begin-commands '(self-insert-command))
 227             (company-backends
 228              (list (lambda (c &optional arg)
 229                      (case c (prefix "") (candidates '("a" "b" "c")))))))
 230         (let (this-command)
 231           (company-call 'complete))
 232         (company-call 'open-line 1)
 233         (should (eq 2 (overlay-start company-pseudo-tooltip-overlay)))))))
 234
 235 (ert-deftest company-pseudo-tooltip-overlay-show ()
 236   :tags '(interactive)
 237   (with-temp-buffer
 238     (save-window-excursion
 239     (set-window-buffer nil (current-buffer))
 240     (insert "aaaa\n bb\nccccc\nddd")
 241     (search-backward "bb")
 242     (let ((col (company--column))
 243           (company-candidates-length 2)
 244           (company-candidates '("123" "45")))
 245       (company-pseudo-tooltip-show (company--row) col 0)
 246       (let ((ov company-pseudo-tooltip-overlay))
 247         (should (eq (overlay-get ov 'company-width) 3))
 248         ;; FIXME: Make it 2?
 249         (should (eq (overlay-get ov 'company-height) company-tooltip-limit))
 250         (should (eq (overlay-get ov 'company-column) col))
 251         (should (string= (overlay-get ov 'company-after)
 252                          " 123\nc45 c\nddd\n")))))))
 253
 254 (ert-deftest company-create-lines-shows-numbers ()
 255   (let ((company-show-numbers t)
 256         (company-candidates '("x" "y" "z"))
 257         (company-candidates-length 3))
 258     (should (equal '("x 1" "y 2" "z 3")
 259                    (company--create-lines 0 999)))))
 260
 261 (ert-deftest company-column-with-composition ()
 262   (with-temp-buffer
 263     (insert "lambda ()")
 264     (compose-region 1 (1+ (length "lambda")) "\\")
 265     (should (= (company--column) 4))))
 266
 267 (ert-deftest company-column-with-line-prefix ()
 268   (with-temp-buffer
 269     (insert "foo")
 270     (put-text-property (point-min) (point) 'line-prefix "  ")
 271     (should (= (company--column) 5))))
 272
 273 (ert-deftest company-column-wth-line-prefix-on-empty-line ()
 274   (with-temp-buffer
 275     (insert "\n")
 276     (forward-char -1)
 277     (put-text-property (point-min) (point-max) 'line-prefix "  ")
 278     (should (= (company--column) 2))))
 279
 280 (ert-deftest company-plainify ()
 281   (let ((tab-width 8))
 282     (should (equal-including-properties
 283              (company-plainify "\tabc\td\t")
 284              (concat "        "
 285                      "abc     "
 286                      "d       "))))
 287   (should (equal-including-properties
 288            (company-plainify (propertize "foobar" 'line-prefix "-*-"))
 289            "-*-foobar")))
 290
 291 (ert-deftest company-modify-line ()
 292   (let ((str "-*-foobar"))
 293     (should (equal-including-properties
 294              (company-modify-line str "zz" 4)
 295              "-*-fzzbar"))
 296     (should (equal-including-properties
 297              (company-modify-line str "xx" 0)
 298              "xx-foobar"))
 299     (should (equal-including-properties
 300              (company-modify-line str "zz" 10)
 301              "-*-foobar zz"))))
 302
 303 ;;; Template
 304
 305 (ert-deftest company-template-removed-after-the-last-jump ()
 306   (with-temp-buffer
 307     (insert "{ }")
 308     (goto-char 2)
 309     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 310       (save-excursion
 311         (dotimes (i 2)
 312           (insert " ")
 313           (company-template-add-field tpl (point) "foo")))
 314       (company-call 'template-forward-field)
 315       (should (= 3 (point)))
 316       (company-call 'template-forward-field)
 317       (should (= 7 (point)))
 318       (company-call 'template-forward-field)
 319       (should (= 11 (point)))
 320       (should (zerop (length (overlay-get tpl 'company-template-fields))))
 321       (should (null (overlay-buffer tpl))))))
 322
 323 (ert-deftest company-template-removed-after-input-and-jump ()
 324   (with-temp-buffer
 325     (insert "{ }")
 326     (goto-char 2)
 327     (let ((tpl (company-template-declare-template (point) (1- (point-max)))))
 328       (save-excursion
 329         (insert " ")
 330         (company-template-add-field tpl (point) "bar"))
 331       (company-call 'template-move-to-first tpl)
 332       (should (= 3 (point)))
 333       (dolist (c (string-to-list "tee"))
 334         (let ((last-command-event c))
 335           (company-call 'self-insert-command 1)))
 336       (should (string= "{ tee }" (buffer-string)))
 337       (should (overlay-buffer tpl))
 338       (company-call 'template-forward-field)
 339       (should (= 7 (point)))
 340       (should (null (overlay-buffer tpl))))))
 341
 342 (defun company-call (name &rest args)
 343   (let* ((maybe (intern (format "company-%s" name)))
 344          (command (if (fboundp maybe) maybe name)))
 345     (apply command args)
 346     (let ((this-command command))
 347       (run-hooks 'post-command-hook))))
 348
 349 (ert-deftest company-template-c-like-templatify ()
 350   (with-temp-buffer
 351     (let ((text "foo(int a, short b)"))
 352       (insert text)
 353       (company-template-c-like-templatify text)
 354       (should (equal "foo(arg0, arg1)" (buffer-string)))
 355       (should (looking-at "arg0"))
 356       (should (equal "int a"
 357                      (overlay-get (company-template-field-at) 'display))))))
 358
 359 (ert-deftest company-template-c-like-templatify-trims-after-closing-paren ()
 360   (with-temp-buffer
 361     (let ((text "foo(int a, short b)!@ #1334 a"))
 362       (insert text)
 363       (company-template-c-like-templatify text)
 364       (should (equal "foo(arg0, arg1)" (buffer-string)))
 365       (should (looking-at "arg0")))))
 366
 367 ;;; Elisp
 368
 369 (defmacro company-elisp-with-buffer (contents &rest body)
 370   (declare (indent 0))
 371   `(with-temp-buffer
 372      (insert ,contents)
 373      (setq major-mode 'emacs-lisp-mode)
 374      (re-search-backward "|")
 375      (replace-match "")
 376      (let ((company-elisp-detect-function-context t))
 377        ,@body)))
 378
 379 (ert-deftest company-elisp-candidates-predicate ()
 380   (company-elisp-with-buffer
 381     "(foo ba|)"
 382     (should (eq (company-elisp--candidates-predicate "ba")
 383                 'boundp))
 384     (should (eq (let (company-elisp-detect-function-context)
 385                   (company-elisp--candidates-predicate "ba"))
 386                 'company-elisp--predicate)))
 387   (company-elisp-with-buffer
 388     "(foo| )"
 389     (should (eq (company-elisp--candidates-predicate "foo")
 390                 'fboundp))
 391     (should (eq (let (company-elisp-detect-function-context)
 392                   (company-elisp--candidates-predicate "foo"))
 393                 'company-elisp--predicate)))
 394   (company-elisp-with-buffer
 395     "(foo 'b|)"
 396     (should (eq (company-elisp--candidates-predicate "b")
 397                 'company-elisp--predicate))))
 398
 399 (ert-deftest company-elisp-candidates-predicate-in-docstring ()
 400   (company-elisp-with-buffer
 401    "(def foo () \"Doo be doo `ide|"
 402    (should (eq 'company-elisp--predicate
 403                (company-elisp--candidates-predicate "ide")))))
 404
 405 ;; This one's also an integration test.
 406 (ert-deftest company-elisp-candidates-recognizes-binding-form ()
 407   (let ((company-elisp-detect-function-context t)
 408         (obarray [when what whelp])
 409         (what 1)
 410         (whelp 2)
 411         (wisp 3))
 412     (company-elisp-with-buffer
 413       "(let ((foo 7) (wh| )))"
 414       (should (equal '("what" "whelp")
 415                      (company-elisp-candidates "wh"))))
 416     (company-elisp-with-buffer
 417       "(cond ((null nil) (wh| )))"
 418       (should (equal '("when")
 419                      (company-elisp-candidates "wh"))))))
 420
 421 (ert-deftest company-elisp-candidates-predicate-binding-without-value ()
 422   (loop for (text prefix predicate) in '(("(let (foo|" "foo" boundp)
 423                                          ("(let (foo (bar|" "bar" boundp)
 424                                          ("(let (foo) (bar|" "bar" fboundp))
 425         do
 426         (eval `(company-elisp-with-buffer
 427                  ,text
 428                  (should (eq ',predicate
 429                              (company-elisp--candidates-predicate ,prefix)))))))
 430
 431 (ert-deftest company-elisp-finds-vars ()
 432   (let ((obarray [boo bar baz backquote])
 433         (boo t)
 434         (bar t)
 435         (baz t))
 436     (should (equal '("bar" "baz")
 437                    (company-elisp--globals "ba" 'boundp)))))
 438
 439 (ert-deftest company-elisp-finds-functions ()
 440   (let ((obarray [when what whelp])
 441         (what t)
 442         (whelp t))
 443     (should (equal '("when")
 444                    (company-elisp--globals "wh" 'fboundp)))))
 445
 446 (ert-deftest company-elisp-finds-things ()
 447   (let ((obarray [when what whelp])
 448         (what t)
 449         (whelp t))
 450     (should (equal '("what" "whelp" "when")
 451                    (sort (company-elisp--globals "wh" 'company-elisp--predicate)
 452                          'string<)))))
 453
 454 (ert-deftest company-elisp-locals-vars ()
 455   (company-elisp-with-buffer
 456     "(let ((foo 5) (bar 6))
 457        (cl-labels ((borg ()))
 458          (lambda (boo baz)
 459            b|)))"
 460     (should (equal '("bar" "baz" "boo")
 461                    (company-elisp--locals "b" nil)))))
 462
 463 (ert-deftest company-elisp-locals-single-var ()
 464   (company-elisp-with-buffer
 465     "(dotimes (itk 100)
 466        (dolist (item items)
 467          it|))"
 468     (should (equal '("itk" "item")
 469                    (company-elisp--locals "it" nil)))))
 470
 471 (ert-deftest company-elisp-locals-funs ()
 472   (company-elisp-with-buffer
 473     "(cl-labels ((foo ())
 474                  (fee ()))
 475        (let ((fun 4))
 476          (f| )))"
 477     (should (equal '("fee" "foo")
 478                    (sort (company-elisp--locals "f" t) 'string<)))))
 479
 480 (ert-deftest company-elisp-locals-skips-current-varlist ()
 481   (company-elisp-with-buffer
 482     "(let ((foo 1)
 483            (f| )))"
 484     (should (null (company-elisp--locals "f" nil)))))
 485
 486 (ert-deftest company-elisp-show-locals-first ()
 487   (company-elisp-with-buffer
 488     "(let ((floo 1)
 489            (flop 2)
 490            (flee 3))
 491        fl|)"
 492     (let ((obarray [float-pi]))
 493       (let (company-elisp-show-locals-first)
 494         (should (eq nil (company-elisp 'sorted))))
 495       (let ((company-elisp-show-locals-first t))
 496         (should (eq t (company-elisp 'sorted)))
 497         (should (equal '("flee" "floo" "flop" "float-pi")
 498                        (company-elisp-candidates "fl")))))))
 499
 500 (ert-deftest company-elisp-candidates-no-duplicates ()
 501   (company-elisp-with-buffer
 502     "(let ((float-pi 4))
 503        f|)"
 504     (let ((obarray [float-pi])
 505           (company-elisp-show-locals-first t))
 506       (should (equal '("float-pi") (company-elisp-candidates "f"))))))
 507
 508 (ert-deftest company-elisp-shouldnt-complete-defun-name ()
 509   (company-elisp-with-buffer
 510     "(defun foob|)"
 511     (should (null (company-elisp 'prefix)))))
 512
 513 (ert-deftest company-elisp-should-complete-def-call ()
 514   (company-elisp-with-buffer
 515     "(defu|"
 516     (should (equal "defu" (company-elisp 'prefix)))))
 517
 518 (ert-deftest company-elisp-should-complete-in-defvar ()
 519   ;; It will also complete the var name, at least for now.
 520   (company-elisp-with-buffer
 521     "(defvar abc de|"
 522     (should (equal "de" (company-elisp 'prefix)))))
 523
 524 (ert-deftest company-elisp-shouldnt-complete-in-defun-arglist ()
 525   (company-elisp-with-buffer
 526     "(defsubst foobar (ba|"
 527     (should (null (company-elisp 'prefix)))))
 528
 529 (ert-deftest company-elisp-prefix-in-defun-body ()
 530   (company-elisp-with-buffer
 531     "(defun foob ()|)"
 532     (should (equal "" (company-elisp 'prefix)))))
 533
 534 ;;; Clang
 535
 536 (ert-deftest company-clang-objc-templatify ()
 537   (with-temp-buffer
 538     (let ((text "createBookWithTitle:andAuthor:"))
 539       (insert text)
 540       (company-clang-objc-templatify text)
 541       (should (equal "createBookWithTitle:arg0 andAuthor:arg1" (buffer-string)))
 542       (should (looking-at "arg0"))
 543       (should (null (overlay-get (company-template-field-at) 'display))))))