code.delx.au - gnu-emacs-elpa/blob - yasnippet-tests.el

   1 ;;; yasnippet-tests.el --- some yasnippet tests
   2
   3 ;; Copyright (C) 2012  João Távora
   4
   5 ;; Author: João Távora <joaot@siscog.pt>
   6 ;; Keywords: emulations, convenience
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; Test basic snippet mechanics and the loading system
  24
  25 ;;; Code:
  26
  27 (require 'yasnippet)
  28 (require 'ert)
  29 (require 'ert-x)
  30
  31 \f
  32 ;;; Snippet mechanics
  33
  34 (defun yas--buffer-contents ()
  35   (buffer-substring-no-properties (point-min) (point-max)))
  36
  37 (ert-deftest field-navigation ()
  38   (with-temp-buffer
  39     (yas-minor-mode 1)
  40     (yas-expand-snippet "${1:brother} from another ${2:mother}")
  41     (should (string= (yas--buffer-contents)
  42                      "brother from another mother"))
  43
  44     (should (looking-at "brother"))
  45     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  46     (should (looking-at "mother"))
  47     (ert-simulate-command '(yas-prev-field))
  48     (should (looking-at "brother"))))
  49
  50 (ert-deftest simple-mirror ()
  51   (with-temp-buffer
  52     (yas-minor-mode 1)
  53     (yas-expand-snippet "${1:brother} from another $1")
  54     (should (string= (yas--buffer-contents)
  55                      "brother from another brother"))
  56     (ert-simulate-command `(yas-mock-insert "bla"))
  57     (should (string= (yas--buffer-contents)
  58                      "bla from another bla"))))
  59
  60 (ert-deftest mirror-with-transformation ()
  61   (with-temp-buffer
  62     (yas-minor-mode 1)
  63     (yas-expand-snippet "${1:brother} from another ${1:$(upcase yas-text)}")
  64     (should (string= (yas--buffer-contents)
  65                      "brother from another BROTHER"))
  66     (ert-simulate-command `(yas-mock-insert "bla"))
  67     (should (string= (yas--buffer-contents)
  68                      "bla from another BLA"))))
  69
  70 (ert-deftest primary-field-transformation ()
  71   (with-temp-buffer
  72     (yas-minor-mode 1)
  73     (let ((snippet "${1:$$(upcase yas/text)}${1:$(concat \"bar\" yas/text)}"))
  74       (yas-expand-snippet snippet)
  75       (should (string= (yas--buffer-contents) "bar"))
  76       (ert-simulate-command `(yas-mock-insert "foo"))
  77       (should (string= (yas--buffer-contents) "FOObarFOO")))))
  78
  79 (ert-deftest nested-placeholders-kill-superfield ()
  80   (with-temp-buffer
  81     (yas-minor-mode 1)
  82     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  83     (should (string= (yas--buffer-contents)
  84                      "brother from another mother!"))
  85     (ert-simulate-command `(yas-mock-insert "bla"))
  86     (should (string= (yas--buffer-contents)
  87                      "brother from bla!"))))
  88
  89 (ert-deftest nested-placeholders-use-subfield ()
  90   (with-temp-buffer
  91     (yas-minor-mode 1)
  92     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  93     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  94     (ert-simulate-command `(yas-mock-insert "bla"))
  95     (should (string= (yas--buffer-contents)
  96                      "brother from another bla!"))))
  97
  98 (ert-deftest mirrors-adjacent-to-fields-with-nested-mirrors ()
  99   (with-temp-buffer)
 100   (yas-minor-mode 1)
 101   (yas-expand-snippet "<%= f.submit \"${1:Submit}\"${2:$(and (yas-text) \", :disable_with => '\")}${2:$1ing...}${2:$(and (yas-text) \"'\")} %>")
 102   (should (string= (yas--buffer-contents)
 103                    "<%= f.submit \"Submit\", :disable_with => 'Submiting...' %>"))
 104   (ert-simulate-command `(yas-mock-insert "Send"))
 105   (should (string= (yas--buffer-contents)
 106                    "<%= f.submit \"Send\", :disable_with => 'Sending...' %>")))
 107
 108 ;; (ert-deftest in-snippet-undo ()
 109 ;;   (with-temp-buffer
 110 ;;     (yas-minor-mode 1)
 111 ;;     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
 112 ;;     (ert-simulate-command '(yas-next-field-or-maybe-expand))
 113 ;;     (ert-simulate-command `(yas-mock-insert "bla"))
 114 ;;     (ert-simulate-command '(undo))
 115 ;;     (should (string= (yas--buffer-contents)
 116 ;;                      "brother from another mother!"))))
 117
 118 \f
 119 ;;; Snippet expansion and character escaping
 120 ;;; Thanks to @zw963 (Billy) for the testing
 121 ;;;
 122 (ert-deftest escape-dollar ()
 123   (with-temp-buffer
 124     (yas-minor-mode 1)
 125     (yas-expand-snippet "bla\\${1:bla}ble")
 126     (should (string= (yas--buffer-contents) "bla${1:bla}ble"))))
 127
 128 (ert-deftest escape-closing-brace ()
 129   (with-temp-buffer
 130     (yas-minor-mode 1)
 131     (yas-expand-snippet "bla${1:bla\\}}ble")
 132     (should (string= (yas--buffer-contents) "blabla}ble"))
 133     (should (string= (yas-field-value 1) "bla}"))))
 134
 135 (ert-deftest escape-backslashes ()
 136   (with-temp-buffer
 137     (yas-minor-mode 1)
 138     (yas-expand-snippet "bla\\ble")
 139     (should (string= (yas--buffer-contents) "bla\\ble"))))
 140
 141 (ert-deftest escape-backquotes ()
 142   (with-temp-buffer
 143     (yas-minor-mode 1)
 144     (yas-expand-snippet "bla`(upcase \"foo\\`bar\")`ble")
 145     (should (string= (yas--buffer-contents) "blaFOO`BARble"))))
 146
 147 (ert-deftest escape-some-elisp-with-strings ()
 148   "elisp with strings and unbalance parens inside it"
 149   (with-temp-buffer
 150     (yas-minor-mode 1)
 151     ;; The rules here is: to output a literal `"' you need to escape
 152     ;; it with one backslash. You don't need to escape them in
 153     ;; embedded elisp.
 154     (yas-expand-snippet "soon \\\"`(concat (upcase \"(my arms\")\"\\\" were all around her\")`")
 155     (should (string= (yas--buffer-contents) "soon \"(MY ARMS\" were all around her"))))
 156
 157 (ert-deftest escape-some-elisp-with-backslashes ()
 158   (with-temp-buffer
 159     (yas-minor-mode 1)
 160     ;; And the rule here is: to output a literal `\' inside a string
 161     ;; inside embedded elisp you need a total of six `\'
 162     (yas-expand-snippet "bla`(upcase \"hey\\\\\\yo\")`ble")
 163     (should (string= (yas--buffer-contents) "blaHEY\\YOble"))))
 164
 165 (ert-deftest be-careful-when-escaping-in-yas-selected-text ()
 166   (with-temp-buffer
 167     (yas-minor-mode 1)
 168     (let ((yas/selected-text "He\\\\o world!"))
 169       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 170       (should (string= (yas--buffer-contents) "Look ma! He\\\\o world!")))
 171     (yas-exit-all-snippets)
 172     (erase-buffer)
 173     (let ((yas/selected-text "He\"o world!"))
 174       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 175       (should (string= (yas--buffer-contents) "Look ma! He\"o world!")))
 176     (yas-exit-all-snippets)
 177     (erase-buffer)
 178     (let ((yas/selected-text "He\"\)\\o world!"))
 179       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 180       (should (string= (yas--buffer-contents) "Look ma! He\"\)\\o world!")))
 181     (yas-exit-all-snippets)
 182     (erase-buffer)))
 183
 184 (ert-deftest be-careful-when-escaping-in-yas-selected-text-2 ()
 185   (with-temp-buffer
 186     (let ((yas/selected-text "He)}o world!"))
 187       (yas-expand-snippet "Look ma! ${1:`(yas/selected-text)`} OK?")
 188       (should (string= (yas--buffer-contents) "Look ma! He)}o world! OK?")))))
 189
 190 (ert-deftest example-for-issue-271 ()
 191   (with-temp-buffer
 192     (yas-minor-mode 1)
 193     (let ((yas-selected-text "aaa")
 194           (snippet "if ${1:condition}\n`yas/selected-text`\nelse\n$3\nend"))
 195       (yas-expand-snippet snippet)
 196       (yas-next-field)
 197       (ert-simulate-command `(yas-mock-insert "bbb"))
 198       (should (string= (yas--buffer-contents) "if condition\naaa\nelse\nbbb\nend")))))
 199
 200 (ert-deftest another-example-for-issue-271 ()
 201   ;; expect this to fail in batch mode since `region-active-p' doesn't
 202   ;; used by `yas-expand-snippet' doesn't make sense in that context.
 203   ;;
 204   :expected-result (if noninteractive
 205                        :failed
 206                      :passed)
 207   (with-temp-buffer
 208     (yas-minor-mode 1)
 209     (let ((snippet "\\${${1:1}:`yas/selected-text`}"))
 210       (insert "aaabbbccc")
 211       (set-mark 4)
 212       (goto-char 7)
 213       (yas-expand-snippet snippet)
 214       (should (string= (yas--buffer-contents) "aaa${1:bbb}ccc")))))
 215
 216 (ert-deftest string-match-with-subregexp-in-embedded-elisp ()
 217   (with-temp-buffer
 218     (yas-minor-mode 1)
 219     ;; the rule here is: To use regexps in embedded `(elisp)` expressions, write
 220     ;; it like you would normal elisp, i.e. no need to escape the backslashes.
 221     (let ((snippet "`(if (string-match \"foo\\\\(ba+r\\\\)foo\" \"foobaaaaaaaaaarfoo\")
 222                          \"ok\"
 223                          \"fail\")`"))
 224       (yas-expand-snippet snippet))
 225       (should (string= (yas--buffer-contents) "ok"))))
 226
 227 (ert-deftest string-match-with-subregexp-in-mirror-transformations ()
 228   (with-temp-buffer
 229     (yas-minor-mode 1)
 230     ;; the rule here is: To use regexps in embedded `(elisp)` expressions,
 231     ;; escape backslashes once, i.e. to use \\( \\) constructs, write \\\\( \\\\).
 232     (let ((snippet "$1${1:$(if (string-match \"foo\\\\\\\\(ba+r\\\\\\\\)baz\" yas/text)
 233                                 \"ok\"
 234                                 \"fail\")}"))
 235       (yas-expand-snippet snippet)
 236       (should (string= (yas--buffer-contents) "fail"))
 237       (ert-simulate-command `(yas-mock-insert "foobaaar"))
 238       (should (string= (yas--buffer-contents) "foobaaarfail"))
 239       (ert-simulate-command `(yas-mock-insert "baz"))
 240       (should (string= (yas--buffer-contents) "foobaaarbazok")))))
 241
 242 \f
 243 ;;; Misc tests
 244 ;;;
 245 (ert-deftest protection-overlay-no-cheating ()
 246   "Protection overlays at the very end of the buffer are dealt
 247   with by cheatingly inserting a newline!
 248
 249 TODO: correct this bug!"
 250   :expected-result :failed
 251   (with-temp-buffer
 252     (yas-minor-mode 1)
 253     (yas-expand-snippet "${2:brother} from another ${1:mother}")
 254     (should (string= (yas--buffer-contents)
 255                      "brother from another mother") ;; no newline should be here!
 256             )))
 257 \f
 258 ;;; Loading
 259 ;;;
 260 (defmacro yas-with-overriden-buffer-list (&rest body)
 261   (let ((saved-sym (gensym)))
 262     `(let ((,saved-sym (symbol-function 'buffer-list)))
 263        (flet ((buffer-list ()
 264                            (remove-if #'(lambda (buf)
 265                                           (with-current-buffer buf
 266                                             (eq major-mode 'lisp-interaction-mode)))
 267                                       (funcall ,saved-sym))))
 268          ,@body))))
 269
 270 (defmacro yas-with-some-interesting-snippet-dirs (&rest body)
 271   `(yas-saving-variables
 272     (yas-with-overriden-buffer-list
 273      (yas-with-snippet-dirs
 274       '((".emacs.d/snippets"
 275          ("c-mode"
 276           (".yas-parents" . "cc-mode")
 277           ("printf" . "printf($1);"))  ;; notice the overriding for issue #281
 278          ("emacs-lisp-mode" ("ert-deftest" . "(ert-deftest ${1:name} () $0)"))
 279          ("lisp-interaction-mode" (".yas-parents" . "emacs-lisp-mode")))
 280         ("library/snippets"
 281          ("c-mode"
 282           (".yas-parents" . "c++-mode")
 283           ("printf" . "printf"))
 284          ("cc-mode" ("def" . "# define"))
 285          ("emacs-lisp-mode" ("dolist" . "(dolist)"))
 286          ("lisp-interaction-mode" ("sc" . "brother from another mother"))))
 287       ,@body))))
 288
 289 (ert-deftest basic-jit-loading ()
 290   "Test basic loading and expansion of snippets"
 291   (yas-with-some-interesting-snippet-dirs
 292    (yas-reload-all)
 293    (yas--basic-jit-loading-1)))
 294
 295 (ert-deftest basic-jit-loading-with-compiled-snippets ()
 296   "Test basic loading and expansion of snippets"
 297   (yas-with-some-interesting-snippet-dirs
 298    (yas-reload-all)
 299    (yas-recompile-all)
 300    (flet ((yas--load-directory-2
 301            (&rest dummies)
 302            (ert-fail "yas--load-directory-2 shouldn't be called when snippets have been compiled")))
 303      (yas-reload-all)
 304      (yas--basic-jit-loading-1))))
 305
 306 (defun yas--basic-jit-loading-1 (&optional compile)
 307   (with-temp-buffer
 308     (should (= 4 (hash-table-count yas--scheduled-jit-loads)))
 309     (should (= 0 (hash-table-count yas--tables)))
 310     (lisp-interaction-mode)
 311     (yas-minor-mode 1)
 312     (should (= 2 (hash-table-count yas--scheduled-jit-loads)))
 313     (should (= 2 (hash-table-count yas--tables)))
 314     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'lisp-interaction-mode yas--tables)))))
 315     (should (= 2 (hash-table-count (yas--table-uuidhash (gethash 'emacs-lisp-mode yas--tables)))))
 316     (yas-should-expand '(("sc" . "brother from another mother")
 317                          ("dolist" . "(dolist)")
 318                          ("ert-deftest" . "(ert-deftest name () )")))
 319     (c-mode)
 320     (yas-minor-mode 1)
 321     (should (= 0 (hash-table-count yas--scheduled-jit-loads)))
 322     (should (= 4 (hash-table-count yas--tables)))
 323     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'c-mode yas--tables)))))
 324     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'cc-mode yas--tables)))))
 325     (yas-should-expand '(("printf" . "printf();")
 326                          ("def" . "# define")))
 327     (yas-should-not-expand '("sc" "dolist" "ert-deftest"))))
 328
 329 \f
 330 ;;; Menu
 331 ;;;
 332 (defmacro yas-with-even-more-interesting-snippet-dirs (&rest body)
 333   `(yas-saving-variables
 334     (yas-with-snippet-dirs
 335      `((".emacs.d/snippets"
 336         ("c-mode"
 337          (".yas-make-groups" . "")
 338          ("printf" . "printf($1);")
 339          ("foo-group-a"
 340           ("fnprintf" . "fprintf($1);")
 341           ("snprintf" . "snprintf($1);"))
 342          ("foo-group-b"
 343           ("strcmp" . "strecmp($1);")
 344           ("strcasecmp" . "strcasecmp($1);")))
 345         ("lisp-interaction-mode"
 346          ("ert-deftest" . "# group: barbar\n# --\n(ert-deftest ${1:name} () $0)"))
 347         ("fancy-mode"
 348          ("a-guy" . "# uuid: 999\n# --\nyo!")
 349          ("a-sir" . "# uuid: 12345\n# --\nindeed!")
 350          ("a-lady" . "# uuid: 54321\n# --\noh-la-la!")
 351          ("a-beggar" . "# uuid: 0101\n# --\narrrgh!")
 352          ("an-outcast" . "# uuid: 666\n# --\narrrgh!")
 353          (".yas-setup.el" . , (pp-to-string
 354                                '(yas-define-menu 'fancy-mode
 355                                                  '((yas-ignore-item "0101")
 356                                                    (yas-item "999")
 357                                                    (yas-submenu "sirs"
 358                                                                 ((yas-item "12345")))
 359                                                    (yas-submenu "ladies"
 360                                                                 ((yas-item "54321"))))
 361                                                  '("666")))))))
 362      ,@body)))
 363
 364 (ert-deftest test-yas-define-menu ()
 365   (let ((yas-use-menu t))
 366     (yas-with-even-more-interesting-snippet-dirs
 367      (yas-reload-all 'no-jit)
 368      (let ((menu (cdr (gethash 'fancy-mode yas--menu-table))))
 369        (should (eql 4 (length menu)))
 370        (dolist (item '("a-guy" "a-beggar"))
 371          (should (find item menu :key #'third :test #'string=)))
 372        (should-not (find "an-outcast" menu :key #'third :test #'string=))
 373        (dolist (submenu '("sirs" "ladies"))
 374          (should (keymapp
 375                   (fourth
 376                    (find submenu menu :key #'third :test #'string=)))))
 377        ))))
 378
 379 (ert-deftest test-group-menus ()
 380   "Test group-based menus using .yas-make-groups and the group directive"
 381   (let ((yas-use-menu t))
 382     (yas-with-even-more-interesting-snippet-dirs
 383      (yas-reload-all 'no-jit)
 384      ;; first the subdir-based groups
 385      ;;
 386      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 387        (should (eql 3 (length menu)))
 388        (dolist (item '("printf" "foo-group-a" "foo-group-b"))
 389          (should (find item menu :key #'third :test #'string=)))
 390        (dolist (submenu '("foo-group-a" "foo-group-b"))
 391          (should (keymapp
 392                   (fourth
 393                    (find submenu menu :key #'third :test #'string=))))))
 394      ;; now group directives
 395      ;;
 396      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 397        (should (eql 1 (length menu)))
 398        (should (find "barbar" menu :key #'third :test #'string=))
 399        (should (keymapp
 400                 (fourth
 401                  (find "barbar" menu :key #'third :test #'string=))))))))
 402
 403 (ert-deftest test-group-menus-twisted ()
 404   "Same as similarly named test, but be mean.
 405
 406 TODO: be meaner"
 407   (let ((yas-use-menu t))
 408     (yas-with-even-more-interesting-snippet-dirs
 409      ;; add a group directive conflicting with the subdir and watch
 410      ;; behaviour
 411      (with-temp-buffer
 412        (insert "# group: foo-group-c\n# --\nstrecmp($1)")
 413        (write-region nil nil (concat (first (yas-snippet-dirs))
 414                                      "/c-mode/foo-group-b/strcmp")))
 415      (yas-reload-all 'no-jit)
 416      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 417        (should (eql 4 (length menu)))
 418        (dolist (item '("printf" "foo-group-a" "foo-group-b" "foo-group-c"))
 419          (should (find item menu :key #'third :test #'string=)))
 420        (dolist (submenu '("foo-group-a" "foo-group-b" "foo-group-c"))
 421          (should (keymapp
 422                   (fourth
 423                    (find submenu menu :key #'third :test #'string=))))))
 424      ;; delete the .yas-make-groups file and watch behaviour
 425      ;;
 426      (delete-file (concat (first (yas-snippet-dirs))
 427                           "/c-mode/.yas-make-groups"))
 428      (yas-reload-all 'no-jit)
 429      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 430        (should (eql 5 (length menu))))
 431      ;; Change a group directive and reload
 432      ;;
 433      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 434        (should (find "barbar" menu :key #'third :test #'string=)))
 435
 436      (with-temp-buffer
 437        (insert "# group: foofoo\n# --\n(ert-deftest ${1:name} () $0)")
 438        (write-region nil nil (concat (first (yas-snippet-dirs))
 439                                      "/lisp-interaction-mode/ert-deftest")))
 440      (yas-reload-all 'no-jit)
 441      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 442        (should (eql 1 (length menu)))
 443        (should (find "foofoo" menu :key #'third :test #'string=))
 444        (should (keymapp
 445                 (fourth
 446                  (find "foofoo" menu :key #'third :test #'string=))))))))
 447
 448 \f
 449 ;;; The infamous and problematic tab keybinding
 450 ;;;
 451 (ert-deftest test-yas-tab-binding ()
 452   (with-temp-buffer
 453     (yas-minor-mode -1)
 454     (should (not (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand)))
 455     (yas-minor-mode 1)
 456     (should (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand))
 457     (yas-expand-snippet "$1 $2 $3")
 458     (should (eq (key-binding [(tab)]) 'yas-next-field-or-maybe-expand))
 459     (should (eq (key-binding (kbd "TAB")) 'yas-next-field-or-maybe-expand))
 460     (should (eq (key-binding [(shift tab)]) 'yas-prev-field))
 461     (should (eq (key-binding [backtab]) 'yas-prev-field))))
 462
 463 (ert-deftest test-yas-in-org ()
 464   (with-temp-buffer
 465     (org-mode)
 466     (yas-minor-mode 1)
 467     (should (eq (key-binding [(tab)]) 'yas-expand))
 468     (should (eq (key-binding (kbd "TAB")) 'yas-expand))))
 469
 470 \f
 471 ;;; Helpers
 472 ;;;
 473 (defun yas/ert ()
 474   (interactive)
 475   (with-temp-buffer
 476     (flet ((message (&rest args)
 477                     (declare (ignore args))
 478                     nil))
 479       (ert t (buffer-name (current-buffer)))
 480       (princ (buffer-string)))))
 481
 482
 483 (defun yas-should-expand (keys-and-expansions)
 484   (dolist (key-and-expansion keys-and-expansions)
 485     (yas-exit-all-snippets)
 486     (erase-buffer)
 487     (insert (car key-and-expansion))
 488     (let ((yas-fallback-behavior nil))
 489       (ert-simulate-command '(yas-expand)))
 490     (should (string= (yas--buffer-contents) (cdr key-and-expansion))))
 491   (yas-exit-all-snippets))
 492
 493 (defun yas-should-not-expand (keys)
 494   (dolist (key keys)
 495     (yas-exit-all-snippets)
 496     (erase-buffer)
 497     (insert key)
 498     (let ((yas-fallback-behavior nil))
 499       (ert-simulate-command '(yas-expand)))
 500     (should (string= (yas--buffer-contents) key))))
 501
 502 (defun yas-mock-insert (string)
 503   (interactive)
 504   (do ((i 0 (1+ i)))
 505       ((= i (length string)))
 506     (insert (aref string i))))
 507
 508 (defun yas-make-file-or-dirs (ass)
 509   (let ((file-or-dir-name (car ass))
 510         (content (cdr ass)))
 511     (cond ((listp content)
 512            (make-directory file-or-dir-name 'parents)
 513            (let ((default-directory (concat default-directory "/" file-or-dir-name)))
 514              (mapc #'yas-make-file-or-dirs content)))
 515           ((stringp content)
 516            (with-temp-buffer
 517              (insert content)
 518              (write-region nil nil file-or-dir-name nil 'nomessage)))
 519           (t
 520            (message "[yas] oops don't know this content")))))
 521
 522
 523 (defun yas-variables ()
 524   (let ((syms))
 525     (mapatoms #'(lambda (sym)
 526                   (if (and (string-match "^yas-[^/]" (symbol-name sym))
 527                            (boundp sym))
 528                       (push sym syms))))
 529     syms))
 530
 531 (defun yas-call-with-saving-variables (fn)
 532   (let* ((vars (yas-variables))
 533          (saved-values (mapcar #'symbol-value vars)))
 534     (unwind-protect
 535         (funcall fn)
 536       (loop for var in vars
 537             for saved in saved-values
 538             do (set var saved)))))
 539
 540 (defmacro yas-saving-variables (&rest body)
 541   `(yas-call-with-saving-variables #'(lambda () ,@body)))
 542
 543
 544 (defun yas-call-with-snippet-dirs (dirs fn)
 545   (let* ((default-directory (make-temp-file "yasnippet-fixture" t))
 546          (yas-snippet-dirs (mapcar #'car dirs)))
 547     (with-temp-message ""
 548       (unwind-protect
 549           (progn
 550             (mapc #'yas-make-file-or-dirs dirs)
 551             (funcall fn))
 552         (when (>= emacs-major-version 24)
 553           (delete-directory default-directory 'recursive))))))
 554
 555 (defmacro yas-with-snippet-dirs (dirs &rest body)
 556   `(yas-call-with-snippet-dirs ,dirs
 557                                #'(lambda ()
 558                                    ,@body)))
 559
 560 ;;; Older emacsen
 561 ;;;
 562 (unless (fboundp 'special-mode)
 563   (define-minor-mode special-mode "Just a placeholder for something isn't in emacs 22"))
 564
 565 ;;; btw to test this in emacs22 mac osx:
 566 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert.el
 567 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert-x.el
 568 ;;; /usr/bin/emacs -nw -Q -L . -l yasnippet-tests.el --batch -e ert
 569
 570
 571 (provide 'yasnippet-tests)
 572 ;;; yasnippet-tests.el ends here
 573 ;; Local Variables:
 574 ;; lexical-binding: t
 575 ;; End: