code.delx.au - gnu-emacs-elpa/blob - yasnippet-tests.el

   1 ;;; yasnippet-tests.el --- some yasnippet tests
   2
   3 ;; Copyright (C) 2012  João Távora
   4
   5 ;; Author: João Távora <joaot@siscog.pt>
   6 ;; Keywords: emulations, convenience
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; Test basic snippet mechanics and the loading system
  24
  25 ;;; Code:
  26
  27 (require 'yasnippet)
  28 (require 'ert)
  29 (require 'ert-x)
  30
  31 \f
  32 ;;; Snippet mechanics
  33
  34 (defun yas--buffer-contents ()
  35   (buffer-substring-no-properties (point-min) (point-max)))
  36
  37 (ert-deftest field-navigation ()
  38   (with-temp-buffer
  39     (yas-minor-mode 1)
  40     (yas-expand-snippet "${1:brother} from another ${2:mother}")
  41     (should (string= (yas--buffer-contents)
  42                      "brother from another mother"))
  43
  44     (should (looking-at "brother"))
  45     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  46     (should (looking-at "mother"))
  47     (ert-simulate-command '(yas-prev-field))
  48     (should (looking-at "brother"))))
  49
  50 (ert-deftest simple-mirror ()
  51   (with-temp-buffer
  52     (yas-minor-mode 1)
  53     (yas-expand-snippet "${1:brother} from another $1")
  54     (should (string= (yas--buffer-contents)
  55                      "brother from another brother"))
  56     (ert-simulate-command `(yas-mock-insert "bla"))
  57     (should (string= (yas--buffer-contents)
  58                      "bla from another bla"))))
  59
  60 (ert-deftest mirror-with-transformation ()
  61   (with-temp-buffer
  62     (yas-minor-mode 1)
  63     (yas-expand-snippet "${1:brother} from another ${1:$(upcase yas-text)}")
  64     (should (string= (yas--buffer-contents)
  65                      "brother from another BROTHER"))
  66     (ert-simulate-command `(yas-mock-insert "bla"))
  67     (should (string= (yas--buffer-contents)
  68                      "bla from another BLA"))))
  69
  70 (ert-deftest primary-field-transformation ()
  71   (with-temp-buffer
  72     (yas-minor-mode 1)
  73     (let ((snippet "${1:$$(upcase yas/text)}${1:$(concat \"bar\" yas/text)}"))
  74       (yas-expand-snippet snippet)
  75       (should (string= (yas--buffer-contents) "bar"))
  76       (ert-simulate-command `(yas-mock-insert "foo"))
  77       (should (string= (yas--buffer-contents) "FOObarFOO")))))
  78
  79 (ert-deftest nested-placeholders-kill-superfield ()
  80   (with-temp-buffer
  81     (yas-minor-mode 1)
  82     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  83     (should (string= (yas--buffer-contents)
  84                      "brother from another mother!"))
  85     (ert-simulate-command `(yas-mock-insert "bla"))
  86     (should (string= (yas--buffer-contents)
  87                      "brother from bla!"))))
  88
  89 (ert-deftest nested-placeholders-use-subfield ()
  90   (with-temp-buffer
  91     (yas-minor-mode 1)
  92     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  93     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  94     (ert-simulate-command `(yas-mock-insert "bla"))
  95     (should (string= (yas--buffer-contents)
  96                      "brother from another bla!"))))
  97
  98 (ert-deftest mirrors-adjacent-to-fields-with-nested-mirrors ()
  99   (with-temp-buffer
 100     (yas-minor-mode 1)
 101     (yas-expand-snippet "<%= f.submit \"${1:Submit}\"${2:$(and (yas-text) \", :disable_with => '\")}${2:$1ing...}${2:$(and (yas-text) \"'\")} %>")
 102     (should (string= (yas--buffer-contents)
 103                      "<%= f.submit \"Submit\", :disable_with => 'Submiting...' %>"))
 104     (ert-simulate-command `(yas-mock-insert "Send"))
 105     (should (string= (yas--buffer-contents)
 106                      "<%= f.submit \"Send\", :disable_with => 'Sending...' %>"))))
 107
 108 (ert-deftest deep-nested-mirroring-issue-351 ()
 109   (with-temp-buffer
 110     (yas-minor-mode 1)
 111     (yas-expand-snippet "${1:FOOOOOOO}${2:$1}${3:$2}${4:$3}")
 112     (ert-simulate-command `(yas-mock-insert "abc"))
 113     (should (string= (yas--buffer-contents) "abcabcabcabc"))))
 114
 115 ;; (ert-deftest in-snippet-undo ()
 116 ;;   (with-temp-buffer
 117 ;;     (yas-minor-mode 1)
 118 ;;     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
 119 ;;     (ert-simulate-command '(yas-next-field-or-maybe-expand))
 120 ;;     (ert-simulate-command `(yas-mock-insert "bla"))
 121 ;;     (ert-simulate-command '(undo))
 122 ;;     (should (string= (yas--buffer-contents)
 123 ;;                      "brother from another mother!"))))
 124
 125 \f
 126 ;;; Snippet expansion and character escaping
 127 ;;; Thanks to @zw963 (Billy) for the testing
 128 ;;;
 129 (ert-deftest escape-dollar ()
 130   (with-temp-buffer
 131     (yas-minor-mode 1)
 132     (yas-expand-snippet "bla\\${1:bla}ble")
 133     (should (string= (yas--buffer-contents) "bla${1:bla}ble"))))
 134
 135 (ert-deftest escape-closing-brace ()
 136   (with-temp-buffer
 137     (yas-minor-mode 1)
 138     (yas-expand-snippet "bla${1:bla\\}}ble")
 139     (should (string= (yas--buffer-contents) "blabla}ble"))
 140     (should (string= (yas-field-value 1) "bla}"))))
 141
 142 (ert-deftest escape-backslashes ()
 143   (with-temp-buffer
 144     (yas-minor-mode 1)
 145     (yas-expand-snippet "bla\\ble")
 146     (should (string= (yas--buffer-contents) "bla\\ble"))))
 147
 148 (ert-deftest escape-backquotes ()
 149   (with-temp-buffer
 150     (yas-minor-mode 1)
 151     (yas-expand-snippet "bla`(upcase \"foo\\`bar\")`ble")
 152     (should (string= (yas--buffer-contents) "blaFOO`BARble"))))
 153
 154 (ert-deftest escape-some-elisp-with-strings ()
 155   "elisp with strings and unbalance parens inside it"
 156   (with-temp-buffer
 157     (yas-minor-mode 1)
 158     ;; The rules here is: to output a literal `"' you need to escape
 159     ;; it with one backslash. You don't need to escape them in
 160     ;; embedded elisp.
 161     (yas-expand-snippet "soon \\\"`(concat (upcase \"(my arms\")\"\\\" were all around her\")`")
 162     (should (string= (yas--buffer-contents) "soon \"(MY ARMS\" were all around her"))))
 163
 164 (ert-deftest escape-some-elisp-with-backslashes ()
 165   (with-temp-buffer
 166     (yas-minor-mode 1)
 167     ;; And the rule here is: to output a literal `\' inside a string
 168     ;; inside embedded elisp you need a total of six `\'
 169     (yas-expand-snippet "bla`(upcase \"hey\\\\\\yo\")`ble")
 170     (should (string= (yas--buffer-contents) "blaHEY\\YOble"))))
 171
 172 (ert-deftest be-careful-when-escaping-in-yas-selected-text ()
 173   (with-temp-buffer
 174     (yas-minor-mode 1)
 175     (let ((yas/selected-text "He\\\\o world!"))
 176       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 177       (should (string= (yas--buffer-contents) "Look ma! He\\\\o world!")))
 178     (yas-exit-all-snippets)
 179     (erase-buffer)
 180     (let ((yas/selected-text "He\"o world!"))
 181       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 182       (should (string= (yas--buffer-contents) "Look ma! He\"o world!")))
 183     (yas-exit-all-snippets)
 184     (erase-buffer)
 185     (let ((yas/selected-text "He\"\)\\o world!"))
 186       (yas-expand-snippet "Look ma! `(yas/selected-text)`")
 187       (should (string= (yas--buffer-contents) "Look ma! He\"\)\\o world!")))
 188     (yas-exit-all-snippets)
 189     (erase-buffer)))
 190
 191 (ert-deftest be-careful-when-escaping-in-yas-selected-text-2 ()
 192   (with-temp-buffer
 193     (let ((yas/selected-text "He)}o world!"))
 194       (yas-expand-snippet "Look ma! ${1:`(yas/selected-text)`} OK?")
 195       (should (string= (yas--buffer-contents) "Look ma! He)}o world! OK?")))))
 196
 197 (ert-deftest example-for-issue-271 ()
 198   (with-temp-buffer
 199     (yas-minor-mode 1)
 200     (let ((yas-selected-text "aaa")
 201           (snippet "if ${1:condition}\n`yas/selected-text`\nelse\n$3\nend"))
 202       (yas-expand-snippet snippet)
 203       (yas-next-field)
 204       (ert-simulate-command `(yas-mock-insert "bbb"))
 205       (should (string= (yas--buffer-contents) "if condition\naaa\nelse\nbbb\nend")))))
 206
 207 (ert-deftest another-example-for-issue-271 ()
 208   ;; expect this to fail in batch mode since `region-active-p' doesn't
 209   ;; used by `yas-expand-snippet' doesn't make sense in that context.
 210   ;;
 211   :expected-result (if noninteractive
 212                        :failed
 213                      :passed)
 214   (with-temp-buffer
 215     (yas-minor-mode 1)
 216     (let ((snippet "\\${${1:1}:`yas/selected-text`}"))
 217       (insert "aaabbbccc")
 218       (set-mark 4)
 219       (goto-char 7)
 220       (yas-expand-snippet snippet)
 221       (should (string= (yas--buffer-contents) "aaa${1:bbb}ccc")))))
 222
 223 (ert-deftest string-match-with-subregexp-in-embedded-elisp ()
 224   (with-temp-buffer
 225     (yas-minor-mode 1)
 226     ;; the rule here is: To use regexps in embedded `(elisp)` expressions, write
 227     ;; it like you would normal elisp, i.e. no need to escape the backslashes.
 228     (let ((snippet "`(if (string-match \"foo\\\\(ba+r\\\\)foo\" \"foobaaaaaaaaaarfoo\")
 229                          \"ok\"
 230                          \"fail\")`"))
 231       (yas-expand-snippet snippet))
 232     (should (string= (yas--buffer-contents) "ok"))))
 233
 234 (ert-deftest string-match-with-subregexp-in-mirror-transformations ()
 235   (with-temp-buffer
 236     (yas-minor-mode 1)
 237     ;; the rule here is: To use regexps in embedded `(elisp)` expressions,
 238     ;; escape backslashes once, i.e. to use \\( \\) constructs, write \\\\( \\\\).
 239     (let ((snippet "$1${1:$(if (string-match \"foo\\\\\\\\(ba+r\\\\\\\\)baz\" yas/text)
 240                                 \"ok\"
 241                                 \"fail\")}"))
 242       (yas-expand-snippet snippet)
 243       (should (string= (yas--buffer-contents) "fail"))
 244       (ert-simulate-command `(yas-mock-insert "foobaaar"))
 245       (should (string= (yas--buffer-contents) "foobaaarfail"))
 246       (ert-simulate-command `(yas-mock-insert "baz"))
 247       (should (string= (yas--buffer-contents) "foobaaarbazok")))))
 248
 249 \f
 250 ;;; Misc tests
 251 ;;;
 252 (ert-deftest protection-overlay-no-cheating ()
 253   "Protection overlays at the very end of the buffer are dealt
 254   with by cheatingly inserting a newline!
 255
 256 TODO: correct this bug!"
 257   :expected-result :failed
 258   (with-temp-buffer
 259     (yas-minor-mode 1)
 260     (yas-expand-snippet "${2:brother} from another ${1:mother}")
 261     (should (string= (yas--buffer-contents)
 262                      "brother from another mother") ;; no newline should be here!
 263             )))
 264 \f
 265 ;;; Loading
 266 ;;;
 267 (defmacro yas-with-overriden-buffer-list (&rest body)
 268   (let ((saved-sym (gensym)))
 269     `(let ((,saved-sym (symbol-function 'buffer-list)))
 270        (yas--with-temporary-redefinitions
 271            ((buffer-list ()
 272                          (remove-if #'(lambda (buf)
 273                                         (with-current-buffer buf
 274                                           (eq major-mode 'lisp-interaction-mode)))
 275                                     (funcall ,saved-sym))))
 276          ,@body))))
 277
 278 (defmacro yas-with-some-interesting-snippet-dirs (&rest body)
 279   `(yas-saving-variables
 280     (yas-with-overriden-buffer-list
 281      (yas-with-snippet-dirs
 282        '((".emacs.d/snippets"
 283           ("c-mode"
 284            (".yas-parents" . "cc-mode")
 285            ("printf" . "printf($1);"))  ;; notice the overriding for issue #281
 286           ("emacs-lisp-mode" ("ert-deftest" . "(ert-deftest ${1:name} () $0)"))
 287           ("lisp-interaction-mode" (".yas-parents" . "emacs-lisp-mode")))
 288          ("library/snippets"
 289           ("c-mode"
 290            (".yas-parents" . "c++-mode")
 291            ("printf" . "printf"))
 292           ("cc-mode" ("def" . "# define"))
 293           ("emacs-lisp-mode" ("dolist" . "(dolist)"))
 294           ("lisp-interaction-mode" ("sc" . "brother from another mother"))))
 295        ,@body))))
 296
 297 (ert-deftest basic-jit-loading ()
 298   "Test basic loading and expansion of snippets"
 299   (yas-with-some-interesting-snippet-dirs
 300    (yas-reload-all)
 301    (yas--basic-jit-loading-1)))
 302
 303 (ert-deftest basic-jit-loading-with-compiled-snippets ()
 304   "Test basic loading and expansion of snippets"
 305   (yas-with-some-interesting-snippet-dirs
 306    (yas-reload-all)
 307    (yas-recompile-all)
 308    (yas--with-temporary-redefinitions ((yas--load-directory-2
 309                                         (&rest dummies)
 310                                         (declare (ignore dummies))
 311                                         (ert-fail "yas--load-directory-2 shouldn't be called when snippets have been compiled")))
 312      (yas-reload-all)
 313      (yas--basic-jit-loading-1))))
 314
 315 (ert-deftest loading-with-cyclic-parenthood ()
 316   "Test loading when cyclic parenthood is setup."
 317   (yas-saving-variables
 318    (yas-with-snippet-dirs '((".emacs.d/snippets"
 319                              ("c-mode"
 320                               (".yas-parents" . "cc-mode"))
 321                              ("cc-mode"
 322                               (".yas-parents" . "yet-another-c-mode"))
 323                              ("yet-another-c-mode"
 324                               (".yas-parents" . "c-mode"))))
 325      (yas-reload-all)
 326      (condition-case nil
 327          (yas--all-parents 'c-mode)
 328        (error
 329         (ert-fail "cyclic parenthood test failed"))))))
 330
 331 (defun yas--basic-jit-loading-1 (&optional compile)
 332   (with-temp-buffer
 333     (should (= 4 (hash-table-count yas--scheduled-jit-loads)))
 334     (should (= 0 (hash-table-count yas--tables)))
 335     (lisp-interaction-mode)
 336     (yas-minor-mode 1)
 337     (should (= 2 (hash-table-count yas--scheduled-jit-loads)))
 338     (should (= 2 (hash-table-count yas--tables)))
 339     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'lisp-interaction-mode yas--tables)))))
 340     (should (= 2 (hash-table-count (yas--table-uuidhash (gethash 'emacs-lisp-mode yas--tables)))))
 341     (yas-should-expand '(("sc" . "brother from another mother")
 342                          ("dolist" . "(dolist)")
 343                          ("ert-deftest" . "(ert-deftest name () )")))
 344     (c-mode)
 345     (yas-minor-mode 1)
 346     (should (= 0 (hash-table-count yas--scheduled-jit-loads)))
 347     (should (= 4 (hash-table-count yas--tables)))
 348     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'c-mode yas--tables)))))
 349     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'cc-mode yas--tables)))))
 350     (yas-should-expand '(("printf" . "printf();")
 351                          ("def" . "# define")))
 352     (yas-should-not-expand '("sc" "dolist" "ert-deftest"))))
 353
 354 \f
 355 ;;; Menu
 356 ;;;
 357 (defmacro yas-with-even-more-interesting-snippet-dirs (&rest body)
 358   `(yas-saving-variables
 359     (yas-with-snippet-dirs
 360       `((".emacs.d/snippets"
 361          ("c-mode"
 362           (".yas-make-groups" . "")
 363           ("printf" . "printf($1);")
 364           ("foo-group-a"
 365            ("fnprintf" . "fprintf($1);")
 366            ("snprintf" . "snprintf($1);"))
 367           ("foo-group-b"
 368            ("strcmp" . "strecmp($1);")
 369            ("strcasecmp" . "strcasecmp($1);")))
 370          ("lisp-interaction-mode"
 371           ("ert-deftest" . "# group: barbar\n# --\n(ert-deftest ${1:name} () $0)"))
 372          ("fancy-mode"
 373           ("a-guy" . "# uuid: 999\n# --\nyo!")
 374           ("a-sir" . "# uuid: 12345\n# --\nindeed!")
 375           ("a-lady" . "# uuid: 54321\n# --\noh-la-la!")
 376           ("a-beggar" . "# uuid: 0101\n# --\narrrgh!")
 377           ("an-outcast" . "# uuid: 666\n# --\narrrgh!")
 378           (".yas-setup.el" . , (pp-to-string
 379                                 '(yas-define-menu 'fancy-mode
 380                                                   '((yas-ignore-item "0101")
 381                                                     (yas-item "999")
 382                                                     (yas-submenu "sirs"
 383                                                                  ((yas-item "12345")))
 384                                                     (yas-submenu "ladies"
 385                                                                  ((yas-item "54321"))))
 386                                                   '("666")))))))
 387       ,@body)))
 388
 389 (ert-deftest test-yas-define-menu ()
 390   (let ((yas-use-menu t))
 391     (yas-with-even-more-interesting-snippet-dirs
 392      (yas-reload-all 'no-jit)
 393      (let ((menu (cdr (gethash 'fancy-mode yas--menu-table))))
 394        (should (eql 4 (length menu)))
 395        (dolist (item '("a-guy" "a-beggar"))
 396          (should (find item menu :key #'third :test #'string=)))
 397        (should-not (find "an-outcast" menu :key #'third :test #'string=))
 398        (dolist (submenu '("sirs" "ladies"))
 399          (should (keymapp
 400                   (fourth
 401                    (find submenu menu :key #'third :test #'string=)))))
 402        ))))
 403
 404 (ert-deftest test-group-menus ()
 405   "Test group-based menus using .yas-make-groups and the group directive"
 406   (let ((yas-use-menu t))
 407     (yas-with-even-more-interesting-snippet-dirs
 408      (yas-reload-all 'no-jit)
 409      ;; first the subdir-based groups
 410      ;;
 411      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 412        (should (eql 3 (length menu)))
 413        (dolist (item '("printf" "foo-group-a" "foo-group-b"))
 414          (should (find item menu :key #'third :test #'string=)))
 415        (dolist (submenu '("foo-group-a" "foo-group-b"))
 416          (should (keymapp
 417                   (fourth
 418                    (find submenu menu :key #'third :test #'string=))))))
 419      ;; now group directives
 420      ;;
 421      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 422        (should (eql 1 (length menu)))
 423        (should (find "barbar" menu :key #'third :test #'string=))
 424        (should (keymapp
 425                 (fourth
 426                  (find "barbar" menu :key #'third :test #'string=))))))))
 427
 428 (ert-deftest test-group-menus-twisted ()
 429   "Same as similarly named test, but be mean.
 430
 431 TODO: be meaner"
 432   (let ((yas-use-menu t))
 433     (yas-with-even-more-interesting-snippet-dirs
 434      ;; add a group directive conflicting with the subdir and watch
 435      ;; behaviour
 436      (with-temp-buffer
 437        (insert "# group: foo-group-c\n# --\nstrecmp($1)")
 438        (write-region nil nil (concat (first (yas-snippet-dirs))
 439                                      "/c-mode/foo-group-b/strcmp")))
 440      (yas-reload-all 'no-jit)
 441      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 442        (should (eql 4 (length menu)))
 443        (dolist (item '("printf" "foo-group-a" "foo-group-b" "foo-group-c"))
 444          (should (find item menu :key #'third :test #'string=)))
 445        (dolist (submenu '("foo-group-a" "foo-group-b" "foo-group-c"))
 446          (should (keymapp
 447                   (fourth
 448                    (find submenu menu :key #'third :test #'string=))))))
 449      ;; delete the .yas-make-groups file and watch behaviour
 450      ;;
 451      (delete-file (concat (first (yas-snippet-dirs))
 452                           "/c-mode/.yas-make-groups"))
 453      (yas-reload-all 'no-jit)
 454      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 455        (should (eql 5 (length menu))))
 456      ;; Change a group directive and reload
 457      ;;
 458      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 459        (should (find "barbar" menu :key #'third :test #'string=)))
 460
 461      (with-temp-buffer
 462        (insert "# group: foofoo\n# --\n(ert-deftest ${1:name} () $0)")
 463        (write-region nil nil (concat (first (yas-snippet-dirs))
 464                                      "/lisp-interaction-mode/ert-deftest")))
 465      (yas-reload-all 'no-jit)
 466      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 467        (should (eql 1 (length menu)))
 468        (should (find "foofoo" menu :key #'third :test #'string=))
 469        (should (keymapp
 470                 (fourth
 471                  (find "foofoo" menu :key #'third :test #'string=))))))))
 472
 473 \f
 474 ;;; The infamous and problematic tab keybinding
 475 ;;;
 476 (ert-deftest test-yas-tab-binding ()
 477   (with-temp-buffer
 478     (yas-minor-mode -1)
 479     (should (not (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand)))
 480     (yas-minor-mode 1)
 481     (should (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand))
 482     (yas-expand-snippet "$1 $2 $3")
 483     (should (eq (key-binding [(tab)]) 'yas-next-field-or-maybe-expand))
 484     (should (eq (key-binding (kbd "TAB")) 'yas-next-field-or-maybe-expand))
 485     (should (eq (key-binding [(shift tab)]) 'yas-prev-field))
 486     (should (eq (key-binding [backtab]) 'yas-prev-field))))
 487
 488 (ert-deftest test-rebindings ()
 489   (unwind-protect
 490       (progn
 491         (define-key yas-minor-mode-map [tab] nil)
 492         (define-key yas-minor-mode-map (kbd "TAB") nil)
 493         (define-key yas-minor-mode-map (kbd "SPC") 'yas-expand)
 494         (with-temp-buffer
 495           (yas-minor-mode 1)
 496           (should (not (eq (key-binding (yas--read-keybinding "TAB")) 'yas-expand)))
 497           (should (eq (key-binding (yas--read-keybinding "SPC")) 'yas-expand))
 498           (yas-reload-all)
 499           (should (not (eq (key-binding (yas--read-keybinding "TAB")) 'yas-expand)))
 500           (should (eq (key-binding (yas--read-keybinding "SPC")) 'yas-expand))))
 501     (setcdr yas-minor-mode-map (cdr (yas--init-minor-keymap)))))
 502
 503 (ert-deftest test-yas-in-org ()
 504   (with-temp-buffer
 505     (org-mode)
 506     (yas-minor-mode 1)
 507     (should (eq (key-binding [(tab)]) 'yas-expand))
 508     (should (eq (key-binding (kbd "TAB")) 'yas-expand))))
 509
 510 \f
 511 ;;; Helpers
 512 ;;;
 513 (defun yas/ert ()
 514   (interactive)
 515   (with-temp-buffer
 516     (yas--with-temporary-redefinitions
 517         ((message (&rest args)        ;
 518                   (declare (ignore args))
 519                   nil))
 520       (ert t (buffer-name (current-buffer)))
 521       (princ (buffer-string)))))
 522
 523
 524 (defun yas-should-expand (keys-and-expansions)
 525   (dolist (key-and-expansion keys-and-expansions)
 526     (yas-exit-all-snippets)
 527     (erase-buffer)
 528     (insert (car key-and-expansion))
 529     (let ((yas-fallback-behavior nil))
 530       (ert-simulate-command '(yas-expand)))
 531     (should (string= (yas--buffer-contents) (cdr key-and-expansion))))
 532   (yas-exit-all-snippets))
 533
 534 (defun yas-should-not-expand (keys)
 535   (dolist (key keys)
 536     (yas-exit-all-snippets)
 537     (erase-buffer)
 538     (insert key)
 539     (let ((yas-fallback-behavior nil))
 540       (ert-simulate-command '(yas-expand)))
 541     (should (string= (yas--buffer-contents) key))))
 542
 543 (defun yas-mock-insert (string)
 544   (interactive)
 545   (do ((i 0 (1+ i)))
 546       ((= i (length string)))
 547     (insert (aref string i))))
 548
 549 (defun yas-make-file-or-dirs (ass)
 550   (let ((file-or-dir-name (car ass))
 551         (content (cdr ass)))
 552     (cond ((listp content)
 553            (make-directory file-or-dir-name 'parents)
 554            (let ((default-directory (concat default-directory "/" file-or-dir-name)))
 555              (mapc #'yas-make-file-or-dirs content)))
 556           ((stringp content)
 557            (with-temp-buffer
 558              (insert content)
 559              (write-region nil nil file-or-dir-name nil 'nomessage)))
 560           (t
 561            (message "[yas] oops don't know this content")))))
 562
 563
 564 (defun yas-variables ()
 565   (let ((syms))
 566     (mapatoms #'(lambda (sym)
 567                   (if (and (string-match "^yas-[^/]" (symbol-name sym))
 568                            (boundp sym))
 569                       (push sym syms))))
 570     syms))
 571
 572 (defun yas-call-with-saving-variables (fn)
 573   (let* ((vars (yas-variables))
 574          (saved-values (mapcar #'symbol-value vars)))
 575     (unwind-protect
 576         (funcall fn)
 577       (loop for var in vars
 578             for saved in saved-values
 579             do (set var saved)))))
 580
 581 (defmacro yas-saving-variables (&rest body)
 582   `(yas-call-with-saving-variables #'(lambda () ,@body)))
 583
 584
 585 (defun yas-call-with-snippet-dirs (dirs fn)
 586   (let* ((default-directory (make-temp-file "yasnippet-fixture" t))
 587          (yas-snippet-dirs (mapcar #'car dirs)))
 588     (with-temp-message ""
 589       (unwind-protect
 590           (progn
 591             (mapc #'yas-make-file-or-dirs dirs)
 592             (funcall fn))
 593         (when (>= emacs-major-version 24)
 594           (delete-directory default-directory 'recursive))))))
 595
 596 (defmacro yas-with-snippet-dirs (dirs &rest body)
 597   (declare (indent defun))
 598   `(yas-call-with-snippet-dirs ,dirs
 599                                #'(lambda ()
 600                                    ,@body)))
 601
 602 ;;; Older emacsen
 603 ;;;
 604 (unless (fboundp 'special-mode)
 605   (define-minor-mode special-mode "Just a placeholder for something isn't in emacs 22"))
 606
 607 ;;; btw to test this in emacs22 mac osx:
 608 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert.el
 609 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert-x.el
 610 ;;; /usr/bin/emacs -nw -Q -L . -l yasnippet-tests.el --batch -e ert
 611
 612
 613 (provide 'yasnippet-tests)
 614 ;;; yasnippet-tests.el ends here
 615 ;; Local Variables:
 616 ;; lexical-binding: t
 617 ;; End: