code.delx.au - gnu-emacs-elpa/blob - company.el

   1 ;;; company.el --- Modular in-buffer completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; Version: 0.6.8
   8 ;; Keywords: abbrev, convenience, matching
   9 ;; URL: http://company-mode.github.com/
  10 ;; Compatibility: GNU Emacs 22.x, GNU Emacs 23.x, GNU Emacs 24.x
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (case command
  52 ;;     (prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;; Known Issues:
  62 ;; When point is at the very end of the buffer, the pseudo-tooltip appears very
  63 ;; wrong, unless company is allowed to temporarily insert a fake newline.
  64 ;; This behavior is enabled by `company-end-of-buffer-workaround'.
  65 ;;
  66 ;;; Change Log:
  67 ;;
  68 ;; See NEWS.md in the repository.
  69
  70 ;;; Code:
  71
  72 (eval-when-compile (require 'cl))
  73
  74 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  75 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  76 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  77 (add-to-list 'debug-ignored-errors "^Company not ")
  78 (add-to-list 'debug-ignored-errors "^No candidate number ")
  79 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  80 (add-to-list 'debug-ignored-errors "^No other back-end$")
  81
  82 (defgroup company nil
  83   "Extensible inline text completion mechanism"
  84   :group 'abbrev
  85   :group 'convenience
  86   :group 'matching)
  87
  88 (defface company-tooltip
  89   '((default :foreground "black")
  90     (((class color) (min-colors 88) (background light))
  91      (:background "cornsilk"))
  92     (((class color) (min-colors 88) (background dark))
  93      (:background "yellow")))
  94   "Face used for the tooltip.")
  95
  96 (defface company-tooltip-selection
  97   '((default :inherit company-tooltip)
  98     (((class color) (min-colors 88) (background light))
  99      (:background "light blue"))
 100     (((class color) (min-colors 88) (background dark))
 101      (:background "orange1"))
 102     (t (:background "green")))
 103   "Face used for the selection in the tooltip.")
 104
 105 (defface company-tooltip-mouse
 106   '((default :inherit highlight))
 107   "Face used for the tooltip item under the mouse.")
 108
 109 (defface company-tooltip-common
 110   '((default :inherit company-tooltip)
 111     (((background light))
 112      :foreground "darkred")
 113     (((background dark))
 114      :foreground "red"))
 115   "Face used for the common completion in the tooltip.")
 116
 117 (defface company-tooltip-common-selection
 118   '((default :inherit company-tooltip-selection)
 119     (((background light))
 120      :foreground "darkred")
 121     (((background dark))
 122      :foreground "red"))
 123   "Face used for the selected common completion in the tooltip.")
 124
 125 (defface company-preview
 126   '((t :background "blue4"
 127        :foreground "wheat"))
 128   "Face used for the completion preview.")
 129
 130 (defface company-preview-common
 131   '((t :inherit company-preview
 132        :foreground "red"))
 133   "Face used for the common part of the completion preview.")
 134
 135 (defface company-preview-search
 136   '((t :inherit company-preview
 137        :background "blue1"))
 138   "Face used for the search string in the completion preview.")
 139
 140 (defface company-echo nil
 141   "Face used for completions in the echo area.")
 142
 143 (defface company-echo-common
 144   '((((background dark)) (:foreground "firebrick1"))
 145     (((background light)) (:background "firebrick4")))
 146   "Face used for the common part of completions in the echo area.")
 147
 148 (defun company-frontends-set (variable value)
 149   ;; uniquify
 150   (let ((remainder value))
 151     (setcdr remainder (delq (car remainder) (cdr remainder))))
 152   (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 153        (memq 'company-pseudo-tooltip-frontend value)
 154        (error "Pseudo tooltip frontend cannot be used twice"))
 155   (and (memq 'company-preview-if-just-one-frontend value)
 156        (memq 'company-preview-frontend value)
 157        (error "Preview frontend cannot be used twice"))
 158   (and (memq 'company-echo value)
 159        (memq 'company-echo-metadata-frontend value)
 160        (error "Echo area cannot be used twice"))
 161   ;; preview must come last
 162   (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 163     (when (memq f value)
 164       (setq value (append (delq f value) (list f)))))
 165   (set variable value))
 166
 167 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 168                                company-preview-if-just-one-frontend
 169                                company-echo-metadata-frontend)
 170   "The list of active front-ends (visualizations).
 171 Each front-end is a function that takes one argument.  It is called with
 172 one of the following arguments:
 173
 174 'show: When the visualization should start.
 175
 176 'hide: When the visualization should end.
 177
 178 'update: When the data has been updated.
 179
 180 'pre-command: Before every command that is executed while the
 181 visualization is active.
 182
 183 'post-command: After every command that is executed while the
 184 visualization is active.
 185
 186 The visualized data is stored in `company-prefix', `company-candidates',
 187 `company-common', `company-selection', `company-point' and
 188 `company-search-string'."
 189   :set 'company-frontends-set
 190   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 191                          (const :tag "echo, strip common"
 192                                 company-echo-strip-common-frontend)
 193                          (const :tag "show echo meta-data in echo"
 194                                 company-echo-metadata-frontend)
 195                          (const :tag "pseudo tooltip"
 196                                 company-pseudo-tooltip-frontend)
 197                          (const :tag "pseudo tooltip, multiple only"
 198                                 company-pseudo-tooltip-unless-just-one-frontend)
 199                          (const :tag "preview" company-preview-frontend)
 200                          (const :tag "preview, unique only"
 201                                 company-preview-if-just-one-frontend)
 202                          (function :tag "custom function" nil))))
 203
 204 (defcustom company-tooltip-limit 10
 205   "The maximum number of candidates in the tooltip"
 206   :type 'integer)
 207
 208 (defcustom company-tooltip-minimum 6
 209   "The minimum height of the tooltip.
 210 If this many lines are not available, prefer to display the tooltip above."
 211   :type 'integer)
 212
 213 (defvar company-safe-backends
 214   '((company-abbrev . "Abbrev")
 215     (company-clang . "Clang")
 216     (company-css . "CSS")
 217     (company-dabbrev . "dabbrev for plain text")
 218     (company-dabbrev-code . "dabbrev for code")
 219     (company-eclim . "Eclim (an Eclipse interface)")
 220     (company-elisp . "Emacs Lisp")
 221     (company-etags . "etags")
 222     (company-files . "Files")
 223     (company-gtags . "GNU Global")
 224     (company-ispell . "Ispell")
 225     (company-keywords . "Programming language keywords")
 226     (company-nxml . "nxml")
 227     (company-oddmuse . "Oddmuse")
 228     (company-pysmell . "PySmell")
 229     (company-ropemacs . "ropemacs")
 230     (company-semantic . "Semantic")
 231     (company-tempo . "Tempo templates")
 232     (company-xcode . "Xcode")))
 233 (put 'company-safe-backends 'risky-local-variable t)
 234
 235 (defun company-safe-backends-p (backends)
 236   (and (consp backends)
 237        (not (dolist (backend backends)
 238               (unless (if (consp backend)
 239                           (company-safe-backends-p backend)
 240                         (assq backend company-safe-backends))
 241                 (return t))))))
 242
 243 (defun company-capf (command &optional arg &rest args)
 244   "`company-mode' back-end using `completion-at-point-functions'.
 245 Requires Emacs 24.1 or newer."
 246   (interactive (list 'interactive))
 247   (case command
 248     (interactive (company-begin-backend 'company-capf))
 249     (prefix
 250      (let ((res (run-hook-wrapped 'completion-at-point-functions
 251                                   ;; Ignore misbehaving functions.
 252                                   #'completion--capf-wrapper 'optimist)))
 253        (when (consp res)
 254          (if (> (nth 2 res) (point))
 255              'stop
 256            (buffer-substring-no-properties (nth 1 res) (point))))))
 257     (candidates
 258      (let ((res (run-hook-wrapped 'completion-at-point-functions
 259                                   ;; Ignore misbehaving functions.
 260                                   #'completion--capf-wrapper 'optimist)))
 261        (when (consp res)
 262          (all-completions arg (nth 3 res)
 263                           (plist-get (nthcdr 4 res) :predicate)))))))
 264
 265 (defcustom company-backends '(company-elisp company-nxml company-css
 266                               company-semantic company-clang company-eclim
 267                               company-xcode company-ropemacs
 268                               (company-gtags company-etags company-dabbrev-code
 269                                company-keywords)
 270                               company-oddmuse company-files company-dabbrev)
 271   "The list of active back-ends (completion engines).
 272 Each list elements can itself be a list of back-ends.  In that case their
 273 completions are merged.  Otherwise only the first matching back-end returns
 274 results.
 275
 276 `company-begin-backend' can be used to start a specific back-end,
 277 `company-other-backend' will skip to the next matching back-end in the list.
 278
 279 Each back-end is a function that takes a variable number of arguments.
 280 The first argument is the command requested from the back-end.  It is one
 281 of the following:
 282
 283 `prefix': The back-end should return the text to be completed.  It must be
 284 text immediately before `point'.  Returning nil passes control to the next
 285 back-end.  The function should return 'stop if it should complete but cannot
 286 \(e.g. if it is in the middle of a string\).  If the returned value is only
 287 part of the prefix (e.g. the part after \"->\" in C), the back-end may return a
 288 cons of prefix and prefix length, which is then used in the
 289 `company-minimum-prefix-length' test.
 290
 291 `candidates': The second argument is the prefix to be completed.  The
 292 return value should be a list of candidates that start with the prefix.
 293
 294 Optional commands:
 295
 296 `sorted': The back-end may return t here to indicate that the candidates
 297 are sorted and will not need to be sorted again.
 298
 299 `duplicates': If non-nil, company will take care of removing duplicates
 300 from the list.
 301
 302 `no-cache': Usually company doesn't ask for candidates again as completion
 303 progresses, unless the back-end returns t for this command.  The second
 304 argument is the latest prefix.
 305
 306 `meta': The second argument is a completion candidate.  The back-end should
 307 return a (short) documentation string for it.
 308
 309 `doc-buffer': The second argument is a completion candidate.
 310 The back-end should create a buffer (preferably with `company-doc-buffer'),
 311 fill it with documentation and return it.
 312
 313 `location': The second argument is a completion candidate.  The back-end can
 314 return the cons of buffer and buffer location, or of file and line
 315 number where the completion candidate was defined.
 316
 317 `require-match': If this value is t, the user is not allowed to enter anything
 318 not offered as a candidate.  Use with care!  The default value nil gives the
 319 user that choice with `company-require-match'.  Return value 'never overrides
 320 that option the other way around.
 321
 322 `init': Called once for each buffer, the back-end can check for external
 323 programs and files and load any required libraries.  Raising an error here will
 324 show up in message log once, and the backend will not be used for completion.
 325
 326 `post-completion': Called after a completion candidate has been inserted into
 327 the buffer.  The second argument is the candidate.  Can be used to modify it,
 328 e.g. to expand a snippet.
 329
 330 The back-end should return nil for all commands it does not support or
 331 does not know about.  It should also be callable interactively and use
 332 `company-begin-backend' to start itself in that case."
 333   :type `(repeat
 334           (choice
 335            :tag "Back-end"
 336            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 337                      company-safe-backends)
 338            (symbol :tag "User defined")
 339            (repeat :tag "Merged Back-ends"
 340                    (choice :tag "Back-end"
 341                            ,@(mapcar (lambda (b)
 342                                        `(const :tag ,(cdr b) ,(car b)))
 343                                      company-safe-backends)
 344                            (symbol :tag "User defined"))))))
 345
 346 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 347
 348 (defcustom company-completion-started-hook nil
 349   "Hook run when company starts completing.
 350 The hook is called with one argument that is non-nil if the completion was
 351 started manually."
 352   :type 'hook)
 353
 354 (defcustom company-completion-cancelled-hook nil
 355   "Hook run when company cancels completing.
 356 The hook is called with one argument that is non-nil if the completion was
 357 aborted manually."
 358   :type 'hook)
 359
 360 (defcustom company-completion-finished-hook nil
 361   "Hook run when company successfully completes.
 362 The hook is called with the selected candidate as an argument.
 363
 364 If you indend to use it to post-process candidates from a specific back-end,
 365 consider using the `post-completion' command instead."
 366   :type 'hook)
 367
 368 (defcustom company-minimum-prefix-length 3
 369   "The minimum prefix length for automatic completion."
 370   :type '(integer :tag "prefix length"))
 371
 372 (defcustom company-require-match 'company-explicit-action-p
 373   "If enabled, disallow non-matching input.
 374 This can be a function do determine if a match is required.
 375
 376 This can be overridden by the back-end, if it returns t or 'never to
 377 'require-match.  `company-auto-complete' also takes precedence over this."
 378   :type '(choice (const :tag "Off" nil)
 379                  (function :tag "Predicate function")
 380                  (const :tag "On, if user interaction took place"
 381                         'company-explicit-action-p)
 382                  (const :tag "On" t)))
 383
 384 (defcustom company-auto-complete nil
 385   "Determines when to auto-complete.
 386 If this is enabled, all characters from `company-auto-complete-chars' complete
 387 the selected completion.  This can also be a function."
 388   :type '(choice (const :tag "Off" nil)
 389                  (function :tag "Predicate function")
 390                  (const :tag "On, if user interaction took place"
 391                         'company-explicit-action-p)
 392                  (const :tag "On" t)))
 393
 394 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 395   "Determines which characters trigger an automatic completion.
 396 See `company-auto-complete'.  If this is a string, each string character causes
 397 completion.  If it is a list of syntax description characters (see
 398 `modify-syntax-entry'), all characters with that syntax auto-complete.
 399
 400 This can also be a function, which is called with the new input and should
 401 return non-nil if company should auto-complete.
 402
 403 A character that is part of a valid candidate never triggers auto-completion."
 404   :type '(choice (string :tag "Characters")
 405                  (set :tag "Syntax"
 406                       (const :tag "Whitespace" ?\ )
 407                       (const :tag "Symbol" ?_)
 408                       (const :tag "Opening parentheses" ?\()
 409                       (const :tag "Closing parentheses" ?\))
 410                       (const :tag "Word constituent" ?w)
 411                       (const :tag "Punctuation." ?.)
 412                       (const :tag "String quote." ?\")
 413                       (const :tag "Paired delimiter." ?$)
 414                       (const :tag "Expression quote or prefix operator." ?\')
 415                       (const :tag "Comment starter." ?<)
 416                       (const :tag "Comment ender." ?>)
 417                       (const :tag "Character-quote." ?/)
 418                       (const :tag "Generic string fence." ?|)
 419                       (const :tag "Generic comment fence." ?!))
 420                  (function :tag "Predicate function")))
 421
 422 (defcustom company-idle-delay .7
 423   "The idle delay in seconds until automatic completions starts.
 424 A value of nil means never complete automatically, t means complete
 425 immediately when a prefix of `company-minimum-prefix-length' is reached."
 426   :type '(choice (const :tag "never (nil)" nil)
 427                  (const :tag "immediate (t)" t)
 428                  (number :tag "seconds")))
 429
 430 (defcustom company-begin-commands t
 431   "A list of commands following which company will start completing.
 432 If this is t, it will complete after any command.  See `company-idle-delay'.
 433
 434 Alternatively any command with a non-nil 'company-begin property is treated as
 435 if it was on this list."
 436   :type '(choice (const :tag "Any command" t)
 437                  (const :tag "Self insert command" '(self-insert-command))
 438                  (repeat :tag "Commands" function)))
 439
 440 (defcustom company-show-numbers nil
 441   "If enabled, show quick-access numbers for the first ten candidates."
 442   :type '(choice (const :tag "off" nil)
 443                  (const :tag "on" t)))
 444
 445 (defvar company-end-of-buffer-workaround t
 446   "Work around a visualization bug when completing at the end of the buffer.
 447 The work-around consists of adding a newline.")
 448
 449 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 450
 451 (defvar company-mode-map (make-sparse-keymap)
 452   "Keymap used by `company-mode'.")
 453
 454 (defvar company-active-map
 455   (let ((keymap (make-sparse-keymap)))
 456     (define-key keymap "\e\e\e" 'company-abort)
 457     (define-key keymap "\C-g" 'company-abort)
 458     (define-key keymap (kbd "M-n") 'company-select-next)
 459     (define-key keymap (kbd "M-p") 'company-select-previous)
 460     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 461     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 462     (define-key keymap [down-mouse-1] 'ignore)
 463     (define-key keymap [down-mouse-3] 'ignore)
 464     (define-key keymap [mouse-1] 'company-complete-mouse)
 465     (define-key keymap [mouse-3] 'company-select-mouse)
 466     (define-key keymap [up-mouse-1] 'ignore)
 467     (define-key keymap [up-mouse-3] 'ignore)
 468     (define-key keymap [return] 'company-complete-selection)
 469     (define-key keymap (kbd "RET") 'company-complete-selection)
 470     (define-key keymap [tab] 'company-complete-common)
 471     (define-key keymap (kbd "TAB") 'company-complete-common)
 472     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 473     (define-key keymap "\C-w" 'company-show-location)
 474     (define-key keymap "\C-s" 'company-search-candidates)
 475     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 476     (dotimes (i 10)
 477       (define-key keymap (vector (+ (aref (kbd "M-0") 0) i))
 478         `(lambda () (interactive) (company-complete-number ,i))))
 479
 480     keymap)
 481   "Keymap that is enabled during an active completion.")
 482
 483 (defvar company--disabled-backends nil)
 484
 485 (defun company-init-backend (backend)
 486   (and (symbolp backend)
 487        (not (fboundp backend))
 488        (ignore-errors (require backend nil t)))
 489
 490   (if (or (symbolp backend)
 491           (functionp backend))
 492       (condition-case err
 493           (progn
 494             (funcall backend 'init)
 495             (put backend 'company-init t))
 496         (error
 497          (put backend 'company-init 'failed)
 498          (unless (memq backend company--disabled-backends)
 499            (message "Company back-end '%s' could not be initialized:\n%s"
 500                     backend (error-message-string err)))
 501          (pushnew backend company--disabled-backends)
 502          nil))
 503     (mapc 'company-init-backend backend)))
 504
 505 (defvar company-default-lighter " company")
 506
 507 (defvar company-lighter company-default-lighter)
 508 (make-variable-buffer-local 'company-lighter)
 509
 510 ;;;###autoload
 511 (define-minor-mode company-mode
 512   "\"complete anything\"; is an in-buffer completion framework.
 513 Completion starts automatically, depending on the values
 514 `company-idle-delay' and `company-minimum-prefix-length'.
 515
 516 Completion can be controlled with the commands:
 517 `company-complete-common', `company-complete-selection', `company-complete',
 518 `company-select-next', `company-select-previous'.  If these commands are
 519 called before `company-idle-delay', completion will also start.
 520
 521 Completions can be searched with `company-search-candidates' or
 522 `company-filter-candidates'.  These can be used while completion is
 523 inactive, as well.
 524
 525 The completion data is retrieved using `company-backends' and displayed using
 526 `company-frontends'.  If you want to start a specific back-end, call it
 527 interactively or use `company-begin-backend'.
 528
 529 regular keymap (`company-mode-map'):
 530
 531 \\{company-mode-map}
 532 keymap during active completions (`company-active-map'):
 533
 534 \\{company-active-map}"
 535   nil company-lighter company-mode-map
 536   (if company-mode
 537       (progn
 538         (add-hook 'pre-command-hook 'company-pre-command nil t)
 539         (add-hook 'post-command-hook 'company-post-command nil t)
 540         (mapc 'company-init-backend company-backends))
 541     (remove-hook 'pre-command-hook 'company-pre-command t)
 542     (remove-hook 'post-command-hook 'company-post-command t)
 543     (company-cancel)
 544     (kill-local-variable 'company-point)))
 545
 546 ;;;###autoload
 547 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 548
 549 (defun company-mode-on ()
 550   (unless (or noninteractive (eq (aref (buffer-name) 0) ?\s))
 551     (company-mode 1)))
 552
 553 (defsubst company-assert-enabled ()
 554   (unless company-mode
 555     (company-uninstall-map)
 556     (error "Company not enabled")))
 557
 558 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 559
 560 (defvar company-my-keymap nil)
 561 (make-variable-buffer-local 'company-my-keymap)
 562
 563 (defvar company-emulation-alist '((t . nil)))
 564
 565 (defsubst company-enable-overriding-keymap (keymap)
 566   (company-uninstall-map)
 567   (setq company-my-keymap keymap))
 568
 569 (defun company-ensure-emulation-alist ()
 570   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 571     (setq emulation-mode-map-alists
 572           (cons 'company-emulation-alist
 573                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 574
 575 (defun company-install-map ()
 576   (unless (or (cdar company-emulation-alist)
 577               (null company-my-keymap))
 578     (setf (cdar company-emulation-alist) company-my-keymap)))
 579
 580 (defun company-uninstall-map ()
 581   (setf (cdar company-emulation-alist) nil))
 582
 583 ;; Hack:
 584 ;; Emacs calculates the active keymaps before reading the event.  That means we
 585 ;; cannot change the keymap from a timer.  So we send a bogus command.
 586 (defun company-ignore ()
 587   (interactive)
 588   (setq this-command last-command))
 589
 590 (global-set-key '[31415926] 'company-ignore)
 591
 592 (defun company-input-noop ()
 593   (push 31415926 unread-command-events))
 594
 595 ;; Hack:
 596 ;; posn-col-row is incorrect in older Emacsen when line-spacing is set
 597 (defun company--col-row (&optional pos)
 598   (let ((posn (posn-at-point pos)))
 599     (cons (car (posn-col-row posn)) (cdr (posn-actual-col-row posn)))))
 600
 601 (defsubst company--column (&optional pos)
 602   (car (posn-col-row (posn-at-point pos))))
 603
 604 (defsubst company--row (&optional pos)
 605   (cdr (posn-actual-col-row (posn-at-point pos))))
 606
 607 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 608
 609 (defun company-grab (regexp &optional expression limit)
 610   (when (looking-back regexp limit)
 611     (or (match-string-no-properties (or expression 0)) "")))
 612
 613 (defun company-grab-line (regexp &optional expression)
 614   (company-grab regexp expression (point-at-bol)))
 615
 616 (defun company-grab-symbol ()
 617   (if (looking-at "\\_>")
 618       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 619                                                 (point)))
 620     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 621       "")))
 622
 623 (defun company-grab-word ()
 624   (if (looking-at "\\>")
 625       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 626                                                 (point)))
 627     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 628       "")))
 629
 630 (defun company-in-string-or-comment ()
 631   (let ((ppss (syntax-ppss)))
 632     (or (car (setq ppss (nthcdr 3 ppss)))
 633         (car (setq ppss (cdr ppss)))
 634         (nth 3 ppss))))
 635
 636 (if (fboundp 'locate-dominating-file)
 637     (defalias 'company-locate-dominating-file 'locate-dominating-file)
 638   (defun company-locate-dominating-file (file name)
 639     (catch 'root
 640       (let ((dir (file-name-directory file))
 641             (prev-dir nil))
 642         (while (not (equal dir prev-dir))
 643           (when (file-exists-p (expand-file-name name dir))
 644             (throw 'root dir))
 645           (setq prev-dir dir
 646                 dir (file-name-directory (directory-file-name dir))))))))
 647
 648 (defun company-call-backend (&rest args)
 649   (if (functionp company-backend)
 650       (apply company-backend args)
 651     (apply 'company--multi-backend-adapter company-backend args)))
 652
 653 (defun company--multi-backend-adapter (backends command &rest args)
 654   (let ((backends (loop for b in backends
 655                         when (not (and (symbolp b)
 656                                        (eq 'failed (get b 'company-init))))
 657                         collect b)))
 658     (case command
 659       (candidates
 660        (loop for backend in backends
 661              when (equal (funcall backend 'prefix)
 662                          (car args))
 663              append (apply backend 'candidates args)))
 664       (sorted nil)
 665       (duplicates t)
 666       (otherwise
 667        (let (value)
 668          (dolist (backend backends)
 669            (when (setq value (apply backend command args))
 670              (return value))))))))
 671
 672 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 673
 674 (defvar company-backend nil)
 675 (make-variable-buffer-local 'company-backend)
 676
 677 (defvar company-prefix nil)
 678 (make-variable-buffer-local 'company-prefix)
 679
 680 (defvar company-candidates nil)
 681 (make-variable-buffer-local 'company-candidates)
 682
 683 (defvar company-candidates-length nil)
 684 (make-variable-buffer-local 'company-candidates-length)
 685
 686 (defvar company-candidates-cache nil)
 687 (make-variable-buffer-local 'company-candidates-cache)
 688
 689 (defvar company-candidates-predicate nil)
 690 (make-variable-buffer-local 'company-candidates-predicate)
 691
 692 (defvar company-common nil)
 693 (make-variable-buffer-local 'company-common)
 694
 695 (defvar company-selection 0)
 696 (make-variable-buffer-local 'company-selection)
 697
 698 (defvar company-selection-changed nil)
 699 (make-variable-buffer-local 'company-selection-changed)
 700
 701 (defvar company--explicit-action nil
 702   "Non-nil, if explicit completion took place.")
 703 (make-variable-buffer-local 'company--explicit-action)
 704
 705 (defvar company--auto-completion nil
 706   "Non-nil when current candidate is being completed automatically.
 707 Controlled by `company-auto-complete'.")
 708
 709 (defvar company--point-max nil)
 710 (make-variable-buffer-local 'company--point-max)
 711
 712 (defvar company-point nil)
 713 (make-variable-buffer-local 'company-point)
 714
 715 (defvar company-timer nil)
 716
 717 (defvar company-added-newline nil)
 718 (make-variable-buffer-local 'company-added-newline)
 719
 720 (defsubst company-strip-prefix (str)
 721   (substring str (length company-prefix)))
 722
 723 (defmacro company-with-candidate-inserted (candidate &rest body)
 724   "Evaluate BODY with CANDIDATE temporarily inserted.
 725 This is a tool for back-ends that need candidates inserted before they
 726 can retrieve meta-data for them."
 727   (declare (indent 1))
 728   `(let ((inhibit-modification-hooks t)
 729          (inhibit-point-motion-hooks t)
 730          (modified-p (buffer-modified-p)))
 731      (insert (company-strip-prefix ,candidate))
 732      (unwind-protect
 733          (progn ,@body)
 734        (delete-region company-point (point)))))
 735
 736 (defun company-explicit-action-p ()
 737   "Return whether explicit completion action was taken by the user."
 738   (or company--explicit-action
 739       company-selection-changed))
 740
 741 (defsubst company-reformat (candidate)
 742   ;; company-ispell needs this, because the results are always lower-case
 743   ;; It's mory efficient to fix it only when they are displayed.
 744   (concat company-prefix (substring candidate (length company-prefix))))
 745
 746 (defun company--should-complete ()
 747   (and (not (or buffer-read-only overriding-terminal-local-map
 748                 overriding-local-map
 749                 (minibufferp)))
 750        ;; Check if in the middle of entering a key combination.
 751        (or (equal (this-command-keys-vector) [])
 752            (not (keymapp (key-binding (this-command-keys-vector)))))
 753        (eq company-idle-delay t)
 754        (or (eq t company-begin-commands)
 755            (memq this-command company-begin-commands)
 756            (and (symbolp this-command) (get this-command 'company-begin)))
 757        (not (and transient-mark-mode mark-active))))
 758
 759 (defsubst company-call-frontends (command)
 760   (dolist (frontend company-frontends)
 761     (condition-case err
 762         (funcall frontend command)
 763       (error (error "Company: Front-end %s error \"%s\" on command %s"
 764                     frontend (error-message-string err) command)))))
 765
 766 (defsubst company-set-selection (selection &optional force-update)
 767   (setq selection (max 0 (min (1- company-candidates-length) selection)))
 768   (when (or force-update (not (equal selection company-selection)))
 769     (setq company-selection selection
 770           company-selection-changed t)
 771     (company-call-frontends 'update)))
 772
 773 (defun company-apply-predicate (candidates predicate)
 774   (let (new)
 775     (dolist (c candidates)
 776       (when (funcall predicate c)
 777         (push c new)))
 778     (nreverse new)))
 779
 780 (defun company-update-candidates (candidates)
 781   (setq company-candidates-length (length candidates))
 782   (if (> company-selection 0)
 783       ;; Try to restore the selection
 784       (let ((selected (nth company-selection company-candidates)))
 785         (setq company-selection 0
 786               company-candidates candidates)
 787         (when selected
 788           (while (and candidates (string< (pop candidates) selected))
 789             (incf company-selection))
 790           (unless candidates
 791             ;; Make sure selection isn't out of bounds.
 792             (setq company-selection (min (1- company-candidates-length)
 793                                          company-selection)))))
 794     (setq company-selection 0
 795           company-candidates candidates))
 796   ;; Save in cache:
 797   (push (cons company-prefix company-candidates) company-candidates-cache)
 798   ;; Calculate common.
 799   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
 800     (setq company-common (company--safe-candidate
 801                           (try-completion company-prefix company-candidates))))
 802   (when (eq company-common t)
 803     (setq company-candidates nil)))
 804
 805 (defun company--safe-candidate (str)
 806   (or (company-call-backend 'crop str)
 807       str))
 808
 809 (defun company-calculate-candidates (prefix)
 810   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
 811         (ignore-case (company-call-backend 'ignore-case)))
 812     (or candidates
 813         (when company-candidates-cache
 814           (let ((len (length prefix))
 815                 (completion-ignore-case ignore-case)
 816                 prev)
 817             (dotimes (i (1+ len))
 818               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
 819                                            company-candidates-cache)))
 820                 (setq candidates (all-completions prefix prev))
 821                 (return t)))))
 822         ;; no cache match, call back-end
 823         (progn
 824           (setq candidates (company-call-backend 'candidates prefix))
 825           (when company-candidates-predicate
 826             (setq candidates
 827                   (company-apply-predicate candidates
 828                                            company-candidates-predicate)))
 829           (unless (company-call-backend 'sorted)
 830             (setq candidates (sort candidates 'string<)))
 831           (when (company-call-backend 'duplicates)
 832             ;; strip duplicates
 833             (let ((c2 candidates))
 834               (while c2
 835                 (setcdr c2 (progn (while (equal (pop c2) (car c2)))
 836                                   c2)))))))
 837     (when candidates
 838       (if (or (cdr candidates)
 839               (not (eq t (compare-strings (car candidates) nil nil
 840                                           prefix nil nil ignore-case))))
 841           candidates
 842         ;; Already completed and unique; don't start.
 843         t))))
 844
 845 (defun company-idle-begin (buf win tick pos)
 846   (and company-mode
 847        (eq buf (current-buffer))
 848        (eq win (selected-window))
 849        (eq tick (buffer-chars-modified-tick))
 850        (eq pos (point))
 851        (not company-candidates)
 852        (not (equal (point) company-point))
 853        (let ((company-idle-delay t)
 854              (company-begin-commands t))
 855          (company-begin)
 856          (when company-candidates
 857            (company-input-noop)
 858            (company-post-command)))))
 859
 860 (defun company-auto-begin ()
 861   (company-assert-enabled)
 862   (and company-mode
 863        (not company-candidates)
 864        (let ((company-idle-delay t)
 865              (company-minimum-prefix-length 0)
 866              (company-begin-commands t))
 867          (company-begin)))
 868   ;; Return non-nil if active.
 869   company-candidates)
 870
 871 (defun company-manual-begin ()
 872   (interactive)
 873   (setq company--explicit-action t)
 874   (unwind-protect
 875       (company-auto-begin)
 876     (unless company-candidates
 877       (setq company--explicit-action nil))))
 878
 879 (defun company-other-backend (&optional backward)
 880   (interactive (list current-prefix-arg))
 881   (company-assert-enabled)
 882   (if company-backend
 883       (let* ((after (cdr (member company-backend company-backends)))
 884              (before (cdr (member company-backend (reverse company-backends))))
 885              (next (if backward
 886                        (append before (reverse after))
 887                      (append after (reverse before)))))
 888         (company-cancel)
 889         (dolist (backend next)
 890           (when (ignore-errors (company-begin-backend backend))
 891             (return t))))
 892     (company-manual-begin))
 893   (unless company-candidates
 894     (error "No other back-end")))
 895
 896 (defun company-require-match-p ()
 897   (let ((backend-value (company-call-backend 'require-match)))
 898     (or (eq backend-value t)
 899         (and (if (functionp company-require-match)
 900                  (funcall company-require-match)
 901                (eq company-require-match t))
 902              (not (eq backend-value 'never))))))
 903
 904 (defun company-auto-complete-p (input)
 905   "Return non-nil, if input starts with punctuation or parentheses."
 906   (and (if (functionp company-auto-complete)
 907            (funcall company-auto-complete)
 908          company-auto-complete)
 909        (if (functionp company-auto-complete-chars)
 910            (funcall company-auto-complete-chars input)
 911          (if (consp company-auto-complete-chars)
 912              (memq (char-syntax (string-to-char input))
 913                    company-auto-complete-chars)
 914            (string-match (substring input 0 1) company-auto-complete-chars)))))
 915
 916 (defun company--incremental-p ()
 917   (and (> (point) company-point)
 918        (> (point-max) company--point-max)
 919        (not (eq this-command 'backward-delete-char-untabify))
 920        (equal (buffer-substring (- company-point (length company-prefix))
 921                                 company-point)
 922               company-prefix)))
 923
 924 (defsubst company--string-incremental-p (old-prefix new-prefix)
 925   (and (> (length new-prefix) (length old-prefix))
 926        (equal old-prefix (substring new-prefix 0 (length old-prefix)))))
 927
 928 (defun company--continue-failed (new-prefix)
 929   (when (company--incremental-p)
 930     (let ((input (buffer-substring-no-properties (point) company-point)))
 931       (cond
 932        ((company-auto-complete-p input)
 933         ;; auto-complete
 934         (save-excursion
 935           (goto-char company-point)
 936           (let ((company--auto-completion t))
 937             (company-complete-selection))
 938           nil))
 939        ((and (company--string-incremental-p company-prefix new-prefix)
 940              (company-require-match-p))
 941         ;; wrong incremental input, but required match
 942         (backward-delete-char (length input))
 943         (ding)
 944         (message "Matching input is required")
 945         company-candidates)
 946        ((equal company-prefix (car company-candidates))
 947         ;; last input was actually success
 948         (company-cancel company-prefix)
 949         nil)))))
 950
 951 (defun company--good-prefix-p (prefix)
 952   (and (or (company-explicit-action-p)
 953            (unless (eq prefix 'stop)
 954              (>= (or (cdr-safe prefix) (length prefix))
 955                  company-minimum-prefix-length)))
 956        (stringp (or (car-safe prefix) prefix))))
 957
 958 (defun company--continue ()
 959   (when (company-call-backend 'no-cache company-prefix)
 960     ;; Don't complete existing candidates, fetch new ones.
 961     (setq company-candidates-cache nil))
 962   (let* ((new-prefix (company-call-backend 'prefix))
 963          (c (when (and (company--good-prefix-p new-prefix)
 964                        (setq new-prefix (or (car-safe new-prefix) new-prefix))
 965                        (= (- (point) (length new-prefix))
 966                           (- company-point (length company-prefix))))
 967               (setq new-prefix (or (car-safe new-prefix) new-prefix))
 968               (company-calculate-candidates new-prefix))))
 969     (or (cond
 970          ((eq c t)
 971           ;; t means complete/unique.
 972           (company-cancel new-prefix)
 973           nil)
 974          ((consp c)
 975           ;; incremental match
 976           (setq company-prefix new-prefix)
 977           (company-update-candidates c)
 978           c)
 979          (t (company--continue-failed new-prefix)))
 980         (company-cancel))))
 981
 982 (defun company--begin-new ()
 983   (let (prefix c)
 984     (dolist (backend (if company-backend
 985                          ;; prefer manual override
 986                          (list company-backend)
 987                        company-backends))
 988       (setq prefix
 989             (if (or (symbolp backend)
 990                     (functionp backend))
 991                 (when (or (not (symbolp backend))
 992                           (eq t (get backend 'company-init))
 993                           (unless (get backend 'company-init)
 994                             (company-init-backend backend)))
 995                   (funcall backend 'prefix))
 996               (company--multi-backend-adapter backend 'prefix)))
 997       (when prefix
 998         (when (company--good-prefix-p prefix)
 999           (setq prefix (or (car-safe prefix) prefix)
1000                 company-backend backend
1001                 c (company-calculate-candidates prefix))
1002           ;; t means complete/unique.  We don't start, so no hooks.
1003           (if (not (consp c))
1004               (when company--explicit-action
1005                 (message "No completion found"))
1006             (setq company-prefix prefix)
1007             (when (symbolp backend)
1008               (setq company-lighter (concat " " (symbol-name backend))))
1009             (company-update-candidates c)
1010             (run-hook-with-args 'company-completion-started-hook
1011                                 (company-explicit-action-p))
1012             (company-call-frontends 'show)))
1013         (return c)))))
1014
1015 (defun company-begin ()
1016   (or (and company-candidates (company--continue))
1017       (and (company--should-complete) (company--begin-new)))
1018   (when company-candidates
1019     (when (and company-end-of-buffer-workaround (eobp))
1020       (save-excursion (insert "\n"))
1021       (setq company-added-newline (buffer-chars-modified-tick)))
1022     (setq company-point (point)
1023           company--point-max (point-max))
1024     (company-ensure-emulation-alist)
1025     (company-enable-overriding-keymap company-active-map)
1026     (company-call-frontends 'update)))
1027
1028 (defun company-cancel (&optional result)
1029   (and company-added-newline
1030        (> (point-max) (point-min))
1031        (let ((tick (buffer-chars-modified-tick)))
1032          (delete-region (1- (point-max)) (point-max))
1033          (equal tick company-added-newline))
1034        ;; Only set unmodified when tick remained the same since insert.
1035        (set-buffer-modified-p nil))
1036   (when company-prefix
1037     (if (stringp result)
1038         (progn
1039           (company-call-backend 'pre-completion result)
1040           (run-hook-with-args 'company-completion-finished-hook result)
1041           (company-call-backend 'post-completion result))
1042       (run-hook-with-args 'company-completion-cancelled-hook result)))
1043   (setq company-added-newline nil
1044         company-backend nil
1045         company-prefix nil
1046         company-candidates nil
1047         company-candidates-length nil
1048         company-candidates-cache nil
1049         company-candidates-predicate nil
1050         company-common nil
1051         company-selection 0
1052         company-selection-changed nil
1053         company--explicit-action nil
1054         company-lighter company-default-lighter
1055         company--point-max nil
1056         company-point nil)
1057   (when company-timer
1058     (cancel-timer company-timer))
1059   (company-search-mode 0)
1060   (company-call-frontends 'hide)
1061   (company-enable-overriding-keymap nil))
1062
1063 (defun company-abort ()
1064   (interactive)
1065   (company-cancel t)
1066   ;; Don't start again, unless started manually.
1067   (setq company-point (point)))
1068
1069 (defun company-finish (result)
1070   (insert (company-strip-prefix result))
1071   (company-cancel result)
1072   ;; Don't start again, unless started manually.
1073   (setq company-point (point)))
1074
1075 (defsubst company-keep (command)
1076   (and (symbolp command) (get command 'company-keep)))
1077
1078 (defun company-pre-command ()
1079   (unless (company-keep this-command)
1080     (condition-case err
1081         (when company-candidates
1082           (company-call-frontends 'pre-command))
1083       (error (message "Company: An error occurred in pre-command")
1084              (message "%s" (error-message-string err))
1085              (company-cancel))))
1086   (when company-timer
1087     (cancel-timer company-timer)
1088     (setq company-timer nil))
1089   (company-uninstall-map))
1090
1091 (defun company-post-command ()
1092   (unless (company-keep this-command)
1093     (condition-case err
1094         (progn
1095           (unless (equal (point) company-point)
1096             (company-begin))
1097           (if company-candidates
1098               (company-call-frontends 'post-command)
1099             (and (numberp company-idle-delay)
1100                  (or (eq t company-begin-commands)
1101                      (memq this-command company-begin-commands))
1102                  (setq company-timer
1103                        (run-with-timer company-idle-delay nil
1104                                        'company-idle-begin
1105                                        (current-buffer) (selected-window)
1106                                        (buffer-chars-modified-tick) (point))))))
1107       (error (message "Company: An error occurred in post-command")
1108              (message "%s" (error-message-string err))
1109              (company-cancel))))
1110   (company-install-map))
1111
1112 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1113
1114 (defvar company-search-string nil)
1115 (make-variable-buffer-local 'company-search-string)
1116
1117 (defvar company-search-lighter " Search: \"\"")
1118 (make-variable-buffer-local 'company-search-lighter)
1119
1120 (defvar company-search-old-map nil)
1121 (make-variable-buffer-local 'company-search-old-map)
1122
1123 (defvar company-search-old-selection 0)
1124 (make-variable-buffer-local 'company-search-old-selection)
1125
1126 (defun company-search (text lines)
1127   (let ((quoted (regexp-quote text))
1128         (i 0))
1129     (dolist (line lines)
1130       (when (string-match quoted line (length company-prefix))
1131         (return i))
1132       (incf i))))
1133
1134 (defun company-search-printing-char ()
1135   (interactive)
1136   (company-search-assert-enabled)
1137   (setq company-search-string
1138         (concat (or company-search-string "") (string last-command-event))
1139         company-search-lighter (concat " Search: \"" company-search-string
1140                                         "\""))
1141   (let ((pos (company-search company-search-string
1142                               (nthcdr company-selection company-candidates))))
1143     (if (null pos)
1144         (ding)
1145       (company-set-selection (+ company-selection pos) t))))
1146
1147 (defun company-search-repeat-forward ()
1148   "Repeat the incremental search in completion candidates forward."
1149   (interactive)
1150   (company-search-assert-enabled)
1151   (let ((pos (company-search company-search-string
1152                               (cdr (nthcdr company-selection
1153                                            company-candidates)))))
1154     (if (null pos)
1155         (ding)
1156       (company-set-selection (+ company-selection pos 1) t))))
1157
1158 (defun company-search-repeat-backward ()
1159   "Repeat the incremental search in completion candidates backwards."
1160   (interactive)
1161   (company-search-assert-enabled)
1162   (let ((pos (company-search company-search-string
1163                               (nthcdr (- company-candidates-length
1164                                          company-selection)
1165                                       (reverse company-candidates)))))
1166     (if (null pos)
1167         (ding)
1168       (company-set-selection (- company-selection pos 1) t))))
1169
1170 (defun company-create-match-predicate ()
1171   (setq company-candidates-predicate
1172         `(lambda (candidate)
1173            ,(if company-candidates-predicate
1174                 `(and (string-match ,company-search-string candidate)
1175                       (funcall ,company-candidates-predicate
1176                                candidate))
1177               `(string-match ,company-search-string candidate))))
1178   (company-update-candidates
1179    (company-apply-predicate company-candidates company-candidates-predicate))
1180   ;; Invalidate cache.
1181   (setq company-candidates-cache (cons company-prefix company-candidates)))
1182
1183 (defun company-filter-printing-char ()
1184   (interactive)
1185   (company-search-assert-enabled)
1186   (company-search-printing-char)
1187   (company-create-match-predicate)
1188   (company-call-frontends 'update))
1189
1190 (defun company-search-kill-others ()
1191   "Limit the completion candidates to the ones matching the search string."
1192   (interactive)
1193   (company-search-assert-enabled)
1194   (company-create-match-predicate)
1195   (company-search-mode 0)
1196   (company-call-frontends 'update))
1197
1198 (defun company-search-abort ()
1199   "Abort searching the completion candidates."
1200   (interactive)
1201   (company-search-assert-enabled)
1202   (company-set-selection company-search-old-selection t)
1203   (company-search-mode 0))
1204
1205 (defun company-search-other-char ()
1206   (interactive)
1207   (company-search-assert-enabled)
1208   (company-search-mode 0)
1209   (company--unread-last-input))
1210
1211 (defvar company-search-map
1212   (let ((i 0)
1213         (keymap (make-keymap)))
1214     (if (fboundp 'max-char)
1215         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1216                               'company-search-printing-char)
1217       (with-no-warnings
1218         ;; obsolete in Emacs 23
1219         (let ((l (generic-character-list))
1220               (table (nth 1 keymap)))
1221           (while l
1222             (set-char-table-default table (car l) 'company-search-printing-char)
1223             (setq l (cdr l))))))
1224     (define-key keymap [t] 'company-search-other-char)
1225     (while (< i ?\s)
1226       (define-key keymap (make-string 1 i) 'company-search-other-char)
1227       (incf i))
1228     (while (< i 256)
1229       (define-key keymap (vector i) 'company-search-printing-char)
1230       (incf i))
1231     (let ((meta-map (make-sparse-keymap)))
1232       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1233       (define-key keymap [escape] meta-map))
1234     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1235     (define-key keymap "\e\e\e" 'company-search-other-char)
1236     (define-key keymap  [escape escape escape] 'company-search-other-char)
1237
1238     (define-key keymap "\C-g" 'company-search-abort)
1239     (define-key keymap "\C-s" 'company-search-repeat-forward)
1240     (define-key keymap "\C-r" 'company-search-repeat-backward)
1241     (define-key keymap "\C-o" 'company-search-kill-others)
1242     keymap)
1243   "Keymap used for incrementally searching the completion candidates.")
1244
1245 (define-minor-mode company-search-mode
1246   "Search mode for completion candidates.
1247 Don't start this directly, use `company-search-candidates' or
1248 `company-filter-candidates'."
1249   nil company-search-lighter nil
1250   (if company-search-mode
1251       (if (company-manual-begin)
1252           (progn
1253             (setq company-search-old-selection company-selection)
1254             (company-call-frontends 'update))
1255         (setq company-search-mode nil))
1256     (kill-local-variable 'company-search-string)
1257     (kill-local-variable 'company-search-lighter)
1258     (kill-local-variable 'company-search-old-selection)
1259     (company-enable-overriding-keymap company-active-map)))
1260
1261 (defsubst company-search-assert-enabled ()
1262   (company-assert-enabled)
1263   (unless company-search-mode
1264     (company-uninstall-map)
1265     (error "Company not in search mode")))
1266
1267 (defun company-search-candidates ()
1268   "Start searching the completion candidates incrementally.
1269
1270 \\<company-search-map>Search can be controlled with the commands:
1271 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1272 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1273 - `company-search-abort' (\\[company-search-abort])
1274
1275 Regular characters are appended to the search string.
1276
1277 The command `company-search-kill-others' (\\[company-search-kill-others]) uses
1278  the search string to limit the completion candidates."
1279   (interactive)
1280   (company-search-mode 1)
1281   (company-enable-overriding-keymap company-search-map))
1282
1283 (defvar company-filter-map
1284   (let ((keymap (make-keymap)))
1285     (define-key keymap [remap company-search-printing-char]
1286       'company-filter-printing-char)
1287     (set-keymap-parent keymap company-search-map)
1288     keymap)
1289   "Keymap used for incrementally searching the completion candidates.")
1290
1291 (defun company-filter-candidates ()
1292   "Start filtering the completion candidates incrementally.
1293 This works the same way as `company-search-candidates' immediately
1294 followed by `company-search-kill-others' after each input."
1295   (interactive)
1296   (company-search-mode 1)
1297   (company-enable-overriding-keymap company-filter-map))
1298
1299 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1300
1301 (defun company-select-next ()
1302   "Select the next candidate in the list."
1303   (interactive)
1304   (when (company-manual-begin)
1305     (company-set-selection (1+ company-selection))))
1306
1307 (defun company-select-previous ()
1308   "Select the previous candidate in the list."
1309   (interactive)
1310   (when (company-manual-begin)
1311     (company-set-selection (1- company-selection))))
1312
1313 (defun company-select-next-or-abort ()
1314   "Select the next candidate if more than one, else abort
1315 and invoke the normal binding."
1316   (interactive)
1317   (if (> company-candidates-length 1)
1318       (company-select-next)
1319     (company-abort)
1320     (company--unread-last-input)))
1321
1322 (defun company-select-previous-or-abort ()
1323   "Select the previous candidate if more than one, else abort
1324 and invoke the normal binding."
1325   (interactive)
1326   (if (> company-candidates-length 1)
1327       (company-select-previous)
1328     (company-abort)
1329     (company--unread-last-input)))
1330
1331 (defun company-select-mouse (event)
1332   "Select the candidate picked by the mouse."
1333   (interactive "e")
1334   (when (nth 4 (event-start event))
1335     (company-set-selection (- (cdr (posn-actual-col-row (event-start event)))
1336                               (if (zerop company-tooltip-offset)
1337                                   1
1338                                 (- 2 company-tooltip-offset))
1339                               (company--row)))
1340     t))
1341
1342 (defun company-complete-mouse (event)
1343   "Complete the candidate picked by the mouse."
1344   (interactive "e")
1345   (when (company-select-mouse event)
1346     (company-complete-selection)))
1347
1348 (defun company-complete-selection ()
1349   "Complete the selected candidate."
1350   (interactive)
1351   (when (company-manual-begin)
1352     (let ((result (nth company-selection company-candidates)))
1353       (when company--auto-completion
1354         (setq result (company--safe-candidate result)))
1355       (company-finish result))))
1356
1357 (defun company-complete-common ()
1358   "Complete the common part of all candidates."
1359   (interactive)
1360   (when (company-manual-begin)
1361     (if (and (not (cdr company-candidates))
1362              (equal company-common (car company-candidates)))
1363         (company-complete-selection)
1364       (insert (company-strip-prefix company-common)))))
1365
1366 (defun company-complete ()
1367   "Complete the common part of all candidates or the current selection.
1368 The first time this is called, the common part is completed, the second time, or
1369 when the selection has been changed, the selected candidate is completed."
1370   (interactive)
1371   (when (company-manual-begin)
1372     (if (or company-selection-changed
1373             (eq last-command 'company-complete-common))
1374         (call-interactively 'company-complete-selection)
1375       (call-interactively 'company-complete-common)
1376       (setq this-command 'company-complete-common))))
1377
1378 (defun company-complete-number (n)
1379   "Complete the Nth candidate.
1380 To show the number next to the candidates in some back-ends, enable
1381 `company-show-numbers'."
1382   (when (company-manual-begin)
1383     (and (< n 1) (> n company-candidates-length)
1384          (error "No candidate number %d" n))
1385     (decf n)
1386     (company-finish (nth n company-candidates))))
1387
1388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1389
1390 (defconst company-space-strings-limit 100)
1391
1392 (defconst company-space-strings
1393   (let (lst)
1394     (dotimes (i company-space-strings-limit)
1395       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1396     (apply 'vector lst)))
1397
1398 (defsubst company-space-string (len)
1399   (if (< len company-space-strings-limit)
1400       (aref company-space-strings len)
1401     (make-string len ?\ )))
1402
1403 (defsubst company-safe-substring (str from &optional to)
1404   (if (> from (string-width str))
1405       ""
1406     (with-temp-buffer
1407       (insert str)
1408       (move-to-column from)
1409       (let ((beg (point)))
1410         (if to
1411             (progn
1412               (move-to-column to)
1413               (concat (buffer-substring beg (point))
1414                       (let ((padding (- to (current-column))))
1415                         (when (> padding 0)
1416                           (company-space-string padding)))))
1417           (buffer-substring beg (point-max)))))))
1418
1419 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1420
1421 (defvar company-last-metadata nil)
1422 (make-variable-buffer-local 'company-last-metadata)
1423
1424 (defun company-fetch-metadata ()
1425   (let ((selected (nth company-selection company-candidates)))
1426     (unless (equal selected (car company-last-metadata))
1427       (setq company-last-metadata
1428             (cons selected (company-call-backend 'meta selected))))
1429     (cdr company-last-metadata)))
1430
1431 (defun company-doc-buffer (&optional string)
1432   (with-current-buffer (get-buffer-create "*Company meta-data*")
1433     (erase-buffer)
1434     (current-buffer)))
1435
1436 (defvar company--electric-commands
1437   '(scroll-other-window scroll-other-window-down)
1438   "List of Commands that won't break out of electric commands.")
1439
1440 (defmacro company--electric-do (&rest body)
1441   (declare (indent 0) (debug t))
1442   `(when (company-manual-begin)
1443      (save-window-excursion
1444        (let ((height (window-height))
1445              (row (company--row))
1446              cmd)
1447          ,@body
1448          (and (< (window-height) height)
1449               (< (- (window-height) row 2) company-tooltip-limit)
1450               (recenter (- (window-height) row 2)))
1451          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1452                       company--electric-commands)
1453            (call-interactively cmd))
1454          (company--unread-last-input)))))
1455
1456 (defun company--unread-last-input ()
1457   (when last-input-event
1458     (clear-this-command-keys t)
1459     (setq unread-command-events (list last-input-event))))
1460
1461 (defun company-show-doc-buffer ()
1462   "Temporarily show a buffer with the complete documentation for the selection."
1463   (interactive)
1464   (company--electric-do
1465     (let* ((selected (nth company-selection company-candidates))
1466            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1467                            (error "No documentation available"))))
1468       (with-current-buffer doc-buffer
1469         (goto-char (point-min)))
1470       (display-buffer doc-buffer t))))
1471 (put 'company-show-doc-buffer 'company-keep t)
1472
1473 (defun company-show-location ()
1474   "Temporarily display a buffer showing the selected candidate in context."
1475   (interactive)
1476   (company--electric-do
1477     (let* ((selected (nth company-selection company-candidates))
1478            (location (company-call-backend 'location selected))
1479            (pos (or (cdr location) (error "No location available")))
1480            (buffer (or (and (bufferp (car location)) (car location))
1481                        (find-file-noselect (car location) t))))
1482       (with-selected-window (display-buffer buffer t)
1483         (save-restriction
1484           (widen)
1485           (if (bufferp (car location))
1486               (goto-char pos)
1487             (goto-char (point-min))
1488             (forward-line (1- pos))))
1489         (set-window-start nil (point))))))
1490 (put 'company-show-location 'company-keep t)
1491
1492 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1493
1494 (defvar company-callback nil)
1495 (make-variable-buffer-local 'company-callback)
1496
1497 (defvar company-begin-with-marker nil)
1498 (make-variable-buffer-local 'company-begin-with-marker)
1499
1500 (defun company-remove-callback (&optional ignored)
1501   (remove-hook 'company-completion-finished-hook company-callback t)
1502   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1503   (remove-hook 'company-completion-finished-hook 'company-remove-callback t)
1504   (when company-begin-with-marker
1505     (set-marker company-begin-with-marker nil)))
1506
1507 (defun company-begin-backend (backend &optional callback)
1508   "Start a completion at point using BACKEND."
1509   (interactive (let ((val (completing-read "Company back-end: "
1510                                            obarray
1511                                            'functionp nil "company-")))
1512                  (when val
1513                    (list (intern val)))))
1514   (when (setq company-callback callback)
1515     (add-hook 'company-completion-finished-hook company-callback nil t))
1516   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1517   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1518   (setq company-backend backend)
1519   ;; Return non-nil if active.
1520   (or (company-manual-begin)
1521       (progn
1522         (setq company-backend nil)
1523         (error "Cannot complete at point"))))
1524
1525 (defun company-begin-with (candidates
1526                            &optional prefix-length require-match callback)
1527   "Start a completion at point.
1528 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length of
1529 the prefix that already is in the buffer before point.  It defaults to 0.
1530
1531 CALLBACK is a function called with the selected result if the user successfully
1532 completes the input.
1533
1534 Example:
1535 \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
1536   (setq company-begin-with-marker (copy-marker (point) t))
1537   (company-begin-backend
1538    `(lambda (command &optional arg &rest ignored)
1539       (cond
1540        ((eq command 'prefix)
1541         (when (equal (point) (marker-position company-begin-with-marker))
1542           (buffer-substring ,(- (point) (or prefix-length 0)) (point))))
1543        ((eq command 'candidates)
1544         (all-completions arg ',candidates))
1545        ((eq command 'require-match)
1546         ,require-match)))
1547    callback))
1548
1549 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1550
1551 (defvar company-pseudo-tooltip-overlay nil)
1552 (make-variable-buffer-local 'company-pseudo-tooltip-overlay)
1553
1554 (defvar company-tooltip-offset 0)
1555 (make-variable-buffer-local 'company-tooltip-offset)
1556
1557 (defun company-pseudo-tooltip-update-offset (selection num-lines limit)
1558
1559   (decf limit 2)
1560   (setq company-tooltip-offset
1561         (max (min selection company-tooltip-offset)
1562              (- selection -1 limit)))
1563
1564   (when (<= company-tooltip-offset 1)
1565     (incf limit)
1566     (setq company-tooltip-offset 0))
1567
1568   (when (>= company-tooltip-offset (- num-lines limit 1))
1569     (incf limit)
1570     (when (= selection (1- num-lines))
1571       (decf company-tooltip-offset)
1572       (when (<= company-tooltip-offset 1)
1573         (setq company-tooltip-offset 0)
1574         (incf limit))))
1575
1576   limit)
1577
1578 ;;; propertize
1579
1580 (defsubst company-round-tab (arg)
1581   (* (/ (+ arg tab-width) tab-width) tab-width))
1582
1583 (defun company-untabify (str)
1584   (let* ((pieces (split-string str "\t"))
1585          (copy pieces))
1586     (while (cdr copy)
1587       (setcar copy (company-safe-substring
1588                     (car copy) 0 (company-round-tab (string-width (car copy)))))
1589       (pop copy))
1590     (apply 'concat pieces)))
1591
1592 (defun company-fill-propertize (line width selected)
1593   (setq line (company-safe-substring line 0 width))
1594   (add-text-properties 0 width '(face company-tooltip
1595                                  mouse-face company-tooltip-mouse)
1596                        line)
1597   (add-text-properties 0 (length company-common)
1598                        '(face company-tooltip-common
1599                          mouse-face company-tooltip-mouse)
1600                        line)
1601   (when selected
1602     (if (and company-search-string
1603              (string-match (regexp-quote company-search-string) line
1604                            (length company-prefix)))
1605         (progn
1606           (add-text-properties (match-beginning 0) (match-end 0)
1607                                '(face company-tooltip-selection)
1608                                line)
1609           (when (< (match-beginning 0) (length company-common))
1610             (add-text-properties (match-beginning 0) (length company-common)
1611                                  '(face company-tooltip-common-selection)
1612                                  line)))
1613       (add-text-properties 0 width '(face company-tooltip-selection
1614                                           mouse-face company-tooltip-selection)
1615                            line)
1616       (add-text-properties 0 (length company-common)
1617                            '(face company-tooltip-common-selection
1618                              mouse-face company-tooltip-selection)
1619                            line)))
1620   line)
1621
1622 ;;; replace
1623
1624 (defun company-buffer-lines (beg end)
1625   (goto-char beg)
1626   (let (lines)
1627     (while (< (point) end)
1628       (let ((bol (point)))
1629         ;; A visual line can contain several physical lines (e.g. with outline's
1630         ;; folding overlay).  Take only the first one.
1631         (re-search-forward "$")
1632         (push (buffer-substring bol (min end (point))) lines))
1633       (vertical-motion 1))
1634     (nreverse lines)))
1635
1636 (defsubst company-modify-line (old new offset)
1637   (concat (company-safe-substring old 0 offset)
1638           new
1639           (company-safe-substring old (+ offset (length new)))))
1640
1641 (defsubst company--length-limit (lst limit)
1642   (if (nthcdr limit lst)
1643       limit
1644     (length lst)))
1645
1646 (defun company--replacement-string (lines old column nl &optional align-top)
1647
1648   (let ((width (length (car lines))))
1649     (when (> width (- (window-width) column))
1650       (setq column (max 0 (- (window-width) width)))))
1651
1652   (let (new)
1653     (when align-top
1654       ;; untouched lines first
1655       (dotimes (i (- (length old) (length lines)))
1656         (push (pop old) new)))
1657     ;; length into old lines.
1658     (while old
1659       (push (company-modify-line (pop old) (pop lines) column) new))
1660     ;; Append whole new lines.
1661     (while lines
1662       (push (concat (company-space-string column) (pop lines)) new))
1663
1664     (let ((str (concat (when nl "\n")
1665                        (mapconcat 'identity (nreverse new) "\n")
1666                        "\n")))
1667       (font-lock-append-text-property 0 (length str) 'face 'default str)
1668       str)))
1669
1670 (defun company--create-lines (selection limit)
1671
1672   (let ((len company-candidates-length)
1673         (numbered 99999)
1674         lines
1675         width
1676         lines-copy
1677         previous
1678         remainder
1679         new)
1680
1681     ;; Scroll to offset.
1682     (setq limit (company-pseudo-tooltip-update-offset selection len limit))
1683
1684     (when (> company-tooltip-offset 0)
1685       (setq previous (format "...(%d)" company-tooltip-offset)))
1686
1687     (setq remainder (- len limit company-tooltip-offset)
1688           remainder (when (> remainder 0)
1689                       (setq remainder (format "...(%d)" remainder))))
1690
1691     (decf selection company-tooltip-offset)
1692     (setq width (max (length previous) (length remainder))
1693           lines (nthcdr company-tooltip-offset company-candidates)
1694           len (min limit len)
1695           lines-copy lines)
1696
1697     (dotimes (i len)
1698       (setq width (max (length (pop lines-copy)) width)))
1699     (setq width (min width (window-width)))
1700
1701     (setq lines-copy lines)
1702
1703     ;; number can make tooltip too long
1704     (when company-show-numbers
1705       (setq numbered company-tooltip-offset))
1706
1707     (when previous
1708       (push (propertize (company-safe-substring previous 0 width)
1709                         'face 'company-tooltip)
1710             new))
1711
1712     (dotimes (i len)
1713       (push (company-fill-propertize
1714              (if (>= numbered 10)
1715                  (company-reformat (pop lines))
1716                (incf numbered)
1717                (format "%s %d"
1718                        (company-safe-substring (company-reformat (pop lines))
1719                                                0 (- width 2))
1720                        (mod numbered 10)))
1721              width (equal i selection))
1722             new))
1723
1724     (when remainder
1725       (push (propertize (company-safe-substring remainder 0 width)
1726                         'face 'company-tooltip)
1727             new))
1728
1729     (setq lines (nreverse new))))
1730
1731 ;; show
1732
1733 (defsubst company--window-inner-height ()
1734   (let ((edges (window-inside-edges (selected-window))))
1735     (- (nth 3 edges) (nth 1 edges))))
1736
1737 (defsubst company--pseudo-tooltip-height ()
1738   "Calculate the appropriate tooltip height.
1739 Returns a negative number if the tooltip should be displayed above point."
1740   (let* ((lines (company--row))
1741          (below (- (company--window-inner-height) 1 lines)))
1742     (if (and (< below (min company-tooltip-minimum company-candidates-length))
1743              (> lines below))
1744         (- (max 3 (min company-tooltip-limit lines)))
1745       (max 3 (min company-tooltip-limit below)))))
1746
1747 (defun company-pseudo-tooltip-show (row column selection)
1748   (company-pseudo-tooltip-hide)
1749   (save-excursion
1750
1751     (move-to-column 0)
1752
1753     (let* ((height (company--pseudo-tooltip-height))
1754            above)
1755
1756       (when (< height 0)
1757         (setq row (+ row height -1)
1758               above t))
1759
1760       (let* ((nl (< (move-to-window-line row) row))
1761              (beg (point))
1762              (end (save-excursion
1763                     (move-to-window-line (+ row (abs height)))
1764                     (point)))
1765              (ov (make-overlay beg end))
1766              (args (list (mapcar 'company-untabify
1767                                  (company-buffer-lines beg end))
1768                          column nl above)))
1769
1770         (setq company-pseudo-tooltip-overlay ov)
1771         (overlay-put ov 'company-replacement-args args)
1772         (overlay-put ov 'company-before
1773                      (apply 'company--replacement-string
1774                             (company--create-lines selection (abs height))
1775                             args))
1776
1777         (overlay-put ov 'company-column column)
1778         (overlay-put ov 'company-height height)))))
1779
1780 (defun company-pseudo-tooltip-show-at-point (pos)
1781   (let ((col-row (company--col-row pos)))
1782     (when col-row
1783       (company-pseudo-tooltip-show (1+ (cdr col-row)) (car col-row)
1784                                    company-selection))))
1785
1786 (defun company-pseudo-tooltip-edit (lines selection)
1787   (let ((column (overlay-get company-pseudo-tooltip-overlay 'company-column))
1788         (height (overlay-get company-pseudo-tooltip-overlay 'company-height)))
1789     (overlay-put company-pseudo-tooltip-overlay 'company-before
1790                  (apply 'company--replacement-string
1791                         (company--create-lines selection (abs height))
1792                         (overlay-get company-pseudo-tooltip-overlay
1793                                      'company-replacement-args)))))
1794
1795 (defun company-pseudo-tooltip-hide ()
1796   (when company-pseudo-tooltip-overlay
1797     (delete-overlay company-pseudo-tooltip-overlay)
1798     (setq company-pseudo-tooltip-overlay nil)))
1799
1800 (defun company-pseudo-tooltip-hide-temporarily ()
1801   (when (overlayp company-pseudo-tooltip-overlay)
1802     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
1803     (overlay-put company-pseudo-tooltip-overlay 'before-string nil)))
1804
1805 (defun company-pseudo-tooltip-unhide ()
1806   (when company-pseudo-tooltip-overlay
1807     (overlay-put company-pseudo-tooltip-overlay 'invisible t)
1808     ;; Beat outline's folding overlays, at least.
1809     (overlay-put company-pseudo-tooltip-overlay 'priority 1)
1810     (overlay-put company-pseudo-tooltip-overlay 'before-string
1811                  (overlay-get company-pseudo-tooltip-overlay 'company-before))
1812     (overlay-put company-pseudo-tooltip-overlay 'window (selected-window))))
1813
1814 (defun company-pseudo-tooltip-guard ()
1815   (buffer-substring-no-properties
1816    (point) (overlay-start company-pseudo-tooltip-overlay)))
1817
1818 (defun company-pseudo-tooltip-frontend (command)
1819   "`company-mode' front-end similar to a tooltip but based on overlays."
1820   (case command
1821     (pre-command (company-pseudo-tooltip-hide-temporarily))
1822     (post-command
1823      (let ((old-height (if (overlayp company-pseudo-tooltip-overlay)
1824                            (overlay-get company-pseudo-tooltip-overlay
1825                                         'company-height)
1826                          0))
1827            (new-height (company--pseudo-tooltip-height)))
1828        (unless (and (>= (* old-height new-height) 0)
1829                     (>= (abs old-height) (abs new-height))
1830                     (equal (company-pseudo-tooltip-guard)
1831                            (overlay-get company-pseudo-tooltip-overlay
1832                                         'company-guard)))
1833          ;; Redraw needed.
1834          (company-pseudo-tooltip-show-at-point (- (point)
1835                                                   (length company-prefix)))
1836          (overlay-put company-pseudo-tooltip-overlay
1837                       'company-guard (company-pseudo-tooltip-guard))))
1838      (company-pseudo-tooltip-unhide))
1839     (hide (company-pseudo-tooltip-hide)
1840           (setq company-tooltip-offset 0))
1841     (update (when (overlayp company-pseudo-tooltip-overlay)
1842               (company-pseudo-tooltip-edit company-candidates
1843                                            company-selection)))))
1844
1845 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
1846   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
1847   (unless (and (eq command 'post-command)
1848                (not (cdr company-candidates)))
1849     (company-pseudo-tooltip-frontend command)))
1850
1851 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1852
1853 (defvar company-preview-overlay nil)
1854 (make-variable-buffer-local 'company-preview-overlay)
1855
1856 (defun company-preview-show-at-point (pos)
1857   (company-preview-hide)
1858
1859   (setq company-preview-overlay (make-overlay pos pos))
1860
1861   (let ((completion(nth company-selection company-candidates)))
1862     (setq completion (propertize completion 'face 'company-preview))
1863     (add-text-properties 0 (length company-common)
1864                          '(face company-preview-common) completion)
1865
1866     ;; Add search string
1867     (and company-search-string
1868          (string-match (regexp-quote company-search-string) completion)
1869          (add-text-properties (match-beginning 0)
1870                               (match-end 0)
1871                               '(face company-preview-search)
1872                               completion))
1873
1874     (setq completion (company-strip-prefix completion))
1875
1876     (and (equal pos (point))
1877          (not (equal completion ""))
1878          (add-text-properties 0 1 '(cursor t) completion))
1879
1880     (overlay-put company-preview-overlay 'after-string completion)
1881     (overlay-put company-preview-overlay 'window (selected-window))))
1882
1883 (defun company-preview-hide ()
1884   (when company-preview-overlay
1885     (delete-overlay company-preview-overlay)
1886     (setq company-preview-overlay nil)))
1887
1888 (defun company-preview-frontend (command)
1889   "`company-mode' front-end showing the selection as if it had been inserted."
1890   (case command
1891     (pre-command (company-preview-hide))
1892     (post-command (company-preview-show-at-point (point)))
1893     (hide (company-preview-hide))))
1894
1895 (defun company-preview-if-just-one-frontend (command)
1896   "`company-preview-frontend', but only shown for single candidates."
1897   (unless (and (eq command 'post-command)
1898                (cdr company-candidates))
1899     (company-preview-frontend command)))
1900
1901 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1902
1903 (defvar company-echo-last-msg nil)
1904 (make-variable-buffer-local 'company-echo-last-msg)
1905
1906 (defvar company-echo-timer nil)
1907
1908 (defvar company-echo-delay .01)
1909
1910 (defun company-echo-show (&optional getter)
1911   (when getter
1912     (setq company-echo-last-msg (funcall getter)))
1913   (let ((message-log-max nil))
1914     (if company-echo-last-msg
1915         (message "%s" company-echo-last-msg)
1916       (message ""))))
1917
1918 (defsubst company-echo-show-soon (&optional getter)
1919   (when company-echo-timer
1920     (cancel-timer company-echo-timer))
1921   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
1922
1923 (defsubst company-echo-show-when-idle (&optional getter)
1924   (when (sit-for .01)
1925     (company-echo-show getter)))
1926
1927 (defsubst company-echo-show-when-not-busy (&optional getter)
1928   "Run `company-echo-show' with arg GETTER once Emacs isn't busy."
1929   (when (sit-for company-echo-delay)
1930     (company-echo-show getter)))
1931
1932 (defun company-echo-format ()
1933
1934   (let ((limit (window-width (minibuffer-window)))
1935         (len -1)
1936         ;; Roll to selection.
1937         (candidates (nthcdr company-selection company-candidates))
1938         (i (if company-show-numbers company-selection 99999))
1939         comp msg)
1940
1941     (while candidates
1942       (setq comp (company-reformat (pop candidates))
1943             len (+ len 1 (length comp)))
1944       (if (< i 10)
1945           ;; Add number.
1946           (progn
1947             (setq comp (propertize (format "%d: %s" i comp)
1948                                    'face 'company-echo))
1949             (incf len 3)
1950             (incf i)
1951             (add-text-properties 3 (+ 3 (length company-common))
1952                                  '(face company-echo-common) comp))
1953         (setq comp (propertize comp 'face 'company-echo))
1954         (add-text-properties 0 (length company-common)
1955                              '(face company-echo-common) comp))
1956       (if (>= len limit)
1957           (setq candidates nil)
1958         (push comp msg)))
1959
1960     (mapconcat 'identity (nreverse msg) " ")))
1961
1962 (defun company-echo-strip-common-format ()
1963
1964   (let ((limit (window-width (minibuffer-window)))
1965         (len (+ (length company-prefix) 2))
1966         ;; Roll to selection.
1967         (candidates (nthcdr company-selection company-candidates))
1968         (i (if company-show-numbers company-selection 99999))
1969         msg comp)
1970
1971     (while candidates
1972       (setq comp (company-strip-prefix (pop candidates))
1973             len (+ len 2 (length comp)))
1974       (when (< i 10)
1975         ;; Add number.
1976         (setq comp (format "%s (%d)" comp i))
1977         (incf len 4)
1978         (incf i))
1979       (if (>= len limit)
1980           (setq candidates nil)
1981         (push (propertize comp 'face 'company-echo) msg)))
1982
1983     (concat (propertize company-prefix 'face 'company-echo-common) "{"
1984             (mapconcat 'identity (nreverse msg) ", ")
1985             "}")))
1986
1987 (defun company-echo-hide ()
1988   (unless (equal company-echo-last-msg "")
1989     (setq company-echo-last-msg "")
1990     (company-echo-show)))
1991
1992 (defun company-echo-frontend (command)
1993   "`company-mode' front-end showing the candidates in the echo area."
1994   (case command
1995     (post-command (company-echo-show-soon 'company-echo-format))
1996     (hide (company-echo-hide))))
1997
1998 (defun company-echo-strip-common-frontend (command)
1999   "`company-mode' front-end showing the candidates in the echo area."
2000   (case command
2001     (post-command (company-echo-show-soon 'company-echo-strip-common-format))
2002     (hide (company-echo-hide))))
2003
2004 (defun company-echo-metadata-frontend (command)
2005   "`company-mode' front-end showing the documentation in the echo area."
2006   (case command
2007     (post-command (company-echo-show-when-idle 'company-fetch-metadata))
2008     (hide (company-echo-hide))))
2009
2010 (provide 'company)
2011 ;;; company.el ends here