code.delx.au - gnu-emacs-elpa/blob - company-clang.el

   1 ;;; company-clang.el --- company-mode completion back-end for Clang  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009, 2011, 2013-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'company-template)
  30 (require 'cl-lib)
  31
  32 (defgroup company-clang nil
  33   "Completion back-end for Clang."
  34   :group 'company)
  35
  36 (defcustom company-clang-executable
  37   (executable-find "clang")
  38   "Location of clang executable."
  39   :type 'file)
  40
  41 (defcustom company-clang-begin-after-member-access t
  42   "When non-nil, automatic completion will start whenever the current
  43 symbol is preceded by \".\", \"->\" or \"::\", ignoring
  44 `company-minimum-prefix-length'.
  45
  46 If `company-begin-commands' is a list, it should include `c-electric-lt-gt'
  47 and `c-electric-colon', for automatic completion right after \">\" and
  48 \":\".")
  49
  50 (defcustom company-clang-arguments nil
  51   "Additional arguments to pass to clang when completing.
  52 Prefix files (-include ...) can be selected with `company-clang-set-prefix'
  53 or automatically through a custom `company-clang-prefix-guesser'."
  54   :type '(repeat (string :tag "Argument")))
  55
  56 (defcustom company-clang-prefix-guesser 'company-clang-guess-prefix
  57   "A function to determine the prefix file for the current buffer."
  58   :type '(function :tag "Guesser function" nil))
  59
  60 (defvar company-clang-modes '(c-mode c++-mode objc-mode)
  61   "Major modes which clang may complete.")
  62
  63 (defcustom company-clang-insert-arguments t
  64   "When non-nil, insert function arguments as a template after completion."
  65   :type 'boolean
  66   :package-version '(company . "0.8.0"))
  67
  68 ;; prefix ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  69
  70 (defvar company-clang--prefix nil)
  71
  72 (defsubst company-clang--guess-pch-file (file)
  73   (let ((dir (directory-file-name (file-name-directory file))))
  74     (when (equal (file-name-nondirectory dir) "Classes")
  75       (setq dir (file-name-directory dir)))
  76     (car (directory-files dir t "\\([^.]h\\|[^h]\\).pch\\'" t))))
  77
  78 (defsubst company-clang--file-substring (file beg end)
  79   (with-temp-buffer
  80     (insert-file-contents-literally file nil beg end)
  81     (buffer-string)))
  82
  83 (defun company-clang-guess-prefix ()
  84   "Try to guess the prefix file for the current buffer."
  85   ;; Prefixes seem to be called .pch.  Pre-compiled headers do, too.
  86   ;; So we look at the magic number to rule them out.
  87   (let* ((file (company-clang--guess-pch-file buffer-file-name))
  88          (magic-number (and file (company-clang--file-substring file 0 4))))
  89     (unless (member magic-number '("CPCH" "gpch"))
  90       file)))
  91
  92 (defun company-clang-set-prefix (&optional prefix)
  93   "Use PREFIX as a prefix (-include ...) file for clang completion."
  94   (interactive (let ((def (funcall company-clang-prefix-guesser)))
  95      (unless (stringp def)
  96        (setq def default-directory))
  97      (list (read-file-name "Prefix file: "
  98                            (when def (file-name-directory def))
  99                            def t (when def (file-name-nondirectory def))))))
 100   ;; TODO: pre-compile?
 101   (setq company-clang--prefix (and (stringp prefix)
 102                                    (file-regular-p prefix)
 103                                    prefix)))
 104
 105 ;; Clean-up on exit.
 106 (add-hook 'kill-emacs-hook 'company-clang-set-prefix)
 107
 108 ;; parsing ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110 ;; TODO: Handle Pattern (syntactic hints would be neat).
 111 ;; Do we ever see OVERLOAD (or OVERRIDE)?
 112 (defconst company-clang--completion-pattern
 113   "^COMPLETION: \\_<\\(%s[a-zA-Z0-9_:]*\\)\\(?: : \\(.*\\)$\\)?$")
 114
 115 (defconst company-clang--error-buffer-name "*clang-error*")
 116
 117 (defun company-clang--lang-option ()
 118      (if (eq major-mode 'objc-mode)
 119          (if (string= "m" (file-name-extension buffer-file-name))
 120              "objective-c" "objective-c++")
 121        (substring (symbol-name major-mode) 0 -5)))
 122
 123 (defun company-clang--parse-output (prefix _objc)
 124   (goto-char (point-min))
 125   (let ((pattern (format company-clang--completion-pattern
 126                          (regexp-quote prefix)))
 127         (case-fold-search nil)
 128         lines match)
 129     (while (re-search-forward pattern nil t)
 130       (setq match (match-string-no-properties 1))
 131       (unless (equal match "Pattern")
 132         (save-match-data
 133           (when (string-match ":" match)
 134             (setq match (substring match 0 (match-beginning 0)))))
 135         (let ((meta (match-string-no-properties 2)))
 136           (when (and meta (not (string= match meta)))
 137             (put-text-property 0 1 'meta
 138                                (company-clang--strip-formatting meta)
 139                                match)))
 140         (push match lines)))
 141     lines))
 142
 143 (defun company-clang--meta (candidate)
 144   (get-text-property 0 'meta candidate))
 145
 146 (defun company-clang--annotation (candidate)
 147   (let ((meta (company-clang--meta candidate)))
 148     (cond
 149      ((null meta) nil)
 150      ((string-match "[^:]:[^:]" meta)
 151       (substring meta (1+ (match-beginning 0))))
 152      ((string-match "\\((.*)[ a-z]*\\'\\)" meta)
 153       (match-string 1 meta)))))
 154
 155 (defun company-clang--strip-formatting (text)
 156   (replace-regexp-in-string
 157    "#]" " "
 158    (replace-regexp-in-string "[<{[]#\\|#[>}]" "" text t)
 159    t))
 160
 161 (defun company-clang--handle-error (res args)
 162   (goto-char (point-min))
 163   (let* ((buf (get-buffer-create company-clang--error-buffer-name))
 164          (cmd (concat company-clang-executable " " (mapconcat 'identity args " ")))
 165          (pattern (format company-clang--completion-pattern ""))
 166          (err (if (re-search-forward pattern nil t)
 167                   (buffer-substring-no-properties (point-min)
 168                                                   (1- (match-beginning 0)))
 169                 ;; Warn the user more aggressively if no match was found.
 170                 (message "clang failed with error %d:\n%s" res cmd)
 171                 (buffer-string))))
 172
 173     (with-current-buffer buf
 174       (let ((inhibit-read-only t))
 175         (erase-buffer)
 176         (insert (current-time-string)
 177                 (format "\nclang failed with error %d:\n" res)
 178                 cmd "\n\n")
 179         (insert err)
 180         (setq buffer-read-only t)
 181         (goto-char (point-min))))))
 182
 183 (defun company-clang--start-process (prefix callback &rest args)
 184   (let ((objc (derived-mode-p 'objc-mode))
 185         (buf (get-buffer-create "*clang-output*")))
 186     (with-current-buffer buf (erase-buffer))
 187     (if (get-buffer-process buf)
 188         (funcall callback nil)
 189       (let ((process (apply #'start-process "company-clang" buf
 190                             company-clang-executable args)))
 191         (set-process-sentinel
 192          process
 193          (lambda (proc status)
 194            (unless (string-match-p "hangup" status)
 195              (funcall
 196               callback
 197               (let ((res (process-exit-status proc)))
 198                 (with-current-buffer buf
 199                   (unless (eq 0 res)
 200                     (company-clang--handle-error res args))
 201                   ;; Still try to get any useful input.
 202                   (company-clang--parse-output prefix objc)))))))
 203         (unless (company-clang--auto-save-p)
 204           (send-region process (point-min) (point-max))
 205           (send-string process "\n")
 206           (process-send-eof process))))))
 207
 208 (defsubst company-clang--build-location (pos)
 209   (save-excursion
 210     (goto-char pos)
 211     (format "%s:%d:%d"
 212             (if (company-clang--auto-save-p) buffer-file-name "-")
 213             (line-number-at-pos)
 214             (1+ (length
 215                  (encode-coding-region
 216                   (line-beginning-position)
 217                   (point)
 218                   'utf-8
 219                   t))))))
 220
 221 (defsubst company-clang--build-complete-args (pos)
 222   (append '("-fsyntax-only" "-Xclang" "-code-completion-macros")
 223           (unless (company-clang--auto-save-p)
 224             (list "-x" (company-clang--lang-option)))
 225           company-clang-arguments
 226           (when (stringp company-clang--prefix)
 227             (list "-include" (expand-file-name company-clang--prefix)))
 228           (list "-Xclang" (format "-code-completion-at=%s"
 229                                   (company-clang--build-location pos)))
 230           (list (if (company-clang--auto-save-p) buffer-file-name "-"))))
 231
 232 (defun company-clang--candidates (prefix callback)
 233   (and (company-clang--auto-save-p)
 234        (buffer-modified-p)
 235        (basic-save-buffer))
 236   (when (null company-clang--prefix)
 237     (company-clang-set-prefix (or (funcall company-clang-prefix-guesser)
 238                                   'none)))
 239   (apply 'company-clang--start-process
 240          prefix
 241          callback
 242          (company-clang--build-complete-args (- (point) (length prefix)))))
 243
 244 (defun company-clang--prefix ()
 245   (if company-clang-begin-after-member-access
 246       (company-grab-symbol-cons "\\.\\|->\\|::" 2)
 247     (company-grab-symbol)))
 248
 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 250
 251 (defconst company-clang-required-version 1.1)
 252
 253 (defvar company-clang--version nil)
 254
 255 (defun company-clang--auto-save-p ()
 256   (< company-clang--version 2.9))
 257
 258 (defsubst company-clang-version ()
 259   "Return the version of `company-clang-executable'."
 260   (with-temp-buffer
 261     (call-process company-clang-executable nil t nil "--version")
 262     (goto-char (point-min))
 263     (if (re-search-forward "clang\\(?: version \\|-\\)\\([0-9.]+\\)" nil t)
 264         (let ((ver (string-to-number (match-string-no-properties 1))))
 265           (if (> ver 100)
 266               (/ ver 100)
 267             ver))
 268       0)))
 269
 270 (defun company-clang-objc-templatify (selector)
 271   (let* ((end (point-marker))
 272          (beg (- (point) (length selector) 1))
 273          (templ (company-template-declare-template beg end))
 274          (cnt 0))
 275     (save-excursion
 276       (goto-char beg)
 277       (catch 'stop
 278         (while (search-forward ":" end t)
 279           (when (looking-at "([^)]*) ?")
 280             (delete-region (match-beginning 0) (match-end 0)))
 281           (company-template-add-field templ (point) (format "arg%d" cnt))
 282           (if (< (point) end)
 283               (insert " ")
 284             (throw 'stop t))
 285           (cl-incf cnt))))
 286     (company-template-move-to-first templ)))
 287
 288 (defun company-clang (command &optional arg &rest ignored)
 289   "`company-mode' completion back-end for Clang.
 290 Clang is a parser for C and ObjC.  Clang version 1.1 or newer is required.
 291
 292 Additional command line arguments can be specified in
 293 `company-clang-arguments'.  Prefix files (-include ...) can be selected
 294 with `company-clang-set-prefix' or automatically through a custom
 295 `company-clang-prefix-guesser'.
 296
 297 With Clang versions before 2.9, we have to save the buffer before
 298 performing completion.  With Clang 2.9 and later, buffer contents are
 299 passed via standard input."
 300   (interactive (list 'interactive))
 301   (cl-case command
 302     (interactive (company-begin-backend 'company-clang))
 303     (init (when (memq major-mode company-clang-modes)
 304             (unless company-clang-executable
 305               (error "Company found no clang executable"))
 306             (setq company-clang--version (company-clang-version))
 307             (when (< company-clang--version company-clang-required-version)
 308               (error "Company requires clang version 1.1"))))
 309     (prefix (and (memq major-mode company-clang-modes)
 310                  buffer-file-name
 311                  company-clang-executable
 312                  (not (company-in-string-or-comment))
 313                  (or (company-clang--prefix) 'stop)))
 314     (candidates (cons :async
 315                       (lambda (cb) (company-clang--candidates arg cb))))
 316     (meta       (company-clang--meta arg))
 317     (annotation (company-clang--annotation arg))
 318     (post-completion (let ((anno (company-clang--annotation arg)))
 319                        (when (and company-clang-insert-arguments anno)
 320                          (insert anno)
 321                          (if (string-match "\\`:[^:]" anno)
 322                              (company-clang-objc-templatify anno)
 323                            (company-template-c-like-templatify anno)))))))
 324
 325 (provide 'company-clang)
 326 ;;; company-clang.el ends here