code.delx.au - gnu-emacs-elpa/blob - aggressive-indent.el

   1 ;;; aggressive-indent.el --- Minor mode to aggressively keep your code always indented
   2
   3 ;; Copyright (C) 2014 Artur Malabarba <bruce.connor.am@gmail.com>
   4
   5 ;; Author: Artur Malabarba <bruce.connor.am@gmail.com>
   6 ;; URL: http://github.com/Bruce-Connor/aggressive-indent-mode
   7 ;; Version: 0.3
   8 ;; Package-Requires: ((emacs "24.1") (names "0.5") (cl-lib "0.5"))
   9 ;; Keywords: indent lisp maint tools
  10 ;; Prefix: aggressive-indent
  11 ;; Separator: -
  12
  13 ;;; Commentary:
  14 ;;
  15 ;; `electric-indent-mode' is enough to keep your code nicely aligned when
  16 ;; all you do is type. However, once you start shifting blocks around,
  17 ;; transposing lines, or slurping and barfing sexps, indentation is bound
  18 ;; to go wrong.
  19 ;;
  20 ;; `aggressive-indent-mode' is a minor mode that keeps your code always
  21 ;; indented. It reindents after every command, making it more reliable
  22 ;; than `electric-indent-mode'.
  23 ;;
  24 ;; ### Instructions ###
  25 ;;
  26 ;; This package is available fom Melpa, you may install it by calling
  27 ;;
  28 ;;     M-x package-install RET aggressive-indent
  29 ;;
  30 ;; Then activate it with
  31 ;;
  32 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  33 ;;     (add-hook 'css-mode-hook #'aggressive-indent-mode)
  34 ;;
  35 ;; You can use this hook on any mode you want, `aggressive-indent' is not
  36 ;; exclusive to emacs-lisp code. In fact, if you want to turn it on for
  37 ;; every programming mode, you can do something like:
  38 ;;
  39 ;;     (global-aggressive-indent-mode 1)
  40 ;;     (add-to-list 'aggressive-indent-excluded-modes 'html-mode)
  41 ;;
  42 ;; ### Manual Installation ###
  43 ;;
  44 ;; If you don't want to install from Melpa, you can download it manually,
  45 ;; place it in your `load-path' and require it with
  46 ;;
  47 ;;     (require 'aggressive-indent)
  48
  49 ;;; Instructions:
  50 ;;
  51 ;; INSTALLATION
  52 ;;
  53 ;; This package is available fom Melpa, you may install it by calling
  54 ;; M-x package-install RET aggressive-indent.
  55 ;;
  56 ;; Then activate it with
  57 ;;     (add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)
  58 ;;
  59 ;; You can also use an equivalent hook for another mode,
  60 ;; `aggressive-indent' is not exclusive to emacs-lisp code.
  61 ;;
  62 ;; Alternatively, you can download it manually, place it in your
  63 ;; `load-path' and require it with
  64 ;;
  65 ;;     (require 'aggressive-indent)
  66
  67 ;;; License:
  68 ;;
  69 ;; This file is NOT part of GNU Emacs.
  70 ;;
  71 ;; This program is free software; you can redistribute it and/or
  72 ;; modify it under the terms of the GNU General Public License
  73 ;; as published by the Free Software Foundation; either version 2
  74 ;; of the License, or (at your option) any later version.
  75 ;;
  76 ;; This program is distributed in the hope that it will be useful,
  77 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  78 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  79 ;; GNU General Public License for more details.
  80 ;;
  81
  82 ;;; Change Log:
  83 ;; 0.3 - 2014/10/23 - Implement a smarter engine for non-lisp modes.
  84 ;; 0.2 - 2014/10/20 - Reactivate `electric-indent-mode'.
  85 ;; 0.2 - 2014/10/19 - Add variable `aggressive-indent-dont-indent-if', so the user can prevent indentation.
  86 ;; 0.1 - 2014/10/15 - Release.
  87 ;;; Code:
  88
  89 (require 'cl-lib)
  90 (require 'names)
  91
  92 ;;;###autoload
  93 (define-namespace aggressive-indent- :group indent
  94
  95 (defconst version "0.3" "Version of the aggressive-indent.el package.")
  96 (defun bug-report ()
  97   "Opens github issues page in a web browser. Please send any bugs you find.
  98 Please include your emacs and aggressive-indent versions."
  99   (interactive)
 100   (message "Your `aggressive-indent-version' is: %s, and your emacs version is: %s.
 101 Please include this in your report!"
 102            version emacs-version)
 103   (browse-url "https://github.com/Bruce-Connor/aggressive-indent-mode/issues/new"))
 104
 105 \f
 106 ;;; Start of actual Code:
 107 (defcustom excluded-modes
 108   '(text-mode tabulated-list-mode special-mode
 109               minibuffer-inactive-mode
 110               yaml-mode jabber-chat-mode)
 111   "Modes in which `aggressive-indent-mode' should not be activated.
 112 This variable is only used if `global-aggressive-indent-mode' is
 113 active. If the minor mode is turned on with the local command,
 114 `aggressive-indent-mode', this variable is ignored."
 115   :type '(repeat symbol)
 116   :package-version '(aggressive-indent . "0.2"))
 117
 118 (defcustom protected-commands '(undo undo-tree-undo undo-tree-redo)
 119   "Commands after which indentation will NOT be performed.
 120 Aggressive indentation could break things like `undo' by locking
 121 the user in a loop, so this variable is used to control which
 122 commands will NOT be followed by a re-indent."
 123   :type '(repeat symbol)
 124   :package-version '(aggressive-indent . "0.1"))
 125
 126 (defvar -internal-dont-indent-if
 127   '((memq this-command aggressive-indent-protected-commands)
 128     (region-active-p)
 129     buffer-read-only
 130     (null (buffer-modified-p))
 131     (string-match "\\`[[:blank:]]*\n?\\'" (thing-at-point 'line)))
 132   "List of forms which prevent indentation when they evaluate to non-nil.
 133 This is for internal use only. For user customization, use
 134 `aggressive-indent-dont-indent-if' instead.")
 135
 136 (defcustom modes-to-prefer-defun '(emacs-lisp-mode lisp-mode scheme-mode)
 137   "List of major-modes in which indenting defun is preferred.
 138 Add here any major modes with very good definitions of
 139 `end-of-defun' and `beginning-of-defun', or modes which bug out
 140 if you have `after-change-functions' (such as paredit).
 141
 142 If current major mode is derived from one of these,
 143 `aggressive-indent-mode' will call
 144 `aggressive-indent-indent-defun' after every command. Otherwise,
 145 it will call `aggressive-indent-indent-region-and-on' after every
 146 buffer change."
 147   :type '(repeat symbol)
 148   :group 'aggressive-indent
 149   :package-version '(aggressive-indent . "0.3"))
 150
 151 (eval-after-load 'yasnippet
 152   '(when (boundp 'yas--active-field-overlay)
 153      (add-to-list 'aggressive-indent--internal-dont-indent-if
 154                   '(and
 155                     (overlayp yas--active-field-overlay)
 156                     (overlay-end yas--active-field-overlay))
 157                   'append)))
 158 (eval-after-load 'company
 159   '(when (boundp 'company-candidates)
 160      (add-to-list 'aggressive-indent--internal-dont-indent-if
 161                   'company-candidates)))
 162 (eval-after-load 'auto-complete
 163   '(when (boundp 'ac-completing)
 164      (add-to-list 'aggressive-indent--internal-dont-indent-if
 165                   'ac-completing)))
 166
 167 (eval-after-load 'css-mode
 168   '(add-hook
 169     'css-mode-hook
 170     (lambda () (unless defun-prompt-regexp
 171             (setq-local defun-prompt-regexp "^[^[:blank:]].*")))))
 172
 173 (defcustom dont-indent-if '()
 174   "List of variables and functions to prevent aggressive indenting.
 175 This variable is a list where each element is a lisp form.
 176 As long as any one of these forms returns non-nil,
 177 aggressive-indent will not perform any indentation.
 178
 179 See `aggressive-indent--internal-dont-indent-if' for usage examples."
 180   :type '(repeat sexp)
 181   :group 'aggressive-indent
 182   :package-version '(aggressive-indent . "0.2"))
 183
 184 (defvar -error-message
 185   "One of the forms in `aggressive-indent-dont-indent-if' had the following error, I've disabled it until you fix it: %S"
 186   "Error message thrown by `aggressive-indent-dont-indent-if'.")
 187
 188 (defvar -has-errored nil
 189   "Keep track of whether `aggressive-indent-dont-indent-if' is throwing.
 190 This is used to prevent an infinite error loop on the user.")
 191
 192 (defun -run-user-hooks ()
 193   "Safely run forms in `aggressive-indent-dont-indent-if'.
 194 If any of them errors out, we only report it once until it stops
 195 erroring again."
 196   (and dont-indent-if
 197        (condition-case er
 198            (prog1 (eval (cons 'or dont-indent-if))
 199              (setq -has-errored nil))
 200          (error
 201           (unless -has-errored
 202             (setq -has-errored t)
 203             (message -error-message er))))))
 204
 205 (defmacro -do-softly (&rest body)
 206   "Execute body unobstrusively.
 207 This means: do nothing if mark is active (to avoid deactivaing
 208 it), or if buffer is not modified (to avoid creating accidental
 209 modifications), or if any of the forms in
 210 `aggressive-indent-dont-indent-if' evaluates to non-nil.
 211
 212 Also, never throw errors nor messages.
 213 Meant for use in functions which go in hooks."
 214   (declare (debug t))
 215   `(unless (or (run-hook-wrapped
 216                 'aggressive-indent--internal-dont-indent-if
 217                 #'eval)
 218                (aggressive-indent--run-user-hooks))
 219      (ignore-errors
 220        (cl-letf (((symbol-function 'message) #'ignore))
 221          ,@body))))
 222
 223 :autoload
 224 (defun indent-defun ()
 225   "Indent current defun.
 226 Throw an error if parentheses are unbalanced."
 227   (interactive)
 228   (let ((p (point-marker)))
 229     (set-marker-insertion-type p t)
 230     (indent-region
 231      (save-excursion (beginning-of-defun 1) (point))
 232      (save-excursion (end-of-defun 1) (point)))
 233     (goto-char p)))
 234
 235 (defun -softly-indent-defun ()
 236   "Indent current defun unobstrusively.
 237 Like `aggressive-indent-indent-defun', but wrapped in a
 238 `aggressive-indent--do-softly'."
 239   (unless (or (run-hook-wrapped
 240                'aggressive-indent--internal-dont-indent-if
 241                #'eval)
 242               (aggressive-indent--run-user-hooks))
 243     (ignore-errors
 244       (cl-letf (((symbol-function 'message) #'ignore))
 245         (indent-defun)))))
 246
 247 :autoload
 248 (defun indent-region-and-on (l r)
 249   "Indent region between L and R, and then some.
 250 Call `indent-region' between L and R, and then keep indenting
 251 until nothing more happens."
 252   (interactive "r")
 253   (let ((p (point-marker))
 254         was-begining-of-line)
 255     (set-marker-insertion-type p t)
 256     (goto-char r)
 257     (setq was-begining-of-line
 258           (= r (line-beginning-position)))
 259     ;; Indent the affected region.
 260     (unless (= l r) (indent-region l r))
 261     ;; `indent-region' doesn't do anything if R was the beginning of a line, so we indent manually there.
 262     (when was-begining-of-line
 263       (indent-according-to-mode))
 264     ;; And then we indent each following line until nothing happens.
 265     (forward-line 1)
 266     (while (/= (progn (skip-chars-forward "[:blank:]\n")
 267                       (point))
 268                (progn (indent-according-to-mode)
 269                       (point)))
 270       (forward-line 1))
 271     (goto-char p)))
 272
 273 (defun -softly-indent-region-and-on (l r &rest _)
 274   "Indent current defun unobstrusively.
 275 Like `aggressive-indent-indent-region-and-on', but wrapped in a
 276 `aggressive-indent--do-softly'."
 277   (unless (or (run-hook-wrapped
 278                'aggressive-indent--internal-dont-indent-if
 279                #'eval)
 280               (aggressive-indent--run-user-hooks))
 281     (ignore-errors
 282       (cl-letf (((symbol-function 'message) #'ignore))
 283         (indent-region-and-on l r)))))
 284
 285 (defvar changed-list-right nil
 286   "List of right limit of regions changed in the last command loop.")
 287
 288 (defvar changed-list-left nil
 289   "List of left limit of regions changed in the last command loop.")
 290
 291 (defun -indent-if-changed ()
 292   "Indent any region that changed in the last command loop."
 293   (let ((inhibit-modification-hooks t))
 294     (when changed-list-left
 295       (-softly-indent-region-and-on
 296        (apply #'min changed-list-left)
 297        (apply #'max changed-list-right))
 298       (setq changed-list-left nil
 299             changed-list-right nil))))
 300
 301 (defun -keep-track-of-changes (l r &rest _)
 302   "Store the limits of each change that happens in the buffer."
 303   (push l changed-list-left)
 304   (push r changed-list-right))
 305
 306 \f
 307 ;;; Minor modes
 308 :autoload
 309 (define-minor-mode mode nil nil " =>"
 310   '(("\C-c\C-q" . aggressive-indent-indent-defun))
 311   (if mode
 312       (if (and global-aggressive-indent-mode
 313                (or (cl-member-if #'derived-mode-p excluded-modes)
 314                    buffer-read-only))
 315           (mode -1)
 316         (when (fboundp 'electric-indent-local-mode)
 317           (electric-indent-local-mode 1))
 318         (if (cl-member-if #'derived-mode-p modes-to-prefer-defun)
 319             (add-hook 'post-command-hook #'-softly-indent-defun nil 'local)
 320           (add-hook 'after-change-functions #'-keep-track-of-changes nil 'local)
 321           (add-hook 'post-command-hook #'-indent-if-changed nil 'local)))
 322     ;; Clean the hooks
 323     (remove-hook 'after-change-functions #'-keep-track-of-changes 'local)
 324     (remove-hook 'post-command-hook #'-indent-if-changed 'local)
 325     (remove-hook 'post-command-hook #'-softly-indent-defun 'local)))
 326
 327 :autoload
 328 (define-globalized-minor-mode global-aggressive-indent-mode
 329   mode mode)
 330
 331 :autoload
 332 (defalias 'aggressive-indent-global-mode
 333   #'global-aggressive-indent-mode)
 334 )
 335
 336 (provide 'aggressive-indent)
 337 ;;; aggressive-indent.el ends here.