code.delx.au - gnu-emacs-elpa/blob - yasnippet-tests.el

   1 ;;; yasnippet-tests.el --- some yasnippet tests
   2
   3 ;; Copyright (C) 2012  João Távora
   4
   5 ;; Author: João Távora <joaot@siscog.pt>
   6 ;; Keywords: emulations, convenience
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; Test basic snippet mechanics and the loading system
  24
  25 ;;; Code:
  26
  27 (require 'yasnippet)
  28 (require 'ert)
  29 (require 'ert-x)
  30
  31 \f
  32 ;;; Snippet mechanics
  33
  34 (defun yas--buffer-contents ()
  35   (buffer-substring-no-properties (point-min) (point-max)))
  36
  37 (ert-deftest field-navigation ()
  38   (with-temp-buffer
  39     (yas-minor-mode 1)
  40     (yas-expand-snippet "${1:brother} from another ${2:mother}")
  41     (should (string= (yas--buffer-contents)
  42                      "brother from another mother"))
  43
  44     (should (looking-at "brother"))
  45     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  46     (should (looking-at "mother"))
  47     (ert-simulate-command '(yas-prev-field))
  48     (should (looking-at "brother"))))
  49
  50 (ert-deftest simple-mirror ()
  51   (with-temp-buffer
  52     (yas-minor-mode 1)
  53     (yas-expand-snippet "${1:brother} from another $1")
  54     (should (string= (yas--buffer-contents)
  55                      "brother from another brother"))
  56     (ert-simulate-command `(yas-mock-insert "bla"))
  57     (should (string= (yas--buffer-contents)
  58                      "bla from another bla"))))
  59
  60 (ert-deftest mirror-with-transformation ()
  61   (with-temp-buffer
  62     (yas-minor-mode 1)
  63     (yas-expand-snippet "${1:brother} from another ${1:$(upcase yas-text)}")
  64     (should (string= (yas--buffer-contents)
  65                      "brother from another BROTHER"))
  66     (ert-simulate-command `(yas-mock-insert "bla"))
  67     (should (string= (yas--buffer-contents)
  68                      "bla from another BLA"))))
  69
  70 (ert-deftest primary-field-transformation ()
  71   (with-temp-buffer
  72     (yas-minor-mode 1)
  73     (let ((snippet "${1:$$(upcase yas/text)}${1:$(concat \"bar\" yas/text)}"))
  74       (yas-expand-snippet snippet)
  75       (should (string= (yas--buffer-contents) "bar"))
  76       (ert-simulate-command `(yas-mock-insert "foo"))
  77       (should (string= (yas--buffer-contents) "FOObarFOO")))))
  78
  79 (ert-deftest nested-placeholders-kill-superfield ()
  80   (with-temp-buffer
  81     (yas-minor-mode 1)
  82     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  83     (should (string= (yas--buffer-contents)
  84                      "brother from another mother!"))
  85     (ert-simulate-command `(yas-mock-insert "bla"))
  86     (should (string= (yas--buffer-contents)
  87                      "brother from bla!"))))
  88
  89 (ert-deftest nested-placeholders-use-subfield ()
  90   (with-temp-buffer
  91     (yas-minor-mode 1)
  92     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  93     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  94     (ert-simulate-command `(yas-mock-insert "bla"))
  95     (should (string= (yas--buffer-contents)
  96                      "brother from another bla!"))))
  97
  98 (ert-deftest mirrors-adjacent-to-fields-with-nested-mirrors ()
  99   (with-temp-buffer)
 100   (yas-minor-mode 1)
 101   (yas-expand-snippet "<%= f.submit \"${1:Submit}\"${2:$(and (yas-text) \", :disable_with => '\")}${2:$1ing...}${2:$(and (yas-text) \"'\")} %>")
 102   (should (string= (yas--buffer-contents)
 103                    "<%= f.submit \"Submit\", :disable_with => 'Submiting...' %>"))
 104   (ert-simulate-command `(yas-mock-insert "Send"))
 105   (should (string= (yas--buffer-contents)
 106                    "<%= f.submit \"Send\", :disable_with => 'Sending...' %>")))
 107
 108 ;; (ert-deftest in-snippet-undo ()
 109 ;;   (with-temp-buffer
 110 ;;     (yas-minor-mode 1)
 111 ;;     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
 112 ;;     (ert-simulate-command '(yas-next-field-or-maybe-expand))
 113 ;;     (ert-simulate-command `(yas-mock-insert "bla"))
 114 ;;     (ert-simulate-command '(undo))
 115 ;;     (should (string= (yas--buffer-contents)
 116 ;;                      "brother from another mother!"))))
 117
 118 \f
 119 ;;; Snippet expansion and character escaping
 120 ;;; Thanks to @zw963 (Billy) for the testing
 121 ;;;
 122 (ert-deftest escape-dollar ()
 123   (with-temp-buffer
 124     (yas-minor-mode 1)
 125     (yas-expand-snippet "bla\\${1:bla}ble")
 126     (should (string= (yas--buffer-contents) "bla${1:bla}ble"))))
 127
 128 (ert-deftest escape-closing-brace ()
 129   (with-temp-buffer
 130     (yas-minor-mode 1)
 131     (yas-expand-snippet "bla${1:bla\\}}ble")
 132     (should (string= (yas--buffer-contents) "blabla}ble"))
 133     (should (string= (yas-field-value 1) "bla}"))))
 134
 135 (ert-deftest escape-backslashes ()
 136   (with-temp-buffer
 137     (yas-minor-mode 1)
 138     (yas-expand-snippet "bla\\ble")
 139     (should (string= (yas--buffer-contents) "bla\\ble"))))
 140
 141 (ert-deftest escape-backquotes ()
 142   (with-temp-buffer
 143     (yas-minor-mode 1)
 144     (yas-expand-snippet "bla`(upcase \"foo\\`bar\")`ble")
 145     (should (string= (yas--buffer-contents) "blaFOO`BARble"))))
 146
 147 (ert-deftest escape-some-elisp-with-strings ()
 148   "elisp with strings and unbalance parens inside it"
 149   (with-temp-buffer
 150     (yas-minor-mode 1)
 151     ;; The rules here is: to output a literal `"' you need to escape
 152     ;; it with one backslash. You don't need to escape them in
 153     ;; embedded elisp.
 154     (yas-expand-snippet "soon \\\"`(concat (upcase \"(my arms\")\"\\\" were all around her\")`")
 155     (should (string= (yas--buffer-contents) "soon \"(MY ARMS\" were all around her"))))
 156
 157 (ert-deftest escape-some-elisp-with-backslashes ()
 158   (with-temp-buffer
 159     (yas-minor-mode 1)
 160     ;; And the rule here is: to output a literal `\' inside a string
 161     ;; inside embedded elisp you need a total of six `\'
 162     (yas-expand-snippet "bla`(upcase \"hey\\\\\\yo\")`ble")
 163     (should (string= (yas--buffer-contents) "blaHEY\\YOble"))))
 164
 165 (ert-deftest be-careful-when-escaping-in-yas-selected-text ()
 166   (with-temp-buffer
 167     (yas-minor-mode 1)
 168     (let ((yas/selected-text "He\\\\o world!"))
 169       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 170       (should (string= (yas--buffer-contents) "Look ma! He\\\\o world!")))
 171     (yas-exit-all-snippets)
 172     (erase-buffer)
 173     (let ((yas/selected-text "He\"o world!"))
 174       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 175       (should (string= (yas--buffer-contents) "Look ma! He\"o world!")))
 176     (yas-exit-all-snippets)
 177     (erase-buffer)
 178     (let ((yas/selected-text "He\"\)\\o world!"))
 179       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 180       (should (string= (yas--buffer-contents) "Look ma! He\"\)\\o world!")))
 181     (yas-exit-all-snippets)
 182     (erase-buffer)))
 183
 184 (ert-deftest be-careful-when-escaping-in-yas-selected-text-2 ()
 185   (with-temp-buffer
 186     (let ((yas/selected-text "He)}o world!"))
 187       (yas-expand-snippet "Look ma! ${1:`(yas/selected-text)`} OK?")
 188       (should (string= (yas--buffer-contents) "Look ma! He)}o world! OK?")))))
 189
 190 (ert-deftest example-for-issue-271 ()
 191   (with-temp-buffer
 192     (yas-minor-mode 1)
 193     (let ((yas-selected-text "aaa")
 194           (snippet "if ${1:condition}\n`yas/selected-text`\nelse\n$3\nend"))
 195       (yas-expand-snippet snippet)
 196       (yas-next-field)
 197       (ert-simulate-command `(yas-mock-insert "bbb"))
 198       (should (string= (yas--buffer-contents) "if condition\naaa\nelse\nbbb\nend")))))
 199
 200 (ert-deftest another-example-for-issue-271 ()
 201   (with-temp-buffer
 202     (yas-minor-mode 1)
 203     (let ((snippet "\\${${1:1}:`yas/selected-text`}"))
 204       (insert "aaabbbccc")
 205       (set-mark 4)
 206       (goto-char 7)
 207       (yas-expand-snippet snippet)
 208       (should (string= (yas--buffer-contents) "aaa${1:bbb}ccc")))))
 209
 210 (ert-deftest string-match-with-subregexp-in-embedded-elisp ()
 211   (with-temp-buffer
 212     (yas-minor-mode 1)
 213     ;; the rule here is: To use regexps in embedded `(elisp)` expressions, write
 214     ;; it like you would normal elisp, i.e. no need to escape the backslashes.
 215     (let ((snippet "`(if (string-match \"foo\\\\(ba+r\\\\)foo\" \"foobaaaaaaaaaarfoo\")
 216                          \"ok\"
 217                          \"fail\")`"))
 218       (yas-expand-snippet snippet))
 219       (should (string= (yas--buffer-contents) "ok"))))
 220
 221 (ert-deftest string-match-with-subregexp-in-mirror-transformations ()
 222   (with-temp-buffer
 223     (yas-minor-mode 1)
 224     ;; the rule here is: To use regexps in embedded `(elisp)` expressions,
 225     ;; escape backslashes once, i.e. to use \\( \\) constructs, write \\\\( \\\\).
 226     (let ((snippet "$1${1:$(if (string-match \"foo\\\\\\\\(ba+r\\\\\\\\)baz\" yas/text)
 227                                 \"ok\"
 228                                 \"fail\")}"))
 229       (yas-expand-snippet snippet)
 230       (should (string= (yas--buffer-contents) "fail"))
 231       (ert-simulate-command `(yas-mock-insert "foobaaar"))
 232       (should (string= (yas--buffer-contents) "foobaaarfail"))
 233       (ert-simulate-command `(yas-mock-insert "baz"))
 234       (should (string= (yas--buffer-contents) "foobaaarbazok")))))
 235
 236 \f
 237 ;;; Misc tests
 238 ;;;
 239 (ert-deftest protection-overlay-no-cheating ()
 240   "Protection overlays at the very end of the buffer are dealt
 241   with by cheatingly inserting a newline!
 242
 243 TODO: correct this bug!"
 244   :expected-result :failed
 245   (with-temp-buffer
 246     (yas-minor-mode 1)
 247     (yas-expand-snippet "${2:brother} from another ${1:mother}")
 248     (should (string= (yas--buffer-contents)
 249                      "brother from another mother") ;; no newline should be here!
 250             )))
 251 \f
 252 ;;; Loading
 253 ;;;
 254 (defmacro yas-with-some-interesting-snippet-dirs (&rest body)
 255   `(yas-saving-variables
 256     (yas-with-snippet-dirs
 257      '((".emacs.d/snippets"
 258         ("c-mode"
 259          (".yas-parents" . "cc-mode")
 260          ("printf" . "printf($1);"))  ;; notice the overriding for issue #281
 261         ("emacs-lisp-mode" ("ert-deftest" . "(ert-deftest ${1:name} () $0)"))
 262         ("lisp-interaction-mode" (".yas-parents" . "emacs-lisp-mode")))
 263        ("library/snippets"
 264         ("c-mode"
 265          (".yas-parents" . "c++-mode")
 266          ("printf" . "printf"))
 267         ("cc-mode" ("def" . "# define"))
 268         ("emacs-lisp-mode" ("dolist" . "(dolist)"))
 269         ("lisp-interaction-mode" ("sc" . "brother from another mother"))))
 270      ,@body)))
 271
 272 (ert-deftest basic-jit-loading ()
 273   "Test basic loading and expansion of snippets"
 274   (yas-with-some-interesting-snippet-dirs
 275    (yas-reload-all)
 276    (yas--basic-jit-loading-1)))
 277
 278 (ert-deftest basic-jit-loading-with-compiled-snippets ()
 279   "Test basic loading and expansion of snippets"
 280   (yas-with-some-interesting-snippet-dirs
 281    (yas-reload-all)
 282    (yas-recompile-all)
 283    (flet ((yas--load-directory-2
 284            (&rest dummies)
 285            (ert-fail "yas--load-directory-2 shouldn't be called when snippets have been compiled")))
 286      (yas-reload-all)
 287      (yas--basic-jit-loading-1))))
 288
 289 (defun yas--basic-jit-loading-1 (&optional compile)
 290   (with-temp-buffer
 291     (should (= 4 (hash-table-count yas--scheduled-jit-loads)))
 292     (should (= 0 (hash-table-count yas--tables)))
 293     (lisp-interaction-mode)
 294     (yas-minor-mode 1)
 295     (should (= 2 (hash-table-count yas--scheduled-jit-loads)))
 296     (should (= 2 (hash-table-count yas--tables)))
 297     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'lisp-interaction-mode yas--tables)))))
 298     (should (= 2 (hash-table-count (yas--table-uuidhash (gethash 'emacs-lisp-mode yas--tables)))))
 299     (yas-should-expand '(("sc" . "brother from another mother")
 300                          ("dolist" . "(dolist)")
 301                          ("ert-deftest" . "(ert-deftest name () )")))
 302     (c-mode)
 303     (yas-minor-mode 1)
 304     (should (= 0 (hash-table-count yas--scheduled-jit-loads)))
 305     (should (= 4 (hash-table-count yas--tables)))
 306     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'c-mode yas--tables)))))
 307     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'cc-mode yas--tables)))))
 308     (yas-should-expand '(("printf" . "printf();")
 309                          ("def" . "# define")))
 310     (yas-should-not-expand '("sc" "dolist" "ert-deftest"))))
 311
 312 \f
 313 ;;; Menu
 314 ;;;
 315 (defmacro yas-with-even-more-interesting-snippet-dirs (&rest body)
 316   `(yas-saving-variables
 317     (yas-with-snippet-dirs
 318      `((".emacs.d/snippets"
 319         ("c-mode"
 320          (".yas-make-groups" . "")
 321          ("printf" . "printf($1);")
 322          ("foo-group-a"
 323           ("fnprintf" . "fprintf($1);")
 324           ("snprintf" . "snprintf($1);"))
 325          ("foo-group-b"
 326           ("strcmp" . "strecmp($1);")
 327           ("strcasecmp" . "strcasecmp($1);")))
 328         ("lisp-interaction-mode"
 329          ("ert-deftest" . "# group: barbar\n# --\n(ert-deftest ${1:name} () $0)"))
 330         ("fancy-mode"
 331          ("a-guy" . "# uuid: 999\n# --\nyo!")
 332          ("a-sir" . "# uuid: 12345\n# --\nindeed!")
 333          ("a-lady" . "# uuid: 54321\n# --\noh-la-la!")
 334          ("a-beggar" . "# uuid: 0101\n# --\narrrgh!")
 335          ("an-outcast" . "# uuid: 666\n# --\narrrgh!")
 336          (".yas-setup.el" . , (pp-to-string
 337                                '(yas-define-menu 'fancy-mode
 338                                                  '((yas-ignore-item "0101")
 339                                                    (yas-item "999")
 340                                                    (yas-submenu "sirs"
 341                                                                 ((yas-item "12345")))
 342                                                    (yas-submenu "ladies"
 343                                                                 ((yas-item "54321"))))
 344                                                  '("666")))))))
 345      ,@body)))
 346
 347 (ert-deftest test-yas-define-menu ()
 348   (let ((yas-use-menu t))
 349     (yas-with-even-more-interesting-snippet-dirs
 350      (yas-reload-all 'no-jit)
 351      (let ((menu (cdr (gethash 'fancy-mode yas--menu-table))))
 352        (should (eql 4 (length menu)))
 353        (dolist (item '("a-guy" "a-beggar"))
 354          (should (find item menu :key #'third :test #'string=)))
 355        (should-not (find "an-outcast" menu :key #'third :test #'string=))
 356        (dolist (submenu '("sirs" "ladies"))
 357          (should (keymapp
 358                   (fourth
 359                    (find submenu menu :key #'third :test #'string=)))))
 360        ))))
 361
 362 (ert-deftest test-group-menus ()
 363   "Test group-based menus using .yas-make-groups and the group directive"
 364   (let ((yas-use-menu t))
 365     (yas-with-even-more-interesting-snippet-dirs
 366      (yas-reload-all 'no-jit)
 367      ;; first the subdir-based groups
 368      ;;
 369      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 370        (should (eql 3 (length menu)))
 371        (dolist (item '("printf" "foo-group-a" "foo-group-b"))
 372          (should (find item menu :key #'third :test #'string=)))
 373        (dolist (submenu '("foo-group-a" "foo-group-b"))
 374          (should (keymapp
 375                   (fourth
 376                    (find submenu menu :key #'third :test #'string=))))))
 377      ;; now group directives
 378      ;;
 379      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 380        (should (eql 1 (length menu)))
 381        (should (find "barbar" menu :key #'third :test #'string=))
 382        (should (keymapp
 383                 (fourth
 384                  (find "barbar" menu :key #'third :test #'string=))))))))
 385
 386 (ert-deftest test-group-menus-twisted ()
 387   "Same as similarly named test, but be mean.
 388
 389 TODO: be meaner"
 390   (let ((yas-use-menu t))
 391     (yas-with-even-more-interesting-snippet-dirs
 392      ;; add a group directive conflicting with the subdir and watch
 393      ;; behaviour
 394      (with-temp-buffer
 395        (insert "# group: foo-group-c\n# --\nstrecmp($1)")
 396        (write-region nil nil (concat (first (yas-snippet-dirs))
 397                                      "/c-mode/foo-group-b/strcmp")))
 398      (yas-reload-all 'no-jit)
 399      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 400        (should (eql 4 (length menu)))
 401        (dolist (item '("printf" "foo-group-a" "foo-group-b" "foo-group-c"))
 402          (should (find item menu :key #'third :test #'string=)))
 403        (dolist (submenu '("foo-group-a" "foo-group-b" "foo-group-c"))
 404          (should (keymapp
 405                   (fourth
 406                    (find submenu menu :key #'third :test #'string=))))))
 407      ;; delete the .yas-make-groups file and watch behaviour
 408      ;;
 409      (delete-file (concat (first (yas-snippet-dirs))
 410                           "/c-mode/.yas-make-groups"))
 411      (yas-reload-all 'no-jit)
 412      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 413        (should (eql 5 (length menu))))
 414      ;; Change a group directive and reload
 415      ;;
 416      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 417        (should (find "barbar" menu :key #'third :test #'string=)))
 418
 419      (with-temp-buffer
 420        (insert "# group: foofoo\n# --\n(ert-deftest ${1:name} () $0)")
 421        (write-region nil nil (concat (first (yas-snippet-dirs))
 422                                      "/lisp-interaction-mode/ert-deftest")))
 423      (yas-reload-all 'no-jit)
 424      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 425        (should (eql 1 (length menu)))
 426        (should (find "foofoo" menu :key #'third :test #'string=))
 427        (should (keymapp
 428                 (fourth
 429                  (find "foofoo" menu :key #'third :test #'string=))))))))
 430
 431 \f
 432 ;;; The infamous and problematic tab keybinding
 433 ;;;
 434 (ert-deftest test-yas-tab-binding ()
 435   (with-temp-buffer
 436     (yas-minor-mode -1)
 437     (should (not (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand)))
 438     (yas-minor-mode 1)
 439     (should (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand))
 440     (yas-expand-snippet "$1 $2 $3")
 441     (dolist (k (if (listp yas-next-field-key)
 442                    yas-next-field-key
 443                  (list yas-next-field-key)))
 444       (should (eq (key-binding (yas--read-keybinding k)) 'yas-next-field-or-maybe-expand)))
 445     (dolist (k (if (listp yas-prev-field-key)
 446                    yas-prev-field-key
 447                  (list yas-prev-field-key)))
 448       (should (eq (key-binding (yas--read-keybinding k)) 'yas-prev-field)))))
 449
 450 (ert-deftest test-yas-in-org ()
 451   (with-temp-buffer
 452     (org-mode)
 453     (yas-minor-mode 1)
 454     (should (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand))))
 455
 456 ;;; Helpers
 457 ;;;
 458
 459 (defun yas-should-expand (keys-and-expansions)
 460   (dolist (key-and-expansion keys-and-expansions)
 461     (yas-exit-all-snippets)
 462     (erase-buffer)
 463     (insert (car key-and-expansion))
 464     (let ((yas-fallback-behavior nil))
 465       (ert-simulate-command '(yas-expand)))
 466     (should (string= (yas--buffer-contents) (cdr key-and-expansion))))
 467   (yas-exit-all-snippets))
 468
 469 (defun yas-should-not-expand (keys)
 470   (dolist (key keys)
 471     (yas-exit-all-snippets)
 472     (erase-buffer)
 473     (insert key)
 474     (let ((yas-fallback-behavior nil))
 475       (ert-simulate-command '(yas-expand)))
 476     (should (string= (yas--buffer-contents) key))))
 477
 478 (defun yas-mock-insert (string)
 479   (interactive)
 480   (do ((i 0 (1+ i)))
 481       ((= i (length string)))
 482     (insert (aref string i))))
 483
 484 (defun yas-make-file-or-dirs (ass)
 485   (let ((file-or-dir-name (car ass))
 486         (content (cdr ass)))
 487     (cond ((listp content)
 488            (make-directory file-or-dir-name 'parents)
 489            (let ((default-directory (concat default-directory "/" file-or-dir-name)))
 490              (mapc #'yas-make-file-or-dirs content)))
 491           ((stringp content)
 492            (with-temp-buffer
 493              (insert content)
 494              (write-region nil nil file-or-dir-name nil 'nomessage)))
 495           (t
 496            (message "[yas] oops don't know this content")))))
 497
 498
 499 (defun yas-variables ()
 500   (let ((syms))
 501     (mapatoms #'(lambda (sym)
 502                   (if (and (string-match "^yas-[^/]" (symbol-name sym))
 503                            (boundp sym))
 504                       (push sym syms))))
 505     syms))
 506
 507 (defun yas-call-with-saving-variables (fn)
 508   (let* ((vars (yas-variables))
 509          (saved-values (mapcar #'symbol-value vars)))
 510     (unwind-protect
 511         (funcall fn)
 512       (loop for var in vars
 513             for saved in saved-values
 514             do (set var saved)))))
 515
 516 (defmacro yas-saving-variables (&rest body)
 517   `(yas-call-with-saving-variables #'(lambda () ,@body)))
 518
 519
 520 (defun yas-call-with-snippet-dirs (dirs fn)
 521   (let* ((default-directory (make-temp-file "yasnippet-fixture" t))
 522          (yas-snippet-dirs (mapcar #'car dirs)))
 523     (with-temp-message ""
 524       (unwind-protect
 525           (progn
 526             (mapc #'yas-make-file-or-dirs dirs)
 527             (funcall fn))
 528         (when (>= emacs-major-version 24)
 529           (delete-directory default-directory 'recursive))))))
 530
 531 (defmacro yas-with-snippet-dirs (dirs &rest body)
 532   `(yas-call-with-snippet-dirs ,dirs
 533                                #'(lambda ()
 534                                    ,@body)))
 535
 536 ;;; Older emacsen
 537 ;;;
 538 (unless (fboundp 'special-mode)
 539   (define-minor-mode special-mode "Just a placeholder for something isn't in emacs 22"))
 540
 541 ;;; btw to test this in emacs22 mac osx:
 542 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert.el
 543 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert-x.el
 544 ;;; /usr/bin/emacs -nw -Q -L . -l yasnippet-tests.el --batch -e ert
 545
 546
 547 (provide 'yasnippet-tests)
 548 ;;; yasnippet-tests.el ends here
 549 ;; Local Variables:
 550 ;; lexical-binding: t
 551 ;; End: