code.delx.au - gnu-emacs-elpa/blob - company-semantic.el

   1 ;;; company-semantic.el --- company-mode completion backend using Semantic
   2
   3 ;; Copyright (C) 2009-2011, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (require 'cl-lib)
  30
  31 (defvar semantic-idle-summary-function)
  32 (declare-function semantic-documentation-for-tag "semantic/doc" )
  33 (declare-function semantic-analyze-current-context "semantic/analyze")
  34 (declare-function semantic-analyze-possible-completions "semantic/complete")
  35 (declare-function semantic-analyze-find-tags-by-prefix "semantic/analyze/fcn")
  36 (declare-function semantic-tag-class "semantic/tag")
  37 (declare-function semantic-tag-name "semantic/tag")
  38 (declare-function semantic-tag-start "semantic/tag")
  39 (declare-function semantic-tag-buffer "semantic/tag")
  40 (declare-function semantic-active-p "semantic")
  41
  42 (defgroup company-semantic nil
  43   "Completion backend using Semantic."
  44   :group 'company)
  45
  46 (defcustom company-semantic-metadata-function 'company-semantic-summary-and-doc
  47   "The function turning a semantic tag into doc information."
  48   :type 'function)
  49
  50 (defvar company-semantic-modes '(c-mode c++-mode jde-mode java-mode))
  51
  52 (defvar-local company-semantic--current-tags nil
  53   "Tags for the current context.")
  54
  55 (defun company-semantic-documentation-for-tag (tag)
  56   (when (semantic-tag-buffer tag)
  57     ;; When TAG's buffer is unknown, the function below raises an error.
  58     (semantic-documentation-for-tag tag)))
  59
  60 (defun company-semantic-doc-or-summary (tag)
  61   (or (company-semantic-documentation-for-tag tag)
  62       (and (require 'semantic-idle nil t)
  63            (require 'semantic/idle nil t)
  64            (funcall semantic-idle-summary-function tag nil t))))
  65
  66 (defun company-semantic-summary-and-doc (tag)
  67   (let ((doc (company-semantic-documentation-for-tag tag))
  68         (summary (funcall semantic-idle-summary-function tag nil t)))
  69     (and (stringp doc)
  70          (string-match "\n*\\(.*\\)$" doc)
  71          (setq doc (match-string 1 doc)))
  72     (concat summary
  73             (when doc
  74                   (if (< (+ (length doc) (length summary) 4) (window-width))
  75                       " -- "
  76                     "\n"))
  77             doc)))
  78
  79 (defun company-semantic-doc-buffer (tag)
  80   (let ((doc (company-semantic-documentation-for-tag tag)))
  81     (when doc
  82       (company-doc-buffer
  83        (concat (funcall semantic-idle-summary-function tag nil t)
  84                "\n"
  85                doc)))))
  86
  87 (defsubst company-semantic-completions (prefix)
  88   (ignore-errors
  89     (let ((completion-ignore-case nil)
  90           (context (semantic-analyze-current-context)))
  91       (setq company-semantic--current-tags
  92             (semantic-analyze-possible-completions context))
  93       (all-completions prefix company-semantic--current-tags))))
  94
  95 (defun company-semantic-completions-raw (prefix)
  96   (setq company-semantic--current-tags nil)
  97   (dolist (tag (semantic-analyze-find-tags-by-prefix prefix))
  98     (unless (eq (semantic-tag-class tag) 'include)
  99       (push tag company-semantic--current-tags)))
 100   (delete "" (mapcar 'semantic-tag-name company-semantic--current-tags)))
 101
 102 (defun company-semantic-annotation (argument tags)
 103   (let* ((tag (assoc argument tags))
 104          (kind (when tag (elt tag 1))))
 105     (cl-case kind
 106       (function (let* ((prototype (semantic-format-tag-prototype tag nil nil))
 107                        (par-pos (string-match "(" prototype)))
 108                   (when par-pos (substring prototype par-pos)))))))
 109
 110 (defun company-semantic--pre-prefix-length (prefix-length)
 111   "Sum up the length of all chained symbols before POS.
 112 Symbols are chained by \".\" or \"->\"."
 113   (save-excursion
 114     (let ((pos (point)))
 115       (goto-char (- (point) prefix-length))
 116       (while (looking-back "->\\|\\.")
 117         (goto-char (match-beginning 0))
 118         (skip-syntax-backward "w_"))
 119       (- pos (point)))))
 120
 121 (defun company-semantic--grab ()
 122   "Grab the semantic prefix, but return everything before -> or . as length."
 123   (let ((symbol (company-grab-symbol)))
 124     (when symbol
 125       (cons symbol (company-semantic--pre-prefix-length (length symbol))))))
 126
 127 ;;;###autoload
 128 (defun company-semantic (command &optional arg &rest ignored)
 129   "`company-mode' completion backend using CEDET Semantic."
 130   (interactive (list 'interactive))
 131   (cl-case command
 132     (interactive (company-begin-backend 'company-semantic))
 133     (prefix (and (featurep 'semantic)
 134                  (semantic-active-p)
 135                  (memq major-mode company-semantic-modes)
 136                  (not (company-in-string-or-comment))
 137                  (or (company-semantic--grab) 'stop)))
 138     (candidates (if (and (equal arg "")
 139                          (not (looking-back "->\\|\\.")))
 140                     (company-semantic-completions-raw arg)
 141                   (company-semantic-completions arg)))
 142     (meta (funcall company-semantic-metadata-function
 143                    (assoc arg company-semantic--current-tags)))
 144     (annotation (company-semantic-annotation arg
 145                                              company-semantic--current-tags))
 146     (doc-buffer (company-semantic-doc-buffer
 147                  (assoc arg company-semantic--current-tags)))
 148     ;; Because "" is an empty context and doesn't return local variables.
 149     (no-cache (equal arg ""))
 150     (location (let ((tag (assoc arg company-semantic--current-tags)))
 151                 (when (buffer-live-p (semantic-tag-buffer tag))
 152                   (cons (semantic-tag-buffer tag)
 153                         (semantic-tag-start tag)))))))
 154
 155 (provide 'company-semantic)
 156 ;;; company-semantic.el ends here