code.delx.au - gnu-emacs-elpa/blob - packages/nameless/nameless.el

   1 ;;; nameless.el --- Hide package namespace in your emacs-lisp code  -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Artur Malabarba <emacs@endlessparentheses.com>
   6 ;; Keywords: convenience, lisp
   7 ;; Version: 0.2
   8 ;; Package-Requires: ((emacs "24.2"))
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Usage
  26 ;; ─────
  27 ;;
  28 ;;   To use this package add the following configuration to your Emacs init
  29 ;;   file.
  30 ;;
  31 ;;   ┌────
  32 ;;   │ (add-hook 'emacs-lisp-mode-hook #'nameless-mode)
  33 ;;   └────
  34 ;;
  35 ;;   You can configure a string to use instead of `:' by setting the
  36 ;;   `nameless-prefix', and the name of the face used is `nameless-face'.
  37 ;;
  38 ;;   While the mode is active, the `_' key inserts the package
  39 ;;   namespace if appropriate.
  40
  41 ;;; Code:
  42 (require 'lisp-mnt)
  43
  44 (defgroup nameless nil
  45   "Customization group for nameless."
  46   :group 'emacs)
  47
  48 (defcustom nameless-prefix ":"
  49   "Prefix displayed instead of package namespace."
  50   :type 'string)
  51
  52 (defcustom nameless-global-aliases '(("fl" . "font-lock"))
  53   "Alist from aliases to namespaces.
  54 This alist is used everywhere.  It is designed for namespaces you
  55 use commonly.  To apply aliases specific to a file, set the
  56 `nameless-aliases' variable with `add-file-local-variable'.
  57
  58 Each element of this list should have the form (ALIAS . NAMESPACE),
  59 both strings.  For example, if you set this variable to
  60           ((\"fl\" . \"font-lock\"))
  61 then expressions like `(font-lock-add-keywords nil kwds)' will
  62 displayed as `(fl/add-keywords nil kwds)' instead.
  63
  64 Furthermore typing `fl' followed by `\\[nameless-insert-name]' will
  65 automatically insert `font-lock-'."
  66   :type '(alist string string))
  67
  68 (defvar nameless-aliases nil
  69   "Alist from namespaces to aliases.
  70 Samse syntax as `nameless-global-aliases', but designed to be
  71 used as a file-local variable.")
  72
  73 (defface nameless-face
  74   '((t :inherit font-lock-type-face))
  75   "Face used on `nameless-prefix'")
  76
  77 (defcustom nameless-affect-indentation-and-filling 'outside-strings
  78   "If non-nil, code is indented and filled according to what you see.
  79 If nil, code is indented and filled according to its actual content.
  80 If the value is `outside-strings', behave like nil inside strings
  81 and behave like t otherwise.
  82
  83 After changing this variable, you must reenable `nameless-mode'
  84 for it to take effect."
  85   :type '(choice (const :tag "Always affect indentation" t)
  86                  (const :tag "Don't affect indentation" nil)
  87                  (const :tag "Only outside strings" 'outside-strings)))
  88
  89 \f
  90 ;;; Font-locking
  91 (defun nameless--make-composition (s)
  92   "Return a list that composes S if passed to `compose-region'."
  93   (cdr (apply #'append (mapcar (lambda (x) (list '(Br . Bl) x)) s))))
  94
  95 (defvar nameless-mode)
  96 (defun nameless--compose-as (display)
  97   "Compose the matched region and return a face spec."
  98   (when nameless-mode
  99     (let ((compose (and nameless-affect-indentation-and-filling
 100                         (or (not (eq nameless-affect-indentation-and-filling 'outside-strings))
 101                             (not (nth 3 (syntax-ppss))))))
 102           (dis (concat display nameless-prefix)))
 103       (when compose
 104         (compose-region (match-beginning 1)
 105                         (match-end 1)
 106                         (nameless--make-composition dis)))
 107       `(face nameless-face ,@(unless compose (list 'display dis))))))
 108
 109 (defvar-local nameless--font-lock-keywords nil)
 110
 111 (defun nameless--ensure ()
 112   (save-excursion
 113     (font-lock-fontify-region (point-min) (point-max))))
 114
 115 (defun nameless--remove-keywords ()
 116   "Remove font-lock keywords set by `nameless--add-keywords'."
 117   (font-lock-remove-keywords nil nameless--font-lock-keywords)
 118   (setq nameless--font-lock-keywords nil)
 119   (nameless--ensure))
 120
 121 (defun nameless--add-keywords (&rest r)
 122   "Add font-lock keywords displaying REGEXP as DISPLAY.
 123
 124 \(fn (regexp . display) [(regexp . display) ...])"
 125   (setq-local font-lock-extra-managed-props
 126               `(composition display ,@font-lock-extra-managed-props))
 127   (let ((kws (mapcar (lambda (x) `(,(nameless--name-regexp (cdr x)) 1 (nameless--compose-as ,(car x)) prepend)) r)))
 128     (setq nameless--font-lock-keywords kws)
 129     (font-lock-add-keywords nil kws t))
 130   (nameless--ensure))
 131
 132 \f
 133 ;;; Name and regexp
 134 (defvar-local nameless-current-name nil)
 135
 136 (defun nameless--in-arglist-p ()
 137   "Is point inside an arglist?"
 138   (save-excursion
 139     (ignore-errors
 140       (backward-up-list)
 141       (or (progn (forward-sexp -1)
 142                  (looking-at-p "[a-z-]lambda\\_>"))
 143           (progn (forward-sexp -1)
 144                  (looking-at-p "\\(cl-\\)?def\\(un\\|macro\\|inline\\)\\*?\\_>"))))))
 145
 146 (defun nameless-insert-name (&optional noerror)
 147   "Insert `nameless-current-name' or the alias at point.
 148 If point is immediately after an alias configured in
 149 `nameless-aliases' or `nameless-global-aliases', replace it with
 150 the full name for that alias.
 151 Otherwise, insert `nameless-current-name'.
 152
 153 If NOERROR is nil, signal an error if the alias at point is not
 154 configured, or if `nameless-current-name' is nil."
 155   (interactive)
 156   (if (string-match (rx (or (syntax symbol)
 157                             (syntax word)))
 158                     (string (char-before)))
 159       (let* ((r (point))
 160              (l (save-excursion
 161                   (forward-sexp -1)
 162                   (skip-chars-forward "^[:alnum:]")
 163                   (point)))
 164              (alias (buffer-substring l r))
 165              (full-name (when alias
 166                           (cdr (or (assoc alias nameless-aliases)
 167                                    (assoc alias nameless-global-aliases))))))
 168         (if full-name
 169             (progn (delete-region l r)
 170                    (insert full-name "-"))
 171           (unless noerror
 172             (user-error "No name for alias `%s', see `nameless-aliases'" alias))))
 173     (if nameless-current-name
 174         (insert nameless-current-name "-")
 175       (unless noerror
 176         (user-error "No name for current buffer, see `nameless-current-name'")))))
 177
 178 (defun nameless-insert-name-or-self-insert (&optional self-insert)
 179   "Insert the name of current package, with a hyphen."
 180   (interactive "P")
 181   (if (or self-insert
 182           (not nameless-current-name)
 183           (eq (char-before) ?\\)
 184           (nameless--in-arglist-p))
 185       (call-interactively #'self-insert-command)
 186     (or (nameless-insert-name 'noerror)
 187         (call-interactively #'self-insert-command))))
 188
 189 (defun nameless--name-regexp (name)
 190   "Return a regexp of the current name."
 191   (concat "\\_<@?\\(" (regexp-quote name) "-\\)\\(\\s_\\|\\sw\\)"))
 192
 193 \f
 194 ;;; Minor mode
 195 ;;;###autoload
 196 (define-minor-mode nameless-mode
 197   nil nil " :" '(("_" . nameless-insert-name-or-self-insert))
 198   (if nameless-mode
 199       (if (or nameless-current-name
 200               (ignore-errors (string-match "\\.el\\'" (lm-get-package-name))))
 201           (progn
 202             (unless nameless-current-name
 203               (setq nameless-current-name (replace-regexp-in-string "\\.[^.]*\\'" "" (lm-get-package-name))))
 204             (apply #'nameless--add-keywords
 205                    `((nil . ,nameless-current-name)
 206                      ,@nameless-global-aliases
 207                      ,@nameless-aliases)))
 208         (nameless-mode -1))
 209     (setq nameless-current-name nil)
 210     (nameless--remove-keywords)))
 211
 212 (provide 'nameless)
 213 ;;; nameless.el ends here