code.delx.au - gnu-emacs-elpa/blob - diff-hl.el

   1 ;;; diff-hl.el --- Highlight uncommitted changes -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2012-2014  Free Software Foundation, Inc.
   4
   5 ;; Author:   Dmitry Gutov <dgutov@yandex.ru>
   6 ;; URL:      https://github.com/dgutov/diff-hl
   7 ;; Keywords: vc, diff
   8 ;; Version:  1.6.0
   9 ;; Package-Requires: ((cl-lib "0.2"))
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; `diff-hl-mode' highlights uncommitted changes on the left side of
  29 ;; the window (using the fringe, by default), allows you to jump
  30 ;; between the hunks and revert them selectively.
  31
  32 ;; Provided commands:
  33 ;;
  34 ;; `diff-hl-diff-goto-hunk'  C-x v =
  35 ;; `diff-hl-revert-hunk'     C-x v n
  36 ;; `diff-hl-previous-hunk'   C-x v [
  37 ;; `diff-hl-next-hunk'       C-x v ]
  38 ;;
  39 ;; The mode takes advantage of `smartrep' if it is installed.
  40
  41 ;; Add either of the following to your init file.
  42 ;;
  43 ;; To use it in all buffers:
  44 ;;
  45 ;; (global-diff-hl-mode)
  46 ;;
  47 ;; Only in `prog-mode' buffers, with `vc-dir' integration:
  48 ;;
  49 ;; (add-hook 'prog-mode-hook 'turn-on-diff-hl-mode)
  50 ;; (add-hook 'vc-dir-mode-hook 'turn-on-diff-hl-mode)
  51
  52 ;;; Code:
  53
  54 (require 'fringe)
  55 (require 'diff-mode)
  56 (require 'vc)
  57 (require 'vc-dir)
  58 (eval-when-compile
  59   (require 'cl-lib)
  60   (require 'vc-git)
  61   (require 'vc-hg)
  62   (require 'face-remap))
  63
  64 (defgroup diff-hl nil
  65   "VC diff highlighting on the side of a window"
  66   :group 'vc)
  67
  68 (defface diff-hl-insert
  69   '((default :inherit diff-added)
  70     (((class color)) :foreground "green4"))
  71   "Face used to highlight inserted lines."
  72   :group 'diff-hl)
  73
  74 (defface diff-hl-delete
  75   '((default :inherit diff-removed)
  76     (((class color)) :foreground "red3"))
  77   "Face used to highlight deleted lines."
  78   :group 'diff-hl)
  79
  80 (defface diff-hl-change
  81   '((default :foreground "blue3")
  82     (((class color) (min-colors 88) (background light))
  83      :background "#ddddff")
  84     (((class color) (min-colors 88) (background dark))
  85      :background "#333355"))
  86   "Face used to highlight changed lines."
  87   :group 'diff-hl)
  88
  89 (defcustom diff-hl-command-prefix (kbd "C-x v")
  90   "The prefix for all `diff-hl' commands."
  91   :group 'diff-hl
  92   :type 'string)
  93
  94 (defcustom diff-hl-draw-borders t
  95   "Non-nil to draw borders around fringe indicators."
  96   :group 'diff-hl
  97   :type 'boolean)
  98
  99 (defcustom diff-hl-highlight-function 'diff-hl-highlight-on-fringe
 100   "Function to highlight the current line. Its arguments are
 101   overlay, change type and position within a hunk."
 102   :group 'diff-hl
 103   :type 'function)
 104
 105 (defcustom diff-hl-fringe-bmp-function 'diff-hl-fringe-bmp-from-pos
 106   "Function to choose the fringe bitmap for a given change type
 107   and position within a hunk.  Should accept two arguments."
 108   :group 'diff-hl
 109   :type '(choice (const diff-hl-fringe-bmp-from-pos)
 110                  (const diff-hl-fringe-bmp-from-type)
 111                  function))
 112
 113 (defcustom diff-hl-fringe-face-function 'diff-hl-fringe-face-from-type
 114   "Function to choose the fringe face for a given change type
 115   and position within a hunk.  Should accept two arguments."
 116   :group 'diff-hl
 117   :type 'function)
 118
 119 (defvar diff-hl-reference-revision nil
 120   "Revision to diff against.  nil means the most recent one.")
 121
 122 (defun diff-hl-define-bitmaps ()
 123   (let* ((scale (if (and (boundp 'text-scale-mode-amount)
 124                          (numberp text-scale-mode-amount))
 125                     (expt text-scale-mode-step text-scale-mode-amount)
 126                   1))
 127          (spacing (or (and (display-graphic-p) (default-value 'line-spacing)) 0))
 128          (h (+ (ceiling (* (frame-char-height) scale))
 129                (if (floatp spacing)
 130                    (truncate (* (frame-char-height) spacing))
 131                  spacing)))
 132          (w (frame-parameter nil 'left-fringe))
 133          (middle (make-vector h (expt 2 (1- w))))
 134          (ones (1- (expt 2 w)))
 135          (top (copy-sequence middle))
 136          (bottom (copy-sequence middle))
 137          (single (copy-sequence middle)))
 138     (aset top 0 ones)
 139     (aset bottom (1- h) ones)
 140     (aset single 0 ones)
 141     (aset single (1- h) ones)
 142     (define-fringe-bitmap 'diff-hl-bmp-top top h w 'top)
 143     (define-fringe-bitmap 'diff-hl-bmp-middle middle h w 'center)
 144     (define-fringe-bitmap 'diff-hl-bmp-bottom bottom h w 'bottom)
 145     (define-fringe-bitmap 'diff-hl-bmp-single single h w 'top)
 146     (let* ((w2 (* (/ w 2) 2))
 147            (delete-row (- (expt 2 (1- w2)) 2))
 148            (middle-pos (1- (/ w2 2)))
 149            (middle-bit (expt 2 middle-pos))
 150            (insert-bmp (make-vector w2 (* 3 middle-bit))))
 151       (define-fringe-bitmap 'diff-hl-bmp-delete (make-vector 2 delete-row) w2 w2)
 152       (aset insert-bmp 0 0)
 153       (aset insert-bmp middle-pos delete-row)
 154       (aset insert-bmp (1+ middle-pos) delete-row)
 155       (aset insert-bmp (1- w2) 0)
 156       (define-fringe-bitmap 'diff-hl-bmp-insert insert-bmp w2 w2)
 157       )))
 158
 159 (defun diff-hl-maybe-define-bitmaps ()
 160   (when (window-system) ;; No fringes in the console.
 161     (unless (fringe-bitmap-p 'diff-hl-bmp-empty)
 162       (diff-hl-define-bitmaps)
 163       (define-fringe-bitmap 'diff-hl-bmp-empty [0] 1 1 'center))))
 164
 165 (defvar diff-hl-spec-cache (make-hash-table :test 'equal))
 166
 167 (defun diff-hl-fringe-spec (type pos)
 168   (let* ((key (list type pos diff-hl-fringe-bmp-function))
 169          (val (gethash key diff-hl-spec-cache)))
 170     (unless val
 171       (let* ((face-sym (funcall diff-hl-fringe-face-function type pos))
 172              (bmp-sym (funcall diff-hl-fringe-bmp-function type pos)))
 173         (setq val (propertize " " 'display `((left-fringe ,bmp-sym ,face-sym))))
 174         (puthash key val diff-hl-spec-cache)))
 175     val))
 176
 177 (defun diff-hl-fringe-face-from-type (type _pos)
 178   (intern (format "diff-hl-%s" type)))
 179
 180 (defun diff-hl-fringe-bmp-from-pos (_type pos)
 181   (intern (format "diff-hl-bmp-%s" pos)))
 182
 183 (defun diff-hl-fringe-bmp-from-type (type _pos)
 184   (cl-case type
 185     (unknown 'question-mark)
 186     (change 'exclamation-mark)
 187     (ignored 'filled-square)
 188     (t (intern (format "diff-hl-bmp-%s" type)))))
 189
 190 (defvar vc-svn-diff-switches)
 191
 192 (defmacro diff-hl-with-diff-switches (body)
 193   `(let ((vc-git-diff-switches nil)
 194          (vc-hg-diff-switches nil)
 195          (vc-svn-diff-switches nil)
 196          (vc-diff-switches '("-U0"))
 197          (vc-disable-async-diff t))
 198      ,body))
 199
 200 (defun diff-hl-changes ()
 201   (let* ((file buffer-file-name)
 202          (backend (vc-backend file)))
 203     (when backend
 204       (let ((state (vc-state file backend)))
 205         (cond
 206          ((or (eq state 'edited)
 207               (and (eq state 'up-to-date)
 208                    ;; VC state is stale in after-revert-hook.
 209                    (or revert-buffer-in-progress-p
 210                        ;; Diffing against an older revision.
 211                        diff-hl-reference-revision)))
 212           (let* ((buf-name " *diff-hl* ")
 213                  diff-auto-refine-mode
 214                  res)
 215             (diff-hl-with-diff-switches
 216              (vc-call-backend backend 'diff (list file)
 217                               diff-hl-reference-revision nil
 218                               buf-name))
 219             (with-current-buffer buf-name
 220               (goto-char (point-min))
 221               (unless (eobp)
 222                 (ignore-errors
 223                   (diff-beginning-of-hunk t))
 224                 (while (looking-at diff-hunk-header-re-unified)
 225                   (let ((line (string-to-number (match-string 3)))
 226                         (len (let ((m (match-string 4)))
 227                                (if m (string-to-number m) 1)))
 228                         (beg (point)))
 229                     (diff-end-of-hunk)
 230                     (let* ((inserts (diff-count-matches "^\\+" beg (point)))
 231                            (deletes (diff-count-matches "^-" beg (point)))
 232                            (type (cond ((zerop deletes) 'insert)
 233                                        ((zerop inserts) 'delete)
 234                                        (t 'change))))
 235                       (when (eq type 'delete)
 236                         (setq len 1)
 237                         (cl-incf line))
 238                       (push (list line len type) res))))))
 239             (nreverse res)))
 240          ((eq state 'added)
 241           `((1 ,(line-number-at-pos (point-max)) insert)))
 242          ((eq state 'removed)
 243           `((1 ,(line-number-at-pos (point-max)) delete))))))))
 244
 245 (defun diff-hl-update ()
 246   (let ((changes (diff-hl-changes))
 247         (current-line 1))
 248     (diff-hl-remove-overlays)
 249     (save-excursion
 250       (goto-char (point-min))
 251       (dolist (c changes)
 252         (cl-destructuring-bind (line len type) c
 253           (forward-line (- line current-line))
 254           (setq current-line line)
 255           (let ((hunk-beg (point)))
 256             (while (cl-plusp len)
 257               (diff-hl-add-highlighting
 258                type
 259                (cond
 260                 ((not diff-hl-draw-borders) 'empty)
 261                 ((and (= len 1) (= line current-line)) 'single)
 262                 ((= len 1) 'bottom)
 263                 ((= line current-line) 'top)
 264                 (t 'middle)))
 265               (forward-line 1)
 266               (cl-incf current-line)
 267               (cl-decf len))
 268             (let ((h (make-overlay hunk-beg (point)))
 269                   (hook '(diff-hl-overlay-modified)))
 270               (overlay-put h 'diff-hl t)
 271               (overlay-put h 'diff-hl-hunk t)
 272               (overlay-put h 'modification-hooks hook)
 273               (overlay-put h 'insert-in-front-hooks hook)
 274               (overlay-put h 'insert-behind-hooks hook))))))))
 275
 276 (defun diff-hl-add-highlighting (type shape)
 277   (let ((o (make-overlay (point) (point))))
 278     (overlay-put o 'diff-hl t)
 279     (funcall diff-hl-highlight-function o type shape)
 280     o))
 281
 282 (defun diff-hl-highlight-on-fringe (ovl type shape)
 283   (overlay-put ovl 'before-string (diff-hl-fringe-spec type shape)))
 284
 285 (defun diff-hl-remove-overlays ()
 286   (dolist (o (overlays-in (point-min) (point-max)))
 287     (when (overlay-get o 'diff-hl) (delete-overlay o))))
 288
 289 (defun diff-hl-overlay-modified (ov after-p _beg _end &optional _length)
 290   "Delete the hunk overlay and all our line overlays inside it."
 291   (unless after-p
 292     (when (overlay-buffer ov)
 293       (save-restriction
 294         (narrow-to-region (overlay-start ov) (overlay-end ov))
 295         (diff-hl-remove-overlays))
 296       (delete-overlay ov))))
 297
 298 (defvar diff-hl-timer nil)
 299
 300 (defun diff-hl-edit (_beg _end _len)
 301   "DTRT when we've `undo'-ne the buffer into unmodified state."
 302   (when undo-in-progress
 303     (when diff-hl-timer
 304       (cancel-timer diff-hl-timer))
 305     (setq diff-hl-timer
 306           (run-with-idle-timer 0.01 nil #'diff-hl-after-undo (current-buffer)))))
 307
 308 (defun diff-hl-after-undo (buffer)
 309   (with-current-buffer buffer
 310     (unless (buffer-modified-p)
 311       (diff-hl-update))))
 312
 313 (defun diff-hl-diff-goto-hunk ()
 314   "Run VC diff command and go to the line corresponding to the current."
 315   (interactive)
 316   (vc-buffer-sync)
 317   (let* ((line (line-number-at-pos))
 318          (buffer (current-buffer)))
 319     (vc-diff-internal t (vc-deduce-fileset) diff-hl-reference-revision nil t)
 320     (vc-exec-after `(if (< (line-number-at-pos (point-max)) 3)
 321                         (with-current-buffer ,buffer (diff-hl-remove-overlays))
 322                       (diff-hl-diff-skip-to ,line)
 323                       (setq vc-sentinel-movepoint (point))))))
 324
 325 (defun diff-hl-diff-skip-to (line)
 326   "In `diff-mode', skip to the hunk and line corresponding to LINE
 327 in the source file, or the last line of the hunk above it."
 328   (diff-hunk-next)
 329   (let (found)
 330     (while (and (looking-at diff-hunk-header-re-unified) (not found))
 331       (let ((hunk-line (string-to-number (match-string 3)))
 332             (len (let ((m (match-string 4)))
 333                    (if m (string-to-number m) 1))))
 334         (if (> line (+ hunk-line len))
 335             (diff-hunk-next)
 336           (setq found t)
 337           (if (< line hunk-line)
 338               ;; Retreat to the previous hunk.
 339               (forward-line -1)
 340             (let ((to-go (1+ (- line hunk-line))))
 341               (while (cl-plusp to-go)
 342                 (forward-line 1)
 343                 (unless (looking-at "^-")
 344                   (cl-decf to-go))))))))))
 345
 346 (defun diff-hl-revert-hunk ()
 347   "Revert the diff hunk with changes at or above the point."
 348   (interactive)
 349   (vc-buffer-sync)
 350   (let ((diff-buffer (generate-new-buffer-name "*diff-hl*"))
 351         (buffer (current-buffer))
 352         (line (save-excursion
 353                 (unless (diff-hl-hunk-overlay-at (point))
 354                   (diff-hl-previous-hunk))
 355                 (line-number-at-pos)))
 356         (fileset (vc-deduce-fileset)))
 357     (unwind-protect
 358         (progn
 359           (vc-diff-internal nil fileset diff-hl-reference-revision nil
 360                             nil diff-buffer)
 361           (vc-exec-after
 362            `(let (beg-line end-line)
 363               (when (eobp)
 364                 (with-current-buffer ,buffer (diff-hl-remove-overlays))
 365                 (error "Buffer is up-to-date"))
 366               (diff-hl-diff-skip-to ,line)
 367               (save-excursion
 368                 (while (looking-at "[-+]") (forward-line 1))
 369                 (setq end-line (line-number-at-pos (point)))
 370                 (unless (eobp) (diff-split-hunk)))
 371               (unless (looking-at "[-+]") (forward-line -1))
 372               (while (looking-at "[-+]") (forward-line -1))
 373               (setq beg-line (line-number-at-pos (point)))
 374               (unless (looking-at "@")
 375                 (forward-line 1)
 376                 (diff-split-hunk))
 377               (let ((wbh (window-body-height)))
 378                 (if (>= wbh (- end-line beg-line))
 379                     (recenter (/ (+ wbh (- beg-line end-line) 2) 2))
 380                   (recenter 1)))
 381               (unless (yes-or-no-p (format "Revert current hunk in %s?"
 382                                            ,(cl-caadr fileset)))
 383                 (error "Revert canceled"))
 384               (let ((diff-advance-after-apply-hunk nil))
 385                 (diff-apply-hunk t))
 386               (with-current-buffer ,buffer
 387                 (save-buffer))
 388               (message "Hunk reverted"))))
 389       (quit-windows-on diff-buffer))))
 390
 391 (defun diff-hl-hunk-overlay-at (pos)
 392   (cl-loop for o in (overlays-in pos (1+ pos))
 393            when (overlay-get o 'diff-hl-hunk)
 394            return o))
 395
 396 (defun diff-hl-next-hunk (&optional backward)
 397   "Go to the beginning of the next hunk in the current buffer."
 398   (interactive)
 399   (let ((pos (save-excursion
 400                (catch 'found
 401                  (while (not (if backward (bobp) (eobp)))
 402                    (goto-char (if backward
 403                                   (previous-overlay-change (point))
 404                                 (next-overlay-change (point))))
 405                    (let ((o (diff-hl-hunk-overlay-at (point))))
 406                      (when (and o (= (overlay-start o) (point)))
 407                        (throw 'found (overlay-start o)))))))))
 408     (if pos
 409         (goto-char pos)
 410       (error "No further hunks found"))))
 411
 412 (defun diff-hl-previous-hunk ()
 413   "Go to the beginning of the previous hunk in the current buffer."
 414   (interactive)
 415   (diff-hl-next-hunk t))
 416
 417 (define-prefix-command 'diff-hl-command-map)
 418
 419 (let ((map diff-hl-command-map))
 420   (define-key map "n" 'diff-hl-revert-hunk)
 421   (define-key map "[" 'diff-hl-previous-hunk)
 422   (define-key map "]" 'diff-hl-next-hunk)
 423   map)
 424
 425 ;;;###autoload
 426 (define-minor-mode diff-hl-mode
 427   "Toggle VC diff highlighting."
 428   :lighter "" :keymap `(([remap vc-diff] . diff-hl-diff-goto-hunk)
 429                         (,diff-hl-command-prefix . diff-hl-command-map))
 430   (if diff-hl-mode
 431       (progn
 432         (diff-hl-maybe-define-bitmaps)
 433         (add-hook 'after-save-hook 'diff-hl-update nil t)
 434         (add-hook 'after-change-functions 'diff-hl-edit nil t)
 435         (add-hook (if vc-mode
 436                       ;; Defer until the end of this hook, so that its
 437                       ;; elements can modify the update behavior.
 438                       'diff-hl-mode-on-hook
 439                     ;; If we're only opening the file now,
 440                     ;; `vc-find-file-hook' likely hasn't run yet, so
 441                     ;; let's wait until the state information is
 442                     ;; saved, in order not to fetch it twice.
 443                     'find-file-hook)
 444                   'diff-hl-update t t)
 445         (add-hook 'vc-checkin-hook 'diff-hl-update nil t)
 446         (add-hook 'after-revert-hook 'diff-hl-update nil t)
 447         ;; Magit does call `auto-revert-handler', but it usually
 448         ;; doesn't do much, because `buffer-stale--default-function'
 449         ;; doesn't care about changed VC state.
 450         ;; https://github.com/magit/magit/issues/603
 451         (add-hook 'magit-revert-buffer-hook 'diff-hl-update nil t)
 452         (add-hook 'text-scale-mode-hook 'diff-hl-define-bitmaps nil t))
 453     (remove-hook 'after-save-hook 'diff-hl-update t)
 454     (remove-hook 'after-change-functions 'diff-hl-edit t)
 455     (remove-hook 'find-file-hook 'diff-hl-update t)
 456     (remove-hook 'vc-checkin-hook 'diff-hl-update t)
 457     (remove-hook 'after-revert-hook 'diff-hl-update t)
 458     (remove-hook 'magit-revert-buffer-hook 'diff-hl-update t)
 459     (remove-hook 'text-scale-mode-hook 'diff-hl-define-bitmaps t)
 460     (diff-hl-remove-overlays)))
 461
 462 (when (require 'smartrep nil t)
 463   (let (smart-keys)
 464     (cl-labels ((scan (map)
 465                       (map-keymap
 466                        (lambda (event binding)
 467                          (if (consp binding)
 468                              (scan binding)
 469                            (when (characterp event)
 470                              (push (cons (string event) binding) smart-keys))))
 471                        map)))
 472       (scan diff-hl-command-map)
 473       (smartrep-define-key diff-hl-mode-map diff-hl-command-prefix smart-keys))))
 474
 475 (defun diff-hl-dir-update ()
 476   (dolist (pair (if (vc-dir-marked-files)
 477                     (vc-dir-marked-only-files-and-states)
 478                   (vc-dir-child-files-and-states)))
 479     (when (eq 'up-to-date (cdr pair))
 480       (let ((buffer (find-buffer-visiting (car pair))))
 481         (when buffer
 482           (with-current-buffer buffer
 483             (diff-hl-remove-overlays)))))))
 484
 485 (define-minor-mode diff-hl-dir-mode
 486   "Toggle `diff-hl-mode' integration in a `vc-dir-mode' buffer."
 487   :lighter ""
 488   (if diff-hl-dir-mode
 489       (add-hook 'vc-checkin-hook 'diff-hl-dir-update t t)
 490     (remove-hook 'vc-checkin-hook 'diff-hl-dir-update t)))
 491
 492 ;;;###autoload
 493 (defun turn-on-diff-hl-mode ()
 494   "Turn on `diff-hl-mode' or `diff-hl-dir-mode' in a buffer if appropriate."
 495   (cond
 496    (buffer-file-name
 497     (diff-hl-mode 1))
 498    ((eq major-mode 'vc-dir-mode)
 499     (diff-hl-dir-mode 1))))
 500
 501 ;;;###autoload
 502 (define-globalized-minor-mode global-diff-hl-mode diff-hl-mode
 503   turn-on-diff-hl-mode :after-hook (diff-hl-global-mode-change))
 504
 505 (defun diff-hl-global-mode-change ()
 506   (unless global-diff-hl-mode
 507     (dolist (buf (buffer-list))
 508       (with-current-buffer buf
 509         (when diff-hl-dir-mode
 510           (diff-hl-dir-mode -1))))))
 511
 512 (provide 'diff-hl)
 513
 514 ;;; diff-hl.el ends here