code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular in-buffer completion framework
   2
   3 ;; Copyright (C) 2009-2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; Version: 0.6.2
   8 ;; Keywords: abbrev, convenience, matching
   9 ;; URL: http://company-mode.github.com/
  10 ;; Compatibility: GNU Emacs 22.x, GNU Emacs 23.x, GNU Emacs 24.x
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (case command
  52 ;;     (prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;; Known Issues:
  62 ;; When point is at the very end of the buffer, the pseudo-tooltip appears very
  63 ;; wrong, unless company is allowed to temporarily insert a fake newline.
  64 ;; This behavior is enabled by `company-end-of-buffer-workaround'.
  65 ;;
  66 ;;; Change Log:
  67 ;;
  68 ;; See NEWS.md in the repository.
  69
  70 ;;; Code:
  71
  72 (eval-when-compile (require 'cl))
  73
  74 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  75 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  76 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  77 (add-to-list 'debug-ignored-errors "^Company not ")
  78 (add-to-list 'debug-ignored-errors "^No candidate number ")
  79 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  80 (add-to-list 'debug-ignored-errors "^No other back-end$")
  81
  82 (defgroup company nil
  83   "Extensible inline text completion mechanism"
  84   :group 'abbrev
  85   :group 'convenience
  86   :group 'matching)
  87
  88 (defface company-tooltip
  89   '((t :background "yellow"
  90        :foreground "black"))
  91   "Face used for the tool tip."
  92   :group 'company)
  93
  94 (defface company-tooltip-selection
  95   '((default :inherit company-tooltip)
  96     (((class color) (min-colors 88)) (:background "orange1"))
  97     (t (:background "green")))
  98   "Face used for the selection in the tool tip."
  99   :group 'company)
 100
 101 (defface company-tooltip-mouse
 102   '((default :inherit highlight))
 103   "Face used for the tool tip item under the mouse."
 104   :group 'company)
 105
 106 (defface company-tooltip-common
 107   '((t :inherit company-tooltip
 108        :foreground "red"))
 109   "Face used for the common completion in the tool tip."
 110   :group 'company)
 111
 112 (defface company-tooltip-common-selection
 113   '((t :inherit company-tooltip-selection
 114        :foreground "red"))
 115   "Face used for the selected common completion in the tool tip."
 116   :group 'company)
 117
 118 (defface company-preview
 119   '((t :background "blue4"
 120        :foreground "wheat"))
 121   "Face used for the completion preview."
 122   :group 'company)
 123
 124 (defface company-preview-common
 125   '((t :inherit company-preview
 126        :foreground "red"))
 127   "Face used for the common part of the completion preview."
 128   :group 'company)
 129
 130 (defface company-preview-search
 131   '((t :inherit company-preview
 132        :background "blue1"))
 133   "Face used for the search string in the completion preview."
 134   :group 'company)
 135
 136 (defface company-echo nil
 137   "Face used for completions in the echo area."
 138   :group 'company)
 139
 140 (defface company-echo-common
 141   '((((background dark)) (:foreground "firebrick1"))
 142     (((background light)) (:background "firebrick4")))
 143   "Face used for the common part of completions in the echo area."
 144   :group 'company)
 145
 146 (defun company-frontends-set (variable value)
 147   ;; uniquify
 148   (let ((remainder value))
 149     (setcdr remainder (delq (car remainder) (cdr remainder))))
 150   (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 151        (memq 'company-pseudo-tooltip-frontend value)
 152        (error "Pseudo tooltip frontend cannot be used twice"))
 153   (and (memq 'company-preview-if-just-one-frontend value)
 154        (memq 'company-preview-frontend value)
 155        (error "Preview frontend cannot be used twice"))
 156   (and (memq 'company-echo value)
 157        (memq 'company-echo-metadata-frontend value)
 158        (error "Echo area cannot be used twice"))
 159   ;; preview must come last
 160   (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 161     (when (memq f value)
 162       (setq value (append (delq f value) (list f)))))
 163   (set variable value))
 164
 165 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 166                                company-preview-if-just-one-frontend
 167                                company-echo-metadata-frontend)
 168   "The list of active front-ends (visualizations).
 169 Each front-end is a function that takes one argument.  It is called with
 170 one of the following arguments:
 171
 172 'show: When the visualization should start.
 173
 174 'hide: When the visualization should end.
 175
 176 'update: When the data has been updated.
 177
 178 'pre-command: Before every command that is executed while the
 179 visualization is active.
 180
 181 'post-command: After every command that is executed while the
 182 visualization is active.
 183
 184 The visualized data is stored in `company-prefix', `company-candidates',
 185 `company-common', `company-selection', `company-point' and
 186 `company-search-string'."
 187   :set 'company-frontends-set
 188   :group 'company
 189   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 190                          (const :tag "echo, strip common"
 191                                 company-echo-strip-common-frontend)
 192                          (const :tag "show echo meta-data in echo"
 193                                 company-echo-metadata-frontend)
 194                          (const :tag "pseudo tooltip"
 195                                 company-pseudo-tooltip-frontend)
 196                          (const :tag "pseudo tooltip, multiple only"
 197                                 company-pseudo-tooltip-unless-just-one-frontend)
 198                          (const :tag "preview" company-preview-frontend)
 199                          (const :tag "preview, unique only"
 200                                 company-preview-if-just-one-frontend)
 201                          (function :tag "custom function" nil))))
 202
 203 (defcustom company-tooltip-limit 10
 204   "The maximum number of candidates in the tool tip"
 205   :group 'company
 206   :type 'integer)
 207
 208 (defcustom company-tooltip-minimum 6
 209   "The minimum height of the tool tip.
 210 If this many lines are not available, prefer to display the tooltip above."
 211   :group 'company
 212   :type 'integer)
 213
 214 (defvar company-safe-backends
 215   '((company-abbrev . "Abbrev")
 216     (company-clang . "clang")
 217     (company-css . "CSS")
 218     (company-dabbrev . "dabbrev for plain text")
 219     (company-dabbrev-code . "dabbrev for code")
 220     (company-eclim . "eclim (an Eclipse interace)")
 221     (company-elisp . "Emacs Lisp")
 222     (company-etags . "etags")
 223     (company-files . "Files")
 224     (company-gtags . "GNU Global")
 225     (company-ispell . "ispell")
 226     (company-keywords . "Programming language keywords")
 227     (company-nxml . "nxml")
 228     (company-oddmuse . "Oddmuse")
 229     (company-pysmell . "PySmell")
 230     (company-ropemacs . "ropemacs")
 231     (company-semantic . "CEDET Semantic")
 232     (company-tempo . "Tempo templates")
 233     (company-xcode . "Xcode")))
 234 (put 'company-safe-backends 'risky-local-variable t)
 235
 236 (defun company-safe-backends-p (backends)
 237   (and (consp backends)
 238        (not (dolist (backend backends)
 239               (unless (if (consp backend)
 240                           (company-safe-backends-p backend)
 241                         (assq backend company-safe-backends))
 242                 (return t))))))
 243
 244 (defun company-capf (command &optional arg &rest args)
 245   "`company-mode' back-end using `completion-at-point-functions'.
 246 Requires Emacs 24.1 or newer."
 247   (interactive (list 'interactive))
 248   (case command
 249     (interactive (company-begin-backend 'company-capf))
 250     (prefix
 251      (let ((res (run-hook-wrapped 'completion-at-point-functions
 252                                   ;; Ignore misbehaving functions.
 253                                   #'completion--capf-wrapper 'optimist)))
 254        (when (consp res)
 255          (if (> (nth 2 res) (point))
 256              'stop
 257            (buffer-substring-no-properties (nth 1 res) (point))))))
 258     (candidates
 259      (let ((res (run-hook-wrapped 'completion-at-point-functions
 260                                   ;; Ignore misbehaving functions.
 261                                   #'completion--capf-wrapper 'optimist)))
 262        (when (consp res)
 263          (all-completions arg (nth 3 res)
 264                           (plist-get (nthcdr 4 res) :predicate)))))))
 265
 266 (defcustom company-backends '(company-elisp company-nxml company-css
 267                               company-clang company-semantic company-eclim
 268                               company-xcode company-ropemacs
 269                               (company-gtags company-etags company-dabbrev-code
 270                                company-keywords)
 271                               company-oddmuse company-files company-dabbrev)
 272   "The list of active back-ends (completion engines).
 273 Each list elements can itself be a list of back-ends.  In that case their
 274 completions are merged.  Otherwise only the first matching back-end returns
 275 results.
 276
 277 `company-begin-backend' can be used to start a specific back-end,
 278 `company-other-backend' will skip to the next matching back-end in the list.
 279
 280 Each back-end is a function that takes a variable number of arguments.
 281 The first argument is the command requested from the back-end.  It is one
 282 of the following:
 283
 284 `prefix': The back-end should return the text to be completed.  It must be
 285 text immediately before `point'.  Returning nil passes control to the next
 286 back-end.  The function should return 'stop if it should complete but cannot
 287 \(e.g. if it is in the middle of a string\).  If the returned value is only
 288 part of the prefix (e.g. the part after \"->\" in C), the back-end may return a
 289 cons of prefix and prefix length, which is then used in the
 290 `company-minimum-prefix-length' test.
 291
 292 `candidates': The second argument is the prefix to be completed.  The
 293 return value should be a list of candidates that start with the prefix.
 294
 295 Optional commands:
 296
 297 `sorted': The back-end may return t here to indicate that the candidates
 298 are sorted and will not need to be sorted again.
 299
 300 `duplicates': If non-nil, company will take care of removing duplicates
 301 from the list.
 302
 303 `no-cache': Usually company doesn't ask for candidates again as completion
 304 progresses, unless the back-end returns t for this command.  The second
 305 argument is the latest prefix.
 306
 307 `meta': The second argument is a completion candidate.  The back-end should
 308 return a (short) documentation string for it.
 309
 310 `doc-buffer': The second argument is a completion candidate.
 311 The back-end should create a buffer (preferably with `company-doc-buffer'),
 312 fill it with documentation and return it.
 313
 314 `location': The second argument is a completion candidate.  The back-end can
 315 return the cons of buffer and buffer location, or of file and line
 316 number where the completion candidate was defined.
 317
 318 `require-match': If this value is t, the user is not allowed to enter anything
 319 not offered as a candidate.  Use with care!  The default value nil gives the
 320 user that choice with `company-require-match'.  Return value 'never overrides
 321 that option the other way around.
 322
 323 `init': Called once for each buffer, the back-end can check for external
 324 programs and files and load any required libraries.  Raising an error here will
 325 show up in message log once, and the backend will not be used for completion.
 326
 327 `post-completion': Called after a completion candidate has been inserted into
 328 the buffer.  The second argument is the candidate.  Can be used to modify it,
 329 e.g. to expand a snippet.
 330
 331 The back-end should return nil for all commands it does not support or
 332 does not know about.  It should also be callable interactively and use
 333 `company-begin-backend' to start itself in that case."
 334   :group 'company
 335   :type `(repeat
 336           (choice
 337            :tag "Back-end"
 338            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 339                      company-safe-backends)
 340            (symbol :tag "User defined")
 341            (repeat :tag "Merged Back-ends"
 342                    (choice :tag "Back-end"
 343                            ,@(mapcar (lambda (b)
 344                                        `(const :tag ,(cdr b) ,(car b)))
 345                                      company-safe-backends)
 346                            (symbol :tag "User defined"))))))
 347
 348 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 349
 350 (defcustom company-completion-started-hook nil
 351   "Hook run when company starts completing.
 352 The hook is called with one argument that is non-nil if the completion was
 353 started manually."
 354   :group 'company
 355   :type 'hook)
 356
 357 (defcustom company-completion-cancelled-hook nil
 358   "Hook run when company cancels completing.
 359 The hook is called with one argument that is non-nil if the completion was
 360 aborted manually."
 361   :group 'company
 362   :type 'hook)
 363
 364 (defcustom company-completion-finished-hook nil
 365   "Hook run when company successfully completes.
 366 The hook is called with the selected candidate as an argument."
 367   :group 'company
 368   :type 'hook)
 369
 370 (defcustom company-minimum-prefix-length 3
 371   "The minimum prefix length for automatic completion."
 372   :group 'company
 373   :type '(integer :tag "prefix length"))
 374
 375 (defcustom company-require-match 'company-explicit-action-p
 376   "If enabled, disallow non-matching input.
 377 This can be a function do determine if a match is required.
 378
 379 This can be overridden by the back-end, if it returns t or 'never to
 380 'require-match.  `company-auto-complete' also takes precedence over this."
 381   :group 'company
 382   :type '(choice (const :tag "Off" nil)
 383                  (function :tag "Predicate function")
 384                  (const :tag "On, if user interaction took place"
 385                         'company-explicit-action-p)
 386                  (const :tag "On" t)))
 387
 388 (defcustom company-auto-complete 'company-explicit-action-p
 389   "Determines when to auto-complete.
 390 If this is enabled, all characters from `company-auto-complete-chars' complete
 391 the selected completion.  This can also be a function."
 392   :group 'company
 393   :type '(choice (const :tag "Off" nil)
 394                  (function :tag "Predicate function")
 395                  (const :tag "On, if user interaction took place"
 396                         'company-explicit-action-p)
 397                  (const :tag "On" t)))
 398
 399 (defcustom company-auto-complete-chars '(?\  ?\( ?\) ?. ?\" ?$ ?\' ?< ?| ?!)
 400   "Determines which characters trigger an automatic completion.
 401 See `company-auto-complete'.  If this is a string, each string character causes
 402 completion.  If it is a list of syntax description characters (see
 403 `modify-syntax-entry'), all characters with that syntax auto-complete.
 404
 405 This can also be a function, which is called with the new input and should
 406 return non-nil if company should auto-complete.
 407
 408 A character that is part of a valid candidate never starts auto-completion."
 409   :group 'company
 410   :type '(choice (string :tag "Characters")
 411                  (set :tag "Syntax"
 412                       (const :tag "Whitespace" ?\ )
 413                       (const :tag "Symbol" ?_)
 414                       (const :tag "Opening parentheses" ?\()
 415                       (const :tag "Closing parentheses" ?\))
 416                       (const :tag "Word constituent" ?w)
 417                       (const :tag "Punctuation." ?.)
 418                       (const :tag "String quote." ?\")
 419                       (const :tag "Paired delimiter." ?$)
 420                       (const :tag "Expression quote or prefix operator." ?\')
 421                       (const :tag "Comment starter." ?<)
 422                       (const :tag "Comment ender." ?>)
 423                       (const :tag "Character-quote." ?/)
 424                       (const :tag "Generic string fence." ?|)
 425                       (const :tag "Generic comment fence." ?!))
 426                  (function :tag "Predicate function")))
 427
 428 (defcustom company-idle-delay .7
 429   "The idle delay in seconds until automatic completions starts.
 430 A value of nil means never complete automatically, t means complete
 431 immediately when a prefix of `company-minimum-prefix-length' is reached."
 432   :group 'company
 433   :type '(choice (const :tag "never (nil)" nil)
 434                  (const :tag "immediate (t)" t)
 435                  (number :tag "seconds")))
 436
 437 (defcustom company-begin-commands t
 438   "A list of commands following which company will start completing.
 439 If this is t, it will complete after any command.  See `company-idle-delay'.
 440
 441 Alternatively any command with a non-nil 'company-begin property is treated as
 442 if it was on this list."
 443   :group 'company
 444   :type '(choice (const :tag "Any command" t)
 445                  (const :tag "Self insert command" '(self-insert-command))
 446                  (repeat :tag "Commands" function)))
 447
 448 (defcustom company-show-numbers nil
 449   "If enabled, show quick-access numbers for the first ten candidates."
 450   :group 'company
 451   :type '(choice (const :tag "off" nil)
 452                  (const :tag "on" t)))
 453
 454 (defvar company-end-of-buffer-workaround t
 455   "Work around a visualization bug when completing at the end of the buffer.
 456 The work-around consists of adding a newline.")
 457
 458 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 459
 460 (defvar company-mode-map (make-sparse-keymap)
 461   "Keymap used by `company-mode'.")
 462
 463 (defvar company-active-map
 464   (let ((keymap (make-sparse-keymap)))
 465     (define-key keymap "\e\e\e" 'company-abort)
 466     (define-key keymap "\C-g" 'company-abort)
 467     (define-key keymap (kbd "M-n") 'company-select-next)
 468     (define-key keymap (kbd "M-p") 'company-select-previous)
 469     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 470     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 471     (define-key keymap [down-mouse-1] 'ignore)
 472     (define-key keymap [down-mouse-3] 'ignore)
 473     (define-key keymap [mouse-1] 'company-complete-mouse)
 474     (define-key keymap [mouse-3] 'company-select-mouse)
 475     (define-key keymap [up-mouse-1] 'ignore)
 476     (define-key keymap [up-mouse-3] 'ignore)
 477     (define-key keymap [return] 'company-complete-selection)
 478     (define-key keymap [tab] 'company-complete-common)
 479     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 480     (define-key keymap "\C-w" 'company-show-location)
 481     (define-key keymap "\C-s" 'company-search-candidates)
 482     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 483     (dotimes (i 10)
 484       (define-key keymap (vector (+ (aref (kbd "M-0") 0) i))
 485         `(lambda () (interactive) (company-complete-number ,i))))
 486
 487     keymap)
 488   "Keymap that is enabled during an active completion.")
 489
 490 (defvar company--disabled-backends nil)
 491
 492 (defun company-init-backend (backend)
 493   (and (symbolp backend)
 494        (not (fboundp backend))
 495        (ignore-errors (require backend nil t)))
 496
 497   (if (or (symbolp backend)
 498           (functionp backend))
 499       (condition-case err
 500           (progn
 501             (funcall backend 'init)
 502             (put backend 'company-init t))
 503         (error
 504          (put backend 'company-init 'failed)
 505          (unless (memq backend company--disabled-backends)
 506            (message "Company back-end '%s' could not be initialized:\n%s"
 507                     backend (error-message-string err)))
 508          (pushnew backend company--disabled-backends)
 509          nil))
 510     (mapc 'company-init-backend backend)))
 511
 512 (defvar company-default-lighter " company")
 513
 514 (defvar company-lighter company-default-lighter)
 515 (make-variable-buffer-local 'company-lighter)
 516
 517 ;;;###autoload
 518 (define-minor-mode company-mode
 519   "\"complete anything\"; is an in-buffer completion framework.
 520 Completion starts automatically, depending on the values
 521 `company-idle-delay' and `company-minimum-prefix-length'.
 522
 523 Completion can be controlled with the commands:
 524 `company-complete-common', `company-complete-selection', `company-complete',
 525 `company-select-next', `company-select-previous'.  If these commands are
 526 called before `company-idle-delay', completion will also start.
 527
 528 Completions can be searched with `company-search-candidates' or
 529 `company-filter-candidates'.  These can be used while completion is
 530 inactive, as well.
 531
 532 The completion data is retrieved using `company-backends' and displayed using
 533 `company-frontends'.  If you want to start a specific back-end, call it
 534 interactively or use `company-begin-backend'.
 535
 536 regular keymap (`company-mode-map'):
 537
 538 \\{company-mode-map}
 539 keymap during active completions (`company-active-map'):
 540
 541 \\{company-active-map}"
 542   nil company-lighter company-mode-map
 543   (if company-mode
 544       (progn
 545         (add-hook 'pre-command-hook 'company-pre-command nil t)
 546         (add-hook 'post-command-hook 'company-post-command nil t)
 547         (mapc 'company-init-backend company-backends))
 548     (remove-hook 'pre-command-hook 'company-pre-command t)
 549     (remove-hook 'post-command-hook 'company-post-command t)
 550     (company-cancel)
 551     (kill-local-variable 'company-point)))
 552
 553 ;;;###autoload
 554 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 555
 556 (defun company-mode-on ()
 557   (unless (or noninteractive (eq (aref (buffer-name) 0) ?\s))
 558     (company-mode 1)))
 559
 560 (defsubst company-assert-enabled ()
 561   (unless company-mode
 562     (company-uninstall-map)
 563     (error "Company not enabled")))
 564
 565 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 566
 567 (defvar company-my-keymap nil)
 568 (make-variable-buffer-local 'company-my-keymap)
 569
 570 (defvar company-emulation-alist '((t . nil)))
 571
 572 (defsubst company-enable-overriding-keymap (keymap)
 573   (company-uninstall-map)
 574   (setq company-my-keymap keymap))
 575
 576 (defun company-ensure-emulation-alist ()
 577   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 578     (setq emulation-mode-map-alists
 579           (cons 'company-emulation-alist
 580                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 581
 582 (defun company-install-map ()
 583   (unless (or (cdar company-emulation-alist)
 584               (null company-my-keymap))
 585     (setf (cdar company-emulation-alist) company-my-keymap)))
 586
 587 (defun company-uninstall-map ()
 588   (setf (cdar company-emulation-alist) nil))
 589
 590 ;; Hack:
 591 ;; Emacs calculates the active keymaps before reading the event.  That means we
 592 ;; cannot change the keymap from a timer.  So we send a bogus command.
 593 (defun company-ignore ()
 594   (interactive)
 595   (setq this-command last-command))
 596
 597 (global-set-key '[31415926] 'company-ignore)
 598
 599 (defun company-input-noop ()
 600   (push 31415926 unread-command-events))
 601
 602 ;; Hack:
 603 ;; posn-col-row is incorrect in older Emacsen when line-spacing is set
 604 (defun company--col-row (&optional pos)
 605   (let ((posn (posn-at-point pos)))
 606     (cons (car (posn-col-row posn)) (cdr (posn-actual-col-row posn)))))
 607
 608 (defsubst company--column (&optional pos)
 609   (car (posn-col-row (posn-at-point pos))))
 610
 611 (defsubst company--row (&optional pos)
 612   (cdr (posn-actual-col-row (posn-at-point pos))))
 613
 614 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 615
 616 (defun company-grab (regexp &optional expression limit)
 617   (when (looking-back regexp limit)
 618     (or (match-string-no-properties (or expression 0)) "")))
 619
 620 (defun company-grab-line (regexp &optional expression)
 621   (company-grab regexp expression (point-at-bol)))
 622
 623 (defun company-grab-symbol ()
 624   (if (looking-at "\\_>")
 625       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 626                                                 (point)))
 627     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 628       "")))
 629
 630 (defun company-grab-word ()
 631   (if (looking-at "\\>")
 632       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 633                                                 (point)))
 634     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 635       "")))
 636
 637 (defun company-in-string-or-comment ()
 638   (let ((ppss (syntax-ppss)))
 639     (or (car (setq ppss (nthcdr 3 ppss)))
 640         (car (setq ppss (cdr ppss)))
 641         (nth 3 ppss))))
 642
 643 (if (fboundp 'locate-dominating-file)
 644     (defalias 'company-locate-dominating-file 'locate-dominating-file)
 645   (defun company-locate-dominating-file (file name)
 646     (catch 'root
 647       (let ((dir (file-name-directory file))
 648             (prev-dir nil))
 649         (while (not (equal dir prev-dir))
 650           (when (file-exists-p (expand-file-name name dir))
 651             (throw 'root dir))
 652           (setq prev-dir dir
 653                 dir (file-name-directory (directory-file-name dir))))))))
 654
 655 (defun company-call-backend (&rest args)
 656   (if (functionp company-backend)
 657       (apply company-backend args)
 658     (apply 'company--multi-backend-adapter company-backend args)))
 659
 660 (defun company--multi-backend-adapter (backends command &rest args)
 661   (let ((backends (loop for b in backends
 662                         when (not (and (symbolp b)
 663                                        (eq 'failed (get b 'company-init))))
 664                         collect b)))
 665     (case command
 666       (candidates
 667        (loop for backend in backends
 668              when (equal (funcall backend 'prefix)
 669                          (car args))
 670              append (apply backend 'candidates args)))
 671       (sorted nil)
 672       (duplicates t)
 673       (otherwise
 674        (let (value)
 675          (dolist (backend backends)
 676            (when (setq value (apply backend command args))
 677              (return value))))))))
 678
 679 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 680
 681 (defvar company-backend nil)
 682 (make-variable-buffer-local 'company-backend)
 683
 684 (defvar company-prefix nil)
 685 (make-variable-buffer-local 'company-prefix)
 686
 687 (defvar company-candidates nil)
 688 (make-variable-buffer-local 'company-candidates)
 689
 690 (defvar company-candidates-length nil)
 691 (make-variable-buffer-local 'company-candidates-length)
 692
 693 (defvar company-candidates-cache nil)
 694 (make-variable-buffer-local 'company-candidates-cache)
 695
 696 (defvar company-candidates-predicate nil)
 697 (make-variable-buffer-local 'company-candidates-predicate)
 698
 699 (defvar company-common nil)
 700 (make-variable-buffer-local 'company-common)
 701
 702 (defvar company-selection 0)
 703 (make-variable-buffer-local 'company-selection)
 704
 705 (defvar company-selection-changed nil)
 706 (make-variable-buffer-local 'company-selection-changed)
 707
 708 (defvar company--explicit-action nil
 709   "Non-nil, if explicit completion took place.")
 710 (make-variable-buffer-local 'company--explicit-action)
 711
 712 (defvar company--auto-completion nil
 713   "Non-nil when current candidate is being completed automatically.
 714 Controlled by `company-auto-complete'.")
 715
 716 (defvar company--point-max nil)
 717 (make-variable-buffer-local 'company--point-max)
 718
 719 (defvar company-point nil)
 720 (make-variable-buffer-local 'company-point)
 721
 722 (defvar company-timer nil)
 723
 724 (defvar company-added-newline nil)
 725 (make-variable-buffer-local 'company-added-newline)
 726
 727 (defsubst company-strip-prefix (str)
 728   (substring str (length company-prefix)))
 729
 730 (defmacro company-with-candidate-inserted (candidate &rest body)
 731   "Evaluate BODY with CANDIDATE temporarily inserted.
 732 This is a tool for back-ends that need candidates inserted before they
 733 can retrieve meta-data for them."
 734   (declare (indent 1))
 735   `(let ((inhibit-modification-hooks t)
 736          (inhibit-point-motion-hooks t)
 737          (modified-p (buffer-modified-p)))
 738      (insert (company-strip-prefix ,candidate))
 739      (unwind-protect
 740          (progn ,@body)
 741        (delete-region company-point (point)))))
 742
 743 (defun company-explicit-action-p ()
 744   "Return whether explicit completion action was taken by the user."
 745   (or company--explicit-action
 746       company-selection-changed))
 747
 748 (defsubst company-reformat (candidate)
 749   ;; company-ispell needs this, because the results are always lower-case
 750   ;; It's mory efficient to fix it only when they are displayed.
 751   (concat company-prefix (substring candidate (length company-prefix))))
 752
 753 (defun company--should-complete ()
 754   (and (not (or buffer-read-only overriding-terminal-local-map
 755                 overriding-local-map
 756                 (minibufferp)))
 757        ;; Check if in the middle of entering a key combination.
 758        (or (equal (this-command-keys-vector) [])
 759            (not (keymapp (key-binding (this-command-keys-vector)))))
 760        (eq company-idle-delay t)
 761        (or (eq t company-begin-commands)
 762            (memq this-command company-begin-commands)
 763            (and (symbolp this-command) (get this-command 'company-begin)))
 764        (not (and transient-mark-mode mark-active))))
 765
 766 (defsubst company-call-frontends (command)
 767   (dolist (frontend company-frontends)
 768     (condition-case err
 769         (funcall frontend command)
 770       (error (error "Company: Front-end %s error \"%s\" on command %s"
 771                     frontend (error-message-string err) command)))))
 772
 773 (defsubst company-set-selection (selection &optional force-update)
 774   (setq selection (max 0 (min (1- company-candidates-length) selection)))
 775   (when (or force-update (not (equal selection company-selection)))
 776     (setq company-selection selection
 777           company-selection-changed t)
 778     (company-call-frontends 'update)))
 779
 780 (defun company-apply-predicate (candidates predicate)
 781   (let (new)
 782     (dolist (c candidates)
 783       (when (funcall predicate c)
 784         (push c new)))
 785     (nreverse new)))
 786
 787 (defun company-update-candidates (candidates)
 788   (setq company-candidates-length (length candidates))
 789   (if (> company-selection 0)
 790       ;; Try to restore the selection
 791       (let ((selected (nth company-selection company-candidates)))
 792         (setq company-selection 0
 793               company-candidates candidates)
 794         (when selected
 795           (while (and candidates (string< (pop candidates) selected))
 796             (incf company-selection))
 797           (unless candidates
 798             ;; Make sure selection isn't out of bounds.
 799             (setq company-selection (min (1- company-candidates-length)
 800                                          company-selection)))))
 801     (setq company-selection 0
 802           company-candidates candidates))
 803   ;; Save in cache:
 804   (push (cons company-prefix company-candidates) company-candidates-cache)
 805   ;; Calculate common.
 806   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
 807     (setq company-common (company--safe-candidate
 808                           (try-completion company-prefix company-candidates))))
 809   (when (eq company-common t)
 810     (setq company-candidates nil)))
 811
 812 (defun company--safe-candidate (str)
 813   (or (company-call-backend 'crop str)
 814       str))
 815
 816 (defun company-calculate-candidates (prefix)
 817   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
 818         (ignore-case (company-call-backend 'ignore-case)))
 819     (or candidates
 820         (when company-candidates-cache
 821           (let ((len (length prefix))
 822                 (completion-ignore-case ignore-case)
 823                 prev)
 824             (dotimes (i (1+ len))
 825               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
 826                                            company-candidates-cache)))
 827                 (setq candidates (all-completions prefix prev))
 828                 (return t)))))
 829         ;; no cache match, call back-end
 830         (progn
 831           (setq candidates (company-call-backend 'candidates prefix))
 832           (when company-candidates-predicate
 833             (setq candidates
 834                   (company-apply-predicate candidates
 835                                            company-candidates-predicate)))
 836           (unless (company-call-backend 'sorted)
 837             (setq candidates (sort candidates 'string<)))
 838           (when (company-call-backend 'duplicates)
 839             ;; strip duplicates
 840             (let ((c2 candidates))
 841               (while c2
 842                 (setcdr c2 (progn (while (equal (pop c2) (car c2)))
 843                                   c2)))))))
 844     (when candidates
 845       (if (or (cdr candidates)
 846               (not (eq t (compare-strings (car candidates) nil nil
 847                                           prefix nil nil ignore-case))))
 848           candidates
 849         ;; Already completed and unique; don't start.
 850         t))))
 851
 852 (defun company-idle-begin (buf win tick pos)
 853   (and company-mode
 854        (eq buf (current-buffer))
 855        (eq win (selected-window))
 856        (eq tick (buffer-chars-modified-tick))
 857        (eq pos (point))
 858        (not company-candidates)
 859        (not (equal (point) company-point))
 860        (let ((company-idle-delay t)
 861              (company-begin-commands t))
 862          (company-begin)
 863          (when company-candidates
 864            (company-input-noop)
 865            (company-post-command)))))
 866
 867 (defun company-auto-begin ()
 868   (company-assert-enabled)
 869   (and company-mode
 870        (not company-candidates)
 871        (let ((company-idle-delay t)
 872              (company-minimum-prefix-length 0)
 873              (company-begin-commands t))
 874          (company-begin)))
 875   ;; Return non-nil if active.
 876   company-candidates)
 877
 878 (defun company-manual-begin ()
 879   (interactive)
 880   (setq company--explicit-action t)
 881   (company-auto-begin))
 882
 883 (defun company-other-backend (&optional backward)
 884   (interactive (list current-prefix-arg))
 885   (company-assert-enabled)
 886   (if company-backend
 887       (let* ((after (cdr (member company-backend company-backends)))
 888              (before (cdr (member company-backend (reverse company-backends))))
 889              (next (if backward
 890                        (append before (reverse after))
 891                      (append after (reverse before)))))
 892         (company-cancel)
 893         (dolist (backend next)
 894           (when (ignore-errors (company-begin-backend backend))
 895             (return t))))
 896     (company-manual-begin))
 897   (unless company-candidates
 898     (error "No other back-end")))
 899
 900 (defun company-require-match-p ()
 901   (let ((backend-value (company-call-backend 'require-match)))
 902     (or (eq backend-value t)
 903         (and (if (functionp company-require-match)
 904                  (funcall company-require-match)
 905                (eq company-require-match t))
 906              (not (eq backend-value 'never))))))
 907
 908 (defun company-punctuation-p (input)
 909   "Return non-nil, if input starts with punctuation or parentheses."
 910   (memq (char-syntax (string-to-char input)) '(?. ?\( ?\))))
 911
 912 (defun company-auto-complete-p (input)
 913   "Return non-nil, if input starts with punctuation or parentheses."
 914   (and (if (functionp company-auto-complete)
 915            (funcall company-auto-complete)
 916          company-auto-complete)
 917        (if (functionp company-auto-complete-chars)
 918            (funcall company-auto-complete-chars input)
 919          (if (consp company-auto-complete-chars)
 920              (memq (char-syntax (string-to-char input))
 921                    company-auto-complete-chars)
 922            (string-match (substring input 0 1) company-auto-complete-chars)))))
 923
 924 (defun company--incremental-p ()
 925   (and (> (point) company-point)
 926        (> (point-max) company--point-max)
 927        (not (eq this-command 'backward-delete-char-untabify))
 928        (equal (buffer-substring (- company-point (length company-prefix))
 929                                 company-point)
 930               company-prefix)))
 931
 932 (defsubst company--string-incremental-p (old-prefix new-prefix)
 933   (and (> (length new-prefix) (length old-prefix))
 934        (equal old-prefix (substring new-prefix 0 (length old-prefix)))))
 935
 936 (defun company--continue-failed (new-prefix)
 937   (when (company--incremental-p)
 938     (let ((input (buffer-substring-no-properties (point) company-point)))
 939       (cond
 940        ((company-auto-complete-p input)
 941         ;; auto-complete
 942         (save-excursion
 943           (goto-char company-point)
 944           (let ((company--auto-completion t))
 945             (company-complete-selection))
 946           nil))
 947        ((and (company--string-incremental-p company-prefix new-prefix)
 948              (company-require-match-p))
 949         ;; wrong incremental input, but required match
 950         (backward-delete-char (length input))
 951         (ding)
 952         (message "Matching input is required")
 953         company-candidates)
 954        ((equal company-prefix (car company-candidates))
 955         ;; last input was actually success
 956         (company-cancel company-prefix)
 957         nil)))))
 958
 959 (defun company--good-prefix-p (prefix)
 960   (and (or (company-explicit-action-p)
 961            (unless (eq prefix 'stop)
 962              (>= (or (cdr-safe prefix) (length prefix))
 963                  company-minimum-prefix-length)))
 964        (stringp (or (car-safe prefix) prefix))))
 965
 966 (defun company--continue ()
 967   (when (company-call-backend 'no-cache company-prefix)
 968     ;; Don't complete existing candidates, fetch new ones.
 969     (setq company-candidates-cache nil))
 970   (let* ((new-prefix (company-call-backend 'prefix))
 971          (c (when (and (company--good-prefix-p new-prefix)
 972                        (setq new-prefix (or (car-safe new-prefix) new-prefix))
 973                        (= (- (point) (length new-prefix))
 974                           (- company-point (length company-prefix))))
 975               (setq new-prefix (or (car-safe new-prefix) new-prefix))
 976               (company-calculate-candidates new-prefix))))
 977     (or (cond
 978          ((eq c t)
 979           ;; t means complete/unique.
 980           (company-cancel new-prefix)
 981           nil)
 982          ((consp c)
 983           ;; incremental match
 984           (setq company-prefix new-prefix)
 985           (company-update-candidates c)
 986           c)
 987          (t (company--continue-failed new-prefix)))
 988         (company-cancel))))
 989
 990 (defun company--begin-new ()
 991   (let (prefix c)
 992     (dolist (backend (if company-backend
 993                          ;; prefer manual override
 994                          (list company-backend)
 995                        company-backends))
 996       (setq prefix
 997             (if (or (symbolp backend)
 998                     (functionp backend))
 999                 (when (or (not (symbolp backend))
1000                           (eq t (get backend 'company-init))
1001                           (unless (get backend 'company-init)
1002                             (company-init-backend backend)))
1003                   (funcall backend 'prefix))
1004               (company--multi-backend-adapter backend 'prefix)))
1005       (when prefix
1006         (when (company--good-prefix-p prefix)
1007           (setq prefix (or (car-safe prefix) prefix)
1008                 company-backend backend
1009                 c (company-calculate-candidates prefix))
1010           ;; t means complete/unique.  We don't start, so no hooks.
1011           (if (not (consp c))
1012               (when company--explicit-action
1013                 (message "No completion found"))
1014             (setq company-prefix prefix)
1015             (when (symbolp backend)
1016               (setq company-lighter (concat " " (symbol-name backend))))
1017             (company-update-candidates c)
1018             (run-hook-with-args 'company-completion-started-hook
1019                                 (company-explicit-action-p))
1020             (company-call-frontends 'show)))
1021         (return c)))))
1022
1023 (defun company-begin ()
1024   (or (and company-candidates (company--continue))
1025       (and (company--should-complete) (company--begin-new)))
1026   (when company-candidates
1027     (when (and company-end-of-buffer-workaround (eobp))
1028       (save-excursion (insert "\n"))
1029       (setq company-added-newline (buffer-chars-modified-tick)))
1030     (setq company-point (point)
1031           company--point-max (point-max))
1032     (company-ensure-emulation-alist)
1033     (company-enable-overriding-keymap company-active-map)
1034     (company-call-frontends 'update)))
1035
1036 (defun company-cancel (&optional result)
1037   (and company-added-newline
1038        (> (point-max) (point-min))
1039        (let ((tick (buffer-chars-modified-tick)))
1040          (delete-region (1- (point-max)) (point-max))
1041          (equal tick company-added-newline))
1042        ;; Only set unmodified when tick remained the same since insert.
1043        (set-buffer-modified-p nil))
1044   (when company-prefix
1045     (if (stringp result)
1046         (progn
1047           (company-call-backend 'pre-completion result)
1048           (run-hook-with-args 'company-completion-finished-hook result)
1049           (company-call-backend 'post-completion result))
1050       (run-hook-with-args 'company-completion-cancelled-hook result)))
1051   (setq company-added-newline nil
1052         company-backend nil
1053         company-prefix nil
1054         company-candidates nil
1055         company-candidates-length nil
1056         company-candidates-cache nil
1057         company-candidates-predicate nil
1058         company-common nil
1059         company-selection 0
1060         company-selection-changed nil
1061         company--explicit-action nil
1062         company-lighter company-default-lighter
1063         company--point-max nil
1064         company-point nil)
1065   (when company-timer
1066     (cancel-timer company-timer))
1067   (company-search-mode 0)
1068   (company-call-frontends 'hide)
1069   (company-enable-overriding-keymap nil))
1070
1071 (defun company-abort ()
1072   (interactive)
1073   (company-cancel t)
1074   ;; Don't start again, unless started manually.
1075   (setq company-point (point)))
1076
1077 (defun company-finish (result)
1078   (insert (company-strip-prefix result))
1079   (company-cancel result)
1080   ;; Don't start again, unless started manually.
1081   (setq company-point (point)))
1082
1083 (defsubst company-keep (command)
1084   (and (symbolp command) (get command 'company-keep)))
1085
1086 (defun company-pre-command ()
1087   (unless (company-keep this-command)
1088     (condition-case err
1089         (when company-candidates
1090           (company-call-frontends 'pre-command))
1091       (error (message "Company: An error occurred in pre-command")
1092              (message "%s" (error-message-string err))
1093              (company-cancel))))
1094   (when company-timer
1095     (cancel-timer company-timer)
1096     (setq company-timer nil))
1097   (company-uninstall-map))
1098
1099 (defun company-post-command ()
1100   (unless (company-keep this-command)
1101     (condition-case err
1102         (progn
1103           (unless (equal (point) company-point)
1104             (company-begin))
1105           (if company-candidates
1106               (company-call-frontends 'post-command)
1107             (and (numberp company-idle-delay)
1108                  (or (eq t company-begin-commands)
1109                      (memq this-command company-begin-commands))
1110                  (setq company-timer
1111                        (run-with-timer company-idle-delay nil
1112                                        'company-idle-begin
1113                                        (current-buffer) (selected-window)
1114                                        (buffer-chars-modified-tick) (point))))))
1115       (error (message "Company: An error occurred in post-command")
1116              (message "%s" (error-message-string err))
1117              (company-cancel))))
1118   (company-install-map))
1119
1120 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1121
1122 (defvar company-search-string nil)
1123 (make-variable-buffer-local 'company-search-string)
1124
1125 (defvar company-search-lighter " Search: \"\"")
1126 (make-variable-buffer-local 'company-search-lighter)
1127
1128 (defvar company-search-old-map nil)
1129 (make-variable-buffer-local 'company-search-old-map)
1130
1131 (defvar company-search-old-selection 0)
1132 (make-variable-buffer-local 'company-search-old-selection)
1133
1134 (defun company-search (text lines)
1135   (let ((quoted (regexp-quote text))
1136         (i 0))
1137     (dolist (line lines)
1138       (when (string-match quoted line (length company-prefix))
1139         (return i))
1140       (incf i))))
1141
1142 (defun company-search-printing-char ()
1143   (interactive)
1144   (company-search-assert-enabled)
1145   (setq company-search-string
1146         (concat (or company-search-string "") (string last-command-event))
1147         company-search-lighter (concat " Search: \"" company-search-string
1148                                         "\""))
1149   (let ((pos (company-search company-search-string
1150                               (nthcdr company-selection company-candidates))))
1151     (if (null pos)
1152         (ding)
1153       (company-set-selection (+ company-selection pos) t))))
1154
1155 (defun company-search-repeat-forward ()
1156   "Repeat the incremental search in completion candidates forward."
1157   (interactive)
1158   (company-search-assert-enabled)
1159   (let ((pos (company-search company-search-string
1160                               (cdr (nthcdr company-selection
1161                                            company-candidates)))))
1162     (if (null pos)
1163         (ding)
1164       (company-set-selection (+ company-selection pos 1) t))))
1165
1166 (defun company-search-repeat-backward ()
1167   "Repeat the incremental search in completion candidates backwards."
1168   (interactive)
1169   (company-search-assert-enabled)
1170   (let ((pos (company-search company-search-string
1171                               (nthcdr (- company-candidates-length
1172                                          company-selection)
1173                                       (reverse company-candidates)))))
1174     (if (null pos)
1175         (ding)
1176       (company-set-selection (- company-selection pos 1) t))))
1177
1178 (defun company-create-match-predicate ()
1179   (setq company-candidates-predicate
1180         `(lambda (candidate)
1181            ,(if company-candidates-predicate
1182                 `(and (string-match ,company-search-string candidate)
1183                       (funcall ,company-candidates-predicate
1184                                candidate))
1185               `(string-match ,company-search-string candidate))))
1186   (company-update-candidates
1187    (company-apply-predicate company-candidates company-candidates-predicate))
1188   ;; Invalidate cache.
1189   (setq company-candidates-cache (cons company-prefix company-candidates)))
1190
1191 (defun company-filter-printing-char ()
1192   (interactive)
1193   (company-search-assert-enabled)
1194   (company-search-printing-char)
1195   (company-create-match-predicate)
1196   (company-call-frontends 'update))
1197
1198 (defun company-search-kill-others ()
1199   "Limit the completion candidates to the ones matching the search string."
1200   (interactive)
1201   (company-search-assert-enabled)
1202   (company-create-match-predicate)
1203   (company-search-mode 0)
1204   (company-call-frontends 'update))
1205
1206 (defun company-search-abort ()
1207   "Abort searching the completion candidates."
1208   (interactive)
1209   (company-search-assert-enabled)
1210   (company-set-selection company-search-old-selection t)
1211   (company-search-mode 0))
1212
1213 (defun company-search-other-char ()
1214   (interactive)
1215   (company-search-assert-enabled)
1216   (company-search-mode 0)
1217   (company--unread-last-input))
1218
1219 (defvar company-search-map
1220   (let ((i 0)
1221         (keymap (make-keymap)))
1222     (if (fboundp 'max-char)
1223         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1224                               'company-search-printing-char)
1225       (with-no-warnings
1226         ;; obsolete in Emacs 23
1227         (let ((l (generic-character-list))
1228               (table (nth 1 keymap)))
1229           (while l
1230             (set-char-table-default table (car l) 'company-search-printing-char)
1231             (setq l (cdr l))))))
1232     (define-key keymap [t] 'company-search-other-char)
1233     (while (< i ?\s)
1234       (define-key keymap (make-string 1 i) 'company-search-other-char)
1235       (incf i))
1236     (while (< i 256)
1237       (define-key keymap (vector i) 'company-search-printing-char)
1238       (incf i))
1239     (let ((meta-map (make-sparse-keymap)))
1240       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1241       (define-key keymap [escape] meta-map))
1242     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1243     (define-key keymap "\e\e\e" 'company-search-other-char)
1244     (define-key keymap  [escape escape escape] 'company-search-other-char)
1245
1246     (define-key keymap "\C-g" 'company-search-abort)
1247     (define-key keymap "\C-s" 'company-search-repeat-forward)
1248     (define-key keymap "\C-r" 'company-search-repeat-backward)
1249     (define-key keymap "\C-o" 'company-search-kill-others)
1250     keymap)
1251   "Keymap used for incrementally searching the completion candidates.")
1252
1253 (define-minor-mode company-search-mode
1254   "Search mode for completion candidates.
1255 Don't start this directly, use `company-search-candidates' or
1256 `company-filter-candidates'."
1257   nil company-search-lighter nil
1258   (if company-search-mode
1259       (if (company-manual-begin)
1260           (progn
1261             (setq company-search-old-selection company-selection)
1262             (company-call-frontends 'update))
1263         (setq company-search-mode nil))
1264     (kill-local-variable 'company-search-string)
1265     (kill-local-variable 'company-search-lighter)
1266     (kill-local-variable 'company-search-old-selection)
1267     (company-enable-overriding-keymap company-active-map)))
1268
1269 (defsubst company-search-assert-enabled ()
1270   (company-assert-enabled)
1271   (unless company-search-mode
1272     (company-uninstall-map)
1273     (error "Company not in search mode")))
1274
1275 (defun company-search-candidates ()
1276   "Start searching the completion candidates incrementally.
1277
1278 \\<company-search-map>Search can be controlled with the commands:
1279 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1280 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1281 - `company-search-abort' (\\[company-search-abort])
1282
1283 Regular characters are appended to the search string.
1284
1285 The command `company-search-kill-others' (\\[company-search-kill-others]) uses
1286  the search string to limit the completion candidates."
1287   (interactive)
1288   (company-search-mode 1)
1289   (company-enable-overriding-keymap company-search-map))
1290
1291 (defvar company-filter-map
1292   (let ((keymap (make-keymap)))
1293     (define-key keymap [remap company-search-printing-char]
1294       'company-filter-printing-char)
1295     (set-keymap-parent keymap company-search-map)
1296     keymap)
1297   "Keymap used for incrementally searching the completion candidates.")
1298
1299 (defun company-filter-candidates ()
1300   "Start filtering the completion candidates incrementally.
1301 This works the same way as `company-search-candidates' immediately
1302 followed by `company-search-kill-others' after each input."
1303   (interactive)
1304   (company-search-mode 1)
1305   (company-enable-overriding-keymap company-filter-map))
1306
1307 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1308
1309 (defun company-select-next ()
1310   "Select the next candidate in the list."
1311   (interactive)
1312   (when (company-manual-begin)
1313     (company-set-selection (1+ company-selection))))
1314
1315 (defun company-select-previous ()
1316   "Select the previous candidate in the list."
1317   (interactive)
1318   (when (company-manual-begin)
1319     (company-set-selection (1- company-selection))))
1320
1321 (defun company-select-next-or-abort ()
1322   "Select the next candidate if more than one, else abort
1323 and invoke the normal binding."
1324   (interactive)
1325   (if (> company-candidates-length 1)
1326       (company-select-next)
1327     (company-abort)
1328     (company--unread-last-input)))
1329
1330 (defun company-select-previous-or-abort ()
1331   "Select the previous candidate if more than one, else abort
1332 and invoke the normal binding."
1333   (interactive)
1334   (if (> company-candidates-length 1)
1335       (company-select-previous)
1336     (company-abort)
1337     (company--unread-last-input)))
1338
1339 (defun company-select-mouse (event)
1340   "Select the candidate picked by the mouse."
1341   (interactive "e")
1342   (when (nth 4 (event-start event))
1343     (company-set-selection (- (cdr (posn-actual-col-row (event-start event)))
1344                               (company--row)
1345                               1))
1346     t))
1347
1348 (defun company-complete-mouse (event)
1349   "Complete the candidate picked by the mouse."
1350   (interactive "e")
1351   (when (company-select-mouse event)
1352     (company-complete-selection)))
1353
1354 (defun company-complete-selection ()
1355   "Complete the selected candidate."
1356   (interactive)
1357   (when (company-manual-begin)
1358     (let ((result (nth company-selection company-candidates)))
1359       (when company--auto-completion
1360         (setq result (company--safe-candidate result)))
1361       (company-finish result))))
1362
1363 (defun company-complete-common ()
1364   "Complete the common part of all candidates."
1365   (interactive)
1366   (when (company-manual-begin)
1367     (if (and (not (cdr company-candidates))
1368              (equal company-common (car company-candidates)))
1369         (company-complete-selection)
1370       (insert (company-strip-prefix company-common)))))
1371
1372 (defun company-complete ()
1373   "Complete the common part of all candidates or the current selection.
1374 The first time this is called, the common part is completed, the second time, or
1375 when the selection has been changed, the selected candidate is completed."
1376   (interactive)
1377   (when (company-manual-begin)
1378     (if (or company-selection-changed
1379             (eq last-command 'company-complete-common))
1380         (call-interactively 'company-complete-selection)
1381       (call-interactively 'company-complete-common)
1382       (setq this-command 'company-complete-common))))
1383
1384 (defun company-complete-number (n)
1385   "Complete the Nth candidate.
1386 To show the number next to the candidates in some back-ends, enable
1387 `company-show-numbers'."
1388   (when (company-manual-begin)
1389     (and (< n 1) (> n company-candidates-length)
1390          (error "No candidate number %d" n))
1391     (decf n)
1392     (company-finish (nth n company-candidates))))
1393
1394 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1395
1396 (defconst company-space-strings-limit 100)
1397
1398 (defconst company-space-strings
1399   (let (lst)
1400     (dotimes (i company-space-strings-limit)
1401       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1402     (apply 'vector lst)))
1403
1404 (defsubst company-space-string (len)
1405   (if (< len company-space-strings-limit)
1406       (aref company-space-strings len)
1407     (make-string len ?\ )))
1408
1409 (defsubst company-safe-substring (str from &optional to)
1410   (if (> from (string-width str))
1411       ""
1412     (with-temp-buffer
1413       (insert str)
1414       (move-to-column from)
1415       (let ((beg (point)))
1416         (if to
1417             (progn
1418               (move-to-column to)
1419               (concat (buffer-substring beg (point))
1420                       (let ((padding (- to (current-column))))
1421                         (when (> padding 0)
1422                           (company-space-string padding)))))
1423           (buffer-substring beg (point-max)))))))
1424
1425 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1426
1427 (defvar company-last-metadata nil)
1428 (make-variable-buffer-local 'company-last-metadata)
1429
1430 (defun company-fetch-metadata ()
1431   (let ((selected (nth company-selection company-candidates)))
1432     (unless (equal selected (car company-last-metadata))
1433       (setq company-last-metadata
1434             (cons selected (company-call-backend 'meta selected))))
1435     (cdr company-last-metadata)))
1436
1437 (defun company-doc-buffer (&optional string)
1438   (with-current-buffer (get-buffer-create "*Company meta-data*")
1439     (erase-buffer)
1440     (current-buffer)))
1441
1442 (defvar company--electric-commands
1443   '(scroll-other-window scroll-other-window-down)
1444   "List of Commands that won't break out of electric commands.")
1445
1446 (defmacro company--electric-do (&rest body)
1447   (declare (indent 0) (debug t))
1448   `(when (company-manual-begin)
1449      (save-window-excursion
1450        (let ((height (window-height))
1451              (row (company--row))
1452              cmd)
1453          ,@body
1454          (and (< (window-height) height)
1455               (< (- (window-height) row 2) company-tooltip-limit)
1456               (recenter (- (window-height) row 2)))
1457          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1458                       company--electric-commands)
1459            (call-interactively cmd))
1460          (company--unread-last-input)))))
1461
1462 (defun company--unread-last-input ()
1463   (when last-input-event
1464     (clear-this-command-keys t)
1465     (setq unread-command-events (list last-input-event))))
1466
1467 (defun company-show-doc-buffer ()
1468   "Temporarily show a buffer with the complete documentation for the selection."
1469   (interactive)
1470   (company--electric-do
1471     (let* ((selected (nth company-selection company-candidates))
1472            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1473                            (error "No documentation available"))))
1474       (with-current-buffer doc-buffer
1475         (goto-char (point-min)))
1476       (display-buffer doc-buffer t))))
1477 (put 'company-show-doc-buffer 'company-keep t)
1478
1479 (defun company-show-location ()
1480   "Temporarily display a buffer showing the selected candidate in context."
1481   (interactive)
1482   (company--electric-do
1483     (let* ((selected (nth company-selection company-candidates))
1484            (location (company-call-backend 'location selected))
1485            (pos (or (cdr location) (error "No location available")))
1486            (buffer (or (and (bufferp (car location)) (car location))
1487                        (find-file-noselect (car location) t))))
1488       (with-selected-window (display-buffer buffer t)
1489         (save-restriction
1490           (widen)
1491           (if (bufferp (car location))
1492               (goto-char pos)
1493             (goto-char (point-min))
1494             (forward-line (1- pos))))
1495         (set-window-start nil (point))))))
1496 (put 'company-show-location 'company-keep t)
1497
1498 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1499
1500 (defvar company-callback nil)
1501 (make-variable-buffer-local 'company-callback)
1502
1503 (defvar company-begin-with-marker nil)
1504 (make-variable-buffer-local 'company-begin-with-marker)
1505
1506 (defun company-remove-callback (&optional ignored)
1507   (remove-hook 'company-completion-finished-hook company-callback t)
1508   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1509   (remove-hook 'company-completion-finished-hook 'company-remove-callback t)
1510   (when company-begin-with-marker
1511     (set-marker company-begin-with-marker nil)))
1512
1513 (defun company-begin-backend (backend &optional callback)
1514   "Start a completion at point using BACKEND."
1515   (interactive (let ((val (completing-read "Company back-end: "
1516                                            obarray
1517                                            'functionp nil "company-")))
1518                  (when val
1519                    (list (intern val)))))
1520   (when (setq company-callback callback)
1521     (add-hook 'company-completion-finished-hook company-callback nil t))
1522   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1523   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1524   (setq company-backend backend)
1525   ;; Return non-nil if active.
1526   (or (company-manual-begin)
1527       (progn
1528         (setq company-backend nil)
1529         (error "Cannot complete at point"))))
1530
1531 (defun company-begin-with (candidates
1532                            &optional prefix-length require-match callback)
1533   "Start a completion at point.
1534 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length of
1535 the prefix that already is in the buffer before point.  It defaults to 0.
1536
1537 CALLBACK is a function called with the selected result if the user successfully
1538 completes the input.
1539
1540 Example:
1541 \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
1542   (setq company-begin-with-marker (copy-marker (point) t))
1543   (company-begin-backend
1544    `(lambda (command &optional arg &rest ignored)
1545       (cond
1546        ((eq command 'prefix)
1547         (when (equal (point) (marker-position company-begin-with-marker))
1548           (buffer-substring ,(- (point) (or prefix-length 0)) (point))))
1549        ((eq command 'candidates)
1550         (all-completions arg ',candidates))
1551        ((eq command 'require-match)
1552         ,require-match)))
1553    callback))
1554
1555 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1556
1557 (defvar company-pseudo-tooltip-overlay nil)
1558 (make-variable-buffer-local 'company-pseudo-tooltip-overlay)
1559
1560 (defvar company-tooltip-offset 0)
1561 (make-variable-buffer-local 'company-tooltip-offset)
1562
1563 (defun company-pseudo-tooltip-update-offset (selection num-lines limit)
1564
1565   (decf limit 2)
1566   (setq company-tooltip-offset
1567         (max (min selection company-tooltip-offset)
1568              (- selection -1 limit)))
1569
1570   (when (<= company-tooltip-offset 1)
1571     (incf limit)
1572     (setq company-tooltip-offset 0))
1573
1574   (when (>= company-tooltip-offset (- num-lines limit 1))
1575     (incf limit)
1576     (when (= selection (1- num-lines))
1577       (decf company-tooltip-offset)
1578       (when (<= company-tooltip-offset 1)
1579         (setq company-tooltip-offset 0)
1580         (incf limit))))
1581
1582   limit)
1583
1584 ;;; propertize
1585
1586 (defsubst company-round-tab (arg)
1587   (* (/ (+ arg tab-width) tab-width) tab-width))
1588
1589 (defun company-untabify (str)
1590   (let* ((pieces (split-string str "\t"))
1591          (copy pieces))
1592     (while (cdr copy)
1593       (setcar copy (company-safe-substring
1594                     (car copy) 0 (company-round-tab (string-width (car copy)))))
1595       (pop copy))
1596     (apply 'concat pieces)))
1597
1598 (defun company-fill-propertize (line width selected)
1599   (setq line (company-safe-substring line 0 width))
1600   (add-text-properties 0 width '(face company-tooltip
1601                                  mouse-face company-tooltip-mouse)
1602                        line)
1603   (add-text-properties 0 (length company-common)
1604                        '(face company-tooltip-common
1605                          mouse-face company-tooltip-mouse)
1606                        line)
1607   (when selected
1608     (if (and company-search-string
1609              (string-match (regexp-quote company-search-string) line
1610                            (length company-prefix)))
1611         (progn
1612           (add-text-properties (match-beginning 0) (match-end 0)
1613                                '(face company-tooltip-selection)
1614                                line)
1615           (when (< (match-beginning 0) (length company-common))
1616             (add-text-properties (match-beginning 0) (length company-common)
1617                                  '(face company-tooltip-common-selection)
1618                                  line)))
1619       (add-text-properties 0 width '(face company-tooltip-selection
1620                                           mouse-face company-tooltip-selection)
1621                            line)
1622       (add-text-properties 0 (length company-common)
1623                            '(face company-tooltip-common-selection
1624                              mouse-face company-tooltip-selection)
1625                            line)))
1626   line)
1627
1628 ;;; replace
1629
1630 (defun company-buffer-lines (beg end)
1631   (goto-char beg)
1632   (let (lines)
1633     (while (and (= 1 (vertical-motion 1))
1634                 (<= (point) end))
1635       (push (buffer-substring beg (min end (1- (point)))) lines)
1636       (setq beg (point)))
1637     (unless (eq beg end)
1638       (push (buffer-substring beg end) lines))
1639     (nreverse lines)))
1640
1641 (defsubst company-modify-line (old new offset)
1642   (concat (company-safe-substring old 0 offset)
1643           new
1644           (company-safe-substring old (+ offset (length new)))))
1645
1646 (defsubst company--length-limit (lst limit)
1647   (if (nthcdr limit lst)
1648       limit
1649     (length lst)))
1650
1651 (defun company--replacement-string (lines old column nl &optional align-top)
1652
1653   (let ((width (length (car lines))))
1654     (when (> width (- (window-width) column))
1655       (setq column (max 0 (- (window-width) width)))))
1656
1657   (let (new)
1658     (when align-top
1659       ;; untouched lines first
1660       (dotimes (i (- (length old) (length lines)))
1661         (push (pop old) new)))
1662     ;; length into old lines.
1663     (while old
1664       (push (company-modify-line (pop old) (pop lines) column) new))
1665     ;; Append whole new lines.
1666     (while lines
1667       (push (concat (company-space-string column) (pop lines)) new))
1668
1669     (let ((str (concat (when nl "\n")
1670                        (mapconcat 'identity (nreverse new) "\n")
1671                        "\n")))
1672       (font-lock-append-text-property 0 (length str) 'face 'default str)
1673       str)))
1674
1675 (defun company--create-lines (selection limit)
1676
1677   (let ((len company-candidates-length)
1678         (numbered 99999)
1679         lines
1680         width
1681         lines-copy
1682         previous
1683         remainder
1684         new)
1685
1686     ;; Scroll to offset.
1687     (setq limit (company-pseudo-tooltip-update-offset selection len limit))
1688
1689     (when (> company-tooltip-offset 0)
1690       (setq previous (format "...(%d)" company-tooltip-offset)))
1691
1692     (setq remainder (- len limit company-tooltip-offset)
1693           remainder (when (> remainder 0)
1694                       (setq remainder (format "...(%d)" remainder))))
1695
1696     (decf selection company-tooltip-offset)
1697     (setq width (max (length previous) (length remainder))
1698           lines (nthcdr company-tooltip-offset company-candidates)
1699           len (min limit len)
1700           lines-copy lines)
1701
1702     (dotimes (i len)
1703       (setq width (max (length (pop lines-copy)) width)))
1704     (setq width (min width (window-width)))
1705
1706     (setq lines-copy lines)
1707
1708     ;; number can make tooltip too long
1709     (when company-show-numbers
1710       (setq numbered company-tooltip-offset))
1711
1712     (when previous
1713       (push (propertize (company-safe-substring previous 0 width)
1714                         'face 'company-tooltip)
1715             new))
1716
1717     (dotimes (i len)
1718       (push (company-fill-propertize
1719              (if (>= numbered 10)
1720                  (company-reformat (pop lines))
1721                (incf numbered)
1722                (format "%s %d"
1723                        (company-safe-substring (company-reformat (pop lines))
1724                                                0 (- width 2))
1725                        (mod numbered 10)))
1726              width (equal i selection))
1727             new))
1728
1729     (when remainder
1730       (push (propertize (company-safe-substring remainder 0 width)
1731                         'face 'company-tooltip)
1732             new))
1733
1734     (setq lines (nreverse new))))
1735
1736 ;; show
1737
1738 (defsubst company--window-inner-height ()
1739   (let ((edges (window-inside-edges (selected-window))))
1740     (- (nth 3 edges) (nth 1 edges))))
1741
1742 (defsubst company--pseudo-tooltip-height ()
1743   "Calculate the appropriate tooltip height.
1744 Returns a negative number if the tooltip should be displayed above point."
1745   (let* ((lines (company--row))
1746          (below (- (company--window-inner-height) 1 lines)))
1747     (if (and (< below (min company-tooltip-minimum company-candidates-length))
1748              (> lines below))
1749         (- (max 3 (min company-tooltip-limit lines)))
1750       (max 3 (min company-tooltip-limit below)))))
1751
1752 (defun company-pseudo-tooltip-show (row column selection)
1753   (company-pseudo-tooltip-hide)
1754   (save-excursion
1755
1756     (move-to-column 0)
1757
1758     (let* ((height (company--pseudo-tooltip-height))
1759            above)
1760
1761       (when (< height 0)
1762         (setq row (+ row height -1)
1763               above t))
1764
1765       (let* ((nl (< (move-to-window-line row) row))
1766              (beg (point))
1767              (end (save-excursion
1768                     (move-to-window-line (+ row (abs height)))
1769                     (point)))
1770              (ov (make-overlay beg end))
1771              (args (list (mapcar 'company-untabify
1772                                  (company-buffer-lines beg end))
1773                          column nl above)))
1774
1775         (setq company-pseudo-tooltip-overlay ov)
1776         (overlay-put ov 'company-replacement-args args)
1777         (overlay-put ov 'company-before
1778                      (apply 'company--replacement-string
1779                             (company--create-lines selection (abs height))
1780                             args))
1781
1782         (overlay-put ov 'company-column column)
1783         (overlay-put ov 'company-height (abs height))))))
1784
1785 (defun company-pseudo-tooltip-show-at-point (pos)
1786   (let ((col-row (company--col-row pos)))
1787     (when col-row
1788       (company-pseudo-tooltip-show (1+ (cdr col-row)) (car col-row)
1789                                    company-selection))))
1790
1791 (defun company-pseudo-tooltip-edit (lines selection)
1792   (let ((column (overlay-get company-pseudo-tooltip-overlay 'company-column))
1793         (height (overlay-get company-pseudo-tooltip-overlay 'company-height)))
1794     (overlay-put company-pseudo-tooltip-overlay 'company-before
1795                  (apply 'company--replacement-string
1796                         (company--create-lines selection height)
1797                         (overlay-get company-pseudo-tooltip-overlay
1798                                      'company-replacement-args)))))
1799
1800 (defun company-pseudo-tooltip-hide ()
1801   (when company-pseudo-tooltip-overlay
1802     (delete-overlay company-pseudo-tooltip-overlay)
1803     (setq company-pseudo-tooltip-overlay nil)))
1804
1805 (defun company-pseudo-tooltip-hide-temporarily ()
1806   (when (overlayp company-pseudo-tooltip-overlay)
1807     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
1808     (overlay-put company-pseudo-tooltip-overlay 'before-string nil)))
1809
1810 (defun company-pseudo-tooltip-unhide ()
1811   (when company-pseudo-tooltip-overlay
1812     (overlay-put company-pseudo-tooltip-overlay 'invisible t)
1813     (overlay-put company-pseudo-tooltip-overlay 'before-string
1814                  (overlay-get company-pseudo-tooltip-overlay 'company-before))
1815     (overlay-put company-pseudo-tooltip-overlay 'window (selected-window))))
1816
1817 (defun company-pseudo-tooltip-frontend (command)
1818   "A `company-mode' front-end similar to a tool-tip but based on overlays."
1819   (case command
1820     (pre-command (company-pseudo-tooltip-hide-temporarily))
1821     (post-command
1822      (let ((old-height (if (overlayp company-pseudo-tooltip-overlay)
1823                            (overlay-get company-pseudo-tooltip-overlay
1824                                         'company-height)
1825                          0))
1826            (new-height (company--pseudo-tooltip-height)))
1827        (unless (and (>= (* old-height new-height) 0)
1828                     (>= (abs old-height) (abs new-height)))
1829          ;; Redraw needed.
1830          (company-pseudo-tooltip-show-at-point (- (point)
1831                                                   (length company-prefix)))))
1832      (company-pseudo-tooltip-unhide))
1833     (hide (company-pseudo-tooltip-hide)
1834           (setq company-tooltip-offset 0))
1835     (update (when (overlayp company-pseudo-tooltip-overlay)
1836               (company-pseudo-tooltip-edit company-candidates
1837                                            company-selection)))))
1838
1839 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
1840   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
1841   (unless (and (eq command 'post-command)
1842                (not (cdr company-candidates)))
1843     (company-pseudo-tooltip-frontend command)))
1844
1845 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1846
1847 (defvar company-preview-overlay nil)
1848 (make-variable-buffer-local 'company-preview-overlay)
1849
1850 (defun company-preview-show-at-point (pos)
1851   (company-preview-hide)
1852
1853   (setq company-preview-overlay (make-overlay pos pos))
1854
1855   (let ((completion(nth company-selection company-candidates)))
1856     (setq completion (propertize completion 'face 'company-preview))
1857     (add-text-properties 0 (length company-common)
1858                          '(face company-preview-common) completion)
1859
1860     ;; Add search string
1861     (and company-search-string
1862          (string-match (regexp-quote company-search-string) completion)
1863          (add-text-properties (match-beginning 0)
1864                               (match-end 0)
1865                               '(face company-preview-search)
1866                               completion))
1867
1868     (setq completion (company-strip-prefix completion))
1869
1870     (and (equal pos (point))
1871          (not (equal completion ""))
1872          (add-text-properties 0 1 '(cursor t) completion))
1873
1874     (overlay-put company-preview-overlay 'after-string completion)
1875     (overlay-put company-preview-overlay 'window (selected-window))))
1876
1877 (defun company-preview-hide ()
1878   (when company-preview-overlay
1879     (delete-overlay company-preview-overlay)
1880     (setq company-preview-overlay nil)))
1881
1882 (defun company-preview-frontend (command)
1883   "A `company-mode' front-end showing the selection as if it had been inserted."
1884   (case command
1885     (pre-command (company-preview-hide))
1886     (post-command (company-preview-show-at-point (point)))
1887     (hide (company-preview-hide))))
1888
1889 (defun company-preview-if-just-one-frontend (command)
1890   "`company-preview-frontend', but only shown for single candidates."
1891   (unless (and (eq command 'post-command)
1892                (cdr company-candidates))
1893     (company-preview-frontend command)))
1894
1895 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1896
1897 (defvar company-echo-last-msg nil)
1898 (make-variable-buffer-local 'company-echo-last-msg)
1899
1900 (defvar company-echo-timer nil)
1901
1902 (defvar company-echo-delay .01)
1903
1904 (defun company-echo-show (&optional getter)
1905   (when getter
1906     (setq company-echo-last-msg (funcall getter)))
1907   (let ((message-log-max nil))
1908     (if company-echo-last-msg
1909         (message "%s" company-echo-last-msg)
1910       (message ""))))
1911
1912 (defsubst company-echo-show-soon (&optional getter)
1913   (when company-echo-timer
1914     (cancel-timer company-echo-timer))
1915   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
1916
1917 (defsubst company-echo-show-when-idle (&optional getter)
1918   (when (sit-for .01)
1919     (company-echo-show getter)))
1920
1921 (defsubst company-echo-show-when-not-busy (&optional getter)
1922   "Run `company-echo-show' with arg GETTER once Emacs isn't busy."
1923   (when (sit-for company-echo-delay)
1924     (company-echo-show getter)))
1925
1926 (defun company-echo-format ()
1927
1928   (let ((limit (window-width (minibuffer-window)))
1929         (len -1)
1930         ;; Roll to selection.
1931         (candidates (nthcdr company-selection company-candidates))
1932         (i (if company-show-numbers company-selection 99999))
1933         comp msg)
1934
1935     (while candidates
1936       (setq comp (company-reformat (pop candidates))
1937             len (+ len 1 (length comp)))
1938       (if (< i 10)
1939           ;; Add number.
1940           (progn
1941             (setq comp (propertize (format "%d: %s" i comp)
1942                                    'face 'company-echo))
1943             (incf len 3)
1944             (incf i)
1945             (add-text-properties 3 (+ 3 (length company-common))
1946                                  '(face company-echo-common) comp))
1947         (setq comp (propertize comp 'face 'company-echo))
1948         (add-text-properties 0 (length company-common)
1949                              '(face company-echo-common) comp))
1950       (if (>= len limit)
1951           (setq candidates nil)
1952         (push comp msg)))
1953
1954     (mapconcat 'identity (nreverse msg) " ")))
1955
1956 (defun company-echo-strip-common-format ()
1957
1958   (let ((limit (window-width (minibuffer-window)))
1959         (len (+ (length company-prefix) 2))
1960         ;; Roll to selection.
1961         (candidates (nthcdr company-selection company-candidates))
1962         (i (if company-show-numbers company-selection 99999))
1963         msg comp)
1964
1965     (while candidates
1966       (setq comp (company-strip-prefix (pop candidates))
1967             len (+ len 2 (length comp)))
1968       (when (< i 10)
1969         ;; Add number.
1970         (setq comp (format "%s (%d)" comp i))
1971         (incf len 4)
1972         (incf i))
1973       (if (>= len limit)
1974           (setq candidates nil)
1975         (push (propertize comp 'face 'company-echo) msg)))
1976
1977     (concat (propertize company-prefix 'face 'company-echo-common) "{"
1978             (mapconcat 'identity (nreverse msg) ", ")
1979             "}")))
1980
1981 (defun company-echo-hide ()
1982   (unless (equal company-echo-last-msg "")
1983     (setq company-echo-last-msg "")
1984     (company-echo-show)))
1985
1986 (defun company-echo-frontend (command)
1987   "A `company-mode' front-end showing the candidates in the echo area."
1988   (case command
1989     (post-command (company-echo-show-soon 'company-echo-format))
1990     (hide (company-echo-hide))))
1991
1992 (defun company-echo-strip-common-frontend (command)
1993   "A `company-mode' front-end showing the candidates in the echo area."
1994   (case command
1995     (post-command (company-echo-show-soon 'company-echo-strip-common-format))
1996     (hide (company-echo-hide))))
1997
1998 (defun company-echo-metadata-frontend (command)
1999   "A `company-mode' front-end showing the documentation in the echo area."
2000   (case command
2001     (post-command (company-echo-show-when-idle 'company-fetch-metadata))
2002     (hide (company-echo-hide))))
2003
2004 (provide 'company)
2005 ;;; company.el ends here