code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular text completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; URL: http://company-mode.github.io/
   8 ;; Version: 0.8.5
   9 ;; Keywords: abbrev, convenience, matching
  10 ;; Package-Requires: ((emacs "24.1") (cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (pcase command
  52 ;;     (`prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (`meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;;; Change Log:
  62 ;;
  63 ;; See NEWS.md in the repository.
  64
  65 ;;; Code:
  66
  67 (require 'cl-lib)
  68 (require 'newcomment)
  69
  70 ;; FIXME: Use `user-error'.
  71 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  72 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  73 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  74 (add-to-list 'debug-ignored-errors "^Company not ")
  75 (add-to-list 'debug-ignored-errors "^No candidate number ")
  76 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  77 (add-to-list 'debug-ignored-errors "^No other back-end$")
  78
  79 ;;; Compatibility
  80 (eval-and-compile
  81   ;; `defvar-local' for Emacs 24.2 and below
  82   (unless (fboundp 'defvar-local)
  83     (defmacro defvar-local (var val &optional docstring)
  84       "Define VAR as a buffer-local variable with default value VAL.
  85 Like `defvar' but additionally marks the variable as being automatically
  86 buffer-local wherever it is set."
  87       (declare (debug defvar) (doc-string 3))
  88       `(progn
  89          (defvar ,var ,val ,docstring)
  90          (make-variable-buffer-local ',var)))))
  91
  92 (defgroup company nil
  93   "Extensible inline text completion mechanism"
  94   :group 'abbrev
  95   :group 'convenience
  96   :group 'matching)
  97
  98 (defface company-tooltip
  99   '((default :foreground "black")
 100     (((class color) (min-colors 88) (background light))
 101      (:background "cornsilk"))
 102     (((class color) (min-colors 88) (background dark))
 103      (:background "yellow")))
 104   "Face used for the tooltip.")
 105
 106 (defface company-tooltip-selection
 107   '((default :inherit company-tooltip)
 108     (((class color) (min-colors 88) (background light))
 109      (:background "light blue"))
 110     (((class color) (min-colors 88) (background dark))
 111      (:background "orange1"))
 112     (t (:background "green")))
 113   "Face used for the selection in the tooltip.")
 114
 115 (defface company-tooltip-search
 116   '((default :inherit company-tooltip-selection))
 117   "Face used for the search string in the tooltip.")
 118
 119 (defface company-tooltip-mouse
 120   '((default :inherit highlight))
 121   "Face used for the tooltip item under the mouse.")
 122
 123 (defface company-tooltip-common
 124   '((default :inherit company-tooltip)
 125     (((background light))
 126      :foreground "darkred")
 127     (((background dark))
 128      :foreground "red"))
 129   "Face used for the common completion in the tooltip.")
 130
 131 (defface company-tooltip-common-selection
 132   '((default :inherit company-tooltip-selection)
 133     (((background light))
 134      :foreground "darkred")
 135     (((background dark))
 136      :foreground "red"))
 137   "Face used for the selected common completion in the tooltip.")
 138
 139 (defface company-tooltip-annotation
 140   '((default :inherit company-tooltip)
 141     (((background light))
 142      :foreground "firebrick4")
 143     (((background dark))
 144      :foreground "red4"))
 145   "Face used for the annotation in the tooltip.")
 146
 147 (defface company-scrollbar-fg
 148   '((((background light))
 149      :background "darkred")
 150     (((background dark))
 151      :background "red"))
 152   "Face used for the tooltip scrollbar thumb.")
 153
 154 (defface company-scrollbar-bg
 155   '((default :inherit company-tooltip)
 156     (((background light))
 157      :background "wheat")
 158     (((background dark))
 159      :background "gold"))
 160   "Face used for the tooltip scrollbar background.")
 161
 162 (defface company-preview
 163   '((((background light))
 164      :inherit company-tooltip-selection)
 165     (((background dark))
 166      :background "blue4"
 167      :foreground "wheat"))
 168   "Face used for the completion preview.")
 169
 170 (defface company-preview-common
 171   '((((background light))
 172      :inherit company-tooltip-selection)
 173     (((background dark))
 174      :inherit company-preview
 175      :foreground "red"))
 176   "Face used for the common part of the completion preview.")
 177
 178 (defface company-preview-search
 179   '((((background light))
 180      :inherit company-tooltip-common-selection)
 181     (((background dark))
 182      :inherit company-preview
 183      :background "blue1"))
 184   "Face used for the search string in the completion preview.")
 185
 186 (defface company-echo nil
 187   "Face used for completions in the echo area.")
 188
 189 (defface company-echo-common
 190   '((((background dark)) (:foreground "firebrick1"))
 191     (((background light)) (:background "firebrick4")))
 192   "Face used for the common part of completions in the echo area.")
 193
 194 (defun company-frontends-set (variable value)
 195   ;; Uniquify.
 196   (let ((value (delete-dups (copy-sequence value))))
 197     (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 198          (memq 'company-pseudo-tooltip-frontend value)
 199          (error "Pseudo tooltip frontend cannot be used twice"))
 200     (and (memq 'company-preview-if-just-one-frontend value)
 201          (memq 'company-preview-frontend value)
 202          (error "Preview frontend cannot be used twice"))
 203     (and (memq 'company-echo value)
 204          (memq 'company-echo-metadata-frontend value)
 205          (error "Echo area cannot be used twice"))
 206     ;; Preview must come last.
 207     (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 208       (when (cdr (memq f value))
 209         (setq value (append (delq f value) (list f)))))
 210     (set variable value)))
 211
 212 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 213                                company-preview-if-just-one-frontend
 214                                company-echo-metadata-frontend)
 215   "The list of active front-ends (visualizations).
 216 Each front-end is a function that takes one argument.  It is called with
 217 one of the following arguments:
 218
 219 `show': When the visualization should start.
 220
 221 `hide': When the visualization should end.
 222
 223 `update': When the data has been updated.
 224
 225 `pre-command': Before every command that is executed while the
 226 visualization is active.
 227
 228 `post-command': After every command that is executed while the
 229 visualization is active.
 230
 231 The visualized data is stored in `company-prefix', `company-candidates',
 232 `company-common', `company-selection', `company-point' and
 233 `company-search-string'."
 234   :set 'company-frontends-set
 235   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 236                          (const :tag "echo, strip common"
 237                                 company-echo-strip-common-frontend)
 238                          (const :tag "show echo meta-data in echo"
 239                                 company-echo-metadata-frontend)
 240                          (const :tag "pseudo tooltip"
 241                                 company-pseudo-tooltip-frontend)
 242                          (const :tag "pseudo tooltip, multiple only"
 243                                 company-pseudo-tooltip-unless-just-one-frontend)
 244                          (const :tag "preview" company-preview-frontend)
 245                          (const :tag "preview, unique only"
 246                                 company-preview-if-just-one-frontend)
 247                          (function :tag "custom function" nil))))
 248
 249 (defcustom company-tooltip-limit 10
 250   "The maximum number of candidates in the tooltip."
 251   :type 'integer)
 252
 253 (defcustom company-tooltip-minimum 6
 254   "The minimum height of the tooltip.
 255 If this many lines are not available, prefer to display the tooltip above."
 256   :type 'integer)
 257
 258 (defcustom company-tooltip-minimum-width 0
 259   "The minimum width of the tooltip's inner area.
 260 This doesn't include the margins and the scroll bar."
 261   :type 'integer
 262   :package-version '(company . "0.8.0"))
 263
 264 (defcustom company-tooltip-margin 1
 265   "Width of margin columns to show around the toolip."
 266   :type 'integer)
 267
 268 (defcustom company-tooltip-offset-display 'scrollbar
 269   "Method using which the tooltip displays scrolling position.
 270 `scrollbar' means draw a scrollbar to the right of the items.
 271 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 272   :type '(choice (const :tag "Scrollbar" scrollbar)
 273                  (const :tag "Two lines" lines)))
 274
 275 (defcustom company-tooltip-align-annotations nil
 276   "When non-nil, align annotations to the right tooltip border."
 277   :type 'boolean
 278   :package-version '(company . "0.7.1"))
 279
 280 (defcustom company-tooltip-flip-when-above nil
 281   "Whether to flip the tooltip when it's above the current line."
 282   :type 'boolean
 283   :package-version '(company . "0.8.1"))
 284
 285 (defvar company-safe-backends
 286   '((company-abbrev . "Abbrev")
 287     (company-bbdb . "BBDB")
 288     (company-capf . "completion-at-point-functions")
 289     (company-clang . "Clang")
 290     (company-cmake . "CMake")
 291     (company-css . "CSS")
 292     (company-dabbrev . "dabbrev for plain text")
 293     (company-dabbrev-code . "dabbrev for code")
 294     (company-eclim . "Eclim (an Eclipse interface)")
 295     (company-elisp . "Emacs Lisp")
 296     (company-etags . "etags")
 297     (company-files . "Files")
 298     (company-gtags . "GNU Global")
 299     (company-ispell . "Ispell")
 300     (company-keywords . "Programming language keywords")
 301     (company-nxml . "nxml")
 302     (company-oddmuse . "Oddmuse")
 303     (company-pysmell . "PySmell")
 304     (company-ropemacs . "ropemacs")
 305     (company-semantic . "Semantic")
 306     (company-tempo . "Tempo templates")
 307     (company-xcode . "Xcode")))
 308 (put 'company-safe-backends 'risky-local-variable t)
 309
 310 (defun company-safe-backends-p (backends)
 311   (and (consp backends)
 312        (not (cl-dolist (backend backends)
 313               (unless (if (consp backend)
 314                           (company-safe-backends-p backend)
 315                         (assq backend company-safe-backends))
 316                 (cl-return t))))))
 317
 318 (defcustom company-backends `(,@(unless (version< "24.3.50" emacs-version)
 319                                   (list 'company-elisp))
 320                               company-bbdb
 321                               company-nxml company-css
 322                               company-eclim company-semantic company-clang
 323                               company-xcode company-ropemacs company-cmake
 324                               company-capf
 325                               (company-dabbrev-code company-gtags company-etags
 326                                company-keywords)
 327                               company-oddmuse company-files company-dabbrev)
 328   "The list of active back-ends (completion engines).
 329
 330 Only one back-end is used at a time.  The choice depends on the order of
 331 the items in this list, and on the values they return in response to the
 332 `prefix' command (see below).  But a back-end can also be a \"grouped\"
 333 one (see below).
 334
 335 `company-begin-backend' can be used to start a specific back-end,
 336 `company-other-backend' will skip to the next matching back-end in the list.
 337
 338 Each back-end is a function that takes a variable number of arguments.
 339 The first argument is the command requested from the back-end.  It is one
 340 of the following:
 341
 342 `prefix': The back-end should return the text to be completed.  It must be
 343 text immediately before point.  Returning nil passes control to the next
 344 back-end.  The function should return `stop' if it should complete but
 345 cannot (e.g. if it is in the middle of a string).  Instead of a string,
 346 the back-end may return a cons where car is the prefix and cdr is used in
 347 `company-minimum-prefix-length' test.  It must be either number or t, and
 348 in the latter case the test automatically succeeds.
 349
 350 `candidates': The second argument is the prefix to be completed.  The
 351 return value should be a list of candidates that match the prefix.
 352
 353 Non-prefix matches are also supported (candidates that don't start with the
 354 prefix, but match it in some backend-defined way).  Backends that use this
 355 feature must disable cache (return t to `no-cache') and should also respond
 356 to `match'.
 357
 358 Optional commands:
 359
 360 `sorted': Return t here to indicate that the candidates are sorted and will
 361 not need to be sorted again.
 362
 363 `duplicates': If non-nil, company will take care of removing duplicates
 364 from the list.
 365
 366 `no-cache': Usually company doesn't ask for candidates again as completion
 367 progresses, unless the back-end returns t for this command.  The second
 368 argument is the latest prefix.
 369
 370 `meta': The second argument is a completion candidate.  Return a (short)
 371 documentation string for it.
 372
 373 `doc-buffer': The second argument is a completion candidate.  Return a
 374 buffer with documentation for it.  Preferably use `company-doc-buffer',
 375
 376 `location': The second argument is a completion candidate.  Return the cons
 377 of buffer and buffer location, or of file and line number where the
 378 completion candidate was defined.
 379
 380 `annotation': The second argument is a completion candidate.  Return a
 381 string to be displayed inline with the candidate in the popup.  If
 382 duplicates are removed by company, candidates with equal string values will
 383 be kept if they have different annotations.  For that to work properly,
 384 backends should store the related information on candidates using text
 385 properties.
 386
 387 `match': The second argument is a completion candidate.  Backends that
 388 provide non-prefix completions should return the position of the end of
 389 text in the candidate that matches `prefix'.  It will be used when
 390 rendering the popup.
 391
 392 `require-match': If this returns t, the user is not allowed to enter
 393 anything not offered as a candidate.  Use with care!  The default value nil
 394 gives the user that choice with `company-require-match'.  Return value
 395 `never' overrides that option the other way around.
 396
 397 `init': Called once for each buffer. The back-end can check for external
 398 programs and files and load any required libraries.  Raising an error here
 399 will show up in message log once, and the back-end will not be used for
 400 completion.
 401
 402 `post-completion': Called after a completion candidate has been inserted
 403 into the buffer.  The second argument is the candidate.  Can be used to
 404 modify it, e.g. to expand a snippet.
 405
 406 The back-end should return nil for all commands it does not support or
 407 does not know about.  It should also be callable interactively and use
 408 `company-begin-backend' to start itself in that case.
 409
 410 Grouped back-ends:
 411
 412 An element of `company-backends' can also itself be a list of back-ends,
 413 then it's considered to be a \"grouped\" back-end.
 414
 415 When possible, commands taking a candidate as an argument are dispatched to
 416 the back-end it came from.  In other cases, the first non-nil value among
 417 all the back-ends is returned.
 418
 419 The latter is the case for the `prefix' command.  But if the group contains
 420 the keyword `:with', the back-ends after it are ignored for this command.
 421
 422 The completions from back-ends in a group are merged (but only from those
 423 that return the same `prefix').
 424
 425 Asynchronous back-ends:
 426
 427 The return value of each command can also be a cons (:async . FETCHER)
 428 where FETCHER is a function of one argument, CALLBACK.  When the data
 429 arrives, FETCHER must call CALLBACK and pass it the appropriate return
 430 value, as described above.
 431
 432 True asynchronous operation is only supported for command `candidates', and
 433 only during idle completion.  Other commands will block the user interface,
 434 even if the back-end uses the asynchronous calling convention."
 435   :type `(repeat
 436           (choice
 437            :tag "Back-end"
 438            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 439                      company-safe-backends)
 440            (symbol :tag "User defined")
 441            (repeat :tag "Merged Back-ends"
 442                    (choice :tag "Back-end"
 443                            ,@(mapcar (lambda (b)
 444                                        `(const :tag ,(cdr b) ,(car b)))
 445                                      company-safe-backends)
 446                            (const :tag "With" :with)
 447                            (symbol :tag "User defined"))))))
 448
 449 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 450
 451 (defcustom company-transformers nil
 452   "Functions to change the list of candidates received from backends,
 453 after sorting and removal of duplicates (if appropriate).
 454 Each function gets called with the return value of the previous one."
 455   :type '(choice
 456           (const :tag "None" nil)
 457           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 458           (const :tag "Sort by back-end importance"
 459                  (company-sort-by-backend-importance))
 460           (repeat :tag "User defined" (function))))
 461
 462 (defcustom company-completion-started-hook nil
 463   "Hook run when company starts completing.
 464 The hook is called with one argument that is non-nil if the completion was
 465 started manually."
 466   :type 'hook)
 467
 468 (defcustom company-completion-cancelled-hook nil
 469   "Hook run when company cancels completing.
 470 The hook is called with one argument that is non-nil if the completion was
 471 aborted manually."
 472   :type 'hook)
 473
 474 (defcustom company-completion-finished-hook nil
 475   "Hook run when company successfully completes.
 476 The hook is called with the selected candidate as an argument.
 477
 478 If you indend to use it to post-process candidates from a specific
 479 back-end, consider using the `post-completion' command instead."
 480   :type 'hook)
 481
 482 (defcustom company-minimum-prefix-length 3
 483   "The minimum prefix length for idle completion."
 484   :type '(integer :tag "prefix length"))
 485
 486 (defcustom company-abort-manual-when-too-short nil
 487   "If enabled, cancel a manually started completion when the prefix gets
 488 shorter than both `company-minimum-prefix-length' and the length of the
 489 prefix it was started from."
 490   :type 'boolean
 491   :package-version '(company . "0.8.0"))
 492
 493 (defcustom company-require-match 'company-explicit-action-p
 494   "If enabled, disallow non-matching input.
 495 This can be a function do determine if a match is required.
 496
 497 This can be overridden by the back-end, if it returns t or `never' to
 498 `require-match'.  `company-auto-complete' also takes precedence over this."
 499   :type '(choice (const :tag "Off" nil)
 500                  (function :tag "Predicate function")
 501                  (const :tag "On, if user interaction took place"
 502                         'company-explicit-action-p)
 503                  (const :tag "On" t)))
 504
 505 (defcustom company-auto-complete nil
 506   "Determines when to auto-complete.
 507 If this is enabled, all characters from `company-auto-complete-chars'
 508 trigger insertion of the selected completion candidate.
 509 This can also be a function."
 510   :type '(choice (const :tag "Off" nil)
 511                  (function :tag "Predicate function")
 512                  (const :tag "On, if user interaction took place"
 513                         'company-explicit-action-p)
 514                  (const :tag "On" t)))
 515
 516 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 517   "Determines which characters trigger auto-completion.
 518 See `company-auto-complete'.  If this is a string, each string character
 519 tiggers auto-completion.  If it is a list of syntax description characters (see
 520 `modify-syntax-entry'), all characters with that syntax auto-complete.
 521
 522 This can also be a function, which is called with the new input and should
 523 return non-nil if company should auto-complete.
 524
 525 A character that is part of a valid candidate never triggers auto-completion."
 526   :type '(choice (string :tag "Characters")
 527                  (set :tag "Syntax"
 528                       (const :tag "Whitespace" ?\ )
 529                       (const :tag "Symbol" ?_)
 530                       (const :tag "Opening parentheses" ?\()
 531                       (const :tag "Closing parentheses" ?\))
 532                       (const :tag "Word constituent" ?w)
 533                       (const :tag "Punctuation." ?.)
 534                       (const :tag "String quote." ?\")
 535                       (const :tag "Paired delimiter." ?$)
 536                       (const :tag "Expression quote or prefix operator." ?\')
 537                       (const :tag "Comment starter." ?<)
 538                       (const :tag "Comment ender." ?>)
 539                       (const :tag "Character-quote." ?/)
 540                       (const :tag "Generic string fence." ?|)
 541                       (const :tag "Generic comment fence." ?!))
 542                  (function :tag "Predicate function")))
 543
 544 (defcustom company-idle-delay .5
 545   "The idle delay in seconds until completion starts automatically.
 546 The prefix still has to satisfy `company-minimum-prefix-length' before that
 547 happens.  The value of nil means no idle completion."
 548   :type '(choice (const :tag "never (nil)" nil)
 549                  (const :tag "immediate (0)" 0)
 550                  (number :tag "seconds")))
 551
 552 (defcustom company-begin-commands '(self-insert-command
 553                                     org-self-insert-command
 554                                     c-scope-operator
 555                                     c-electric-colon
 556                                     c-electric-lt-gt
 557                                     c-electric-slash)
 558   "A list of commands after which idle completion is allowed.
 559 If this is t, it can show completions after any command except a few from a
 560 pre-defined list.  See `company-idle-delay'.
 561
 562 Alternatively, any command with a non-nil `company-begin' property is
 563 treated as if it was on this list."
 564   :type '(choice (const :tag "Any command" t)
 565                  (const :tag "Self insert command" '(self-insert-command))
 566                  (repeat :tag "Commands" function))
 567   :package-version '(company . "0.8.4"))
 568
 569 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 570                                            save-buffers-kill-terminal
 571                                            save-buffers-kill-emacs)
 572   "A list of commands that are allowed during completion.
 573 If this is t, or if `company-begin-commands' is t, any command is allowed.
 574 Otherwise, the value must be a list of symbols.  If it starts with `not',
 575 the cdr is the list of commands that abort completion.  Otherwise, all
 576 commands except those in that list, or in `company-begin-commands', or
 577 commands in the `company-' namespace, abort completion."
 578   :type '(choice (const :tag "Any command" t)
 579                  (cons  :tag "Any except"
 580                         (const not)
 581                         (repeat :tag "Commands" function))
 582                  (repeat :tag "Commands" function)))
 583
 584 (defcustom company-show-numbers nil
 585   "If enabled, show quick-access numbers for the first ten candidates."
 586   :type '(choice (const :tag "off" nil)
 587                  (const :tag "on" t)))
 588
 589 (defcustom company-selection-wrap-around nil
 590   "If enabled, selecting item before first or after last wraps around."
 591   :type '(choice (const :tag "off" nil)
 592                  (const :tag "on" t)))
 593
 594 (defvar company-async-wait 0.03
 595   "Pause between checks to see if the value's been set when turning an
 596 asynchronous call into synchronous.")
 597
 598 (defvar company-async-timeout 2
 599   "Maximum wait time for a value to be set during asynchronous call.")
 600
 601 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 602
 603 (defvar company-mode-map (make-sparse-keymap)
 604   "Keymap used by `company-mode'.")
 605
 606 (defvar company-active-map
 607   (let ((keymap (make-sparse-keymap)))
 608     (define-key keymap "\e\e\e" 'company-abort)
 609     (define-key keymap "\C-g" 'company-abort)
 610     (define-key keymap (kbd "M-n") 'company-select-next)
 611     (define-key keymap (kbd "M-p") 'company-select-previous)
 612     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 613     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 614     (define-key keymap [down-mouse-1] 'ignore)
 615     (define-key keymap [down-mouse-3] 'ignore)
 616     (define-key keymap [mouse-1] 'company-complete-mouse)
 617     (define-key keymap [mouse-3] 'company-select-mouse)
 618     (define-key keymap [up-mouse-1] 'ignore)
 619     (define-key keymap [up-mouse-3] 'ignore)
 620     (define-key keymap [return] 'company-complete-selection)
 621     (define-key keymap (kbd "RET") 'company-complete-selection)
 622     (define-key keymap [tab] 'company-complete-common)
 623     (define-key keymap (kbd "TAB") 'company-complete-common)
 624     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 625     (define-key keymap (kbd "C-h") 'company-show-doc-buffer)
 626     (define-key keymap "\C-w" 'company-show-location)
 627     (define-key keymap "\C-s" 'company-search-candidates)
 628     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 629     (dotimes (i 10)
 630       (define-key keymap (read-kbd-macro (format "M-%d" i)) 'company-complete-number))
 631      keymap)
 632   "Keymap that is enabled during an active completion.")
 633
 634 (defvar company--disabled-backends nil)
 635
 636 (defun company-init-backend (backend)
 637   (and (symbolp backend)
 638        (not (fboundp backend))
 639        (ignore-errors (require backend nil t)))
 640   (cond
 641    ((symbolp backend)
 642     (condition-case err
 643         (progn
 644           (funcall backend 'init)
 645           (put backend 'company-init t))
 646       (error
 647        (put backend 'company-init 'failed)
 648        (unless (memq backend company--disabled-backends)
 649          (message "Company back-end '%s' could not be initialized:\n%s"
 650                   backend (error-message-string err)))
 651        (cl-pushnew backend company--disabled-backends)
 652        nil)))
 653    ;; No initialization for lambdas.
 654    ((functionp backend) t)
 655    (t ;; Must be a list.
 656     (cl-dolist (b backend)
 657       (unless (keywordp b)
 658         (company-init-backend b))))))
 659
 660 (defvar company-default-lighter " company")
 661
 662 (defvar-local company-lighter company-default-lighter)
 663
 664 ;;;###autoload
 665 (define-minor-mode company-mode
 666   "\"complete anything\"; is an in-buffer completion framework.
 667 Completion starts automatically, depending on the values
 668 `company-idle-delay' and `company-minimum-prefix-length'.
 669
 670 Completion can be controlled with the commands:
 671 `company-complete-common', `company-complete-selection', `company-complete',
 672 `company-select-next', `company-select-previous'.  If these commands are
 673 called before `company-idle-delay', completion will also start.
 674
 675 Completions can be searched with `company-search-candidates' or
 676 `company-filter-candidates'.  These can be used while completion is
 677 inactive, as well.
 678
 679 The completion data is retrieved using `company-backends' and displayed
 680 using `company-frontends'.  If you want to start a specific back-end, call
 681 it interactively or use `company-begin-backend'.
 682
 683 regular keymap (`company-mode-map'):
 684
 685 \\{company-mode-map}
 686 keymap during active completions (`company-active-map'):
 687
 688 \\{company-active-map}"
 689   nil company-lighter company-mode-map
 690   (if company-mode
 691       (progn
 692         (when (eq company-idle-delay t)
 693           (setq company-idle-delay 0)
 694           (warn "Setting `company-idle-delay' to t is deprecated.  Set it to 0 instead."))
 695         (add-hook 'pre-command-hook 'company-pre-command nil t)
 696         (add-hook 'post-command-hook 'company-post-command nil t)
 697         (mapc 'company-init-backend company-backends))
 698     (remove-hook 'pre-command-hook 'company-pre-command t)
 699     (remove-hook 'post-command-hook 'company-post-command t)
 700     (company-cancel)
 701     (kill-local-variable 'company-point)))
 702
 703 (defcustom company-global-modes t
 704   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 705 If nil, means no modes.  If t, then all major modes have it turned on.
 706 If a list, it should be a list of `major-mode' symbol names for which
 707 `company-mode' should be automatically turned on.  The sense of the list is
 708 negated if it begins with `not'.  For example:
 709  (c-mode c++-mode)
 710 means that `company-mode' is turned on for buffers in C and C++ modes only.
 711  (not message-mode)
 712 means that `company-mode' is always turned on except in `message-mode' buffers."
 713   :type '(choice (const :tag "none" nil)
 714                  (const :tag "all" t)
 715                  (set :menu-tag "mode specific" :tag "modes"
 716                       :value (not)
 717                       (const :tag "Except" not)
 718                       (repeat :inline t (symbol :tag "mode")))))
 719
 720 ;;;###autoload
 721 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 722
 723 (defun company-mode-on ()
 724   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 725              (cond ((eq company-global-modes t)
 726                     t)
 727                    ((eq (car-safe company-global-modes) 'not)
 728                     (not (memq major-mode (cdr company-global-modes))))
 729                    (t (memq major-mode company-global-modes))))
 730     (company-mode 1)))
 731
 732 (defsubst company-assert-enabled ()
 733   (unless company-mode
 734     (company-uninstall-map)
 735     (error "Company not enabled")))
 736
 737 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 738
 739 (defvar-local company-my-keymap nil)
 740
 741 (defvar company-emulation-alist '((t . nil)))
 742
 743 (defsubst company-enable-overriding-keymap (keymap)
 744   (company-uninstall-map)
 745   (setq company-my-keymap keymap))
 746
 747 (defun company-ensure-emulation-alist ()
 748   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 749     (setq emulation-mode-map-alists
 750           (cons 'company-emulation-alist
 751                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 752
 753 (defun company-install-map ()
 754   (unless (or (cdar company-emulation-alist)
 755               (null company-my-keymap))
 756     (setf (cdar company-emulation-alist) company-my-keymap)))
 757
 758 (defun company-uninstall-map ()
 759   (setf (cdar company-emulation-alist) nil))
 760
 761 ;; Hack:
 762 ;; Emacs calculates the active keymaps before reading the event.  That means we
 763 ;; cannot change the keymap from a timer.  So we send a bogus command.
 764 ;; XXX: Even in Emacs 24.4, seems to be needed in the terminal.
 765 (defun company-ignore ()
 766   (interactive)
 767   (setq this-command last-command))
 768
 769 (global-set-key '[31415926] 'company-ignore)
 770
 771 (defun company-input-noop ()
 772   (push 31415926 unread-command-events))
 773
 774 (defun company--posn-col-row (posn)
 775   (let ((col (car (posn-col-row posn)))
 776         ;; `posn-col-row' doesn't work well with lines of different height.
 777         ;; `posn-actual-col-row' doesn't handle multiple-width characters.
 778         (row (cdr (posn-actual-col-row posn))))
 779     (when (and header-line-format (version< emacs-version "24.3.93.3"))
 780       ;; http://debbugs.gnu.org/18384
 781       (cl-decf row))
 782     (cons (+ col (window-hscroll)) row)))
 783
 784 (defun company--col-row (&optional pos)
 785   (company--posn-col-row (posn-at-point pos)))
 786
 787 (defun company--row (&optional pos)
 788   (cdr (company--col-row pos)))
 789
 790 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 791
 792 (defvar-local company-backend nil)
 793
 794 (defun company-grab (regexp &optional expression limit)
 795   (when (looking-back regexp limit)
 796     (or (match-string-no-properties (or expression 0)) "")))
 797
 798 (defun company-grab-line (regexp &optional expression)
 799   (company-grab regexp expression (point-at-bol)))
 800
 801 (defun company-grab-symbol ()
 802   (if (looking-at "\\_>")
 803       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 804                                                 (point)))
 805     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 806       "")))
 807
 808 (defun company-grab-word ()
 809   (if (looking-at "\\>")
 810       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 811                                                 (point)))
 812     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 813       "")))
 814
 815 (defun company-grab-symbol-cons (idle-begin-after-re &optional max-len)
 816   (let ((symbol (company-grab-symbol)))
 817     (when symbol
 818       (save-excursion
 819         (forward-char (- (length symbol)))
 820         (if (looking-back idle-begin-after-re (if max-len
 821                                                   (- (point) max-len)
 822                                                 (line-beginning-position)))
 823             (cons symbol t)
 824           symbol)))))
 825
 826 (defun company-in-string-or-comment ()
 827   (let ((ppss (syntax-ppss)))
 828     (or (car (setq ppss (nthcdr 3 ppss)))
 829         (car (setq ppss (cdr ppss)))
 830         (nth 3 ppss))))
 831
 832 (defun company-call-backend (&rest args)
 833   (company--force-sync #'company-call-backend-raw args company-backend))
 834
 835 (defun company--force-sync (fun args backend)
 836   (let ((value (apply fun args)))
 837     (if (not (eq (car-safe value) :async))
 838         value
 839       (let ((res 'trash)
 840             (start (time-to-seconds)))
 841         (funcall (cdr value)
 842                  (lambda (result) (setq res result)))
 843         (while (eq res 'trash)
 844           (if (> (- (time-to-seconds) start) company-async-timeout)
 845               (error "Company: Back-end %s async timeout with args %s"
 846                      backend args)
 847             (sleep-for company-async-wait)))
 848         res))))
 849
 850 (defun company-call-backend-raw (&rest args)
 851   (condition-case err
 852       (if (functionp company-backend)
 853           (apply company-backend args)
 854         (apply #'company--multi-backend-adapter company-backend args))
 855     (error (error "Company: Back-end %s error \"%s\" with args %s"
 856                   company-backend (error-message-string err) args))))
 857
 858 (defun company--multi-backend-adapter (backends command &rest args)
 859   (let ((backends (cl-loop for b in backends
 860                            when (not (and (symbolp b)
 861                                           (eq 'failed (get b 'company-init))))
 862                            collect b)))
 863     (setq backends
 864           (if (eq command 'prefix)
 865               (butlast backends (length (member :with backends)))
 866             (delq :with backends)))
 867     (pcase command
 868       (`candidates
 869        (company--multi-backend-adapter-candidates backends (car args)))
 870       (`sorted nil)
 871       (`duplicates t)
 872       ((or `prefix `ignore-case `no-cache `require-match)
 873        (let (value)
 874          (cl-dolist (backend backends)
 875            (when (setq value (company--force-sync
 876                               backend (cons command args) backend))
 877              (cl-return value)))))
 878       (_
 879        (let ((arg (car args)))
 880          (when (> (length arg) 0)
 881            (let ((backend (or (get-text-property 0 'company-backend arg)
 882                               (car backends))))
 883              (apply backend command args))))))))
 884
 885 (defun company--multi-backend-adapter-candidates (backends prefix)
 886   (let ((pairs (cl-loop for backend in (cdr backends)
 887                         when (equal (company--prefix-str
 888                                      (funcall backend 'prefix))
 889                                     prefix)
 890                         collect (cons (funcall backend 'candidates prefix)
 891                                       (let ((b backend))
 892                                         (lambda (candidates)
 893                                           (mapcar
 894                                            (lambda (str)
 895                                              (propertize str 'company-backend b))
 896                                            candidates)))))))
 897     (when (equal (company--prefix-str (funcall (car backends) 'prefix)) prefix)
 898       ;; Small perf optimization: don't tag the candidates received
 899       ;; from the first backend in the group.
 900       (push (cons (funcall (car backends) 'candidates prefix)
 901                   'identity)
 902             pairs))
 903     (company--merge-async pairs (lambda (values) (apply #'append values)))))
 904
 905 (defun company--merge-async (pairs merger)
 906   (let ((async (cl-loop for pair in pairs
 907                         thereis
 908                         (eq :async (car-safe (car pair))))))
 909     (if (not async)
 910         (funcall merger (cl-loop for (val . mapper) in pairs
 911                                  collect (funcall mapper val)))
 912       (cons
 913        :async
 914        (lambda (callback)
 915          (let* (lst pending
 916                 (finisher (lambda ()
 917                             (unless pending
 918                               (funcall callback
 919                                        (funcall merger
 920                                                 (nreverse lst)))))))
 921            (dolist (pair pairs)
 922              (let ((val (car pair))
 923                    (mapper (cdr pair)))
 924                (if (not (eq :async (car-safe val)))
 925                    (push (funcall mapper val) lst)
 926                  (push nil lst)
 927                  (let ((cell lst)
 928                        (fetcher (cdr val)))
 929                    (push fetcher pending)
 930                    (funcall fetcher
 931                             (lambda (res)
 932                               (setq pending (delq fetcher pending))
 933                               (setcar cell (funcall mapper res))
 934                               (funcall finisher)))))))))))))
 935
 936 (defun company--prefix-str (prefix)
 937   (or (car-safe prefix) prefix))
 938
 939 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 940
 941 (defvar-local company-prefix nil)
 942
 943 (defvar-local company-candidates nil)
 944
 945 (defvar-local company-candidates-length nil)
 946
 947 (defvar-local company-candidates-cache nil)
 948
 949 (defvar-local company-candidates-predicate nil)
 950
 951 (defvar-local company-common nil)
 952
 953 (defvar-local company-selection 0)
 954
 955 (defvar-local company-selection-changed nil)
 956
 957 (defvar-local company--manual-action nil
 958   "Non-nil, if manual completion took place.")
 959
 960 (defvar-local company--manual-prefix nil)
 961
 962 (defvar company--auto-completion nil
 963   "Non-nil when current candidate is being inserted automatically.
 964 Controlled by `company-auto-complete'.")
 965
 966 (defvar-local company--point-max nil)
 967
 968 (defvar-local company-point nil)
 969
 970 (defvar company-timer nil)
 971
 972 (defsubst company-strip-prefix (str)
 973   (substring str (length company-prefix)))
 974
 975 (defun company--insert-candidate (candidate)
 976   (setq candidate (substring-no-properties candidate))
 977   ;; XXX: Return value we check here is subject to change.
 978   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 979       (insert (company-strip-prefix candidate))
 980     (delete-region (- (point) (length company-prefix)) (point))
 981     (insert candidate)))
 982
 983 (defmacro company-with-candidate-inserted (candidate &rest body)
 984   "Evaluate BODY with CANDIDATE temporarily inserted.
 985 This is a tool for back-ends that need candidates inserted before they
 986 can retrieve meta-data for them."
 987   (declare (indent 1))
 988   `(let ((inhibit-modification-hooks t)
 989          (inhibit-point-motion-hooks t)
 990          (modified-p (buffer-modified-p)))
 991      (company--insert-candidate ,candidate)
 992      (unwind-protect
 993          (progn ,@body)
 994        (delete-region company-point (point))
 995        (set-buffer-modified-p modified-p))))
 996
 997 (defun company-explicit-action-p ()
 998   "Return whether explicit completion action was taken by the user."
 999   (or company--manual-action
1000       company-selection-changed))
1001
1002 (defun company-reformat (candidate)
1003   ;; company-ispell needs this, because the results are always lower-case
1004   ;; It's mory efficient to fix it only when they are displayed.
1005   ;; FIXME: Adopt the current text's capitalization instead?
1006   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
1007       (concat company-prefix (substring candidate (length company-prefix)))
1008     candidate))
1009
1010 (defun company--should-complete ()
1011   (and (eq company-idle-delay 'now)
1012        (not (or buffer-read-only overriding-terminal-local-map
1013                 overriding-local-map))
1014        ;; Check if in the middle of entering a key combination.
1015        (or (equal (this-command-keys-vector) [])
1016            (not (keymapp (key-binding (this-command-keys-vector)))))
1017        (not (and transient-mark-mode mark-active))))
1018
1019 (defun company--should-continue ()
1020   (or (eq t company-begin-commands)
1021       (eq t company-continue-commands)
1022       (if (eq 'not (car company-continue-commands))
1023           (not (memq this-command (cdr company-continue-commands)))
1024         (or (memq this-command company-begin-commands)
1025             (memq this-command company-continue-commands)
1026             (and (symbolp this-command)
1027                  (string-match-p "\\`company-" (symbol-name this-command)))))))
1028
1029 (defun company-call-frontends (command)
1030   (dolist (frontend company-frontends)
1031     (condition-case err
1032         (funcall frontend command)
1033       (error (error "Company: Front-end %s error \"%s\" on command %s"
1034                     frontend (error-message-string err) command)))))
1035
1036 (defun company-set-selection (selection &optional force-update)
1037   (setq selection
1038         (if company-selection-wrap-around
1039             (mod selection company-candidates-length)
1040           (max 0 (min (1- company-candidates-length) selection))))
1041   (when (or force-update (not (equal selection company-selection)))
1042     (company--update-group-lighter (nth selection company-candidates))
1043     (setq company-selection selection
1044           company-selection-changed t)
1045     (company-call-frontends 'update)))
1046
1047 (defun company--update-group-lighter (candidate)
1048   (when (listp company-backend)
1049     (let ((backend (or (get-text-property 0 'company-backend candidate)
1050                        (car company-backend))))
1051       (when (and backend (symbolp backend))
1052         (let ((name (replace-regexp-in-string "company-\\|-company" ""
1053                                               (symbol-name backend))))
1054           (setq company-lighter (format " company-<%s>" name)))))))
1055
1056 (defun company-apply-predicate (candidates predicate)
1057   (let (new)
1058     (dolist (c candidates)
1059       (when (funcall predicate c)
1060         (push c new)))
1061     (nreverse new)))
1062
1063 (defun company-update-candidates (candidates)
1064   (setq company-candidates-length (length candidates))
1065   (if (> company-selection 0)
1066       ;; Try to restore the selection
1067       (let ((selected (nth company-selection company-candidates)))
1068         (setq company-selection 0
1069               company-candidates candidates)
1070         (when selected
1071           (while (and candidates (string< (pop candidates) selected))
1072             (cl-incf company-selection))
1073           (unless candidates
1074             ;; Make sure selection isn't out of bounds.
1075             (setq company-selection (min (1- company-candidates-length)
1076                                          company-selection)))))
1077     (setq company-selection 0
1078           company-candidates candidates))
1079   ;; Save in cache:
1080   (push (cons company-prefix company-candidates) company-candidates-cache)
1081   ;; Calculate common.
1082   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
1083     ;; We want to support non-prefix completion, so filtering is the
1084     ;; responsibility of each respective backend, not ours.
1085     ;; On the other hand, we don't want to replace non-prefix input in
1086     ;; `company-complete-common'.
1087     (setq company-common
1088           (if (cdr company-candidates)
1089               (let ((common (try-completion company-prefix company-candidates)))
1090                 (if (eq common t)
1091                     ;; Mulple equal strings, probably with different
1092                     ;; annotations.
1093                     company-prefix
1094                   common))
1095             (car company-candidates)))))
1096
1097 (defun company-calculate-candidates (prefix)
1098   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
1099         (ignore-case (company-call-backend 'ignore-case)))
1100     (or candidates
1101         (when company-candidates-cache
1102           (let ((len (length prefix))
1103                 (completion-ignore-case ignore-case)
1104                 prev)
1105             (cl-dotimes (i (1+ len))
1106               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1107                                            company-candidates-cache)))
1108                 (setq candidates (all-completions prefix prev))
1109                 (cl-return t)))))
1110         ;; no cache match, call back-end
1111         (setq candidates
1112               (company--process-candidates
1113                (company--fetch-candidates prefix))))
1114     (setq candidates (company--transform-candidates candidates))
1115     (when candidates
1116       (if (or (cdr candidates)
1117               (not (eq t (compare-strings (car candidates) nil nil
1118                                           prefix nil nil ignore-case))))
1119           candidates
1120         ;; Already completed and unique; don't start.
1121         t))))
1122
1123 (defun company--fetch-candidates (prefix)
1124   (let ((c (if company--manual-action
1125                (company-call-backend 'candidates prefix)
1126              (company-call-backend-raw 'candidates prefix)))
1127         res)
1128     (if (not (eq (car c) :async))
1129         c
1130       (let ((buf (current-buffer))
1131             (win (selected-window))
1132             (tick (buffer-chars-modified-tick))
1133             (pt (point))
1134             (backend company-backend))
1135         (funcall
1136          (cdr c)
1137          (lambda (candidates)
1138            (if (not (and candidates (eq res 'done)))
1139                ;; Fetcher called us back right away.
1140                (setq res candidates)
1141              (setq company-backend backend
1142                    company-candidates-cache
1143                    (list (cons prefix
1144                                (company--process-candidates
1145                                 candidates))))
1146              (company-idle-begin buf win tick pt)))))
1147       ;; FIXME: Relying on the fact that the callers
1148       ;; will interpret nil as "do nothing" is shaky.
1149       ;; A throw-catch would be one possible improvement.
1150       (or res
1151           (progn (setq res 'done) nil)))))
1152
1153 (defun company--process-candidates (candidates)
1154   (when company-candidates-predicate
1155     (setq candidates
1156           (company-apply-predicate candidates
1157                                    company-candidates-predicate)))
1158   (unless (company-call-backend 'sorted)
1159     (setq candidates (sort candidates 'string<)))
1160   (when (company-call-backend 'duplicates)
1161     (company--strip-duplicates candidates))
1162   candidates)
1163
1164 (defun company--strip-duplicates (candidates)
1165   (let ((c2 candidates))
1166     (while c2
1167       (setcdr c2
1168               (let ((str (car c2))
1169                     (anno 'unk))
1170                 (pop c2)
1171                 (while (let ((str2 (car c2)))
1172                          (if (not (equal str str2))
1173                              nil
1174                            (when (eq anno 'unk)
1175                              (setq anno (company-call-backend
1176                                          'annotation str)))
1177                            (equal anno
1178                                   (company-call-backend
1179                                    'annotation str2))))
1180                   (pop c2))
1181                 c2)))))
1182
1183 (defun company--transform-candidates (candidates)
1184   (let ((c candidates))
1185     (dolist (tr company-transformers)
1186       (setq c (funcall tr c)))
1187     c))
1188
1189 (defcustom company-occurrence-weight-function
1190   #'company-occurrence-prefer-closest-above
1191   "Function to weigh matches in `company-sort-by-occurrence'.
1192 It's called with three arguments: cursor position, the beginning and the
1193 end of the match."
1194   :type '(choice
1195           (const :tag "First above point, then below point"
1196                  company-occurrence-prefer-closest-above)
1197           (const :tag "Prefer closest in any direction"
1198                  company-occurrence-prefer-any-closest)))
1199
1200 (defun company-occurrence-prefer-closest-above (pos match-beg match-end)
1201   "Give priority to the matches above point, then those below point."
1202   (if (< match-beg pos)
1203       (- pos match-end)
1204     (- match-beg (window-start))))
1205
1206 (defun company-occurrence-prefer-any-closest (pos _match-beg match-end)
1207   "Give priority to the matches closest to the point."
1208   (abs (- pos match-end)))
1209
1210 (defun company-sort-by-occurrence (candidates)
1211   "Sort CANDIDATES according to their occurrences.
1212 Searches for each in the currently visible part of the current buffer and
1213 prioritizes the matches according to `company-occurrence-weight-function'.
1214 The rest of the list is appended unchanged.
1215 Keywords and function definition names are ignored."
1216   (let* ((w-start (window-start))
1217          (w-end (window-end))
1218          (start-point (point))
1219          occurs
1220          (noccurs
1221           (save-excursion
1222             (cl-delete-if
1223              (lambda (candidate)
1224                (when (catch 'done
1225                        (goto-char w-start)
1226                        (while (search-forward candidate w-end t)
1227                          (when (and (not (eq (point) start-point))
1228                                     (save-match-data
1229                                       (company--occurrence-predicate)))
1230                            (throw 'done t))))
1231                  (push
1232                   (cons candidate
1233                         (funcall company-occurrence-weight-function
1234                                  start-point
1235                                  (match-beginning 0)
1236                                  (match-end 0)))
1237                   occurs)
1238                  t))
1239              candidates))))
1240     (nconc
1241      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1242      noccurs)))
1243
1244 (defun company--occurrence-predicate ()
1245   (let ((beg (match-beginning 0))
1246         (end (match-end 0)))
1247     (save-excursion
1248       (goto-char end)
1249       (and (not (memq (get-text-property (1- (point)) 'face)
1250                       '(font-lock-function-name-face
1251                         font-lock-keyword-face)))
1252            (let ((prefix (company--prefix-str
1253                           (company-call-backend 'prefix))))
1254              (and (stringp prefix)
1255                   (= (length prefix) (- end beg))))))))
1256
1257 (defun company-sort-by-backend-importance (candidates)
1258   "Sort CANDIDATES as two priority groups.
1259 If `company-backend' is a function, do nothing.  If it's a list, move
1260 candidates from back-ends before keyword `:with' to the front.  Candidates
1261 from the rest of the back-ends in the group, if any, will be left at the end."
1262   (if (functionp company-backend)
1263       candidates
1264     (let ((low-priority (cdr (memq :with company-backend))))
1265       (if (null low-priority)
1266           candidates
1267         (sort candidates
1268               (lambda (c1 c2)
1269                 (and
1270                  (let ((b2 (get-text-property 0 'company-backend c2)))
1271                    (and b2 (memq b2 low-priority)))
1272                  (let ((b1 (get-text-property 0 'company-backend c1)))
1273                    (or (not b1) (not (memq b1 low-priority)))))))))))
1274
1275 (defun company-idle-begin (buf win tick pos)
1276   (and (eq buf (current-buffer))
1277        (eq win (selected-window))
1278        (eq tick (buffer-chars-modified-tick))
1279        (eq pos (point))
1280        (when (company-auto-begin)
1281          (company-input-noop)
1282          (company-post-command))))
1283
1284 (defun company-auto-begin ()
1285   (and company-mode
1286        (not company-candidates)
1287        (let ((company-idle-delay 'now))
1288          (condition-case-unless-debug err
1289              (company--perform)
1290            (error (message "Company: An error occurred in auto-begin")
1291                   (message "%s" (error-message-string err))
1292                   (company-cancel))
1293            (quit (company-cancel)))))
1294   (unless company-candidates
1295     (setq company-backend nil))
1296   ;; Return non-nil if active.
1297   company-candidates)
1298
1299 (defun company-manual-begin ()
1300   (interactive)
1301   (company-assert-enabled)
1302   (setq company--manual-action t)
1303   (unwind-protect
1304       (let ((company-minimum-prefix-length 0))
1305         (company-auto-begin))
1306     (unless company-candidates
1307       (setq company--manual-action nil))))
1308
1309 (defun company-other-backend (&optional backward)
1310   (interactive (list current-prefix-arg))
1311   (company-assert-enabled)
1312   (let* ((after (if company-backend
1313                     (cdr (member company-backend company-backends))
1314                   company-backends))
1315          (before (cdr (member company-backend (reverse company-backends))))
1316          (next (if backward
1317                    (append before (reverse after))
1318                  (append after (reverse before)))))
1319     (company-cancel)
1320     (cl-dolist (backend next)
1321       (when (ignore-errors (company-begin-backend backend))
1322         (cl-return t))))
1323   (unless company-candidates
1324     (error "No other back-end")))
1325
1326 (defun company-require-match-p ()
1327   (let ((backend-value (company-call-backend 'require-match)))
1328     (or (eq backend-value t)
1329         (and (not (eq backend-value 'never))
1330              (if (functionp company-require-match)
1331                  (funcall company-require-match)
1332                (eq company-require-match t))))))
1333
1334 (defun company-auto-complete-p (input)
1335   "Return non-nil, if input starts with punctuation or parentheses."
1336   (and (if (functionp company-auto-complete)
1337            (funcall company-auto-complete)
1338          company-auto-complete)
1339        (if (functionp company-auto-complete-chars)
1340            (funcall company-auto-complete-chars input)
1341          (if (consp company-auto-complete-chars)
1342              (memq (char-syntax (string-to-char input))
1343                    company-auto-complete-chars)
1344            (string-match (substring input 0 1) company-auto-complete-chars)))))
1345
1346 (defun company--incremental-p ()
1347   (and (> (point) company-point)
1348        (> (point-max) company--point-max)
1349        (not (eq this-command 'backward-delete-char-untabify))
1350        (equal (buffer-substring (- company-point (length company-prefix))
1351                                 company-point)
1352               company-prefix)))
1353
1354 (defun company--continue-failed (new-prefix)
1355   (let ((input (buffer-substring-no-properties (point) company-point)))
1356     (cond
1357      ((company-auto-complete-p input)
1358       ;; auto-complete
1359       (save-excursion
1360         (goto-char company-point)
1361         (let ((company--auto-completion t))
1362           (company-complete-selection))
1363         nil))
1364      ((and (or (not (company-require-match-p))
1365                ;; Don't require match if the new prefix
1366                ;; doesn't continue the old one, and the latter was a match.
1367                (<= (length new-prefix) (length company-prefix)))
1368            (member company-prefix company-candidates))
1369       ;; Last input was a success,
1370       ;; but we're treating it as an abort + input anyway,
1371       ;; like the `unique' case below.
1372       (company-cancel 'non-unique))
1373      ((company-require-match-p)
1374       ;; Wrong incremental input, but required match.
1375       (delete-char (- (length input)))
1376       (ding)
1377       (message "Matching input is required")
1378       company-candidates)
1379      (t (company-cancel)))))
1380
1381 (defun company--good-prefix-p (prefix)
1382   (and (stringp (company--prefix-str prefix)) ;excludes 'stop
1383        (or (eq (cdr-safe prefix) t)
1384            (let ((len (or (cdr-safe prefix) (length prefix))))
1385              (if company--manual-prefix
1386                  (or (not company-abort-manual-when-too-short)
1387                      ;; Must not be less than minimum or initial length.
1388                      (>= len (min company-minimum-prefix-length
1389                                   (length company--manual-prefix))))
1390                (>= len company-minimum-prefix-length))))))
1391
1392 (defun company--continue ()
1393   (when (company-call-backend 'no-cache company-prefix)
1394     ;; Don't complete existing candidates, fetch new ones.
1395     (setq company-candidates-cache nil))
1396   (let* ((new-prefix (company-call-backend 'prefix))
1397          (c (when (and (company--good-prefix-p new-prefix)
1398                        (setq new-prefix (company--prefix-str new-prefix))
1399                        (= (- (point) (length new-prefix))
1400                           (- company-point (length company-prefix))))
1401               (company-calculate-candidates new-prefix))))
1402     (cond
1403      ((eq c t)
1404       ;; t means complete/unique.
1405       ;; Handle it like completion was aborted, to differentiate from user
1406       ;; calling one of Company's commands to insert the candidate,
1407       ;; not to trigger template expansion, etc.
1408       (company-cancel 'unique))
1409      ((consp c)
1410       ;; incremental match
1411       (setq company-prefix new-prefix)
1412       (company-update-candidates c)
1413       c)
1414      ((not (company--incremental-p))
1415       (company-cancel))
1416      (t (company--continue-failed new-prefix)))))
1417
1418 (defun company--begin-new ()
1419   (let (prefix c)
1420     (cl-dolist (backend (if company-backend
1421                             ;; prefer manual override
1422                             (list company-backend)
1423                           company-backends))
1424       (setq prefix
1425             (if (or (symbolp backend)
1426                     (functionp backend))
1427                 (when (or (not (symbolp backend))
1428                           (eq t (get backend 'company-init))
1429                           (unless (get backend 'company-init)
1430                             (company-init-backend backend)))
1431                   (funcall backend 'prefix))
1432               (company--multi-backend-adapter backend 'prefix)))
1433       (when prefix
1434         (when (company--good-prefix-p prefix)
1435           (setq company-prefix (company--prefix-str prefix)
1436                 company-backend backend
1437                 c (company-calculate-candidates company-prefix))
1438           ;; t means complete/unique.  We don't start, so no hooks.
1439           (if (not (consp c))
1440               (when company--manual-action
1441                 (message "No completion found"))
1442             (when company--manual-action
1443               (setq company--manual-prefix prefix))
1444             (if (symbolp backend)
1445                 (setq company-lighter (concat " " (symbol-name backend)))
1446               (company--update-group-lighter (car c)))
1447             (company-update-candidates c)
1448             (run-hook-with-args 'company-completion-started-hook
1449                                 (company-explicit-action-p))
1450             (company-call-frontends 'show)))
1451         (cl-return c)))))
1452
1453 (defun company--perform ()
1454   (or (and company-candidates (company--continue))
1455       (and (company--should-complete) (company--begin-new)))
1456   (when company-candidates
1457     (setq company-point (point)
1458           company--point-max (point-max))
1459     (company-ensure-emulation-alist)
1460     (company-enable-overriding-keymap company-active-map)
1461     (company-call-frontends 'update)))
1462
1463 (defun company-cancel (&optional result)
1464   (unwind-protect
1465       (when company-prefix
1466         (if (stringp result)
1467             (progn
1468               (company-call-backend 'pre-completion result)
1469               (run-hook-with-args 'company-completion-finished-hook result)
1470               (company-call-backend 'post-completion result))
1471           (run-hook-with-args 'company-completion-cancelled-hook result)))
1472     (setq company-backend nil
1473           company-prefix nil
1474           company-candidates nil
1475           company-candidates-length nil
1476           company-candidates-cache nil
1477           company-candidates-predicate nil
1478           company-common nil
1479           company-selection 0
1480           company-selection-changed nil
1481           company--manual-action nil
1482           company--manual-prefix nil
1483           company-lighter company-default-lighter
1484           company--point-max nil
1485           company-point nil)
1486     (when company-timer
1487       (cancel-timer company-timer))
1488     (company-search-mode 0)
1489     (company-call-frontends 'hide)
1490     (company-enable-overriding-keymap nil))
1491   ;; Make return value explicit.
1492   nil)
1493
1494 (defun company-abort ()
1495   (interactive)
1496   (company-cancel 'abort))
1497
1498 (defun company-finish (result)
1499   (company--insert-candidate result)
1500   (company-cancel result))
1501
1502 (defsubst company-keep (command)
1503   (and (symbolp command) (get command 'company-keep)))
1504
1505 (defun company-pre-command ()
1506   (unless (company-keep this-command)
1507     (condition-case err
1508         (when company-candidates
1509           (company-call-frontends 'pre-command)
1510           (unless (company--should-continue)
1511             (company-abort)))
1512       (error (message "Company: An error occurred in pre-command")
1513              (message "%s" (error-message-string err))
1514              (company-cancel))))
1515   (when company-timer
1516     (cancel-timer company-timer)
1517     (setq company-timer nil))
1518   (company-uninstall-map))
1519
1520 (defun company-post-command ()
1521   (unless (company-keep this-command)
1522     (condition-case err
1523         (progn
1524           (unless (equal (point) company-point)
1525             (let (company-idle-delay) ; Against misbehavior while debugging.
1526               (company--perform)))
1527           (if company-candidates
1528               (company-call-frontends 'post-command)
1529             (and (numberp company-idle-delay)
1530                  (company--should-begin)
1531                  (setq company-timer
1532                        (run-with-timer company-idle-delay nil
1533                                        'company-idle-begin
1534                                        (current-buffer) (selected-window)
1535                                        (buffer-chars-modified-tick) (point))))))
1536       (error (message "Company: An error occurred in post-command")
1537              (message "%s" (error-message-string err))
1538              (company-cancel))))
1539   (company-install-map))
1540
1541 (defvar company--begin-inhibit-commands '(company-abort
1542                                           company-complete-mouse
1543                                           company-complete
1544                                           company-complete-common
1545                                           company-complete-selection
1546                                           company-complete-number)
1547   "List of commands after which idle completion is (still) disabled when
1548 `company-begin-commands' is t.")
1549
1550 (defun company--should-begin ()
1551   (if (eq t company-begin-commands)
1552       (not (memq this-command company--begin-inhibit-commands))
1553     (or
1554      (memq this-command company-begin-commands)
1555      (and (symbolp this-command) (get this-command 'company-begin)))))
1556
1557 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1558
1559 (defvar-local company-search-string nil)
1560
1561 (defvar-local company-search-lighter " Search: \"\"")
1562
1563 (defvar-local company-search-old-map nil)
1564
1565 (defvar-local company-search-old-selection 0)
1566
1567 (defun company-search (text lines)
1568   (let ((quoted (regexp-quote text))
1569         (i 0))
1570     (cl-dolist (line lines)
1571       (when (string-match quoted line (length company-prefix))
1572         (cl-return i))
1573       (cl-incf i))))
1574
1575 (defun company-search-printing-char ()
1576   (interactive)
1577   (company-search-assert-enabled)
1578   (let* ((ss (concat company-search-string (string last-command-event)))
1579          (pos (company-search ss (nthcdr company-selection company-candidates))))
1580     (if (null pos)
1581         (ding)
1582       (setq company-search-string ss
1583             company-search-lighter (concat " Search: \"" ss "\""))
1584       (company-set-selection (+ company-selection pos) t))))
1585
1586 (defun company-search-repeat-forward ()
1587   "Repeat the incremental search in completion candidates forward."
1588   (interactive)
1589   (company-search-assert-enabled)
1590   (let ((pos (company-search company-search-string
1591                              (cdr (nthcdr company-selection
1592                                           company-candidates)))))
1593     (if (null pos)
1594         (ding)
1595       (company-set-selection (+ company-selection pos 1) t))))
1596
1597 (defun company-search-repeat-backward ()
1598   "Repeat the incremental search in completion candidates backwards."
1599   (interactive)
1600   (company-search-assert-enabled)
1601   (let ((pos (company-search company-search-string
1602                              (nthcdr (- company-candidates-length
1603                                         company-selection)
1604                                      (reverse company-candidates)))))
1605     (if (null pos)
1606         (ding)
1607       (company-set-selection (- company-selection pos 1) t))))
1608
1609 (defun company-create-match-predicate ()
1610   (setq company-candidates-predicate
1611         `(lambda (candidate)
1612            ,(if company-candidates-predicate
1613                 `(and (string-match ,company-search-string candidate)
1614                       (funcall ,company-candidates-predicate
1615                                candidate))
1616               `(string-match ,company-search-string candidate))))
1617   (company-update-candidates
1618    (company-apply-predicate company-candidates company-candidates-predicate))
1619   ;; Invalidate cache.
1620   (setq company-candidates-cache (cons company-prefix company-candidates)))
1621
1622 (defun company-filter-printing-char ()
1623   (interactive)
1624   (company-search-assert-enabled)
1625   (company-search-printing-char)
1626   (company-create-match-predicate)
1627   (company-call-frontends 'update))
1628
1629 (defun company-search-kill-others ()
1630   "Limit the completion candidates to the ones matching the search string."
1631   (interactive)
1632   (company-search-assert-enabled)
1633   (company-create-match-predicate)
1634   (company-search-mode 0)
1635   (company-call-frontends 'update))
1636
1637 (defun company-search-abort ()
1638   "Abort searching the completion candidates."
1639   (interactive)
1640   (company-search-assert-enabled)
1641   (company-set-selection company-search-old-selection t)
1642   (company-search-mode 0))
1643
1644 (defun company-search-other-char ()
1645   (interactive)
1646   (company-search-assert-enabled)
1647   (company-search-mode 0)
1648   (company--unread-last-input))
1649
1650 (defvar company-search-map
1651   (let ((i 0)
1652         (keymap (make-keymap)))
1653     (if (fboundp 'max-char)
1654         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1655                               'company-search-printing-char)
1656       (with-no-warnings
1657         ;; obsolete in Emacs 23
1658         (let ((l (generic-character-list))
1659               (table (nth 1 keymap)))
1660           (while l
1661             (set-char-table-default table (car l) 'company-search-printing-char)
1662             (setq l (cdr l))))))
1663     (define-key keymap [t] 'company-search-other-char)
1664     (while (< i ?\s)
1665       (define-key keymap (make-string 1 i) 'company-search-other-char)
1666       (cl-incf i))
1667     (while (< i 256)
1668       (define-key keymap (vector i) 'company-search-printing-char)
1669       (cl-incf i))
1670     (let ((meta-map (make-sparse-keymap)))
1671       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1672       (define-key keymap [escape] meta-map))
1673     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1674     (define-key keymap "\e\e\e" 'company-search-other-char)
1675     (define-key keymap [escape escape escape] 'company-search-other-char)
1676     (define-key keymap (kbd "DEL") 'company-search-other-char)
1677
1678     (define-key keymap "\C-g" 'company-search-abort)
1679     (define-key keymap "\C-s" 'company-search-repeat-forward)
1680     (define-key keymap "\C-r" 'company-search-repeat-backward)
1681     (define-key keymap "\C-o" 'company-search-kill-others)
1682     keymap)
1683   "Keymap used for incrementally searching the completion candidates.")
1684
1685 (define-minor-mode company-search-mode
1686   "Search mode for completion candidates.
1687 Don't start this directly, use `company-search-candidates' or
1688 `company-filter-candidates'."
1689   nil company-search-lighter nil
1690   (if company-search-mode
1691       (if (company-manual-begin)
1692           (progn
1693             (setq company-search-old-selection company-selection)
1694             (company-call-frontends 'update))
1695         (setq company-search-mode nil))
1696     (kill-local-variable 'company-search-string)
1697     (kill-local-variable 'company-search-lighter)
1698     (kill-local-variable 'company-search-old-selection)
1699     (company-enable-overriding-keymap company-active-map)))
1700
1701 (defun company-search-assert-enabled ()
1702   (company-assert-enabled)
1703   (unless company-search-mode
1704     (company-uninstall-map)
1705     (error "Company not in search mode")))
1706
1707 (defun company-search-candidates ()
1708   "Start searching the completion candidates incrementally.
1709
1710 \\<company-search-map>Search can be controlled with the commands:
1711 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1712 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1713 - `company-search-abort' (\\[company-search-abort])
1714
1715 Regular characters are appended to the search string.
1716
1717 The command `company-search-kill-others' (\\[company-search-kill-others])
1718 uses the search string to limit the completion candidates."
1719   (interactive)
1720   (company-search-mode 1)
1721   (company-enable-overriding-keymap company-search-map))
1722
1723 (defvar company-filter-map
1724   (let ((keymap (make-keymap)))
1725     (define-key keymap [remap company-search-printing-char]
1726       'company-filter-printing-char)
1727     (set-keymap-parent keymap company-search-map)
1728     keymap)
1729   "Keymap used for incrementally searching the completion candidates.")
1730
1731 (defun company-filter-candidates ()
1732   "Start filtering the completion candidates incrementally.
1733 This works the same way as `company-search-candidates' immediately
1734 followed by `company-search-kill-others' after each input."
1735   (interactive)
1736   (company-search-mode 1)
1737   (company-enable-overriding-keymap company-filter-map))
1738
1739 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1740
1741 (defun company-select-next ()
1742   "Select the next candidate in the list."
1743   (interactive)
1744   (when (company-manual-begin)
1745     (company-set-selection (1+ company-selection))))
1746
1747 (defun company-select-previous ()
1748   "Select the previous candidate in the list."
1749   (interactive)
1750   (when (company-manual-begin)
1751     (company-set-selection (1- company-selection))))
1752
1753 (defun company-select-next-or-abort ()
1754   "Select the next candidate if more than one, else abort
1755 and invoke the normal binding."
1756   (interactive)
1757   (if (> company-candidates-length 1)
1758       (company-select-next)
1759     (company-abort)
1760     (company--unread-last-input)))
1761
1762 (defun company-select-previous-or-abort ()
1763   "Select the previous candidate if more than one, else abort
1764 and invoke the normal binding."
1765   (interactive)
1766   (if (> company-candidates-length 1)
1767       (company-select-previous)
1768     (company-abort)
1769     (company--unread-last-input)))
1770
1771 (defvar company-pseudo-tooltip-overlay)
1772
1773 (defvar company-tooltip-offset)
1774
1775 (defun company--inside-tooltip-p (event-col-row row height)
1776   (let* ((ovl company-pseudo-tooltip-overlay)
1777          (column (overlay-get ovl 'company-column))
1778          (width (overlay-get ovl 'company-width))
1779          (evt-col (car event-col-row))
1780          (evt-row (cdr event-col-row)))
1781     (and (>= evt-col column)
1782          (< evt-col (+ column width))
1783          (if (> height 0)
1784              (and (> evt-row row)
1785                   (<= evt-row (+ row height) ))
1786            (and (< evt-row row)
1787                 (>= evt-row (+ row height)))))))
1788
1789 (defun company--event-col-row (event)
1790   (company--posn-col-row (event-start event)))
1791
1792 (defun company-select-mouse (event)
1793   "Select the candidate picked by the mouse."
1794   (interactive "e")
1795   (let ((event-col-row (company--event-col-row event))
1796         (ovl-row (company--row))
1797         (ovl-height (and company-pseudo-tooltip-overlay
1798                          (min (overlay-get company-pseudo-tooltip-overlay
1799                                            'company-height)
1800                               company-candidates-length))))
1801     (if (and ovl-height
1802              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1803         (progn
1804           (company-set-selection (+ (cdr event-col-row)
1805                                     (1- company-tooltip-offset)
1806                                     (if (and (eq company-tooltip-offset-display 'lines)
1807                                              (not (zerop company-tooltip-offset)))
1808                                         -1 0)
1809                                     (- ovl-row)
1810                                     (if (< ovl-height 0)
1811                                         (- 1 ovl-height)
1812                                       0)))
1813           t)
1814       (company-abort)
1815       (company--unread-last-input)
1816       nil)))
1817
1818 (defun company-complete-mouse (event)
1819   "Insert the candidate picked by the mouse."
1820   (interactive "e")
1821   (when (company-select-mouse event)
1822     (company-complete-selection)))
1823
1824 (defun company-complete-selection ()
1825   "Insert the selected candidate."
1826   (interactive)
1827   (when (company-manual-begin)
1828     (let ((result (nth company-selection company-candidates)))
1829       (company-finish result))))
1830
1831 (defun company-complete-common ()
1832   "Insert the common part of all candidates."
1833   (interactive)
1834   (when (company-manual-begin)
1835     (if (and (not (cdr company-candidates))
1836              (equal company-common (car company-candidates)))
1837         (company-complete-selection)
1838       (when company-common
1839         (company--insert-candidate company-common)))))
1840
1841 (defun company-complete ()
1842   "Insert the common part of all candidates or the current selection.
1843 The first time this is called, the common part is inserted, the second
1844 time, or when the selection has been changed, the selected candidate is
1845 inserted."
1846   (interactive)
1847   (when (company-manual-begin)
1848     (if (or company-selection-changed
1849             (eq last-command 'company-complete-common))
1850         (call-interactively 'company-complete-selection)
1851       (call-interactively 'company-complete-common)
1852       (setq this-command 'company-complete-common))))
1853
1854 (defun company-complete-number (n)
1855   "Insert the Nth candidate.
1856 To show the number next to the candidates in some back-ends, enable
1857 `company-show-numbers'.  When called interactively, uses the last typed
1858 character, stripping the modifiers.  That character must be a digit."
1859   (interactive
1860    (list (let ((n (- (event-basic-type last-command-event) ?0)))
1861            (if (zerop n) 10 n))))
1862   (when (company-manual-begin)
1863     (and (or (< n 1) (> n company-candidates-length))
1864          (error "No candidate number %d" n))
1865     (cl-decf n)
1866     (company-finish (nth n company-candidates))))
1867
1868 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1869
1870 (defconst company-space-strings-limit 100)
1871
1872 (defconst company-space-strings
1873   (let (lst)
1874     (dotimes (i company-space-strings-limit)
1875       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1876     (apply 'vector lst)))
1877
1878 (defun company-space-string (len)
1879   (if (< len company-space-strings-limit)
1880       (aref company-space-strings len)
1881     (make-string len ?\ )))
1882
1883 (defun company-safe-substring (str from &optional to)
1884   (if (> from (string-width str))
1885       ""
1886     (with-temp-buffer
1887       (insert str)
1888       (move-to-column from)
1889       (let ((beg (point)))
1890         (if to
1891             (progn
1892               (move-to-column to)
1893               (concat (buffer-substring beg (point))
1894                       (let ((padding (- to (current-column))))
1895                         (when (> padding 0)
1896                           (company-space-string padding)))))
1897           (buffer-substring beg (point-max)))))))
1898
1899 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1900
1901 (defvar-local company-last-metadata nil)
1902
1903 (defun company-fetch-metadata ()
1904   (let ((selected (nth company-selection company-candidates)))
1905     (unless (eq selected (car company-last-metadata))
1906       (setq company-last-metadata
1907             (cons selected (company-call-backend 'meta selected))))
1908     (cdr company-last-metadata)))
1909
1910 (defun company-doc-buffer (&optional string)
1911   (with-current-buffer (get-buffer-create "*company-documentation*")
1912     (erase-buffer)
1913     (when string
1914       (save-excursion
1915         (insert string)))
1916     (current-buffer)))
1917
1918 (defvar company--electric-commands
1919   '(scroll-other-window scroll-other-window-down)
1920   "List of Commands that won't break out of electric commands.")
1921
1922 (defmacro company--electric-do (&rest body)
1923   (declare (indent 0) (debug t))
1924   `(when (company-manual-begin)
1925      (save-window-excursion
1926        (let ((height (window-height))
1927              (row (company--row))
1928              cmd)
1929          ,@body
1930          (and (< (window-height) height)
1931               (< (- (window-height) row 2) company-tooltip-limit)
1932               (recenter (- (window-height) row 2)))
1933          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1934                       company--electric-commands)
1935            (call-interactively cmd))
1936          (company--unread-last-input)))))
1937
1938 (defun company--unread-last-input ()
1939   (when last-input-event
1940     (clear-this-command-keys t)
1941     (setq unread-command-events (list last-input-event))))
1942
1943 (defun company-show-doc-buffer ()
1944   "Temporarily show the documentation buffer for the selection."
1945   (interactive)
1946   (company--electric-do
1947     (let* ((selected (nth company-selection company-candidates))
1948            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1949                            (error "No documentation available"))))
1950       (with-current-buffer doc-buffer
1951         (goto-char (point-min)))
1952       (display-buffer doc-buffer t))))
1953 (put 'company-show-doc-buffer 'company-keep t)
1954
1955 (defun company-show-location ()
1956   "Temporarily display a buffer showing the selected candidate in context."
1957   (interactive)
1958   (company--electric-do
1959     (let* ((selected (nth company-selection company-candidates))
1960            (location (company-call-backend 'location selected))
1961            (pos (or (cdr location) (error "No location available")))
1962            (buffer (or (and (bufferp (car location)) (car location))
1963                        (find-file-noselect (car location) t))))
1964       (with-selected-window (display-buffer buffer t)
1965         (save-restriction
1966           (widen)
1967           (if (bufferp (car location))
1968               (goto-char pos)
1969             (goto-char (point-min))
1970             (forward-line (1- pos))))
1971         (set-window-start nil (point))))))
1972 (put 'company-show-location 'company-keep t)
1973
1974 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1975
1976 (defvar-local company-callback nil)
1977
1978 (defun company-remove-callback (&optional ignored)
1979   (remove-hook 'company-completion-finished-hook company-callback t)
1980   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1981   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
1982
1983 (defun company-begin-backend (backend &optional callback)
1984   "Start a completion at point using BACKEND."
1985   (interactive (let ((val (completing-read "Company back-end: "
1986                                            obarray
1987                                            'functionp nil "company-")))
1988                  (when val
1989                    (list (intern val)))))
1990   (when (setq company-callback callback)
1991     (add-hook 'company-completion-finished-hook company-callback nil t))
1992   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1993   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1994   (setq company-backend backend)
1995   ;; Return non-nil if active.
1996   (or (company-manual-begin)
1997       (error "Cannot complete at point")))
1998
1999 (defun company-begin-with (candidates
2000                            &optional prefix-length require-match callback)
2001   "Start a completion at point.
2002 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
2003 of the prefix that already is in the buffer before point.
2004 It defaults to 0.
2005
2006 CALLBACK is a function called with the selected result if the user
2007 successfully completes the input.
2008
2009 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
2010   (let ((begin-marker (copy-marker (point) t)))
2011     (company-begin-backend
2012      (lambda (command &optional arg &rest ignored)
2013        (pcase command
2014          (`prefix
2015           (when (equal (point) (marker-position begin-marker))
2016             (buffer-substring (- (point) (or prefix-length 0)) (point))))
2017          (`candidates
2018           (all-completions arg candidates))
2019          (`require-match
2020           require-match)))
2021      callback)))
2022
2023 (defun company-version (&optional show-version)
2024   "Get the Company version as string.
2025
2026 If SHOW-VERSION is non-nil, show the version in the echo area."
2027   (interactive (list t))
2028   (with-temp-buffer
2029     (insert-file-contents (find-library-name "company"))
2030     (require 'lisp-mnt)
2031     (if show-version
2032         (message "Company version: %s" (lm-version))
2033       (lm-version))))
2034
2035 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2036
2037 (defvar-local company-pseudo-tooltip-overlay nil)
2038
2039 (defvar-local company-tooltip-offset 0)
2040
2041 (defun company-tooltip--lines-update-offset (selection num-lines limit)
2042   (cl-decf limit 2)
2043   (setq company-tooltip-offset
2044         (max (min selection company-tooltip-offset)
2045              (- selection -1 limit)))
2046
2047   (when (<= company-tooltip-offset 1)
2048     (cl-incf limit)
2049     (setq company-tooltip-offset 0))
2050
2051   (when (>= company-tooltip-offset (- num-lines limit 1))
2052     (cl-incf limit)
2053     (when (= selection (1- num-lines))
2054       (cl-decf company-tooltip-offset)
2055       (when (<= company-tooltip-offset 1)
2056         (setq company-tooltip-offset 0)
2057         (cl-incf limit))))
2058
2059   limit)
2060
2061 (defun company-tooltip--simple-update-offset (selection _num-lines limit)
2062   (setq company-tooltip-offset
2063         (if (< selection company-tooltip-offset)
2064             selection
2065           (max company-tooltip-offset
2066                (- selection limit -1)))))
2067
2068 ;;; propertize
2069
2070 (defsubst company-round-tab (arg)
2071   (* (/ (+ arg tab-width) tab-width) tab-width))
2072
2073 (defun company-plainify (str)
2074   (let ((prefix (get-text-property 0 'line-prefix str)))
2075     (when prefix ; Keep the original value unmodified, for no special reason.
2076       (setq str (concat prefix str))
2077       (remove-text-properties 0 (length str) '(line-prefix) str)))
2078   (let* ((pieces (split-string str "\t"))
2079          (copy pieces))
2080     (while (cdr copy)
2081       (setcar copy (company-safe-substring
2082                     (car copy) 0 (company-round-tab (string-width (car copy)))))
2083       (pop copy))
2084     (apply 'concat pieces)))
2085
2086 (defun company-fill-propertize (value annotation width selected left right)
2087   (let* ((margin (length left))
2088          (common (or (company-call-backend 'match value)
2089                      (length company-common)))
2090          (ann-ralign company-tooltip-align-annotations)
2091          (ann-truncate (< width
2092                           (+ (length value) (length annotation)
2093                              (if ann-ralign 1 0))))
2094          (ann-start (+ margin
2095                        (if ann-ralign
2096                            (if ann-truncate
2097                                (1+ (length value))
2098                              (- width (length annotation)))
2099                          (length value))))
2100          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
2101          (line (concat left
2102                        (if (or ann-truncate (not ann-ralign))
2103                            (company-safe-substring
2104                             (concat value
2105                                     (when (and annotation ann-ralign) " ")
2106                                     annotation)
2107                             0 width)
2108                          (concat
2109                           (company-safe-substring value 0
2110                                                   (- width (length annotation)))
2111                           annotation))
2112                        right)))
2113     (setq common (+ (min common width) margin))
2114     (setq width (+ width margin (length right)))
2115
2116     (add-text-properties 0 width '(face company-tooltip
2117                                    mouse-face company-tooltip-mouse)
2118                          line)
2119     (add-text-properties margin common
2120                          '(face company-tooltip-common
2121                            mouse-face company-tooltip-mouse)
2122                          line)
2123     (when (< ann-start ann-end)
2124       (add-text-properties ann-start ann-end
2125                            '(face company-tooltip-annotation
2126                              mouse-face company-tooltip-mouse)
2127                            line))
2128     (when selected
2129       (if (and company-search-string
2130                (string-match (regexp-quote company-search-string) value
2131                              (length company-prefix)))
2132           (let ((beg (+ margin (match-beginning 0)))
2133                 (end (+ margin (match-end 0))))
2134             (add-text-properties beg end '(face company-tooltip-search)
2135                                  line)
2136             (when (< beg common)
2137               (add-text-properties beg common
2138                                    '(face company-tooltip-common-selection)
2139                                    line)))
2140         (add-text-properties 0 width '(face company-tooltip-selection
2141                                        mouse-face company-tooltip-selection)
2142                              line)
2143         (add-text-properties margin common
2144                              '(face company-tooltip-common-selection
2145                                mouse-face company-tooltip-selection)
2146                              line)))
2147     line))
2148
2149 ;;; replace
2150
2151 (defun company-buffer-lines (beg end)
2152   (goto-char beg)
2153   (let (lines lines-moved)
2154     (while (and (> (setq lines-moved (vertical-motion 1)) 0)
2155                 (<= (point) end))
2156       (let ((bound (min end (1- (point)))))
2157         ;; A visual line can contain several physical lines (e.g. with outline's
2158         ;; folding overlay).  Take only the first one.
2159         (push (buffer-substring beg
2160                                 (save-excursion
2161                                   (goto-char beg)
2162                                   (re-search-forward "$" bound 'move)
2163                                   (point)))
2164               lines))
2165       ;; One physical line can be displayed as several visual ones as well:
2166       ;; add empty strings to the list, to even the count.
2167       (dotimes (_ (1- lines-moved))
2168         (push "" lines))
2169       (setq beg (point)))
2170     (unless (eq beg end)
2171       (push (buffer-substring beg end) lines))
2172     (nreverse lines)))
2173
2174 (defun company-modify-line (old new offset)
2175   (concat (company-safe-substring old 0 offset)
2176           new
2177           (company-safe-substring old (+ offset (length new)))))
2178
2179 (defsubst company--length-limit (lst limit)
2180   (if (nthcdr limit lst)
2181       limit
2182     (length lst)))
2183
2184 (defun company--replacement-string (lines old column nl &optional align-top)
2185   (cl-decf column company-tooltip-margin)
2186
2187   (when (and align-top company-tooltip-flip-when-above)
2188     (setq lines (reverse lines)))
2189
2190   (let ((width (length (car lines)))
2191         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2192                            column)))
2193     (when (> width remaining-cols)
2194       (cl-decf column (- width remaining-cols))))
2195
2196   (let ((offset (and (< column 0) (- column)))
2197         new)
2198     (when offset
2199       (setq column 0))
2200     (when align-top
2201       ;; untouched lines first
2202       (dotimes (_ (- (length old) (length lines)))
2203         (push (pop old) new)))
2204     ;; length into old lines.
2205     (while old
2206       (push (company-modify-line (pop old)
2207                                  (company--offset-line (pop lines) offset)
2208                                  column) new))
2209     ;; Append whole new lines.
2210     (while lines
2211       (push (concat (company-space-string column)
2212                     (company--offset-line (pop lines) offset))
2213             new))
2214
2215     (let ((str (concat (when nl " ")
2216                        "\n"
2217                        (mapconcat 'identity (nreverse new) "\n")
2218                        "\n")))
2219       (font-lock-append-text-property 0 (length str) 'face 'default str)
2220       (when nl (put-text-property 0 1 'cursor t str))
2221       str)))
2222
2223 (defun company--offset-line (line offset)
2224   (if (and offset line)
2225       (substring line offset)
2226     line))
2227
2228 (defun company--create-lines (selection limit)
2229   (let ((len company-candidates-length)
2230         (numbered 99999)
2231         (window-width (company--window-width))
2232         lines
2233         width
2234         lines-copy
2235         items
2236         previous
2237         remainder
2238         scrollbar-bounds)
2239
2240     ;; Maybe clear old offset.
2241     (when (< len (+ company-tooltip-offset limit))
2242       (setq company-tooltip-offset 0))
2243
2244     ;; Scroll to offset.
2245     (if (eq company-tooltip-offset-display 'lines)
2246         (setq limit (company-tooltip--lines-update-offset selection len limit))
2247       (company-tooltip--simple-update-offset selection len limit))
2248
2249     (cond
2250      ((eq company-tooltip-offset-display 'scrollbar)
2251       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2252                                                         limit len)))
2253      ((eq company-tooltip-offset-display 'lines)
2254       (when (> company-tooltip-offset 0)
2255         (setq previous (format "...(%d)" company-tooltip-offset)))
2256       (setq remainder (- len limit company-tooltip-offset)
2257             remainder (when (> remainder 0)
2258                         (setq remainder (format "...(%d)" remainder))))))
2259
2260     (cl-decf selection company-tooltip-offset)
2261     (setq width (max (length previous) (length remainder))
2262           lines (nthcdr company-tooltip-offset company-candidates)
2263           len (min limit len)
2264           lines-copy lines)
2265
2266     (cl-decf window-width (* 2 company-tooltip-margin))
2267     (when scrollbar-bounds (cl-decf window-width))
2268
2269     (dotimes (_ len)
2270       (let* ((value (pop lines-copy))
2271              (annotation (company-call-backend 'annotation value)))
2272         (when (and annotation company-tooltip-align-annotations)
2273           ;; `lisp-completion-at-point' adds a space.
2274           (setq annotation (comment-string-strip annotation t nil)))
2275         (push (cons value annotation) items)
2276         (setq width (max (+ (length value)
2277                             (if (and annotation company-tooltip-align-annotations)
2278                                 (1+ (length annotation))
2279                               (length annotation)))
2280                          width))))
2281
2282     (setq width (min window-width
2283                      (max company-tooltip-minimum-width
2284                           (if (and company-show-numbers
2285                                    (< company-tooltip-offset 10))
2286                               (+ 2 width)
2287                             width))))
2288
2289     ;; number can make tooltip too long
2290     (when company-show-numbers
2291       (setq numbered company-tooltip-offset))
2292
2293     (let ((items (nreverse items)) new)
2294       (when previous
2295         (push (company--scrollpos-line previous width) new))
2296
2297       (dotimes (i len)
2298         (let* ((item (pop items))
2299                (str (company-reformat (car item)))
2300                (annotation (cdr item))
2301                (right (company-space-string company-tooltip-margin))
2302                (width width))
2303           (when (< numbered 10)
2304             (cl-decf width 2)
2305             (cl-incf numbered)
2306             (setq right (concat (format " %d" (mod numbered 10)) right)))
2307           (push (concat
2308                  (company-fill-propertize str annotation
2309                                           width (equal i selection)
2310                                           (company-space-string
2311                                            company-tooltip-margin)
2312                                           right)
2313                  (when scrollbar-bounds
2314                    (company--scrollbar i scrollbar-bounds)))
2315                 new)))
2316
2317       (when remainder
2318         (push (company--scrollpos-line remainder width) new))
2319
2320       (nreverse new))))
2321
2322 (defun company--scrollbar-bounds (offset limit length)
2323   (when (> length limit)
2324     (let* ((size (ceiling (* limit (float limit)) length))
2325            (lower (floor (* limit (float offset)) length))
2326            (upper (+ lower size -1)))
2327       (cons lower upper))))
2328
2329 (defun company--scrollbar (i bounds)
2330   (propertize " " 'face
2331               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2332                   'company-scrollbar-fg
2333                 'company-scrollbar-bg)))
2334
2335 (defun company--scrollpos-line (text width)
2336   (propertize (concat (company-space-string company-tooltip-margin)
2337                       (company-safe-substring text 0 width)
2338                       (company-space-string company-tooltip-margin))
2339               'face 'company-tooltip))
2340
2341 ;; show
2342
2343 (defsubst company--window-height ()
2344   (if (fboundp 'window-screen-lines)
2345       (floor (window-screen-lines))
2346     (window-body-height)))
2347
2348 (defsubst company--window-width ()
2349   (let ((ww (window-body-width)))
2350     ;; Account for the line continuation column.
2351     (when (zerop (cadr (window-fringes)))
2352       (cl-decf ww))
2353     (unless (or (display-graphic-p)
2354                 (version< "24.3.1" emacs-version))
2355       ;; Emacs 24.3 and earlier included margins
2356       ;; in window-width when in TTY.
2357       (cl-decf ww
2358                (let ((margins (window-margins)))
2359                  (+ (or (car margins) 0)
2360                     (or (cdr margins) 0)))))
2361     ww))
2362
2363 (defun company--pseudo-tooltip-height ()
2364   "Calculate the appropriate tooltip height.
2365 Returns a negative number if the tooltip should be displayed above point."
2366   (let* ((lines (company--row))
2367          (below (- (company--window-height) 1 lines)))
2368     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2369              (> lines below))
2370         (- (max 3 (min company-tooltip-limit lines)))
2371       (max 3 (min company-tooltip-limit below)))))
2372
2373 (defun company-pseudo-tooltip-show (row column selection)
2374   (company-pseudo-tooltip-hide)
2375   (save-excursion
2376
2377     (let* ((height (company--pseudo-tooltip-height))
2378            above)
2379
2380       (when (< height 0)
2381         (setq row (+ row height -1)
2382               above t))
2383
2384       (let* ((nl (< (move-to-window-line row) row))
2385              (beg (point))
2386              (end (save-excursion
2387                     (move-to-window-line (+ row (abs height)))
2388                     (point)))
2389              (ov (make-overlay (if nl beg (1- beg)) end nil t t))
2390              (args (list (mapcar 'company-plainify
2391                                  (company-buffer-lines beg end))
2392                          column nl above)))
2393
2394         (setq company-pseudo-tooltip-overlay ov)
2395         (overlay-put ov 'company-replacement-args args)
2396
2397         (let ((lines (company--create-lines selection (abs height))))
2398           (overlay-put ov 'company-display
2399                        (apply 'company--replacement-string lines args))
2400           (overlay-put ov 'company-width (string-width (car lines))))
2401
2402         (overlay-put ov 'company-column column)
2403         (overlay-put ov 'company-height height)))))
2404
2405 (defun company-pseudo-tooltip-show-at-point (pos column-offset)
2406   (let* ((col-row (company--col-row pos))
2407          (col (- (car col-row) column-offset)))
2408     (when (< col 0) (setq col 0))
2409     (company-pseudo-tooltip-show (1+ (cdr col-row)) col company-selection)))
2410
2411 (defun company-pseudo-tooltip-edit (selection)
2412   (let* ((height (overlay-get company-pseudo-tooltip-overlay 'company-height))
2413          (lines  (company--create-lines selection (abs height))))
2414     (overlay-put company-pseudo-tooltip-overlay 'company-width
2415                  (string-width (car lines)))
2416     (overlay-put company-pseudo-tooltip-overlay 'company-display
2417                  (apply 'company--replacement-string
2418                         lines
2419                         (overlay-get company-pseudo-tooltip-overlay
2420                                      'company-replacement-args)))))
2421
2422 (defun company-pseudo-tooltip-hide ()
2423   (when company-pseudo-tooltip-overlay
2424     (delete-overlay company-pseudo-tooltip-overlay)
2425     (setq company-pseudo-tooltip-overlay nil)))
2426
2427 (defun company-pseudo-tooltip-hide-temporarily ()
2428   (when (overlayp company-pseudo-tooltip-overlay)
2429     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2430     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)))
2431
2432 (defun company-pseudo-tooltip-unhide ()
2433   (when company-pseudo-tooltip-overlay
2434     (let* ((ov company-pseudo-tooltip-overlay)
2435            (disp (overlay-get ov 'company-display)))
2436       ;; Beat outline's folding overlays, at least.
2437       (overlay-put ov 'priority 1)
2438       ;; `display' could be better (http://debbugs.gnu.org/18285), but it
2439       ;; doesn't work when the overlay is empty, which is what happens at eob.
2440       ;; It also seems to interact badly with `cursor'.
2441       ;; We deal with priorities by having the overlay start before the newline.
2442       (overlay-put ov 'after-string disp)
2443       (overlay-put ov 'invisible t)
2444       (overlay-put ov 'window (selected-window)))))
2445
2446 (defun company-pseudo-tooltip-guard ()
2447   (cons
2448    (save-excursion (beginning-of-visual-line))
2449    (let ((ov company-pseudo-tooltip-overlay)
2450          (overhang (save-excursion (end-of-visual-line)
2451                                    (- (line-end-position) (point)))))
2452      (when (>= (overlay-get ov 'company-height) 0)
2453        (cons
2454         (buffer-substring-no-properties (point) (overlay-start ov))
2455         (when (>= overhang 0) overhang))))))
2456
2457 (defun company-pseudo-tooltip-frontend (command)
2458   "`company-mode' front-end similar to a tooltip but based on overlays."
2459   (cl-case command
2460     (pre-command (company-pseudo-tooltip-hide-temporarily))
2461     (post-command
2462      (unless (when (overlayp company-pseudo-tooltip-overlay)
2463               (let* ((ov company-pseudo-tooltip-overlay)
2464                      (old-height (overlay-get ov 'company-height))
2465                      (new-height (company--pseudo-tooltip-height)))
2466                 (and
2467                  (>= (* old-height new-height) 0)
2468                  (>= (abs old-height) (abs new-height))
2469                  (equal (company-pseudo-tooltip-guard)
2470                         (overlay-get ov 'company-guard)))))
2471        ;; Redraw needed.
2472        (company-pseudo-tooltip-show-at-point (point) (length company-prefix))
2473        (overlay-put company-pseudo-tooltip-overlay
2474                     'company-guard (company-pseudo-tooltip-guard)))
2475      (company-pseudo-tooltip-unhide))
2476     (hide (company-pseudo-tooltip-hide)
2477           (setq company-tooltip-offset 0))
2478     (update (when (overlayp company-pseudo-tooltip-overlay)
2479               (company-pseudo-tooltip-edit company-selection)))))
2480
2481 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2482   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2483   (unless (and (eq command 'post-command)
2484                (company--show-inline-p))
2485     (company-pseudo-tooltip-frontend command)))
2486
2487 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2488
2489 (defvar-local company-preview-overlay nil)
2490
2491 (defun company-preview-show-at-point (pos)
2492   (company-preview-hide)
2493
2494   (setq company-preview-overlay (make-overlay pos pos))
2495
2496   (let ((completion (nth company-selection company-candidates)))
2497     (setq completion (propertize completion 'face 'company-preview))
2498     (add-text-properties 0 (length company-common)
2499                          '(face company-preview-common) completion)
2500
2501     ;; Add search string
2502     (and company-search-string
2503          (string-match (regexp-quote company-search-string) completion)
2504          (add-text-properties (match-beginning 0)
2505                               (match-end 0)
2506                               '(face company-preview-search)
2507                               completion))
2508
2509     (setq completion (company-strip-prefix completion))
2510
2511     (and (equal pos (point))
2512          (not (equal completion ""))
2513          (add-text-properties 0 1 '(cursor t) completion))
2514
2515     (let ((ov company-preview-overlay))
2516       (overlay-put ov 'after-string completion)
2517       (overlay-put ov 'window (selected-window)))))
2518
2519 (defun company-preview-hide ()
2520   (when company-preview-overlay
2521     (delete-overlay company-preview-overlay)
2522     (setq company-preview-overlay nil)))
2523
2524 (defun company-preview-frontend (command)
2525   "`company-mode' front-end showing the selection as if it had been inserted."
2526   (pcase command
2527     (`pre-command (company-preview-hide))
2528     (`post-command (company-preview-show-at-point (point)))
2529     (`hide (company-preview-hide))))
2530
2531 (defun company-preview-if-just-one-frontend (command)
2532   "`company-preview-frontend', but only shown for single candidates."
2533   (when (or (not (eq command 'post-command))
2534             (company--show-inline-p))
2535     (company-preview-frontend command)))
2536
2537 (defun company--show-inline-p ()
2538   (and (not (cdr company-candidates))
2539        company-common
2540        (or (eq (company-call-backend 'ignore-case) 'keep-prefix)
2541            (string-prefix-p company-prefix company-common))))
2542
2543 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2544
2545 (defvar-local company-echo-last-msg nil)
2546
2547 (defvar company-echo-timer nil)
2548
2549 (defvar company-echo-delay .01)
2550
2551 (defun company-echo-show (&optional getter)
2552   (when getter
2553     (setq company-echo-last-msg (funcall getter)))
2554   (let ((message-log-max nil))
2555     (if company-echo-last-msg
2556         (message "%s" company-echo-last-msg)
2557       (message ""))))
2558
2559 (defun company-echo-show-soon (&optional getter)
2560   (when company-echo-timer
2561     (cancel-timer company-echo-timer))
2562   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2563
2564 (defsubst company-echo-show-when-idle (&optional getter)
2565   (when (sit-for company-echo-delay)
2566     (company-echo-show getter)))
2567
2568 (defun company-echo-format ()
2569
2570   (let ((limit (window-body-width (minibuffer-window)))
2571         (len -1)
2572         ;; Roll to selection.
2573         (candidates (nthcdr company-selection company-candidates))
2574         (i (if company-show-numbers company-selection 99999))
2575         comp msg)
2576
2577     (while candidates
2578       (setq comp (company-reformat (pop candidates))
2579             len (+ len 1 (length comp)))
2580       (if (< i 10)
2581           ;; Add number.
2582           (progn
2583             (setq comp (propertize (format "%d: %s" i comp)
2584                                    'face 'company-echo))
2585             (cl-incf len 3)
2586             (cl-incf i)
2587             (add-text-properties 3 (+ 3 (length company-common))
2588                                  '(face company-echo-common) comp))
2589         (setq comp (propertize comp 'face 'company-echo))
2590         (add-text-properties 0 (length company-common)
2591                              '(face company-echo-common) comp))
2592       (if (>= len limit)
2593           (setq candidates nil)
2594         (push comp msg)))
2595
2596     (mapconcat 'identity (nreverse msg) " ")))
2597
2598 (defun company-echo-strip-common-format ()
2599
2600   (let ((limit (window-body-width (minibuffer-window)))
2601         (len (+ (length company-prefix) 2))
2602         ;; Roll to selection.
2603         (candidates (nthcdr company-selection company-candidates))
2604         (i (if company-show-numbers company-selection 99999))
2605         msg comp)
2606
2607     (while candidates
2608       (setq comp (company-strip-prefix (pop candidates))
2609             len (+ len 2 (length comp)))
2610       (when (< i 10)
2611         ;; Add number.
2612         (setq comp (format "%s (%d)" comp i))
2613         (cl-incf len 4)
2614         (cl-incf i))
2615       (if (>= len limit)
2616           (setq candidates nil)
2617         (push (propertize comp 'face 'company-echo) msg)))
2618
2619     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2620             (mapconcat 'identity (nreverse msg) ", ")
2621             "}")))
2622
2623 (defun company-echo-hide ()
2624   (unless (equal company-echo-last-msg "")
2625     (setq company-echo-last-msg "")
2626     (company-echo-show)))
2627
2628 (defun company-echo-frontend (command)
2629   "`company-mode' front-end showing the candidates in the echo area."
2630   (pcase command
2631     (`post-command (company-echo-show-soon 'company-echo-format))
2632     (`hide (company-echo-hide))))
2633
2634 (defun company-echo-strip-common-frontend (command)
2635   "`company-mode' front-end showing the candidates in the echo area."
2636   (pcase command
2637     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2638     (`hide (company-echo-hide))))
2639
2640 (defun company-echo-metadata-frontend (command)
2641   "`company-mode' front-end showing the documentation in the echo area."
2642   (pcase command
2643     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
2644     (`hide (company-echo-hide))))
2645
2646 (provide 'company)
2647 ;;; company.el ends here