code.delx.au - gnu-emacs-elpa/blob - diff-hl-margin.el

   1 ;;; diff-hl-margin.el --- Highlight buffer changes on margins -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2012-2014  Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software: you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; This is a global mode, it modifies `diff-hl-mode' to use the margin
  23 ;; instead of the fringe. To toggle, type `M-x diff-hl-margin-mode'.
  24 ;;
  25 ;; Compared to the default behavior, this makes `diff-hl-mode'
  26 ;; indicators show up even when Emacs is running in a terminal.
  27 ;;
  28 ;; On the flip side, the indicators look simpler, and they are
  29 ;; incompatible with `linum-mode' or any other mode that uses the
  30 ;; margin.
  31 ;;
  32 ;; You might want to enable it conditionally in your init file
  33 ;; depending on whether Emacs is running in graphical mode:
  34 ;;
  35 ;; (unless (window-system) (diff-hl-margin-mode))
  36
  37 (require 'cl-lib)
  38 (require 'diff-hl)
  39 (require 'diff-hl-dired)
  40
  41 (defvar diff-hl-margin-old-highlight-function nil)
  42
  43 (defgroup diff-hl-margin nil
  44   "Highlight buffer changes on margin"
  45   :group 'diff-hl)
  46
  47 (defcustom diff-hl-margin-side 'left
  48   "Which margin to use for indicators."
  49   :type '(choice (const left)
  50                  (const right))
  51   :set (lambda (var value)
  52          (let ((on diff-hl-margin-mode))
  53            (when on (diff-hl-margin-mode -1))
  54            (set-default var value)
  55            (when on (diff-hl-margin-mode 1)))))
  56
  57 ;;;###autoload
  58 (define-minor-mode diff-hl-margin-mode
  59   "Toggle displaying `diff-hl-mode' highlights on the margin."
  60   :lighter "" :global t
  61   (if diff-hl-margin-mode
  62       (progn
  63         (add-hook 'diff-hl-mode-on-hook 'diff-hl-margin-minor-mode)
  64         (add-hook 'diff-hl-mode-off-hook 'diff-hl-margin-minor-mode-off)
  65         (add-hook 'diff-hl-dired-mode-on-hook 'diff-hl-margin-minor-mode)
  66         (add-hook 'diff-hl-dired-mode-off-hook 'diff-hl-margin-minor-mode-off))
  67     (remove-hook 'diff-hl-mode-on-hook 'diff-hl-margin-minor-mode)
  68     (remove-hook 'diff-hl-mode-off-hook 'diff-hl-margin-minor-mode-off)
  69     (remove-hook 'diff-hl-dired-mode-on-hook 'diff-hl-margin-minor-mode)
  70     (remove-hook 'diff-hl-dired-mode-off-hook 'diff-hl-margin-minor-mode-off))
  71   (dolist (buf (buffer-list))
  72     (with-current-buffer buf
  73       (cond
  74        (diff-hl-mode
  75         (diff-hl-margin-minor-mode (if diff-hl-margin-mode 1 -1))
  76         (diff-hl-update))
  77        (diff-hl-dired-mode
  78         (diff-hl-margin-minor-mode (if diff-hl-margin-mode 1 -1))
  79         (diff-hl-dired-update))))))
  80
  81 (define-minor-mode diff-hl-margin-minor-mode
  82   "Toggle displaying `diff-hl-mode' highlights on the margin locally.
  83 You probably shouldn't use this function directly."
  84   :lighter ""
  85   (let ((width-var (intern (format "%s-margin-width" diff-hl-margin-side))))
  86     (if diff-hl-margin-minor-mode
  87         (progn
  88           (set (make-local-variable 'diff-hl-margin-old-highlight-function)
  89                diff-hl-highlight-function)
  90           (set (make-local-variable 'diff-hl-highlight-function)
  91                'diff-hl-highlight-on-margin)
  92           (set width-var 1))
  93       (setq diff-hl-highlight-function diff-hl-margin-old-highlight-function
  94             diff-hl-margin-old-highlight-function nil)
  95       (set width-var 0)))
  96   (dolist (win (get-buffer-window-list))
  97     (set-window-buffer win (current-buffer))))
  98
  99 (defun diff-hl-margin-minor-mode-off ()
 100   (diff-hl-margin-minor-mode -1))
 101
 102 (defvar diff-hl-margin-spec-cache
 103   (cl-loop for (type . char) in '((insert . "+") (delete . "-")
 104                                   (change . "|") (unknown . "?"))
 105         nconc
 106         (cl-loop for side in '(left right)
 107                  collect
 108                  (cons (cons type side)
 109                        (propertize
 110                         " " 'display
 111                         `((margin ,(intern (format "%s-margin" side)))
 112                           ,(propertize char 'face
 113                                        (intern (format "diff-hl-%s" type)))))))))
 114
 115 (defun diff-hl-highlight-on-margin (ovl type _shape)
 116   (let ((spec (cdr (assoc (cons type diff-hl-margin-side)
 117                           diff-hl-margin-spec-cache))))
 118     (overlay-put ovl 'before-string spec)))
 119
 120 (provide 'diff-hl-margin)
 121
 122 ;;; diff-hl-margin.el ends here