code.delx.au - gnu-emacs-elpa/blob - packages/hydra/hydra.el

   1 ;;; hydra.el --- Make bindings that stick around
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; Maintainer: Oleh Krehel <ohwoeowho@gmail.com>
   7 ;; URL: https://github.com/abo-abo/hydra
   8 ;; Version: 0.4.0
   9 ;; Keywords: bindings
  10 ;; Package-Requires: ((cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This package can be used to tie related commands into a family of
  30 ;; short bindings with a common prefix - a Hydra.
  31 ;;
  32 ;; Once you summon the Hydra (through the prefixed binding), all the
  33 ;; heads can be called in succession with only a short extension.
  34 ;; The Hydra is vanquished once Hercules, any binding that isn't the
  35 ;; Hydra's head, arrives.  Note that Hercules, besides vanquishing the
  36 ;; Hydra, will still serve his orignal purpose, calling his proper
  37 ;; command.  This makes the Hydra very seamless, it's like a minor
  38 ;; mode that disables itself automagically.
  39 ;;
  40 ;; Here's how to use the examples bundled with Hydra:
  41 ;;
  42 ;;    (require 'hydra-examples)
  43 ;;    (hydra-create "C-M-y" hydra-example-move-window-splitter)
  44 ;;    (hydra-create "M-g" hydra-example-goto-error)
  45 ;;
  46 ;; You can expand the examples in-place, it still looks elegant:
  47 ;;
  48 ;;     (hydra-create "<f2>"
  49 ;;       '(("g" text-scale-increase "zoom in")
  50 ;;         ("l" text-scale-decrease "zoom out")))
  51 ;;
  52 ;; The third element of each list is the optional doc string that will
  53 ;; be displayed in the echo area when `hydra-is-helpful' is t.
  54
  55 ;;; Code:
  56 (require 'cl-lib)
  57
  58 (defgroup hydra nil
  59   "Make bindings that stick around."
  60   :group 'bindings
  61   :prefix "hydra-")
  62
  63 (defcustom hydra-is-helpful t
  64   "When t, display a hint with possible bindings in the echo area."
  65   :type 'boolean
  66   :group 'hydra)
  67
  68 (defalias 'hydra-set-transient-map
  69   (if (fboundp 'set-transient-map)
  70       'set-transient-map
  71     'set-temporary-overlay-map))
  72
  73 (defvar hydra-last nil
  74   "The result of the last `hydra-set-transient-map' call.")
  75
  76 ;;;###autoload
  77 (defmacro hydra-create (body heads &optional method)
  78   "Create a hydra with a BODY prefix and HEADS with METHOD.
  79 This will result in `global-set-key' statements with the keys
  80 being the concatenation of BODY and each head in HEADS.  HEADS is
  81 an list of (KEY FUNCTION &optional HINT).
  82
  83 After one of the HEADS is called via BODY+KEY, it and the other
  84 HEADS can be called with only KEY (no need for BODY).  This state
  85 is broken once any key binding that is not in HEADS is called.
  86
  87 METHOD is a lambda takes two arguments: a KEY and a COMMAND.
  88 It defaults to `global-set-key'.
  89 When `(keymapp METHOD)`, it becomes:
  90
  91     (lambda (key command) (define-key METHOD key command))"
  92   (declare (indent 1))
  93   `(defhydra ,(intern
  94                (concat
  95                 "hydra-" (replace-regexp-in-string " " "_" body)))
  96        ,(cond ((hydra--callablep method)
  97               method)
  98              ((null method)
  99               `(global-map ,body))
 100              (t
 101               (list method body)))
 102      "hydra"
 103      ,@(eval heads)))
 104
 105 (defun hydra--callablep (x)
 106   "Test if X looks like it's callable."
 107   (or (functionp x)
 108       (and (consp x)
 109            (memq (car x) '(function quote)))))
 110
 111 (defmacro defhydra (name body &optional docstring &rest heads)
 112   "Create a hydra named NAME with a prefix BODY.
 113
 114 NAME should be a symbol, it will be the prefix of all functions
 115 defined here.
 116
 117 BODY should be either:
 118
 119     (BODY-MAP &optional BODY-KEY)
 120 or:
 121
 122     (lambda (KEY CMD) ...)
 123
 124 BODY-MAP should be a keymap; `global-map' is acceptable here.
 125 BODY-KEY should be a string processable by `kbd'.
 126
 127 DOCSTRING will be displayed in the echo area to identify the
 128 hydra.
 129
 130 HEADS is a list of (KEY CMD &optional HINT)."
 131   (unless (stringp docstring)
 132     (setq heads (cons docstring heads))
 133     (setq docstring "hydra"))
 134   (let* ((keymap (make-sparse-keymap))
 135          (names (mapcar
 136                  (lambda (x)
 137                    (define-key keymap (kbd (car x))
 138                      (intern (format "%S/%s" name (cadr x)))))
 139                  heads))
 140          (body-name (intern (format "%S/body" name)))
 141          (body-key (unless (hydra--callablep body)
 142                      (cadr body)))
 143          (method (if (hydra--callablep body)
 144                      body
 145                    (car body)))
 146          (hint (format "%s: %s."
 147                        docstring
 148                        (mapconcat
 149                         (lambda (h)
 150                           (format
 151                            (if (cl-caddr h)
 152                                (concat "[%s]: " (cl-caddr h))
 153                              "%s")
 154                            (propertize (car h) 'face 'font-lock-keyword-face)))
 155                         heads ", ")))
 156          (doc (format
 157                "Create a hydra with %s body and the heads:\n\n%s\n\n%s"
 158                (if body-key
 159                    (format "a \"%s\"" body-key)
 160                  "no")
 161                (mapconcat
 162                 (lambda (x)
 163                   (format "\"%s\":    `%S'" (car x) (cadr x)))
 164                 heads ",\n")
 165                (format "The body can be accessed via `%S'." body-name))))
 166     `(progn
 167        ,@(cl-mapcar
 168           (lambda (head name)
 169             `(defun ,name ()
 170                ,(format "%s\n\nCall the head: `%S'." doc (cadr head))
 171                (interactive)
 172                ,@(if (null (cadr head))
 173                      '((if (functionp hydra-last)
 174                            (funcall hydra-last)
 175                          (ignore-errors
 176                            (funcall 'clear-temporary-overlay-map))))
 177                      `((call-interactively #',(cadr head))
 178                        (when hydra-is-helpful
 179                          (message ,hint))
 180                        (setq hydra-last
 181                              (hydra-set-transient-map ',keymap t))))))
 182           heads names)
 183        ,@(unless (or (null body-key)
 184                      (null method)
 185                      (hydra--callablep method))
 186                  `((unless (keymapp (lookup-key ,method (kbd ,body-key)))
 187                      (define-key ,method (kbd ,body-key) nil))))
 188        ,@(delq nil
 189                (cl-mapcar
 190                 (lambda (head name)
 191                   (unless (or (null body-key) (null method))
 192                     (list
 193                      (if (hydra--callablep method)
 194                          'funcall
 195                        'define-key)
 196                      method
 197                      (vconcat (kbd body-key) (kbd (car head)))
 198                      (list 'function name))))
 199                 heads names))
 200        (defun ,body-name ()
 201          ,doc
 202          (interactive)
 203          (when hydra-is-helpful
 204            (message ,hint))
 205          (setq hydra-last
 206                (hydra-set-transient-map ',keymap t))))))
 207
 208 (provide 'hydra)
 209 ;;; hydra.el ends here