code.delx.au - gnu-emacs-elpa/blob - company-etags.el

   1 ;;; company-etags.el --- company-mode completion back-end for etags
   2
   3 ;; Copyright (C) 2009-2011, 2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'cl-lib)
  30 (require 'etags)
  31
  32 (defgroup company-etags nil
  33   "Completion back-end for etags."
  34   :group 'company)
  35
  36 (defcustom company-etags-use-main-table-list t
  37   "Always search `tags-table-list' if set.
  38 If this is disabled, `company-etags' will try to find the one table for each
  39 buffer automatically."
  40   :type '(choice (const :tag "off" nil)
  41                  (const :tag "on" t)))
  42
  43 (defcustom company-etags-ignore-case nil
  44   "Non-nil to ignore case in completion candidates."
  45   :type 'boolean)
  46
  47 (defvar company-etags-modes '(prog-mode c-mode objc-mode c++-mode java-mode
  48                               jde-mode pascal-mode perl-mode python-mode))
  49
  50 (defvar-local company-etags-buffer-table 'unknown)
  51
  52 (defun company-etags-find-table ()
  53   (let ((file (locate-dominating-file (or buffer-file-name
  54                                           default-directory)
  55                                       "TAGS")))
  56     (when file
  57       (list (expand-file-name file)))))
  58
  59 (defun company-etags-buffer-table ()
  60   (or (and company-etags-use-main-table-list tags-table-list)
  61       (if (eq company-etags-buffer-table 'unknown)
  62           (setq company-etags-buffer-table (company-etags-find-table))
  63         company-etags-buffer-table)))
  64
  65 (defun company-etags--candidates (prefix)
  66   (let ((tags-table-list (company-etags-buffer-table))
  67         (completion-ignore-case company-etags-ignore-case))
  68     (and (or tags-file-name tags-table-list)
  69          (fboundp 'tags-completion-table)
  70          (save-excursion
  71            (visit-tags-table-buffer)
  72            (all-completions prefix (tags-completion-table))))))
  73
  74 ;;;###autoload
  75 (defun company-etags (command &optional arg &rest ignored)
  76   "`company-mode' completion back-end for etags."
  77   (interactive (list 'interactive))
  78   (cl-case command
  79     (interactive (company-begin-backend 'company-etags))
  80     (prefix (and (apply 'derived-mode-p company-etags-modes)
  81                  (not (company-in-string-or-comment))
  82                  (company-etags-buffer-table)
  83                  (or (company-grab-symbol) 'stop)))
  84     (candidates (company-etags--candidates arg))
  85     (location (let ((tags-table-list (company-etags-buffer-table)))
  86                 (when (fboundp 'find-tag-noselect)
  87                   (save-excursion
  88                     (let ((buffer (find-tag-noselect arg)))
  89                       (cons buffer (with-current-buffer buffer (point))))))))
  90     (ignore-case company-etags-ignore-case)))
  91
  92 (provide 'company-etags)
  93 ;;; company-etags.el ends here