code.delx.au - gnu-emacs-elpa/blob - yasnippet-tests.el

   1 ;;; yasnippet-tests.el --- some yasnippet tests
   2
   3 ;; Copyright (C) 2012  João Távora
   4
   5 ;; Author: João Távora <joaot@siscog.pt>
   6 ;; Keywords: emulations, convenience
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; Test basic snippet mechanics and the loading system
  24
  25 ;;; Code:
  26
  27 (require 'yasnippet)
  28 (require 'ert)
  29 (require 'ert-x)
  30
  31 \f
  32 ;;; Snippet mechanics
  33
  34 (defun yas--buffer-contents ()
  35   (buffer-substring-no-properties (point-min) (point-max)))
  36
  37 (ert-deftest field-navigation ()
  38   (with-temp-buffer
  39     (yas-minor-mode 1)
  40     (yas-expand-snippet "${1:brother} from another ${2:mother}")
  41     (should (string= (yas--buffer-contents)
  42                      "brother from another mother"))
  43
  44     (should (looking-at "brother"))
  45     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  46     (should (looking-at "mother"))
  47     (ert-simulate-command '(yas-prev-field))
  48     (should (looking-at "brother"))))
  49
  50 (ert-deftest simple-mirror ()
  51   (with-temp-buffer
  52     (yas-minor-mode 1)
  53     (yas-expand-snippet "${1:brother} from another $1")
  54     (should (string= (yas--buffer-contents)
  55                      "brother from another brother"))
  56     (ert-simulate-command `(yas-mock-insert "bla"))
  57     (should (string= (yas--buffer-contents)
  58                      "bla from another bla"))))
  59
  60 (ert-deftest mirror-with-transformation ()
  61   (with-temp-buffer
  62     (yas-minor-mode 1)
  63     (yas-expand-snippet "${1:brother} from another ${1:$(upcase yas-text)}")
  64     (should (string= (yas--buffer-contents)
  65                      "brother from another BROTHER"))
  66     (ert-simulate-command `(yas-mock-insert "bla"))
  67     (should (string= (yas--buffer-contents)
  68                      "bla from another BLA"))))
  69
  70 (ert-deftest primary-field-transformation ()
  71   (with-temp-buffer
  72     (yas-minor-mode 1)
  73     (let ((snippet "${1:$$(upcase yas-text)}${1:$(concat \"bar\" yas-text)}"))
  74       (yas-expand-snippet snippet)
  75       (should (string= (yas--buffer-contents) "bar"))
  76       (ert-simulate-command `(yas-mock-insert "foo"))
  77       (should (string= (yas--buffer-contents) "FOObarFOO")))))
  78
  79 (ert-deftest nested-placeholders-kill-superfield ()
  80   (with-temp-buffer
  81     (yas-minor-mode 1)
  82     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  83     (should (string= (yas--buffer-contents)
  84                      "brother from another mother!"))
  85     (ert-simulate-command `(yas-mock-insert "bla"))
  86     (should (string= (yas--buffer-contents)
  87                      "brother from bla!"))))
  88
  89 (ert-deftest nested-placeholders-use-subfield ()
  90   (with-temp-buffer
  91     (yas-minor-mode 1)
  92     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
  93     (ert-simulate-command '(yas-next-field-or-maybe-expand))
  94     (ert-simulate-command `(yas-mock-insert "bla"))
  95     (should (string= (yas--buffer-contents)
  96                      "brother from another bla!"))))
  97
  98 (ert-deftest mirrors-adjacent-to-fields-with-nested-mirrors ()
  99   (with-temp-buffer
 100     (yas-minor-mode 1)
 101     (yas-expand-snippet "<%= f.submit \"${1:Submit}\"${2:$(and (yas-text) \", :disable_with => '\")}${2:$1ing...}${2:$(and (yas-text) \"'\")} %>")
 102     (should (string= (yas--buffer-contents)
 103                      "<%= f.submit \"Submit\", :disable_with => 'Submiting...' %>"))
 104     (ert-simulate-command `(yas-mock-insert "Send"))
 105     (should (string= (yas--buffer-contents)
 106                      "<%= f.submit \"Send\", :disable_with => 'Sending...' %>"))))
 107
 108 (ert-deftest deep-nested-mirroring-issue-351 ()
 109   (with-temp-buffer
 110     (yas-minor-mode 1)
 111     (yas-expand-snippet "${1:FOOOOOOO}${2:$1}${3:$2}${4:$3}")
 112     (ert-simulate-command `(yas-mock-insert "abc"))
 113     (should (string= (yas--buffer-contents) "abcabcabcabc"))))
 114
 115 ;; (ert-deftest in-snippet-undo ()
 116 ;;   (with-temp-buffer
 117 ;;     (yas-minor-mode 1)
 118 ;;     (yas-expand-snippet "brother from ${2:another ${3:mother}}!")
 119 ;;     (ert-simulate-command '(yas-next-field-or-maybe-expand))
 120 ;;     (ert-simulate-command `(yas-mock-insert "bla"))
 121 ;;     (ert-simulate-command '(undo))
 122 ;;     (should (string= (yas--buffer-contents)
 123 ;;                      "brother from another mother!"))))
 124
 125 \f
 126 ;;; Snippet expansion and character escaping
 127 ;;; Thanks to @zw963 (Billy) for the testing
 128 ;;;
 129 (ert-deftest escape-dollar ()
 130   (with-temp-buffer
 131     (yas-minor-mode 1)
 132     (yas-expand-snippet "bla\\${1:bla}ble")
 133     (should (string= (yas--buffer-contents) "bla${1:bla}ble"))))
 134
 135 (ert-deftest escape-closing-brace ()
 136   (with-temp-buffer
 137     (yas-minor-mode 1)
 138     (yas-expand-snippet "bla${1:bla\\}}ble")
 139     (should (string= (yas--buffer-contents) "blabla}ble"))
 140     (should (string= (yas-field-value 1) "bla}"))))
 141
 142 (ert-deftest escape-backslashes ()
 143   (with-temp-buffer
 144     (yas-minor-mode 1)
 145     (yas-expand-snippet "bla\\ble")
 146     (should (string= (yas--buffer-contents) "bla\\ble"))))
 147
 148 (ert-deftest escape-backquotes ()
 149   (with-temp-buffer
 150     (yas-minor-mode 1)
 151     (yas-expand-snippet "bla`(upcase \"foo\\`bar\")`ble")
 152     (should (string= (yas--buffer-contents) "blaFOO`BARble"))))
 153
 154 (ert-deftest escape-some-elisp-with-strings ()
 155   "elisp with strings and unbalance parens inside it"
 156   (with-temp-buffer
 157     (yas-minor-mode 1)
 158     ;; The rules here is: to output a literal `"' you need to escape
 159     ;; it with one backslash. You don't need to escape them in
 160     ;; embedded elisp.
 161     (yas-expand-snippet "soon \\\"`(concat (upcase \"(my arms\")\"\\\" were all around her\")`")
 162     (should (string= (yas--buffer-contents) "soon \"(MY ARMS\" were all around her"))))
 163
 164 (ert-deftest escape-some-elisp-with-backslashes ()
 165   (with-temp-buffer
 166     (yas-minor-mode 1)
 167     ;; And the rule here is: to output a literal `\' inside a string
 168     ;; inside embedded elisp you need a total of six `\'
 169     (yas-expand-snippet "bla`(upcase \"hey\\\\\\yo\")`ble")
 170     (should (string= (yas--buffer-contents) "blaHEY\\YOble"))))
 171
 172 (ert-deftest be-careful-when-escaping-in-yas-selected-text ()
 173   (with-temp-buffer
 174     (yas-minor-mode 1)
 175     (let ((yas-selected-text "He\\\\o world!"))
 176       (yas-expand-snippet "Look ma! `(yas-selected-text)`")
 177       (should (string= (yas--buffer-contents) "Look ma! He\\\\o world!")))
 178     (yas-exit-all-snippets)
 179     (erase-buffer)
 180     (let ((yas-selected-text "He\"o world!"))
 181       (yas-expand-snippet "Look ma! `(yas-selected-text)`")
 182       (should (string= (yas--buffer-contents) "Look ma! He\"o world!")))
 183     (yas-exit-all-snippets)
 184     (erase-buffer)
 185     (let ((yas-selected-text "He\"\)\\o world!"))
 186       (yas-expand-snippet "Look ma! `(yas-selected-text)`")
 187       (should (string= (yas--buffer-contents) "Look ma! He\"\)\\o world!")))
 188     (yas-exit-all-snippets)
 189     (erase-buffer)))
 190
 191 (ert-deftest be-careful-when-escaping-in-yas-selected-text-2 ()
 192   (with-temp-buffer
 193     (let ((yas-selected-text "He)}o world!"))
 194       (yas-expand-snippet "Look ma! ${1:`(yas-selected-text)`} OK?")
 195       (should (string= (yas--buffer-contents) "Look ma! He)}o world! OK?")))))
 196
 197 (ert-deftest example-for-issue-271 ()
 198   (with-temp-buffer
 199     (yas-minor-mode 1)
 200     (let ((yas-selected-text "aaa")
 201           (snippet "if ${1:condition}\n`yas-selected-text`\nelse\n$3\nend"))
 202       (yas-expand-snippet snippet)
 203       (yas-next-field)
 204       (ert-simulate-command `(yas-mock-insert "bbb"))
 205       (should (string= (yas--buffer-contents) "if condition\naaa\nelse\nbbb\nend")))))
 206
 207 (ert-deftest another-example-for-issue-271 ()
 208   ;; expect this to fail in batch mode since `region-active-p' doesn't
 209   ;; used by `yas-expand-snippet' doesn't make sense in that context.
 210   ;;
 211   :expected-result (if noninteractive
 212                        :failed
 213                      :passed)
 214   (with-temp-buffer
 215     (yas-minor-mode 1)
 216     (let ((snippet "\\${${1:1}:`yas-selected-text`}"))
 217       (insert "aaabbbccc")
 218       (set-mark 4)
 219       (goto-char 7)
 220       (yas-expand-snippet snippet)
 221       (should (string= (yas--buffer-contents) "aaa${1:bbb}ccc")))))
 222
 223 (ert-deftest string-match-with-subregexp-in-embedded-elisp ()
 224   (with-temp-buffer
 225     (yas-minor-mode 1)
 226     ;; the rule here is: To use regexps in embedded `(elisp)` expressions, write
 227     ;; it like you would normal elisp, i.e. no need to escape the backslashes.
 228     (let ((snippet "`(if (string-match \"foo\\\\(ba+r\\\\)foo\" \"foobaaaaaaaaaarfoo\")
 229                          \"ok\"
 230                          \"fail\")`"))
 231       (yas-expand-snippet snippet))
 232     (should (string= (yas--buffer-contents) "ok"))))
 233
 234 (ert-deftest string-match-with-subregexp-in-mirror-transformations ()
 235   (with-temp-buffer
 236     (yas-minor-mode 1)
 237     ;; the rule here is: To use regexps in embedded `(elisp)` expressions,
 238     ;; escape backslashes once, i.e. to use \\( \\) constructs, write \\\\( \\\\).
 239     (let ((snippet "$1${1:$(if (string-match \"foo\\\\\\\\(ba+r\\\\\\\\)baz\" yas-text)
 240                                 \"ok\"
 241                                 \"fail\")}"))
 242       (yas-expand-snippet snippet)
 243       (should (string= (yas--buffer-contents) "fail"))
 244       (ert-simulate-command `(yas-mock-insert "foobaaar"))
 245       (should (string= (yas--buffer-contents) "foobaaarfail"))
 246       (ert-simulate-command `(yas-mock-insert "baz"))
 247       (should (string= (yas--buffer-contents) "foobaaarbazok")))))
 248
 249 \f
 250 ;;; Misc tests
 251 ;;;
 252 (ert-deftest protection-overlay-no-cheating ()
 253   "Protection overlays at the very end of the buffer are dealt
 254   with by cheatingly inserting a newline!
 255
 256 TODO: correct this bug!"
 257   :expected-result :failed
 258   (with-temp-buffer
 259     (yas-minor-mode 1)
 260     (yas-expand-snippet "${2:brother} from another ${1:mother}")
 261     (should (string= (yas--buffer-contents)
 262                      "brother from another mother") ;; no newline should be here!
 263             )))
 264 \f
 265 ;;; Loading
 266 ;;;
 267 (defun yas--call-with-temporary-redefinitions (function
 268                                                &rest function-names-and-overriding-functions)
 269   (let* ((overrides (remove-if-not #'(lambda (fdef)
 270                                        (fboundp (first fdef)))
 271                                    function-names-and-overriding-functions))
 272          (definition-names (mapcar #'first overrides))
 273          (overriding-functions (mapcar #'second overrides))
 274          (saved-functions (mapcar #'symbol-function definition-names)))
 275     ;; saving all definitions before overriding anything ensures FDEFINITION
 276     ;; errors don't cause accidental permanent redefinitions.
 277     ;;
 278     (cl-flet ((set-fdefinitions (names functions)
 279                                 (loop for name in names
 280                                       for fn in functions
 281                                       do (fset name fn))))
 282       (set-fdefinitions definition-names overriding-functions)
 283       (unwind-protect (funcall function)
 284         (set-fdefinitions definition-names saved-functions)))))
 285
 286 (defmacro yas--with-temporary-redefinitions (fdefinitions &rest body)
 287   ;; "Temporarily (but globally) redefine each function in FDEFINITIONS.
 288   ;; E.g.: (yas--with-temporary-redefinitions ((foo (x) ...)
 289   ;;                                           (bar (x) ...))
 290   ;;         ;; code that eventually calls foo, bar of (setf foo)
 291   ;;         ...)"
 292   ;; FIXME: This is hideous!  Better use defadvice (or at least letf).
 293   `(yas--call-with-temporary-redefinitions
 294     (lambda () ,@body)
 295     ,@(mapcar #'(lambda (thingy)
 296                   `(list ',(first thingy)
 297                          (lambda ,@(rest thingy))))
 298               fdefinitions)))
 299
 300 (defmacro yas-with-overriden-buffer-list (&rest body)
 301   (let ((saved-sym (make-symbol "yas--buffer-list")))
 302     `(let ((,saved-sym (symbol-function 'buffer-list)))
 303        (yas--with-temporary-redefinitions
 304            ((buffer-list ()
 305                          (remove-if #'(lambda (buf)
 306                                         (with-current-buffer buf
 307                                           (eq major-mode 'lisp-interaction-mode)))
 308                                     (funcall ,saved-sym))))
 309          ,@body))))
 310
 311 (defmacro yas-with-some-interesting-snippet-dirs (&rest body)
 312   `(yas-saving-variables
 313     (yas-with-overriden-buffer-list
 314      (yas-with-snippet-dirs
 315        '((".emacs.d/snippets"
 316           ("c-mode"
 317            (".yas-parents" . "cc-mode")
 318            ("printf" . "printf($1);"))  ;; notice the overriding for issue #281
 319           ("emacs-lisp-mode" ("ert-deftest" . "(ert-deftest ${1:name} () $0)"))
 320           ("lisp-interaction-mode" (".yas-parents" . "emacs-lisp-mode")))
 321          ("library/snippets"
 322           ("c-mode"
 323            (".yas-parents" . "c++-mode")
 324            ("printf" . "printf"))
 325           ("cc-mode" ("def" . "# define"))
 326           ("emacs-lisp-mode" ("dolist" . "(dolist)"))
 327           ("lisp-interaction-mode" ("sc" . "brother from another mother"))))
 328        ,@body))))
 329
 330 (ert-deftest basic-jit-loading ()
 331   "Test basic loading and expansion of snippets"
 332   (yas-with-some-interesting-snippet-dirs
 333    (yas-reload-all)
 334    (yas--basic-jit-loading-1)))
 335
 336 (ert-deftest basic-jit-loading-with-compiled-snippets ()
 337   "Test basic loading and expansion of snippets"
 338   (yas-with-some-interesting-snippet-dirs
 339    (yas-reload-all)
 340    (yas-recompile-all)
 341    (yas--with-temporary-redefinitions ((yas--load-directory-2
 342                                         (&rest _dummies)
 343                                         (ert-fail "yas--load-directory-2 shouldn't be called when snippets have been compiled")))
 344      (yas-reload-all)
 345      (yas--basic-jit-loading-1))))
 346
 347 (ert-deftest loading-with-cyclic-parenthood ()
 348   "Test loading when cyclic parenthood is setup."
 349   (yas-saving-variables
 350    (yas-with-snippet-dirs '((".emacs.d/snippets"
 351                              ("c-mode"
 352                               (".yas-parents" . "cc-mode"))
 353                              ("cc-mode"
 354                               (".yas-parents" . "yet-another-c-mode"))
 355                              ("yet-another-c-mode"
 356                               (".yas-parents" . "c-mode"))))
 357      (yas-reload-all)
 358      (condition-case nil
 359          (yas--all-parents 'c-mode)
 360        (error
 361         (ert-fail "cyclic parenthood test failed"))))))
 362
 363 (defun yas--basic-jit-loading-1 ()
 364   (with-temp-buffer
 365     (should (= 4 (hash-table-count yas--scheduled-jit-loads)))
 366     (should (= 0 (hash-table-count yas--tables)))
 367     (lisp-interaction-mode)
 368     (yas-minor-mode 1)
 369     (should (= 2 (hash-table-count yas--scheduled-jit-loads)))
 370     (should (= 2 (hash-table-count yas--tables)))
 371     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'lisp-interaction-mode yas--tables)))))
 372     (should (= 2 (hash-table-count (yas--table-uuidhash (gethash 'emacs-lisp-mode yas--tables)))))
 373     (yas-should-expand '(("sc" . "brother from another mother")
 374                          ("dolist" . "(dolist)")
 375                          ("ert-deftest" . "(ert-deftest name () )")))
 376     (c-mode)
 377     (yas-minor-mode 1)
 378     (should (= 0 (hash-table-count yas--scheduled-jit-loads)))
 379     (should (= 4 (hash-table-count yas--tables)))
 380     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'c-mode yas--tables)))))
 381     (should (= 1 (hash-table-count (yas--table-uuidhash (gethash 'cc-mode yas--tables)))))
 382     (yas-should-expand '(("printf" . "printf();")
 383                          ("def" . "# define")))
 384     (yas-should-not-expand '("sc" "dolist" "ert-deftest"))))
 385
 386 \f
 387 ;;; Menu
 388 ;;;
 389 (defmacro yas-with-even-more-interesting-snippet-dirs (&rest body)
 390   `(yas-saving-variables
 391     (yas-with-snippet-dirs
 392       `((".emacs.d/snippets"
 393          ("c-mode"
 394           (".yas-make-groups" . "")
 395           ("printf" . "printf($1);")
 396           ("foo-group-a"
 397            ("fnprintf" . "fprintf($1);")
 398            ("snprintf" . "snprintf($1);"))
 399           ("foo-group-b"
 400            ("strcmp" . "strecmp($1);")
 401            ("strcasecmp" . "strcasecmp($1);")))
 402          ("lisp-interaction-mode"
 403           ("ert-deftest" . "# group: barbar\n# --\n(ert-deftest ${1:name} () $0)"))
 404          ("fancy-mode"
 405           ("a-guy" . "# uuid: 999\n# --\nyo!")
 406           ("a-sir" . "# uuid: 12345\n# --\nindeed!")
 407           ("a-lady" . "# uuid: 54321\n# --\noh-la-la!")
 408           ("a-beggar" . "# uuid: 0101\n# --\narrrgh!")
 409           ("an-outcast" . "# uuid: 666\n# --\narrrgh!")
 410           (".yas-setup.el" . , (pp-to-string
 411                                 '(yas-define-menu 'fancy-mode
 412                                                   '((yas-ignore-item "0101")
 413                                                     (yas-item "999")
 414                                                     (yas-submenu "sirs"
 415                                                                  ((yas-item "12345")))
 416                                                     (yas-submenu "ladies"
 417                                                                  ((yas-item "54321"))))
 418                                                   '("666")))))))
 419       ,@body)))
 420
 421 (ert-deftest test-yas-define-menu ()
 422   (let ((yas-use-menu t))
 423     (yas-with-even-more-interesting-snippet-dirs
 424      (yas-reload-all 'no-jit)
 425      (let ((menu (cdr (gethash 'fancy-mode yas--menu-table))))
 426        (should (eql 4 (length menu)))
 427        (dolist (item '("a-guy" "a-beggar"))
 428          (should (find item menu :key #'third :test #'string=)))
 429        (should-not (find "an-outcast" menu :key #'third :test #'string=))
 430        (dolist (submenu '("sirs" "ladies"))
 431          (should (keymapp
 432                   (fourth
 433                    (find submenu menu :key #'third :test #'string=)))))
 434        ))))
 435
 436 (ert-deftest test-group-menus ()
 437   "Test group-based menus using .yas-make-groups and the group directive"
 438   (let ((yas-use-menu t))
 439     (yas-with-even-more-interesting-snippet-dirs
 440      (yas-reload-all 'no-jit)
 441      ;; first the subdir-based groups
 442      ;;
 443      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 444        (should (eql 3 (length menu)))
 445        (dolist (item '("printf" "foo-group-a" "foo-group-b"))
 446          (should (find item menu :key #'third :test #'string=)))
 447        (dolist (submenu '("foo-group-a" "foo-group-b"))
 448          (should (keymapp
 449                   (fourth
 450                    (find submenu menu :key #'third :test #'string=))))))
 451      ;; now group directives
 452      ;;
 453      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 454        (should (eql 1 (length menu)))
 455        (should (find "barbar" menu :key #'third :test #'string=))
 456        (should (keymapp
 457                 (fourth
 458                  (find "barbar" menu :key #'third :test #'string=))))))))
 459
 460 (ert-deftest test-group-menus-twisted ()
 461   "Same as similarly named test, but be mean.
 462
 463 TODO: be meaner"
 464   (let ((yas-use-menu t))
 465     (yas-with-even-more-interesting-snippet-dirs
 466      ;; add a group directive conflicting with the subdir and watch
 467      ;; behaviour
 468      (with-temp-buffer
 469        (insert "# group: foo-group-c\n# --\nstrecmp($1)")
 470        (write-region nil nil (concat (first (yas-snippet-dirs))
 471                                      "/c-mode/foo-group-b/strcmp")))
 472      (yas-reload-all 'no-jit)
 473      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 474        (should (eql 4 (length menu)))
 475        (dolist (item '("printf" "foo-group-a" "foo-group-b" "foo-group-c"))
 476          (should (find item menu :key #'third :test #'string=)))
 477        (dolist (submenu '("foo-group-a" "foo-group-b" "foo-group-c"))
 478          (should (keymapp
 479                   (fourth
 480                    (find submenu menu :key #'third :test #'string=))))))
 481      ;; delete the .yas-make-groups file and watch behaviour
 482      ;;
 483      (delete-file (concat (first (yas-snippet-dirs))
 484                           "/c-mode/.yas-make-groups"))
 485      (yas-reload-all 'no-jit)
 486      (let ((menu (cdr (gethash 'c-mode yas--menu-table))))
 487        (should (eql 5 (length menu))))
 488      ;; Change a group directive and reload
 489      ;;
 490      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 491        (should (find "barbar" menu :key #'third :test #'string=)))
 492
 493      (with-temp-buffer
 494        (insert "# group: foofoo\n# --\n(ert-deftest ${1:name} () $0)")
 495        (write-region nil nil (concat (first (yas-snippet-dirs))
 496                                      "/lisp-interaction-mode/ert-deftest")))
 497      (yas-reload-all 'no-jit)
 498      (let ((menu (cdr (gethash 'lisp-interaction-mode yas--menu-table))))
 499        (should (eql 1 (length menu)))
 500        (should (find "foofoo" menu :key #'third :test #'string=))
 501        (should (keymapp
 502                 (fourth
 503                  (find "foofoo" menu :key #'third :test #'string=))))))))
 504
 505 \f
 506 ;;; The infamous and problematic tab keybinding
 507 ;;;
 508 (ert-deftest test-yas-tab-binding ()
 509   (with-temp-buffer
 510     (yas-minor-mode -1)
 511     (should (not (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand)))
 512     (yas-minor-mode 1)
 513     (should (eq (key-binding (yas--read-keybinding "<tab>")) 'yas-expand))
 514     (yas-expand-snippet "$1 $2 $3")
 515     (should (eq (key-binding [(tab)]) 'yas-next-field-or-maybe-expand))
 516     (should (eq (key-binding (kbd "TAB")) 'yas-next-field-or-maybe-expand))
 517     (should (eq (key-binding [(shift tab)]) 'yas-prev-field))
 518     (should (eq (key-binding [backtab]) 'yas-prev-field))))
 519
 520 (ert-deftest test-rebindings ()
 521   (unwind-protect
 522       (progn
 523         (define-key yas-minor-mode-map [tab] nil)
 524         (define-key yas-minor-mode-map (kbd "TAB") nil)
 525         (define-key yas-minor-mode-map (kbd "SPC") 'yas-expand)
 526         (with-temp-buffer
 527           (yas-minor-mode 1)
 528           (should (not (eq (key-binding (yas--read-keybinding "TAB")) 'yas-expand)))
 529           (should (eq (key-binding (yas--read-keybinding "SPC")) 'yas-expand))
 530           (yas-reload-all)
 531           (should (not (eq (key-binding (yas--read-keybinding "TAB")) 'yas-expand)))
 532           (should (eq (key-binding (yas--read-keybinding "SPC")) 'yas-expand))))
 533     (setcdr yas-minor-mode-map (cdr (yas--init-minor-keymap)))))
 534
 535 (ert-deftest test-yas-in-org ()
 536   (with-temp-buffer
 537     (org-mode)
 538     (yas-minor-mode 1)
 539     (should (eq (key-binding [(tab)]) 'yas-expand))
 540     (should (eq (key-binding (kbd "TAB")) 'yas-expand))))
 541
 542 \f
 543 ;;; Helpers
 544 ;;;
 545 (defun yas-batch-run-tests ()
 546   (interactive)
 547   (with-temp-buffer
 548     (yas--with-temporary-redefinitions
 549         ((message (&rest _args) nil))
 550       (ert t (buffer-name (current-buffer)))
 551       (princ (buffer-string)))))
 552
 553
 554 (defun yas-should-expand (keys-and-expansions)
 555   (dolist (key-and-expansion keys-and-expansions)
 556     (yas-exit-all-snippets)
 557     (erase-buffer)
 558     (insert (car key-and-expansion))
 559     (let ((yas-fallback-behavior nil))
 560       (ert-simulate-command '(yas-expand)))
 561     (should (string= (yas--buffer-contents) (cdr key-and-expansion))))
 562   (yas-exit-all-snippets))
 563
 564 (defun yas-should-not-expand (keys)
 565   (dolist (key keys)
 566     (yas-exit-all-snippets)
 567     (erase-buffer)
 568     (insert key)
 569     (let ((yas-fallback-behavior nil))
 570       (ert-simulate-command '(yas-expand)))
 571     (should (string= (yas--buffer-contents) key))))
 572
 573 (defun yas-mock-insert (string)
 574   (interactive)
 575   (do ((i 0 (1+ i)))
 576       ((= i (length string)))
 577     (insert (aref string i))))
 578
 579 (defun yas-make-file-or-dirs (ass)
 580   (let ((file-or-dir-name (car ass))
 581         (content (cdr ass)))
 582     (cond ((listp content)
 583            (make-directory file-or-dir-name 'parents)
 584            (let ((default-directory (concat default-directory "/" file-or-dir-name)))
 585              (mapc #'yas-make-file-or-dirs content)))
 586           ((stringp content)
 587            (with-temp-buffer
 588              (insert content)
 589              (write-region nil nil file-or-dir-name nil 'nomessage)))
 590           (t
 591            (message "[yas] oops don't know this content")))))
 592
 593
 594 (defun yas-variables ()
 595   (let ((syms))
 596     (mapatoms #'(lambda (sym)
 597                   (if (and (string-match "^yas-[^/]" (symbol-name sym))
 598                            (boundp sym))
 599                       (push sym syms))))
 600     syms))
 601
 602 (defun yas-call-with-saving-variables (fn)
 603   (let* ((vars (yas-variables))
 604          (saved-values (mapcar #'symbol-value vars)))
 605     (unwind-protect
 606         (funcall fn)
 607       (loop for var in vars
 608             for saved in saved-values
 609             do (set var saved)))))
 610
 611 (defmacro yas-saving-variables (&rest body)
 612   `(yas-call-with-saving-variables #'(lambda () ,@body)))
 613
 614
 615 (defun yas-call-with-snippet-dirs (dirs fn)
 616   (let* ((default-directory (make-temp-file "yasnippet-fixture" t))
 617          (yas-snippet-dirs (mapcar #'car dirs)))
 618     (with-temp-message ""
 619       (unwind-protect
 620           (progn
 621             (mapc #'yas-make-file-or-dirs dirs)
 622             (funcall fn))
 623         (when (>= emacs-major-version 24)
 624           (delete-directory default-directory 'recursive))))))
 625
 626 (defmacro yas-with-snippet-dirs (dirs &rest body)
 627   (declare (indent defun))
 628   `(yas-call-with-snippet-dirs ,dirs
 629                                #'(lambda ()
 630                                    ,@body)))
 631
 632 ;;; Older emacsen
 633 ;;;
 634 (unless (fboundp 'special-mode)
 635   ;; FIXME: Why provide this default definition here?!?
 636   (defalias 'special-mode 'fundamental))
 637
 638 ;;; btw to test this in emacs22 mac osx:
 639 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert.el
 640 ;;; curl -L -O https://github.com/mirrors/emacs/raw/master/lisp/emacs-lisp/ert-x.el
 641 ;;; /usr/bin/emacs -nw -Q -L . -l yasnippet-tests.el --batch -e ert
 642
 643
 644 (put 'yas-saving-variables                   'edebug-form-spec t)
 645 (put 'yas-with-snippet-dirs                  'edebug-form-spec t)
 646 (put 'yas-with-overriden-buffer-list         'edebug-form-spec t)
 647 (put 'yas-with-some-interesting-snippet-dirs 'edebug-form-spec t)
 648
 649
 650 (put 'yas--with-temporary-redefinitions 'lisp-indent-function 1)
 651 (put 'yas--with-temporary-redefinitions 'edebug-form-spec '((&rest (defun*)) cl-declarations body))
 652
 653
 654
 655
 656 (provide 'yasnippet-tests)
 657 ;;; yasnippet-tests.el ends here
 658 ;; Local Variables:
 659 ;; lexical-binding: t
 660 ;; byte-compile-warnings: (not cl-functions)
 661 ;; End: