code.delx.au - gnu-emacs-elpa/blob - company-etags.el

   1 ;;; company-etags.el --- company-mode completion backend for etags
   2
   3 ;; Copyright (C) 2009-2011, 2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'cl-lib)
  30 (require 'etags)
  31
  32 (defgroup company-etags nil
  33   "Completion backend for etags."
  34   :group 'company)
  35
  36 (defcustom company-etags-use-main-table-list t
  37   "Always search `tags-table-list' if set.
  38 If this is disabled, `company-etags' will try to find the one table for each
  39 buffer automatically."
  40   :type '(choice (const :tag "off" nil)
  41                  (const :tag "on" t)))
  42
  43 (defcustom company-etags-ignore-case nil
  44   "Non-nil to ignore case in completion candidates."
  45   :type 'boolean
  46   :package-version '(company . "0.7.3"))
  47
  48 (defvar company-etags-modes '(prog-mode c-mode objc-mode c++-mode java-mode
  49                               jde-mode pascal-mode perl-mode python-mode))
  50
  51 (defvar-local company-etags-buffer-table 'unknown)
  52
  53 (defun company-etags-find-table ()
  54   (let ((file (expand-file-name
  55                "TAGS"
  56                (locate-dominating-file (or buffer-file-name
  57                                            default-directory)
  58                                        "TAGS"))))
  59     (when (and file (file-regular-p file))
  60       (list file))))
  61
  62 (defun company-etags-buffer-table ()
  63   (or (and company-etags-use-main-table-list tags-table-list)
  64       (if (eq company-etags-buffer-table 'unknown)
  65           (setq company-etags-buffer-table (company-etags-find-table))
  66         company-etags-buffer-table)))
  67
  68 (defun company-etags--candidates (prefix)
  69   (let ((tags-table-list (company-etags-buffer-table))
  70         (completion-ignore-case company-etags-ignore-case))
  71     (and (or tags-file-name tags-table-list)
  72          (fboundp 'tags-completion-table)
  73          (save-excursion
  74            (visit-tags-table-buffer)
  75            (all-completions prefix (tags-completion-table))))))
  76
  77 ;;;###autoload
  78 (defun company-etags (command &optional arg &rest ignored)
  79   "`company-mode' completion backend for etags."
  80   (interactive (list 'interactive))
  81   (cl-case command
  82     (interactive (company-begin-backend 'company-etags))
  83     (prefix (and (apply 'derived-mode-p company-etags-modes)
  84                  (not (company-in-string-or-comment))
  85                  (company-etags-buffer-table)
  86                  (or (company-grab-symbol) 'stop)))
  87     (candidates (company-etags--candidates arg))
  88     (location (let ((tags-table-list (company-etags-buffer-table)))
  89                 (when (fboundp 'find-tag-noselect)
  90                   (save-excursion
  91                     (let ((buffer (find-tag-noselect arg)))
  92                       (cons buffer (with-current-buffer buffer (point))))))))
  93     (ignore-case company-etags-ignore-case)))
  94
  95 (provide 'company-etags)
  96 ;;; company-etags.el ends here