code.delx.au - gnu-emacs-elpa/blob - packages/url-http-ntlm/url-http-ntlm.el

   1 ;;; url-http-ntlm.el --- NTLM authentication for the url library
   2
   3 ;; Copyright (C) 2008  Tom Schutzer-Weissmann
   4
   5 ;; Author: Tom Schutzer-Weissmann <tom@schutzer-weissmann.net>
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22 ;;
  23 ;; This package provides a NTLM handler for the URL package.
  24 ;; It supports one username and password per server.
  25 ;;
  26 ;; Installation:
  27 ;;
  28 ;; Add the directory containing this file to the load path and then
  29 ;; load the url-http-ntlm package.  One way would be to add something
  30 ;; like the lines below to your .emacs file:
  31 ;;
  32 ;; (add-to-list 'load-path ".emacs.d/url-http-ntlm")
  33 ;; (require 'url-http-ntlm)
  34 ;;
  35 ;; Acknowledgements:
  36 ;;
  37 ;; Taro Kawagishi <tarok@transpulse.org> wrote ntlm.el and md4.el,
  38 ;; which are parts of FLIM (Faithful Library about Internet Message).
  39 ;;
  40 ;; http://stuff.mit.edu/afs/sipb/contrib/emacs/packages/flim-1.14.7/ntlm.el
  41 ;; http://stuff.mit.edu/afs/sipb/contrib/emacs/packages/flim-1.14.7/md4.el
  42
  43 ;;; Code:
  44 (require 'url-auth)
  45 (require 'url-http)
  46 (require 'mail-parse)
  47 (require 'cl)
  48 (require 'ntlm)
  49
  50 (defvar url-http-ntlm-auth-storage nil
  51   "Authentication storage.
  52 An alist that maps a server name to a pair of \(<username> <ntlm
  53 hashes>\).
  54
  55 The hashes are built using `ntlm-get-password-hashes'.
  56 The username can contain the domain name, in the form \"user@domain\".
  57
  58 Note that for any server, only one user and password is ever stored.")
  59
  60 (defun url-ntlm-auth (url &optional prompt overwrite realm args)
  61   "Return an NTLM HTTP authorization header.
  62 Get the contents of the Authorization header for a HTTP response
  63 using NTLM authentication, to access URL.  Because NTLM is a
  64 two-step process, this function expects to be called twice, first
  65 to generate the NTLM type 1 message (request), then to respond to
  66 the server's type 2 message (challenge) with a suitable response.
  67
  68 PROMPT, OVERWRITE, and REALM are ignored.
  69
  70 ARGS is expected to contain the WWW-Authentication header from
  71 the server's last response.  These are used by
  72 `url-http-get-stage' to determine what stage we are at."
  73   (url-ntlm-ensure-keepalive)
  74   (let ((stage (url-ntlm-get-stage args)))
  75     (case stage
  76       ;; NTLM Type 1 message: the request
  77       (:request
  78        (destructuring-bind (&optional server user hash)
  79            (url-http-ntlm-authorisation url)
  80          (when server
  81            (url-http-ntlm-string (ntlm-build-auth-request user server)))))
  82       ;; NTLM Type 3 message: the response
  83       (:response
  84        (let ((challenge (url-http-ntlm-get-challenge)))
  85          (destructuring-bind (server user hash)
  86              (url-http-ntlm-authorisation url)
  87            (url-http-ntlm-string (ntlm-build-auth-response challenge
  88                                                            user
  89                                                            hash)))))
  90       (:error
  91        (url-http-ntlm-authorisation url :clear)))))
  92
  93 (defun url-ntlm-ensure-keepalive ()
  94   "Report an error if `url-http-attempt-keepalives' is not set."
  95   (assert url-http-attempt-keepalives
  96           nil
  97           (concat "NTLM authentication won't work unless"
  98                   " `url-http-attempt-keepalives' is set!")))
  99
 100 (defun url-ntlm-clean-headers ()
 101   "Remove Authorization element from `url-http-extra-headers' alist."
 102   (setq url-http-extra-headers
 103         (url-http-ntlm-rmssoc "Authorization" url-http-extra-headers)))
 104
 105 (defvar url-ntlm-last-args nil
 106   "Stores the last ARGS argument to `url-ntlm-get-stage' and the return value.
 107 This is used to detect multiple calls.")
 108 (make-variable-buffer-local 'url-ntlm-last-args)
 109
 110 (defun url-ntlm-get-stage (args)
 111   "Determine what stage of the NTLM handshake we are at.
 112 PROMPT and ARGS come from `url-ntlm-auth''s caller,
 113 `url-get-authentication'.  Their meaning depends on the current
 114 implementation - this function is well and truly coupled.
 115
 116 url-get-authentication' calls `url-ntlm-auth' once when checking
 117 what authentication schemes are supported (PROMPT and ARGS are
 118 nil), and then twice for every stage of the handshake: the first
 119 time PROMPT is nil, the second, t; ARGS contains the server
 120 response's \"WWW-Authenticate\" header, munged by
 121 `url-parse-args'."
 122   (let* ((response-rxp     "^NTLM TlRMTVNTUAADAAA")
 123          (challenge-rxp    "^TLRMTVNTUAACAAA")
 124          (auth-header      (assoc "Authorization" url-http-extra-headers))
 125          (case-fold-search t)
 126          stage)
 127     (if (eq args (car url-ntlm-last-args))
 128         ;; multiple calls, return the same argument we returned last time
 129         (cdr url-ntlm-last-args)
 130         (let ((stage
 131                (cond ((and auth-header (string-match response-rxp
 132                                                      (cdr auth-header)))
 133                       :error)
 134                      ((and (= (length args) 2)
 135                            (destructuring-bind (challenge ntlm) args
 136                              (and (string-equal "ntlm" (car ntlm))
 137                                   (string-match challenge-rxp
 138                                                 (car challenge)))))
 139                       :response)
 140                      (t
 141                       :request))))
 142           (url-ntlm-clean-headers)
 143           (setq url-ntlm-last-args (cons args stage))
 144           stage))))
 145
 146 (defun url-http-ntlm-authorisation (url &optional clear)
 147   "Get or clear NTLM authentication details for URL.
 148 If CLEAR is non-nil, clear any saved credentials for server.
 149 Otherwise, return the credentials, prompting the user if
 150 necessary.
 151
 152 If URL contains a username and a password, they are used and
 153 stored credentials are not affected.
 154
 155 Note that for any server, only one user and password is ever
 156 stored."
 157   (let* ((href   (if (stringp url)
 158                      (url-generic-parse-url url)
 159                      url))
 160          (server (url-host href))
 161          (user   (url-user href))
 162          (pass   (url-password href))
 163          (stored (assoc server url-http-ntlm-auth-storage))
 164          (both   (and user pass)))
 165     (if clear
 166         ;; clear
 167         (unless both
 168           (setq url-http-ntlm-auth-storage
 169                 (url-http-ntlm-rmssoc server url-http-ntlm-auth-storage))
 170           nil)
 171         ;; get
 172         (if (or both
 173                 (and stored user (not (equal user (second stored))))
 174                 (not stored))
 175             (let* ((user*  (if both
 176                                user
 177                                (read-string (url-auth-user-prompt url realm)
 178                                             (or user (user-real-login-name)))))
 179                    (pass*  (if both
 180                                pass
 181                                (read-passwd "Password: ")))
 182                    (entry `(,server . (,user*
 183                                        ,(ntlm-get-password-hashes pass*)))))
 184               (unless both
 185                 (setq url-http-ntlm-auth-storage
 186                       (cons entry
 187                             (url-http-ntlm-rmssoc server
 188                                                   url-http-ntlm-auth-storage))))
 189               entry)
 190             stored))))
 191
 192 (defun url-http-ntlm-get-challenge ()
 193   "Return the NTLM Type-2 message in the WWW-Authenticate header, if present."
 194   (save-restriction
 195     (mail-narrow-to-head)
 196     (let ((www-authenticate (mail-fetch-field "www-authenticate")))
 197       (when (string-match "NTLM\\s-+\\(\\S-+\\)"
 198                           www-authenticate)
 199         (base64-decode-string (match-string 1 www-authenticate))))))
 200
 201 (defun url-http-ntlm-rmssoc (key alist)
 202   "Remove all elements whose `car' match KEY from ALIST."
 203   (remove* key alist :key 'car :test 'equal))
 204
 205 (defun url-http-ntlm-string (data)
 206   "Return DATA encoded as an NTLM string."
 207   (concat "NTLM " (base64-encode-string data :nobreak)))
 208
 209 (url-register-auth-scheme "ntlm" nil 8)
 210
 211 (provide 'url-http-ntlm)
 212
 213 ;;; url-http-ntlm.el ends here