code.delx.au - gnu-emacs-elpa/blob - company-dabbrev.el

   1 ;;; company-dabbrev.el --- dabbrev-like company-mode completion back-end
   2
   3 ;; Copyright (C) 2009, 2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (eval-when-compile (require 'cl))
  30
  31 (defgroup company-dabbrev nil
  32   "dabbrev-like completion back-end."
  33   :group 'company)
  34
  35 (defcustom company-dabbrev-other-buffers 'all
  36   "Determines whether `company-dabbrev' should search other buffers.
  37 If `all', search all other buffers.  If t, search buffers with the same
  38 major mode.
  39 See also `company-dabbrev-time-limit'."
  40   :type '(choice (const :tag "Off" nil)
  41                  (const :tag "Same major mode" t)
  42                  (const :tag "All" all)))
  43
  44 (defcustom company-dabbrev-time-limit .1
  45   "Determines how many seconds `company-dabbrev' should look for matches."
  46   :type '(choice (const :tag "Off" nil)
  47                  (number :tag "Seconds")))
  48
  49 (defcustom company-dabbrev-char-regexp "\\sw"
  50   "A regular expression matching the characters `company-dabbrev' looks for."
  51   :type 'regexp)
  52
  53 (defcustom company-dabbrev-ignore-case 'keep-prefix
  54   "The value of `ignore-case' returned by `company-dabbrev'.")
  55
  56 (defmacro company-dabrev--time-limit-while (test start limit &rest body)
  57   (declare (indent 3) (debug t))
  58   `(let ((company-time-limit-while-counter 0))
  59      (catch 'done
  60        (while ,test
  61          ,@body
  62          (and ,limit
  63               (eq (incf company-time-limit-while-counter) 25)
  64               (setq company-time-limit-while-counter 0)
  65               (> (float-time (time-since ,start)) ,limit)
  66               (throw 'done 'company-time-out))))))
  67
  68 (defsubst company-dabbrev--make-regexp (prefix)
  69   (concat "\\<" (if (equal prefix "")
  70               company-dabbrev-char-regexp
  71             (regexp-quote prefix))
  72           "\\(" company-dabbrev-char-regexp "\\)*\\>"))
  73
  74 (defun company-dabbrev--search-buffer (regexp pos symbols start limit
  75                                        ignore-comments)
  76   (save-excursion
  77     (let (match)
  78       (goto-char (if pos (1- pos) (point-min)))
  79       ;; search before pos
  80       (company-dabrev--time-limit-while (re-search-backward regexp nil t)
  81           start limit
  82         (setq match (match-string-no-properties 0))
  83         (if (and ignore-comments (company-in-string-or-comment))
  84             (re-search-backward "\\s<\\|\\s!\\|\\s\"\\|\\s|" nil t)
  85           (push match symbols)))
  86       (goto-char (or pos (point-min)))
  87       ;; search after pos
  88       (company-dabrev--time-limit-while (re-search-forward regexp nil t)
  89           start limit
  90         (setq match (match-string-no-properties 0))
  91         (if (and ignore-comments (company-in-string-or-comment))
  92             (re-search-forward "\\s>\\|\\s!\\|\\s\"" nil t)
  93           (push match symbols)))
  94       symbols)))
  95
  96 (defun company-dabbrev--search (regexp &optional limit other-buffers
  97                                 ignore-comments)
  98   (let* ((start (current-time))
  99          (symbols (company-dabbrev--search-buffer regexp (point) nil start limit
 100                                                   ignore-comments)))
 101     (when other-buffers
 102       (dolist (buffer (delq (current-buffer) (buffer-list)))
 103         (and (or (eq other-buffers 'all)
 104                  (eq (buffer-local-value 'major-mode buffer) major-mode))
 105              (with-current-buffer buffer
 106                (setq symbols
 107                      (company-dabbrev--search-buffer regexp nil symbols start
 108                                                      limit ignore-comments))))
 109         (and limit
 110              (> (float-time (time-since start)) limit)
 111              (return))))
 112     symbols))
 113
 114 ;;;###autoload
 115 (defun company-dabbrev (command &optional arg &rest ignored)
 116   "dabbrev-like `company-mode' completion back-end."
 117   (interactive (list 'interactive))
 118   (case command
 119     (interactive (company-begin-backend 'company-dabbrev))
 120     (prefix (company-grab-word))
 121     (candidates
 122      (mapcar 'downcase
 123              (company-dabbrev--search (company-dabbrev--make-regexp arg)
 124                                       company-dabbrev-time-limit
 125                                       company-dabbrev-other-buffers)))
 126     (ignore-case company-dabbrev-ignore-case)
 127     (duplicates t)))
 128
 129 (provide 'company-dabbrev)
 130 ;;; company-dabbrev.el ends here