code.delx.au - gnu-emacs-elpa/blob - chess.el

   1 ;;; chess.el --- Play chess in Emacs
   2
   3 ;; Copyright (C) 2001 John Wiegley <johnw@gnu.org>
   4
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: chess.el
   7 ;; Version: 2.0
   8 ;; Keywords: games
   9 ;; Author: John Wiegley <johnw@gnu.org>
  10 ;; Maintainer: John Wiegley <johnw@gnu.org>
  11 ;; Description: Play chess in Emacs
  12 ;; URL: http://www.gci-net.com/~johnw/Emacs/packages/chess.tar.gz
  13 ;; Compatibility: Emacs20, Emacs21, XEmacs21
  14
  15 ;; This file is not part of GNU Emacs.
  16
  17 ;; This is free software; you can redistribute it and/or modify it under
  18 ;; the terms of the GNU General Public License as published by the Free
  19 ;; Software Foundation; either version 2, or (at your option) any later
  20 ;; version.
  21 ;;
  22 ;; This is distributed in the hope that it will be useful, but WITHOUT
  23 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  24 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  25 ;; for more details.
  26 ;;
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  29 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  30 ;; MA 02111-1307, USA.
  31
  32 ;;; Commentary:
  33
  34 ;; Welcome to Emacs Chess, a chess playing module for GNU Emacs.
  35 ;;
  36 ;; This program will not play chess against you; it is not a chess
  37 ;; computer.  It can use a chess computer, however, to simulate your
  38 ;; opponent's moves.  This is decided when you choose your opponent.
  39 ;; You must, of course, have that chess computer installed.  See the
  40 ;; top of chess-player.el for more information.
  41 ;;
  42 ;; To just get a chessboard up, put the following in your .emacs file:
  43 ;;
  44 ;;   (add-to-list 'load-list "<the path to Emacs Chess>")
  45 ;;
  46 ;;   (autoload 'chess "chess" "Play a game of chess" t)
  47 ;;
  48 ;; Now you can type `M-x chess', and play chess against anyone else in
  49 ;; the room with you, without having to install anything more.
  50 ;;
  51 ;; Once this is working, the next thing to do is to customize
  52 ;; `chess-use-modules'.  This is a list of functionality modules used
  53 ;; by chess.el to provide its functionality.  You can enable or
  54 ;; disable modules so that Emacs Chess better suites your tastes.
  55 ;; Those modules in turn often have configuration variables, and
  56 ;; appropriate documentation at the top of the related file.
  57 ;;
  58 ;; Emacs Chess is designed in a highly modular fashion, using loosely
  59 ;; coupled modules that respond to events on the chess board.  This
  60 ;; makes it very easy for programmers to add their own types of
  61 ;; displays, opponents, analysis programs, etc.  See the documentation
  62 ;; in chess-module.el to learn more.
  63 ;;
  64 ;; There is no documentation for this program other than what exists
  65 ;; in the source files.  This is because the source files aim at being
  66 ;; self documenting, and as chess is such a simple game, most chess
  67 ;; players aren't going to need to know much about this program in
  68 ;; particular.
  69 ;;
  70 ;; However, most people will probably be interested in reading the top
  71 ;; of chess-display.el and chess-pgn.el, which describe the user
  72 ;; interface commands available in each of those buffer types.
  73
  74 ;;; Code:
  75
  76 (require 'chess-game)
  77 (require 'chess-display)
  78 (require 'chess-engine)
  79
  80 (defgroup chess nil
  81   "An Emacs chess playing program."
  82   :group 'games)
  83
  84 (defconst chess-version "2.0b4"
  85   "The version of the Emacs chess program.")
  86
  87 (defcustom chess-default-display
  88   '(chess-images chess-ics1 chess-plain)
  89   "Default display to be used when starting a chess session.
  90 A list indicates a series of alternatives if the first display is
  91 not available."
  92   :type '(choice symbol (repeat symbol))
  93   :group 'chess)
  94
  95 (defcustom chess-default-modules
  96   '((chess-sound chess-announce)
  97     chess-autosave
  98     chess-clock
  99     ;;chess-kibitz   jww (2002-04-30): not fully supported yet
 100     ;;chess-chat
 101     )
 102   "Modules to be used when starting a chess session.
 103 A sublist indicates a series of alternatives, if the first is not
 104 available.
 105 These can do just about anything."
 106   :type '(repeat (choice symbol (repeat symbol)))
 107   :group 'chess)
 108
 109 (defcustom chess-default-engine
 110   '(chess-crafty chess-gnuchess chess-phalanx)
 111   "Default engine to be used when starting a chess session.
 112 A list indicates a series of alternatives if the first engine is not
 113 available."
 114   :type '(choice symbol (repeat symbol))
 115   :group 'chess)
 116
 117 (defcustom chess-full-name (user-full-name)
 118   "The full name to use when playing chess."
 119   :type 'string
 120   :group 'chess)
 121
 122 (defun chess--create-display (module game my-color disable-popup)
 123   (let ((display (chess-display-create game module my-color)))
 124     (when display
 125       (chess-game-set-data game 'my-color my-color)
 126       (if disable-popup
 127           (chess-display-disable-popup display))
 128       display)))
 129
 130 (defun chess--create-engine (module game response-handler ctor-args)
 131   (let ((engine (apply 'chess-engine-create module game
 132                        response-handler ctor-args)))
 133     (when engine
 134       ;; for the sake of engines which are ready to play now, and
 135       ;; which don't need connect/accept negotiation (most
 136       ;; computerized engines fall into this category), we need to
 137       ;; let them know we're ready to begin
 138       (chess-engine-command engine 'ready)
 139       engine)))
 140
 141 (defun chess-create-modules (module-list create-func &rest args)
 142   (let (objects)
 143     (dolist (module module-list)
 144       (let (object)
 145         (if (symbolp module)
 146             (if (setq object (apply create-func module args))
 147                 (push object objects))
 148           ;; this module is actually a list, which means keep trying
 149           ;; until we find one that works
 150           (while module
 151             (if (setq object (apply create-func (car module) args))
 152                 (progn
 153                   (push object objects)
 154                   (setq module nil))
 155               (setq module (cdr module)))))))
 156     (nreverse objects)))
 157
 158 (chess-message-catalog 'english
 159   '((no-engines-found . "Could not find any chess engines to play against; install gnuchess!")))
 160
 161 ;;;###autoload
 162 (defun chess (&optional engine disable-popup engine-response-handler
 163                         &rest engine-ctor-args)
 164   "Start a game of chess, playing against ENGINE (a module name)."
 165   (interactive
 166    (list
 167     (if current-prefix-arg
 168         (intern
 169          (concat "chess-"
 170                  (let ((str (read-string "Engine to play against: ")))
 171                    (if (> (length str) 0)
 172                        str
 173                      "none"))))
 174       chess-default-engine)))
 175
 176   (let ((game (chess-game-create))
 177         (my-color t)                    ; we start out as white always
 178         objects)
 179
 180     ;; all these odd calls are so that `objects' ends up looking like:
 181     ;;   (ENGINE FIRST-DISPLAY...)
 182
 183     (setq objects (chess-create-modules (list chess-default-display)
 184                                         'chess--create-display
 185                                         game my-color disable-popup))
 186     (when (car objects)
 187       (mapc 'chess-display-update objects)
 188       (chess-module-set-leader (car objects))
 189       (unless disable-popup
 190         (chess-display-popup (car objects))))
 191
 192     (nconc objects (chess-create-modules chess-default-modules
 193                                          'chess-module-create game))
 194
 195     (push (unless (eq engine 'none)
 196             (car (condition-case nil
 197                      (chess-create-modules (list (or engine chess-default-engine))
 198                                            'chess--create-engine game
 199                                            engine-response-handler
 200                                            engine-ctor-args)
 201                    (error nil))))
 202           objects)
 203
 204     (unless (car objects)
 205       (chess-message 'no-engines-found))
 206
 207     objects))
 208
 209 ;;;###autoload
 210 (defalias 'chess-session 'chess)
 211
 212 ;;;###autoload
 213 (defun chess-create-display (perspective &optional modules-too)
 214   "Create a display, letting the user's customization decide the style.
 215 If MODULES-TOO is non-nil, also create and associate the modules
 216 listed in `chess-default-modules'."
 217   (if modules-too
 218       (let ((display (cadr (chess-session 'none))))
 219         (chess-display-set-perspective* display perspective))
 220     (car (chess-create-modules (list chess-default-display)
 221                                'chess--create-display
 222                                (chess-game-create) perspective nil))))
 223
 224 (provide 'chess)
 225
 226 ;;; chess.el ends here