code.delx.au - gnu-emacs-elpa/blob - multishell.el

   1 ;;; multishell.el --- manage interaction with multiple local and remote shells
   2
   3 ;; Copyright (C) 1999-2016 Free Software Foundation, Inc. and Ken Manheimer
   4
   5 ;; Author: Ken Manheimer <ken.manheimer@gmail.com>
   6 ;; Version: 1.0.5
   7 ;; Created: 1999 -- first public availability
   8 ;; Keywords: processes
   9 ;; URL: https://github.com/kenmanheimer/EmacsUtils
  10 ;;
  11 ;;; Commentary:
  12 ;;
  13 ;; Easily use and navigate multiple shell buffers, including remote shells.
  14 ;; Fundamentally, multishell is the function `multishell-pop-to-shell' -
  15 ;; a la `pop-to-buffer' - plus a keybinding. Together, they enable you to:
  16 ;;
  17 ;; * Get to the input point from wherever you are in a shell buffer,
  18 ;; * ... or to a shell buffer if you're not currently in one.
  19 ;; * Use universal arguments to launch and choose among alternate shell buffers,
  20 ;; * ... and select which is default.
  21 ;; * Append a path to a new shell name to launch a shell in that directory,
  22 ;; * ... and use a path with Emacs tramp syntax to launch a remote shell.
  23 ;;
  24 ;; Customize-group `multishell` to select and activate a keybinding and set
  25 ;; various behaviors.
  26 ;;
  27 ;; See the multishell-pop-to-shell docstring for details.
  28 ;;
  29 ;;; Change Log:
  30 ;;
  31 ;; 2016-01-02 Ken Manheimer - working on this in public, but not yet released.
  32 ;;
  33 ;;; TODO:
  34 ;;
  35 ;; * Preserveable (savehist) history that associates names with paths
  36 ;;   - Editible
  37 ;;     - New shell prompts for confirmation
  38 ;;       - Including path from history, if any
  39 ;;       - which offers opportunity to entry
  40 ;;       - ?completions list toggles between short and long?
  41 ;;         - "Toggle short/long listing by immediately repeating completion key"
  42 ;;   - History tracks buffer disposition
  43 ;;     - Deleting buffer removes history entry
  44 ;;     - Track buffer name change using buffer-list-update-hook
  45 ;;   - Option to track last directory - multishell-remember-last-dir
  46 ;;     - dig into tramp to find out where the actual remote+dir path is
  47 ;;     - Include note about tramp not tracking remote dir changes well
  48 ;;       - use `M-x shell-resync-dirs'; I bind to M-return
  49 ;; * Note in multishell doc to activate (customize) savehist to preserve history
  50
  51 ;;; Code:
  52
  53 (require 'comint)
  54 (require 'shell)
  55
  56 (defgroup multishell nil
  57   "Allout extension that highlights outline structure graphically.
  58
  59 Customize `allout-widgets-auto-activation' to activate allout-widgets
  60 with allout-mode."
  61   :group 'shell)
  62
  63 (defcustom multishell-command-key "\M- "
  64   "The key to use if `multishell-activate-command-key' is true.
  65
  66 You can instead manually bind `multishell-pop-to-shell` using emacs
  67 lisp, eg: (global-set-key \"\\M- \" 'multishell-pop-to-shell)."
  68   :type 'key-sequence
  69   :group 'multishell)
  70
  71 (defvar multishell--responsible-for-command-key nil
  72   "Multishell internal.")
  73 (defun multishell-activate-command-key-setter (symbol setting)
  74   "Implement `multishell-activate-command-key' choice."
  75   (set-default 'multishell-activate-command-key setting)
  76   (when (or setting multishell--responsible-for-command-key)
  77     (multishell-implement-command-key-choice (not setting))))
  78 (defun multishell-implement-command-key-choice (&optional unbind)
  79   "If settings dicate, implement binding of multishell command key.
  80
  81 If optional UNBIND is true, globally unbind the key.
  82
  83 * `multishell-activate-command-key' - Set this to get the binding or not.
  84 * `multishell-command-key' - The key to use for the binding, if appropriate."
  85   (cond (unbind
  86          (when (and (boundp 'multishell-command-key) multishell-command-key)
  87            (global-unset-key multishell-command-key)))
  88         ((not (and (boundp 'multishell-activate-command-key)
  89                    (boundp 'multishell-command-key)))
  90          nil)
  91         ((and multishell-activate-command-key multishell-command-key)
  92          (setq multishell--responsible-for-command-key t)
  93          (global-set-key multishell-command-key 'multishell-pop-to-shell))))
  94
  95 (defcustom multishell-activate-command-key nil
  96   "Set this to impose the `multishell-command-key' binding.
  97
  98 You can instead manually bind `multishell-pop-to-shell` using emacs
  99 lisp, eg: (global-set-key \"\\M- \" 'multishell-pop-to-shell)."
 100   :type 'boolean
 101   :set 'multishell-activate-command-key-setter
 102   :group 'multishell)
 103
 104 ;; Assert the customizations whenever the package is loaded:
 105 (with-eval-after-load "multishell"
 106   (multishell-implement-command-key-choice))
 107
 108 (defcustom multishell-pop-to-frame nil
 109   "*If non-nil, jump to a frame already showing the shell, if another is.
 110
 111 Otherwise, disregard already-open windows on the shell if they're
 112 in another frame, and open a new window on the shell in the
 113 current frame.
 114
 115 \(Use `pop-up-windows' to change multishell other-buffer vs
 116 current-buffer behavior.)"
 117   :type 'boolean
 118   :group 'multishell)
 119
 120 ;; (defcustom multishell-persist-shell-names nil
 121 ;;   "Remember shell name/path associations across sessions. Note well:
 122 ;; This will activate minibuffer history persistence, in general, if it's not
 123 ;; already active."
 124 ;;  :type 'boolean
 125 ;;  :set 'multishell-activate-persistence
 126 ;;  :group 'shell)
 127
 128 (defvar multishell-history nil
 129   "Name/path entries, most recent first.")
 130 (when (and (not multishell-history)
 131            (boundp 'multishell-buffer-name-history)
 132            multishell-buffer-name-history)
 133   ;; Migrate few users who had old var to new.
 134   (setq multishell-history multishell-buffer-name-history)
 135  )
 136
 137 (defvar multishell-primary-name "*shell*"
 138   "Shell name to use for un-modified multishell-pop-to-shell buffer target.")
 139
 140 (defun multishell-register-name-to-path (name path)
 141   "Add or replace entry associating NAME with PATH in `multishell-history'."
 142   ;; Add or promote to the front, tracking path changes in the process.
 143   (let* ((entry (multishell-history-entry name))
 144          (becomes (concat name path)))
 145     (when entry
 146       (setq multishell-history (delete entry multishell-history)))
 147     (push becomes multishell-history)))
 148
 149 (defun multishell-history-entry (name)
 150   "Return `multishell-history' entry that starts with NAME, or nil if none."
 151   (let ((match-expr (concat "^" name "\\\(/.*$\\\)?")))
 152     (dolist (entry multishell-history)
 153       (when (string-match match-expr entry)
 154         (return entry)))))
 155
 156 (defun multishell-pop-to-shell (&optional arg)
 157   "Easily navigate to and within multiple shell buffers, local and remote.
 158
 159 Use universal arguments to launch and choose between alternate
 160 shell buffers and to select which is default.  Append a path to
 161 a new shell name to launch a shell in that directory, and use
 162 Emacs tramp syntax to launch a remote shell.
 163
 164 Customize-group `multishell' to set up a key binding and tweak behaviors.
 165
 166 ==== Basic operation:
 167
 168  - If the current buffer is shell-mode (or shell-mode derived)
 169    buffer then focus is moved to the process input point.
 170
 171    \(You can use a universal argument go to a different shell
 172    buffer when already in a buffer that has a process - see
 173    below.)
 174
 175  - If not in a shell buffer (or with universal argument), go to a
 176    window that is already showing the (a) shell buffer, if any.
 177
 178    In this case, the cursor is left in its prior position in the
 179    shell buffer. Repeating the command will then go to the
 180    process input point, per the first item in this list.
 181
 182    We respect `pop-up-windows', so you can adjust it to set the
 183    other-buffer/same-buffer behavior.
 184
 185  - Otherwise, start a new shell buffer, using the current
 186    directory as the working directory.
 187
 188 If a buffer with the resulting name exists and its shell process
 189 was disconnected or otherwise stopped, it's resumed.
 190
 191 ===== Universal arg to start and select between named shell buffers:
 192
 193 You can name alternate shell buffers to create or return to using
 194 single or doubled universal arguments:
 195
 196  - With a single universal argument, prompt for the buffer name
 197    to use (without the asterisks that shell mode will put around
 198    the name), defaulting to 'shell'.
 199
 200    Completion is available.
 201
 202    This combination makes it easy to start and switch between
 203    multiple shell buffers.
 204
 205  - A double universal argument will prompt for the name *and* set
 206    the default to that name, so the target shell becomes the
 207    primary.
 208
 209 ===== Select starting directory and remote host:
 210
 211 The shell buffer name you give to the prompt for a universal arg
 212 can include an appended path. That will be used for the startup
 213 directory. You can use tramp remote syntax to specify a remote
 214 shell. If there is an element after a final '/', that's used for
 215 the buffer name. Otherwise, the host, domain, or path is used.
 216
 217 For example:
 218
 219 * Use '/ssh:example.net:' for a shell buffer in your homedir on
 220   example.net; the buffer will be named \"example.net\".
 221 * '\#ex/ssh:example.net|sudo:root@example.net:/etc' for a root shell
 222   in /etc on example.net named \"#ex\".
 223
 224 You can change the startup path for a shell buffer by editing it
 225 at the completion prompt. The new path will be preserved in
 226 history but will not take effect for an already-running shell.
 227
 228 To remove a shell buffer's history entry, kill the buffer and
 229 affirm removal of the entry when prompted.
 230
 231 ===== Activate savehist to persisting your shell buffer names and paths:
 232
 233 To have emacs maintain your history of shell buffer names and paths,
 234 customize the savehist group to activate savehist."
 235
 236   (interactive "P")
 237
 238   (let* ((from-buffer (current-buffer))
 239          (from-buffer-is-shell (derived-mode-p 'shell-mode))
 240          (doublearg (equal arg '(16)))
 241          (target-name-and-path
 242           (multishell-derive-target-name-and-path
 243            (if arg
 244                (multishell-read-bare-shell-buffer-name
 245                 (format "Shell buffer name [%s]%s "
 246                         (substring-no-properties
 247                          multishell-primary-name
 248                          1 (- (length multishell-primary-name) 1))
 249                         (if doublearg " <==" ":"))
 250                 multishell-primary-name)
 251              multishell-primary-name)))
 252          (use-default-dir (cadr target-name-and-path))
 253          (target-shell-buffer-name (car target-name-and-path))
 254          (curr-buff-proc (get-buffer-process from-buffer))
 255          (target-buffer (if from-buffer-is-shell
 256                             from-buffer
 257                           (get-buffer target-shell-buffer-name)))
 258          inwin
 259          already-there)
 260
 261     (when doublearg
 262       (setq multishell-primary-name target-shell-buffer-name))
 263
 264     ;; Situate:
 265
 266     (cond
 267
 268      ((and (or curr-buff-proc from-buffer-is-shell)
 269            (not arg)
 270            (eq from-buffer target-buffer)
 271            (not (eq target-shell-buffer-name (buffer-name from-buffer))))
 272       ;; In a shell buffer, but not named - stay in buffer, but go to end.
 273       (setq already-there t))
 274
 275      ((string= (buffer-name) target-shell-buffer-name)
 276       ;; Already in the specified shell buffer:
 277       (setq already-there t))
 278
 279      ((or (not target-buffer)
 280           (not (setq inwin
 281                      (multishell-get-visible-window-for-buffer target-buffer))))
 282       ;; No preexisting shell buffer, or not in a visible window:
 283       (pop-to-buffer target-shell-buffer-name pop-up-windows))
 284
 285        ;; Buffer exists and already has a window - jump to it:
 286      (t (if (and multishell-pop-to-frame
 287                  inwin
 288                  (not (equal (window-frame (selected-window))
 289                              (window-frame inwin))))
 290             (select-frame-set-input-focus (window-frame inwin)))
 291         (if (not (string= (buffer-name (current-buffer))
 292                           target-shell-buffer-name))
 293             (pop-to-buffer target-shell-buffer-name t))))
 294
 295     ;; We're in the buffer. Activate:
 296
 297     (cond ((not (comint-check-proc (current-buffer)))
 298            (multishell-start-shell-in-buffer (buffer-name (current-buffer))
 299                                              use-default-dir))
 300           (use-default-dir
 301            (cd use-default-dir)))
 302
 303     ;; If the destination buffer has a stopped process, resume it:
 304     (let ((process (get-buffer-process (current-buffer))))
 305       (if (and process (equal 'stop (process-status process)))
 306           (continue-process process)))
 307     (multishell-register-name-to-path (multishell-unbracket-asterisks
 308                                        target-shell-buffer-name)
 309                                       use-default-dir)
 310     (when (or already-there
 311              (equal (current-buffer) from-buffer))
 312       (goto-char (point-max))
 313       (and (get-buffer-process from-buffer)
 314            (goto-char (process-mark (get-buffer-process from-buffer)))))))
 315
 316 (defun multishell-kill-buffer-query-function ()
 317   "Offer to remove multishell-history entry for buffer."
 318   ;; Removal choice is crucial, so users can, eg, kill and a runaway shell
 319   ;; and keep the history entry to easily restart it.
 320   ;;
 321   ;; We use kill-buffer-query-functions instead of kill-buffer-hook because:
 322   ;;
 323   ;; 1. It enables the user to remove the history without killing the buffer,
 324   ;;    by cancelling the kill-buffer process after affirming history removal.
 325   ;; 2. kill-buffer-hooks often fails to run when killing shell buffers!
 326   ;;    I've failed to resolve that, and like the first reason well enough.
 327
 328   ;; (Use condition-case to avoid inadvertant disruption of kill-buffer
 329   ;; activity.  kill-buffer happens behind the scenes a whole lot.)
 330   (condition-case anyerr
 331       (let ((entry (and (derived-mode-p 'shell-mode)
 332                         (multishell-history-entry
 333                          (multishell-unbracket-asterisks (buffer-name))))))
 334         (when (and entry
 335                    (y-or-n-p (format "Remove multishell history entry `%s'? "
 336                                      entry)))
 337           (setq multishell-history
 338                 (delete entry multishell-history))))
 339     (error nil))
 340   t)
 341 (add-hook 'kill-buffer-query-functions 'multishell-kill-buffer-query-function)
 342
 343 (defun multishell-get-visible-window-for-buffer (buffer)
 344   "Return visible window containing buffer."
 345   (catch 'got-a-vis
 346     (walk-windows
 347      (function (lambda (win)
 348                  (if (and (eq (window-buffer win) buffer)
 349                           (equal (frame-parameter
 350                                   (selected-frame) 'display)
 351                                  (frame-parameter
 352                                   (window-frame win) 'display)))
 353                      (throw 'got-a-vis win))))
 354      nil 'visible)
 355     nil))
 356
 357 (defun multishell-read-bare-shell-buffer-name (prompt default)
 358   "PROMPT for shell buffer name, sans asterisks.
 359
 360 Return the supplied name bracketed with the asterisks, or specified DEFAULT
 361 on empty input."
 362   (let* ((candidates
 363           (append
 364            ;; Plain shell buffer names appended with names from name/path hist:
 365            (remq nil
 366                  (mapcar (lambda (buffer)
 367                            (let* ((name (multishell-unbracket-asterisks
 368                                          (buffer-name buffer))))
 369                              (and (with-current-buffer buffer
 370                                     ;; Shell mode buffers.
 371                                     (derived-mode-p 'shell-mode))
 372                                   (not (multishell-history-entry name))
 373                                   name)))
 374                          (buffer-list)))
 375            multishell-history))
 376          (got (completing-read prompt
 377                                ;; COLLECTION:
 378                                (reverse candidates)
 379                                ;; PREDICATE:
 380                                nil
 381                                ;; REQUIRE-MATCH:
 382                                'confirm
 383                                ;; INITIAL-INPUT
 384                                nil
 385                                ;; HIST:
 386                                'multishell-history)))
 387     (if (not (string= got ""))
 388         (multishell-bracket-asterisks got)
 389       default)))
 390
 391 (defun multishell-derive-target-name-and-path (path-ish)
 392   "Give tramp-style PATH-ISH, determine target name and default directory.
 393
 394 The name is the part of the string before the initial '/' slash,
 395 if any. Otherwise, it's either the host-name, domain-name, final
 396 directory name, or local host name. The path is everything
 397 besides the string before the initial '/' slash.
 398
 399 Return them as a list (name dir), with dir nil if none given."
 400   (let (name (path "") dir)
 401     (cond ((string= path-ish "") (setq dir multishell-primary-name))
 402           ((string-match "^\\*\\([^/]*\\)\\(/.*\\)\\*" path-ish)
 403            ;; We have a path, use it
 404            (let ((overt-name (match-string 1 path-ish)))
 405              (setq path (match-string 2 path-ish))
 406              (if (string= overt-name "") (setq overt-name nil))
 407              (if (string= path "") (setq path nil))
 408              (setq name
 409                    (multishell-bracket-asterisks
 410                     (or overt-name
 411                         (if (file-remote-p path)
 412                             (let ((vec (tramp-dissect-file-name path)))
 413                               (or (tramp-file-name-host vec)
 414                                   (tramp-file-name-domain vec)
 415                                   (tramp-file-name-localname vec)
 416                                   system-name))
 417                           (multishell-unbracket-asterisks
 418                            multishell-primary-name)))))))
 419           (t (setq name (multishell-bracket-asterisks path-ish))))
 420     (list name path)))
 421
 422 (defun multishell-bracket-asterisks (name)
 423   "Return a copy of name, ensuring it has an asterisk at the beginning and end."
 424   (if (not (string= (substring name 0 1) "*"))
 425       (setq name (concat "*" name)))
 426   (if (not (string= (substring name -1) "*"))
 427       (setq name (concat name "*")))
 428   name)
 429 (defun multishell-unbracket-asterisks (name)
 430   "Return a copy of name, removing asterisks, if any, at beginning and end."
 431   (if (string= (substring name 0 1) "*")
 432       (setq name (substring name 1)))
 433   (if (string= (substring name -1) "*")
 434       (setq name (substring name 0 -1)))
 435   name)
 436
 437 (defun multishell-start-shell-in-buffer (buffer-name path)
 438   "Ensure a shell is started, with name NAME and PATH."
 439   ;; We work around shell-mode's bracketing of the buffer name, and do
 440   ;; some tramp-mode hygiene for remote connections.
 441
 442   (let* ((buffer buffer-name)
 443          (prog (or explicit-shell-file-name
 444                    (getenv "ESHELL")
 445                    (getenv "SHELL")
 446                    "/bin/sh"))
 447          (name (file-name-nondirectory prog))
 448          (startfile (concat "~/.emacs_" name))
 449          (xargs-name (intern-soft (concat "explicit-" name "-args"))))
 450     (set-buffer buffer-name)
 451     (if (and path (not (string= path "")))
 452         (setq default-directory path))
 453     (when (and (file-remote-p default-directory)
 454                (derived-mode-p 'shell-mode)
 455                (not (comint-check-proc (current-buffer))))
 456       ;; We're returning to an already established but disconnected remote
 457       ;; shell, tidy it:
 458       (tramp-cleanup-connection
 459        (tramp-dissect-file-name default-directory 'noexpand)
 460        'keep-debug 'keep-password))
 461     ;; (cd default-directory) will reconnect a disconnected remote:
 462     (cd default-directory)
 463     (setq buffer (set-buffer (apply 'make-comint
 464                                     (multishell-unbracket-asterisks buffer-name)
 465                                     prog
 466                                     (if (file-exists-p startfile)
 467                                         startfile)
 468                                     (if (and xargs-name
 469                                              (boundp xargs-name))
 470                                         (symbol-value xargs-name)
 471                                       '("-i")))))
 472     (shell-mode)))
 473
 474 (provide 'multishell)
 475
 476 ;;; multishell.el ends here