code.delx.au - gnu-emacs-elpa/blob - diff-hl-margin.el

   1 ;;; diff-hl-margin.el --- Highlight buffer changes on margins -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2012-2014  Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software: you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; This is a global mode, it modifies `diff-hl-mode' to use the margin
  23 ;; instead of the fringe. To toggle, type `M-x diff-hl-margin-mode'.
  24 ;;
  25 ;; Compared to the default behavior, this makes `diff-hl-mode'
  26 ;; indicators show up even when Emacs is running in a terminal.
  27 ;;
  28 ;; On the flip side, the indicators look simpler, and they are
  29 ;; incompatible with `linum-mode' or any other mode that uses the
  30 ;; margin.
  31 ;;
  32 ;; You might want to enable it conditionally in your init file
  33 ;; depending on whether Emacs is running in graphical mode:
  34 ;;
  35 ;; (unless (window-system) (diff-hl-margin-mode))
  36
  37 (require 'cl-lib)
  38 (require 'diff-hl)
  39 (require 'diff-hl-dired)
  40
  41 (defvar diff-hl-margin-side)
  42
  43 (defvar diff-hl-margin-old-highlight-function nil)
  44
  45 (defgroup diff-hl-margin nil
  46   "Highlight buffer changes on margin"
  47   :group 'diff-hl)
  48
  49 ;;;###autoload
  50 (define-minor-mode diff-hl-margin-mode
  51   "Toggle displaying `diff-hl-mode' highlights on the margin."
  52   :lighter "" :global t
  53   (if diff-hl-margin-mode
  54       (progn
  55         (add-hook 'diff-hl-mode-on-hook 'diff-hl-margin-minor-mode)
  56         (add-hook 'diff-hl-mode-off-hook 'diff-hl-margin-minor-mode-off)
  57         (add-hook 'diff-hl-dired-mode-on-hook 'diff-hl-margin-minor-mode)
  58         (add-hook 'diff-hl-dired-mode-off-hook 'diff-hl-margin-minor-mode-off))
  59     (remove-hook 'diff-hl-mode-on-hook 'diff-hl-margin-minor-mode)
  60     (remove-hook 'diff-hl-mode-off-hook 'diff-hl-margin-minor-mode-off)
  61     (remove-hook 'diff-hl-dired-mode-on-hook 'diff-hl-margin-minor-mode)
  62     (remove-hook 'diff-hl-dired-mode-off-hook 'diff-hl-margin-minor-mode-off))
  63   (dolist (buf (buffer-list))
  64     (with-current-buffer buf
  65       (cond
  66        (diff-hl-mode
  67         (diff-hl-margin-minor-mode (if diff-hl-margin-mode 1 -1))
  68         (diff-hl-update))
  69        (diff-hl-dired-mode
  70         (diff-hl-margin-minor-mode (if diff-hl-margin-mode 1 -1))
  71         (diff-hl-dired-update))))))
  72
  73 (define-minor-mode diff-hl-margin-minor-mode
  74   "Toggle displaying `diff-hl-mode' highlights on the margin locally.
  75 You probably shouldn't use this function directly."
  76   :lighter ""
  77   (let ((width-var (intern (format "%s-margin-width" diff-hl-margin-side))))
  78     (if diff-hl-margin-minor-mode
  79         (progn
  80           (set (make-local-variable 'diff-hl-margin-old-highlight-function)
  81                diff-hl-highlight-function)
  82           (set (make-local-variable 'diff-hl-highlight-function)
  83                'diff-hl-highlight-on-margin)
  84           (set width-var 1))
  85       (setq diff-hl-highlight-function diff-hl-margin-old-highlight-function
  86             diff-hl-margin-old-highlight-function nil)
  87       (set width-var 0)))
  88   (dolist (win (get-buffer-window-list))
  89     (set-window-buffer win (current-buffer))))
  90
  91 (defcustom diff-hl-margin-side 'left
  92   "Which margin to use for indicators."
  93   :type '(choice (const left)
  94                  (const right))
  95   :set (lambda (var value)
  96          (let ((on diff-hl-margin-mode))
  97            (when on (diff-hl-margin-mode -1))
  98            (set-default var value)
  99            (when on (diff-hl-margin-mode 1)))))
 100
 101 (defun diff-hl-margin-minor-mode-off ()
 102   (diff-hl-margin-minor-mode -1))
 103
 104 (defvar diff-hl-margin-spec-cache
 105   (cl-loop for (type . char) in '((insert . "+") (delete . "-")
 106                                   (change . "!") (unknown . "?")
 107                                   (ignored . "i"))
 108         nconc
 109         (cl-loop for side in '(left right)
 110                  collect
 111                  (cons (cons type side)
 112                        (propertize
 113                         " " 'display
 114                         `((margin ,(intern (format "%s-margin" side)))
 115                           ,(propertize char 'face
 116                                        (intern (format "diff-hl-%s" type)))))))))
 117
 118 (defun diff-hl-highlight-on-margin (ovl type _shape)
 119   (let ((spec (cdr (assoc (cons type diff-hl-margin-side)
 120                           diff-hl-margin-spec-cache))))
 121     (overlay-put ovl 'before-string spec)))
 122
 123 (provide 'diff-hl-margin)
 124
 125 ;;; diff-hl-margin.el ends here