code.delx.au - gnu-emacs-elpa/blob - diff-hl.el

   1 ;;; diff-hl.el --- VC diff fringe highlighting -*- lexical-binding: t -*-
   2
   3 ;; Author:   Dmitry Gutov <dgutov@yandex.ru>
   4 ;; URL:      https://github.com/dgutov/diff-hl
   5 ;; Keywords: vc, diff
   6 ;; Version:  1.3.4
   7
   8 ;; This file is not part of GNU Emacs.
   9
  10 ;; This file is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; This file is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; `diff-hl-mode' highlights uncommitted changes on the left fringe of the
  26 ;; window, allows you to jump between and revert them selectively.
  27
  28 ;; Provided commands:
  29 ;;
  30 ;; `diff-hl-diff-goto-hunk'  C-x v =
  31 ;; `diff-hl-revert-hunk'     C-x v n
  32 ;; `diff-hl-previous-hunk'   C-x v [
  33 ;; `diff-hl-next-hunk'       C-x v ]
  34 ;;
  35 ;; The mode takes advantage of `smartrep' if it is installed.
  36
  37 ;; Add either of the following to your init file.
  38 ;;
  39 ;; To use it in all buffers:
  40 ;;
  41 ;; (global-diff-hl-mode)
  42 ;;
  43 ;; Only in `prog-mode' buffers, with `vc-dir' integration:
  44 ;;
  45 ;; (add-hook 'prog-mode-hook 'turn-on-diff-hl-mode)
  46 ;; (add-hook 'vc-dir-mode-hook 'turn-on-diff-hl-mode)
  47
  48 ;;; Code:
  49
  50 (require 'diff-mode)
  51 (require 'vc)
  52 (require 'vc-dir)
  53 (eval-when-compile
  54   (require 'cl)
  55   (require 'vc-git)
  56   (require 'vc-hg)
  57   (require 'face-remap))
  58
  59 (defgroup diff-hl nil
  60   "VC diff fringe highlighting"
  61   :group 'vc)
  62
  63 (defface diff-hl-insert
  64   '((t :inherit diff-added))
  65   "Face used to highlight inserted lines."
  66   :group 'diff-hl)
  67
  68 (defface diff-hl-delete
  69   '((t :inherit diff-removed))
  70   "Face used to highlight deleted lines."
  71   :group 'diff-hl)
  72
  73 (defface diff-hl-change
  74   '((default
  75      :foreground "blue")
  76     (((class color) (min-colors 88) (background light))
  77      :background "#ddddff")
  78     (((class color) (min-colors 88) (background dark))
  79      :background "#333355"))
  80   "Face used to highlight changed lines."
  81   :group 'diff-hl)
  82
  83 (defcustom diff-hl-draw-borders t
  84   "Non-nil to draw borders around fringe indicators."
  85   :group 'diff-hl
  86   :type 'boolean)
  87
  88 (defun diff-hl-define-bitmaps ()
  89   (let* ((scale (if (and (boundp 'text-scale-mode-amount)
  90                          (plusp text-scale-mode-amount))
  91                     (expt text-scale-mode-step text-scale-mode-amount)
  92                   1))
  93          (h (round (* (frame-char-height) scale)))
  94          (w (frame-parameter nil 'left-fringe))
  95          (middle (make-vector h (expt 2 (1- w))))
  96          (ones (1- (expt 2 w)))
  97          (top (copy-sequence middle))
  98          (bottom (copy-sequence middle))
  99          (single (copy-sequence middle)))
 100     (aset top 0 ones)
 101     (aset bottom (1- h) ones)
 102     (aset single 0 ones)
 103     (aset single (1- h) ones)
 104     (define-fringe-bitmap 'diff-hl-bmp-top top h w 'top)
 105     (define-fringe-bitmap 'diff-hl-bmp-middle middle h w 'center)
 106     (define-fringe-bitmap 'diff-hl-bmp-bottom bottom h w 'bottom)
 107     (define-fringe-bitmap 'diff-hl-bmp-single single h w 'top)))
 108
 109 (when (window-system)
 110   (define-fringe-bitmap 'diff-hl-bmp-empty [0] 1 1 'center)
 111   (diff-hl-define-bitmaps))
 112
 113 (defvar diff-hl-spec-cache (make-hash-table :test 'equal))
 114
 115 (defun diff-hl-fringe-spec (type pos)
 116   (let* ((key (cons type pos))
 117          (val (gethash key diff-hl-spec-cache)))
 118     (unless val
 119       (let* ((face-sym (intern (concat "diff-hl-" (symbol-name type))))
 120              (bmp-sym (intern (concat "diff-hl-bmp-" (symbol-name pos)))))
 121         (setq val (propertize " " 'display `((left-fringe ,bmp-sym ,face-sym))))
 122         (puthash key val diff-hl-spec-cache)))
 123     val))
 124
 125 (defmacro diff-hl-with-diff-switches (body)
 126   `(let ((vc-git-diff-switches nil)
 127          (vc-hg-diff-switches nil)
 128          (vc-diff-switches '("-U0"))
 129          (vc-disable-async-diff t))
 130      ,body))
 131
 132 (defun diff-hl-changes ()
 133   (let* ((buf-name " *diff-hl* ")
 134          (file buffer-file-name)
 135          (backend (vc-backend file))
 136          res)
 137     (when (and backend (eq (vc-state file backend) 'edited))
 138       (diff-hl-with-diff-switches
 139        (vc-call-backend backend 'diff (list file) nil nil buf-name))
 140       (with-current-buffer buf-name
 141         (goto-char (point-min))
 142         (unless (eobp)
 143           (diff-beginning-of-hunk t)
 144           (while (looking-at diff-hunk-header-re-unified)
 145             (let ((line (string-to-number (match-string 3)))
 146                   (len (let ((m (match-string 4)))
 147                          (if m (string-to-number m) 1)))
 148                   (beg (point)))
 149               (diff-end-of-hunk)
 150               (let* ((inserts (diff-count-matches "^\\+" beg (point)))
 151                      (deletes (diff-count-matches "^-" beg (point)))
 152                      (type (cond ((zerop deletes) 'insert)
 153                                  ((zerop inserts) 'delete)
 154                                  (t 'change))))
 155                 (push (list line len type) res)))))))
 156     (nreverse res)))
 157
 158 (defun diff-hl-update ()
 159   (let ((changes (diff-hl-changes))
 160         (current-line 1))
 161     (diff-hl-remove-overlays)
 162     (save-excursion
 163       (goto-char (point-min))
 164       (dolist (c changes)
 165         (destructuring-bind (line len type) c
 166           (when (eq type 'delete)
 167             (setq len 1)
 168             (incf line))
 169           (forward-line (- line current-line))
 170           (setq current-line line)
 171           (let ((hunk-beg (point)))
 172             (while (plusp len)
 173               (let ((o (make-overlay (point) (line-end-position))))
 174                 (overlay-put o 'diff-hl t)
 175                 (overlay-put o 'before-string
 176                              (diff-hl-fringe-spec
 177                               type
 178                               (cond
 179                                ((not diff-hl-draw-borders) 'empty)
 180                                ((and (= len 1) (= line current-line)) 'single)
 181                                ((= len 1) 'bottom)
 182                                ((= line current-line) 'top)
 183                                (t 'middle)))))
 184               (forward-line 1)
 185               (incf current-line)
 186               (decf len))
 187             (let ((h (make-overlay hunk-beg (point)))
 188                   (hook '(diff-hl-overlay-modified)))
 189               (overlay-put h 'diff-hl t)
 190               (overlay-put h 'diff-hl-hunk t)
 191               (overlay-put h 'modification-hooks hook)
 192               (overlay-put h 'insert-in-front-hooks hook))))))))
 193
 194 (defun diff-hl-remove-overlays ()
 195   (dolist (o (overlays-in (point-min) (point-max)))
 196     (when (overlay-get o 'diff-hl) (delete-overlay o))))
 197
 198 (defun diff-hl-overlay-modified (ov after-p _beg _end &optional _length)
 199   "Delete the overlay and all our overlays inside it."
 200   (unless after-p
 201     (save-restriction
 202       (narrow-to-region (overlay-start ov) (overlay-end ov))
 203       (diff-hl-remove-overlays))
 204     (delete-overlay ov)))
 205
 206 (defvar diff-hl-timer nil)
 207
 208 (defun diff-hl-edit (_beg _end _len)
 209   "DTRT when we've `undo'-ne the buffer into unmodified state."
 210   (when undo-in-progress
 211     (when diff-hl-timer
 212       (cancel-timer diff-hl-timer))
 213     (setq diff-hl-timer
 214           (run-with-idle-timer 0.01 nil #'diff-hl-after-undo (current-buffer)))))
 215
 216 (defun diff-hl-after-undo (buffer)
 217   (with-current-buffer buffer
 218     (unless (buffer-modified-p)
 219       (diff-hl-update))))
 220
 221 (defun diff-hl-diff-goto-hunk ()
 222   "Run VC diff command and go to the line corresponding to the current."
 223   (interactive)
 224   (vc-buffer-sync)
 225   (let* ((line (line-number-at-pos))
 226          (buffer (current-buffer)))
 227     (vc-diff-internal t (vc-deduce-fileset) nil nil t)
 228     (vc-exec-after `(if (< (line-number-at-pos (point-max)) 3)
 229                         (with-current-buffer ,buffer (diff-hl-remove-overlays))
 230                       (diff-hl-diff-skip-to ,line)
 231                       (setq vc-sentinel-movepoint (point))))))
 232
 233 (defun diff-hl-diff-skip-to (line)
 234   "In `diff-mode', skip to the hunk and line corresponding to LINE
 235 in the source file, or the last line of the hunk above it."
 236   (diff-hunk-next)
 237   (let (found)
 238     (while (and (looking-at diff-hunk-header-re-unified) (not found))
 239       (let ((hunk-line (string-to-number (match-string 3)))
 240             (len (let ((m (match-string 4)))
 241                    (if m (string-to-number m) 1))))
 242         (if (> line (+ hunk-line len))
 243             (diff-hunk-next)
 244           (setq found t)
 245           (if (< line hunk-line)
 246               ;; Retreat to the previous hunk.
 247               (forward-line -1)
 248             (let ((to-go (1+ (- line hunk-line))))
 249               (while (plusp to-go)
 250                 (forward-line 1)
 251                 (unless (looking-at "^-")
 252                   (decf to-go))))))))))
 253
 254 (defun diff-hl-revert-hunk ()
 255   "Revert the diff hunk with changes at or above the point."
 256   (interactive)
 257   (vc-buffer-sync)
 258   (let ((diff-buffer (generate-new-buffer-name "*diff-hl*"))
 259         (buffer (current-buffer))
 260         (line (save-excursion
 261                 (unless (diff-hl-hunk-overlay-at (point))
 262                   (diff-hl-previous-hunk))
 263                 (line-number-at-pos)))
 264         (fileset (vc-deduce-fileset)))
 265     (unwind-protect
 266         (progn
 267           (vc-diff-internal nil fileset nil nil nil diff-buffer)
 268           (vc-exec-after
 269            `(let (beg-line end-line)
 270               (when (eobp)
 271                 (with-current-buffer ,buffer (diff-hl-remove-overlays))
 272                 (error "Buffer is up-to-date"))
 273               (diff-hl-diff-skip-to ,line)
 274               (save-excursion
 275                 (while (looking-at "[-+]") (forward-line 1))
 276                 (setq end-line (line-number-at-pos (point)))
 277                 (unless (eobp) (diff-split-hunk)))
 278               (unless (looking-at "[-+]") (forward-line -1))
 279               (while (looking-at "[-+]") (forward-line -1))
 280               (setq beg-line (line-number-at-pos (point)))
 281               (unless (looking-at "@")
 282                 (forward-line 1)
 283                 (diff-split-hunk))
 284               (let ((wbh (window-body-height)))
 285                 (if (>= wbh (- end-line beg-line))
 286                     (recenter (/ (+ wbh (- beg-line end-line) 2) 2))
 287                   (recenter 1)))
 288               (unless (yes-or-no-p (format "Revert current hunk in %s?"
 289                                            ,(caadr fileset)))
 290                 (error "Revert canceled"))
 291               (let ((diff-advance-after-apply-hunk nil))
 292                 (diff-apply-hunk t))
 293               (with-current-buffer ,buffer
 294                 (save-buffer))
 295               (message "Hunk reverted"))))
 296       (quit-windows-on diff-buffer))))
 297
 298 (defun diff-hl-hunk-overlay-at (pos)
 299   (loop for o in (overlays-at pos)
 300         when (overlay-get o 'diff-hl-hunk)
 301         return o))
 302
 303 (defun diff-hl-next-hunk (&optional backward)
 304   "Go to the beginning of the next hunk in the current buffer."
 305   (interactive)
 306   (let ((pos (save-excursion
 307                (catch 'found
 308                  (while (not (if backward (bobp) (eobp)))
 309                    (goto-char (if backward
 310                                   (previous-overlay-change (point))
 311                                 (next-overlay-change (point))))
 312                    (let ((o (diff-hl-hunk-overlay-at (point))))
 313                      (when (and o (if backward
 314                                       (<= (overlay-end o) (1+ (point)))
 315                                     (>= (overlay-start o) (point))))
 316                        (throw 'found (overlay-start o)))))))))
 317     (if pos
 318         (goto-char pos)
 319       (error "No further hunks found"))))
 320
 321 (defun diff-hl-previous-hunk ()
 322   "Go to the beginning of the previous hunk in the current buffer."
 323   (interactive)
 324   (diff-hl-next-hunk t))
 325
 326 (define-minor-mode diff-hl-mode
 327   "Toggle VC diff fringe highlighting."
 328   :lighter "" :keymap `(([remap vc-diff] . diff-hl-diff-goto-hunk)
 329                         (,(kbd "C-x v n") . diff-hl-revert-hunk)
 330                         (,(kbd "C-x v [") . diff-hl-previous-hunk)
 331                         (,(kbd "C-x v ]") . diff-hl-next-hunk))
 332   (if diff-hl-mode
 333       (progn
 334         (add-hook 'after-save-hook 'diff-hl-update nil t)
 335         (add-hook 'after-change-functions 'diff-hl-edit nil t)
 336         (if vc-mode
 337             (diff-hl-update)
 338           (add-hook 'find-file-hook 'diff-hl-update t t))
 339         (add-hook 'vc-checkin-hook 'diff-hl-update nil t)
 340         (add-hook 'after-revert-hook 'diff-hl-update nil t)
 341         (add-hook 'text-scale-mode-hook 'diff-hl-define-bitmaps nil t))
 342     (remove-hook 'after-save-hook 'diff-hl-update t)
 343     (remove-hook 'after-change-functions 'diff-hl-edit t)
 344     (remove-hook 'find-file-hook 'diff-hl-update t)
 345     (remove-hook 'vc-checkin-hook 'diff-hl-update t)
 346     (remove-hook 'after-revert-hook 'diff-hl-update t)
 347     (remove-hook 'text-scale-mode-hook 'diff-hl-define-bitmaps t)
 348     (diff-hl-remove-overlays)))
 349
 350 (when (require 'smartrep nil t)
 351   (let (smart-keys)
 352     (cl-labels ((scan (map)
 353                       (map-keymap
 354                        (lambda (event binding)
 355                          (if (consp binding)
 356                              (scan binding)
 357                            (when (characterp event)
 358                              (push (cons (string event) binding) smart-keys))))
 359                        map)))
 360       (scan diff-hl-mode-map)
 361       (smartrep-define-key diff-hl-mode-map "C-x v" smart-keys))))
 362
 363 (defun diff-hl-dir-update ()
 364   (dolist (pair (if (vc-dir-marked-files)
 365                     (vc-dir-marked-only-files-and-states)
 366                   (vc-dir-child-files-and-states)))
 367     (when (eq 'up-to-date (cdr pair))
 368       (let ((buffer (find-buffer-visiting (car pair))))
 369         (when buffer
 370           (with-current-buffer buffer
 371             (diff-hl-remove-overlays)))))))
 372
 373 (define-minor-mode diff-hl-dir-mode
 374   "Toggle `diff-hl-mode' integration in a `vc-dir-mode' buffer."
 375   :lighter ""
 376   (if diff-hl-dir-mode
 377       (add-hook 'vc-checkin-hook 'diff-hl-dir-update t t)
 378     (remove-hook 'vc-checkin-hook 'diff-hl-dir-update t)))
 379
 380 ;;;###autoload
 381 (defun turn-on-diff-hl-mode ()
 382   "Turn on `diff-hl-mode' or `diff-hl-dir-mode' in a buffer if appropriate."
 383   (when (window-system) ;; No fringes in the console.
 384     (cond
 385      (buffer-file-name
 386       (diff-hl-mode 1))
 387      ((eq major-mode 'vc-dir-mode)
 388       (diff-hl-dir-mode 1)))))
 389
 390 (defun diff-hl-global-mode-change ()
 391   (unless global-diff-hl-mode
 392     (dolist (buf (buffer-list))
 393       (with-current-buffer buf
 394         (when diff-hl-dir-mode
 395           (diff-hl-dir-mode -1))))))
 396
 397 ;;;###autoload
 398 (define-globalized-minor-mode global-diff-hl-mode diff-hl-mode
 399   turn-on-diff-hl-mode :after-hook (diff-hl-global-mode-change))
 400
 401 (provide 'diff-hl)
 402
 403 ;;; diff-hl.el ends here