code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular text completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; URL: http://company-mode.github.io/
   8 ;; Version: 0.8.8-cvs
   9 ;; Keywords: abbrev, convenience, matching
  10 ;; Package-Requires: ((emacs "24.1") (cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (pcase command
  52 ;;     (`prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (`meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;;; Change Log:
  62 ;;
  63 ;; See NEWS.md in the repository.
  64
  65 ;;; Code:
  66
  67 (require 'cl-lib)
  68 (require 'newcomment)
  69
  70 ;; FIXME: Use `user-error'.
  71 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  72 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  73 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  74 (add-to-list 'debug-ignored-errors "^Company not ")
  75 (add-to-list 'debug-ignored-errors "^No candidate number ")
  76 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  77 (add-to-list 'debug-ignored-errors "^No other back-end$")
  78
  79 ;;; Compatibility
  80 (eval-and-compile
  81   ;; `defvar-local' for Emacs 24.2 and below
  82   (unless (fboundp 'defvar-local)
  83     (defmacro defvar-local (var val &optional docstring)
  84       "Define VAR as a buffer-local variable with default value VAL.
  85 Like `defvar' but additionally marks the variable as being automatically
  86 buffer-local wherever it is set."
  87       (declare (debug defvar) (doc-string 3))
  88       `(progn
  89          (defvar ,var ,val ,docstring)
  90          (make-variable-buffer-local ',var)))))
  91
  92 (defgroup company nil
  93   "Extensible inline text completion mechanism"
  94   :group 'abbrev
  95   :group 'convenience
  96   :group 'matching)
  97
  98 (defface company-tooltip
  99   '((default :foreground "black")
 100     (((class color) (min-colors 88) (background light))
 101      (:background "cornsilk"))
 102     (((class color) (min-colors 88) (background dark))
 103      (:background "yellow")))
 104   "Face used for the tooltip.")
 105
 106 (defface company-tooltip-selection
 107   '((default :inherit company-tooltip)
 108     (((class color) (min-colors 88) (background light))
 109      (:background "light blue"))
 110     (((class color) (min-colors 88) (background dark))
 111      (:background "orange1"))
 112     (t (:background "green")))
 113   "Face used for the selection in the tooltip.")
 114
 115 (defface company-tooltip-search
 116   '((default :inherit company-tooltip-selection))
 117   "Face used for the search string in the tooltip.")
 118
 119 (defface company-tooltip-mouse
 120   '((default :inherit highlight))
 121   "Face used for the tooltip item under the mouse.")
 122
 123 (defface company-tooltip-common
 124   '((default :inherit company-tooltip)
 125     (((background light))
 126      :foreground "darkred")
 127     (((background dark))
 128      :foreground "red"))
 129   "Face used for the common completion in the tooltip.")
 130
 131 (defface company-tooltip-common-selection
 132   '((default :inherit company-tooltip-selection)
 133     (((background light))
 134      :foreground "darkred")
 135     (((background dark))
 136      :foreground "red"))
 137   "Face used for the selected common completion in the tooltip.")
 138
 139 (defface company-tooltip-annotation
 140   '((default :inherit company-tooltip)
 141     (((background light))
 142      :foreground "firebrick4")
 143     (((background dark))
 144      :foreground "red4"))
 145   "Face used for the annotation in the tooltip.")
 146
 147 (defface company-scrollbar-fg
 148   '((((background light))
 149      :background "darkred")
 150     (((background dark))
 151      :background "red"))
 152   "Face used for the tooltip scrollbar thumb.")
 153
 154 (defface company-scrollbar-bg
 155   '((default :inherit company-tooltip)
 156     (((background light))
 157      :background "wheat")
 158     (((background dark))
 159      :background "gold"))
 160   "Face used for the tooltip scrollbar background.")
 161
 162 (defface company-preview
 163   '((((background light))
 164      :inherit company-tooltip-selection)
 165     (((background dark))
 166      :background "blue4"
 167      :foreground "wheat"))
 168   "Face used for the completion preview.")
 169
 170 (defface company-preview-common
 171   '((((background light))
 172      :inherit company-tooltip-selection)
 173     (((background dark))
 174      :inherit company-preview
 175      :foreground "red"))
 176   "Face used for the common part of the completion preview.")
 177
 178 (defface company-preview-search
 179   '((((background light))
 180      :inherit company-tooltip-common-selection)
 181     (((background dark))
 182      :inherit company-preview
 183      :background "blue1"))
 184   "Face used for the search string in the completion preview.")
 185
 186 (defface company-echo nil
 187   "Face used for completions in the echo area.")
 188
 189 (defface company-echo-common
 190   '((((background dark)) (:foreground "firebrick1"))
 191     (((background light)) (:background "firebrick4")))
 192   "Face used for the common part of completions in the echo area.")
 193
 194 (defun company-frontends-set (variable value)
 195   ;; Uniquify.
 196   (let ((value (delete-dups (copy-sequence value))))
 197     (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 198          (memq 'company-pseudo-tooltip-frontend value)
 199          (error "Pseudo tooltip frontend cannot be used twice"))
 200     (and (memq 'company-preview-if-just-one-frontend value)
 201          (memq 'company-preview-frontend value)
 202          (error "Preview frontend cannot be used twice"))
 203     (and (memq 'company-echo value)
 204          (memq 'company-echo-metadata-frontend value)
 205          (error "Echo area cannot be used twice"))
 206     ;; Preview must come last.
 207     (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 208       (when (cdr (memq f value))
 209         (setq value (append (delq f value) (list f)))))
 210     (set variable value)))
 211
 212 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 213                                company-preview-if-just-one-frontend
 214                                company-echo-metadata-frontend)
 215   "The list of active front-ends (visualizations).
 216 Each front-end is a function that takes one argument.  It is called with
 217 one of the following arguments:
 218
 219 `show': When the visualization should start.
 220
 221 `hide': When the visualization should end.
 222
 223 `update': When the data has been updated.
 224
 225 `pre-command': Before every command that is executed while the
 226 visualization is active.
 227
 228 `post-command': After every command that is executed while the
 229 visualization is active.
 230
 231 The visualized data is stored in `company-prefix', `company-candidates',
 232 `company-common', `company-selection', `company-point' and
 233 `company-search-string'."
 234   :set 'company-frontends-set
 235   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 236                          (const :tag "echo, strip common"
 237                                 company-echo-strip-common-frontend)
 238                          (const :tag "show echo meta-data in echo"
 239                                 company-echo-metadata-frontend)
 240                          (const :tag "pseudo tooltip"
 241                                 company-pseudo-tooltip-frontend)
 242                          (const :tag "pseudo tooltip, multiple only"
 243                                 company-pseudo-tooltip-unless-just-one-frontend)
 244                          (const :tag "preview" company-preview-frontend)
 245                          (const :tag "preview, unique only"
 246                                 company-preview-if-just-one-frontend)
 247                          (function :tag "custom function" nil))))
 248
 249 (defcustom company-tooltip-limit 10
 250   "The maximum number of candidates in the tooltip."
 251   :type 'integer)
 252
 253 (defcustom company-tooltip-minimum 6
 254   "The minimum height of the tooltip.
 255 If this many lines are not available, prefer to display the tooltip above."
 256   :type 'integer)
 257
 258 (defcustom company-tooltip-minimum-width 0
 259   "The minimum width of the tooltip's inner area.
 260 This doesn't include the margins and the scroll bar."
 261   :type 'integer
 262   :package-version '(company . "0.8.0"))
 263
 264 (defcustom company-tooltip-margin 1
 265   "Width of margin columns to show around the toolip."
 266   :type 'integer)
 267
 268 (defcustom company-tooltip-offset-display 'scrollbar
 269   "Method using which the tooltip displays scrolling position.
 270 `scrollbar' means draw a scrollbar to the right of the items.
 271 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 272   :type '(choice (const :tag "Scrollbar" scrollbar)
 273                  (const :tag "Two lines" lines)))
 274
 275 (defcustom company-tooltip-align-annotations nil
 276   "When non-nil, align annotations to the right tooltip border."
 277   :type 'boolean
 278   :package-version '(company . "0.7.1"))
 279
 280 (defcustom company-tooltip-flip-when-above nil
 281   "Whether to flip the tooltip when it's above the current line."
 282   :type 'boolean
 283   :package-version '(company . "0.8.1"))
 284
 285 (defvar company-safe-backends
 286   '((company-abbrev . "Abbrev")
 287     (company-bbdb . "BBDB")
 288     (company-capf . "completion-at-point-functions")
 289     (company-clang . "Clang")
 290     (company-cmake . "CMake")
 291     (company-css . "CSS")
 292     (company-dabbrev . "dabbrev for plain text")
 293     (company-dabbrev-code . "dabbrev for code")
 294     (company-eclim . "Eclim (an Eclipse interface)")
 295     (company-elisp . "Emacs Lisp")
 296     (company-etags . "etags")
 297     (company-files . "Files")
 298     (company-gtags . "GNU Global")
 299     (company-ispell . "Ispell")
 300     (company-keywords . "Programming language keywords")
 301     (company-nxml . "nxml")
 302     (company-oddmuse . "Oddmuse")
 303     (company-pysmell . "PySmell")
 304     (company-ropemacs . "ropemacs")
 305     (company-semantic . "Semantic")
 306     (company-tempo . "Tempo templates")
 307     (company-xcode . "Xcode")))
 308 (put 'company-safe-backends 'risky-local-variable t)
 309
 310 (defun company-safe-backends-p (backends)
 311   (and (consp backends)
 312        (not (cl-dolist (backend backends)
 313               (unless (if (consp backend)
 314                           (company-safe-backends-p backend)
 315                         (assq backend company-safe-backends))
 316                 (cl-return t))))))
 317
 318 (defcustom company-backends `(,@(unless (version< "24.3.50" emacs-version)
 319                                   (list 'company-elisp))
 320                               company-bbdb
 321                               company-nxml company-css
 322                               company-eclim company-semantic company-clang
 323                               company-xcode company-ropemacs company-cmake
 324                               company-capf
 325                               (company-dabbrev-code company-gtags company-etags
 326                                company-keywords)
 327                               company-oddmuse company-files company-dabbrev)
 328   "The list of active back-ends (completion engines).
 329
 330 Only one back-end is used at a time.  The choice depends on the order of
 331 the items in this list, and on the values they return in response to the
 332 `prefix' command (see below).  But a back-end can also be a \"grouped\"
 333 one (see below).
 334
 335 `company-begin-backend' can be used to start a specific back-end,
 336 `company-other-backend' will skip to the next matching back-end in the list.
 337
 338 Each back-end is a function that takes a variable number of arguments.
 339 The first argument is the command requested from the back-end.  It is one
 340 of the following:
 341
 342 `prefix': The back-end should return the text to be completed.  It must be
 343 text immediately before point.  Returning nil from this command passes
 344 control to the next back-end.  The function should return `stop' if it
 345 should complete but cannot (e.g. if it is in the middle of a string).
 346 Instead of a string, the back-end may return a cons where car is the prefix
 347 and cdr is used in `company-minimum-prefix-length' test.  It must be either
 348 number or t, and in the latter case the test automatically succeeds.
 349
 350 `candidates': The second argument is the prefix to be completed.  The
 351 return value should be a list of candidates that match the prefix.
 352
 353 Non-prefix matches are also supported (candidates that don't start with the
 354 prefix, but match it in some backend-defined way).  Backends that use this
 355 feature must disable cache (return t to `no-cache') and might also want to
 356 respond to `match'.
 357
 358 Optional commands:
 359
 360 `sorted': Return t here to indicate that the candidates are sorted and will
 361 not need to be sorted again.
 362
 363 `duplicates': If non-nil, company will take care of removing duplicates
 364 from the list.
 365
 366 `no-cache': Usually company doesn't ask for candidates again as completion
 367 progresses, unless the back-end returns t for this command.  The second
 368 argument is the latest prefix.
 369
 370 `meta': The second argument is a completion candidate.  Return a (short)
 371 documentation string for it.
 372
 373 `doc-buffer': The second argument is a completion candidate.  Return a
 374 buffer with documentation for it.  Preferably use `company-doc-buffer',
 375
 376 `location': The second argument is a completion candidate.  Return the cons
 377 of buffer and buffer location, or of file and line number where the
 378 completion candidate was defined.
 379
 380 `annotation': The second argument is a completion candidate.  Return a
 381 string to be displayed inline with the candidate in the popup.  If
 382 duplicates are removed by company, candidates with equal string values will
 383 be kept if they have different annotations.  For that to work properly,
 384 backends should store the related information on candidates using text
 385 properties.
 386
 387 `match': The second argument is a completion candidate.  Return the index
 388 after the end of text matching `prefix' within the candidate string.  It
 389 will be used when rendering the popup.  This command only makes sense for
 390 backends that provide non-prefix completion.
 391
 392 `require-match': If this returns t, the user is not allowed to enter
 393 anything not offered as a candidate.  Use with care!  The default value nil
 394 gives the user that choice with `company-require-match'.  Return value
 395 `never' overrides that option the other way around.
 396
 397 `init': Called once for each buffer. The back-end can check for external
 398 programs and files and load any required libraries.  Raising an error here
 399 will show up in message log once, and the back-end will not be used for
 400 completion.
 401
 402 `post-completion': Called after a completion candidate has been inserted
 403 into the buffer.  The second argument is the candidate.  Can be used to
 404 modify it, e.g. to expand a snippet.
 405
 406 The back-end should return nil for all commands it does not support or
 407 does not know about.  It should also be callable interactively and use
 408 `company-begin-backend' to start itself in that case.
 409
 410 Grouped back-ends:
 411
 412 An element of `company-backends' can also itself be a list of back-ends,
 413 then it's considered to be a \"grouped\" back-end.
 414
 415 When possible, commands taking a candidate as an argument are dispatched to
 416 the back-end it came from.  In other cases, the first non-nil value among
 417 all the back-ends is returned.
 418
 419 The latter is the case for the `prefix' command.  But if the group contains
 420 the keyword `:with', the back-ends after it are ignored for this command.
 421
 422 The completions from back-ends in a group are merged (but only from those
 423 that return the same `prefix').
 424
 425 Asynchronous back-ends:
 426
 427 The return value of each command can also be a cons (:async . FETCHER)
 428 where FETCHER is a function of one argument, CALLBACK.  When the data
 429 arrives, FETCHER must call CALLBACK and pass it the appropriate return
 430 value, as described above.
 431
 432 True asynchronous operation is only supported for command `candidates', and
 433 only during idle completion.  Other commands will block the user interface,
 434 even if the back-end uses the asynchronous calling convention."
 435   :type `(repeat
 436           (choice
 437            :tag "Back-end"
 438            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 439                      company-safe-backends)
 440            (symbol :tag "User defined")
 441            (repeat :tag "Merged Back-ends"
 442                    (choice :tag "Back-end"
 443                            ,@(mapcar (lambda (b)
 444                                        `(const :tag ,(cdr b) ,(car b)))
 445                                      company-safe-backends)
 446                            (const :tag "With" :with)
 447                            (symbol :tag "User defined"))))))
 448
 449 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 450
 451 (defcustom company-transformers nil
 452   "Functions to change the list of candidates received from backends,
 453 after sorting and removal of duplicates (if appropriate).
 454 Each function gets called with the return value of the previous one."
 455   :type '(choice
 456           (const :tag "None" nil)
 457           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 458           (const :tag "Sort by back-end importance"
 459                  (company-sort-by-backend-importance))
 460           (repeat :tag "User defined" (function))))
 461
 462 (defcustom company-completion-started-hook nil
 463   "Hook run when company starts completing.
 464 The hook is called with one argument that is non-nil if the completion was
 465 started manually."
 466   :type 'hook)
 467
 468 (defcustom company-completion-cancelled-hook nil
 469   "Hook run when company cancels completing.
 470 The hook is called with one argument that is non-nil if the completion was
 471 aborted manually."
 472   :type 'hook)
 473
 474 (defcustom company-completion-finished-hook nil
 475   "Hook run when company successfully completes.
 476 The hook is called with the selected candidate as an argument.
 477
 478 If you indend to use it to post-process candidates from a specific
 479 back-end, consider using the `post-completion' command instead."
 480   :type 'hook)
 481
 482 (defcustom company-minimum-prefix-length 3
 483   "The minimum prefix length for idle completion."
 484   :type '(integer :tag "prefix length"))
 485
 486 (defcustom company-abort-manual-when-too-short nil
 487   "If enabled, cancel a manually started completion when the prefix gets
 488 shorter than both `company-minimum-prefix-length' and the length of the
 489 prefix it was started from."
 490   :type 'boolean
 491   :package-version '(company . "0.8.0"))
 492
 493 (defcustom company-require-match 'company-explicit-action-p
 494   "If enabled, disallow non-matching input.
 495 This can be a function do determine if a match is required.
 496
 497 This can be overridden by the back-end, if it returns t or `never' to
 498 `require-match'.  `company-auto-complete' also takes precedence over this."
 499   :type '(choice (const :tag "Off" nil)
 500                  (function :tag "Predicate function")
 501                  (const :tag "On, if user interaction took place"
 502                         'company-explicit-action-p)
 503                  (const :tag "On" t)))
 504
 505 (defcustom company-auto-complete nil
 506   "Determines when to auto-complete.
 507 If this is enabled, all characters from `company-auto-complete-chars'
 508 trigger insertion of the selected completion candidate.
 509 This can also be a function."
 510   :type '(choice (const :tag "Off" nil)
 511                  (function :tag "Predicate function")
 512                  (const :tag "On, if user interaction took place"
 513                         'company-explicit-action-p)
 514                  (const :tag "On" t)))
 515
 516 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 517   "Determines which characters trigger auto-completion.
 518 See `company-auto-complete'.  If this is a string, each string character
 519 tiggers auto-completion.  If it is a list of syntax description characters (see
 520 `modify-syntax-entry'), all characters with that syntax auto-complete.
 521
 522 This can also be a function, which is called with the new input and should
 523 return non-nil if company should auto-complete.
 524
 525 A character that is part of a valid candidate never triggers auto-completion."
 526   :type '(choice (string :tag "Characters")
 527                  (set :tag "Syntax"
 528                       (const :tag "Whitespace" ?\ )
 529                       (const :tag "Symbol" ?_)
 530                       (const :tag "Opening parentheses" ?\()
 531                       (const :tag "Closing parentheses" ?\))
 532                       (const :tag "Word constituent" ?w)
 533                       (const :tag "Punctuation." ?.)
 534                       (const :tag "String quote." ?\")
 535                       (const :tag "Paired delimiter." ?$)
 536                       (const :tag "Expression quote or prefix operator." ?\')
 537                       (const :tag "Comment starter." ?<)
 538                       (const :tag "Comment ender." ?>)
 539                       (const :tag "Character-quote." ?/)
 540                       (const :tag "Generic string fence." ?|)
 541                       (const :tag "Generic comment fence." ?!))
 542                  (function :tag "Predicate function")))
 543
 544 (defcustom company-idle-delay .5
 545   "The idle delay in seconds until completion starts automatically.
 546 The prefix still has to satisfy `company-minimum-prefix-length' before that
 547 happens.  The value of nil means no idle completion."
 548   :type '(choice (const :tag "never (nil)" nil)
 549                  (const :tag "immediate (0)" 0)
 550                  (number :tag "seconds")))
 551
 552 (defcustom company-begin-commands '(self-insert-command
 553                                     org-self-insert-command
 554                                     orgtbl-self-insert-command
 555                                     c-scope-operator
 556                                     c-electric-colon
 557                                     c-electric-lt-gt
 558                                     c-electric-slash)
 559   "A list of commands after which idle completion is allowed.
 560 If this is t, it can show completions after any command except a few from a
 561 pre-defined list.  See `company-idle-delay'.
 562
 563 Alternatively, any command with a non-nil `company-begin' property is
 564 treated as if it was on this list."
 565   :type '(choice (const :tag "Any command" t)
 566                  (const :tag "Self insert command" '(self-insert-command))
 567                  (repeat :tag "Commands" function))
 568   :package-version '(company . "0.8.4"))
 569
 570 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 571                                            save-buffers-kill-terminal
 572                                            save-buffers-kill-emacs)
 573   "A list of commands that are allowed during completion.
 574 If this is t, or if `company-begin-commands' is t, any command is allowed.
 575 Otherwise, the value must be a list of symbols.  If it starts with `not',
 576 the cdr is the list of commands that abort completion.  Otherwise, all
 577 commands except those in that list, or in `company-begin-commands', or
 578 commands in the `company-' namespace, abort completion."
 579   :type '(choice (const :tag "Any command" t)
 580                  (cons  :tag "Any except"
 581                         (const not)
 582                         (repeat :tag "Commands" function))
 583                  (repeat :tag "Commands" function)))
 584
 585 (defcustom company-show-numbers nil
 586   "If enabled, show quick-access numbers for the first ten candidates."
 587   :type '(choice (const :tag "off" nil)
 588                  (const :tag "on" t)))
 589
 590 (defcustom company-selection-wrap-around nil
 591   "If enabled, selecting item before first or after last wraps around."
 592   :type '(choice (const :tag "off" nil)
 593                  (const :tag "on" t)))
 594
 595 (defvar company-async-wait 0.03
 596   "Pause between checks to see if the value's been set when turning an
 597 asynchronous call into synchronous.")
 598
 599 (defvar company-async-timeout 2
 600   "Maximum wait time for a value to be set during asynchronous call.")
 601
 602 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 603
 604 (defvar company-mode-map (make-sparse-keymap)
 605   "Keymap used by `company-mode'.")
 606
 607 (defvar company-active-map
 608   (let ((keymap (make-sparse-keymap)))
 609     (define-key keymap "\e\e\e" 'company-abort)
 610     (define-key keymap "\C-g" 'company-abort)
 611     (define-key keymap (kbd "M-n") 'company-select-next)
 612     (define-key keymap (kbd "M-p") 'company-select-previous)
 613     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 614     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 615     (define-key keymap [down-mouse-1] 'ignore)
 616     (define-key keymap [down-mouse-3] 'ignore)
 617     (define-key keymap [mouse-1] 'company-complete-mouse)
 618     (define-key keymap [mouse-3] 'company-select-mouse)
 619     (define-key keymap [up-mouse-1] 'ignore)
 620     (define-key keymap [up-mouse-3] 'ignore)
 621     (define-key keymap [return] 'company-complete-selection)
 622     (define-key keymap (kbd "RET") 'company-complete-selection)
 623     (define-key keymap [tab] 'company-complete-common)
 624     (define-key keymap (kbd "TAB") 'company-complete-common)
 625     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 626     (define-key keymap (kbd "C-h") 'company-show-doc-buffer)
 627     (define-key keymap "\C-w" 'company-show-location)
 628     (define-key keymap "\C-s" 'company-search-candidates)
 629     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 630     (dotimes (i 10)
 631       (define-key keymap (read-kbd-macro (format "M-%d" i)) 'company-complete-number))
 632      keymap)
 633   "Keymap that is enabled during an active completion.")
 634
 635 (defvar company--disabled-backends nil)
 636
 637 (defun company-init-backend (backend)
 638   (and (symbolp backend)
 639        (not (fboundp backend))
 640        (ignore-errors (require backend nil t)))
 641   (cond
 642    ((symbolp backend)
 643     (condition-case err
 644         (progn
 645           (funcall backend 'init)
 646           (put backend 'company-init t))
 647       (error
 648        (put backend 'company-init 'failed)
 649        (unless (memq backend company--disabled-backends)
 650          (message "Company back-end '%s' could not be initialized:\n%s"
 651                   backend (error-message-string err)))
 652        (cl-pushnew backend company--disabled-backends)
 653        nil)))
 654    ;; No initialization for lambdas.
 655    ((functionp backend) t)
 656    (t ;; Must be a list.
 657     (cl-dolist (b backend)
 658       (unless (keywordp b)
 659         (company-init-backend b))))))
 660
 661 (defvar company-default-lighter " company")
 662
 663 (defvar-local company-lighter company-default-lighter)
 664
 665 ;;;###autoload
 666 (define-minor-mode company-mode
 667   "\"complete anything\"; is an in-buffer completion framework.
 668 Completion starts automatically, depending on the values
 669 `company-idle-delay' and `company-minimum-prefix-length'.
 670
 671 Completion can be controlled with the commands:
 672 `company-complete-common', `company-complete-selection', `company-complete',
 673 `company-select-next', `company-select-previous'.  If these commands are
 674 called before `company-idle-delay', completion will also start.
 675
 676 Completions can be searched with `company-search-candidates' or
 677 `company-filter-candidates'.  These can be used while completion is
 678 inactive, as well.
 679
 680 The completion data is retrieved using `company-backends' and displayed
 681 using `company-frontends'.  If you want to start a specific back-end, call
 682 it interactively or use `company-begin-backend'.
 683
 684 regular keymap (`company-mode-map'):
 685
 686 \\{company-mode-map}
 687 keymap during active completions (`company-active-map'):
 688
 689 \\{company-active-map}"
 690   nil company-lighter company-mode-map
 691   (if company-mode
 692       (progn
 693         (when (eq company-idle-delay t)
 694           (setq company-idle-delay 0)
 695           (warn "Setting `company-idle-delay' to t is deprecated.  Set it to 0 instead."))
 696         (add-hook 'pre-command-hook 'company-pre-command nil t)
 697         (add-hook 'post-command-hook 'company-post-command nil t)
 698         (mapc 'company-init-backend company-backends))
 699     (remove-hook 'pre-command-hook 'company-pre-command t)
 700     (remove-hook 'post-command-hook 'company-post-command t)
 701     (company-cancel)
 702     (kill-local-variable 'company-point)))
 703
 704 (defcustom company-global-modes t
 705   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 706 If nil, means no modes.  If t, then all major modes have it turned on.
 707 If a list, it should be a list of `major-mode' symbol names for which
 708 `company-mode' should be automatically turned on.  The sense of the list is
 709 negated if it begins with `not'.  For example:
 710  (c-mode c++-mode)
 711 means that `company-mode' is turned on for buffers in C and C++ modes only.
 712  (not message-mode)
 713 means that `company-mode' is always turned on except in `message-mode' buffers."
 714   :type '(choice (const :tag "none" nil)
 715                  (const :tag "all" t)
 716                  (set :menu-tag "mode specific" :tag "modes"
 717                       :value (not)
 718                       (const :tag "Except" not)
 719                       (repeat :inline t (symbol :tag "mode")))))
 720
 721 ;;;###autoload
 722 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 723
 724 (defun company-mode-on ()
 725   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 726              (cond ((eq company-global-modes t)
 727                     t)
 728                    ((eq (car-safe company-global-modes) 'not)
 729                     (not (memq major-mode (cdr company-global-modes))))
 730                    (t (memq major-mode company-global-modes))))
 731     (company-mode 1)))
 732
 733 (defsubst company-assert-enabled ()
 734   (unless company-mode
 735     (company-uninstall-map)
 736     (error "Company not enabled")))
 737
 738 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 739
 740 (defvar-local company-my-keymap nil)
 741
 742 (defvar company-emulation-alist '((t . nil)))
 743
 744 (defsubst company-enable-overriding-keymap (keymap)
 745   (company-uninstall-map)
 746   (setq company-my-keymap keymap))
 747
 748 (defun company-ensure-emulation-alist ()
 749   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 750     (setq emulation-mode-map-alists
 751           (cons 'company-emulation-alist
 752                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 753
 754 (defun company-install-map ()
 755   (unless (or (cdar company-emulation-alist)
 756               (null company-my-keymap))
 757     (setf (cdar company-emulation-alist) company-my-keymap)))
 758
 759 (defun company-uninstall-map ()
 760   (setf (cdar company-emulation-alist) nil))
 761
 762 ;; Hack:
 763 ;; Emacs calculates the active keymaps before reading the event.  That means we
 764 ;; cannot change the keymap from a timer.  So we send a bogus command.
 765 ;; XXX: Even in Emacs 24.4, seems to be needed in the terminal.
 766 (defun company-ignore ()
 767   (interactive)
 768   (setq this-command last-command))
 769
 770 (global-set-key '[company-dummy-event] 'company-ignore)
 771
 772 (defun company-input-noop ()
 773   (push 'company-dummy-event unread-command-events))
 774
 775 (defun company--posn-col-row (posn)
 776   (let ((col (car (posn-col-row posn)))
 777         ;; `posn-col-row' doesn't work well with lines of different height.
 778         ;; `posn-actual-col-row' doesn't handle multiple-width characters.
 779         (row (cdr (posn-actual-col-row posn))))
 780     (when (and header-line-format (version< emacs-version "24.3.93.3"))
 781       ;; http://debbugs.gnu.org/18384
 782       (cl-decf row))
 783     (cons (+ col (window-hscroll)) row)))
 784
 785 (defun company--col-row (&optional pos)
 786   (company--posn-col-row (posn-at-point pos)))
 787
 788 (defun company--row (&optional pos)
 789   (cdr (company--col-row pos)))
 790
 791 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 792
 793 (defvar-local company-backend nil)
 794
 795 (defun company-grab (regexp &optional expression limit)
 796   (when (looking-back regexp limit)
 797     (or (match-string-no-properties (or expression 0)) "")))
 798
 799 (defun company-grab-line (regexp &optional expression)
 800   (company-grab regexp expression (point-at-bol)))
 801
 802 (defun company-grab-symbol ()
 803   (if (looking-at "\\_>")
 804       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 805                                                 (point)))
 806     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 807       "")))
 808
 809 (defun company-grab-word ()
 810   (if (looking-at "\\>")
 811       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 812                                                 (point)))
 813     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 814       "")))
 815
 816 (defun company-grab-symbol-cons (idle-begin-after-re &optional max-len)
 817   (let ((symbol (company-grab-symbol)))
 818     (when symbol
 819       (save-excursion
 820         (forward-char (- (length symbol)))
 821         (if (looking-back idle-begin-after-re (if max-len
 822                                                   (- (point) max-len)
 823                                                 (line-beginning-position)))
 824             (cons symbol t)
 825           symbol)))))
 826
 827 (defun company-in-string-or-comment ()
 828   (let ((ppss (syntax-ppss)))
 829     (or (car (setq ppss (nthcdr 3 ppss)))
 830         (car (setq ppss (cdr ppss)))
 831         (nth 3 ppss))))
 832
 833 (defun company-call-backend (&rest args)
 834   (company--force-sync #'company-call-backend-raw args company-backend))
 835
 836 (defun company--force-sync (fun args backend)
 837   (let ((value (apply fun args)))
 838     (if (not (eq (car-safe value) :async))
 839         value
 840       (let ((res 'trash)
 841             (start (time-to-seconds)))
 842         (funcall (cdr value)
 843                  (lambda (result) (setq res result)))
 844         (while (eq res 'trash)
 845           (if (> (- (time-to-seconds) start) company-async-timeout)
 846               (error "Company: Back-end %s async timeout with args %s"
 847                      backend args)
 848             (sleep-for company-async-wait)))
 849         res))))
 850
 851 (defun company-call-backend-raw (&rest args)
 852   (condition-case-unless-debug err
 853       (if (functionp company-backend)
 854           (apply company-backend args)
 855         (apply #'company--multi-backend-adapter company-backend args))
 856     (error (error "Company: Back-end %s error \"%s\" with args %s"
 857                   company-backend (error-message-string err) args))))
 858
 859 (defun company--multi-backend-adapter (backends command &rest args)
 860   (let ((backends (cl-loop for b in backends
 861                            when (not (and (symbolp b)
 862                                           (eq 'failed (get b 'company-init))))
 863                            collect b)))
 864     (setq backends
 865           (if (eq command 'prefix)
 866               (butlast backends (length (member :with backends)))
 867             (delq :with backends)))
 868     (pcase command
 869       (`candidates
 870        (company--multi-backend-adapter-candidates backends (car args)))
 871       (`sorted nil)
 872       (`duplicates t)
 873       ((or `prefix `ignore-case `no-cache `require-match)
 874        (let (value)
 875          (cl-dolist (backend backends)
 876            (when (setq value (company--force-sync
 877                               backend (cons command args) backend))
 878              (cl-return value)))))
 879       (_
 880        (let ((arg (car args)))
 881          (when (> (length arg) 0)
 882            (let ((backend (or (get-text-property 0 'company-backend arg)
 883                               (car backends))))
 884              (apply backend command args))))))))
 885
 886 (defun company--multi-backend-adapter-candidates (backends prefix)
 887   (let ((pairs (cl-loop for backend in (cdr backends)
 888                         when (equal (company--prefix-str
 889                                      (funcall backend 'prefix))
 890                                     prefix)
 891                         collect (cons (funcall backend 'candidates prefix)
 892                                       (let ((b backend))
 893                                         (lambda (candidates)
 894                                           (mapcar
 895                                            (lambda (str)
 896                                              (propertize str 'company-backend b))
 897                                            candidates)))))))
 898     (when (equal (company--prefix-str (funcall (car backends) 'prefix)) prefix)
 899       ;; Small perf optimization: don't tag the candidates received
 900       ;; from the first backend in the group.
 901       (push (cons (funcall (car backends) 'candidates prefix)
 902                   'identity)
 903             pairs))
 904     (company--merge-async pairs (lambda (values) (apply #'append values)))))
 905
 906 (defun company--merge-async (pairs merger)
 907   (let ((async (cl-loop for pair in pairs
 908                         thereis
 909                         (eq :async (car-safe (car pair))))))
 910     (if (not async)
 911         (funcall merger (cl-loop for (val . mapper) in pairs
 912                                  collect (funcall mapper val)))
 913       (cons
 914        :async
 915        (lambda (callback)
 916          (let* (lst pending
 917                 (finisher (lambda ()
 918                             (unless pending
 919                               (funcall callback
 920                                        (funcall merger
 921                                                 (nreverse lst)))))))
 922            (dolist (pair pairs)
 923              (let ((val (car pair))
 924                    (mapper (cdr pair)))
 925                (if (not (eq :async (car-safe val)))
 926                    (push (funcall mapper val) lst)
 927                  (push nil lst)
 928                  (let ((cell lst)
 929                        (fetcher (cdr val)))
 930                    (push fetcher pending)
 931                    (funcall fetcher
 932                             (lambda (res)
 933                               (setq pending (delq fetcher pending))
 934                               (setcar cell (funcall mapper res))
 935                               (funcall finisher)))))))))))))
 936
 937 (defun company--prefix-str (prefix)
 938   (or (car-safe prefix) prefix))
 939
 940 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 941
 942 (defvar-local company-prefix nil)
 943
 944 (defvar-local company-candidates nil)
 945
 946 (defvar-local company-candidates-length nil)
 947
 948 (defvar-local company-candidates-cache nil)
 949
 950 (defvar-local company-candidates-predicate nil)
 951
 952 (defvar-local company-common nil)
 953
 954 (defvar-local company-selection 0)
 955
 956 (defvar-local company-selection-changed nil)
 957
 958 (defvar-local company--manual-action nil
 959   "Non-nil, if manual completion took place.")
 960
 961 (defvar-local company--manual-prefix nil)
 962
 963 (defvar company--auto-completion nil
 964   "Non-nil when current candidate is being inserted automatically.
 965 Controlled by `company-auto-complete'.")
 966
 967 (defvar-local company--point-max nil)
 968
 969 (defvar-local company-point nil)
 970
 971 (defvar company-timer nil)
 972
 973 (defsubst company-strip-prefix (str)
 974   (substring str (length company-prefix)))
 975
 976 (defun company--insert-candidate (candidate)
 977   (setq candidate (substring-no-properties candidate))
 978   ;; XXX: Return value we check here is subject to change.
 979   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 980       (insert (company-strip-prefix candidate))
 981     (delete-region (- (point) (length company-prefix)) (point))
 982     (insert candidate)))
 983
 984 (defmacro company-with-candidate-inserted (candidate &rest body)
 985   "Evaluate BODY with CANDIDATE temporarily inserted.
 986 This is a tool for back-ends that need candidates inserted before they
 987 can retrieve meta-data for them."
 988   (declare (indent 1))
 989   `(let ((inhibit-modification-hooks t)
 990          (inhibit-point-motion-hooks t)
 991          (modified-p (buffer-modified-p)))
 992      (company--insert-candidate ,candidate)
 993      (unwind-protect
 994          (progn ,@body)
 995        (delete-region company-point (point))
 996        (set-buffer-modified-p modified-p))))
 997
 998 (defun company-explicit-action-p ()
 999   "Return whether explicit completion action was taken by the user."
1000   (or company--manual-action
1001       company-selection-changed))
1002
1003 (defun company-reformat (candidate)
1004   ;; company-ispell needs this, because the results are always lower-case
1005   ;; It's mory efficient to fix it only when they are displayed.
1006   ;; FIXME: Adopt the current text's capitalization instead?
1007   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
1008       (concat company-prefix (substring candidate (length company-prefix)))
1009     candidate))
1010
1011 (defun company--should-complete ()
1012   (and (eq company-idle-delay 'now)
1013        (not (or buffer-read-only overriding-terminal-local-map
1014                 overriding-local-map))
1015        ;; Check if in the middle of entering a key combination.
1016        (or (equal (this-command-keys-vector) [])
1017            (not (keymapp (key-binding (this-command-keys-vector)))))
1018        (not (and transient-mark-mode mark-active))))
1019
1020 (defun company--should-continue ()
1021   (or (eq t company-begin-commands)
1022       (eq t company-continue-commands)
1023       (if (eq 'not (car company-continue-commands))
1024           (not (memq this-command (cdr company-continue-commands)))
1025         (or (memq this-command company-begin-commands)
1026             (memq this-command company-continue-commands)
1027             (and (symbolp this-command)
1028                  (string-match-p "\\`company-" (symbol-name this-command)))))))
1029
1030 (defun company-call-frontends (command)
1031   (dolist (frontend company-frontends)
1032     (condition-case-unless-debug err
1033         (funcall frontend command)
1034       (error (error "Company: Front-end %s error \"%s\" on command %s"
1035                     frontend (error-message-string err) command)))))
1036
1037 (defun company-set-selection (selection &optional force-update)
1038   (setq selection
1039         (if company-selection-wrap-around
1040             (mod selection company-candidates-length)
1041           (max 0 (min (1- company-candidates-length) selection))))
1042   (when (or force-update (not (equal selection company-selection)))
1043     (company--update-group-lighter (nth selection company-candidates))
1044     (setq company-selection selection
1045           company-selection-changed t)
1046     (company-call-frontends 'update)))
1047
1048 (defun company--update-group-lighter (candidate)
1049   (when (listp company-backend)
1050     (let ((backend (or (get-text-property 0 'company-backend candidate)
1051                        (car company-backend))))
1052       (when (and backend (symbolp backend))
1053         (let ((name (replace-regexp-in-string "company-\\|-company" ""
1054                                               (symbol-name backend))))
1055           (setq company-lighter (format " company-<%s>" name)))))))
1056
1057 (defun company-apply-predicate (candidates predicate)
1058   (let (new)
1059     (dolist (c candidates)
1060       (when (funcall predicate c)
1061         (push c new)))
1062     (nreverse new)))
1063
1064 (defun company-update-candidates (candidates)
1065   (setq company-candidates-length (length candidates))
1066   (if (> company-selection 0)
1067       ;; Try to restore the selection
1068       (let ((selected (nth company-selection company-candidates)))
1069         (setq company-selection 0
1070               company-candidates candidates)
1071         (when selected
1072           (while (and candidates (string< (pop candidates) selected))
1073             (cl-incf company-selection))
1074           (unless candidates
1075             ;; Make sure selection isn't out of bounds.
1076             (setq company-selection (min (1- company-candidates-length)
1077                                          company-selection)))))
1078     (setq company-selection 0
1079           company-candidates candidates))
1080   ;; Save in cache:
1081   (push (cons company-prefix company-candidates) company-candidates-cache)
1082   ;; Calculate common.
1083   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
1084     ;; We want to support non-prefix completion, so filtering is the
1085     ;; responsibility of each respective backend, not ours.
1086     ;; On the other hand, we don't want to replace non-prefix input in
1087     ;; `company-complete-common', unless there's only one candidate.
1088     (setq company-common
1089           (if (cdr company-candidates)
1090               (let ((common (try-completion "" company-candidates)))
1091                 (when (string-prefix-p company-prefix common
1092                                        completion-ignore-case)
1093                   common))
1094             (car company-candidates)))))
1095
1096 (defun company-calculate-candidates (prefix)
1097   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
1098         (ignore-case (company-call-backend 'ignore-case)))
1099     (or candidates
1100         (when company-candidates-cache
1101           (let ((len (length prefix))
1102                 (completion-ignore-case ignore-case)
1103                 prev)
1104             (cl-dotimes (i (1+ len))
1105               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1106                                            company-candidates-cache)))
1107                 (setq candidates (all-completions prefix prev))
1108                 (cl-return t)))))
1109         ;; no cache match, call back-end
1110         (setq candidates
1111               (company--process-candidates
1112                (company--fetch-candidates prefix))))
1113     (setq candidates (company--transform-candidates candidates))
1114     (when candidates
1115       (if (or (cdr candidates)
1116               (not (eq t (compare-strings (car candidates) nil nil
1117                                           prefix nil nil ignore-case))))
1118           candidates
1119         ;; Already completed and unique; don't start.
1120         t))))
1121
1122 (defun company--fetch-candidates (prefix)
1123   (let ((c (if company--manual-action
1124                (company-call-backend 'candidates prefix)
1125              (company-call-backend-raw 'candidates prefix)))
1126         res)
1127     (if (not (eq (car c) :async))
1128         c
1129       (let ((buf (current-buffer))
1130             (win (selected-window))
1131             (tick (buffer-chars-modified-tick))
1132             (pt (point))
1133             (backend company-backend))
1134         (funcall
1135          (cdr c)
1136          (lambda (candidates)
1137            (if (not (and candidates (eq res 'done)))
1138                ;; Fetcher called us back right away.
1139                (setq res candidates)
1140              (setq company-backend backend
1141                    company-candidates-cache
1142                    (list (cons prefix
1143                                (company--process-candidates
1144                                 candidates))))
1145              (company-idle-begin buf win tick pt)))))
1146       ;; FIXME: Relying on the fact that the callers
1147       ;; will interpret nil as "do nothing" is shaky.
1148       ;; A throw-catch would be one possible improvement.
1149       (or res
1150           (progn (setq res 'done) nil)))))
1151
1152 (defun company--process-candidates (candidates)
1153   (when company-candidates-predicate
1154     (setq candidates
1155           (company-apply-predicate candidates
1156                                    company-candidates-predicate)))
1157   (unless (company-call-backend 'sorted)
1158     (setq candidates (sort candidates 'string<)))
1159   (when (company-call-backend 'duplicates)
1160     (company--strip-duplicates candidates))
1161   candidates)
1162
1163 (defun company--strip-duplicates (candidates)
1164   (let ((c2 candidates))
1165     (while c2
1166       (setcdr c2
1167               (let ((str (car c2))
1168                     (anno 'unk))
1169                 (pop c2)
1170                 (while (let ((str2 (car c2)))
1171                          (if (not (equal str str2))
1172                              nil
1173                            (when (eq anno 'unk)
1174                              (setq anno (company-call-backend
1175                                          'annotation str)))
1176                            (equal anno
1177                                   (company-call-backend
1178                                    'annotation str2))))
1179                   (pop c2))
1180                 c2)))))
1181
1182 (defun company--transform-candidates (candidates)
1183   (let ((c candidates))
1184     (dolist (tr company-transformers)
1185       (setq c (funcall tr c)))
1186     c))
1187
1188 (defcustom company-occurrence-weight-function
1189   #'company-occurrence-prefer-closest-above
1190   "Function to weigh matches in `company-sort-by-occurrence'.
1191 It's called with three arguments: cursor position, the beginning and the
1192 end of the match."
1193   :type '(choice
1194           (const :tag "First above point, then below point"
1195                  company-occurrence-prefer-closest-above)
1196           (const :tag "Prefer closest in any direction"
1197                  company-occurrence-prefer-any-closest)))
1198
1199 (defun company-occurrence-prefer-closest-above (pos match-beg match-end)
1200   "Give priority to the matches above point, then those below point."
1201   (if (< match-beg pos)
1202       (- pos match-end)
1203     (- match-beg (window-start))))
1204
1205 (defun company-occurrence-prefer-any-closest (pos _match-beg match-end)
1206   "Give priority to the matches closest to the point."
1207   (abs (- pos match-end)))
1208
1209 (defun company-sort-by-occurrence (candidates)
1210   "Sort CANDIDATES according to their occurrences.
1211 Searches for each in the currently visible part of the current buffer and
1212 prioritizes the matches according to `company-occurrence-weight-function'.
1213 The rest of the list is appended unchanged.
1214 Keywords and function definition names are ignored."
1215   (let* ((w-start (window-start))
1216          (w-end (window-end))
1217          (start-point (point))
1218          occurs
1219          (noccurs
1220           (save-excursion
1221             (cl-delete-if
1222              (lambda (candidate)
1223                (when (catch 'done
1224                        (goto-char w-start)
1225                        (while (search-forward candidate w-end t)
1226                          (when (and (not (eq (point) start-point))
1227                                     (save-match-data
1228                                       (company--occurrence-predicate)))
1229                            (throw 'done t))))
1230                  (push
1231                   (cons candidate
1232                         (funcall company-occurrence-weight-function
1233                                  start-point
1234                                  (match-beginning 0)
1235                                  (match-end 0)))
1236                   occurs)
1237                  t))
1238              candidates))))
1239     (nconc
1240      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1241      noccurs)))
1242
1243 (defun company--occurrence-predicate ()
1244   (let ((beg (match-beginning 0))
1245         (end (match-end 0)))
1246     (save-excursion
1247       (goto-char end)
1248       (and (not (memq (get-text-property (1- (point)) 'face)
1249                       '(font-lock-function-name-face
1250                         font-lock-keyword-face)))
1251            (let ((prefix (company--prefix-str
1252                           (company-call-backend 'prefix))))
1253              (and (stringp prefix)
1254                   (= (length prefix) (- end beg))))))))
1255
1256 (defun company-sort-by-backend-importance (candidates)
1257   "Sort CANDIDATES as two priority groups.
1258 If `company-backend' is a function, do nothing.  If it's a list, move
1259 candidates from back-ends before keyword `:with' to the front.  Candidates
1260 from the rest of the back-ends in the group, if any, will be left at the end."
1261   (if (functionp company-backend)
1262       candidates
1263     (let ((low-priority (cdr (memq :with company-backend))))
1264       (if (null low-priority)
1265           candidates
1266         (sort candidates
1267               (lambda (c1 c2)
1268                 (and
1269                  (let ((b2 (get-text-property 0 'company-backend c2)))
1270                    (and b2 (memq b2 low-priority)))
1271                  (let ((b1 (get-text-property 0 'company-backend c1)))
1272                    (or (not b1) (not (memq b1 low-priority)))))))))))
1273
1274 (defun company-idle-begin (buf win tick pos)
1275   (and (eq buf (current-buffer))
1276        (eq win (selected-window))
1277        (eq tick (buffer-chars-modified-tick))
1278        (eq pos (point))
1279        (when (company-auto-begin)
1280          (company-input-noop)
1281          (let ((this-command 'company-idle-begin))
1282            (company-post-command)))))
1283
1284 (defun company-auto-begin ()
1285   (and company-mode
1286        (not company-candidates)
1287        (let ((company-idle-delay 'now))
1288          (condition-case-unless-debug err
1289              (company--perform)
1290            (error (message "Company: An error occurred in auto-begin")
1291                   (message "%s" (error-message-string err))
1292                   (company-cancel))
1293            (quit (company-cancel)))))
1294   (unless company-candidates
1295     (setq company-backend nil))
1296   ;; Return non-nil if active.
1297   company-candidates)
1298
1299 (defun company-manual-begin ()
1300   (interactive)
1301   (company-assert-enabled)
1302   (setq company--manual-action t)
1303   (unwind-protect
1304       (let ((company-minimum-prefix-length 0))
1305         (company-auto-begin))
1306     (unless company-candidates
1307       (setq company--manual-action nil))))
1308
1309 (defun company-other-backend (&optional backward)
1310   (interactive (list current-prefix-arg))
1311   (company-assert-enabled)
1312   (let* ((after (if company-backend
1313                     (cdr (member company-backend company-backends))
1314                   company-backends))
1315          (before (cdr (member company-backend (reverse company-backends))))
1316          (next (if backward
1317                    (append before (reverse after))
1318                  (append after (reverse before)))))
1319     (company-cancel)
1320     (cl-dolist (backend next)
1321       (when (ignore-errors (company-begin-backend backend))
1322         (cl-return t))))
1323   (unless company-candidates
1324     (error "No other back-end")))
1325
1326 (defun company-require-match-p ()
1327   (let ((backend-value (company-call-backend 'require-match)))
1328     (or (eq backend-value t)
1329         (and (not (eq backend-value 'never))
1330              (if (functionp company-require-match)
1331                  (funcall company-require-match)
1332                (eq company-require-match t))))))
1333
1334 (defun company-auto-complete-p (input)
1335   "Return non-nil, if input starts with punctuation or parentheses."
1336   (and (if (functionp company-auto-complete)
1337            (funcall company-auto-complete)
1338          company-auto-complete)
1339        (if (functionp company-auto-complete-chars)
1340            (funcall company-auto-complete-chars input)
1341          (if (consp company-auto-complete-chars)
1342              (memq (char-syntax (string-to-char input))
1343                    company-auto-complete-chars)
1344            (string-match (substring input 0 1) company-auto-complete-chars)))))
1345
1346 (defun company--incremental-p ()
1347   (and (> (point) company-point)
1348        (> (point-max) company--point-max)
1349        (not (eq this-command 'backward-delete-char-untabify))
1350        (equal (buffer-substring (- company-point (length company-prefix))
1351                                 company-point)
1352               company-prefix)))
1353
1354 (defun company--continue-failed (new-prefix)
1355   (let ((input (buffer-substring-no-properties (point) company-point)))
1356     (cond
1357      ((company-auto-complete-p input)
1358       ;; auto-complete
1359       (save-excursion
1360         (goto-char company-point)
1361         (let ((company--auto-completion t))
1362           (company-complete-selection))
1363         nil))
1364      ((and (or (not (company-require-match-p))
1365                ;; Don't require match if the new prefix
1366                ;; doesn't continue the old one, and the latter was a match.
1367                (<= (length new-prefix) (length company-prefix)))
1368            (member company-prefix company-candidates))
1369       ;; Last input was a success,
1370       ;; but we're treating it as an abort + input anyway,
1371       ;; like the `unique' case below.
1372       (company-cancel 'non-unique))
1373      ((company-require-match-p)
1374       ;; Wrong incremental input, but required match.
1375       (delete-char (- (length input)))
1376       (ding)
1377       (message "Matching input is required")
1378       company-candidates)
1379      (t (company-cancel)))))
1380
1381 (defun company--good-prefix-p (prefix)
1382   (and (stringp (company--prefix-str prefix)) ;excludes 'stop
1383        (or (eq (cdr-safe prefix) t)
1384            (let ((len (or (cdr-safe prefix) (length prefix))))
1385              (if company--manual-prefix
1386                  (or (not company-abort-manual-when-too-short)
1387                      ;; Must not be less than minimum or initial length.
1388                      (>= len (min company-minimum-prefix-length
1389                                   (length company--manual-prefix))))
1390                (>= len company-minimum-prefix-length))))))
1391
1392 (defun company--continue ()
1393   (when (company-call-backend 'no-cache company-prefix)
1394     ;; Don't complete existing candidates, fetch new ones.
1395     (setq company-candidates-cache nil))
1396   (let* ((new-prefix (company-call-backend 'prefix))
1397          (c (when (and (company--good-prefix-p new-prefix)
1398                        (setq new-prefix (company--prefix-str new-prefix))
1399                        (= (- (point) (length new-prefix))
1400                           (- company-point (length company-prefix))))
1401               (company-calculate-candidates new-prefix))))
1402     (cond
1403      ((eq c t)
1404       ;; t means complete/unique.
1405       ;; Handle it like completion was aborted, to differentiate from user
1406       ;; calling one of Company's commands to insert the candidate,
1407       ;; not to trigger template expansion, etc.
1408       (company-cancel 'unique))
1409      ((consp c)
1410       ;; incremental match
1411       (setq company-prefix new-prefix)
1412       (company-update-candidates c)
1413       c)
1414      ((not (company--incremental-p))
1415       (company-cancel))
1416      (t (company--continue-failed new-prefix)))))
1417
1418 (defun company--begin-new ()
1419   (let (prefix c)
1420     (cl-dolist (backend (if company-backend
1421                             ;; prefer manual override
1422                             (list company-backend)
1423                           company-backends))
1424       (setq prefix
1425             (if (or (symbolp backend)
1426                     (functionp backend))
1427                 (when (or (not (symbolp backend))
1428                           (eq t (get backend 'company-init))
1429                           (unless (get backend 'company-init)
1430                             (company-init-backend backend)))
1431                   (funcall backend 'prefix))
1432               (company--multi-backend-adapter backend 'prefix)))
1433       (when prefix
1434         (when (company--good-prefix-p prefix)
1435           (setq company-prefix (company--prefix-str prefix)
1436                 company-backend backend
1437                 c (company-calculate-candidates company-prefix))
1438           ;; t means complete/unique.  We don't start, so no hooks.
1439           (if (not (consp c))
1440               (when company--manual-action
1441                 (message "No completion found"))
1442             (when company--manual-action
1443               (setq company--manual-prefix prefix))
1444             (if (symbolp backend)
1445                 (setq company-lighter (concat " " (symbol-name backend)))
1446               (company--update-group-lighter (car c)))
1447             (company-update-candidates c)
1448             (run-hook-with-args 'company-completion-started-hook
1449                                 (company-explicit-action-p))
1450             (company-call-frontends 'show)))
1451         (cl-return c)))))
1452
1453 (defun company--perform ()
1454   (or (and company-candidates (company--continue))
1455       (and (company--should-complete) (company--begin-new)))
1456   (when company-candidates
1457     (setq company-point (point)
1458           company--point-max (point-max))
1459     (company-ensure-emulation-alist)
1460     (company-enable-overriding-keymap company-active-map)
1461     (company-call-frontends 'update)))
1462
1463 (defun company-cancel (&optional result)
1464   (unwind-protect
1465       (when company-prefix
1466         (if (stringp result)
1467             (progn
1468               (company-call-backend 'pre-completion result)
1469               (run-hook-with-args 'company-completion-finished-hook result)
1470               (company-call-backend 'post-completion result))
1471           (run-hook-with-args 'company-completion-cancelled-hook result)))
1472     (setq company-backend nil
1473           company-prefix nil
1474           company-candidates nil
1475           company-candidates-length nil
1476           company-candidates-cache nil
1477           company-candidates-predicate nil
1478           company-common nil
1479           company-selection 0
1480           company-selection-changed nil
1481           company--manual-action nil
1482           company--manual-prefix nil
1483           company-lighter company-default-lighter
1484           company--point-max nil
1485           company-point nil)
1486     (when company-timer
1487       (cancel-timer company-timer))
1488     (company-search-mode 0)
1489     (company-call-frontends 'hide)
1490     (company-enable-overriding-keymap nil))
1491   ;; Make return value explicit.
1492   nil)
1493
1494 (defun company-abort ()
1495   (interactive)
1496   (company-cancel 'abort))
1497
1498 (defun company-finish (result)
1499   (company--insert-candidate result)
1500   (company-cancel result))
1501
1502 (defsubst company-keep (command)
1503   (and (symbolp command) (get command 'company-keep)))
1504
1505 (defun company-pre-command ()
1506   (unless (company-keep this-command)
1507     (condition-case-unless-debug err
1508         (when company-candidates
1509           (company-call-frontends 'pre-command)
1510           (unless (company--should-continue)
1511             (company-abort)))
1512       (error (message "Company: An error occurred in pre-command")
1513              (message "%s" (error-message-string err))
1514              (company-cancel))))
1515   (when company-timer
1516     (cancel-timer company-timer)
1517     (setq company-timer nil))
1518   (company-uninstall-map))
1519
1520 (defun company-post-command ()
1521   (when (null this-command)
1522     ;; Happens when the user presses `C-g' while inside
1523     ;; `flyspell-post-command-hook', for example.
1524     ;; Or any other `post-command-hook' function that can call `sit-for',
1525     ;; or any quittable timer function.
1526     (company-abort)
1527     (setq this-command 'company-abort))
1528   (unless (company-keep this-command)
1529     (condition-case-unless-debug err
1530         (progn
1531           (unless (equal (point) company-point)
1532             (let (company-idle-delay) ; Against misbehavior while debugging.
1533               (company--perform)))
1534           (if company-candidates
1535               (company-call-frontends 'post-command)
1536             (and (numberp company-idle-delay)
1537                  (company--should-begin)
1538                  (setq company-timer
1539                        (run-with-timer company-idle-delay nil
1540                                        'company-idle-begin
1541                                        (current-buffer) (selected-window)
1542                                        (buffer-chars-modified-tick) (point))))))
1543       (error (message "Company: An error occurred in post-command")
1544              (message "%s" (error-message-string err))
1545              (company-cancel))))
1546   (company-install-map))
1547
1548 (defvar company--begin-inhibit-commands '(company-abort
1549                                           company-complete-mouse
1550                                           company-complete
1551                                           company-complete-common
1552                                           company-complete-selection
1553                                           company-complete-number)
1554   "List of commands after which idle completion is (still) disabled when
1555 `company-begin-commands' is t.")
1556
1557 (defun company--should-begin ()
1558   (if (eq t company-begin-commands)
1559       (not (memq this-command company--begin-inhibit-commands))
1560     (or
1561      (memq this-command company-begin-commands)
1562      (and (symbolp this-command) (get this-command 'company-begin)))))
1563
1564 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1565
1566 (defvar-local company-search-string nil)
1567
1568 (defvar-local company-search-lighter " Search: \"\"")
1569
1570 (defvar-local company-search-old-map nil)
1571
1572 (defvar-local company-search-old-selection 0)
1573
1574 (defun company-search (text lines)
1575   (let ((quoted (regexp-quote text))
1576         (i 0))
1577     (cl-dolist (line lines)
1578       (when (string-match quoted line (length company-prefix))
1579         (cl-return i))
1580       (cl-incf i))))
1581
1582 (defun company-search-printing-char ()
1583   (interactive)
1584   (company-search-assert-enabled)
1585   (let* ((ss (concat company-search-string (string last-command-event)))
1586          (pos (company-search ss (nthcdr company-selection company-candidates))))
1587     (if (null pos)
1588         (ding)
1589       (setq company-search-string ss
1590             company-search-lighter (concat " Search: \"" ss "\""))
1591       (company-set-selection (+ company-selection pos) t))))
1592
1593 (defun company-search-repeat-forward ()
1594   "Repeat the incremental search in completion candidates forward."
1595   (interactive)
1596   (company-search-assert-enabled)
1597   (let ((pos (company-search company-search-string
1598                              (cdr (nthcdr company-selection
1599                                           company-candidates)))))
1600     (if (null pos)
1601         (ding)
1602       (company-set-selection (+ company-selection pos 1) t))))
1603
1604 (defun company-search-repeat-backward ()
1605   "Repeat the incremental search in completion candidates backwards."
1606   (interactive)
1607   (company-search-assert-enabled)
1608   (let ((pos (company-search company-search-string
1609                              (nthcdr (- company-candidates-length
1610                                         company-selection)
1611                                      (reverse company-candidates)))))
1612     (if (null pos)
1613         (ding)
1614       (company-set-selection (- company-selection pos 1) t))))
1615
1616 (defun company-create-match-predicate ()
1617   (let ((ss company-search-string))
1618     (setq company-candidates-predicate
1619           (when ss (lambda (candidate) (string-match ss candidate)))))
1620   (company-update-candidates
1621    (company-apply-predicate company-candidates company-candidates-predicate))
1622   ;; Invalidate cache.
1623   (setq company-candidates-cache (cons company-prefix company-candidates)))
1624
1625 (defun company-filter-printing-char ()
1626   (interactive)
1627   (company-search-assert-enabled)
1628   (company-search-printing-char)
1629   (company-create-match-predicate)
1630   (company-call-frontends 'update))
1631
1632 (defun company-search-kill-others ()
1633   "Limit the completion candidates to the ones matching the search string."
1634   (interactive)
1635   (company-search-assert-enabled)
1636   (company-create-match-predicate)
1637   (company-search-mode 0)
1638   (company-call-frontends 'update))
1639
1640 (defun company-search-abort ()
1641   "Abort searching the completion candidates."
1642   (interactive)
1643   (company-search-assert-enabled)
1644   (company-set-selection company-search-old-selection t)
1645   (company-search-mode 0))
1646
1647 (defun company-search-other-char ()
1648   (interactive)
1649   (company-search-assert-enabled)
1650   (company-search-mode 0)
1651   (company--unread-last-input))
1652
1653 (defvar company-search-map
1654   (let ((i 0)
1655         (keymap (make-keymap)))
1656     (if (fboundp 'max-char)
1657         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1658                               'company-search-printing-char)
1659       (with-no-warnings
1660         ;; obsolete in Emacs 23
1661         (let ((l (generic-character-list))
1662               (table (nth 1 keymap)))
1663           (while l
1664             (set-char-table-default table (car l) 'company-search-printing-char)
1665             (setq l (cdr l))))))
1666     (define-key keymap [t] 'company-search-other-char)
1667     (while (< i ?\s)
1668       (define-key keymap (make-string 1 i) 'company-search-other-char)
1669       (cl-incf i))
1670     (while (< i 256)
1671       (define-key keymap (vector i) 'company-search-printing-char)
1672       (cl-incf i))
1673     (let ((meta-map (make-sparse-keymap)))
1674       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1675       (define-key keymap [escape] meta-map))
1676     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1677     (define-key keymap "\e\e\e" 'company-search-other-char)
1678     (define-key keymap [escape escape escape] 'company-search-other-char)
1679     (define-key keymap (kbd "DEL") 'company-search-other-char)
1680
1681     (define-key keymap "\C-g" 'company-search-abort)
1682     (define-key keymap "\C-s" 'company-search-repeat-forward)
1683     (define-key keymap "\C-r" 'company-search-repeat-backward)
1684     (define-key keymap "\C-o" 'company-search-kill-others)
1685     keymap)
1686   "Keymap used for incrementally searching the completion candidates.")
1687
1688 (define-minor-mode company-search-mode
1689   "Search mode for completion candidates.
1690 Don't start this directly, use `company-search-candidates' or
1691 `company-filter-candidates'."
1692   nil company-search-lighter nil
1693   (if company-search-mode
1694       (if (company-manual-begin)
1695           (progn
1696             (setq company-search-old-selection company-selection)
1697             (company-call-frontends 'update))
1698         (setq company-search-mode nil))
1699     (kill-local-variable 'company-search-string)
1700     (kill-local-variable 'company-search-lighter)
1701     (kill-local-variable 'company-search-old-selection)
1702     (company-enable-overriding-keymap company-active-map)))
1703
1704 (defun company-search-assert-enabled ()
1705   (company-assert-enabled)
1706   (unless company-search-mode
1707     (company-uninstall-map)
1708     (error "Company not in search mode")))
1709
1710 (defun company-search-candidates ()
1711   "Start searching the completion candidates incrementally.
1712
1713 \\<company-search-map>Search can be controlled with the commands:
1714 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1715 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1716 - `company-search-abort' (\\[company-search-abort])
1717
1718 Regular characters are appended to the search string.
1719
1720 The command `company-search-kill-others' (\\[company-search-kill-others])
1721 uses the search string to limit the completion candidates."
1722   (interactive)
1723   (company-search-mode 1)
1724   (company-enable-overriding-keymap company-search-map))
1725
1726 (defvar company-filter-map
1727   (let ((keymap (make-keymap)))
1728     (define-key keymap [remap company-search-printing-char]
1729       'company-filter-printing-char)
1730     (set-keymap-parent keymap company-search-map)
1731     keymap)
1732   "Keymap used for incrementally searching the completion candidates.")
1733
1734 (defun company-filter-candidates ()
1735   "Start filtering the completion candidates incrementally.
1736 This works the same way as `company-search-candidates' immediately
1737 followed by `company-search-kill-others' after each input."
1738   (interactive)
1739   (company-search-mode 1)
1740   (company-enable-overriding-keymap company-filter-map))
1741
1742 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1743
1744 (defun company-select-next ()
1745   "Select the next candidate in the list."
1746   (interactive)
1747   (when (company-manual-begin)
1748     (company-set-selection (1+ company-selection))))
1749
1750 (defun company-select-previous ()
1751   "Select the previous candidate in the list."
1752   (interactive)
1753   (when (company-manual-begin)
1754     (company-set-selection (1- company-selection))))
1755
1756 (defun company-select-next-or-abort ()
1757   "Select the next candidate if more than one, else abort
1758 and invoke the normal binding."
1759   (interactive)
1760   (if (> company-candidates-length 1)
1761       (company-select-next)
1762     (company-abort)
1763     (company--unread-last-input)))
1764
1765 (defun company-select-previous-or-abort ()
1766   "Select the previous candidate if more than one, else abort
1767 and invoke the normal binding."
1768   (interactive)
1769   (if (> company-candidates-length 1)
1770       (company-select-previous)
1771     (company-abort)
1772     (company--unread-last-input)))
1773
1774 (defvar company-pseudo-tooltip-overlay)
1775
1776 (defvar company-tooltip-offset)
1777
1778 (defun company--inside-tooltip-p (event-col-row row height)
1779   (let* ((ovl company-pseudo-tooltip-overlay)
1780          (column (overlay-get ovl 'company-column))
1781          (width (overlay-get ovl 'company-width))
1782          (evt-col (car event-col-row))
1783          (evt-row (cdr event-col-row)))
1784     (and (>= evt-col column)
1785          (< evt-col (+ column width))
1786          (if (> height 0)
1787              (and (> evt-row row)
1788                   (<= evt-row (+ row height) ))
1789            (and (< evt-row row)
1790                 (>= evt-row (+ row height)))))))
1791
1792 (defun company--event-col-row (event)
1793   (company--posn-col-row (event-start event)))
1794
1795 (defun company-select-mouse (event)
1796   "Select the candidate picked by the mouse."
1797   (interactive "e")
1798   (let ((event-col-row (company--event-col-row event))
1799         (ovl-row (company--row))
1800         (ovl-height (and company-pseudo-tooltip-overlay
1801                          (min (overlay-get company-pseudo-tooltip-overlay
1802                                            'company-height)
1803                               company-candidates-length))))
1804     (if (and ovl-height
1805              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1806         (progn
1807           (company-set-selection (+ (cdr event-col-row)
1808                                     (1- company-tooltip-offset)
1809                                     (if (and (eq company-tooltip-offset-display 'lines)
1810                                              (not (zerop company-tooltip-offset)))
1811                                         -1 0)
1812                                     (- ovl-row)
1813                                     (if (< ovl-height 0)
1814                                         (- 1 ovl-height)
1815                                       0)))
1816           t)
1817       (company-abort)
1818       (company--unread-last-input)
1819       nil)))
1820
1821 (defun company-complete-mouse (event)
1822   "Insert the candidate picked by the mouse."
1823   (interactive "e")
1824   (when (company-select-mouse event)
1825     (company-complete-selection)))
1826
1827 (defun company-complete-selection ()
1828   "Insert the selected candidate."
1829   (interactive)
1830   (when (company-manual-begin)
1831     (let ((result (nth company-selection company-candidates)))
1832       (company-finish result))))
1833
1834 (defun company-complete-common ()
1835   "Insert the common part of all candidates."
1836   (interactive)
1837   (when (company-manual-begin)
1838     (if (and (not (cdr company-candidates))
1839              (equal company-common (car company-candidates)))
1840         (company-complete-selection)
1841       (when company-common
1842         (company--insert-candidate company-common)))))
1843
1844 (defun company-complete ()
1845   "Insert the common part of all candidates or the current selection.
1846 The first time this is called, the common part is inserted, the second
1847 time, or when the selection has been changed, the selected candidate is
1848 inserted."
1849   (interactive)
1850   (when (company-manual-begin)
1851     (if (or company-selection-changed
1852             (eq last-command 'company-complete-common))
1853         (call-interactively 'company-complete-selection)
1854       (call-interactively 'company-complete-common)
1855       (setq this-command 'company-complete-common))))
1856
1857 (defun company-complete-number (n)
1858   "Insert the Nth candidate visible in the tooltip.
1859 To show the number next to the candidates in some back-ends, enable
1860 `company-show-numbers'.  When called interactively, uses the last typed
1861 character, stripping the modifiers.  That character must be a digit."
1862   (interactive
1863    (list (let* ((type (event-basic-type last-command-event))
1864                 (char (if (characterp type)
1865                           ;; Number on the main row.
1866                           type
1867                         ;; Keypad number, if bound directly.
1868                         (car (last (string-to-list (symbol-name type))))))
1869                 (n (- char ?0)))
1870            (if (zerop n) 10 n))))
1871   (when (company-manual-begin)
1872     (and (or (< n 1) (> n (- company-candidates-length
1873                              company-tooltip-offset)))
1874          (error "No candidate number %d" n))
1875     (cl-decf n)
1876     (company-finish (nth (+ n company-tooltip-offset)
1877                          company-candidates))))
1878
1879 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1880
1881 (defconst company-space-strings-limit 100)
1882
1883 (defconst company-space-strings
1884   (let (lst)
1885     (dotimes (i company-space-strings-limit)
1886       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1887     (apply 'vector lst)))
1888
1889 (defun company-space-string (len)
1890   (if (< len company-space-strings-limit)
1891       (aref company-space-strings len)
1892     (make-string len ?\ )))
1893
1894 (defun company-safe-substring (str from &optional to)
1895   (if (> from (string-width str))
1896       ""
1897     (with-temp-buffer
1898       (insert str)
1899       (move-to-column from)
1900       (let ((beg (point)))
1901         (if to
1902             (progn
1903               (move-to-column to)
1904               (concat (buffer-substring beg (point))
1905                       (let ((padding (- to (current-column))))
1906                         (when (> padding 0)
1907                           (company-space-string padding)))))
1908           (buffer-substring beg (point-max)))))))
1909
1910 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1911
1912 (defvar-local company-last-metadata nil)
1913
1914 (defun company-fetch-metadata ()
1915   (let ((selected (nth company-selection company-candidates)))
1916     (unless (eq selected (car company-last-metadata))
1917       (setq company-last-metadata
1918             (cons selected (company-call-backend 'meta selected))))
1919     (cdr company-last-metadata)))
1920
1921 (defun company-doc-buffer (&optional string)
1922   (with-current-buffer (get-buffer-create "*company-documentation*")
1923     (erase-buffer)
1924     (when string
1925       (save-excursion
1926         (insert string)))
1927     (current-buffer)))
1928
1929 (defvar company--electric-commands
1930   '(scroll-other-window scroll-other-window-down)
1931   "List of Commands that won't break out of electric commands.")
1932
1933 (defmacro company--electric-do (&rest body)
1934   (declare (indent 0) (debug t))
1935   `(when (company-manual-begin)
1936      (save-window-excursion
1937        (let ((height (window-height))
1938              (row (company--row))
1939              cmd)
1940          ,@body
1941          (and (< (window-height) height)
1942               (< (- (window-height) row 2) company-tooltip-limit)
1943               (recenter (- (window-height) row 2)))
1944          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1945                       company--electric-commands)
1946            (call-interactively cmd))
1947          (company--unread-last-input)))))
1948
1949 (defun company--unread-last-input ()
1950   (when last-input-event
1951     (clear-this-command-keys t)
1952     (setq unread-command-events (list last-input-event))))
1953
1954 (defun company-show-doc-buffer ()
1955   "Temporarily show the documentation buffer for the selection."
1956   (interactive)
1957   (company--electric-do
1958     (let* ((selected (nth company-selection company-candidates))
1959            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1960                            (error "No documentation available"))))
1961       (with-current-buffer doc-buffer
1962         (goto-char (point-min)))
1963       (display-buffer doc-buffer t))))
1964 (put 'company-show-doc-buffer 'company-keep t)
1965
1966 (defun company-show-location ()
1967   "Temporarily display a buffer showing the selected candidate in context."
1968   (interactive)
1969   (company--electric-do
1970     (let* ((selected (nth company-selection company-candidates))
1971            (location (company-call-backend 'location selected))
1972            (pos (or (cdr location) (error "No location available")))
1973            (buffer (or (and (bufferp (car location)) (car location))
1974                        (find-file-noselect (car location) t))))
1975       (with-selected-window (display-buffer buffer t)
1976         (save-restriction
1977           (widen)
1978           (if (bufferp (car location))
1979               (goto-char pos)
1980             (goto-char (point-min))
1981             (forward-line (1- pos))))
1982         (set-window-start nil (point))))))
1983 (put 'company-show-location 'company-keep t)
1984
1985 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1986
1987 (defvar-local company-callback nil)
1988
1989 (defun company-remove-callback (&optional ignored)
1990   (remove-hook 'company-completion-finished-hook company-callback t)
1991   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1992   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
1993
1994 (defun company-begin-backend (backend &optional callback)
1995   "Start a completion at point using BACKEND."
1996   (interactive (let ((val (completing-read "Company back-end: "
1997                                            obarray
1998                                            'functionp nil "company-")))
1999                  (when val
2000                    (list (intern val)))))
2001   (when (setq company-callback callback)
2002     (add-hook 'company-completion-finished-hook company-callback nil t))
2003   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
2004   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
2005   (setq company-backend backend)
2006   ;; Return non-nil if active.
2007   (or (company-manual-begin)
2008       (error "Cannot complete at point")))
2009
2010 (defun company-begin-with (candidates
2011                            &optional prefix-length require-match callback)
2012   "Start a completion at point.
2013 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
2014 of the prefix that already is in the buffer before point.
2015 It defaults to 0.
2016
2017 CALLBACK is a function called with the selected result if the user
2018 successfully completes the input.
2019
2020 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
2021   (let ((begin-marker (copy-marker (point) t)))
2022     (company-begin-backend
2023      (lambda (command &optional arg &rest ignored)
2024        (pcase command
2025          (`prefix
2026           (when (equal (point) (marker-position begin-marker))
2027             (buffer-substring (- (point) (or prefix-length 0)) (point))))
2028          (`candidates
2029           (all-completions arg candidates))
2030          (`require-match
2031           require-match)))
2032      callback)))
2033
2034 (defun company-version (&optional show-version)
2035   "Get the Company version as string.
2036
2037 If SHOW-VERSION is non-nil, show the version in the echo area."
2038   (interactive (list t))
2039   (with-temp-buffer
2040     (insert-file-contents (find-library-name "company"))
2041     (require 'lisp-mnt)
2042     (if show-version
2043         (message "Company version: %s" (lm-version))
2044       (lm-version))))
2045
2046 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2047
2048 (defvar-local company-pseudo-tooltip-overlay nil)
2049
2050 (defvar-local company-tooltip-offset 0)
2051
2052 (defun company-tooltip--lines-update-offset (selection num-lines limit)
2053   (cl-decf limit 2)
2054   (setq company-tooltip-offset
2055         (max (min selection company-tooltip-offset)
2056              (- selection -1 limit)))
2057
2058   (when (<= company-tooltip-offset 1)
2059     (cl-incf limit)
2060     (setq company-tooltip-offset 0))
2061
2062   (when (>= company-tooltip-offset (- num-lines limit 1))
2063     (cl-incf limit)
2064     (when (= selection (1- num-lines))
2065       (cl-decf company-tooltip-offset)
2066       (when (<= company-tooltip-offset 1)
2067         (setq company-tooltip-offset 0)
2068         (cl-incf limit))))
2069
2070   limit)
2071
2072 (defun company-tooltip--simple-update-offset (selection _num-lines limit)
2073   (setq company-tooltip-offset
2074         (if (< selection company-tooltip-offset)
2075             selection
2076           (max company-tooltip-offset
2077                (- selection limit -1)))))
2078
2079 ;;; propertize
2080
2081 (defsubst company-round-tab (arg)
2082   (* (/ (+ arg tab-width) tab-width) tab-width))
2083
2084 (defun company-plainify (str)
2085   (let ((prefix (get-text-property 0 'line-prefix str)))
2086     (when prefix ; Keep the original value unmodified, for no special reason.
2087       (setq str (concat prefix str))
2088       (remove-text-properties 0 (length str) '(line-prefix) str)))
2089   (let* ((pieces (split-string str "\t"))
2090          (copy pieces))
2091     (while (cdr copy)
2092       (setcar copy (company-safe-substring
2093                     (car copy) 0 (company-round-tab (string-width (car copy)))))
2094       (pop copy))
2095     (apply 'concat pieces)))
2096
2097 (defun company-fill-propertize (value annotation width selected left right)
2098   (let* ((margin (length left))
2099          (common (or (company-call-backend 'match value)
2100                      (if company-common
2101                          (string-width company-common)
2102                        0)))
2103          (ann-ralign company-tooltip-align-annotations)
2104          (ann-truncate (< width
2105                           (+ (length value) (length annotation)
2106                              (if ann-ralign 1 0))))
2107          (ann-start (+ margin
2108                        (if ann-ralign
2109                            (if ann-truncate
2110                                (1+ (length value))
2111                              (- width (length annotation)))
2112                          (length value))))
2113          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
2114          (line (concat left
2115                        (if (or ann-truncate (not ann-ralign))
2116                            (company-safe-substring
2117                             (concat value
2118                                     (when (and annotation ann-ralign) " ")
2119                                     annotation)
2120                             0 width)
2121                          (concat
2122                           (company-safe-substring value 0
2123                                                   (- width (length annotation)))
2124                           annotation))
2125                        right)))
2126     (setq common (+ (min common width) margin))
2127     (setq width (+ width margin (length right)))
2128
2129     (add-text-properties 0 width '(face company-tooltip
2130                                    mouse-face company-tooltip-mouse)
2131                          line)
2132     (add-text-properties margin common
2133                          '(face company-tooltip-common
2134                            mouse-face company-tooltip-mouse)
2135                          line)
2136     (when (< ann-start ann-end)
2137       (add-text-properties ann-start ann-end
2138                            '(face company-tooltip-annotation
2139                              mouse-face company-tooltip-mouse)
2140                            line))
2141     (when selected
2142       (if (and company-search-string
2143                (string-match (regexp-quote company-search-string) value
2144                              (length company-prefix)))
2145           (let ((beg (+ margin (match-beginning 0)))
2146                 (end (+ margin (match-end 0))))
2147             (add-text-properties beg end '(face company-tooltip-search)
2148                                  line)
2149             (when (< beg common)
2150               (add-text-properties beg common
2151                                    '(face company-tooltip-common-selection)
2152                                    line)))
2153         (add-text-properties 0 width '(face company-tooltip-selection
2154                                        mouse-face company-tooltip-selection)
2155                              line)
2156         (add-text-properties margin common
2157                              '(face company-tooltip-common-selection
2158                                mouse-face company-tooltip-selection)
2159                              line)))
2160     line))
2161
2162 (defun company--clean-string (str)
2163   (replace-regexp-in-string
2164    "\\([^[:graph:] ]\\)\\|\\(\ufeff\\)\\|[[:multibyte:]]"
2165    (lambda (match)
2166      (cond
2167       ((match-beginning 1)
2168        ;; FIXME: Better char for 'non-printable'?
2169        ;; We shouldn't get any of these, but sometimes we might.
2170        "\u2017")
2171       ((match-beginning 2)
2172        ;; Zero-width non-breakable space.
2173        "")
2174       ((> (string-width match) 1)
2175        (concat
2176         (make-string (1- (string-width match)) ?\ufeff)
2177         match))
2178       (t match)))
2179    str))
2180
2181 ;;; replace
2182
2183 (defun company-buffer-lines (beg end)
2184   (goto-char beg)
2185   (let (lines lines-moved)
2186     (while (and (> (setq lines-moved (vertical-motion 1)) 0)
2187                 (<= (point) end))
2188       (let ((bound (min end (1- (point)))))
2189         ;; A visual line can contain several physical lines (e.g. with outline's
2190         ;; folding overlay).  Take only the first one.
2191         (push (buffer-substring beg
2192                                 (save-excursion
2193                                   (goto-char beg)
2194                                   (re-search-forward "$" bound 'move)
2195                                   (point)))
2196               lines))
2197       ;; One physical line can be displayed as several visual ones as well:
2198       ;; add empty strings to the list, to even the count.
2199       (dotimes (_ (1- lines-moved))
2200         (push "" lines))
2201       (setq beg (point)))
2202     (unless (eq beg end)
2203       (push (buffer-substring beg end) lines))
2204     (nreverse lines)))
2205
2206 (defun company-modify-line (old new offset)
2207   (concat (company-safe-substring old 0 offset)
2208           new
2209           (company-safe-substring old (+ offset (length new)))))
2210
2211 (defsubst company--length-limit (lst limit)
2212   (if (nthcdr limit lst)
2213       limit
2214     (length lst)))
2215
2216 (defsubst company--window-height ()
2217   (if (fboundp 'window-screen-lines)
2218       (floor (window-screen-lines))
2219     (window-body-height)))
2220
2221 (defsubst company--window-width ()
2222   (let ((ww (window-body-width)))
2223     ;; Account for the line continuation column.
2224     (when (zerop (cadr (window-fringes)))
2225       (cl-decf ww))
2226     (unless (or (display-graphic-p)
2227                 (version< "24.3.1" emacs-version))
2228       ;; Emacs 24.3 and earlier included margins
2229       ;; in window-width when in TTY.
2230       (cl-decf ww
2231                (let ((margins (window-margins)))
2232                  (+ (or (car margins) 0)
2233                     (or (cdr margins) 0)))))
2234     ww))
2235
2236 (defun company--replacement-string (lines old column nl &optional align-top)
2237   (cl-decf column company-tooltip-margin)
2238
2239   (when (and align-top company-tooltip-flip-when-above)
2240     (setq lines (reverse lines)))
2241
2242   (let ((width (length (car lines)))
2243         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2244                            column)))
2245     (when (> width remaining-cols)
2246       (cl-decf column (- width remaining-cols))))
2247
2248   (let ((offset (and (< column 0) (- column)))
2249         new)
2250     (when offset
2251       (setq column 0))
2252     (when align-top
2253       ;; untouched lines first
2254       (dotimes (_ (- (length old) (length lines)))
2255         (push (pop old) new)))
2256     ;; length into old lines.
2257     (while old
2258       (push (company-modify-line (pop old)
2259                                  (company--offset-line (pop lines) offset)
2260                                  column)
2261             new))
2262     ;; Append whole new lines.
2263     (while lines
2264       (push (concat (company-space-string column)
2265                     (company--offset-line (pop lines) offset))
2266             new))
2267
2268     (let ((str (concat (when nl " ")
2269                        "\n"
2270                        (mapconcat 'identity (nreverse new) "\n")
2271                        "\n")))
2272       (font-lock-append-text-property 0 (length str) 'face 'default str)
2273       (when nl (put-text-property 0 1 'cursor t str))
2274       str)))
2275
2276 (defun company--offset-line (line offset)
2277   (if (and offset line)
2278       (substring line offset)
2279     line))
2280
2281 (defun company--create-lines (selection limit)
2282   (let ((len company-candidates-length)
2283         (window-width (company--window-width))
2284         lines
2285         width
2286         lines-copy
2287         items
2288         previous
2289         remainder
2290         scrollbar-bounds)
2291
2292     ;; Maybe clear old offset.
2293     (when (< len (+ company-tooltip-offset limit))
2294       (setq company-tooltip-offset 0))
2295
2296     ;; Scroll to offset.
2297     (if (eq company-tooltip-offset-display 'lines)
2298         (setq limit (company-tooltip--lines-update-offset selection len limit))
2299       (company-tooltip--simple-update-offset selection len limit))
2300
2301     (cond
2302      ((eq company-tooltip-offset-display 'scrollbar)
2303       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2304                                                         limit len)))
2305      ((eq company-tooltip-offset-display 'lines)
2306       (when (> company-tooltip-offset 0)
2307         (setq previous (format "...(%d)" company-tooltip-offset)))
2308       (setq remainder (- len limit company-tooltip-offset)
2309             remainder (when (> remainder 0)
2310                         (setq remainder (format "...(%d)" remainder))))))
2311
2312     (cl-decf selection company-tooltip-offset)
2313     (setq width (max (length previous) (length remainder))
2314           lines (nthcdr company-tooltip-offset company-candidates)
2315           len (min limit len)
2316           lines-copy lines)
2317
2318     (cl-decf window-width (* 2 company-tooltip-margin))
2319     (when scrollbar-bounds (cl-decf window-width))
2320
2321     (dotimes (_ len)
2322       (let* ((value (pop lines-copy))
2323              (annotation (company-call-backend 'annotation value)))
2324         (setq value (company--clean-string value))
2325         (when annotation
2326           (when company-tooltip-align-annotations
2327             ;; `lisp-completion-at-point' adds a space.
2328             (setq annotation (comment-string-strip annotation t nil)))
2329           (setq annotation (company--clean-string annotation)))
2330         (push (cons value annotation) items)
2331         (setq width (max (+ (length value)
2332                             (if (and annotation company-tooltip-align-annotations)
2333                                 (1+ (length annotation))
2334                               (length annotation)))
2335                          width))))
2336
2337     (setq width (min window-width
2338                      (max company-tooltip-minimum-width
2339                           (if company-show-numbers
2340                               (+ 2 width)
2341                             width))))
2342
2343     (let ((items (nreverse items))
2344           (numbered (if company-show-numbers 0 99999))
2345           new)
2346       (when previous
2347         (push (company--scrollpos-line previous width) new))
2348
2349       (dotimes (i len)
2350         (let* ((item (pop items))
2351                (str (company-reformat (car item)))
2352                (annotation (cdr item))
2353                (right (company-space-string company-tooltip-margin))
2354                (width width))
2355           (when (< numbered 10)
2356             (cl-decf width 2)
2357             (cl-incf numbered)
2358             (setq right (concat (format " %d" (mod numbered 10)) right)))
2359           (push (concat
2360                  (company-fill-propertize str annotation
2361                                           width (equal i selection)
2362                                           (company-space-string
2363                                            company-tooltip-margin)
2364                                           right)
2365                  (when scrollbar-bounds
2366                    (company--scrollbar i scrollbar-bounds)))
2367                 new)))
2368
2369       (when remainder
2370         (push (company--scrollpos-line remainder width) new))
2371
2372       (nreverse new))))
2373
2374 (defun company--scrollbar-bounds (offset limit length)
2375   (when (> length limit)
2376     (let* ((size (ceiling (* limit (float limit)) length))
2377            (lower (floor (* limit (float offset)) length))
2378            (upper (+ lower size -1)))
2379       (cons lower upper))))
2380
2381 (defun company--scrollbar (i bounds)
2382   (propertize " " 'face
2383               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2384                   'company-scrollbar-fg
2385                 'company-scrollbar-bg)))
2386
2387 (defun company--scrollpos-line (text width)
2388   (propertize (concat (company-space-string company-tooltip-margin)
2389                       (company-safe-substring text 0 width)
2390                       (company-space-string company-tooltip-margin))
2391               'face 'company-tooltip))
2392
2393 ;; show
2394
2395 (defun company--pseudo-tooltip-height ()
2396   "Calculate the appropriate tooltip height.
2397 Returns a negative number if the tooltip should be displayed above point."
2398   (let* ((lines (company--row))
2399          (below (- (company--window-height) 1 lines)))
2400     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2401              (> lines below))
2402         (- (max 3 (min company-tooltip-limit lines)))
2403       (max 3 (min company-tooltip-limit below)))))
2404
2405 (defun company-pseudo-tooltip-show (row column selection)
2406   (company-pseudo-tooltip-hide)
2407   (save-excursion
2408
2409     (let* ((height (company--pseudo-tooltip-height))
2410            above)
2411
2412       (when (< height 0)
2413         (setq row (+ row height -1)
2414               above t))
2415
2416       (let* ((nl (< (move-to-window-line row) row))
2417              (beg (point))
2418              (end (save-excursion
2419                     (move-to-window-line (+ row (abs height)))
2420                     (point)))
2421              (ov (make-overlay (if nl beg (1- beg)) end nil t t))
2422              (args (list (mapcar 'company-plainify
2423                                  (company-buffer-lines beg end))
2424                          column nl above)))
2425
2426         (setq company-pseudo-tooltip-overlay ov)
2427         (overlay-put ov 'company-replacement-args args)
2428
2429         (let ((lines (company--create-lines selection (abs height))))
2430           (overlay-put ov 'company-display
2431                        (apply 'company--replacement-string lines args))
2432           (overlay-put ov 'company-width (string-width (car lines))))
2433
2434         (overlay-put ov 'company-column column)
2435         (overlay-put ov 'company-height height)))))
2436
2437 (defun company-pseudo-tooltip-show-at-point (pos column-offset)
2438   (let* ((col-row (company--col-row pos))
2439          (col (- (car col-row) column-offset)))
2440     (when (< col 0) (setq col 0))
2441     (company-pseudo-tooltip-show (1+ (cdr col-row)) col company-selection)))
2442
2443 (defun company-pseudo-tooltip-edit (selection)
2444   (let* ((height (overlay-get company-pseudo-tooltip-overlay 'company-height))
2445          (lines  (company--create-lines selection (abs height))))
2446     (overlay-put company-pseudo-tooltip-overlay 'company-width
2447                  (string-width (car lines)))
2448     (overlay-put company-pseudo-tooltip-overlay 'company-display
2449                  (apply 'company--replacement-string
2450                         lines
2451                         (overlay-get company-pseudo-tooltip-overlay
2452                                      'company-replacement-args)))))
2453
2454 (defun company-pseudo-tooltip-hide ()
2455   (when company-pseudo-tooltip-overlay
2456     (delete-overlay company-pseudo-tooltip-overlay)
2457     (setq company-pseudo-tooltip-overlay nil)))
2458
2459 (defun company-pseudo-tooltip-hide-temporarily ()
2460   (when (overlayp company-pseudo-tooltip-overlay)
2461     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2462     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)))
2463
2464 (defun company-pseudo-tooltip-unhide ()
2465   (when company-pseudo-tooltip-overlay
2466     (let* ((ov company-pseudo-tooltip-overlay)
2467            (disp (overlay-get ov 'company-display)))
2468       ;; Beat outline's folding overlays, at least.
2469       (overlay-put ov 'priority 1)
2470       ;; `display' could be better (http://debbugs.gnu.org/18285), but it
2471       ;; doesn't work when the overlay is empty, which is what happens at eob.
2472       ;; It also seems to interact badly with `cursor'.
2473       ;; We deal with priorities by having the overlay start before the newline.
2474       (overlay-put ov 'after-string disp)
2475       (overlay-put ov 'invisible t)
2476       (overlay-put ov 'window (selected-window)))))
2477
2478 (defun company-pseudo-tooltip-guard ()
2479   (cons
2480    (save-excursion (beginning-of-visual-line))
2481    (let ((ov company-pseudo-tooltip-overlay)
2482          (overhang (save-excursion (end-of-visual-line)
2483                                    (- (line-end-position) (point)))))
2484      (when (>= (overlay-get ov 'company-height) 0)
2485        (cons
2486         (buffer-substring-no-properties (point) (overlay-start ov))
2487         (when (>= overhang 0) overhang))))))
2488
2489 (defun company-pseudo-tooltip-frontend (command)
2490   "`company-mode' front-end similar to a tooltip but based on overlays."
2491   (cl-case command
2492     (pre-command (company-pseudo-tooltip-hide-temporarily))
2493     (post-command
2494      (unless (when (overlayp company-pseudo-tooltip-overlay)
2495               (let* ((ov company-pseudo-tooltip-overlay)
2496                      (old-height (overlay-get ov 'company-height))
2497                      (new-height (company--pseudo-tooltip-height)))
2498                 (and
2499                  (>= (* old-height new-height) 0)
2500                  (>= (abs old-height) (abs new-height))
2501                  (equal (company-pseudo-tooltip-guard)
2502                         (overlay-get ov 'company-guard)))))
2503        ;; Redraw needed.
2504        (company-pseudo-tooltip-show-at-point (point) (length company-prefix))
2505        (overlay-put company-pseudo-tooltip-overlay
2506                     'company-guard (company-pseudo-tooltip-guard)))
2507      (company-pseudo-tooltip-unhide))
2508     (hide (company-pseudo-tooltip-hide)
2509           (setq company-tooltip-offset 0))
2510     (update (when (overlayp company-pseudo-tooltip-overlay)
2511               (company-pseudo-tooltip-edit company-selection)))))
2512
2513 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2514   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2515   (unless (and (eq command 'post-command)
2516                (company--show-inline-p))
2517     (company-pseudo-tooltip-frontend command)))
2518
2519 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2520
2521 (defvar-local company-preview-overlay nil)
2522
2523 (defun company-preview-show-at-point (pos)
2524   (company-preview-hide)
2525
2526   (setq company-preview-overlay (make-overlay pos pos))
2527
2528   (let ((completion (nth company-selection company-candidates)))
2529     (setq completion (propertize completion 'face 'company-preview))
2530     (add-text-properties 0 (length company-common)
2531                          '(face company-preview-common) completion)
2532
2533     ;; Add search string
2534     (and company-search-string
2535          (string-match (regexp-quote company-search-string) completion)
2536          (add-text-properties (match-beginning 0)
2537                               (match-end 0)
2538                               '(face company-preview-search)
2539                               completion))
2540
2541     (setq completion (company-strip-prefix completion))
2542
2543     (and (equal pos (point))
2544          (not (equal completion ""))
2545          (add-text-properties 0 1 '(cursor t) completion))
2546
2547     (let ((ov company-preview-overlay))
2548       (overlay-put ov 'after-string completion)
2549       (overlay-put ov 'window (selected-window)))))
2550
2551 (defun company-preview-hide ()
2552   (when company-preview-overlay
2553     (delete-overlay company-preview-overlay)
2554     (setq company-preview-overlay nil)))
2555
2556 (defun company-preview-frontend (command)
2557   "`company-mode' front-end showing the selection as if it had been inserted."
2558   (pcase command
2559     (`pre-command (company-preview-hide))
2560     (`post-command (company-preview-show-at-point (point)))
2561     (`hide (company-preview-hide))))
2562
2563 (defun company-preview-if-just-one-frontend (command)
2564   "`company-preview-frontend', but only shown for single candidates."
2565   (when (or (not (eq command 'post-command))
2566             (company--show-inline-p))
2567     (company-preview-frontend command)))
2568
2569 (defun company--show-inline-p ()
2570   (and (not (cdr company-candidates))
2571        company-common
2572        (or (eq (company-call-backend 'ignore-case) 'keep-prefix)
2573            (string-prefix-p company-prefix company-common))))
2574
2575 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2576
2577 (defvar-local company-echo-last-msg nil)
2578
2579 (defvar company-echo-timer nil)
2580
2581 (defvar company-echo-delay .01)
2582
2583 (defun company-echo-show (&optional getter)
2584   (when getter
2585     (setq company-echo-last-msg (funcall getter)))
2586   (let ((message-log-max nil))
2587     (if company-echo-last-msg
2588         (message "%s" company-echo-last-msg)
2589       (message ""))))
2590
2591 (defun company-echo-show-soon (&optional getter)
2592   (when company-echo-timer
2593     (cancel-timer company-echo-timer))
2594   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2595
2596 (defsubst company-echo-show-when-idle (&optional getter)
2597   (when (sit-for company-echo-delay)
2598     (company-echo-show getter)))
2599
2600 (defun company-echo-format ()
2601
2602   (let ((limit (window-body-width (minibuffer-window)))
2603         (len -1)
2604         ;; Roll to selection.
2605         (candidates (nthcdr company-selection company-candidates))
2606         (i (if company-show-numbers company-selection 99999))
2607         comp msg)
2608
2609     (while candidates
2610       (setq comp (company-reformat (pop candidates))
2611             len (+ len 1 (length comp)))
2612       (if (< i 10)
2613           ;; Add number.
2614           (progn
2615             (setq comp (propertize (format "%d: %s" i comp)
2616                                    'face 'company-echo))
2617             (cl-incf len 3)
2618             (cl-incf i)
2619             (add-text-properties 3 (+ 3 (length company-common))
2620                                  '(face company-echo-common) comp))
2621         (setq comp (propertize comp 'face 'company-echo))
2622         (add-text-properties 0 (length company-common)
2623                              '(face company-echo-common) comp))
2624       (if (>= len limit)
2625           (setq candidates nil)
2626         (push comp msg)))
2627
2628     (mapconcat 'identity (nreverse msg) " ")))
2629
2630 (defun company-echo-strip-common-format ()
2631
2632   (let ((limit (window-body-width (minibuffer-window)))
2633         (len (+ (length company-prefix) 2))
2634         ;; Roll to selection.
2635         (candidates (nthcdr company-selection company-candidates))
2636         (i (if company-show-numbers company-selection 99999))
2637         msg comp)
2638
2639     (while candidates
2640       (setq comp (company-strip-prefix (pop candidates))
2641             len (+ len 2 (length comp)))
2642       (when (< i 10)
2643         ;; Add number.
2644         (setq comp (format "%s (%d)" comp i))
2645         (cl-incf len 4)
2646         (cl-incf i))
2647       (if (>= len limit)
2648           (setq candidates nil)
2649         (push (propertize comp 'face 'company-echo) msg)))
2650
2651     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2652             (mapconcat 'identity (nreverse msg) ", ")
2653             "}")))
2654
2655 (defun company-echo-hide ()
2656   (unless (equal company-echo-last-msg "")
2657     (setq company-echo-last-msg "")
2658     (company-echo-show)))
2659
2660 (defun company-echo-frontend (command)
2661   "`company-mode' front-end showing the candidates in the echo area."
2662   (pcase command
2663     (`post-command (company-echo-show-soon 'company-echo-format))
2664     (`hide (company-echo-hide))))
2665
2666 (defun company-echo-strip-common-frontend (command)
2667   "`company-mode' front-end showing the candidates in the echo area."
2668   (pcase command
2669     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2670     (`hide (company-echo-hide))))
2671
2672 (defun company-echo-metadata-frontend (command)
2673   "`company-mode' front-end showing the documentation in the echo area."
2674   (pcase command
2675     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
2676     (`hide (company-echo-hide))))
2677
2678 (provide 'company)
2679 ;;; company.el ends here