code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular text completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; URL: http://company-mode.github.io/
   8 ;; Version: 0.8.8-cvs
   9 ;; Keywords: abbrev, convenience, matching
  10 ;; Package-Requires: ((emacs "24.1") (cl-lib "0.5"))
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (pcase command
  52 ;;     (`prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (`meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;;; Change Log:
  62 ;;
  63 ;; See NEWS.md in the repository.
  64
  65 ;;; Code:
  66
  67 (require 'cl-lib)
  68 (require 'newcomment)
  69
  70 ;; FIXME: Use `user-error'.
  71 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  72 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  73 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  74 (add-to-list 'debug-ignored-errors "^Company not ")
  75 (add-to-list 'debug-ignored-errors "^No candidate number ")
  76 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  77 (add-to-list 'debug-ignored-errors "^No other back-end$")
  78
  79 ;;; Compatibility
  80 (eval-and-compile
  81   ;; `defvar-local' for Emacs 24.2 and below
  82   (unless (fboundp 'defvar-local)
  83     (defmacro defvar-local (var val &optional docstring)
  84       "Define VAR as a buffer-local variable with default value VAL.
  85 Like `defvar' but additionally marks the variable as being automatically
  86 buffer-local wherever it is set."
  87       (declare (debug defvar) (doc-string 3))
  88       `(progn
  89          (defvar ,var ,val ,docstring)
  90          (make-variable-buffer-local ',var)))))
  91
  92 (defgroup company nil
  93   "Extensible inline text completion mechanism"
  94   :group 'abbrev
  95   :group 'convenience
  96   :group 'matching)
  97
  98 (defface company-tooltip
  99   '((default :foreground "black")
 100     (((class color) (min-colors 88) (background light))
 101      (:background "cornsilk"))
 102     (((class color) (min-colors 88) (background dark))
 103      (:background "yellow")))
 104   "Face used for the tooltip.")
 105
 106 (defface company-tooltip-selection
 107   '((default :inherit company-tooltip)
 108     (((class color) (min-colors 88) (background light))
 109      (:background "light blue"))
 110     (((class color) (min-colors 88) (background dark))
 111      (:background "orange1"))
 112     (t (:background "green")))
 113   "Face used for the selection in the tooltip.")
 114
 115 (defface company-tooltip-search
 116   '((default :inherit company-tooltip-selection))
 117   "Face used for the search string in the tooltip.")
 118
 119 (defface company-tooltip-mouse
 120   '((default :inherit highlight))
 121   "Face used for the tooltip item under the mouse.")
 122
 123 (defface company-tooltip-common
 124   '((default :inherit company-tooltip)
 125     (((background light))
 126      :foreground "darkred")
 127     (((background dark))
 128      :foreground "red"))
 129   "Face used for the common completion in the tooltip.")
 130
 131 (defface company-tooltip-common-selection
 132   '((default :inherit company-tooltip-selection)
 133     (((background light))
 134      :foreground "darkred")
 135     (((background dark))
 136      :foreground "red"))
 137   "Face used for the selected common completion in the tooltip.")
 138
 139 (defface company-tooltip-annotation
 140   '((default :inherit company-tooltip)
 141     (((background light))
 142      :foreground "firebrick4")
 143     (((background dark))
 144      :foreground "red4"))
 145   "Face used for the annotation in the tooltip.")
 146
 147 (defface company-scrollbar-fg
 148   '((((background light))
 149      :background "darkred")
 150     (((background dark))
 151      :background "red"))
 152   "Face used for the tooltip scrollbar thumb.")
 153
 154 (defface company-scrollbar-bg
 155   '((default :inherit company-tooltip)
 156     (((background light))
 157      :background "wheat")
 158     (((background dark))
 159      :background "gold"))
 160   "Face used for the tooltip scrollbar background.")
 161
 162 (defface company-preview
 163   '((((background light))
 164      :inherit company-tooltip-selection)
 165     (((background dark))
 166      :background "blue4"
 167      :foreground "wheat"))
 168   "Face used for the completion preview.")
 169
 170 (defface company-preview-common
 171   '((((background light))
 172      :inherit company-tooltip-selection)
 173     (((background dark))
 174      :inherit company-preview
 175      :foreground "red"))
 176   "Face used for the common part of the completion preview.")
 177
 178 (defface company-preview-search
 179   '((((background light))
 180      :inherit company-tooltip-common-selection)
 181     (((background dark))
 182      :inherit company-preview
 183      :background "blue1"))
 184   "Face used for the search string in the completion preview.")
 185
 186 (defface company-echo nil
 187   "Face used for completions in the echo area.")
 188
 189 (defface company-echo-common
 190   '((((background dark)) (:foreground "firebrick1"))
 191     (((background light)) (:background "firebrick4")))
 192   "Face used for the common part of completions in the echo area.")
 193
 194 (defun company-frontends-set (variable value)
 195   ;; Uniquify.
 196   (let ((value (delete-dups (copy-sequence value))))
 197     (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 198          (memq 'company-pseudo-tooltip-frontend value)
 199          (error "Pseudo tooltip frontend cannot be used twice"))
 200     (and (memq 'company-preview-if-just-one-frontend value)
 201          (memq 'company-preview-frontend value)
 202          (error "Preview frontend cannot be used twice"))
 203     (and (memq 'company-echo value)
 204          (memq 'company-echo-metadata-frontend value)
 205          (error "Echo area cannot be used twice"))
 206     ;; Preview must come last.
 207     (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 208       (when (cdr (memq f value))
 209         (setq value (append (delq f value) (list f)))))
 210     (set variable value)))
 211
 212 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 213                                company-preview-if-just-one-frontend
 214                                company-echo-metadata-frontend)
 215   "The list of active front-ends (visualizations).
 216 Each front-end is a function that takes one argument.  It is called with
 217 one of the following arguments:
 218
 219 `show': When the visualization should start.
 220
 221 `hide': When the visualization should end.
 222
 223 `update': When the data has been updated.
 224
 225 `pre-command': Before every command that is executed while the
 226 visualization is active.
 227
 228 `post-command': After every command that is executed while the
 229 visualization is active.
 230
 231 The visualized data is stored in `company-prefix', `company-candidates',
 232 `company-common', `company-selection', `company-point' and
 233 `company-search-string'."
 234   :set 'company-frontends-set
 235   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 236                          (const :tag "echo, strip common"
 237                                 company-echo-strip-common-frontend)
 238                          (const :tag "show echo meta-data in echo"
 239                                 company-echo-metadata-frontend)
 240                          (const :tag "pseudo tooltip"
 241                                 company-pseudo-tooltip-frontend)
 242                          (const :tag "pseudo tooltip, multiple only"
 243                                 company-pseudo-tooltip-unless-just-one-frontend)
 244                          (const :tag "preview" company-preview-frontend)
 245                          (const :tag "preview, unique only"
 246                                 company-preview-if-just-one-frontend)
 247                          (function :tag "custom function" nil))))
 248
 249 (defcustom company-tooltip-limit 10
 250   "The maximum number of candidates in the tooltip."
 251   :type 'integer)
 252
 253 (defcustom company-tooltip-minimum 6
 254   "The minimum height of the tooltip.
 255 If this many lines are not available, prefer to display the tooltip above."
 256   :type 'integer)
 257
 258 (defcustom company-tooltip-minimum-width 0
 259   "The minimum width of the tooltip's inner area.
 260 This doesn't include the margins and the scroll bar."
 261   :type 'integer
 262   :package-version '(company . "0.8.0"))
 263
 264 (defcustom company-tooltip-margin 1
 265   "Width of margin columns to show around the toolip."
 266   :type 'integer)
 267
 268 (defcustom company-tooltip-offset-display 'scrollbar
 269   "Method using which the tooltip displays scrolling position.
 270 `scrollbar' means draw a scrollbar to the right of the items.
 271 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 272   :type '(choice (const :tag "Scrollbar" scrollbar)
 273                  (const :tag "Two lines" lines)))
 274
 275 (defcustom company-tooltip-align-annotations nil
 276   "When non-nil, align annotations to the right tooltip border."
 277   :type 'boolean
 278   :package-version '(company . "0.7.1"))
 279
 280 (defcustom company-tooltip-flip-when-above nil
 281   "Whether to flip the tooltip when it's above the current line."
 282   :type 'boolean
 283   :package-version '(company . "0.8.1"))
 284
 285 (defvar company-safe-backends
 286   '((company-abbrev . "Abbrev")
 287     (company-bbdb . "BBDB")
 288     (company-capf . "completion-at-point-functions")
 289     (company-clang . "Clang")
 290     (company-cmake . "CMake")
 291     (company-css . "CSS")
 292     (company-dabbrev . "dabbrev for plain text")
 293     (company-dabbrev-code . "dabbrev for code")
 294     (company-eclim . "Eclim (an Eclipse interface)")
 295     (company-elisp . "Emacs Lisp")
 296     (company-etags . "etags")
 297     (company-files . "Files")
 298     (company-gtags . "GNU Global")
 299     (company-ispell . "Ispell")
 300     (company-keywords . "Programming language keywords")
 301     (company-nxml . "nxml")
 302     (company-oddmuse . "Oddmuse")
 303     (company-pysmell . "PySmell")
 304     (company-ropemacs . "ropemacs")
 305     (company-semantic . "Semantic")
 306     (company-tempo . "Tempo templates")
 307     (company-xcode . "Xcode")))
 308 (put 'company-safe-backends 'risky-local-variable t)
 309
 310 (defun company-safe-backends-p (backends)
 311   (and (consp backends)
 312        (not (cl-dolist (backend backends)
 313               (unless (if (consp backend)
 314                           (company-safe-backends-p backend)
 315                         (assq backend company-safe-backends))
 316                 (cl-return t))))))
 317
 318 (defcustom company-backends `(,@(unless (version< "24.3.50" emacs-version)
 319                                   (list 'company-elisp))
 320                               company-bbdb
 321                               company-nxml company-css
 322                               company-eclim company-semantic company-clang
 323                               company-xcode company-ropemacs company-cmake
 324                               company-capf
 325                               (company-dabbrev-code company-gtags company-etags
 326                                company-keywords)
 327                               company-oddmuse company-files company-dabbrev)
 328   "The list of active back-ends (completion engines).
 329
 330 Only one back-end is used at a time.  The choice depends on the order of
 331 the items in this list, and on the values they return in response to the
 332 `prefix' command (see below).  But a back-end can also be a \"grouped\"
 333 one (see below).
 334
 335 `company-begin-backend' can be used to start a specific back-end,
 336 `company-other-backend' will skip to the next matching back-end in the list.
 337
 338 Each back-end is a function that takes a variable number of arguments.
 339 The first argument is the command requested from the back-end.  It is one
 340 of the following:
 341
 342 `prefix': The back-end should return the text to be completed.  It must be
 343 text immediately before point.  Returning nil from this command passes
 344 control to the next back-end.  The function should return `stop' if it
 345 should complete but cannot (e.g. if it is in the middle of a string).
 346 Instead of a string, the back-end may return a cons where car is the prefix
 347 and cdr is used in `company-minimum-prefix-length' test.  It must be either
 348 number or t, and in the latter case the test automatically succeeds.
 349
 350 `candidates': The second argument is the prefix to be completed.  The
 351 return value should be a list of candidates that match the prefix.
 352
 353 Non-prefix matches are also supported (candidates that don't start with the
 354 prefix, but match it in some backend-defined way).  Backends that use this
 355 feature must disable cache (return t to `no-cache') and might also want to
 356 respond to `match'.
 357
 358 Optional commands:
 359
 360 `sorted': Return t here to indicate that the candidates are sorted and will
 361 not need to be sorted again.
 362
 363 `duplicates': If non-nil, company will take care of removing duplicates
 364 from the list.
 365
 366 `no-cache': Usually company doesn't ask for candidates again as completion
 367 progresses, unless the back-end returns t for this command.  The second
 368 argument is the latest prefix.
 369
 370 `meta': The second argument is a completion candidate.  Return a (short)
 371 documentation string for it.
 372
 373 `doc-buffer': The second argument is a completion candidate.  Return a
 374 buffer with documentation for it.  Preferably use `company-doc-buffer',
 375
 376 `location': The second argument is a completion candidate.  Return the cons
 377 of buffer and buffer location, or of file and line number where the
 378 completion candidate was defined.
 379
 380 `annotation': The second argument is a completion candidate.  Return a
 381 string to be displayed inline with the candidate in the popup.  If
 382 duplicates are removed by company, candidates with equal string values will
 383 be kept if they have different annotations.  For that to work properly,
 384 backends should store the related information on candidates using text
 385 properties.
 386
 387 `match': The second argument is a completion candidate.  Return the index
 388 after the end of text matching `prefix' within the candidate string.  It
 389 will be used when rendering the popup.  This command only makes sense for
 390 backends that provide non-prefix completion.
 391
 392 `require-match': If this returns t, the user is not allowed to enter
 393 anything not offered as a candidate.  Use with care!  The default value nil
 394 gives the user that choice with `company-require-match'.  Return value
 395 `never' overrides that option the other way around.
 396
 397 `init': Called once for each buffer. The back-end can check for external
 398 programs and files and load any required libraries.  Raising an error here
 399 will show up in message log once, and the back-end will not be used for
 400 completion.
 401
 402 `post-completion': Called after a completion candidate has been inserted
 403 into the buffer.  The second argument is the candidate.  Can be used to
 404 modify it, e.g. to expand a snippet.
 405
 406 The back-end should return nil for all commands it does not support or
 407 does not know about.  It should also be callable interactively and use
 408 `company-begin-backend' to start itself in that case.
 409
 410 Grouped back-ends:
 411
 412 An element of `company-backends' can also itself be a list of back-ends,
 413 then it's considered to be a \"grouped\" back-end.
 414
 415 When possible, commands taking a candidate as an argument are dispatched to
 416 the back-end it came from.  In other cases, the first non-nil value among
 417 all the back-ends is returned.
 418
 419 The latter is the case for the `prefix' command.  But if the group contains
 420 the keyword `:with', the back-ends after it are ignored for this command.
 421
 422 The completions from back-ends in a group are merged (but only from those
 423 that return the same `prefix').
 424
 425 Asynchronous back-ends:
 426
 427 The return value of each command can also be a cons (:async . FETCHER)
 428 where FETCHER is a function of one argument, CALLBACK.  When the data
 429 arrives, FETCHER must call CALLBACK and pass it the appropriate return
 430 value, as described above.
 431
 432 True asynchronous operation is only supported for command `candidates', and
 433 only during idle completion.  Other commands will block the user interface,
 434 even if the back-end uses the asynchronous calling convention."
 435   :type `(repeat
 436           (choice
 437            :tag "Back-end"
 438            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 439                      company-safe-backends)
 440            (symbol :tag "User defined")
 441            (repeat :tag "Merged Back-ends"
 442                    (choice :tag "Back-end"
 443                            ,@(mapcar (lambda (b)
 444                                        `(const :tag ,(cdr b) ,(car b)))
 445                                      company-safe-backends)
 446                            (const :tag "With" :with)
 447                            (symbol :tag "User defined"))))))
 448
 449 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 450
 451 (defcustom company-transformers nil
 452   "Functions to change the list of candidates received from backends,
 453 after sorting and removal of duplicates (if appropriate).
 454 Each function gets called with the return value of the previous one."
 455   :type '(choice
 456           (const :tag "None" nil)
 457           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 458           (const :tag "Sort by back-end importance"
 459                  (company-sort-by-backend-importance))
 460           (repeat :tag "User defined" (function))))
 461
 462 (defcustom company-completion-started-hook nil
 463   "Hook run when company starts completing.
 464 The hook is called with one argument that is non-nil if the completion was
 465 started manually."
 466   :type 'hook)
 467
 468 (defcustom company-completion-cancelled-hook nil
 469   "Hook run when company cancels completing.
 470 The hook is called with one argument that is non-nil if the completion was
 471 aborted manually."
 472   :type 'hook)
 473
 474 (defcustom company-completion-finished-hook nil
 475   "Hook run when company successfully completes.
 476 The hook is called with the selected candidate as an argument.
 477
 478 If you indend to use it to post-process candidates from a specific
 479 back-end, consider using the `post-completion' command instead."
 480   :type 'hook)
 481
 482 (defcustom company-minimum-prefix-length 3
 483   "The minimum prefix length for idle completion."
 484   :type '(integer :tag "prefix length"))
 485
 486 (defcustom company-abort-manual-when-too-short nil
 487   "If enabled, cancel a manually started completion when the prefix gets
 488 shorter than both `company-minimum-prefix-length' and the length of the
 489 prefix it was started from."
 490   :type 'boolean
 491   :package-version '(company . "0.8.0"))
 492
 493 (defcustom company-require-match 'company-explicit-action-p
 494   "If enabled, disallow non-matching input.
 495 This can be a function do determine if a match is required.
 496
 497 This can be overridden by the back-end, if it returns t or `never' to
 498 `require-match'.  `company-auto-complete' also takes precedence over this."
 499   :type '(choice (const :tag "Off" nil)
 500                  (function :tag "Predicate function")
 501                  (const :tag "On, if user interaction took place"
 502                         'company-explicit-action-p)
 503                  (const :tag "On" t)))
 504
 505 (defcustom company-auto-complete nil
 506   "Determines when to auto-complete.
 507 If this is enabled, all characters from `company-auto-complete-chars'
 508 trigger insertion of the selected completion candidate.
 509 This can also be a function."
 510   :type '(choice (const :tag "Off" nil)
 511                  (function :tag "Predicate function")
 512                  (const :tag "On, if user interaction took place"
 513                         'company-explicit-action-p)
 514                  (const :tag "On" t)))
 515
 516 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 517   "Determines which characters trigger auto-completion.
 518 See `company-auto-complete'.  If this is a string, each string character
 519 tiggers auto-completion.  If it is a list of syntax description characters (see
 520 `modify-syntax-entry'), all characters with that syntax auto-complete.
 521
 522 This can also be a function, which is called with the new input and should
 523 return non-nil if company should auto-complete.
 524
 525 A character that is part of a valid candidate never triggers auto-completion."
 526   :type '(choice (string :tag "Characters")
 527                  (set :tag "Syntax"
 528                       (const :tag "Whitespace" ?\ )
 529                       (const :tag "Symbol" ?_)
 530                       (const :tag "Opening parentheses" ?\()
 531                       (const :tag "Closing parentheses" ?\))
 532                       (const :tag "Word constituent" ?w)
 533                       (const :tag "Punctuation." ?.)
 534                       (const :tag "String quote." ?\")
 535                       (const :tag "Paired delimiter." ?$)
 536                       (const :tag "Expression quote or prefix operator." ?\')
 537                       (const :tag "Comment starter." ?<)
 538                       (const :tag "Comment ender." ?>)
 539                       (const :tag "Character-quote." ?/)
 540                       (const :tag "Generic string fence." ?|)
 541                       (const :tag "Generic comment fence." ?!))
 542                  (function :tag "Predicate function")))
 543
 544 (defcustom company-idle-delay .5
 545   "The idle delay in seconds until completion starts automatically.
 546 The prefix still has to satisfy `company-minimum-prefix-length' before that
 547 happens.  The value of nil means no idle completion."
 548   :type '(choice (const :tag "never (nil)" nil)
 549                  (const :tag "immediate (0)" 0)
 550                  (number :tag "seconds")))
 551
 552 (defcustom company-begin-commands '(self-insert-command
 553                                     org-self-insert-command
 554                                     orgtbl-self-insert-command
 555                                     c-scope-operator
 556                                     c-electric-colon
 557                                     c-electric-lt-gt
 558                                     c-electric-slash)
 559   "A list of commands after which idle completion is allowed.
 560 If this is t, it can show completions after any command except a few from a
 561 pre-defined list.  See `company-idle-delay'.
 562
 563 Alternatively, any command with a non-nil `company-begin' property is
 564 treated as if it was on this list."
 565   :type '(choice (const :tag "Any command" t)
 566                  (const :tag "Self insert command" '(self-insert-command))
 567                  (repeat :tag "Commands" function))
 568   :package-version '(company . "0.8.4"))
 569
 570 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 571                                            save-buffers-kill-terminal
 572                                            save-buffers-kill-emacs)
 573   "A list of commands that are allowed during completion.
 574 If this is t, or if `company-begin-commands' is t, any command is allowed.
 575 Otherwise, the value must be a list of symbols.  If it starts with `not',
 576 the cdr is the list of commands that abort completion.  Otherwise, all
 577 commands except those in that list, or in `company-begin-commands', or
 578 commands in the `company-' namespace, abort completion."
 579   :type '(choice (const :tag "Any command" t)
 580                  (cons  :tag "Any except"
 581                         (const not)
 582                         (repeat :tag "Commands" function))
 583                  (repeat :tag "Commands" function)))
 584
 585 (defcustom company-show-numbers nil
 586   "If enabled, show quick-access numbers for the first ten candidates."
 587   :type '(choice (const :tag "off" nil)
 588                  (const :tag "on" t)))
 589
 590 (defcustom company-selection-wrap-around nil
 591   "If enabled, selecting item before first or after last wraps around."
 592   :type '(choice (const :tag "off" nil)
 593                  (const :tag "on" t)))
 594
 595 (defvar company-async-wait 0.03
 596   "Pause between checks to see if the value's been set when turning an
 597 asynchronous call into synchronous.")
 598
 599 (defvar company-async-timeout 2
 600   "Maximum wait time for a value to be set during asynchronous call.")
 601
 602 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 603
 604 (defvar company-mode-map (make-sparse-keymap)
 605   "Keymap used by `company-mode'.")
 606
 607 (defvar company-active-map
 608   (let ((keymap (make-sparse-keymap)))
 609     (define-key keymap "\e\e\e" 'company-abort)
 610     (define-key keymap "\C-g" 'company-abort)
 611     (define-key keymap (kbd "M-n") 'company-select-next)
 612     (define-key keymap (kbd "M-p") 'company-select-previous)
 613     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 614     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 615     (define-key keymap [down-mouse-1] 'ignore)
 616     (define-key keymap [down-mouse-3] 'ignore)
 617     (define-key keymap [mouse-1] 'company-complete-mouse)
 618     (define-key keymap [mouse-3] 'company-select-mouse)
 619     (define-key keymap [up-mouse-1] 'ignore)
 620     (define-key keymap [up-mouse-3] 'ignore)
 621     (define-key keymap [return] 'company-complete-selection)
 622     (define-key keymap (kbd "RET") 'company-complete-selection)
 623     (define-key keymap [tab] 'company-complete-common)
 624     (define-key keymap (kbd "TAB") 'company-complete-common)
 625     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 626     (define-key keymap (kbd "C-h") 'company-show-doc-buffer)
 627     (define-key keymap "\C-w" 'company-show-location)
 628     (define-key keymap "\C-s" 'company-search-candidates)
 629     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 630     (dotimes (i 10)
 631       (define-key keymap (read-kbd-macro (format "M-%d" i)) 'company-complete-number))
 632      keymap)
 633   "Keymap that is enabled during an active completion.")
 634
 635 (defvar company--disabled-backends nil)
 636
 637 (defun company-init-backend (backend)
 638   (and (symbolp backend)
 639        (not (fboundp backend))
 640        (ignore-errors (require backend nil t)))
 641   (cond
 642    ((symbolp backend)
 643     (condition-case err
 644         (progn
 645           (funcall backend 'init)
 646           (put backend 'company-init t))
 647       (error
 648        (put backend 'company-init 'failed)
 649        (unless (memq backend company--disabled-backends)
 650          (message "Company back-end '%s' could not be initialized:\n%s"
 651                   backend (error-message-string err)))
 652        (cl-pushnew backend company--disabled-backends)
 653        nil)))
 654    ;; No initialization for lambdas.
 655    ((functionp backend) t)
 656    (t ;; Must be a list.
 657     (cl-dolist (b backend)
 658       (unless (keywordp b)
 659         (company-init-backend b))))))
 660
 661 (defvar company-default-lighter " company")
 662
 663 (defvar-local company-lighter company-default-lighter)
 664
 665 ;;;###autoload
 666 (define-minor-mode company-mode
 667   "\"complete anything\"; is an in-buffer completion framework.
 668 Completion starts automatically, depending on the values
 669 `company-idle-delay' and `company-minimum-prefix-length'.
 670
 671 Completion can be controlled with the commands:
 672 `company-complete-common', `company-complete-selection', `company-complete',
 673 `company-select-next', `company-select-previous'.  If these commands are
 674 called before `company-idle-delay', completion will also start.
 675
 676 Completions can be searched with `company-search-candidates' or
 677 `company-filter-candidates'.  These can be used while completion is
 678 inactive, as well.
 679
 680 The completion data is retrieved using `company-backends' and displayed
 681 using `company-frontends'.  If you want to start a specific back-end, call
 682 it interactively or use `company-begin-backend'.
 683
 684 regular keymap (`company-mode-map'):
 685
 686 \\{company-mode-map}
 687 keymap during active completions (`company-active-map'):
 688
 689 \\{company-active-map}"
 690   nil company-lighter company-mode-map
 691   (if company-mode
 692       (progn
 693         (when (eq company-idle-delay t)
 694           (setq company-idle-delay 0)
 695           (warn "Setting `company-idle-delay' to t is deprecated.  Set it to 0 instead."))
 696         (add-hook 'pre-command-hook 'company-pre-command nil t)
 697         (add-hook 'post-command-hook 'company-post-command nil t)
 698         (mapc 'company-init-backend company-backends))
 699     (remove-hook 'pre-command-hook 'company-pre-command t)
 700     (remove-hook 'post-command-hook 'company-post-command t)
 701     (company-cancel)
 702     (kill-local-variable 'company-point)))
 703
 704 (defcustom company-global-modes t
 705   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 706 If nil, means no modes.  If t, then all major modes have it turned on.
 707 If a list, it should be a list of `major-mode' symbol names for which
 708 `company-mode' should be automatically turned on.  The sense of the list is
 709 negated if it begins with `not'.  For example:
 710  (c-mode c++-mode)
 711 means that `company-mode' is turned on for buffers in C and C++ modes only.
 712  (not message-mode)
 713 means that `company-mode' is always turned on except in `message-mode' buffers."
 714   :type '(choice (const :tag "none" nil)
 715                  (const :tag "all" t)
 716                  (set :menu-tag "mode specific" :tag "modes"
 717                       :value (not)
 718                       (const :tag "Except" not)
 719                       (repeat :inline t (symbol :tag "mode")))))
 720
 721 ;;;###autoload
 722 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 723
 724 (defun company-mode-on ()
 725   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 726              (cond ((eq company-global-modes t)
 727                     t)
 728                    ((eq (car-safe company-global-modes) 'not)
 729                     (not (memq major-mode (cdr company-global-modes))))
 730                    (t (memq major-mode company-global-modes))))
 731     (company-mode 1)))
 732
 733 (defsubst company-assert-enabled ()
 734   (unless company-mode
 735     (company-uninstall-map)
 736     (error "Company not enabled")))
 737
 738 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 739
 740 (defvar-local company-my-keymap nil)
 741
 742 (defvar company-emulation-alist '((t . nil)))
 743
 744 (defsubst company-enable-overriding-keymap (keymap)
 745   (company-uninstall-map)
 746   (setq company-my-keymap keymap))
 747
 748 (defun company-ensure-emulation-alist ()
 749   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 750     (setq emulation-mode-map-alists
 751           (cons 'company-emulation-alist
 752                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 753
 754 (defun company-install-map ()
 755   (unless (or (cdar company-emulation-alist)
 756               (null company-my-keymap))
 757     (setf (cdar company-emulation-alist) company-my-keymap)))
 758
 759 (defun company-uninstall-map ()
 760   (setf (cdar company-emulation-alist) nil))
 761
 762 ;; Hack:
 763 ;; Emacs calculates the active keymaps before reading the event.  That means we
 764 ;; cannot change the keymap from a timer.  So we send a bogus command.
 765 ;; XXX: Even in Emacs 24.4, seems to be needed in the terminal.
 766 (defun company-ignore ()
 767   (interactive)
 768   (setq this-command last-command))
 769
 770 (global-set-key '[company-dummy-event] 'company-ignore)
 771
 772 (defun company-input-noop ()
 773   (push 'company-dummy-event unread-command-events))
 774
 775 (defun company--posn-col-row (posn)
 776   (let ((col (car (posn-col-row posn)))
 777         ;; `posn-col-row' doesn't work well with lines of different height.
 778         ;; `posn-actual-col-row' doesn't handle multiple-width characters.
 779         (row (cdr (posn-actual-col-row posn))))
 780     (when (and header-line-format (version< emacs-version "24.3.93.3"))
 781       ;; http://debbugs.gnu.org/18384
 782       (cl-decf row))
 783     (cons (+ col (window-hscroll)) row)))
 784
 785 (defun company--col-row (&optional pos)
 786   (company--posn-col-row (posn-at-point pos)))
 787
 788 (defun company--row (&optional pos)
 789   (cdr (company--col-row pos)))
 790
 791 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 792
 793 (defvar-local company-backend nil)
 794
 795 (defun company-grab (regexp &optional expression limit)
 796   (when (looking-back regexp limit)
 797     (or (match-string-no-properties (or expression 0)) "")))
 798
 799 (defun company-grab-line (regexp &optional expression)
 800   (company-grab regexp expression (point-at-bol)))
 801
 802 (defun company-grab-symbol ()
 803   (if (looking-at "\\_>")
 804       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 805                                                 (point)))
 806     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 807       "")))
 808
 809 (defun company-grab-word ()
 810   (if (looking-at "\\>")
 811       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 812                                                 (point)))
 813     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 814       "")))
 815
 816 (defun company-grab-symbol-cons (idle-begin-after-re &optional max-len)
 817   (let ((symbol (company-grab-symbol)))
 818     (when symbol
 819       (save-excursion
 820         (forward-char (- (length symbol)))
 821         (if (looking-back idle-begin-after-re (if max-len
 822                                                   (- (point) max-len)
 823                                                 (line-beginning-position)))
 824             (cons symbol t)
 825           symbol)))))
 826
 827 (defun company-in-string-or-comment ()
 828   (let ((ppss (syntax-ppss)))
 829     (or (car (setq ppss (nthcdr 3 ppss)))
 830         (car (setq ppss (cdr ppss)))
 831         (nth 3 ppss))))
 832
 833 (defun company-call-backend (&rest args)
 834   (company--force-sync #'company-call-backend-raw args company-backend))
 835
 836 (defun company--force-sync (fun args backend)
 837   (let ((value (apply fun args)))
 838     (if (not (eq (car-safe value) :async))
 839         value
 840       (let ((res 'trash)
 841             (start (time-to-seconds)))
 842         (funcall (cdr value)
 843                  (lambda (result) (setq res result)))
 844         (while (eq res 'trash)
 845           (if (> (- (time-to-seconds) start) company-async-timeout)
 846               (error "Company: Back-end %s async timeout with args %s"
 847                      backend args)
 848             (sleep-for company-async-wait)))
 849         res))))
 850
 851 (defun company-call-backend-raw (&rest args)
 852   (condition-case-unless-debug err
 853       (if (functionp company-backend)
 854           (apply company-backend args)
 855         (apply #'company--multi-backend-adapter company-backend args))
 856     (error (error "Company: Back-end %s error \"%s\" with args %s"
 857                   company-backend (error-message-string err) args))))
 858
 859 (defun company--multi-backend-adapter (backends command &rest args)
 860   (let ((backends (cl-loop for b in backends
 861                            when (not (and (symbolp b)
 862                                           (eq 'failed (get b 'company-init))))
 863                            collect b)))
 864     (setq backends
 865           (if (eq command 'prefix)
 866               (butlast backends (length (member :with backends)))
 867             (delq :with backends)))
 868     (pcase command
 869       (`candidates
 870        (company--multi-backend-adapter-candidates backends (car args)))
 871       (`sorted nil)
 872       (`duplicates t)
 873       ((or `prefix `ignore-case `no-cache `require-match)
 874        (let (value)
 875          (cl-dolist (backend backends)
 876            (when (setq value (company--force-sync
 877                               backend (cons command args) backend))
 878              (cl-return value)))))
 879       (_
 880        (let ((arg (car args)))
 881          (when (> (length arg) 0)
 882            (let ((backend (or (get-text-property 0 'company-backend arg)
 883                               (car backends))))
 884              (apply backend command args))))))))
 885
 886 (defun company--multi-backend-adapter-candidates (backends prefix)
 887   (let ((pairs (cl-loop for backend in (cdr backends)
 888                         when (equal (company--prefix-str
 889                                      (funcall backend 'prefix))
 890                                     prefix)
 891                         collect (cons (funcall backend 'candidates prefix)
 892                                       (let ((b backend))
 893                                         (lambda (candidates)
 894                                           (mapcar
 895                                            (lambda (str)
 896                                              (propertize str 'company-backend b))
 897                                            candidates)))))))
 898     (when (equal (company--prefix-str (funcall (car backends) 'prefix)) prefix)
 899       ;; Small perf optimization: don't tag the candidates received
 900       ;; from the first backend in the group.
 901       (push (cons (funcall (car backends) 'candidates prefix)
 902                   'identity)
 903             pairs))
 904     (company--merge-async pairs (lambda (values) (apply #'append values)))))
 905
 906 (defun company--merge-async (pairs merger)
 907   (let ((async (cl-loop for pair in pairs
 908                         thereis
 909                         (eq :async (car-safe (car pair))))))
 910     (if (not async)
 911         (funcall merger (cl-loop for (val . mapper) in pairs
 912                                  collect (funcall mapper val)))
 913       (cons
 914        :async
 915        (lambda (callback)
 916          (let* (lst pending
 917                 (finisher (lambda ()
 918                             (unless pending
 919                               (funcall callback
 920                                        (funcall merger
 921                                                 (nreverse lst)))))))
 922            (dolist (pair pairs)
 923              (let ((val (car pair))
 924                    (mapper (cdr pair)))
 925                (if (not (eq :async (car-safe val)))
 926                    (push (funcall mapper val) lst)
 927                  (push nil lst)
 928                  (let ((cell lst)
 929                        (fetcher (cdr val)))
 930                    (push fetcher pending)
 931                    (funcall fetcher
 932                             (lambda (res)
 933                               (setq pending (delq fetcher pending))
 934                               (setcar cell (funcall mapper res))
 935                               (funcall finisher)))))))))))))
 936
 937 (defun company--prefix-str (prefix)
 938   (or (car-safe prefix) prefix))
 939
 940 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 941
 942 (defvar-local company-prefix nil)
 943
 944 (defvar-local company-candidates nil)
 945
 946 (defvar-local company-candidates-length nil)
 947
 948 (defvar-local company-candidates-cache nil)
 949
 950 (defvar-local company-candidates-predicate nil)
 951
 952 (defvar-local company-common nil)
 953
 954 (defvar-local company-selection 0)
 955
 956 (defvar-local company-selection-changed nil)
 957
 958 (defvar-local company--manual-action nil
 959   "Non-nil, if manual completion took place.")
 960
 961 (defvar-local company--manual-prefix nil)
 962
 963 (defvar company--auto-completion nil
 964   "Non-nil when current candidate is being inserted automatically.
 965 Controlled by `company-auto-complete'.")
 966
 967 (defvar-local company--point-max nil)
 968
 969 (defvar-local company-point nil)
 970
 971 (defvar company-timer nil)
 972
 973 (defsubst company-strip-prefix (str)
 974   (substring str (length company-prefix)))
 975
 976 (defun company--insert-candidate (candidate)
 977   (setq candidate (substring-no-properties candidate))
 978   ;; XXX: Return value we check here is subject to change.
 979   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 980       (insert (company-strip-prefix candidate))
 981     (unless (equal company-prefix candidate)
 982       (delete-region (- (point) (length company-prefix)) (point))
 983       (insert candidate))))
 984
 985 (defmacro company-with-candidate-inserted (candidate &rest body)
 986   "Evaluate BODY with CANDIDATE temporarily inserted.
 987 This is a tool for back-ends that need candidates inserted before they
 988 can retrieve meta-data for them."
 989   (declare (indent 1))
 990   `(let ((inhibit-modification-hooks t)
 991          (inhibit-point-motion-hooks t)
 992          (modified-p (buffer-modified-p)))
 993      (company--insert-candidate ,candidate)
 994      (unwind-protect
 995          (progn ,@body)
 996        (delete-region company-point (point))
 997        (set-buffer-modified-p modified-p))))
 998
 999 (defun company-explicit-action-p ()
1000   "Return whether explicit completion action was taken by the user."
1001   (or company--manual-action
1002       company-selection-changed))
1003
1004 (defun company-reformat (candidate)
1005   ;; company-ispell needs this, because the results are always lower-case
1006   ;; It's mory efficient to fix it only when they are displayed.
1007   ;; FIXME: Adopt the current text's capitalization instead?
1008   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
1009       (concat company-prefix (substring candidate (length company-prefix)))
1010     candidate))
1011
1012 (defun company--should-complete ()
1013   (and (eq company-idle-delay 'now)
1014        (not (or buffer-read-only overriding-terminal-local-map
1015                 overriding-local-map))
1016        ;; Check if in the middle of entering a key combination.
1017        (or (equal (this-command-keys-vector) [])
1018            (not (keymapp (key-binding (this-command-keys-vector)))))
1019        (not (and transient-mark-mode mark-active))))
1020
1021 (defun company--should-continue ()
1022   (or (eq t company-begin-commands)
1023       (eq t company-continue-commands)
1024       (if (eq 'not (car company-continue-commands))
1025           (not (memq this-command (cdr company-continue-commands)))
1026         (or (memq this-command company-begin-commands)
1027             (memq this-command company-continue-commands)
1028             (and (symbolp this-command)
1029                  (string-match-p "\\`company-" (symbol-name this-command)))))))
1030
1031 (defun company-call-frontends (command)
1032   (dolist (frontend company-frontends)
1033     (condition-case-unless-debug err
1034         (funcall frontend command)
1035       (error (error "Company: Front-end %s error \"%s\" on command %s"
1036                     frontend (error-message-string err) command)))))
1037
1038 (defun company-set-selection (selection &optional force-update)
1039   (setq selection
1040         (if company-selection-wrap-around
1041             (mod selection company-candidates-length)
1042           (max 0 (min (1- company-candidates-length) selection))))
1043   (when (or force-update (not (equal selection company-selection)))
1044     (company--update-group-lighter (nth selection company-candidates))
1045     (setq company-selection selection
1046           company-selection-changed t)
1047     (company-call-frontends 'update)))
1048
1049 (defun company--update-group-lighter (candidate)
1050   (when (listp company-backend)
1051     (let ((backend (or (get-text-property 0 'company-backend candidate)
1052                        (car company-backend))))
1053       (when (and backend (symbolp backend))
1054         (let ((name (replace-regexp-in-string "company-\\|-company" ""
1055                                               (symbol-name backend))))
1056           (setq company-lighter (format " company-<%s>" name)))))))
1057
1058 (defun company-apply-predicate (candidates predicate)
1059   (let (new)
1060     (dolist (c candidates)
1061       (when (funcall predicate c)
1062         (push c new)))
1063     (nreverse new)))
1064
1065 (defun company-update-candidates (candidates)
1066   (setq company-candidates-length (length candidates))
1067   (if (> company-selection 0)
1068       ;; Try to restore the selection
1069       (let ((selected (nth company-selection company-candidates)))
1070         (setq company-selection 0
1071               company-candidates candidates)
1072         (when selected
1073           (while (and candidates (string< (pop candidates) selected))
1074             (cl-incf company-selection))
1075           (unless candidates
1076             ;; Make sure selection isn't out of bounds.
1077             (setq company-selection (min (1- company-candidates-length)
1078                                          company-selection)))))
1079     (setq company-selection 0
1080           company-candidates candidates))
1081   ;; Save in cache:
1082   (push (cons company-prefix company-candidates) company-candidates-cache)
1083   ;; Calculate common.
1084   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
1085     ;; We want to support non-prefix completion, so filtering is the
1086     ;; responsibility of each respective backend, not ours.
1087     ;; On the other hand, we don't want to replace non-prefix input in
1088     ;; `company-complete-common', unless there's only one candidate.
1089     (setq company-common
1090           (if (cdr company-candidates)
1091               (let ((common (try-completion "" company-candidates)))
1092                 (when (string-prefix-p company-prefix common
1093                                        completion-ignore-case)
1094                   common))
1095             (car company-candidates)))))
1096
1097 (defun company-calculate-candidates (prefix)
1098   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
1099         (ignore-case (company-call-backend 'ignore-case)))
1100     (or candidates
1101         (when company-candidates-cache
1102           (let ((len (length prefix))
1103                 (completion-ignore-case ignore-case)
1104                 prev)
1105             (cl-dotimes (i (1+ len))
1106               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1107                                            company-candidates-cache)))
1108                 (setq candidates (all-completions prefix prev))
1109                 (cl-return t)))))
1110         ;; no cache match, call back-end
1111         (setq candidates
1112               (company--process-candidates
1113                (company--fetch-candidates prefix))))
1114     (setq candidates (company--transform-candidates candidates))
1115     (when candidates
1116       (if (or (cdr candidates)
1117               (not (eq t (compare-strings (car candidates) nil nil
1118                                           prefix nil nil ignore-case))))
1119           candidates
1120         ;; Already completed and unique; don't start.
1121         t))))
1122
1123 (defun company--fetch-candidates (prefix)
1124   (let ((c (if company--manual-action
1125                (company-call-backend 'candidates prefix)
1126              (company-call-backend-raw 'candidates prefix)))
1127         res)
1128     (if (not (eq (car c) :async))
1129         c
1130       (let ((buf (current-buffer))
1131             (win (selected-window))
1132             (tick (buffer-chars-modified-tick))
1133             (pt (point))
1134             (backend company-backend))
1135         (funcall
1136          (cdr c)
1137          (lambda (candidates)
1138            (if (not (and candidates (eq res 'done)))
1139                ;; There's no completions to display,
1140                ;; or the fetcher called us back right away.
1141                (setq res candidates)
1142              (setq company-backend backend
1143                    company-candidates-cache
1144                    (list (cons prefix
1145                                (company--process-candidates
1146                                 candidates))))
1147              (company-idle-begin buf win tick pt)))))
1148       ;; FIXME: Relying on the fact that the callers
1149       ;; will interpret nil as "do nothing" is shaky.
1150       ;; A throw-catch would be one possible improvement.
1151       (or res
1152           (progn (setq res 'done) nil)))))
1153
1154 (defun company--process-candidates (candidates)
1155   (when company-candidates-predicate
1156     (setq candidates
1157           (company-apply-predicate candidates
1158                                    company-candidates-predicate)))
1159   (unless (company-call-backend 'sorted)
1160     (setq candidates (sort candidates 'string<)))
1161   (when (company-call-backend 'duplicates)
1162     (company--strip-duplicates candidates))
1163   candidates)
1164
1165 (defun company--strip-duplicates (candidates)
1166   (let ((c2 candidates))
1167     (while c2
1168       (setcdr c2
1169               (let ((str (car c2))
1170                     (anno 'unk))
1171                 (pop c2)
1172                 (while (let ((str2 (car c2)))
1173                          (if (not (equal str str2))
1174                              nil
1175                            (when (eq anno 'unk)
1176                              (setq anno (company-call-backend
1177                                          'annotation str)))
1178                            (equal anno
1179                                   (company-call-backend
1180                                    'annotation str2))))
1181                   (pop c2))
1182                 c2)))))
1183
1184 (defun company--transform-candidates (candidates)
1185   (let ((c candidates))
1186     (dolist (tr company-transformers)
1187       (setq c (funcall tr c)))
1188     c))
1189
1190 (defcustom company-occurrence-weight-function
1191   #'company-occurrence-prefer-closest-above
1192   "Function to weigh matches in `company-sort-by-occurrence'.
1193 It's called with three arguments: cursor position, the beginning and the
1194 end of the match."
1195   :type '(choice
1196           (const :tag "First above point, then below point"
1197                  company-occurrence-prefer-closest-above)
1198           (const :tag "Prefer closest in any direction"
1199                  company-occurrence-prefer-any-closest)))
1200
1201 (defun company-occurrence-prefer-closest-above (pos match-beg match-end)
1202   "Give priority to the matches above point, then those below point."
1203   (if (< match-beg pos)
1204       (- pos match-end)
1205     (- match-beg (window-start))))
1206
1207 (defun company-occurrence-prefer-any-closest (pos _match-beg match-end)
1208   "Give priority to the matches closest to the point."
1209   (abs (- pos match-end)))
1210
1211 (defun company-sort-by-occurrence (candidates)
1212   "Sort CANDIDATES according to their occurrences.
1213 Searches for each in the currently visible part of the current buffer and
1214 prioritizes the matches according to `company-occurrence-weight-function'.
1215 The rest of the list is appended unchanged.
1216 Keywords and function definition names are ignored."
1217   (let* ((w-start (window-start))
1218          (w-end (window-end))
1219          (start-point (point))
1220          occurs
1221          (noccurs
1222           (save-excursion
1223             (cl-delete-if
1224              (lambda (candidate)
1225                (when (catch 'done
1226                        (goto-char w-start)
1227                        (while (search-forward candidate w-end t)
1228                          (when (and (not (eq (point) start-point))
1229                                     (save-match-data
1230                                       (company--occurrence-predicate)))
1231                            (throw 'done t))))
1232                  (push
1233                   (cons candidate
1234                         (funcall company-occurrence-weight-function
1235                                  start-point
1236                                  (match-beginning 0)
1237                                  (match-end 0)))
1238                   occurs)
1239                  t))
1240              candidates))))
1241     (nconc
1242      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1243      noccurs)))
1244
1245 (defun company--occurrence-predicate ()
1246   (let ((beg (match-beginning 0))
1247         (end (match-end 0)))
1248     (save-excursion
1249       (goto-char end)
1250       (and (not (memq (get-text-property (1- (point)) 'face)
1251                       '(font-lock-function-name-face
1252                         font-lock-keyword-face)))
1253            (let ((prefix (company--prefix-str
1254                           (company-call-backend 'prefix))))
1255              (and (stringp prefix)
1256                   (= (length prefix) (- end beg))))))))
1257
1258 (defun company-sort-by-backend-importance (candidates)
1259   "Sort CANDIDATES as two priority groups.
1260 If `company-backend' is a function, do nothing.  If it's a list, move
1261 candidates from back-ends before keyword `:with' to the front.  Candidates
1262 from the rest of the back-ends in the group, if any, will be left at the end."
1263   (if (functionp company-backend)
1264       candidates
1265     (let ((low-priority (cdr (memq :with company-backend))))
1266       (if (null low-priority)
1267           candidates
1268         (sort candidates
1269               (lambda (c1 c2)
1270                 (and
1271                  (let ((b2 (get-text-property 0 'company-backend c2)))
1272                    (and b2 (memq b2 low-priority)))
1273                  (let ((b1 (get-text-property 0 'company-backend c1)))
1274                    (or (not b1) (not (memq b1 low-priority)))))))))))
1275
1276 (defun company-idle-begin (buf win tick pos)
1277   (and (eq buf (current-buffer))
1278        (eq win (selected-window))
1279        (eq tick (buffer-chars-modified-tick))
1280        (eq pos (point))
1281        (when (company-auto-begin)
1282          (company-input-noop)
1283          (let ((this-command 'company-idle-begin))
1284            (company-post-command)))))
1285
1286 (defun company-auto-begin ()
1287   (and company-mode
1288        (not company-candidates)
1289        (let ((company-idle-delay 'now))
1290          (condition-case-unless-debug err
1291              (progn
1292                (company--perform)
1293                ;; Return non-nil if active.
1294                company-candidates)
1295            (error (message "Company: An error occurred in auto-begin")
1296                   (message "%s" (error-message-string err))
1297                   (company-cancel))
1298            (quit (company-cancel))))))
1299
1300 (defun company-manual-begin ()
1301   (interactive)
1302   (company-assert-enabled)
1303   (setq company--manual-action t)
1304   (unwind-protect
1305       (let ((company-minimum-prefix-length 0))
1306         (or company-candidates
1307             (company-auto-begin)))
1308     (unless company-candidates
1309       (setq company--manual-action nil))))
1310
1311 (defun company-other-backend (&optional backward)
1312   (interactive (list current-prefix-arg))
1313   (company-assert-enabled)
1314   (let* ((after (if company-backend
1315                     (cdr (member company-backend company-backends))
1316                   company-backends))
1317          (before (cdr (member company-backend (reverse company-backends))))
1318          (next (if backward
1319                    (append before (reverse after))
1320                  (append after (reverse before)))))
1321     (company-cancel)
1322     (cl-dolist (backend next)
1323       (when (ignore-errors (company-begin-backend backend))
1324         (cl-return t))))
1325   (unless company-candidates
1326     (error "No other back-end")))
1327
1328 (defun company-require-match-p ()
1329   (let ((backend-value (company-call-backend 'require-match)))
1330     (or (eq backend-value t)
1331         (and (not (eq backend-value 'never))
1332              (if (functionp company-require-match)
1333                  (funcall company-require-match)
1334                (eq company-require-match t))))))
1335
1336 (defun company-auto-complete-p (input)
1337   "Return non-nil, if input starts with punctuation or parentheses."
1338   (and (if (functionp company-auto-complete)
1339            (funcall company-auto-complete)
1340          company-auto-complete)
1341        (if (functionp company-auto-complete-chars)
1342            (funcall company-auto-complete-chars input)
1343          (if (consp company-auto-complete-chars)
1344              (memq (char-syntax (string-to-char input))
1345                    company-auto-complete-chars)
1346            (string-match (substring input 0 1) company-auto-complete-chars)))))
1347
1348 (defun company--incremental-p ()
1349   (and (> (point) company-point)
1350        (> (point-max) company--point-max)
1351        (not (eq this-command 'backward-delete-char-untabify))
1352        (equal (buffer-substring (- company-point (length company-prefix))
1353                                 company-point)
1354               company-prefix)))
1355
1356 (defun company--continue-failed (new-prefix)
1357   (let ((input (buffer-substring-no-properties (point) company-point)))
1358     (cond
1359      ((company-auto-complete-p input)
1360       ;; auto-complete
1361       (save-excursion
1362         (goto-char company-point)
1363         (let ((company--auto-completion t))
1364           (company-complete-selection))
1365         nil))
1366      ((and (or (not (company-require-match-p))
1367                ;; Don't require match if the new prefix
1368                ;; doesn't continue the old one, and the latter was a match.
1369                (not (stringp new-prefix))
1370                (<= (length new-prefix) (length company-prefix)))
1371            (member company-prefix company-candidates))
1372       ;; Last input was a success,
1373       ;; but we're treating it as an abort + input anyway,
1374       ;; like the `unique' case below.
1375       (company-cancel 'non-unique))
1376      ((company-require-match-p)
1377       ;; Wrong incremental input, but required match.
1378       (delete-char (- (length input)))
1379       (ding)
1380       (message "Matching input is required")
1381       company-candidates)
1382      (t (company-cancel)))))
1383
1384 (defun company--good-prefix-p (prefix)
1385   (and (stringp (company--prefix-str prefix)) ;excludes 'stop
1386        (or (eq (cdr-safe prefix) t)
1387            (let ((len (or (cdr-safe prefix) (length prefix))))
1388              (if company--manual-prefix
1389                  (or (not company-abort-manual-when-too-short)
1390                      ;; Must not be less than minimum or initial length.
1391                      (>= len (min company-minimum-prefix-length
1392                                   (length company--manual-prefix))))
1393                (>= len company-minimum-prefix-length))))))
1394
1395 (defun company--continue ()
1396   (when (company-call-backend 'no-cache company-prefix)
1397     ;; Don't complete existing candidates, fetch new ones.
1398     (setq company-candidates-cache nil))
1399   (let* ((new-prefix (company-call-backend 'prefix))
1400          (c (when (and (company--good-prefix-p new-prefix)
1401                        (setq new-prefix (company--prefix-str new-prefix))
1402                        (= (- (point) (length new-prefix))
1403                           (- company-point (length company-prefix))))
1404               (company-calculate-candidates new-prefix))))
1405     (cond
1406      ((eq c t)
1407       ;; t means complete/unique.
1408       ;; Handle it like completion was aborted, to differentiate from user
1409       ;; calling one of Company's commands to insert the candidate,
1410       ;; not to trigger template expansion, etc.
1411       (company-cancel 'unique))
1412      ((consp c)
1413       ;; incremental match
1414       (setq company-prefix new-prefix)
1415       (company-update-candidates c)
1416       c)
1417      ((not (company--incremental-p))
1418       (company-cancel))
1419      (t (company--continue-failed new-prefix)))))
1420
1421 (defun company--begin-new ()
1422   (let (prefix c)
1423     (cl-dolist (backend (if company-backend
1424                             ;; prefer manual override
1425                             (list company-backend)
1426                           company-backends))
1427       (setq prefix
1428             (if (or (symbolp backend)
1429                     (functionp backend))
1430                 (when (or (not (symbolp backend))
1431                           (eq t (get backend 'company-init))
1432                           (unless (get backend 'company-init)
1433                             (company-init-backend backend)))
1434                   (funcall backend 'prefix))
1435               (company--multi-backend-adapter backend 'prefix)))
1436       (when prefix
1437         (when (company--good-prefix-p prefix)
1438           (setq company-prefix (company--prefix-str prefix)
1439                 company-backend backend
1440                 c (company-calculate-candidates company-prefix))
1441           ;; t means complete/unique.  We don't start, so no hooks.
1442           (if (not (consp c))
1443               (when company--manual-action
1444                 (message "No completion found"))
1445             (when company--manual-action
1446               (setq company--manual-prefix prefix))
1447             (if (symbolp backend)
1448                 (setq company-lighter (concat " " (symbol-name backend)))
1449               (company--update-group-lighter (car c)))
1450             (company-update-candidates c)
1451             (run-hook-with-args 'company-completion-started-hook
1452                                 (company-explicit-action-p))
1453             (company-call-frontends 'show)))
1454         (cl-return c)))))
1455
1456 (defun company--perform ()
1457   (or (and company-candidates (company--continue))
1458       (and (company--should-complete) (company--begin-new)))
1459   (if (not company-candidates)
1460       (setq company-backend nil)
1461     (setq company-point (point)
1462           company--point-max (point-max))
1463     (company-ensure-emulation-alist)
1464     (company-enable-overriding-keymap company-active-map)
1465     (company-call-frontends 'update)))
1466
1467 (defun company-cancel (&optional result)
1468   (unwind-protect
1469       (when company-prefix
1470         (if (stringp result)
1471             (progn
1472               (company-call-backend 'pre-completion result)
1473               (run-hook-with-args 'company-completion-finished-hook result)
1474               (company-call-backend 'post-completion result))
1475           (run-hook-with-args 'company-completion-cancelled-hook result)))
1476     (setq company-backend nil
1477           company-prefix nil
1478           company-candidates nil
1479           company-candidates-length nil
1480           company-candidates-cache nil
1481           company-candidates-predicate nil
1482           company-common nil
1483           company-selection 0
1484           company-selection-changed nil
1485           company--manual-action nil
1486           company--manual-prefix nil
1487           company-lighter company-default-lighter
1488           company--point-max nil
1489           company-point nil)
1490     (when company-timer
1491       (cancel-timer company-timer))
1492     (company-search-mode 0)
1493     (company-call-frontends 'hide)
1494     (company-enable-overriding-keymap nil))
1495   ;; Make return value explicit.
1496   nil)
1497
1498 (defun company-abort ()
1499   (interactive)
1500   (company-cancel 'abort))
1501
1502 (defun company-finish (result)
1503   (company--insert-candidate result)
1504   (company-cancel result))
1505
1506 (defsubst company-keep (command)
1507   (and (symbolp command) (get command 'company-keep)))
1508
1509 (defun company-pre-command ()
1510   (unless (company-keep this-command)
1511     (condition-case-unless-debug err
1512         (when company-candidates
1513           (company-call-frontends 'pre-command)
1514           (unless (company--should-continue)
1515             (company-abort)))
1516       (error (message "Company: An error occurred in pre-command")
1517              (message "%s" (error-message-string err))
1518              (company-cancel))))
1519   (when company-timer
1520     (cancel-timer company-timer)
1521     (setq company-timer nil))
1522   (company-uninstall-map))
1523
1524 (defun company-post-command ()
1525   (when (null this-command)
1526     ;; Happens when the user presses `C-g' while inside
1527     ;; `flyspell-post-command-hook', for example.
1528     ;; Or any other `post-command-hook' function that can call `sit-for',
1529     ;; or any quittable timer function.
1530     (company-abort)
1531     (setq this-command 'company-abort))
1532   (unless (company-keep this-command)
1533     (condition-case-unless-debug err
1534         (progn
1535           (unless (equal (point) company-point)
1536             (let (company-idle-delay) ; Against misbehavior while debugging.
1537               (company--perform)))
1538           (if company-candidates
1539               (company-call-frontends 'post-command)
1540             (and (numberp company-idle-delay)
1541                  (company--should-begin)
1542                  (setq company-timer
1543                        (run-with-timer company-idle-delay nil
1544                                        'company-idle-begin
1545                                        (current-buffer) (selected-window)
1546                                        (buffer-chars-modified-tick) (point))))))
1547       (error (message "Company: An error occurred in post-command")
1548              (message "%s" (error-message-string err))
1549              (company-cancel))))
1550   (company-install-map))
1551
1552 (defvar company--begin-inhibit-commands '(company-abort
1553                                           company-complete-mouse
1554                                           company-complete
1555                                           company-complete-common
1556                                           company-complete-selection
1557                                           company-complete-number)
1558   "List of commands after which idle completion is (still) disabled when
1559 `company-begin-commands' is t.")
1560
1561 (defun company--should-begin ()
1562   (if (eq t company-begin-commands)
1563       (not (memq this-command company--begin-inhibit-commands))
1564     (or
1565      (memq this-command company-begin-commands)
1566      (and (symbolp this-command) (get this-command 'company-begin)))))
1567
1568 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1569
1570 (defvar-local company-search-string nil)
1571
1572 (defvar-local company-search-lighter " Search: \"\"")
1573
1574 (defvar-local company-search-old-map nil)
1575
1576 (defvar-local company-search-old-selection 0)
1577
1578 (defun company-search (text lines)
1579   (let ((quoted (regexp-quote text))
1580         (i 0))
1581     (cl-dolist (line lines)
1582       (when (string-match quoted line (length company-prefix))
1583         (cl-return i))
1584       (cl-incf i))))
1585
1586 (defun company-search-printing-char ()
1587   (interactive)
1588   (company-search-assert-enabled)
1589   (let* ((ss (concat company-search-string (string last-command-event)))
1590          (pos (company-search ss (nthcdr company-selection company-candidates))))
1591     (if (null pos)
1592         (ding)
1593       (setq company-search-string ss
1594             company-search-lighter (concat " Search: \"" ss "\""))
1595       (company-set-selection (+ company-selection pos) t))))
1596
1597 (defun company-search-repeat-forward ()
1598   "Repeat the incremental search in completion candidates forward."
1599   (interactive)
1600   (company-search-assert-enabled)
1601   (let ((pos (company-search company-search-string
1602                              (cdr (nthcdr company-selection
1603                                           company-candidates)))))
1604     (if (null pos)
1605         (ding)
1606       (company-set-selection (+ company-selection pos 1) t))))
1607
1608 (defun company-search-repeat-backward ()
1609   "Repeat the incremental search in completion candidates backwards."
1610   (interactive)
1611   (company-search-assert-enabled)
1612   (let ((pos (company-search company-search-string
1613                              (nthcdr (- company-candidates-length
1614                                         company-selection)
1615                                      (reverse company-candidates)))))
1616     (if (null pos)
1617         (ding)
1618       (company-set-selection (- company-selection pos 1) t))))
1619
1620 (defun company-create-match-predicate ()
1621   (let ((ss company-search-string))
1622     (setq company-candidates-predicate
1623           (when ss (lambda (candidate) (string-match ss candidate)))))
1624   (company-update-candidates
1625    (company-apply-predicate company-candidates company-candidates-predicate))
1626   ;; Invalidate cache.
1627   (setq company-candidates-cache (cons company-prefix company-candidates)))
1628
1629 (defun company-filter-printing-char ()
1630   (interactive)
1631   (company-search-assert-enabled)
1632   (company-search-printing-char)
1633   (company-create-match-predicate)
1634   (company-call-frontends 'update))
1635
1636 (defun company-search-kill-others ()
1637   "Limit the completion candidates to the ones matching the search string."
1638   (interactive)
1639   (company-search-assert-enabled)
1640   (company-create-match-predicate)
1641   (company-search-mode 0)
1642   (company-call-frontends 'update))
1643
1644 (defun company-search-abort ()
1645   "Abort searching the completion candidates."
1646   (interactive)
1647   (company-search-assert-enabled)
1648   (company-set-selection company-search-old-selection t)
1649   (company-search-mode 0))
1650
1651 (defun company-search-other-char ()
1652   (interactive)
1653   (company-search-assert-enabled)
1654   (company-search-mode 0)
1655   (company--unread-last-input))
1656
1657 (defvar company-search-map
1658   (let ((i 0)
1659         (keymap (make-keymap)))
1660     (if (fboundp 'max-char)
1661         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1662                               'company-search-printing-char)
1663       (with-no-warnings
1664         ;; obsolete in Emacs 23
1665         (let ((l (generic-character-list))
1666               (table (nth 1 keymap)))
1667           (while l
1668             (set-char-table-default table (car l) 'company-search-printing-char)
1669             (setq l (cdr l))))))
1670     (define-key keymap [t] 'company-search-other-char)
1671     (while (< i ?\s)
1672       (define-key keymap (make-string 1 i) 'company-search-other-char)
1673       (cl-incf i))
1674     (while (< i 256)
1675       (define-key keymap (vector i) 'company-search-printing-char)
1676       (cl-incf i))
1677     (let ((meta-map (make-sparse-keymap)))
1678       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1679       (define-key keymap [escape] meta-map))
1680     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1681     (define-key keymap "\e\e\e" 'company-search-other-char)
1682     (define-key keymap [escape escape escape] 'company-search-other-char)
1683     (define-key keymap (kbd "DEL") 'company-search-other-char)
1684
1685     (define-key keymap "\C-g" 'company-search-abort)
1686     (define-key keymap "\C-s" 'company-search-repeat-forward)
1687     (define-key keymap "\C-r" 'company-search-repeat-backward)
1688     (define-key keymap "\C-o" 'company-search-kill-others)
1689     keymap)
1690   "Keymap used for incrementally searching the completion candidates.")
1691
1692 (define-minor-mode company-search-mode
1693   "Search mode for completion candidates.
1694 Don't start this directly, use `company-search-candidates' or
1695 `company-filter-candidates'."
1696   nil company-search-lighter nil
1697   (if company-search-mode
1698       (if (company-manual-begin)
1699           (progn
1700             (setq company-search-old-selection company-selection)
1701             (company-call-frontends 'update))
1702         (setq company-search-mode nil))
1703     (kill-local-variable 'company-search-string)
1704     (kill-local-variable 'company-search-lighter)
1705     (kill-local-variable 'company-search-old-selection)
1706     (company-enable-overriding-keymap company-active-map)))
1707
1708 (defun company-search-assert-enabled ()
1709   (company-assert-enabled)
1710   (unless company-search-mode
1711     (company-uninstall-map)
1712     (error "Company not in search mode")))
1713
1714 (defun company-search-candidates ()
1715   "Start searching the completion candidates incrementally.
1716
1717 \\<company-search-map>Search can be controlled with the commands:
1718 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1719 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1720 - `company-search-abort' (\\[company-search-abort])
1721
1722 Regular characters are appended to the search string.
1723
1724 The command `company-search-kill-others' (\\[company-search-kill-others])
1725 uses the search string to limit the completion candidates."
1726   (interactive)
1727   (company-search-mode 1)
1728   (company-enable-overriding-keymap company-search-map))
1729
1730 (defvar company-filter-map
1731   (let ((keymap (make-keymap)))
1732     (define-key keymap [remap company-search-printing-char]
1733       'company-filter-printing-char)
1734     (set-keymap-parent keymap company-search-map)
1735     keymap)
1736   "Keymap used for incrementally searching the completion candidates.")
1737
1738 (defun company-filter-candidates ()
1739   "Start filtering the completion candidates incrementally.
1740 This works the same way as `company-search-candidates' immediately
1741 followed by `company-search-kill-others' after each input."
1742   (interactive)
1743   (company-search-mode 1)
1744   (company-enable-overriding-keymap company-filter-map))
1745
1746 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1747
1748 (defun company-select-next ()
1749   "Select the next candidate in the list."
1750   (interactive)
1751   (when (company-manual-begin)
1752     (company-set-selection (1+ company-selection))))
1753
1754 (defun company-select-previous ()
1755   "Select the previous candidate in the list."
1756   (interactive)
1757   (when (company-manual-begin)
1758     (company-set-selection (1- company-selection))))
1759
1760 (defun company-select-next-or-abort ()
1761   "Select the next candidate if more than one, else abort
1762 and invoke the normal binding."
1763   (interactive)
1764   (if (> company-candidates-length 1)
1765       (company-select-next)
1766     (company-abort)
1767     (company--unread-last-input)))
1768
1769 (defun company-select-previous-or-abort ()
1770   "Select the previous candidate if more than one, else abort
1771 and invoke the normal binding."
1772   (interactive)
1773   (if (> company-candidates-length 1)
1774       (company-select-previous)
1775     (company-abort)
1776     (company--unread-last-input)))
1777
1778 (defvar company-pseudo-tooltip-overlay)
1779
1780 (defvar company-tooltip-offset)
1781
1782 (defun company--inside-tooltip-p (event-col-row row height)
1783   (let* ((ovl company-pseudo-tooltip-overlay)
1784          (column (overlay-get ovl 'company-column))
1785          (width (overlay-get ovl 'company-width))
1786          (evt-col (car event-col-row))
1787          (evt-row (cdr event-col-row)))
1788     (and (>= evt-col column)
1789          (< evt-col (+ column width))
1790          (if (> height 0)
1791              (and (> evt-row row)
1792                   (<= evt-row (+ row height) ))
1793            (and (< evt-row row)
1794                 (>= evt-row (+ row height)))))))
1795
1796 (defun company--event-col-row (event)
1797   (company--posn-col-row (event-start event)))
1798
1799 (defun company-select-mouse (event)
1800   "Select the candidate picked by the mouse."
1801   (interactive "e")
1802   (let ((event-col-row (company--event-col-row event))
1803         (ovl-row (company--row))
1804         (ovl-height (and company-pseudo-tooltip-overlay
1805                          (min (overlay-get company-pseudo-tooltip-overlay
1806                                            'company-height)
1807                               company-candidates-length))))
1808     (if (and ovl-height
1809              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1810         (progn
1811           (company-set-selection (+ (cdr event-col-row)
1812                                     (1- company-tooltip-offset)
1813                                     (if (and (eq company-tooltip-offset-display 'lines)
1814                                              (not (zerop company-tooltip-offset)))
1815                                         -1 0)
1816                                     (- ovl-row)
1817                                     (if (< ovl-height 0)
1818                                         (- 1 ovl-height)
1819                                       0)))
1820           t)
1821       (company-abort)
1822       (company--unread-last-input)
1823       nil)))
1824
1825 (defun company-complete-mouse (event)
1826   "Insert the candidate picked by the mouse."
1827   (interactive "e")
1828   (when (company-select-mouse event)
1829     (company-complete-selection)))
1830
1831 (defun company-complete-selection ()
1832   "Insert the selected candidate."
1833   (interactive)
1834   (when (company-manual-begin)
1835     (let ((result (nth company-selection company-candidates)))
1836       (company-finish result))))
1837
1838 (defun company-complete-common ()
1839   "Insert the common part of all candidates."
1840   (interactive)
1841   (when (company-manual-begin)
1842     (if (and (not (cdr company-candidates))
1843              (equal company-common (car company-candidates)))
1844         (company-complete-selection)
1845       (when company-common
1846         (company--insert-candidate company-common)))))
1847
1848 (defun company-complete ()
1849   "Insert the common part of all candidates or the current selection.
1850 The first time this is called, the common part is inserted, the second
1851 time, or when the selection has been changed, the selected candidate is
1852 inserted."
1853   (interactive)
1854   (when (company-manual-begin)
1855     (if (or company-selection-changed
1856             (eq last-command 'company-complete-common))
1857         (call-interactively 'company-complete-selection)
1858       (call-interactively 'company-complete-common)
1859       (setq this-command 'company-complete-common))))
1860
1861 (defun company-complete-number (n)
1862   "Insert the Nth candidate visible in the tooltip.
1863 To show the number next to the candidates in some back-ends, enable
1864 `company-show-numbers'.  When called interactively, uses the last typed
1865 character, stripping the modifiers.  That character must be a digit."
1866   (interactive
1867    (list (let* ((type (event-basic-type last-command-event))
1868                 (char (if (characterp type)
1869                           ;; Number on the main row.
1870                           type
1871                         ;; Keypad number, if bound directly.
1872                         (car (last (string-to-list (symbol-name type))))))
1873                 (n (- char ?0)))
1874            (if (zerop n) 10 n))))
1875   (when (company-manual-begin)
1876     (and (or (< n 1) (> n (- company-candidates-length
1877                              company-tooltip-offset)))
1878          (error "No candidate number %d" n))
1879     (cl-decf n)
1880     (company-finish (nth (+ n company-tooltip-offset)
1881                          company-candidates))))
1882
1883 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1884
1885 (defconst company-space-strings-limit 100)
1886
1887 (defconst company-space-strings
1888   (let (lst)
1889     (dotimes (i company-space-strings-limit)
1890       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1891     (apply 'vector lst)))
1892
1893 (defun company-space-string (len)
1894   (if (< len company-space-strings-limit)
1895       (aref company-space-strings len)
1896     (make-string len ?\ )))
1897
1898 (defun company-safe-substring (str from &optional to)
1899   (if (> from (string-width str))
1900       ""
1901     (with-temp-buffer
1902       (insert str)
1903       (move-to-column from)
1904       (let ((beg (point)))
1905         (if to
1906             (progn
1907               (move-to-column to)
1908               (concat (buffer-substring beg (point))
1909                       (let ((padding (- to (current-column))))
1910                         (when (> padding 0)
1911                           (company-space-string padding)))))
1912           (buffer-substring beg (point-max)))))))
1913
1914 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1915
1916 (defvar-local company-last-metadata nil)
1917
1918 (defun company-fetch-metadata ()
1919   (let ((selected (nth company-selection company-candidates)))
1920     (unless (eq selected (car company-last-metadata))
1921       (setq company-last-metadata
1922             (cons selected (company-call-backend 'meta selected))))
1923     (cdr company-last-metadata)))
1924
1925 (defun company-doc-buffer (&optional string)
1926   (with-current-buffer (get-buffer-create "*company-documentation*")
1927     (erase-buffer)
1928     (when string
1929       (save-excursion
1930         (insert string)))
1931     (current-buffer)))
1932
1933 (defvar company--electric-commands
1934   '(scroll-other-window scroll-other-window-down)
1935   "List of Commands that won't break out of electric commands.")
1936
1937 (defmacro company--electric-do (&rest body)
1938   (declare (indent 0) (debug t))
1939   `(when (company-manual-begin)
1940      (save-window-excursion
1941        (let ((height (window-height))
1942              (row (company--row))
1943              cmd)
1944          ,@body
1945          (and (< (window-height) height)
1946               (< (- (window-height) row 2) company-tooltip-limit)
1947               (recenter (- (window-height) row 2)))
1948          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1949                       company--electric-commands)
1950            (call-interactively cmd))
1951          (company--unread-last-input)))))
1952
1953 (defun company--unread-last-input ()
1954   (when last-input-event
1955     (clear-this-command-keys t)
1956     (setq unread-command-events (list last-input-event))))
1957
1958 (defun company-show-doc-buffer ()
1959   "Temporarily show the documentation buffer for the selection."
1960   (interactive)
1961   (company--electric-do
1962     (let* ((selected (nth company-selection company-candidates))
1963            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1964                            (error "No documentation available"))))
1965       (with-current-buffer doc-buffer
1966         (goto-char (point-min)))
1967       (display-buffer doc-buffer t))))
1968 (put 'company-show-doc-buffer 'company-keep t)
1969
1970 (defun company-show-location ()
1971   "Temporarily display a buffer showing the selected candidate in context."
1972   (interactive)
1973   (company--electric-do
1974     (let* ((selected (nth company-selection company-candidates))
1975            (location (company-call-backend 'location selected))
1976            (pos (or (cdr location) (error "No location available")))
1977            (buffer (or (and (bufferp (car location)) (car location))
1978                        (find-file-noselect (car location) t))))
1979       (with-selected-window (display-buffer buffer t)
1980         (save-restriction
1981           (widen)
1982           (if (bufferp (car location))
1983               (goto-char pos)
1984             (goto-char (point-min))
1985             (forward-line (1- pos))))
1986         (set-window-start nil (point))))))
1987 (put 'company-show-location 'company-keep t)
1988
1989 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1990
1991 (defvar-local company-callback nil)
1992
1993 (defun company-remove-callback (&optional ignored)
1994   (remove-hook 'company-completion-finished-hook company-callback t)
1995   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1996   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
1997
1998 (defun company-begin-backend (backend &optional callback)
1999   "Start a completion at point using BACKEND."
2000   (interactive (let ((val (completing-read "Company back-end: "
2001                                            obarray
2002                                            'functionp nil "company-")))
2003                  (when val
2004                    (list (intern val)))))
2005   (when (setq company-callback callback)
2006     (add-hook 'company-completion-finished-hook company-callback nil t))
2007   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
2008   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
2009   (setq company-backend backend)
2010   ;; Return non-nil if active.
2011   (or (company-manual-begin)
2012       (error "Cannot complete at point")))
2013
2014 (defun company-begin-with (candidates
2015                            &optional prefix-length require-match callback)
2016   "Start a completion at point.
2017 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
2018 of the prefix that already is in the buffer before point.
2019 It defaults to 0.
2020
2021 CALLBACK is a function called with the selected result if the user
2022 successfully completes the input.
2023
2024 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
2025   (let ((begin-marker (copy-marker (point) t)))
2026     (company-begin-backend
2027      (lambda (command &optional arg &rest ignored)
2028        (pcase command
2029          (`prefix
2030           (when (equal (point) (marker-position begin-marker))
2031             (buffer-substring (- (point) (or prefix-length 0)) (point))))
2032          (`candidates
2033           (all-completions arg candidates))
2034          (`require-match
2035           require-match)))
2036      callback)))
2037
2038 (defun company-version (&optional show-version)
2039   "Get the Company version as string.
2040
2041 If SHOW-VERSION is non-nil, show the version in the echo area."
2042   (interactive (list t))
2043   (with-temp-buffer
2044     (insert-file-contents (find-library-name "company"))
2045     (require 'lisp-mnt)
2046     (if show-version
2047         (message "Company version: %s" (lm-version))
2048       (lm-version))))
2049
2050 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2051
2052 (defvar-local company-pseudo-tooltip-overlay nil)
2053
2054 (defvar-local company-tooltip-offset 0)
2055
2056 (defun company-tooltip--lines-update-offset (selection num-lines limit)
2057   (cl-decf limit 2)
2058   (setq company-tooltip-offset
2059         (max (min selection company-tooltip-offset)
2060              (- selection -1 limit)))
2061
2062   (when (<= company-tooltip-offset 1)
2063     (cl-incf limit)
2064     (setq company-tooltip-offset 0))
2065
2066   (when (>= company-tooltip-offset (- num-lines limit 1))
2067     (cl-incf limit)
2068     (when (= selection (1- num-lines))
2069       (cl-decf company-tooltip-offset)
2070       (when (<= company-tooltip-offset 1)
2071         (setq company-tooltip-offset 0)
2072         (cl-incf limit))))
2073
2074   limit)
2075
2076 (defun company-tooltip--simple-update-offset (selection _num-lines limit)
2077   (setq company-tooltip-offset
2078         (if (< selection company-tooltip-offset)
2079             selection
2080           (max company-tooltip-offset
2081                (- selection limit -1)))))
2082
2083 ;;; propertize
2084
2085 (defsubst company-round-tab (arg)
2086   (* (/ (+ arg tab-width) tab-width) tab-width))
2087
2088 (defun company-plainify (str)
2089   (let ((prefix (get-text-property 0 'line-prefix str)))
2090     (when prefix ; Keep the original value unmodified, for no special reason.
2091       (setq str (concat prefix str))
2092       (remove-text-properties 0 (length str) '(line-prefix) str)))
2093   (let* ((pieces (split-string str "\t"))
2094          (copy pieces))
2095     (while (cdr copy)
2096       (setcar copy (company-safe-substring
2097                     (car copy) 0 (company-round-tab (string-width (car copy)))))
2098       (pop copy))
2099     (apply 'concat pieces)))
2100
2101 (defun company-fill-propertize (value annotation width selected left right)
2102   (let* ((margin (length left))
2103          (common (or (company-call-backend 'match value)
2104                      (if company-common
2105                          (string-width company-common)
2106                        0)))
2107          (ann-ralign company-tooltip-align-annotations)
2108          (ann-truncate (< width
2109                           (+ (length value) (length annotation)
2110                              (if ann-ralign 1 0))))
2111          (ann-start (+ margin
2112                        (if ann-ralign
2113                            (if ann-truncate
2114                                (1+ (length value))
2115                              (- width (length annotation)))
2116                          (length value))))
2117          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
2118          (line (concat left
2119                        (if (or ann-truncate (not ann-ralign))
2120                            (company-safe-substring
2121                             (concat value
2122                                     (when (and annotation ann-ralign) " ")
2123                                     annotation)
2124                             0 width)
2125                          (concat
2126                           (company-safe-substring value 0
2127                                                   (- width (length annotation)))
2128                           annotation))
2129                        right)))
2130     (setq common (+ (min common width) margin))
2131     (setq width (+ width margin (length right)))
2132
2133     (add-text-properties 0 width '(face company-tooltip
2134                                    mouse-face company-tooltip-mouse)
2135                          line)
2136     (add-text-properties margin common
2137                          '(face company-tooltip-common
2138                            mouse-face company-tooltip-mouse)
2139                          line)
2140     (when (< ann-start ann-end)
2141       (add-text-properties ann-start ann-end
2142                            '(face company-tooltip-annotation
2143                              mouse-face company-tooltip-mouse)
2144                            line))
2145     (when selected
2146       (if (and company-search-string
2147                (string-match (regexp-quote company-search-string) value
2148                              (length company-prefix)))
2149           (let ((beg (+ margin (match-beginning 0)))
2150                 (end (+ margin (match-end 0))))
2151             (add-text-properties beg end '(face company-tooltip-search)
2152                                  line)
2153             (when (< beg common)
2154               (add-text-properties beg common
2155                                    '(face company-tooltip-common-selection)
2156                                    line)))
2157         (add-text-properties 0 width '(face company-tooltip-selection
2158                                        mouse-face company-tooltip-selection)
2159                              line)
2160         (add-text-properties margin common
2161                              '(face company-tooltip-common-selection
2162                                mouse-face company-tooltip-selection)
2163                              line)))
2164     line))
2165
2166 (defun company--clean-string (str)
2167   (replace-regexp-in-string
2168    "\\([^[:graph:] ]\\)\\|\\(\ufeff\\)\\|[[:multibyte:]]"
2169    (lambda (match)
2170      (cond
2171       ((match-beginning 1)
2172        ;; FIXME: Better char for 'non-printable'?
2173        ;; We shouldn't get any of these, but sometimes we might.
2174        "\u2017")
2175       ((match-beginning 2)
2176        ;; Zero-width non-breakable space.
2177        "")
2178       ((> (string-width match) 1)
2179        (concat
2180         (make-string (1- (string-width match)) ?\ufeff)
2181         match))
2182       (t match)))
2183    str))
2184
2185 ;;; replace
2186
2187 (defun company-buffer-lines (beg end)
2188   (goto-char beg)
2189   (let (lines lines-moved)
2190     (while (and (> (setq lines-moved (vertical-motion 1)) 0)
2191                 (<= (point) end))
2192       (let ((bound (min end (1- (point)))))
2193         ;; A visual line can contain several physical lines (e.g. with outline's
2194         ;; folding overlay).  Take only the first one.
2195         (push (buffer-substring beg
2196                                 (save-excursion
2197                                   (goto-char beg)
2198                                   (re-search-forward "$" bound 'move)
2199                                   (point)))
2200               lines))
2201       ;; One physical line can be displayed as several visual ones as well:
2202       ;; add empty strings to the list, to even the count.
2203       (dotimes (_ (1- lines-moved))
2204         (push "" lines))
2205       (setq beg (point)))
2206     (unless (eq beg end)
2207       (push (buffer-substring beg end) lines))
2208     (nreverse lines)))
2209
2210 (defun company-modify-line (old new offset)
2211   (concat (company-safe-substring old 0 offset)
2212           new
2213           (company-safe-substring old (+ offset (length new)))))
2214
2215 (defsubst company--length-limit (lst limit)
2216   (if (nthcdr limit lst)
2217       limit
2218     (length lst)))
2219
2220 (defsubst company--window-height ()
2221   (if (fboundp 'window-screen-lines)
2222       (floor (window-screen-lines))
2223     (window-body-height)))
2224
2225 (defun company--window-width ()
2226   (let ((ww (window-body-width)))
2227     ;; Account for the line continuation column.
2228     (when (zerop (cadr (window-fringes)))
2229       (cl-decf ww))
2230     (unless (or (display-graphic-p)
2231                 (version< "24.3.1" emacs-version))
2232       ;; Emacs 24.3 and earlier included margins
2233       ;; in window-width when in TTY.
2234       (cl-decf ww
2235                (let ((margins (window-margins)))
2236                  (+ (or (car margins) 0)
2237                     (or (cdr margins) 0)))))
2238     (when (and word-wrap
2239                (version< emacs-version "24.4.51.5"))
2240       ;; http://debbugs.gnu.org/18384
2241       (cl-decf ww))
2242     ww))
2243
2244 (defun company--replacement-string (lines old column nl &optional align-top)
2245   (cl-decf column company-tooltip-margin)
2246
2247   (when (and align-top company-tooltip-flip-when-above)
2248     (setq lines (reverse lines)))
2249
2250   (let ((width (length (car lines)))
2251         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2252                            column)))
2253     (when (> width remaining-cols)
2254       (cl-decf column (- width remaining-cols))))
2255
2256   (let ((offset (and (< column 0) (- column)))
2257         new)
2258     (when offset
2259       (setq column 0))
2260     (when align-top
2261       ;; untouched lines first
2262       (dotimes (_ (- (length old) (length lines)))
2263         (push (pop old) new)))
2264     ;; length into old lines.
2265     (while old
2266       (push (company-modify-line (pop old)
2267                                  (company--offset-line (pop lines) offset)
2268                                  column)
2269             new))
2270     ;; Append whole new lines.
2271     (while lines
2272       (push (concat (company-space-string column)
2273                     (company--offset-line (pop lines) offset))
2274             new))
2275
2276     (let ((str (concat (when nl " ")
2277                        "\n"
2278                        (mapconcat 'identity (nreverse new) "\n")
2279                        "\n")))
2280       (font-lock-append-text-property 0 (length str) 'face 'default str)
2281       (when nl (put-text-property 0 1 'cursor t str))
2282       str)))
2283
2284 (defun company--offset-line (line offset)
2285   (if (and offset line)
2286       (substring line offset)
2287     line))
2288
2289 (defun company--create-lines (selection limit)
2290   (let ((len company-candidates-length)
2291         (window-width (company--window-width))
2292         lines
2293         width
2294         lines-copy
2295         items
2296         previous
2297         remainder
2298         scrollbar-bounds)
2299
2300     ;; Maybe clear old offset.
2301     (when (< len (+ company-tooltip-offset limit))
2302       (setq company-tooltip-offset 0))
2303
2304     ;; Scroll to offset.
2305     (if (eq company-tooltip-offset-display 'lines)
2306         (setq limit (company-tooltip--lines-update-offset selection len limit))
2307       (company-tooltip--simple-update-offset selection len limit))
2308
2309     (cond
2310      ((eq company-tooltip-offset-display 'scrollbar)
2311       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2312                                                         limit len)))
2313      ((eq company-tooltip-offset-display 'lines)
2314       (when (> company-tooltip-offset 0)
2315         (setq previous (format "...(%d)" company-tooltip-offset)))
2316       (setq remainder (- len limit company-tooltip-offset)
2317             remainder (when (> remainder 0)
2318                         (setq remainder (format "...(%d)" remainder))))))
2319
2320     (cl-decf selection company-tooltip-offset)
2321     (setq width (max (length previous) (length remainder))
2322           lines (nthcdr company-tooltip-offset company-candidates)
2323           len (min limit len)
2324           lines-copy lines)
2325
2326     (cl-decf window-width (* 2 company-tooltip-margin))
2327     (when scrollbar-bounds (cl-decf window-width))
2328
2329     (dotimes (_ len)
2330       (let* ((value (pop lines-copy))
2331              (annotation (company-call-backend 'annotation value)))
2332         (setq value (company--clean-string value))
2333         (when annotation
2334           (when company-tooltip-align-annotations
2335             ;; `lisp-completion-at-point' adds a space.
2336             (setq annotation (comment-string-strip annotation t nil)))
2337           (setq annotation (company--clean-string annotation)))
2338         (push (cons value annotation) items)
2339         (setq width (max (+ (length value)
2340                             (if (and annotation company-tooltip-align-annotations)
2341                                 (1+ (length annotation))
2342                               (length annotation)))
2343                          width))))
2344
2345     (setq width (min window-width
2346                      (max company-tooltip-minimum-width
2347                           (if company-show-numbers
2348                               (+ 2 width)
2349                             width))))
2350
2351     (let ((items (nreverse items))
2352           (numbered (if company-show-numbers 0 99999))
2353           new)
2354       (when previous
2355         (push (company--scrollpos-line previous width) new))
2356
2357       (dotimes (i len)
2358         (let* ((item (pop items))
2359                (str (company-reformat (car item)))
2360                (annotation (cdr item))
2361                (right (company-space-string company-tooltip-margin))
2362                (width width))
2363           (when (< numbered 10)
2364             (cl-decf width 2)
2365             (cl-incf numbered)
2366             (setq right (concat (format " %d" (mod numbered 10)) right)))
2367           (push (concat
2368                  (company-fill-propertize str annotation
2369                                           width (equal i selection)
2370                                           (company-space-string
2371                                            company-tooltip-margin)
2372                                           right)
2373                  (when scrollbar-bounds
2374                    (company--scrollbar i scrollbar-bounds)))
2375                 new)))
2376
2377       (when remainder
2378         (push (company--scrollpos-line remainder width) new))
2379
2380       (nreverse new))))
2381
2382 (defun company--scrollbar-bounds (offset limit length)
2383   (when (> length limit)
2384     (let* ((size (ceiling (* limit (float limit)) length))
2385            (lower (floor (* limit (float offset)) length))
2386            (upper (+ lower size -1)))
2387       (cons lower upper))))
2388
2389 (defun company--scrollbar (i bounds)
2390   (propertize " " 'face
2391               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2392                   'company-scrollbar-fg
2393                 'company-scrollbar-bg)))
2394
2395 (defun company--scrollpos-line (text width)
2396   (propertize (concat (company-space-string company-tooltip-margin)
2397                       (company-safe-substring text 0 width)
2398                       (company-space-string company-tooltip-margin))
2399               'face 'company-tooltip))
2400
2401 ;; show
2402
2403 (defun company--pseudo-tooltip-height ()
2404   "Calculate the appropriate tooltip height.
2405 Returns a negative number if the tooltip should be displayed above point."
2406   (let* ((lines (company--row))
2407          (below (- (company--window-height) 1 lines)))
2408     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2409              (> lines below))
2410         (- (max 3 (min company-tooltip-limit lines)))
2411       (max 3 (min company-tooltip-limit below)))))
2412
2413 (defun company-pseudo-tooltip-show (row column selection)
2414   (company-pseudo-tooltip-hide)
2415   (save-excursion
2416
2417     (let* ((height (company--pseudo-tooltip-height))
2418            above)
2419
2420       (when (< height 0)
2421         (setq row (+ row height -1)
2422               above t))
2423
2424       (let* ((nl (< (move-to-window-line row) row))
2425              (beg (point))
2426              (end (save-excursion
2427                     (move-to-window-line (+ row (abs height)))
2428                     (point)))
2429              (ov (make-overlay (if nl beg (1- beg)) end nil t))
2430              (args (list (mapcar 'company-plainify
2431                                  (company-buffer-lines beg end))
2432                          column nl above)))
2433
2434         (setq company-pseudo-tooltip-overlay ov)
2435         (overlay-put ov 'company-replacement-args args)
2436
2437         (let ((lines (company--create-lines selection (abs height))))
2438           (overlay-put ov 'company-display
2439                        (apply 'company--replacement-string lines args))
2440           (overlay-put ov 'company-width (string-width (car lines))))
2441
2442         (overlay-put ov 'company-column column)
2443         (overlay-put ov 'company-height height)))))
2444
2445 (defun company-pseudo-tooltip-show-at-point (pos column-offset)
2446   (let* ((col-row (company--col-row pos))
2447          (col (- (car col-row) column-offset)))
2448     (when (< col 0) (setq col 0))
2449     (company-pseudo-tooltip-show (1+ (cdr col-row)) col company-selection)))
2450
2451 (defun company-pseudo-tooltip-edit (selection)
2452   (let* ((height (overlay-get company-pseudo-tooltip-overlay 'company-height))
2453          (lines  (company--create-lines selection (abs height))))
2454     (overlay-put company-pseudo-tooltip-overlay 'company-width
2455                  (string-width (car lines)))
2456     (overlay-put company-pseudo-tooltip-overlay 'company-display
2457                  (apply 'company--replacement-string
2458                         lines
2459                         (overlay-get company-pseudo-tooltip-overlay
2460                                      'company-replacement-args)))))
2461
2462 (defun company-pseudo-tooltip-hide ()
2463   (when company-pseudo-tooltip-overlay
2464     (delete-overlay company-pseudo-tooltip-overlay)
2465     (setq company-pseudo-tooltip-overlay nil)))
2466
2467 (defun company-pseudo-tooltip-hide-temporarily ()
2468   (when (overlayp company-pseudo-tooltip-overlay)
2469     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2470     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)))
2471
2472 (defun company-pseudo-tooltip-unhide ()
2473   (when company-pseudo-tooltip-overlay
2474     (let* ((ov company-pseudo-tooltip-overlay)
2475            (disp (overlay-get ov 'company-display)))
2476       ;; Beat outline's folding overlays, at least.
2477       (overlay-put ov 'priority 1)
2478       ;; `display' could be better (http://debbugs.gnu.org/18285), but it
2479       ;; doesn't work when the overlay is empty, which is what happens at eob.
2480       ;; It also seems to interact badly with `cursor'.
2481       ;; We deal with priorities by having the overlay start before the newline.
2482       (overlay-put ov 'after-string disp)
2483       (overlay-put ov 'invisible t)
2484       (overlay-put ov 'window (selected-window)))))
2485
2486 (defun company-pseudo-tooltip-guard ()
2487   (cons
2488    (save-excursion (beginning-of-visual-line))
2489    (let ((ov company-pseudo-tooltip-overlay)
2490          (overhang (save-excursion (end-of-visual-line)
2491                                    (- (line-end-position) (point)))))
2492      (when (>= (overlay-get ov 'company-height) 0)
2493        (cons
2494         (buffer-substring-no-properties (point) (overlay-start ov))
2495         (when (>= overhang 0) overhang))))))
2496
2497 (defun company-pseudo-tooltip-frontend (command)
2498   "`company-mode' front-end similar to a tooltip but based on overlays."
2499   (cl-case command
2500     (pre-command (company-pseudo-tooltip-hide-temporarily))
2501     (post-command
2502      (unless (when (overlayp company-pseudo-tooltip-overlay)
2503               (let* ((ov company-pseudo-tooltip-overlay)
2504                      (old-height (overlay-get ov 'company-height))
2505                      (new-height (company--pseudo-tooltip-height)))
2506                 (and
2507                  (>= (* old-height new-height) 0)
2508                  (>= (abs old-height) (abs new-height))
2509                  (equal (company-pseudo-tooltip-guard)
2510                         (overlay-get ov 'company-guard)))))
2511        ;; Redraw needed.
2512        (company-pseudo-tooltip-show-at-point (point) (length company-prefix))
2513        (overlay-put company-pseudo-tooltip-overlay
2514                     'company-guard (company-pseudo-tooltip-guard)))
2515      (company-pseudo-tooltip-unhide))
2516     (hide (company-pseudo-tooltip-hide)
2517           (setq company-tooltip-offset 0))
2518     (update (when (overlayp company-pseudo-tooltip-overlay)
2519               (company-pseudo-tooltip-edit company-selection)))))
2520
2521 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2522   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2523   (unless (and (eq command 'post-command)
2524                (company--show-inline-p))
2525     (company-pseudo-tooltip-frontend command)))
2526
2527 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2528
2529 (defvar-local company-preview-overlay nil)
2530
2531 (defun company-preview-show-at-point (pos)
2532   (company-preview-hide)
2533
2534   (let ((completion (nth company-selection company-candidates)))
2535     (setq completion (propertize completion 'face 'company-preview))
2536     (add-text-properties 0 (length company-common)
2537                          '(face company-preview-common) completion)
2538
2539     ;; Add search string
2540     (and company-search-string
2541          (string-match (regexp-quote company-search-string) completion)
2542          (add-text-properties (match-beginning 0)
2543                               (match-end 0)
2544                               '(face company-preview-search)
2545                               completion))
2546
2547     (setq completion (company-strip-prefix completion))
2548
2549     (and (equal pos (point))
2550          (not (equal completion ""))
2551          (add-text-properties 0 1 '(cursor 1) completion))
2552
2553     (let* ((beg pos)
2554            (pto company-pseudo-tooltip-overlay)
2555            (ptf-workaround (and
2556                             pto
2557                             (char-before pos)
2558                             (eq pos (overlay-start pto)))))
2559       ;; Try to accomodate for the pseudo-tooltip overlay,
2560       ;; which may start at the same position if it's at eol.
2561       (when ptf-workaround
2562         (cl-decf beg)
2563         (setq completion (concat (buffer-substring beg pos) completion)))
2564
2565       (setq company-preview-overlay (make-overlay beg pos))
2566
2567       (let ((ov company-preview-overlay))
2568         (overlay-put ov (if ptf-workaround 'display 'after-string)
2569                      completion)
2570         (overlay-put ov 'window (selected-window))))))
2571
2572 (defun company-preview-hide ()
2573   (when company-preview-overlay
2574     (delete-overlay company-preview-overlay)
2575     (setq company-preview-overlay nil)))
2576
2577 (defun company-preview-frontend (command)
2578   "`company-mode' front-end showing the selection as if it had been inserted."
2579   (pcase command
2580     (`pre-command (company-preview-hide))
2581     (`post-command (company-preview-show-at-point (point)))
2582     (`hide (company-preview-hide))))
2583
2584 (defun company-preview-if-just-one-frontend (command)
2585   "`company-preview-frontend', but only shown for single candidates."
2586   (when (or (not (eq command 'post-command))
2587             (company--show-inline-p))
2588     (company-preview-frontend command)))
2589
2590 (defun company--show-inline-p ()
2591   (and (not (cdr company-candidates))
2592        company-common
2593        (or (eq (company-call-backend 'ignore-case) 'keep-prefix)
2594            (string-prefix-p company-prefix company-common))))
2595
2596 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2597
2598 (defvar-local company-echo-last-msg nil)
2599
2600 (defvar company-echo-timer nil)
2601
2602 (defvar company-echo-delay .01)
2603
2604 (defun company-echo-show (&optional getter)
2605   (when getter
2606     (setq company-echo-last-msg (funcall getter)))
2607   (let ((message-log-max nil))
2608     (if company-echo-last-msg
2609         (message "%s" company-echo-last-msg)
2610       (message ""))))
2611
2612 (defun company-echo-show-soon (&optional getter)
2613   (when company-echo-timer
2614     (cancel-timer company-echo-timer))
2615   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2616
2617 (defsubst company-echo-show-when-idle (&optional getter)
2618   (when (sit-for company-echo-delay)
2619     (company-echo-show getter)))
2620
2621 (defun company-echo-format ()
2622
2623   (let ((limit (window-body-width (minibuffer-window)))
2624         (len -1)
2625         ;; Roll to selection.
2626         (candidates (nthcdr company-selection company-candidates))
2627         (i (if company-show-numbers company-selection 99999))
2628         comp msg)
2629
2630     (while candidates
2631       (setq comp (company-reformat (pop candidates))
2632             len (+ len 1 (length comp)))
2633       (if (< i 10)
2634           ;; Add number.
2635           (progn
2636             (setq comp (propertize (format "%d: %s" i comp)
2637                                    'face 'company-echo))
2638             (cl-incf len 3)
2639             (cl-incf i)
2640             (add-text-properties 3 (+ 3 (length company-common))
2641                                  '(face company-echo-common) comp))
2642         (setq comp (propertize comp 'face 'company-echo))
2643         (add-text-properties 0 (length company-common)
2644                              '(face company-echo-common) comp))
2645       (if (>= len limit)
2646           (setq candidates nil)
2647         (push comp msg)))
2648
2649     (mapconcat 'identity (nreverse msg) " ")))
2650
2651 (defun company-echo-strip-common-format ()
2652
2653   (let ((limit (window-body-width (minibuffer-window)))
2654         (len (+ (length company-prefix) 2))
2655         ;; Roll to selection.
2656         (candidates (nthcdr company-selection company-candidates))
2657         (i (if company-show-numbers company-selection 99999))
2658         msg comp)
2659
2660     (while candidates
2661       (setq comp (company-strip-prefix (pop candidates))
2662             len (+ len 2 (length comp)))
2663       (when (< i 10)
2664         ;; Add number.
2665         (setq comp (format "%s (%d)" comp i))
2666         (cl-incf len 4)
2667         (cl-incf i))
2668       (if (>= len limit)
2669           (setq candidates nil)
2670         (push (propertize comp 'face 'company-echo) msg)))
2671
2672     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2673             (mapconcat 'identity (nreverse msg) ", ")
2674             "}")))
2675
2676 (defun company-echo-hide ()
2677   (unless (equal company-echo-last-msg "")
2678     (setq company-echo-last-msg "")
2679     (company-echo-show)))
2680
2681 (defun company-echo-frontend (command)
2682   "`company-mode' front-end showing the candidates in the echo area."
2683   (pcase command
2684     (`post-command (company-echo-show-soon 'company-echo-format))
2685     (`hide (company-echo-hide))))
2686
2687 (defun company-echo-strip-common-frontend (command)
2688   "`company-mode' front-end showing the candidates in the echo area."
2689   (pcase command
2690     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2691     (`hide (company-echo-hide))))
2692
2693 (defun company-echo-metadata-frontend (command)
2694   "`company-mode' front-end showing the documentation in the echo area."
2695   (pcase command
2696     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
2697     (`hide (company-echo-hide))))
2698
2699 (provide 'company)
2700 ;;; company.el ends here