code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 86, 87, 93, 94, 95, 96, 97, 98, 1999, 2001, 03, 2004
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (epc
 175      "^Error [0-9]+ at (\\([0-9]*\\):\\([^)\n]+\\))" 2 1)
 176
 177     (iar
 178      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 179      1 2 nil (3))
 180
 181     (ibm
 182      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 183  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 184
 185     ;; fixme: should be `mips'
 186     (irix
 187      "^[-[:alnum:]_/]+: \\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*:\
 188  \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 189
 190     (java
 191      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 192
 193     (jikes-file
 194      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 195     (jikes-line
 196      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 197      nil 1 nil 2 0
 198      (2 (compilation-face '(3))))
 199
 200     (gcc-include
 201      "^\\(?:In file included\\|                \\) from \
 202 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 203
 204     (gnu
 205      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 206 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\): ?\
 207 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 208 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 209 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 210  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 211      1 (2 . 5) (4 . 6) (7 . 8))
 212
 213     (lcc
 214      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 215      2 3 4 (1))
 216
 217     (makepp
 218      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 219 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 220      4 5 nil (1 . 2) 3
 221      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 222       (2 compilation-info-face)
 223       (3 compilation-line-face nil t)
 224       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 225          append)))
 226
 227     ;; Should be lint-1, lint-2 (SysV lint)
 228     (mips-1
 229      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 230     (mips-2
 231      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 232
 233     (msft
 234      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 235 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 236
 237     (oracle
 238      "^Semantic error at line \\([0-9]+\\), column \\([0-9]+\\), file \\(.*\\):$"
 239      3 1 2)
 240
 241     (perl
 242      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 243
 244     (rxp
 245      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 246  \\([0-9]+\\) of file://\\(.+\\)"
 247      4 2 3 (1))
 248
 249     (sparc-pascal-file
 250      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 251  [12][09][0-9][0-9] +\\(.*\\):$"
 252      1 nil nil 0)
 253     (sparc-pascal-line
 254      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 255      nil 3 nil (2) nil (1 (compilation-face '(2))))
 256     (sparc-pascal-example
 257      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 258      nil 1 nil (3) nil (2 (compilation-face '(3))))
 259
 260     (sun
 261      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 262 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 263      3 4 5 (1 . 2))
 264
 265     (sun-ada
 266      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 267
 268     ;; Redundant with `mips'
 269 ;;    (ultrix
 270 ;;      "^\\(?:cfe\\|fort\\): \\(Warning\\)?[^:\n]*: \\([^ \n]*\\), line \\([0-9]+\\):" 2 3 nil (1))
 271
 272     (4bsd
 273      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 274 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3)))
 275   "Alist of values for `compilation-error-regexp-alist'.")
 276
 277 (defcustom compilation-error-regexp-alist
 278   (mapcar 'car compilation-error-regexp-alist-alist)
 279   "Alist that specifies how to match errors in compiler output.
 280 Note that on Unix everything is a valid filename, so these
 281 matchers must make some common sense assumptions, which catch
 282 normal cases.  A shorter list will be lighter on resource usage.
 283
 284 Instead of an alist element, you can use a symbol, which is
 285 looked up in `compilation-error-regexp-alist-alist'.  You can see
 286 the predefined symbols and their effects in the file
 287 `etc/compilation.txt' (linked below if you are customizing this).
 288
 289 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 290 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 291 gives the file name, and the LINE'th subexpression gives the line
 292 number.  The COLUMN'th subexpression gives the column number on
 293 that line.
 294
 295 If FILE, LINE or COLUMN are nil or that index didn't match, that
 296 information is not present on the matched line.  In that case the
 297 file name is assumed to be the same as the previous one in the
 298 buffer, line number defaults to 1 and column defaults to
 299 beginning of line's indentation.
 300
 301 FILE can also have the form (FILE FORMAT...), where the FORMATs
 302 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 303 name, until a file of that name is found.  Or FILE can also be a
 304 function to return the filename.
 305
 306 LINE can also be of the form (LINE . END-LINE) meaning a range
 307 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 308 meaning a range of columns starting on LINE and ending on
 309 END-LINE, if that matched.
 310
 311 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 312 TYPE can also be of the form (WARNING . INFO).  In that case this
 313 will be equivalent to 1 if the WARNING'th subexpression matched
 314 or else equivalent to 0 if the INFO'th subexpression matched.
 315 See `compilation-error-face', `compilation-warning-face',
 316 `compilation-info-face' and `compilation-skip-threshold'.
 317
 318 What matched the HYPERLINK'th subexpression has `mouse-face' and
 319 `compilation-message-face' applied.  If this is nil, the text
 320 matched by the whole REGEXP becomes the hyperlink.
 321
 322 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 323 be added."
 324   :type `(set :menu-tag "Pick"
 325               ,@(mapcar (lambda (elt)
 326                           (list 'const (car elt)))
 327                         compilation-error-regexp-alist-alist))
 328   :link `(file-link :tag "example file"
 329                     ,(concat doc-directory "compilation.txt"))
 330   :group 'compilation)
 331
 332 (defvar compilation-directory nil
 333   "Directory to restore to when doing `recompile'.")
 334
 335 (defvar compilation-directory-matcher
 336   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 337   "A list for tracking when directories are entered or left.
 338 Nil means not to track directories, e.g. if all file names are absolute.  The
 339 first element is the REGEXP matching these messages.  It can match any number
 340 of variants, e.g. different languages.  The remaining elements are all of the
 341 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 342 matches, that is a directory name.  If LEAVE is nil or the corresponding
 343 LEAVE'th subexpression doesn't match, this message is about going into another
 344 directory.  If it does match anything, this message is about going back to the
 345 directory we were in before the last entering message.  If you change this,
 346 you may also want to change `compilation-page-delimiter'.")
 347
 348 (defvar compilation-page-delimiter
 349   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 350   "Value of `page-delimiter' in Compilation mode.")
 351
 352 (defvar compilation-mode-font-lock-keywords
 353    '(;; configure output lines.
 354      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 355       (1 font-lock-variable-name-face)
 356       (2 (compilation-face '(4 . 3))))
 357      ;; Command output lines.  Recognize `make[n]:' lines too.
 358      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 359       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 360      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 361      ("^Compilation finished" . compilation-info-face)
 362      ("^Compilation exited abnormally" . compilation-error-face))
 363    "Additional things to highlight in Compilation mode.
 364 This gets tacked on the end of the generated expressions.")
 365
 366 (defvar compilation-highlight-regexp t
 367   "Regexp matching part of visited source lines to highlight temporarily.
 368 Highlight entire line if t; don't highlight source lines if nil.")
 369
 370 (defvar compilation-highlight-overlay nil
 371   "Overlay used to temporarily highlight compilation matches.")
 372
 373 (defcustom compilation-error-screen-columns t
 374   "*If non-nil, column numbers in error messages are screen columns.
 375 Otherwise they are interpreted as character positions, with
 376 each character occupying one column.
 377 The default is to use screen columns, which requires that the compilation
 378 program and Emacs agree about the display width of the characters,
 379 especially the TAB character."
 380   :type 'boolean
 381   :group 'compilation
 382   :version "20.4")
 383
 384 (defcustom compilation-read-command t
 385   "*Non-nil means \\[compile] reads the compilation command to use.
 386 Otherwise, \\[compile] just uses the value of `compile-command'."
 387   :type 'boolean
 388   :group 'compilation)
 389
 390 ;;;###autoload
 391 (defcustom compilation-ask-about-save t
 392   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 393 Otherwise, it saves all modified buffers without asking."
 394   :type 'boolean
 395   :group 'compilation)
 396
 397 ;;;###autoload
 398 (defcustom compilation-search-path '(nil)
 399   "*List of directories to search for source files named in error messages.
 400 Elements should be directory names, not file names of directories.
 401 nil as an element means to try the default directory."
 402   :type '(repeat (choice (const :tag "Default" nil)
 403                          (string :tag "Directory")))
 404   :group 'compilation)
 405
 406 (defcustom compile-command "make -k "
 407   "*Last shell command used to do a compilation; default for next compilation.
 408
 409 Sometimes it is useful for files to supply local values for this variable.
 410 You might also use mode hooks to specify it in certain modes, like this:
 411
 412     (add-hook 'c-mode-hook
 413        (lambda ()
 414          (unless (or (file-exists-p \"makefile\")
 415                      (file-exists-p \"Makefile\"))
 416            (set (make-local-variable 'compile-command)
 417                 (concat \"make -k \"
 418                         (file-name-sans-extension buffer-file-name))))))"
 419   :type 'string
 420   :group 'compilation)
 421
 422 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 423 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 424 ;; key.  This holds the tree seen from root, for storing new nodes.
 425 (defvar compilation-locs ())
 426
 427 (defvar compilation-debug nil
 428   "*Set this to t before creating a *compilation* buffer.
 429 Then every error line will have a debug text property with the matcher that
 430 fit this line and the match data.  Use `describe-text-properties'.")
 431
 432 (defvar compilation-exit-message-function nil "\
 433 If non-nil, called when a compilation process dies to return a status message.
 434 This should be a function of three arguments: process status, exit status,
 435 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 436 write into the compilation buffer, and to put in its mode line.")
 437
 438 (defvar compilation-environment nil
 439   "*List of environment variables for compilation to inherit.
 440 Each element should be a string of the form ENVVARNAME=VALUE.
 441 This list is temporarily prepended to `process-environment' prior to
 442 starting the compilation process.")
 443
 444 ;; History of compile commands.
 445 (defvar compile-history nil)
 446
 447 (defface compilation-warning-face
 448   '((((type tty) (class color)) (:foreground "cyan" :weight bold))
 449     (((class color)) (:foreground "Orange" :weight bold))
 450     (t (:weight bold)))
 451   "Face used to highlight compiler warnings."
 452   :group 'font-lock-highlighting-faces
 453   :version "21.4")
 454
 455 (defface compilation-info-face
 456   '((((type tty) (class color)) (:foreground "green" :weight bold))
 457     (((class color) (background light)) (:foreground "Green3" :weight bold))
 458     (((class color) (background dark)) (:foreground "Green" :weight bold))
 459     (t (:weight bold)))
 460   "Face used to highlight compiler warnings."
 461   :group 'font-lock-highlighting-faces
 462   :version "21.4")
 463
 464 (defvar compilation-message-face nil
 465   "Face name to use for whole messages.
 466 Faces `compilation-error-face', `compilation-warning-face',
 467 `compilation-info-face', `compilation-line-face' and
 468 `compilation-column-face' get prepended to this, when applicable.")
 469
 470 (defvar compilation-error-face 'font-lock-warning-face
 471   "Face name to use for file name in error messages.")
 472
 473 (defvar compilation-warning-face 'compilation-warning-face
 474   "Face name to use for file name in warning messages.")
 475
 476 (defvar compilation-info-face 'compilation-info-face
 477   "Face name to use for file name in informational messages.")
 478
 479 (defvar compilation-line-face 'font-lock-variable-name-face
 480   "Face name to use for line number in message.")
 481
 482 (defvar compilation-column-face 'font-lock-type-face
 483   "Face name to use for column number in message.")
 484
 485 ;; same faces as dired uses
 486 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 487   "Face name to use for column number in message.")
 488
 489 (defvar compilation-leave-directory-face 'font-lock-type-face
 490   "Face name to use for column number in message.")
 491
 492
 493
 494 ;; Used for compatibility with the old compile.el.
 495 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 496 (defvar compilation-parsing-end (make-marker))
 497 (defvar compilation-parse-errors-function nil)
 498 (defvar compilation-error-list nil)
 499 (defvar compilation-old-error-list nil)
 500
 501 (defun compilation-face (type)
 502   (or (and (car type) (match-end (car type)) compilation-warning-face)
 503       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 504       compilation-error-face))
 505
 506 (defun compilation-directory-properties (idx leave)
 507   (if leave (setq leave (match-end leave)))
 508   ;; find previous stack, and push onto it, or if `leave' pop it
 509   (let ((dir (previous-single-property-change (point) 'directory)))
 510     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 511                           (get-text-property dir 'directory))))
 512     `(face ,(if leave
 513                 compilation-leave-directory-face
 514               compilation-enter-directory-face)
 515       directory ,(if leave
 516                      (or (cdr dir)
 517                          '(nil))        ; nil only isn't a property-change
 518                    (cons (match-string-no-properties idx) dir))
 519       mouse-face highlight
 520       keymap compilation-button-map
 521       help-echo "mouse-2: visit current directory")))
 522
 523 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 524 ;; KEY element from the ALIST, creating it in the right position if not already
 525 ;; present. ALIST structure is
 526 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 527 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 528 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 529 ;; numbers can be inserted in front and searching can abort after half the
 530 ;; list on average.
 531 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 532 (defmacro compilation-assq (key alist)
 533   `(let* ((l1 ,alist)
 534           (l2 (cdr l1)))
 535      (car (if (if (null ,key)
 536                   (if l2 (null (caar l2)))
 537                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 538                   (setq l1 l2
 539                         l2 (cdr l1)))
 540                 (if l2 (eq ,key (caar l2))))
 541               l2
 542             (setcdr l1 (cons (list ,key) l2)))))))
 543
 544
 545 ;; This function is the central driver, called when font-locking to gather
 546 ;; all information needed to later jump to corresponding source code.
 547 ;; Return a property list with all meta information on this error location.
 548 (defun compilation-error-properties (file line end-line col end-col type fmt)
 549   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 550              (point))
 551     (if file
 552         (if (functionp file)
 553             (setq file (funcall file))
 554           (let (dir)
 555             (setq file (match-string-no-properties file))
 556             (unless (file-name-absolute-p file)
 557               (setq dir (previous-single-property-change (point) 'directory)
 558                     dir (if dir (or (get-text-property (1- dir) 'directory)
 559                                     (get-text-property dir 'directory)))))
 560             (setq file (cons file (car dir)))))
 561       ;; This message didn't mention one, get it from previous
 562       (setq file (previous-single-property-change (point) 'message)
 563             file (or (if file
 564                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 565                                          (get-text-property file 'message))))))
 566                      '("*unknown*"))))
 567     ;; All of these fields are optional, get them only if we have an index, and
 568     ;; it matched some part of the message.
 569     (and line
 570          (setq line (match-string-no-properties line))
 571          (setq line (string-to-number line)))
 572     (and end-line
 573          (setq end-line (match-string-no-properties end-line))
 574          (setq end-line (string-to-number end-line)))
 575     (and col
 576          (setq col (match-string-no-properties col))
 577          (setq col (- (string-to-number col) compilation-first-column)))
 578     (if (and end-col (setq end-col (match-string-no-properties end-col)))
 579         (setq end-col (- (string-to-number end-col) compilation-first-column))
 580       (if end-line (setq end-col -1)))
 581     (if (consp type)                    ; not a static type, check what it is.
 582         (setq type (or (and (car type) (match-end (car type)) 1)
 583                        (and (cdr type) (match-end (cdr type)) 0)
 584                        2)))
 585     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 586
 587 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 588   "Get the meta-info that will be added as text-properties.
 589 LINE, END-LINE, COL, END-COL are integers or nil.
 590 TYPE can be 0, 1, or 2.
 591 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 592   (unless file (setq file '("*unknown*")))
 593   (setq file (compilation-get-file-structure file fmt))
 594   ;; Get first already existing marker (if any has one, all have one).
 595   ;; Do this first, as the compilation-assq`s may create new nodes.
 596   (let* ((marker-line (car (cddr file)))        ; a line structure
 597          (marker (nth 3 (cadr marker-line)))    ; its marker
 598          (compilation-error-screen-columns compilation-error-screen-columns)
 599          end-marker loc end-loc)
 600     (if (not (and marker (marker-buffer marker)))
 601         (setq marker)                   ; no valid marker for this file
 602       (setq loc (or line 1))            ; normalize no linenumber to line 1
 603       (catch 'marker                    ; find nearest loc, at least one exists
 604         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 605           (if (> (car x) loc)           ; still bigger
 606               (setq marker-line x)
 607             (if (> (- (or (car marker-line) 1) loc)
 608                    (- loc (car x)))     ; current line is nearer
 609                 (setq marker-line x))
 610             (throw 'marker t))))
 611       (setq marker (nth 3 (cadr marker-line))
 612             marker-line (or (car marker-line) 1))
 613       (with-current-buffer (marker-buffer marker)
 614         (save-restriction
 615           (widen)
 616           (goto-char (marker-position marker))
 617           (when (or end-col end-line)
 618             (beginning-of-line (- (or end-line line) marker-line -1))
 619             (if (< end-col 0)
 620                 (end-of-line)
 621               (if compilation-error-screen-columns
 622                   (move-to-column end-col)
 623                 (forward-char end-col)))
 624             (setq end-marker (list (point-marker))))
 625           (beginning-of-line (if end-line
 626                                  (- end-line line -1)
 627                                (- loc marker-line -1)))
 628           (if col
 629               (if compilation-error-screen-columns
 630                   (move-to-column col)
 631                 (forward-char col))
 632             (forward-to-indentation 0))
 633           (setq marker (list (point-marker))))))
 634
 635     (setq loc (compilation-assq line (cdr file)))
 636     (if end-line
 637         (setq end-loc (compilation-assq end-line (cdr file))
 638               end-loc (compilation-assq end-col end-loc))
 639       (if end-col                       ; use same line element
 640           (setq end-loc (compilation-assq end-col loc))))
 641     (setq loc (compilation-assq col loc))
 642     ;; If they are new, make the loc(s) reference the file they point to.
 643     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 644     (if end-loc
 645         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 646
 647     ;; Must start with face
 648     `(face ,compilation-message-face
 649            message (,loc ,type ,end-loc)
 650            ,@(if compilation-debug
 651                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 652                           ,@(match-data))))
 653            help-echo ,(if col
 654                           "mouse-2: visit this file, line and column"
 655                         (if line
 656                             "mouse-2: visit this file and line"
 657                           "mouse-2: visit this file"))
 658            keymap compilation-button-map
 659            mouse-face highlight)))
 660
 661 (defun compilation-mode-font-lock-keywords ()
 662   "Return expressions to highlight in Compilation mode."
 663   (if compilation-parse-errors-function
 664       ;; An old package!  Try the compatibility code.
 665       '((compilation-compat-parse-errors))
 666     (append
 667      ;; make directory tracking
 668      (if compilation-directory-matcher
 669          `((,(car compilation-directory-matcher)
 670             ,@(mapcar (lambda (elt)
 671                         `(,(car elt)
 672                           (compilation-directory-properties
 673                            ,(car elt) ,(cdr elt))
 674                           t))
 675                       (cdr compilation-directory-matcher)))))
 676
 677      ;; Compiler warning/error lines.
 678      (mapcar
 679       (lambda (item)
 680         (if (symbolp item)
 681             (setq item (cdr (assq item
 682                                   compilation-error-regexp-alist-alist))))
 683         (let ((file (nth 1 item))
 684               (line (nth 2 item))
 685               (col (nth 3 item))
 686               (type (nth 4 item))
 687               end-line end-col fmt)
 688           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 689           (if (consp line)      (setq end-line (cdr line) line (car line)))
 690           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 691
 692           (if (functionp line)
 693               ;; The old compile.el had here an undocumented hook that
 694               ;; allowed `line' to be a function that computed the actual
 695               ;; error location.  Let's do our best.
 696               `(,(car item)
 697                 (0 (compilation-compat-error-properties
 698                     (funcall ',line (cons (match-string ,file)
 699                                           (cons default-directory
 700                                                 ',(nthcdr 4 item)))
 701                              ,(if col `(match-string ,col)))))
 702                 (,file compilation-error-face t))
 703
 704             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 705               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 706
 707             `(,(nth 0 item)
 708
 709               ,@(when (integerp file)
 710                   `((,file ,(if (consp type)
 711                                 `(compilation-face ',type)
 712                               (aref [compilation-info-face
 713                                      compilation-warning-face
 714                                      compilation-error-face]
 715                                     (or type 2))))))
 716
 717               ,@(when line
 718                   `((,line compilation-line-face nil t)))
 719               ,@(when end-line
 720                   `((,end-line compilation-line-face nil t)))
 721
 722               ,@(when col
 723                   `((,col compilation-column-face nil t)))
 724               ,@(when end-col
 725                   `((,end-col compilation-column-face nil t)))
 726
 727               ,@(nthcdr 6 item)
 728               (,(or (nth 5 item) 0)
 729                (compilation-error-properties ',file ,line ,end-line
 730                                              ,col ,end-col ',(or type 2)
 731                                              ',fmt)
 732                append)))))              ; for compilation-message-face
 733       compilation-error-regexp-alist)
 734
 735      compilation-mode-font-lock-keywords)))
 736
 737 \f
 738 ;;;###autoload
 739 (defun compile (command &optional comint)
 740   "Compile the program including the current buffer.  Default: run `make'.
 741 Runs COMMAND, a shell command, in a separate process asynchronously
 742 with output going to the buffer `*compilation*'.
 743
 744 If optional second arg COMINT is t the buffer will be in Comint mode with
 745 `compilation-shell-minor-mode'.
 746
 747 You can then use the command \\[next-error] to find the next error message
 748 and move to the source code that caused it.
 749
 750 Interactively, prompts for the command if `compilation-read-command' is
 751 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 752
 753 To run more than one compilation at once, start one and rename
 754 the \`*compilation*' buffer to some other name with
 755 \\[rename-buffer].  Then start the next one.  On most systems,
 756 termination of the main compilation process kills its
 757 subprocesses.
 758
 759 The name used for the buffer is actually whatever is returned by
 760 the function in `compilation-buffer-name-function', so you can set that
 761 to a function that generates a unique name."
 762   (interactive
 763    (if (or compilation-read-command current-prefix-arg)
 764        (list (read-from-minibuffer "Compile command: "
 765                                  (eval compile-command) nil nil
 766                                  '(compile-history . 1)))
 767      (list (eval compile-command))))
 768   (unless (equal command (eval compile-command))
 769     (setq compile-command command))
 770   (save-some-buffers (not compilation-ask-about-save) nil)
 771   (setq compilation-directory default-directory)
 772   (compilation-start command comint))
 773
 774 ;; run compile with the default command line
 775 (defun recompile ()
 776   "Re-compile the program including the current buffer.
 777 If this is run in a Compilation mode buffer, re-use the arguments from the
 778 original use.  Otherwise, recompile using `compile-command'."
 779   (interactive)
 780   (save-some-buffers (not compilation-ask-about-save) nil)
 781   (let ((default-directory (or compilation-directory default-directory)))
 782     (apply 'compilation-start (or compilation-arguments
 783                                   `(,(eval compile-command))))))
 784
 785 (defcustom compilation-scroll-output nil
 786   "*Non-nil to scroll the *compilation* buffer window as output appears.
 787
 788 Setting it causes the Compilation mode commands to put point at the
 789 end of their output window so that the end of the output is always
 790 visible rather than the beginning."
 791   :type 'boolean
 792   :version "20.3"
 793   :group 'compilation)
 794
 795
 796 (defun compilation-buffer-name (mode-name name-function)
 797   "Return the name of a compilation buffer to use.
 798 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 799 to determine the buffer name.
 800 Likewise if `compilation-buffer-name-function' is non-nil.
 801 If current buffer is in Compilation mode for the same mode name
 802 return the name of the current buffer, so that it gets reused.
 803 Otherwise, construct a buffer name from MODE-NAME."
 804   (cond (name-function
 805          (funcall name-function mode-name))
 806         (compilation-buffer-name-function
 807          (funcall compilation-buffer-name-function mode-name))
 808         ((and (eq major-mode 'compilation-mode)
 809               (equal mode-name (nth 2 compilation-arguments)))
 810          (buffer-name))
 811         (t
 812          (concat "*" (downcase mode-name) "*"))))
 813
 814 ;; This is a rough emulation of the old hack, until the transition to new
 815 ;; compile is complete.
 816 (defun compile-internal (command error-message
 817                                  &optional name-of-mode parser
 818                                  error-regexp-alist name-function
 819                                  enter-regexp-alist leave-regexp-alist
 820                                  file-regexp-alist nomessage-regexp-alist
 821                                  no-async highlight-regexp local-map)
 822   (if parser
 823       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 824   (let ((compilation-error-regexp-alist
 825          (append file-regexp-alist (or error-regexp-alist
 826                                        compilation-error-regexp-alist)))
 827         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 828                                                      "\\1" error-message)))
 829     (compilation-start command nil name-function highlight-regexp)))
 830 (make-obsolete 'compile-internal 'compilation-start)
 831
 832 (defun compilation-start (command &optional mode name-function highlight-regexp)
 833   "Run compilation command COMMAND (low level interface).
 834 The rest of the arguments are optional; for them, nil means use the default.
 835
 836 MODE is the major mode to set in the compilation buffer.  Mode
 837 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 838 NAME-FUNCTION is a function called to name the buffer.
 839
 840 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 841 the matching section of the visited source line; the default is to use the
 842 global value of `compilation-highlight-regexp'.
 843
 844 Returns the compilation buffer created."
 845   (or mode (setq mode 'compilation-mode))
 846   (let ((name-of-mode
 847          (if (eq mode t)
 848              (prog1 "compilation" (require 'comint))
 849            (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 850         (process-environment
 851          (append
 852           compilation-environment
 853           (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 854                   system-uses-terminfo)
 855               (list "TERM=dumb" "TERMCAP="
 856                     (format "COLUMNS=%d" (window-width)))
 857             (list "TERM=emacs"
 858                   (format "TERMCAP=emacs:co#%d:tc=unknown:"
 859                           (window-width))))
 860           ;; Set the EMACS variable, but
 861           ;; don't override users' setting of $EMACS.
 862           (unless (getenv "EMACS") '("EMACS=t"))
 863           process-environment))
 864         (thisdir default-directory)
 865         outwin outbuf)
 866     (with-current-buffer
 867         (setq outbuf
 868               (get-buffer-create
 869                (compilation-buffer-name name-of-mode name-function)))
 870       (let ((comp-proc (get-buffer-process (current-buffer))))
 871         (if comp-proc
 872             (if (or (not (eq (process-status comp-proc) 'run))
 873                     (yes-or-no-p
 874                      (format "A %s process is running; kill it? "
 875                              name-of-mode)))
 876                 (condition-case ()
 877                     (progn
 878                       (interrupt-process comp-proc)
 879                       (sit-for 1)
 880                       (delete-process comp-proc))
 881                   (error nil))
 882               (error "Cannot have two processes in `%s' at once"
 883                      (buffer-name)))))
 884       ;; Clear out the compilation buffer and make it writable.
 885       ;; Change its default-directory to the directory where the compilation
 886       ;; will happen, and insert a `cd' command to indicate this.
 887       (setq buffer-read-only nil)
 888       (buffer-disable-undo (current-buffer))
 889       (erase-buffer)
 890       (buffer-enable-undo (current-buffer))
 891       (setq default-directory thisdir)
 892       ;; output a mode setter, for saving and later reloading this buffer
 893       (insert "cd " thisdir "   # -*-" name-of-mode
 894               "-*-\nEntering directory `" thisdir "'\n" command "\n")
 895       (set-buffer-modified-p nil))
 896     ;; If we're already in the compilation buffer, go to the end
 897     ;; of the buffer, so point will track the compilation output.
 898     (if (eq outbuf (current-buffer))
 899         (goto-char (point-max)))
 900     ;; Pop up the compilation buffer.
 901     (setq outwin (display-buffer outbuf nil t))
 902     (with-current-buffer outbuf
 903       (if (not (eq mode t))
 904           (funcall mode)
 905         (with-no-warnings (comint-mode))
 906         (compilation-shell-minor-mode))
 907       ;; In what way is it non-ergonomic ?  -stef
 908       ;; (toggle-read-only 1) ;;; Non-ergonomic.
 909       (if highlight-regexp
 910           (set (make-local-variable 'compilation-highlight-regexp)
 911                highlight-regexp))
 912       (set (make-local-variable 'compilation-arguments)
 913            (list command mode name-function highlight-regexp))
 914       (set (make-local-variable 'revert-buffer-function)
 915            'compilation-revert-buffer)
 916       (set-window-start outwin (point-min))
 917       (or (eq outwin (selected-window))
 918           (set-window-point outwin (if compilation-scroll-output
 919                                        (point)
 920                                      (point-min))))
 921       ;; The setup function is called before compilation-set-window-height
 922       ;; so it can set the compilation-window-height buffer locally.
 923       (if compilation-process-setup-function
 924           (funcall compilation-process-setup-function))
 925       (compilation-set-window-height outwin)
 926       ;; Start the compilation.
 927       (if (fboundp 'start-process)
 928           (let ((proc (if (eq mode t)
 929                           (get-buffer-process
 930                            (with-no-warnings
 931                             (comint-exec outbuf (downcase mode-name)
 932                                          shell-file-name nil `("-c" ,command))))
 933                         (start-process-shell-command (downcase mode-name)
 934                                                      outbuf command))))
 935             ;; Make the buffer's mode line show process state.
 936             (setq mode-line-process '(":%s"))
 937             (set-process-sentinel proc 'compilation-sentinel)
 938             (set-process-filter proc 'compilation-filter)
 939             (set-marker (process-mark proc) (point) outbuf)
 940             (setq compilation-in-progress
 941                   (cons proc compilation-in-progress)))
 942         ;; No asynchronous processes available.
 943         (message "Executing `%s'..." command)
 944         ;; Fake modeline display as if `start-process' were run.
 945         (setq mode-line-process ":run")
 946         (force-mode-line-update)
 947         (sit-for 0)                     ; Force redisplay
 948         (let ((status (call-process shell-file-name nil outbuf nil "-c"
 949                                     command)))
 950           (cond ((numberp status)
 951                  (compilation-handle-exit 'exit status
 952                                           (if (zerop status)
 953                                               "finished\n"
 954                                             (format "\
 955 exited abnormally with code %d\n"
 956                                                     status))))
 957                 ((stringp status)
 958                  (compilation-handle-exit 'signal status
 959                                           (concat status "\n")))
 960                 (t
 961                  (compilation-handle-exit 'bizarre status status))))
 962         ;; Without async subprocesses, the buffer is not yet
 963         ;; fontified, so fontify it now.
 964         (let ((font-lock-verbose nil))  ; shut up font-lock messages
 965           (font-lock-fontify-buffer))
 966         (message "Executing `%s'...done" command)))
 967     (if (buffer-local-value 'compilation-scroll-output outbuf)
 968         (save-selected-window
 969           (select-window outwin)
 970           (goto-char (point-max))))
 971     ;; Make it so the next C-x ` will use this buffer.
 972     (setq next-error-last-buffer outbuf)))
 973
 974 (defun compilation-set-window-height (window)
 975   "Set the height of WINDOW according to `compilation-window-height'."
 976   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
 977     (and height
 978          (= (window-width window) (frame-width (window-frame window)))
 979          ;; If window is alone in its frame, aside from a minibuffer,
 980          ;; don't change its height.
 981          (not (eq window (frame-root-window (window-frame window))))
 982          ;; This save-current-buffer prevents us from changing the current
 983          ;; buffer, which might not be the same as the selected window's buffer.
 984          (save-current-buffer
 985            (save-selected-window
 986              (select-window window)
 987              (enlarge-window (- height (window-height))))))))
 988
 989 (defvar compilation-menu-map
 990   (let ((map (make-sparse-keymap "Errors")))
 991     (define-key map [stop-subjob]
 992       '("Stop Compilation" . kill-compilation))
 993     (define-key map [compilation-mode-separator2]
 994       '("----" . nil))
 995     (define-key map [compilation-first-error]
 996       '("First Error" . first-error))
 997     (define-key map [compilation-previous-error]
 998       '("Previous Error" . previous-error))
 999     (define-key map [compilation-next-error]
1000       '("Next Error" . next-error))
1001     map))
1002
1003 (defvar compilation-minor-mode-map
1004   (let ((map (make-sparse-keymap)))
1005     (define-key map [mouse-2] 'compile-goto-error)
1006     (define-key map "\C-c\C-c" 'compile-goto-error)
1007     (define-key map "\C-m" 'compile-goto-error)
1008     (define-key map "\C-c\C-k" 'kill-compilation)
1009     (define-key map "\M-n" 'compilation-next-error)
1010     (define-key map "\M-p" 'compilation-previous-error)
1011     (define-key map "\M-{" 'compilation-previous-file)
1012     (define-key map "\M-}" 'compilation-next-file)
1013     ;; Set up the menu-bar
1014     (define-key map [menu-bar compilation]
1015       (cons "Errors" compilation-menu-map))
1016     map)
1017   "Keymap for `compilation-minor-mode'.")
1018
1019 (defvar compilation-shell-minor-mode-map
1020   (let ((map (make-sparse-keymap)))
1021     (define-key map "\M-\C-m" 'compile-goto-error)
1022     (define-key map "\M-\C-n" 'compilation-next-error)
1023     (define-key map "\M-\C-p" 'compilation-previous-error)
1024     (define-key map "\M-{" 'compilation-previous-file)
1025     (define-key map "\M-}" 'compilation-next-file)
1026     ;; Set up the menu-bar
1027     (define-key map [menu-bar compilation]
1028       (cons "Errors" compilation-menu-map))
1029     map)
1030   "Keymap for `compilation-shell-minor-mode'.")
1031
1032 (defvar compilation-button-map
1033   (let ((map (make-sparse-keymap)))
1034     (define-key map [mouse-2] 'compile-goto-error)
1035     (define-key map "\C-m" 'compile-goto-error)
1036     map)
1037   "Keymap for compilation-message buttons.")
1038 (fset 'compilation-button-map compilation-button-map)
1039
1040 (defvar compilation-mode-map
1041   (let ((map (make-sparse-keymap)))
1042     (set-keymap-parent map compilation-minor-mode-map)
1043     (define-key map " " 'scroll-up)
1044     (define-key map "\^?" 'scroll-down)
1045
1046     ;; Set up the menu-bar
1047     (define-key map [menu-bar compilation]
1048       (cons "Compile" (make-sparse-keymap "Compile")))
1049     (define-key map [menu-bar compilation compilation-separator2]
1050       '("----" . nil))
1051     (define-key map [menu-bar compilation compilation-grep]
1052       '("Search Files (grep)" . grep))
1053     (define-key map [menu-bar compilation compilation-recompile]
1054       '("Recompile" . recompile))
1055     (define-key map [menu-bar compilation compilation-compile]
1056       '("Compile..." . compile))
1057     map)
1058   "Keymap for compilation log buffers.
1059 `compilation-minor-mode-map' is a parent of this.")
1060
1061 (put 'compilation-mode 'mode-class 'special)
1062
1063 (defvar compilation-skip-to-next-location t
1064   "*If non-nil, skip multiple error messages for the same source location.")
1065
1066 (defcustom compilation-skip-threshold 1
1067   "*Compilation motion commands skip less important messages.
1068 The value can be either 2 -- skip anything less than error, 1 --
1069 skip anything less than warning or 0 -- don't skip any messages.
1070 Note that all messages not positively identified as warning or
1071 info, are considered errors."
1072   :type '(choice (const :tag "Warnings and info" 2)
1073                  (const :tag "Info" 1)
1074                  (const :tag "None" 0))
1075   :group 'compilation
1076   :version "21.4")
1077
1078 (defcustom compilation-skip-visited nil
1079   "*Compilation motion commands skip visited messages if this is t.
1080 Visited messages are ones for which the file, line and column have been jumped
1081 to from the current content in the current compilation buffer, even if it was
1082 from a different message."
1083   :type 'boolean
1084   :group 'compilation
1085   :version "21.4")
1086
1087 ;;;###autoload
1088 (defun compilation-mode ()
1089   "Major mode for compilation log buffers.
1090 \\<compilation-mode-map>To visit the source for a line-numbered error,
1091 move point to the error message line and type \\[compile-goto-error].
1092 To kill the compilation, type \\[kill-compilation].
1093
1094 Runs `compilation-mode-hook' with `run-hooks' (which see)."
1095   (interactive)
1096   (kill-all-local-variables)
1097   (use-local-map compilation-mode-map)
1098   (setq major-mode 'compilation-mode
1099         mode-name "Compilation")
1100   (set (make-local-variable 'page-delimiter)
1101        compilation-page-delimiter)
1102   (compilation-setup)
1103   (run-mode-hooks 'compilation-mode-hook))
1104
1105 (defmacro define-compilation-mode (mode name doc &rest body)
1106   "This is like `define-derived-mode' without the PARENT argument.
1107 The parent is always `compilation-mode' and the customizable `compilation-...'
1108 variables are also set from the name of the mode you have chosen, by replacing
1109 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1110 variable exists."
1111   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1112     `(define-derived-mode ,mode compilation-mode ,name
1113        ,doc
1114        ,@(mapcar (lambda (v)
1115                    (setq v (cons v
1116                                  (intern-soft (replace-regexp-in-string
1117                                                "^compilation" mode-name
1118                                                (symbol-name v)))))
1119                    (and (cdr v)
1120                         (or (boundp (cdr v))
1121                             (if (boundp 'byte-compile-bound-variables)
1122                                 (memq (cdr v) byte-compile-bound-variables)))
1123                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1124                  '(compilation-buffer-name-function
1125                    compilation-directory-matcher
1126                    compilation-error
1127                    compilation-error-regexp-alist
1128                    compilation-error-regexp-alist-alist
1129                    compilation-error-screen-columns
1130                    compilation-finish-function
1131                    compilation-finish-functions
1132                    compilation-first-column
1133                    compilation-mode-font-lock-keywords
1134                    compilation-page-delimiter
1135                    compilation-parse-errors-filename-function
1136                    compilation-process-setup-function
1137                    compilation-scroll-output
1138                    compilation-search-path
1139                    compilation-skip-threshold
1140                    compilation-window-height))
1141        ,@body)))
1142
1143 (defun compilation-revert-buffer (ignore-auto noconfirm)
1144   (if buffer-file-name
1145       (let (revert-buffer-function)
1146         (revert-buffer ignore-auto noconfirm))
1147     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1148         (apply 'compilation-start compilation-arguments))))
1149
1150 (defvar compilation-current-error nil
1151   "Marker to the location from where the next error will be found.
1152 The global commands next/previous/first-error/goto-error use this.")
1153
1154 (defvar compilation-messages-start nil
1155   "Buffer position of the beginning of the compilation messages.
1156 If nil, use the beginning of buffer.")
1157
1158 ;; A function name can't be a hook, must be something with a value.
1159 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1160
1161 (defun compilation-setup (&optional minor)
1162   "Prepare the buffer for the compilation parsing commands to work.
1163 Optional argument MINOR indicates this is called from
1164 `compilation-minor-mode'."
1165   (make-local-variable 'compilation-current-error)
1166   (make-local-variable 'compilation-messages-start)
1167   (make-local-variable 'compilation-error-screen-columns)
1168   (make-local-variable 'overlay-arrow-position)
1169   ;; Note that compilation-next-error-function is for interfacing
1170   ;; with the next-error function in simple.el, and it's only
1171   ;; coincidentally named similarly to compilation-next-error.
1172   (setq next-error-function 'compilation-next-error-function)
1173   (set (make-local-variable 'font-lock-extra-managed-props)
1174        '(directory message help-echo mouse-face debug))
1175   (set (make-local-variable 'compilation-locs)
1176        (make-hash-table :test 'equal :weakness 'value))
1177   ;; lazy-lock would never find the message unless it's scrolled to.
1178   ;; jit-lock might fontify some things too late.
1179   (set (make-local-variable 'font-lock-support-mode) nil)
1180   (set (make-local-variable 'font-lock-maximum-size) nil)
1181   (let ((fld font-lock-defaults))
1182     (if (and minor fld)
1183         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1184       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1185     (if minor
1186         (if font-lock-mode
1187             (if fld
1188                 (font-lock-fontify-buffer)
1189               (font-lock-change-mode)
1190               (turn-on-font-lock))
1191           (turn-on-font-lock))
1192       ;; maybe defer font-lock till after derived mode is set up
1193       (run-mode-hooks 'compilation-turn-on-font-lock))))
1194
1195 ;;;###autoload
1196 (define-minor-mode compilation-shell-minor-mode
1197   "Toggle compilation shell minor mode.
1198 With arg, turn compilation mode on if and only if arg is positive.
1199 In this minor mode, all the error-parsing commands of the
1200 Compilation major mode are available but bound to keys that don't
1201 collide with Shell mode.  See `compilation-mode'.
1202 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1203   nil " Shell-Compile"
1204   :group 'compilation
1205   (if compilation-shell-minor-mode
1206       (compilation-setup t)
1207     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1208     (font-lock-fontify-buffer)))
1209
1210 ;;;###autoload
1211 (define-minor-mode compilation-minor-mode
1212   "Toggle compilation minor mode.
1213 With arg, turn compilation mode on if and only if arg is positive.
1214 In this minor mode, all the error-parsing commands of the
1215 Compilation major mode are available.  See `compilation-mode'.
1216 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1217   nil " Compilation"
1218   :group 'compilation
1219   (if compilation-minor-mode
1220       (compilation-setup t)
1221     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1222     (font-lock-fontify-buffer)))
1223
1224 (defun compilation-handle-exit (process-status exit-status msg)
1225   "Write MSG in the current buffer and hack its mode-line-process."
1226   (let ((buffer-read-only nil)
1227         (status (if compilation-exit-message-function
1228                     (funcall compilation-exit-message-function
1229                              process-status exit-status msg)
1230                   (cons msg exit-status)))
1231         (omax (point-max))
1232         (opoint (point)))
1233     ;; Record where we put the message, so we can ignore it later on.
1234     (goto-char omax)
1235     (insert ?\n mode-name " " (car status))
1236     (if (and (numberp compilation-window-height)
1237              (zerop compilation-window-height))
1238         (message "%s" (cdr status)))
1239     (if (bolp)
1240         (forward-char -1))
1241     (insert " at " (substring (current-time-string) 0 19))
1242     (goto-char (point-max))
1243     ;; Prevent that message from being recognized as a compilation error.
1244     (add-text-properties omax (point)
1245                          (append '(compilation-handle-exit t) nil))
1246     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1247     ;; Force mode line redisplay soon.
1248     (force-mode-line-update)
1249     (if (and opoint (< opoint omax))
1250         (goto-char opoint))
1251     (if compilation-finish-function
1252         (funcall compilation-finish-function (current-buffer) msg))
1253     (let ((functions compilation-finish-functions))
1254       (while functions
1255         (funcall (car functions) (current-buffer) msg)
1256         (setq functions (cdr functions))))))
1257
1258 ;; Called when compilation process changes state.
1259 (defun compilation-sentinel (proc msg)
1260   "Sentinel for compilation buffers."
1261   (if (memq (process-status proc) '(exit signal))
1262       (let ((buffer (process-buffer proc)))
1263         (if (null (buffer-name buffer))
1264             ;; buffer killed
1265             (set-process-buffer proc nil)
1266           (with-current-buffer buffer
1267             ;; Write something in the compilation buffer
1268             ;; and hack its mode line.
1269             (compilation-handle-exit (process-status proc)
1270                                      (process-exit-status proc)
1271                                      msg)
1272             ;; Since the buffer and mode line will show that the
1273             ;; process is dead, we can delete it now.  Otherwise it
1274             ;; will stay around until M-x list-processes.
1275             (delete-process proc)))
1276         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1277
1278 (defun compilation-filter (proc string)
1279   "Process filter for compilation buffers.
1280 Just inserts the text, but uses `insert-before-markers'."
1281   (if (buffer-name (process-buffer proc))
1282       (with-current-buffer (process-buffer proc)
1283         (let ((inhibit-read-only t))
1284           (save-excursion
1285             (goto-char (process-mark proc))
1286             (insert-before-markers string)
1287             (run-hooks 'compilation-filter-hook))))))
1288
1289 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1290 (defsubst compilation-buffer-internal-p ()
1291   "Test if inside a compilation buffer."
1292   (local-variable-p 'compilation-locs))
1293
1294 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1295 (defsubst compilation-buffer-p (buffer)
1296   "Test if BUFFER is a compilation buffer."
1297   (with-current-buffer buffer
1298     (compilation-buffer-internal-p)))
1299
1300 (defmacro compilation-loop (< property-change 1+ error)
1301   `(while (,< n 0)
1302       (or (setq pt (,property-change pt 'message))
1303           (error ,error compilation-error))
1304       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1305       (or (setq msg (get-text-property pt 'message))
1306           (if (setq pt (,property-change pt 'message))
1307               (setq msg (get-text-property pt 'message)))
1308           (error ,error compilation-error))
1309       (or (< (cadr msg) compilation-skip-threshold)
1310           (if different-file
1311               (eq (prog1 last (setq last (nth 2 (car msg))))
1312                   last))
1313           (if compilation-skip-visited
1314               (nthcdr 4 (car msg)))
1315           (if compilation-skip-to-next-location
1316               (eq (car msg) loc))
1317           ;; count this message only if none of the above are true
1318           (setq n (,1+ n)))))
1319
1320 (defun compilation-next-error (n &optional different-file pt)
1321   "Move point to the next error in the compilation buffer.
1322 Prefix arg N says how many error messages to move forwards (or
1323 backwards, if negative).
1324 Does NOT find the source line like \\[next-error]."
1325   (interactive "p")
1326   (or (compilation-buffer-p (current-buffer))
1327       (error "Not in a compilation buffer"))
1328   (or pt (setq pt (point)))
1329   (let* ((msg (get-text-property pt 'message))
1330          (loc (car msg))
1331          last)
1332     (if (zerop n)
1333         (unless (or msg                 ; find message near here
1334                     (setq msg (get-text-property (max (1- pt) (point-min))
1335                                                  'message)))
1336           (setq pt (previous-single-property-change pt 'message nil
1337                                                     (line-beginning-position)))
1338           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1339             (setq pt (next-single-property-change pt 'message nil
1340                                                   (line-end-position)))
1341             (or (setq msg (get-text-property pt 'message))
1342                 (setq pt (point)))))
1343       (setq last (nth 2 (car msg)))
1344       (if (>= n 0)
1345           (compilation-loop > next-single-property-change 1-
1346                             (if (get-buffer-process (current-buffer))
1347                                 "No more %ss yet"
1348                               "Moved past last %s"))
1349         ;; Don't move "back" to message at or before point.
1350         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1351         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1352         (compilation-loop < previous-single-property-change 1+
1353                           "Moved back before first %s")))
1354     (goto-char pt)
1355     (or msg
1356         (error "No %s here" compilation-error))))
1357
1358 (defun compilation-previous-error (n)
1359   "Move point to the previous error in the compilation buffer.
1360 Prefix arg N says how many error messages to move backwards (or
1361 forwards, if negative).
1362 Does NOT find the source line like \\[previous-error]."
1363   (interactive "p")
1364   (compilation-next-error (- n)))
1365
1366 (defun compilation-next-file (n)
1367   "Move point to the next error for a different file than the current one.
1368 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1369   (interactive "p")
1370   (compilation-next-error n t))
1371
1372 (defun compilation-previous-file (n)
1373   "Move point to the previous error for a different file than the current one.
1374 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1375   (interactive "p")
1376   (compilation-next-file (- n)))
1377
1378 (defun kill-compilation ()
1379   "Kill the process made by the \\[compile] or \\[grep] commands."
1380   (interactive)
1381   (let ((buffer (compilation-find-buffer)))
1382     (if (get-buffer-process buffer)
1383         (interrupt-process (get-buffer-process buffer))
1384       (error "The compilation process is not running"))))
1385
1386 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1387
1388 (defun compile-goto-error (&optional event)
1389   "Visit the source for the error message at point.
1390 Use this command in a compilation log buffer.  Sets the mark at point there."
1391   (interactive (list last-input-event))
1392   (if event (posn-set-point (event-end event)))
1393   (or (compilation-buffer-p (current-buffer))
1394       (error "Not in a compilation buffer"))
1395   (if (get-text-property (point) 'directory)
1396       (dired-other-window (car (get-text-property (point) 'directory)))
1397     (push-mark)
1398     (setq compilation-current-error (point))
1399     (next-error 0)))
1400
1401 ;; Return a compilation buffer.
1402 ;; If the current buffer is a compilation buffer, return it.
1403 ;; Otherwise, look for a compilation buffer and signal an error
1404 ;; if there are none.
1405 (defun compilation-find-buffer (&optional other-buffer)
1406   (next-error-find-buffer other-buffer 'compilation-buffer-internal-p))
1407
1408 ;;;###autoload
1409 (defun compilation-next-error-function (n &optional reset)
1410   (interactive "p")
1411   (set-buffer (compilation-find-buffer))
1412   (when reset
1413     (setq compilation-current-error nil))
1414   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1415          (last 1)
1416          (loc (compilation-next-error (or n 1) nil
1417                                       (or compilation-current-error
1418                                           compilation-messages-start
1419                                           (point-min))))
1420          (end-loc (nth 2 loc))
1421          (marker (point-marker)))
1422     (setq compilation-current-error (point-marker)
1423           overlay-arrow-position
1424             (if (bolp)
1425                 compilation-current-error
1426               (copy-marker (line-beginning-position)))
1427           loc (car loc))
1428     ;; If loc contains no marker, no error in that file has been visited.  If
1429     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1430     ;; markers for that file.
1431     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1432       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1433                                                   (or (cdar (nth 2 loc))
1434                                                       default-directory))
1435         (save-restriction
1436           (widen)
1437           (goto-char (point-min))
1438           ;; Treat file's found lines in forward order, 1 by 1.
1439           (dolist (line (reverse (cddr (nth 2 loc))))
1440             (when (car line)            ; else this is a filename w/o a line#
1441               (beginning-of-line (- (car line) last -1))
1442               (setq last (car line)))
1443             ;; Treat line's found columns and store/update a marker for each.
1444             (dolist (col (cdr line))
1445               (if (car col)
1446                   (if (eq (car col) -1) ; special case for range end
1447                       (end-of-line)
1448                     (if columns
1449                         (move-to-column (car col))
1450                       (beginning-of-line)
1451                       (forward-char (car col))))
1452                 (beginning-of-line)
1453                 (skip-chars-forward " \t"))
1454               (if (nth 3 col)
1455                   (set-marker (nth 3 col) (point))
1456                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1457     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1458     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1459
1460 (defun compilation-fake-loc (marker file &optional line col)
1461   "Preassociate MARKER with FILE.
1462 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1463 This is useful when you compile temporary files, but want
1464 automatic translation of the messages to the real buffer from
1465 which the temporary file came.  This only works if done before a
1466 message about FILE appears!
1467
1468 Optional args LINE and COL default to 1 and beginning of
1469 indentation respectively.  The marker is expected to reflect
1470 this.  In the simplest case the marker points to the first line
1471 of the region that was saved to the temp file.
1472
1473 If you concatenate several regions into the temp file (e.g. a
1474 header with variable assignments and a code region), you must
1475 call this several times, once each for the last line of one
1476 region and the first line of the next region."
1477   (or (consp file) (setq file (list file)))
1478   (setq file (compilation-get-file-structure file))
1479   (let ((loc (compilation-assq (or line 1) (cdr file))))
1480     (setq loc (compilation-assq col loc))
1481     (if (cdr loc)
1482         (setcdr (cddr loc) (list marker))
1483       (setcdr loc (list line file marker)))
1484     loc))
1485
1486 (defcustom compilation-context-lines 0
1487   "*Display this many lines of leading context before message.
1488 If nil, don't scroll the compilation output window."
1489   :type '(choice integer (const :tag "No window scrolling" nil))
1490   :group 'compilation
1491   :version "21.4")
1492
1493 (defsubst compilation-set-window (w mk)
1494   "Align the compilation output window W with marker MK near top."
1495   (if (integerp compilation-context-lines)
1496       (set-window-start w (save-excursion
1497                             (goto-char mk)
1498                             (beginning-of-line (- 1 compilation-context-lines))
1499                             (point))))
1500   (set-window-point w mk))
1501
1502 (defun compilation-goto-locus (msg mk end-mk)
1503   "Jump to an error corresponding to MSG at MK.
1504 All arguments are markers.  If END-MK is non nil, mark is set there."
1505   (if (eq (window-buffer (selected-window))
1506           (marker-buffer msg))
1507       ;; If the compilation buffer window is selected,
1508       ;; keep the compilation buffer in this window;
1509       ;; display the source in another window.
1510       (let ((pop-up-windows t))
1511         (pop-to-buffer (marker-buffer mk)))
1512     (if (window-dedicated-p (selected-window))
1513         (pop-to-buffer (marker-buffer mk))
1514       (switch-to-buffer (marker-buffer mk))))
1515   ;; If narrowing gets in the way of going to the right place, widen.
1516   (unless (eq (goto-char mk) (point))
1517     (widen)
1518     (goto-char mk))
1519   (if end-mk
1520       (push-mark end-mk nil t)
1521     (if mark-active (setq mark-active)))
1522   ;; If hideshow got in the way of
1523   ;; seeing the right place, open permanently.
1524   (dolist (ov (overlays-at (point)))
1525     (when (eq 'hs (overlay-get ov 'invisible))
1526       (delete-overlay ov)
1527       (goto-char mk)))
1528
1529   ;; Show compilation buffer in other window, scrolled to this error.
1530   (let* ((pop-up-windows t)
1531          ;; Use an existing window if it is in a visible frame.
1532          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1533                 ;; Pop up a window.
1534                 (display-buffer (marker-buffer msg))))
1535          (highlight-regexp (with-current-buffer (marker-buffer msg)
1536                              ;; also do this while we change buffer
1537                              (compilation-set-window w msg)
1538                              compilation-highlight-regexp)))
1539     (compilation-set-window-height w)
1540
1541     (when (and highlight-regexp
1542                (not (and end-mk transient-mark-mode)))
1543       (unless compilation-highlight-overlay
1544         (setq compilation-highlight-overlay
1545               (make-overlay (point-min) (point-min)))
1546         (overlay-put compilation-highlight-overlay 'face 'region))
1547       (with-current-buffer (marker-buffer mk)
1548         (save-excursion
1549           (end-of-line)
1550           (let ((end (point)))
1551             (beginning-of-line)
1552             (if (and (stringp highlight-regexp)
1553                      (re-search-forward highlight-regexp end t))
1554                 (progn
1555                   (goto-char (match-beginning 0))
1556                   (move-overlay compilation-highlight-overlay (match-beginning 0) (match-end 0)))
1557               (move-overlay compilation-highlight-overlay (point) end))
1558             (sit-for 0.5)
1559             (delete-overlay compilation-highlight-overlay)))))))
1560
1561 \f
1562 (defun compilation-find-file (marker filename dir &rest formats)
1563   "Find a buffer for file FILENAME.
1564 Search the directories in `compilation-search-path'.
1565 A nil in `compilation-search-path' means to try the
1566 current directory, which is passed in DIR.
1567 If FILENAME is not found at all, ask the user where to find it.
1568 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1569   (or formats (setq formats '("%s")))
1570   (save-excursion
1571     (let ((dirs compilation-search-path)
1572           buffer thisdir fmts name)
1573       (if (file-name-absolute-p filename)
1574           ;; The file name is absolute.  Use its explicit directory as
1575           ;; the first in the search path, and strip it from FILENAME.
1576           (setq filename (abbreviate-file-name (expand-file-name filename))
1577                 dirs (cons (file-name-directory filename) dirs)
1578                 filename (file-name-nondirectory filename)))
1579       ;; Now search the path.
1580       (while (and dirs (null buffer))
1581         (setq thisdir (or (car dirs) dir)
1582               fmts formats)
1583         ;; For each directory, try each format string.
1584         (while (and fmts (null buffer))
1585           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1586                 buffer (and (file-exists-p name)
1587                             (find-file-noselect name))
1588                 fmts (cdr fmts)))
1589         (setq dirs (cdr dirs)))
1590       (or buffer
1591           ;; The file doesn't exist.  Ask the user where to find it.
1592           (let ((pop-up-windows t))
1593             (compilation-set-window (display-buffer (marker-buffer marker))
1594                                     marker)
1595             (let ((name (expand-file-name
1596                          (read-file-name
1597                           (format "Find this error in: (default %s) "
1598                                   filename)
1599                           dir filename t))))
1600               (if (file-directory-p name)
1601                   (setq name (expand-file-name filename name)))
1602               (setq buffer (and (file-exists-p name)
1603                                 (find-file name))))))
1604       ;; Make intangible overlays tangible.
1605       (mapcar (function (lambda (ov)
1606                           (when (overlay-get ov 'intangible)
1607                             (overlay-put ov 'intangible nil))))
1608               (overlays-in (point-min) (point-max)))
1609       buffer)))
1610
1611 (defun compilation-get-file-structure (file &optional fmt)
1612   "Retrieve FILE's file-structure or create a new one.
1613 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1614
1615   (or (gethash file compilation-locs)
1616       ;; File was not previously encountered, at least not in the form passed.
1617       ;; Let's normalize it and look again.
1618       (let ((filename (car file))
1619             (default-directory (if (cdr file)
1620                                    (file-truename (cdr file))
1621                                  default-directory)))
1622
1623         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1624         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1625         ;; buffer.)
1626         (if (boundp 'comint-file-name-prefix)
1627             (if (file-name-absolute-p filename)
1628                 (setq filename
1629                       (concat (with-no-warnings comint-file-name-prefix) filename))
1630               (setq default-directory
1631                     (file-truename
1632                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1633
1634         ;; If compilation-parse-errors-filename-function is
1635         ;; defined, use it to process the filename.
1636         (when compilation-parse-errors-filename-function
1637           (setq filename
1638                 (funcall compilation-parse-errors-filename-function
1639                          filename)))
1640
1641         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1642         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1643         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1644         ;; the appropriate file.  So we look for doubled slashes in the file
1645         ;; name and fix them.
1646         (setq filename (command-line-normalize-file-name filename))
1647
1648         ;; Now eliminate any "..", because find-file would get them wrong.
1649         ;; Make relative and absolute filenames, with or without links, the
1650         ;; same.
1651         (setq filename
1652               (list (abbreviate-file-name
1653                      (file-truename (if (cdr file)
1654                                         (expand-file-name filename)
1655                                       filename)))))
1656
1657         ;; Store it for the possibly unnormalized name
1658         (puthash file
1659                  ;; Retrieve or create file-structure for normalized name
1660                  (or (gethash filename compilation-locs)
1661                      (puthash filename (list filename fmt) compilation-locs))
1662                  compilation-locs))))
1663
1664 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1665
1666 ;;; Compatibility with the old compile.el.
1667
1668 (defun compile-buffer-substring (n) (if n (match-string n)))
1669
1670 (defun compilation-compat-error-properties (err)
1671   "Map old-style error ERR to new-style message."
1672   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1673   ;; (MARKER . MARKER).
1674   (let ((dst (cdr err)))
1675     (if (markerp dst)
1676         ;; Must start with a face, for font-lock.
1677         `(face nil
1678           message ,(list (list nil nil nil dst) 2)
1679           help-echo "mouse-2: visit the source location"
1680           keymap compilation-button-map
1681           mouse-face highlight)
1682       ;; Too difficult to do it by hand: dispatch to the normal code.
1683       (let* ((file (pop dst))
1684              (line (pop dst))
1685              (col (pop dst))
1686              (filename (pop file))
1687              (dirname (pop file))
1688              (fmt (pop file)))
1689         (compilation-internal-error-properties
1690          (cons filename dirname) line nil col nil 2 fmt)))))
1691
1692 (defun compilation-compat-parse-errors (limit)
1693   (when compilation-parse-errors-function
1694     ;; FIXME: We should remove the rest of the compilation keywords
1695     ;; but we can't do that from here because font-lock is using
1696     ;; the value right now.  --stef
1697     (save-excursion
1698       (setq compilation-error-list nil)
1699       ;; Reset compilation-parsing-end each time because font-lock
1700       ;; might force us the re-parse many times (typically because
1701       ;; some code adds some text-property to the output that we
1702       ;; already parsed).  You might say "why reparse", well:
1703       ;; because font-lock has just removed the `message' property so
1704       ;; have to do it all over again.
1705       (if compilation-parsing-end
1706           (set-marker compilation-parsing-end (point))
1707         (setq compilation-parsing-end (point-marker)))
1708       (condition-case nil
1709           ;; Ignore any error: we're calling this function earlier than
1710           ;; in the old compile.el so things might not all be setup yet.
1711           (funcall compilation-parse-errors-function limit nil)
1712         (error nil))
1713       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1714         (let* ((src (car err))
1715                (dst (cdr err))
1716                (loc (cond ((markerp dst) (list nil nil nil dst))
1717                           ((consp dst)
1718                            (list (nth 2 dst) (nth 1 dst)
1719                                  (cons (cdar dst) (caar dst)))))))
1720           (when loc
1721             (goto-char src)
1722             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1723             (put-text-property src (line-end-position)
1724                                'message (list loc 2)))))))
1725   (goto-char limit)
1726   nil)
1727
1728 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1729 (defun compilation-forget-errors ()
1730   ;; In case we hit the same file/line specs, we want to recompute a new
1731   ;; marker for them, so flush our cache.
1732   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1733   ;; FIXME: the old code reset the directory-stack, so maybe we should
1734   ;; put a `directory change' marker of some sort, but where?  -stef
1735   ;;
1736   ;; FIXME: The old code moved compilation-current-error (which was
1737   ;; virtually represented by a mix of compilation-parsing-end and
1738   ;; compilation-error-list) to point-min, but that was only meaningful for
1739   ;; the internal uses of compilation-forget-errors: all calls from external
1740   ;; packages seem to be followed by a move of compilation-parsing-end to
1741   ;; something equivalent to point-max.  So we speculatively move
1742   ;; compilation-current-error to point-max (since the external package
1743   ;; won't know that it should do it).  --stef
1744   (setq compilation-current-error nil)
1745   (let* ((proc (get-buffer-process (current-buffer)))
1746          (mark (if proc (process-mark proc)))
1747          (pos (or mark (point-max))))
1748     (setq compilation-messages-start
1749           ;; In the future, ignore the text already present in the buffer.
1750           ;; Since many process filter functions insert before markers,
1751           ;; we need to put ours just before the insertion point rather
1752           ;; than at the insertion point.  If that's not possible, then
1753           ;; don't use a marker.  --Stef
1754           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1755
1756 (provide 'compile)
1757
1758 ;;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1759 ;;; compile.el ends here